can-utils/configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([can-utils], [trunk], [socketcan-core@lists.berlios.de])
   6 AC_CONFIG_SRCDIR([lib.c])
   7 AC_CONFIG_MACRO_DIR([config/m4])
   8 AC_CONFIG_AUX_DIR([config/autoconf])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11
  12 #AM_MAINTAINER_MODE
  13
  14 CFLAGS="${CFLAGS} -Wall"
  15
  16 #
  17 # Checks for programs.
  18 #
  19 AC_PROG_CC
  20 #AM_MISSING_PROG(PERL, perl, $missing_dir)
  21 # libtool, old:
  22 AC_LIBTOOL_WIN32_DLL
  23 #AC_LIBTOOL_TAGS([])
  24 AC_PROG_LIBTOOL
  25 # libtool, new:
  26 # LT_INIT(win32-dll)
  27
  28 AM_INIT_AUTOMAKE([foreign no-exeext dist-bzip2])
  29
  30
  31 #
  32 # Checks for header files.
  33 #
  34 AC_CHECK_HEADERS([ \
  35         fcntl.h \
  36         limits.h \
  37         locale.h \
  38         stdint.h \
  39         stdlib.h \
  40         string.h \
  41         syslog.h \
  42         termios.h \
  43         unistd.h \
  44         \
  45         netinet/in.h \
  46         \
  47         sys/ioctl.h \
  48         sys/socket.h \
  49         sys/time.h \
  50 ])
  51
  52
  53 #
  54 # Checks for typedefs, structures, and compiler characteristics.
  55 #
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_UINT64_T
  59
  60
  61 #
  62 # Checks for library functions.
  63 #
  64 AC_FUNC_FORK
  65 AC_FUNC_MKTIME
  66 AC_CHECK_FUNCS([ \
  67         alarm \
  68         gettimeofday \
  69         localtime_r \
  70         memset \
  71         select \
  72         setlocale \
  73         socket \
  74         strchr \
  75         strerror \
  76         strstr \
  77         strtoul \
  78 ])
  79
  80
  81 #
  82 # check for SOCKETCAN specific defines and headers
  83 #
  84 AC_ARG_WITH(linux-headers,
  85     AS_HELP_STRING([--with-linux-headers=/path/to/kernel/include], [path to linux kernel headers]),
  86     [case "${withval}" in
  87         (""|y|ye|yes|n|no)
  88             AC_MSG_ERROR([You must supply a PATH as argument to --with-linux-headers]) ;;
  89         (*)
  90             LINUX_HEADERS_DIR="$(cd "${withval}" && pwd)"
  91             if test $? -ne 0; then
  92                 AC_MSG_ERROR(["${withval}" seems to be an invalid path!])
  93             fi ;;
  94     esac]
  95 )
  96
  97 maybe_linux_headers_dir="../kernel/2.6/include"
  98 if test -z "${LINUX_HEADERS_DIR}" -a -e "${maybe_linux_headers_dir}"; then
  99     LINUX_HEADERS_DIR="$(cd "${maybe_linux_headers_dir}" && pwd)"
 100 fi
 101 if test -n "${LINUX_HEADERS_DIR}"; then
 102     linux_CFLAGS="-I${LINUX_HEADERS_DIR}"
 103 fi
 104 CPPFLAGS="${CPPFLAGS} ${linux_CFLAGS}"
 105 AC_SUBST(linux_CFLAGS)
 106
 107
 108 AC_CHECK_HEADERS([ \
 109         linux/can/gw.h \
 110         linux/can/isotp.h \
 111         ],[],[],
 112 [
 113 #ifdef HAVE_SYS_SOCKET_H
 114 #include <sys/socket.h>
 115 #endif
 116 ])
 117
 118 AM_CONDITIONAL(CONFIG_GW, [test "${ac_cv_header_linux_can_gw_h}" = "yes"])
 119 AM_CONDITIONAL(CONFIG_ISOTP, [test "${ac_cv_header_linux_can_isotp_h}" = "yes"])
 120
 121
 122 AC_CHECK_DECL(SO_RXQ_OVFL,,
 123     [AC_DEFINE([SO_RXQ_OVFL], [40], [SO_RXQ_OVFL])]
 124 )
 125 AC_CHECK_DECL(PF_CAN,,
 126     [AC_DEFINE([PF_CAN], [29], [PF_CAN])]
 127 )
 128 AC_CHECK_DECL(AF_CAN,,
 129     [AC_DEFINE([AF_CAN], [PF_CAN], [AF_CAN])]
 130 )
 131
 132
 133 #
 134 # Debugging
 135 #
 136 AC_MSG_CHECKING([whether to enable debugging])
 137 AC_ARG_ENABLE(debug,
 138     AS_HELP_STRING([--enable-debug], [enable debugging [[default=no]]]),
 139         [case "$enableval" in
 140         (y | yes) CONFIG_DEBUG=yes ;;
 141         (*) CONFIG_DEBUG=no ;;
 142     esac],
 143     [CONFIG_DEBUG=no])
 144 AC_MSG_RESULT([${CONFIG_DEBUG}])
 145 if test "${CONFIG_DEBUG}" = "yes"; then
 146     CFLAGS="${CFLAGS} -Wsign-compare -Wfloat-equal -Wformat-security -g -O1"
 147     AC_DEFINE(DEBUG, 1, [debugging])
 148 else
 149     CFLAGS="${CFLAGS} -O2"
 150 fi
 151
 152
 153 AC_CONFIG_FILES([
 154         GNUmakefile
 155         ])
 156 AC_OUTPUT