src/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 set(KCF_LIB_SRC kcf.cpp kcf.h fft.cpp)
   4
   5 SET(FFT "OpenCV" CACHE STRING "Select FFT implementation")
   6 SET_PROPERTY(CACHE FFT PROPERTY STRINGS OpenCV OpenCV_cuFFT fftw cuFFTW cuFFT)
   7 MESSAGE(STATUS "FFT implementation: ${FFT}")
   8
   9 option(OPENMP "Use OpenMP library. Works with FFTW and OpenCV implementation." OFF)
  10 option(ASYNC "Works only if OPENCV_CUFFT is not ON. Will enable C++ async directive." OFF)
  11 option(CUDA_DEBUG "Enables error cheking for cuda and cufft. " OFF)
  12 option(BIG_BATCH "Enable transforming all features from all scales together." OFF)
  13
  14 IF(PROFILING)
  15   add_definitions(-DPROFILING )
  16   MESSAGE(STATUS "Profiling mode")
  17 ENDIF()
  18
  19 IF(BIG_BATCH)
  20   add_definitions(-DBIG_BATCH )
  21   MESSAGE(STATUS "Big_batch mode")
  22 ENDIF()
  23
  24 SET(use_cuda OFF)
  25
  26 IF(FFT STREQUAL "OpenCV")
  27   list(APPEND KCF_LIB_SRC fft_opencv.cpp complexmat.hpp)
  28 ELSEIF(FFT STREQUAL "OpenCV_cuFFT")
  29   list(APPEND KCF_LIB_SRC fft_opencv_cuda.cpp complexmat.hpp)
  30   add_definitions(-DOPENCV_CUFFT)
  31   set(use_cuda ON)
  32 ELSEIF(FFT STREQUAL "fftw")
  33   list(APPEND KCF_LIB_SRC fft_fftw.cpp complexmat.hpp)
  34   add_definitions(-DFFTW)
  35 ELSEIF(FFT STREQUAL "cuFFTW")
  36   list(APPEND KCF_LIB_SRC fft_fftw.cpp complexmat.hpp)
  37   add_definitions(-DFFTW -DCUFFTW)
  38   set(use_cuda ON)
  39 ELSEIF(FFT STREQUAL "cuFFT")
  40     list(APPEND KCF_LIB_SRC fft_cufft.cpp complexmat.cuh)
  41     add_definitions(-DCUFFT)
  42     set(use_cuda ON)
  43     iF(CUDA_DEBUG)
  44       add_definitions(-DCUDA_DEBUG)
  45       MESSAGE(STATUS "CUDA debug mode")
  46     ENDIF()
  47 ELSE()
  48   MESSAGE(FATAL_ERROR "Invalid FFT implementation selected")
  49 ENDIF()
  50
  51 IF(ASYNC AND NOT OPENMP)
  52   add_definitions(-DASYNC)
  53   MESSAGE(STATUS "ASYNC")
  54 ENDIF() #ASYNC
  55
  56 FIND_PACKAGE( OpenCV REQUIRED )
  57
  58 IF(use_cuda)
  59   find_package(CUDA REQUIRED)
  60
  61   if (NOT ${OpenCV_USE_CUFFT})
  62     message(SEND_ERROR "OpenCV was not built with cuFFT")
  63   endif()
  64
  65   include_directories ( ${CUDA_INCLUDE_DIRS} )
  66   set(CUDA_SEPARABLE_COMPILATION ON)
  67   set(CUDA_PROPAGATE_HOST_FLAGS OFF)
  68   set(CUDA_HOST_COMPILER /usr/bin/g++)
  69   list( APPEND CUDA_NVCC_FLAGS -O3 --gpu-architecture sm_62 -std=c++11 -default-stream per-thread)
  70   find_cuda_helper_libs(cufftw)
  71   IF(FFT STREQUAL "cuFFT")
  72   cuda_add_library(complexmat complexmat.cu)
  73   ENDIF()
  74
  75 ENDIF()
  76
  77 add_subdirectory(piotr_fhog)
  78 add_subdirectory(cn)
  79
  80 add_library(kcf STATIC ${KCF_LIB_SRC})
  81 target_link_libraries(kcf fhog cndata  ${OpenCV_LIBS})
  82 set_target_properties(kcf PROPERTIES VERSION 1.0.0 SOVERSION 1)
  83
  84 IF(FFT STREQUAL "fftw")
  85   target_link_libraries(kcf fftw3f)
  86   IF(OPENMP)
  87     target_link_libraries(kcf fftw3_omp)
  88   ELSEIF(ASYNC)
  89     target_link_libraries(kcf fftw3_threads)
  90   ENDIF()
  91 ENDIF() #FFTW
  92
  93 IF(FFT STREQUAL "cuFFTW")
  94   target_link_libraries(kcf ${CUDA_cufft_LIBRARY} ${CUDA_cufftw_LIBRARY})
  95 ENDIF() #cuFFTW
  96
  97 IF(FFT STREQUAL "cuFFT")
  98     target_link_libraries(kcf ${CUDA_cufft_LIBRARY} ${CUDA_LIBRARIES} complexmat)
  99 ENDIF()
 100
 101 IF(PROFILING)
 102   target_link_libraries(kcf pfm)
 103 ENDIF()