cmake/FindCUDA/make2cmake.cmake

   1 #  James Bigler, NVIDIA Corp (nvidia.com - jbigler)
   2 #  Abe Stephens, SCI Institute -- http://www.sci.utah.edu/~abe/FindCuda.html
   3 #
   4 #  Copyright (c) 2008 - 2009 NVIDIA Corporation.  All rights reserved.
   5 #
   6 #  Copyright (c) 2007-2009
   7 #  Scientific Computing and Imaging Institute, University of Utah
   8 #
   9 #  This code is licensed under the MIT License.  See the FindCUDA.cmake script
  10 #  for the text of the license.
  11
  12 # The MIT License
  13 #
  14 # License for the specific language governing rights and limitations under
  15 # Permission is hereby granted, free of charge, to any person obtaining a
  16 # copy of this software and associated documentation files (the "Software"),
  17 # to deal in the Software without restriction, including without limitation
  18 # the rights to use, copy, modify, merge, publish, distribute, sublicense,
  19 # and/or sell copies of the Software, and to permit persons to whom the
  20 # Software is furnished to do so, subject to the following conditions:
  21 #
  22 # The above copyright notice and this permission notice shall be included
  23 # in all copies or substantial portions of the Software.
  24 #
  25 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  26 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
  28 # THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 # DEALINGS IN THE SOFTWARE.
  32 #
  33
  34 #######################################################################
  35 # This converts a file written in makefile syntax into one that can be included
  36 # by CMake.
  37
  38 # Input variables
  39 #
  40 # verbose:BOOL=<>          OFF: Be as quiet as possible (default)
  41 #                          ON : Extra output
  42 #
  43 # input_file:FILEPATH=<>   Path to dependecy file in makefile format
  44 #
  45 # output_file:FILEPATH=<>  Path to file with dependencies in CMake readable variable
  46 #
  47
  48 file(READ ${input_file} depend_text)
  49
  50 if (NOT "${depend_text}" STREQUAL "")
  51
  52   # message("FOUND DEPENDS")
  53
  54   string(REPLACE "\\ " " " depend_text ${depend_text})
  55
  56   # This works for the nvcc -M generated dependency files.
  57   string(REGEX REPLACE "^.* : " "" depend_text ${depend_text})
  58   string(REGEX REPLACE "[ \\\\]*\n" ";" depend_text ${depend_text})
  59
  60   set(dependency_list "")
  61
  62   foreach(file ${depend_text})
  63
  64     string(REGEX REPLACE "^ +" "" file ${file})
  65
  66     # OK, now if we had a UNC path, nvcc has a tendency to only output the first '/'
  67     # instead of '//'.  Here we will test to see if the file exists, if it doesn't then
  68     # try to prepend another '/' to the path and test again.  If it still fails remove the
  69     # path.
  70
  71     if(NOT EXISTS "${file}")
  72       if (EXISTS "/${file}")
  73         set(file "/${file}")
  74       else()
  75         if(verbose)
  76           message(WARNING " Removing non-existent dependency file: ${file}")
  77         endif()
  78         set(file "")
  79       endif()
  80     endif()
  81
  82     # Make sure we check to see if we have a file, before asking if it is not a directory.
  83     # if(NOT IS_DIRECTORY "") will return TRUE.
  84     if(file AND NOT IS_DIRECTORY "${file}")
  85       # If softlinks start to matter, we should change this to REALPATH.  For now we need
  86       # to flatten paths, because nvcc can generate stuff like /bin/../include instead of
  87       # just /include.
  88       get_filename_component(file_absolute "${file}" ABSOLUTE)
  89       list(APPEND dependency_list "${file_absolute}")
  90     endif()
  91
  92   endforeach()
  93
  94 else()
  95   # message("FOUND NO DEPENDS")
  96 endif()
  97
  98 # Remove the duplicate entries and sort them.
  99 list(REMOVE_DUPLICATES dependency_list)
 100 list(SORT dependency_list)
 101
 102 foreach(file ${dependency_list})
 103   string(APPEND cuda_nvcc_depend " \"${file}\"\n")
 104 endforeach()
 105
 106 file(WRITE ${output_file} "# Generated by: make2cmake.cmake\nSET(CUDA_NVCC_DEPEND\n ${cuda_nvcc_depend})\n\n")