arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/memory.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/unistd.h>
  34
  35 /*
  36  * Context tracking subsystem.  Used to instrument transitions
  37  * between user and kernel mode.
  38  */
  39         .macro ct_user_exit, syscall = 0
  40 #ifdef CONFIG_CONTEXT_TRACKING
  41         bl      context_tracking_user_exit
  42         .if \syscall == 1
  43         /*
  44          * Save/restore needed during syscalls.  Restore syscall arguments from
  45          * the values already saved on stack during kernel_entry.
  46          */
  47         ldp     x0, x1, [sp]
  48         ldp     x2, x3, [sp, #S_X2]
  49         ldp     x4, x5, [sp, #S_X4]
  50         ldp     x6, x7, [sp, #S_X6]
  51         .endif
  52 #endif
  53         .endm
  54
  55         .macro ct_user_enter
  56 #ifdef CONFIG_CONTEXT_TRACKING
  57         bl      context_tracking_user_enter
  58 #endif
  59         .endm
  60
  61 /*
  62  * Bad Abort numbers
  63  *-----------------
  64  */
  65 #define BAD_SYNC        0
  66 #define BAD_IRQ         1
  67 #define BAD_FIQ         2
  68 #define BAD_ERROR       3
  69
  70         .macro  kernel_entry, el, regsize = 64
  71         sub     sp, sp, #S_FRAME_SIZE
  72         .if     \regsize == 32
  73         mov     w0, w0                          // zero upper 32 bits of x0
  74         .endif
  75         stp     x0, x1, [sp, #16 * 0]
  76         stp     x2, x3, [sp, #16 * 1]
  77         stp     x4, x5, [sp, #16 * 2]
  78         stp     x6, x7, [sp, #16 * 3]
  79         stp     x8, x9, [sp, #16 * 4]
  80         stp     x10, x11, [sp, #16 * 5]
  81         stp     x12, x13, [sp, #16 * 6]
  82         stp     x14, x15, [sp, #16 * 7]
  83         stp     x16, x17, [sp, #16 * 8]
  84         stp     x18, x19, [sp, #16 * 9]
  85         stp     x20, x21, [sp, #16 * 10]
  86         stp     x22, x23, [sp, #16 * 11]
  87         stp     x24, x25, [sp, #16 * 12]
  88         stp     x26, x27, [sp, #16 * 13]
  89         stp     x28, x29, [sp, #16 * 14]
  90
  91         .if     \el == 0
  92         mrs     x21, sp_el0
  93         mov     tsk, sp
  94         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
  95         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  96         disable_step_tsk x19, x20               // exceptions when scheduling.
  97
  98         mov     x29, xzr                        // fp pointed to user-space
  99         .else
 100         add     x21, sp, #S_FRAME_SIZE
 101         get_thread_info tsk
 102         /* Save the task's original addr_limit and set USER_DS (TASK_SIZE_64) */
 103         ldr     x20, [tsk, #TI_ADDR_LIMIT]
 104         str     x20, [sp, #S_ORIG_ADDR_LIMIT]
 105         mov     x20, #TASK_SIZE_64
 106         str     x20, [tsk, #TI_ADDR_LIMIT]
 107         /* No need to reset PSTATE.UAO, hardware's already set it to 0 for us */
 108         .endif /* \el == 0 */
 109         mrs     x22, elr_el1
 110         mrs     x23, spsr_el1
 111         stp     lr, x21, [sp, #S_LR]
 112         stp     x22, x23, [sp, #S_PC]
 113
 114         /*
 115          * Set syscallno to -1 by default (overridden later if real syscall).
 116          */
 117         .if     \el == 0
 118         mvn     x21, xzr
 119         str     x21, [sp, #S_SYSCALLNO]
 120         .endif
 121
 122         /*
 123          * Set sp_el0 to current thread_info.
 124          */
 125         .if     \el == 0
 126         msr     sp_el0, tsk
 127         .endif
 128
 129         /*
 130          * Registers that may be useful after this macro is invoked:
 131          *
 132          * x21 - aborted SP
 133          * x22 - aborted PC
 134          * x23 - aborted PSTATE
 135         */
 136         .endm
 137
 138         .macro  kernel_exit, el
 139         .if     \el != 0
 140         /* Restore the task's original addr_limit. */
 141         ldr     x20, [sp, #S_ORIG_ADDR_LIMIT]
 142         str     x20, [tsk, #TI_ADDR_LIMIT]
 143
 144         /* No need to restore UAO, it will be restored from SPSR_EL1 */
 145         .endif
 146
 147         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 148         .if     \el == 0
 149         ct_user_enter
 150         ldr     x23, [sp, #S_SP]                // load return stack pointer
 151         msr     sp_el0, x23
 152 #ifdef CONFIG_ARM64_ERRATUM_845719
 153 alternative_if ARM64_WORKAROUND_845719
 154         tbz     x22, #4, 1f
 155 #ifdef CONFIG_PID_IN_CONTEXTIDR
 156         mrs     x29, contextidr_el1
 157         msr     contextidr_el1, x29
 158 #else
 159         msr contextidr_el1, xzr
 160 #endif
 161 1:
 162 alternative_else_nop_endif
 163 #endif
 164         .endif
 165         msr     elr_el1, x21                    // set up the return data
 166         msr     spsr_el1, x22
 167         ldp     x0, x1, [sp, #16 * 0]
 168         ldp     x2, x3, [sp, #16 * 1]
 169         ldp     x4, x5, [sp, #16 * 2]
 170         ldp     x6, x7, [sp, #16 * 3]
 171         ldp     x8, x9, [sp, #16 * 4]
 172         ldp     x10, x11, [sp, #16 * 5]
 173         ldp     x12, x13, [sp, #16 * 6]
 174         ldp     x14, x15, [sp, #16 * 7]
 175         ldp     x16, x17, [sp, #16 * 8]
 176         ldp     x18, x19, [sp, #16 * 9]
 177         ldp     x20, x21, [sp, #16 * 10]
 178         ldp     x22, x23, [sp, #16 * 11]
 179         ldp     x24, x25, [sp, #16 * 12]
 180         ldp     x26, x27, [sp, #16 * 13]
 181         ldp     x28, x29, [sp, #16 * 14]
 182         ldr     lr, [sp, #S_LR]
 183         add     sp, sp, #S_FRAME_SIZE           // restore sp
 184         eret                                    // return to kernel
 185         .endm
 186
 187         .macro  get_thread_info, rd
 188         mrs     \rd, sp_el0
 189         .endm
 190
 191         .macro  irq_stack_entry
 192         mov     x19, sp                 // preserve the original sp
 193
 194         /*
 195          * Compare sp with the current thread_info, if the top
 196          * ~(THREAD_SIZE - 1) bits match, we are on a task stack, and
 197          * should switch to the irq stack.
 198          */
 199         and     x25, x19, #~(THREAD_SIZE - 1)
 200         cmp     x25, tsk
 201         b.ne    9998f
 202
 203         this_cpu_ptr irq_stack, x25, x26
 204         mov     x26, #IRQ_STACK_START_SP
 205         add     x26, x25, x26
 206
 207         /* switch to the irq stack */
 208         mov     sp, x26
 209
 210         /*
 211          * Add a dummy stack frame, this non-standard format is fixed up
 212          * by unwind_frame()
 213          */
 214         stp     x29, x19, [sp, #-16]!
 215         mov     x29, sp
 216
 217 9998:
 218         .endm
 219
 220         /*
 221          * x19 should be preserved between irq_stack_entry and
 222          * irq_stack_exit.
 223          */
 224         .macro  irq_stack_exit
 225         mov     sp, x19
 226         .endm
 227
 228 /*
 229  * These are the registers used in the syscall handler, and allow us to
 230  * have in theory up to 7 arguments to a function - x0 to x6.
 231  *
 232  * x7 is reserved for the system call number in 32-bit mode.
 233  */
 234 sc_nr   .req    x25             // number of system calls
 235 scno    .req    x26             // syscall number
 236 stbl    .req    x27             // syscall table pointer
 237 tsk     .req    x28             // current thread_info
 238
 239 /*
 240  * Interrupt handling.
 241  */
 242         .macro  irq_handler
 243         ldr_l   x1, handle_arch_irq
 244         mov     x0, sp
 245         irq_stack_entry
 246         blr     x1
 247         irq_stack_exit
 248         .endm
 249
 250         .text
 251
 252 /*
 253  * Exception vectors.
 254  */
 255         .pushsection ".entry.text", "ax"
 256
 257         .align  11
 258 ENTRY(vectors)
 259         ventry  el1_sync_invalid                // Synchronous EL1t
 260         ventry  el1_irq_invalid                 // IRQ EL1t
 261         ventry  el1_fiq_invalid                 // FIQ EL1t
 262         ventry  el1_error_invalid               // Error EL1t
 263
 264         ventry  el1_sync                        // Synchronous EL1h
 265         ventry  el1_irq                         // IRQ EL1h
 266         ventry  el1_fiq_invalid                 // FIQ EL1h
 267         ventry  el1_error_invalid               // Error EL1h
 268
 269         ventry  el0_sync                        // Synchronous 64-bit EL0
 270         ventry  el0_irq                         // IRQ 64-bit EL0
 271         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 272         ventry  el0_error_invalid               // Error 64-bit EL0
 273
 274 #ifdef CONFIG_COMPAT
 275         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 276         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 277         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 278         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 279 #else
 280         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 281         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 282         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 283         ventry  el0_error_invalid               // Error 32-bit EL0
 284 #endif
 285 END(vectors)
 286
 287 /*
 288  * Invalid mode handlers
 289  */
 290         .macro  inv_entry, el, reason, regsize = 64
 291         kernel_entry \el, \regsize
 292         mov     x0, sp
 293         mov     x1, #\reason
 294         mrs     x2, esr_el1
 295         b       bad_mode
 296         .endm
 297
 298 el0_sync_invalid:
 299         inv_entry 0, BAD_SYNC
 300 ENDPROC(el0_sync_invalid)
 301
 302 el0_irq_invalid:
 303         inv_entry 0, BAD_IRQ
 304 ENDPROC(el0_irq_invalid)
 305
 306 el0_fiq_invalid:
 307         inv_entry 0, BAD_FIQ
 308 ENDPROC(el0_fiq_invalid)
 309
 310 el0_error_invalid:
 311         inv_entry 0, BAD_ERROR
 312 ENDPROC(el0_error_invalid)
 313
 314 #ifdef CONFIG_COMPAT
 315 el0_fiq_invalid_compat:
 316         inv_entry 0, BAD_FIQ, 32
 317 ENDPROC(el0_fiq_invalid_compat)
 318
 319 el0_error_invalid_compat:
 320         inv_entry 0, BAD_ERROR, 32
 321 ENDPROC(el0_error_invalid_compat)
 322 #endif
 323
 324 el1_sync_invalid:
 325         inv_entry 1, BAD_SYNC
 326 ENDPROC(el1_sync_invalid)
 327
 328 el1_irq_invalid:
 329         inv_entry 1, BAD_IRQ
 330 ENDPROC(el1_irq_invalid)
 331
 332 el1_fiq_invalid:
 333         inv_entry 1, BAD_FIQ
 334 ENDPROC(el1_fiq_invalid)
 335
 336 el1_error_invalid:
 337         inv_entry 1, BAD_ERROR
 338 ENDPROC(el1_error_invalid)
 339
 340 /*
 341  * EL1 mode handlers.
 342  */
 343         .align  6
 344 el1_sync:
 345         kernel_entry 1
 346         mrs     x1, esr_el1                     // read the syndrome register
 347         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 348         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 349         b.eq    el1_da
 350         cmp     x24, #ESR_ELx_EC_IABT_CUR       // instruction abort in EL1
 351         b.eq    el1_ia
 352         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 353         b.eq    el1_undef
 354         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 355         b.eq    el1_sp_pc
 356         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 357         b.eq    el1_sp_pc
 358         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 359         b.eq    el1_undef
 360         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 361         b.ge    el1_dbg
 362         b       el1_inv
 363
 364 el1_ia:
 365         /*
 366          * Fall through to the Data abort case
 367          */
 368 el1_da:
 369         /*
 370          * Data abort handling
 371          */
 372         mrs     x0, far_el1
 373         enable_dbg
 374         // re-enable interrupts if they were enabled in the aborted context
 375         tbnz    x23, #7, 1f                     // PSR_I_BIT
 376         enable_irq
 377 1:
 378         mov     x2, sp                          // struct pt_regs
 379         bl      do_mem_abort
 380
 381         // disable interrupts before pulling preserved data off the stack
 382         disable_irq
 383         kernel_exit 1
 384 el1_sp_pc:
 385         /*
 386          * Stack or PC alignment exception handling
 387          */
 388         mrs     x0, far_el1
 389         enable_dbg
 390         mov     x2, sp
 391         b       do_sp_pc_abort
 392 el1_undef:
 393         /*
 394          * Undefined instruction
 395          */
 396         enable_dbg
 397         mov     x0, sp
 398         b       do_undefinstr
 399 el1_dbg:
 400         /*
 401          * Debug exception handling
 402          */
 403         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 404         cinc    x24, x24, eq                    // set bit '0'
 405         tbz     x24, #0, el1_inv                // EL1 only
 406         mrs     x0, far_el1
 407         mov     x2, sp                          // struct pt_regs
 408         bl      do_debug_exception
 409         kernel_exit 1
 410 el1_inv:
 411         // TODO: add support for undefined instructions in kernel mode
 412         enable_dbg
 413         mov     x0, sp
 414         mov     x2, x1
 415         mov     x1, #BAD_SYNC
 416         b       bad_mode
 417 ENDPROC(el1_sync)
 418
 419         .align  6
 420 el1_irq:
 421         kernel_entry 1
 422         enable_dbg
 423 #ifdef CONFIG_TRACE_IRQFLAGS
 424         bl      trace_hardirqs_off
 425 #endif
 426
 427         irq_handler
 428
 429 #ifdef CONFIG_PREEMPT
 430         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 431         cbnz    w24, 2f                         // preempt count != 0
 432         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 433         tbnz    x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 434
 435         ldr     w24, [tsk, #TI_PREEMPT_LAZY]    // get preempt lazy count
 436         cbnz    w24, 2f                         // preempt lazy count != 0
 437         tbz     x0, #TIF_NEED_RESCHED_LAZY, 2f  // needs rescheduling?
 438 1:
 439         bl      el1_preempt
 440 2:
 441 #endif
 442 #ifdef CONFIG_TRACE_IRQFLAGS
 443         bl      trace_hardirqs_on
 444 #endif
 445         kernel_exit 1
 446 ENDPROC(el1_irq)
 447
 448 #ifdef CONFIG_PREEMPT
 449 el1_preempt:
 450         mov     x24, lr
 451 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 452         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 453         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 454         tbnz    x0, #TIF_NEED_RESCHED_LAZY, 1b  // needs rescheduling?
 455         ret     x24
 456 #endif
 457
 458 /*
 459  * EL0 mode handlers.
 460  */
 461         .align  6
 462 el0_sync:
 463         kernel_entry 0
 464         mrs     x25, esr_el1                    // read the syndrome register
 465         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 466         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 467         b.eq    el0_svc
 468         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 469         b.eq    el0_da
 470         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 471         b.eq    el0_ia
 472         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 473         b.eq    el0_fpsimd_acc
 474         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 475         b.eq    el0_fpsimd_exc
 476         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 477         b.eq    el0_sys
 478         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 479         b.eq    el0_sp_pc
 480         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 481         b.eq    el0_sp_pc
 482         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 483         b.eq    el0_undef
 484         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 485         b.ge    el0_dbg
 486         b       el0_inv
 487
 488 #ifdef CONFIG_COMPAT
 489         .align  6
 490 el0_sync_compat:
 491         kernel_entry 0, 32
 492         mrs     x25, esr_el1                    // read the syndrome register
 493         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 494         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 495         b.eq    el0_svc_compat
 496         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 497         b.eq    el0_da
 498         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 499         b.eq    el0_ia
 500         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 501         b.eq    el0_fpsimd_acc
 502         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 503         b.eq    el0_fpsimd_exc
 504         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 505         b.eq    el0_sp_pc
 506         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 507         b.eq    el0_undef
 508         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 509         b.eq    el0_undef
 510         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 511         b.eq    el0_undef
 512         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 513         b.eq    el0_undef
 514         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 515         b.eq    el0_undef
 516         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 517         b.eq    el0_undef
 518         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 519         b.ge    el0_dbg
 520         b       el0_inv
 521 el0_svc_compat:
 522         /*
 523          * AArch32 syscall handling
 524          */
 525         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 526         uxtw    scno, w7                        // syscall number in w7 (r7)
 527         mov     sc_nr, #__NR_compat_syscalls
 528         b       el0_svc_naked
 529
 530         .align  6
 531 el0_irq_compat:
 532         kernel_entry 0, 32
 533         b       el0_irq_naked
 534 #endif
 535
 536 el0_da:
 537         /*
 538          * Data abort handling
 539          */
 540         mrs     x26, far_el1
 541         // enable interrupts before calling the main handler
 542         enable_dbg_and_irq
 543         ct_user_exit
 544         bic     x0, x26, #(0xff << 56)
 545         mov     x1, x25
 546         mov     x2, sp
 547         bl      do_mem_abort
 548         b       ret_to_user
 549 el0_ia:
 550         /*
 551          * Instruction abort handling
 552          */
 553         mrs     x26, far_el1
 554         // enable interrupts before calling the main handler
 555         enable_dbg_and_irq
 556         ct_user_exit
 557         mov     x0, x26
 558         mov     x1, x25
 559         mov     x2, sp
 560         bl      do_mem_abort
 561         b       ret_to_user
 562 el0_fpsimd_acc:
 563         /*
 564          * Floating Point or Advanced SIMD access
 565          */
 566         enable_dbg
 567         ct_user_exit
 568         mov     x0, x25
 569         mov     x1, sp
 570         bl      do_fpsimd_acc
 571         b       ret_to_user
 572 el0_fpsimd_exc:
 573         /*
 574          * Floating Point or Advanced SIMD exception
 575          */
 576         enable_dbg
 577         ct_user_exit
 578         mov     x0, x25
 579         mov     x1, sp
 580         bl      do_fpsimd_exc
 581         b       ret_to_user
 582 el0_sp_pc:
 583         /*
 584          * Stack or PC alignment exception handling
 585          */
 586         mrs     x26, far_el1
 587         // enable interrupts before calling the main handler
 588         enable_dbg_and_irq
 589         ct_user_exit
 590         mov     x0, x26
 591         mov     x1, x25
 592         mov     x2, sp
 593         bl      do_sp_pc_abort
 594         b       ret_to_user
 595 el0_undef:
 596         /*
 597          * Undefined instruction
 598          */
 599         // enable interrupts before calling the main handler
 600         enable_dbg_and_irq
 601         ct_user_exit
 602         mov     x0, sp
 603         bl      do_undefinstr
 604         b       ret_to_user
 605 el0_sys:
 606         /*
 607          * System instructions, for trapped cache maintenance instructions
 608          */
 609         enable_dbg_and_irq
 610         ct_user_exit
 611         mov     x0, x25
 612         mov     x1, sp
 613         bl      do_sysinstr
 614         b       ret_to_user
 615 el0_dbg:
 616         /*
 617          * Debug exception handling
 618          */
 619         tbnz    x24, #0, el0_inv                // EL0 only
 620         mrs     x0, far_el1
 621         mov     x1, x25
 622         mov     x2, sp
 623         bl      do_debug_exception
 624         enable_dbg
 625         ct_user_exit
 626         b       ret_to_user
 627 el0_inv:
 628         enable_dbg
 629         ct_user_exit
 630         mov     x0, sp
 631         mov     x1, #BAD_SYNC
 632         mov     x2, x25
 633         bl      bad_mode
 634         b       ret_to_user
 635 ENDPROC(el0_sync)
 636
 637         .align  6
 638 el0_irq:
 639         kernel_entry 0
 640 el0_irq_naked:
 641         enable_dbg
 642 #ifdef CONFIG_TRACE_IRQFLAGS
 643         bl      trace_hardirqs_off
 644 #endif
 645
 646         ct_user_exit
 647         irq_handler
 648
 649 #ifdef CONFIG_TRACE_IRQFLAGS
 650         bl      trace_hardirqs_on
 651 #endif
 652         b       ret_to_user
 653 ENDPROC(el0_irq)
 654
 655 /*
 656  * Register switch for AArch64. The callee-saved registers need to be saved
 657  * and restored. On entry:
 658  *   x0 = previous task_struct (must be preserved across the switch)
 659  *   x1 = next task_struct
 660  * Previous and next are guaranteed not to be the same.
 661  *
 662  */
 663 ENTRY(cpu_switch_to)
 664         mov     x10, #THREAD_CPU_CONTEXT
 665         add     x8, x0, x10
 666         mov     x9, sp
 667         stp     x19, x20, [x8], #16             // store callee-saved registers
 668         stp     x21, x22, [x8], #16
 669         stp     x23, x24, [x8], #16
 670         stp     x25, x26, [x8], #16
 671         stp     x27, x28, [x8], #16
 672         stp     x29, x9, [x8], #16
 673         str     lr, [x8]
 674         add     x8, x1, x10
 675         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 676         ldp     x21, x22, [x8], #16
 677         ldp     x23, x24, [x8], #16
 678         ldp     x25, x26, [x8], #16
 679         ldp     x27, x28, [x8], #16
 680         ldp     x29, x9, [x8], #16
 681         ldr     lr, [x8]
 682         mov     sp, x9
 683         and     x9, x9, #~(THREAD_SIZE - 1)
 684         msr     sp_el0, x9
 685         ret
 686 ENDPROC(cpu_switch_to)
 687
 688 /*
 689  * This is the fast syscall return path.  We do as little as possible here,
 690  * and this includes saving x0 back into the kernel stack.
 691  */
 692 ret_fast_syscall:
 693         disable_irq                             // disable interrupts
 694         str     x0, [sp, #S_X0]                 // returned x0
 695         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 696         and     x2, x1, #_TIF_SYSCALL_WORK
 697         cbnz    x2, ret_fast_syscall_trace
 698         and     x2, x1, #_TIF_WORK_MASK
 699         cbnz    x2, work_pending
 700         enable_step_tsk x1, x2
 701         kernel_exit 0
 702 ret_fast_syscall_trace:
 703         enable_irq                              // enable interrupts
 704         b       __sys_trace_return_skipped      // we already saved x0
 705
 706 /*
 707  * Ok, we need to do extra processing, enter the slow path.
 708  */
 709 work_pending:
 710         mov     x0, sp                          // 'regs'
 711         bl      do_notify_resume
 712 #ifdef CONFIG_TRACE_IRQFLAGS
 713         bl      trace_hardirqs_on               // enabled while in userspace
 714 #endif
 715         ldr     x1, [tsk, #TI_FLAGS]            // re-check for single-step
 716         b       finish_ret_to_user
 717 /*
 718  * "slow" syscall return path.
 719  */
 720 ret_to_user:
 721         disable_irq                             // disable interrupts
 722         ldr     x1, [tsk, #TI_FLAGS]
 723         and     x2, x1, #_TIF_WORK_MASK
 724         cbnz    x2, work_pending
 725 finish_ret_to_user:
 726         enable_step_tsk x1, x2
 727         kernel_exit 0
 728 ENDPROC(ret_to_user)
 729
 730 /*
 731  * This is how we return from a fork.
 732  */
 733 ENTRY(ret_from_fork)
 734         bl      schedule_tail
 735         cbz     x19, 1f                         // not a kernel thread
 736         mov     x0, x20
 737         blr     x19
 738 1:      get_thread_info tsk
 739         b       ret_to_user
 740 ENDPROC(ret_from_fork)
 741
 742 /*
 743  * SVC handler.
 744  */
 745         .align  6
 746 el0_svc:
 747         adrp    stbl, sys_call_table            // load syscall table pointer
 748         uxtw    scno, w8                        // syscall number in w8
 749         mov     sc_nr, #__NR_syscalls
 750 el0_svc_naked:                                  // compat entry point
 751         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 752         enable_dbg_and_irq
 753         ct_user_exit 1
 754
 755         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 756         tst     x16, #_TIF_SYSCALL_WORK
 757         b.ne    __sys_trace
 758         cmp     scno, sc_nr                     // check upper syscall limit
 759         b.hs    ni_sys
 760         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 761         blr     x16                             // call sys_* routine
 762         b       ret_fast_syscall
 763 ni_sys:
 764         mov     x0, sp
 765         bl      do_ni_syscall
 766         b       ret_fast_syscall
 767 ENDPROC(el0_svc)
 768
 769         /*
 770          * This is the really slow path.  We're going to be doing context
 771          * switches, and waiting for our parent to respond.
 772          */
 773 __sys_trace:
 774         mov     w0, #-1                         // set default errno for
 775         cmp     scno, x0                        // user-issued syscall(-1)
 776         b.ne    1f
 777         mov     x0, #-ENOSYS
 778         str     x0, [sp, #S_X0]
 779 1:      mov     x0, sp
 780         bl      syscall_trace_enter
 781         cmp     w0, #-1                         // skip the syscall?
 782         b.eq    __sys_trace_return_skipped
 783         uxtw    scno, w0                        // syscall number (possibly new)
 784         mov     x1, sp                          // pointer to regs
 785         cmp     scno, sc_nr                     // check upper syscall limit
 786         b.hs    __ni_sys_trace
 787         ldp     x0, x1, [sp]                    // restore the syscall args
 788         ldp     x2, x3, [sp, #S_X2]
 789         ldp     x4, x5, [sp, #S_X4]
 790         ldp     x6, x7, [sp, #S_X6]
 791         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 792         blr     x16                             // call sys_* routine
 793
 794 __sys_trace_return:
 795         str     x0, [sp, #S_X0]                 // save returned x0
 796 __sys_trace_return_skipped:
 797         mov     x0, sp
 798         bl      syscall_trace_exit
 799         b       ret_to_user
 800
 801 __ni_sys_trace:
 802         mov     x0, sp
 803         bl      do_ni_syscall
 804         b       __sys_trace_return
 805
 806         .popsection                             // .entry.text
 807
 808 /*
 809  * Special system call wrappers.
 810  */
 811 ENTRY(sys_rt_sigreturn_wrapper)
 812         mov     x0, sp
 813         b       sys_rt_sigreturn
 814 ENDPROC(sys_rt_sigreturn_wrapper)