board/h8300/hi_cpu2/libs/hi_cpu2.ld-boot

   1 /* linker script for inteligent boot block (for user-program-mode boot-loader in flash) */
   2
   3 INCLUDE "hi_cpu2.ld-cfg"
   4
   5 PROVIDE( ___stack_top = ( __iram0_end & ~ 3 ) - 4 );
   6 /*PROVIDE( ___setup_board = _start);*/
   7
   8 STARTUP(crt0.o)
   9 INPUT(bsp0common.o)
  10 INPUT(bsp0hwinit.o setup_board.o)
  11
  12 SECTIONS
  13 {
  14         .fvector :
  15         {
  16           ___flashbb_vector = . ;
  17           LONG( ABSOLUTE( ___setup_board ) )
  18           *(.fvector)
  19         } > flashvec
  20
  21         .shadreg (NOLOAD) :
  22         {
  23           *(.shadreg)
  24           . = ALIGN( 0x4 ) ;
  25         } > iram0
  26
  27         .text.boot_fn ALIGN(4) :
  28         {
  29           . = ALIGN( 0x4 ) ;
  30           KEEP (boot_fn.o(.text))
  31           KEEP (boot_fn.o(.rodata))
  32           KEEP (boot_fn.o(.strings))
  33           . = ALIGN( 4 ) ;
  34         } > iram0 AT>flashbb
  35         ___boot_fn_start = ADDR(.text.boot_fn);
  36         ___boot_fn_end   = ADDR(.text.boot_fn) + SIZEOF(.text.boot_fn);
  37         ___boot_fn_load  = LOADADDR(.text.boot_fn);
  38
  39         .text :
  40         {
  41           text_start = . ;
  42           KEEP (crt0.o(.text))
  43           *(.text)
  44           *(.rodata)
  45           *(.text .stub .text.* .gnu.linkonce.t.*)
  46           *(.rodata .rodata.* .gnu.linkonce.r.*)
  47           *(.strings)
  48           . = ALIGN( 0x4 ) ;
  49           _etext = ALIGN( 0x4 ) ;
  50         } > flashbb
  51
  52         .tors :
  53         {
  54           ___ctors = . ;
  55           *(.ctors)
  56           ___ctors_end = . ;
  57           ___dtors = . ;
  58           *(.dtors)
  59           ___dtors_end = . ;
  60           . = ALIGN( 0x4 ) ;
  61           ___data_lma = ALIGN( 0x4 ) ;
  62         }  > flashbb /*at> flashusr*/
  63
  64         .data :
  65           AT ( ADDR( .tors ) + SIZEOF( .tors ) )
  66         {
  67           _data_start = . ;
  68           *(.data)
  69           . = ALIGN( 0x4 ) ;
  70           _edata = ALIGN( 0x4 ) ;
  71         } > iram1
  72
  73         /* ___data_lma = LOADADDR(.data) ; */
  74
  75         .bss :
  76         {
  77           _bss_start = ALIGN( 0x10 ) ;
  78           *(.bss)
  79           *(COMMON)
  80           . = ALIGN( 0x4 ) ;
  81           _end = . ;
  82         } > iram0
  83
  84         .flashusr :
  85         {
  86           _usrprog_start = . ;
  87         } > flashusr
  88
  89         /* Stabs debugging sections.  */
  90         .stab          0 (NOLOAD): { *(.stab) }
  91         .stabstr       0 (NOLOAD): { *(.stabstr) }
  92         .stab.excl     0 (NOLOAD): { *(.stab.excl) }
  93         .stab.exclstr  0 (NOLOAD): { *(.stab.exclstr) }
  94         .stab.index    0 (NOLOAD): { *(.stab.index) }
  95         .stab.indexstr 0 (NOLOAD): { *(.stab.indexstr) }
  96         .comment       0 (NOLOAD): { *(.comment) }
  97         /* DWARF debug sections.
  98            Symbols in the DWARF debugging sections are relative to the beginning
  99            of the section so we begin them at 0.  */
 100         /* DWARF 1 */
 101         .debug          0 (NOLOAD): { *(.debug) }
 102         .line           0 (NOLOAD): { *(.line) }
 103         /* GNU DWARF 1 extensions */
 104         .debug_srcinfo  0 (NOLOAD): { *(.debug_srcinfo) }
 105         .debug_sfnames  0 (NOLOAD): { *(.debug_sfnames) }
 106         /* DWARF 1.1 and DWARF 2 */
 107         .debug_aranges  0 (NOLOAD): { *(.debug_aranges) }
 108         .debug_pubnames 0 (NOLOAD): { *(.debug_pubnames) }
 109         /* DWARF 2 */
 110         .debug_info     0 (NOLOAD): { *(.debug_info .gnu.linkonce.wi.*) }
 111         .debug_abbrev   0 (NOLOAD): { *(.debug_abbrev) }
 112         .debug_line     0 (NOLOAD): { *(.debug_line) }
 113         .debug_frame    0 (NOLOAD): { *(.debug_frame) }
 114         .debug_str      0 (NOLOAD): { *(.debug_str) }
 115         .debug_loc      0 (NOLOAD): { *(.debug_loc) }
 116         .debug_macinfo  0 (NOLOAD): { *(.debug_macinfo) }
 117         /* SGI/MIPS DWARF 2 extensions */
 118         .debug_weaknames 0 (NOLOAD): { *(.debug_weaknames) }
 119         .debug_funcnames 0 (NOLOAD): { *(.debug_funcnames) }
 120         .debug_typenames 0 (NOLOAD): { *(.debug_typenames) }
 121         .debug_varnames  0 (NOLOAD): { *(.debug_varnames) }
 122         /* DWARF 3 */
 123         .debug_pubtypes 0 (NOLOAD): { *(.debug_pubtypes) }
 124         .debug_ranges   0 (NOLOAD): { *(.debug_ranges) }
 125         .gnu.attributes 0 (NOLOAD): { KEEP (*(.gnu.attributes)) }
 126 }