company.el

   1 ;;; company.el --- Modular in-buffer completion framework  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2009-2014  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6 ;; Maintainer: Dmitry Gutov <dgutov@yandex.ru>
   7 ;; Version: 0.7.3
   8 ;; Keywords: abbrev, convenience, matching
   9 ;; URL: http://company-mode.github.io/
  10 ;; Compatibility: GNU Emacs 24.x
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; Company is a modular completion mechanism.  Modules for retrieving completion
  30 ;; candidates are called back-ends, modules for displaying them are front-ends.
  31 ;;
  32 ;; Company comes with many back-ends, e.g. `company-elisp'.  These are
  33 ;; distributed in separate files and can be used individually.
  34 ;;
  35 ;; Place company.el and the back-ends you want to use in a directory and add the
  36 ;; following to your .emacs:
  37 ;; (add-to-list 'load-path "/path/to/company")
  38 ;; (autoload 'company-mode "company" nil t)
  39 ;;
  40 ;; Enable company-mode with M-x company-mode.  For further information look at
  41 ;; the documentation for `company-mode' (C-h f company-mode RET)
  42 ;;
  43 ;; If you want to start a specific back-end, call it interactively or use
  44 ;; `company-begin-backend'.  For example:
  45 ;; M-x company-abbrev will prompt for and insert an abbrev.
  46 ;;
  47 ;; To write your own back-end, look at the documentation for `company-backends'.
  48 ;; Here is a simple example completing "foo":
  49 ;;
  50 ;; (defun company-my-backend (command &optional arg &rest ignored)
  51 ;;   (pcase command
  52 ;;     (`prefix (when (looking-back "foo\\>")
  53 ;;               (match-string 0)))
  54 ;;     (`candidates (list "foobar" "foobaz" "foobarbaz"))
  55 ;;     (`meta (format "This value is named %s" arg))))
  56 ;;
  57 ;; Sometimes it is a good idea to mix several back-ends together, for example to
  58 ;; enrich gtags with dabbrev-code results (to emulate local variables).
  59 ;; To do this, add a list with both back-ends as an element in company-backends.
  60 ;;
  61 ;; Known Issues:
  62 ;; When point is at the very end of the buffer, the pseudo-tooltip appears very
  63 ;; wrong, unless company is allowed to temporarily insert a fake newline.
  64 ;; This behavior is enabled by `company-end-of-buffer-workaround'.
  65 ;;
  66 ;;; Change Log:
  67 ;;
  68 ;; See NEWS.md in the repository.
  69
  70 ;;; Code:
  71
  72 (eval-when-compile (require 'cl))
  73 (require 'newcomment)
  74
  75 ;; FIXME: Use `user-error'.
  76 (add-to-list 'debug-ignored-errors "^.* frontend cannot be used twice$")
  77 (add-to-list 'debug-ignored-errors "^Echo area cannot be used twice$")
  78 (add-to-list 'debug-ignored-errors "^No \\(document\\|loc\\)ation available$")
  79 (add-to-list 'debug-ignored-errors "^Company not ")
  80 (add-to-list 'debug-ignored-errors "^No candidate number ")
  81 (add-to-list 'debug-ignored-errors "^Cannot complete at point$")
  82 (add-to-list 'debug-ignored-errors "^No other back-end$")
  83
  84 (defgroup company nil
  85   "Extensible inline text completion mechanism"
  86   :group 'abbrev
  87   :group 'convenience
  88   :group 'matching)
  89
  90 (defface company-tooltip
  91   '((default :foreground "black")
  92     (((class color) (min-colors 88) (background light))
  93      (:background "cornsilk"))
  94     (((class color) (min-colors 88) (background dark))
  95      (:background "yellow")))
  96   "Face used for the tooltip.")
  97
  98 (defface company-tooltip-selection
  99   '((default :inherit company-tooltip)
 100     (((class color) (min-colors 88) (background light))
 101      (:background "light blue"))
 102     (((class color) (min-colors 88) (background dark))
 103      (:background "orange1"))
 104     (t (:background "green")))
 105   "Face used for the selection in the tooltip.")
 106
 107 (defface company-tooltip-mouse
 108   '((default :inherit highlight))
 109   "Face used for the tooltip item under the mouse.")
 110
 111 (defface company-tooltip-common
 112   '((default :inherit company-tooltip)
 113     (((background light))
 114      :foreground "darkred")
 115     (((background dark))
 116      :foreground "red"))
 117   "Face used for the common completion in the tooltip.")
 118
 119 (defface company-tooltip-common-selection
 120   '((default :inherit company-tooltip-selection)
 121     (((background light))
 122      :foreground "darkred")
 123     (((background dark))
 124      :foreground "red"))
 125   "Face used for the selected common completion in the tooltip.")
 126
 127 (defface company-tooltip-annotation
 128   '((default :inherit company-tooltip)
 129     (((background light))
 130      :foreground "firebrick4")
 131     (((background dark))
 132      :foreground "red4"))
 133   "Face used for the annotation in the tooltip.")
 134
 135 (defface company-scrollbar-fg
 136   '((((background light))
 137      :background "darkred")
 138     (((background dark))
 139      :background "red"))
 140   "Face used for the tooltip scrollbar thumb.")
 141
 142 (defface company-scrollbar-bg
 143   '((default :inherit company-tooltip)
 144     (((background light))
 145      :background "wheat")
 146     (((background dark))
 147      :background "gold"))
 148   "Face used for the tooltip scrollbar background.")
 149
 150 (defface company-preview
 151   '((((background light))
 152      :inherit company-tooltip-selection)
 153     (((background dark))
 154      :background "blue4"
 155      :foreground "wheat"))
 156   "Face used for the completion preview.")
 157
 158 (defface company-preview-common
 159   '((((background light))
 160      :inherit company-tooltip-selection)
 161     (((background dark))
 162      :inherit company-preview
 163      :foreground "red"))
 164   "Face used for the common part of the completion preview.")
 165
 166 (defface company-preview-search
 167   '((((background light))
 168      :inherit company-tooltip-common-selection)
 169     (((background dark))
 170      :inherit company-preview
 171      :background "blue1"))
 172   "Face used for the search string in the completion preview.")
 173
 174 (defface company-echo nil
 175   "Face used for completions in the echo area.")
 176
 177 (defface company-echo-common
 178   '((((background dark)) (:foreground "firebrick1"))
 179     (((background light)) (:background "firebrick4")))
 180   "Face used for the common part of completions in the echo area.")
 181
 182 (defun company-frontends-set (variable value)
 183   ;; uniquify
 184   (let ((remainder value))
 185     (setcdr remainder (delq (car remainder) (cdr remainder))))
 186   (and (memq 'company-pseudo-tooltip-unless-just-one-frontend value)
 187        (memq 'company-pseudo-tooltip-frontend value)
 188        (error "Pseudo tooltip frontend cannot be used twice"))
 189   (and (memq 'company-preview-if-just-one-frontend value)
 190        (memq 'company-preview-frontend value)
 191        (error "Preview frontend cannot be used twice"))
 192   (and (memq 'company-echo value)
 193        (memq 'company-echo-metadata-frontend value)
 194        (error "Echo area cannot be used twice"))
 195   ;; preview must come last
 196   (dolist (f '(company-preview-if-just-one-frontend company-preview-frontend))
 197     (when (memq f value)
 198       (setq value (append (delq f value) (list f)))))
 199   (set variable value))
 200
 201 (defcustom company-frontends '(company-pseudo-tooltip-unless-just-one-frontend
 202                                company-preview-if-just-one-frontend
 203                                company-echo-metadata-frontend)
 204   "The list of active front-ends (visualizations).
 205 Each front-end is a function that takes one argument.  It is called with
 206 one of the following arguments:
 207
 208 `show': When the visualization should start.
 209
 210 `hide': When the visualization should end.
 211
 212 `update': When the data has been updated.
 213
 214 `pre-command': Before every command that is executed while the
 215 visualization is active.
 216
 217 `post-command': After every command that is executed while the
 218 visualization is active.
 219
 220 The visualized data is stored in `company-prefix', `company-candidates',
 221 `company-common', `company-selection', `company-point' and
 222 `company-search-string'."
 223   :set 'company-frontends-set
 224   :type '(repeat (choice (const :tag "echo" company-echo-frontend)
 225                          (const :tag "echo, strip common"
 226                                 company-echo-strip-common-frontend)
 227                          (const :tag "show echo meta-data in echo"
 228                                 company-echo-metadata-frontend)
 229                          (const :tag "pseudo tooltip"
 230                                 company-pseudo-tooltip-frontend)
 231                          (const :tag "pseudo tooltip, multiple only"
 232                                 company-pseudo-tooltip-unless-just-one-frontend)
 233                          (const :tag "preview" company-preview-frontend)
 234                          (const :tag "preview, unique only"
 235                                 company-preview-if-just-one-frontend)
 236                          (function :tag "custom function" nil))))
 237
 238 (defcustom company-tooltip-limit 10
 239   "The maximum number of candidates in the tooltip"
 240   :type 'integer)
 241
 242 (defcustom company-tooltip-minimum 6
 243   "The minimum height of the tooltip.
 244 If this many lines are not available, prefer to display the tooltip above."
 245   :type 'integer)
 246
 247 (defcustom company-tooltip-margin 1
 248   "Width of margin columns to show around the toolip."
 249   :type 'integer)
 250
 251 (defcustom company-tooltip-offset-display 'scrollbar
 252   "Method using which the tooltip displays scrolling position.
 253 `scrollbar' means draw a scrollbar to the right of the items.
 254 `lines' means wrap items in lines with \"before\" and \"after\" counters."
 255   :type '(choice (const :tag "Scrollbar" scrollbar)
 256                  (const :tag "Two lines" lines)))
 257
 258 (defcustom company-tooltip-align-annotations nil
 259   "When non-nil, align annotations to the right tooltip border."
 260   :type 'boolean)
 261
 262 (defvar company-safe-backends
 263   '((company-abbrev . "Abbrev")
 264     (company-bbdb . "BBDB")
 265     (company-capf . "completion-at-point-functions")
 266     (company-clang . "Clang")
 267     (company-cmake . "CMake")
 268     (company-css . "CSS")
 269     (company-dabbrev . "dabbrev for plain text")
 270     (company-dabbrev-code . "dabbrev for code")
 271     (company-eclim . "Eclim (an Eclipse interface)")
 272     (company-elisp . "Emacs Lisp")
 273     (company-etags . "etags")
 274     (company-files . "Files")
 275     (company-gtags . "GNU Global")
 276     (company-ispell . "Ispell")
 277     (company-keywords . "Programming language keywords")
 278     (company-nxml . "nxml")
 279     (company-oddmuse . "Oddmuse")
 280     (company-pysmell . "PySmell")
 281     (company-ropemacs . "ropemacs")
 282     (company-semantic . "Semantic")
 283     (company-tempo . "Tempo templates")
 284     (company-xcode . "Xcode")))
 285 (put 'company-safe-backends 'risky-local-variable t)
 286
 287 (defun company-safe-backends-p (backends)
 288   (and (consp backends)
 289        (not (dolist (backend backends)
 290               (unless (if (consp backend)
 291                           (company-safe-backends-p backend)
 292                         (assq backend company-safe-backends))
 293                 (return t))))))
 294
 295 (defvar company--include-capf (version< "24.3.50" emacs-version))
 296
 297 (defcustom company-backends `(,@(unless company--include-capf
 298                                   (list 'company-elisp))
 299                               company-bbdb
 300                               company-nxml company-css
 301                               company-eclim company-semantic company-clang
 302                               company-xcode company-ropemacs company-cmake
 303                               ,@(when company--include-capf
 304                                   (list 'company-capf))
 305                               (company-dabbrev-code company-gtags company-etags
 306                                company-keywords)
 307                               company-oddmuse company-files company-dabbrev)
 308   "The list of active back-ends (completion engines).
 309
 310 `company-begin-backend' can be used to start a specific back-end,
 311 `company-other-backend' will skip to the next matching back-end in the list.
 312
 313 Each back-end is a function that takes a variable number of arguments.
 314 The first argument is the command requested from the back-end.  It is one
 315 of the following:
 316
 317 `prefix': The back-end should return the text to be completed.  It must be
 318 text immediately before point.  Returning nil passes control to the next
 319 back-end.  The function should return `stop' if it should complete but
 320 cannot \(e.g. if it is in the middle of a string\).  Instead of a string,
 321 the back-end may return a cons where car is the prefix and cdr is used in
 322 `company-minimum-prefix-length' test.  It must be either number or t, and
 323 in the latter case the test automatically succeeds.
 324
 325 `candidates': The second argument is the prefix to be completed.  The
 326 return value should be a list of candidates that match the prefix.
 327
 328 Non-prefix matches are also supported (candidates that don't start with the
 329 prefix, but match it in some backend-defined way).  Backends that use this
 330 feature must disable cache (return t to `no-cache') and should also respond
 331 to `match'.
 332
 333 Optional commands:
 334
 335 `sorted': Return t here to indicate that the candidates are sorted and will
 336 not need to be sorted again.
 337
 338 `duplicates': If non-nil, company will take care of removing duplicates
 339 from the list.
 340
 341 `no-cache': Usually company doesn't ask for candidates again as completion
 342 progresses, unless the back-end returns t for this command.  The second
 343 argument is the latest prefix.
 344
 345 `meta': The second argument is a completion candidate.  Return a (short)
 346 documentation string for it.
 347
 348 `doc-buffer': The second argument is a completion candidate.  Return a
 349 buffer with documentation for it.  Preferably use `company-doc-buffer',
 350
 351 `location': The second argument is a completion candidate.  Return the cons
 352 of buffer and buffer location, or of file and line number where the
 353 completion candidate was defined.
 354
 355 `annotation': The second argument is a completion candidate.  Return a
 356 string to be displayed inline with the candidate in the popup.  If
 357 duplicates are removed by company, candidates with equal string values will
 358 be kept if they have different annotations.  For that to work properly,
 359 backends should store the related information on candidates using text
 360 properties.
 361
 362 `match': The second argument is a completion candidate.  Backends that
 363 provide non-prefix completions should return the position of the end of
 364 text in the candidate that matches `prefix'.  It will be used when
 365 rendering the popup.
 366
 367 `require-match': If this returns t, the user is not allowed to enter
 368 anything not offered as a candidate.  Use with care!  The default value nil
 369 gives the user that choice with `company-require-match'.  Return value
 370 `never' overrides that option the other way around.
 371
 372 `init': Called once for each buffer. The back-end can check for external
 373 programs and files and load any required libraries.  Raising an error here
 374 will show up in message log once, and the back-end will not be used for
 375 completion.
 376
 377 `post-completion': Called after a completion candidate has been inserted
 378 into the buffer.  The second argument is the candidate.  Can be used to
 379 modify it, e.g. to expand a snippet.
 380
 381 The back-end should return nil for all commands it does not support or
 382 does not know about.  It should also be callable interactively and use
 383 `company-begin-backend' to start itself in that case.
 384
 385 Grouped back-ends:
 386
 387 An element of `company-backends' can also itself be a list of back-ends,
 388 then it's considered to be a \"grouped\" back-end.
 389
 390 When possible, commands taking a candidate as an argument are dispatched to
 391 the back-end it came from.  In other cases, the first non-nil value among
 392 all the back-ends is returned.
 393
 394 The latter is the case for the `prefix' command.  But if the group contains
 395 the keyword `:with', the back-ends after it are ignored for this command.
 396
 397 The completions from back-ends in a group are merged (but only from those
 398 that return the same `prefix')."
 399   :type `(repeat
 400           (choice
 401            :tag "Back-end"
 402            ,@(mapcar (lambda (b) `(const :tag ,(cdr b) ,(car b)))
 403                      company-safe-backends)
 404            (symbol :tag "User defined")
 405            (repeat :tag "Merged Back-ends"
 406                    (choice :tag "Back-end"
 407                            ,@(mapcar (lambda (b)
 408                                        `(const :tag ,(cdr b) ,(car b)))
 409                                      company-safe-backends)
 410                            (const :tag "With" :with)
 411                            (symbol :tag "User defined"))))))
 412
 413 (put 'company-backends 'safe-local-variable 'company-safe-backends-p)
 414
 415 (defcustom company-transformers nil
 416   "Functions to change the list of candidates received from backends,
 417 after sorting and removal of duplicates (if appropriate).
 418 Each function gets called with the return value of the previous one."
 419   :type '(choice
 420           (const :tag "None" nil)
 421           (const :tag "Sort by occurrence" (company-sort-by-occurrence))
 422           (repeat :tag "User defined" (function))))
 423
 424 (defcustom company-completion-started-hook nil
 425   "Hook run when company starts completing.
 426 The hook is called with one argument that is non-nil if the completion was
 427 started manually."
 428   :type 'hook)
 429
 430 (defcustom company-completion-cancelled-hook nil
 431   "Hook run when company cancels completing.
 432 The hook is called with one argument that is non-nil if the completion was
 433 aborted manually."
 434   :type 'hook)
 435
 436 (defcustom company-completion-finished-hook nil
 437   "Hook run when company successfully completes.
 438 The hook is called with the selected candidate as an argument.
 439
 440 If you indend to use it to post-process candidates from a specific
 441 back-end, consider using the `post-completion' command instead."
 442   :type 'hook)
 443
 444 (defcustom company-minimum-prefix-length 3
 445   "The minimum prefix length for idle completion."
 446   :type '(integer :tag "prefix length"))
 447
 448 (defcustom company-abort-manual-when-too-short nil
 449   "If enabled, cancel a manually started completion when the prefix gets
 450 shorter than both `company-minimum-prefix-length' and the length of the
 451 prefix it was started from."
 452   :type 'boolean)
 453
 454 (defcustom company-require-match 'company-explicit-action-p
 455   "If enabled, disallow non-matching input.
 456 This can be a function do determine if a match is required.
 457
 458 This can be overridden by the back-end, if it returns t or `never' to
 459 `require-match'.  `company-auto-complete' also takes precedence over this."
 460   :type '(choice (const :tag "Off" nil)
 461                  (function :tag "Predicate function")
 462                  (const :tag "On, if user interaction took place"
 463                         'company-explicit-action-p)
 464                  (const :tag "On" t)))
 465
 466 (defcustom company-auto-complete nil
 467   "Determines when to auto-complete.
 468 If this is enabled, all characters from `company-auto-complete-chars'
 469 trigger insertion of the selected completion candidate.
 470 This can also be a function."
 471   :type '(choice (const :tag "Off" nil)
 472                  (function :tag "Predicate function")
 473                  (const :tag "On, if user interaction took place"
 474                         'company-explicit-action-p)
 475                  (const :tag "On" t)))
 476
 477 (defcustom company-auto-complete-chars '(?\  ?\) ?.)
 478   "Determines which characters trigger auto-completion.
 479 See `company-auto-complete'.  If this is a string, each string character
 480 tiggers auto-completion.  If it is a list of syntax description characters (see
 481 `modify-syntax-entry'), all characters with that syntax auto-complete.
 482
 483 This can also be a function, which is called with the new input and should
 484 return non-nil if company should auto-complete.
 485
 486 A character that is part of a valid candidate never triggers auto-completion."
 487   :type '(choice (string :tag "Characters")
 488                  (set :tag "Syntax"
 489                       (const :tag "Whitespace" ?\ )
 490                       (const :tag "Symbol" ?_)
 491                       (const :tag "Opening parentheses" ?\()
 492                       (const :tag "Closing parentheses" ?\))
 493                       (const :tag "Word constituent" ?w)
 494                       (const :tag "Punctuation." ?.)
 495                       (const :tag "String quote." ?\")
 496                       (const :tag "Paired delimiter." ?$)
 497                       (const :tag "Expression quote or prefix operator." ?\')
 498                       (const :tag "Comment starter." ?<)
 499                       (const :tag "Comment ender." ?>)
 500                       (const :tag "Character-quote." ?/)
 501                       (const :tag "Generic string fence." ?|)
 502                       (const :tag "Generic comment fence." ?!))
 503                  (function :tag "Predicate function")))
 504
 505 (defcustom company-idle-delay .7
 506   "The idle delay in seconds until completion starts automatically.
 507 A value of nil means no idle completion, t means show candidates
 508 immediately when a prefix of `company-minimum-prefix-length' is reached."
 509   :type '(choice (const :tag "never (nil)" nil)
 510                  (const :tag "immediate (t)" t)
 511                  (number :tag "seconds")))
 512
 513 (defcustom company-begin-commands '(self-insert-command org-self-insert-command)
 514   "A list of commands after which idle completion is allowed.
 515 If this is t, it can show completions after any command.  See
 516 `company-idle-delay'.
 517
 518 Alternatively, any command with a non-nil `company-begin' property is
 519 treated as if it was on this list."
 520   :type '(choice (const :tag "Any command" t)
 521                  (const :tag "Self insert command" '(self-insert-command))
 522                  (repeat :tag "Commands" function)))
 523
 524 (defcustom company-continue-commands '(not save-buffer save-some-buffers
 525                                            save-buffers-kill-terminal
 526                                            save-buffers-kill-emacs)
 527   "A list of commands that are allowed during completion.
 528 If this is t, or if `company-begin-commands' is t, any command is allowed.
 529 Otherwise, the value must be a list of symbols.  If it starts with `not',
 530 the cdr is the list of commands that abort completion.  Otherwise, all
 531 commands except those in that list, or in `company-begin-commands', or
 532 commands in the `company-' namespace, abort completion."
 533   :type '(choice (const :tag "Any command" t)
 534                  (cons  :tag "Any except"
 535                         (const not)
 536                         (repeat :tag "Commands" function))
 537                  (repeat :tag "Commands" function)))
 538
 539 (defcustom company-show-numbers nil
 540   "If enabled, show quick-access numbers for the first ten candidates."
 541   :type '(choice (const :tag "off" nil)
 542                  (const :tag "on" t)))
 543
 544 (defcustom company-selection-wrap-around nil
 545   "If enabled, selecting item before first or after last wraps around."
 546   :type '(choice (const :tag "off" nil)
 547                  (const :tag "on" t)))
 548
 549 (defvar company-end-of-buffer-workaround t
 550   "Work around a visualization bug when completing at the end of the buffer.
 551 The work-around consists of adding a newline.")
 552
 553 ;;; mode ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 554
 555 (defvar company-mode-map (make-sparse-keymap)
 556   "Keymap used by `company-mode'.")
 557
 558 (defvar company-active-map
 559   (let ((keymap (make-sparse-keymap)))
 560     (define-key keymap "\e\e\e" 'company-abort)
 561     (define-key keymap "\C-g" 'company-abort)
 562     (define-key keymap (kbd "M-n") 'company-select-next)
 563     (define-key keymap (kbd "M-p") 'company-select-previous)
 564     (define-key keymap (kbd "<down>") 'company-select-next-or-abort)
 565     (define-key keymap (kbd "<up>") 'company-select-previous-or-abort)
 566     (define-key keymap [down-mouse-1] 'ignore)
 567     (define-key keymap [down-mouse-3] 'ignore)
 568     (define-key keymap [mouse-1] 'company-complete-mouse)
 569     (define-key keymap [mouse-3] 'company-select-mouse)
 570     (define-key keymap [up-mouse-1] 'ignore)
 571     (define-key keymap [up-mouse-3] 'ignore)
 572     (define-key keymap [return] 'company-complete-selection)
 573     (define-key keymap (kbd "RET") 'company-complete-selection)
 574     (define-key keymap [tab] 'company-complete-common)
 575     (define-key keymap (kbd "TAB") 'company-complete-common)
 576     (define-key keymap (kbd "<f1>") 'company-show-doc-buffer)
 577     (define-key keymap "\C-w" 'company-show-location)
 578     (define-key keymap "\C-s" 'company-search-candidates)
 579     (define-key keymap "\C-\M-s" 'company-filter-candidates)
 580     (dotimes (i 10)
 581       (define-key keymap (vector (+ (aref (kbd "M-0") 0) i))
 582         `(lambda () (interactive) (company-complete-number ,i))))
 583
 584     keymap)
 585   "Keymap that is enabled during an active completion.")
 586
 587 (defvar company--disabled-backends nil)
 588
 589 (defun company-init-backend (backend)
 590   (and (symbolp backend)
 591        (not (fboundp backend))
 592        (ignore-errors (require backend nil t)))
 593   (cond
 594    ((symbolp backend)
 595     (condition-case err
 596         (progn
 597           (funcall backend 'init)
 598           (put backend 'company-init t))
 599       (error
 600        (put backend 'company-init 'failed)
 601        (unless (memq backend company--disabled-backends)
 602          (message "Company back-end '%s' could not be initialized:\n%s"
 603                   backend (error-message-string err)))
 604        (pushnew backend company--disabled-backends)
 605        nil)))
 606    ;; No initialization for lambdas.
 607    ((functionp backend) t)
 608    (t ;; Must be a list.
 609     (dolist (b backend)
 610       (unless (keywordp b)
 611         (company-init-backend b))))))
 612
 613 (defvar company-default-lighter " company")
 614
 615 (defvar company-lighter company-default-lighter)
 616 (make-variable-buffer-local 'company-lighter)
 617
 618 ;;;###autoload
 619 (define-minor-mode company-mode
 620   "\"complete anything\"; is an in-buffer completion framework.
 621 Completion starts automatically, depending on the values
 622 `company-idle-delay' and `company-minimum-prefix-length'.
 623
 624 Completion can be controlled with the commands:
 625 `company-complete-common', `company-complete-selection', `company-complete',
 626 `company-select-next', `company-select-previous'.  If these commands are
 627 called before `company-idle-delay', completion will also start.
 628
 629 Completions can be searched with `company-search-candidates' or
 630 `company-filter-candidates'.  These can be used while completion is
 631 inactive, as well.
 632
 633 The completion data is retrieved using `company-backends' and displayed
 634 using `company-frontends'.  If you want to start a specific back-end, call
 635 it interactively or use `company-begin-backend'.
 636
 637 regular keymap (`company-mode-map'):
 638
 639 \\{company-mode-map}
 640 keymap during active completions (`company-active-map'):
 641
 642 \\{company-active-map}"
 643   nil company-lighter company-mode-map
 644   (if company-mode
 645       (progn
 646         (add-hook 'pre-command-hook 'company-pre-command nil t)
 647         (add-hook 'post-command-hook 'company-post-command nil t)
 648         (mapc 'company-init-backend company-backends))
 649     (remove-hook 'pre-command-hook 'company-pre-command t)
 650     (remove-hook 'post-command-hook 'company-post-command t)
 651     (company-cancel)
 652     (kill-local-variable 'company-point)))
 653
 654 (defcustom company-global-modes t
 655   "Modes for which `company-mode' mode is turned on by `global-company-mode'.
 656 If nil, means no modes.  If t, then all major modes have it turned on.
 657 If a list, it should be a list of `major-mode' symbol names for which
 658 `company-mode' should be automatically turned on.  The sense of the list is
 659 negated if it begins with `not'.  For example:
 660  (c-mode c++-mode)
 661 means that `company-mode' is turned on for buffers in C and C++ modes only.
 662  (not message-mode)
 663 means that `company-mode' is always turned on except in `message-mode' buffers."
 664   :type '(choice (const :tag "none" nil)
 665                  (const :tag "all" t)
 666                  (set :menu-tag "mode specific" :tag "modes"
 667                       :value (not)
 668                       (const :tag "Except" not)
 669                       (repeat :inline t (symbol :tag "mode")))))
 670
 671 ;;;###autoload
 672 (define-globalized-minor-mode global-company-mode company-mode company-mode-on)
 673
 674 (defun company-mode-on ()
 675   (when (and (not (or noninteractive (eq (aref (buffer-name) 0) ?\s)))
 676              (cond ((eq company-global-modes t)
 677                     t)
 678                    ((eq (car-safe company-global-modes) 'not)
 679                     (not (memq major-mode (cdr company-global-modes))))
 680                    (t (memq major-mode company-global-modes))))
 681     (company-mode 1)))
 682
 683 (defsubst company-assert-enabled ()
 684   (unless company-mode
 685     (company-uninstall-map)
 686     (error "Company not enabled")))
 687
 688 ;;; keymaps ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 689
 690 (defvar company-my-keymap nil)
 691 (make-variable-buffer-local 'company-my-keymap)
 692
 693 (defvar company-emulation-alist '((t . nil)))
 694
 695 (defsubst company-enable-overriding-keymap (keymap)
 696   (company-uninstall-map)
 697   (setq company-my-keymap keymap))
 698
 699 (defun company-ensure-emulation-alist ()
 700   (unless (eq 'company-emulation-alist (car emulation-mode-map-alists))
 701     (setq emulation-mode-map-alists
 702           (cons 'company-emulation-alist
 703                 (delq 'company-emulation-alist emulation-mode-map-alists)))))
 704
 705 (defun company-install-map ()
 706   (unless (or (cdar company-emulation-alist)
 707               (null company-my-keymap))
 708     (setf (cdar company-emulation-alist) company-my-keymap)))
 709
 710 (defun company-uninstall-map ()
 711   (setf (cdar company-emulation-alist) nil))
 712
 713 ;; Hack:
 714 ;; Emacs calculates the active keymaps before reading the event.  That means we
 715 ;; cannot change the keymap from a timer.  So we send a bogus command.
 716 ;; XXX: Seems not to be needed anymore in Emacs 24.4
 717 (defun company-ignore ()
 718   (interactive)
 719   (setq this-command last-command))
 720
 721 (global-set-key '[31415926] 'company-ignore)
 722
 723 (defun company-input-noop ()
 724   (push 31415926 unread-command-events))
 725
 726 (defun company--column (&optional pos)
 727   (save-excursion
 728     (when pos (goto-char pos))
 729     (save-restriction
 730       (+ (save-excursion
 731            (vertical-motion 0)
 732            (narrow-to-region (point) (point-max))
 733            (let ((prefix (get-text-property (point) 'line-prefix)))
 734              (if prefix (length prefix) 0)))
 735          (current-column)))))
 736
 737 (defun company--row (&optional pos)
 738   (save-excursion
 739     (when pos (goto-char pos))
 740     (count-screen-lines (window-start)
 741                         (progn (vertical-motion 0) (point)))))
 742
 743 ;;; backends ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 744
 745 (defvar company-backend nil)
 746 (make-variable-buffer-local 'company-backend)
 747
 748 (defun company-grab (regexp &optional expression limit)
 749   (when (looking-back regexp limit)
 750     (or (match-string-no-properties (or expression 0)) "")))
 751
 752 (defun company-grab-line (regexp &optional expression)
 753   (company-grab regexp expression (point-at-bol)))
 754
 755 (defun company-grab-symbol ()
 756   (if (looking-at "\\_>")
 757       (buffer-substring (point) (save-excursion (skip-syntax-backward "w_")
 758                                                 (point)))
 759     (unless (and (char-after) (memq (char-syntax (char-after)) '(?w ?_)))
 760       "")))
 761
 762 (defun company-grab-word ()
 763   (if (looking-at "\\>")
 764       (buffer-substring (point) (save-excursion (skip-syntax-backward "w")
 765                                                 (point)))
 766     (unless (and (char-after) (eq (char-syntax (char-after)) ?w))
 767       "")))
 768
 769 (defun company-in-string-or-comment ()
 770   (let ((ppss (syntax-ppss)))
 771     (or (car (setq ppss (nthcdr 3 ppss)))
 772         (car (setq ppss (cdr ppss)))
 773         (nth 3 ppss))))
 774
 775 (if (fboundp 'locate-dominating-file)
 776     (defalias 'company-locate-dominating-file 'locate-dominating-file)
 777   (defun company-locate-dominating-file (file name)
 778     (catch 'root
 779       (let ((dir (file-name-directory file))
 780             (prev-dir nil))
 781         (while (not (equal dir prev-dir))
 782           (when (file-exists-p (expand-file-name name dir))
 783             (throw 'root dir))
 784           (setq prev-dir dir
 785                 dir (file-name-directory (directory-file-name dir))))))))
 786
 787 (defun company-call-backend (&rest args)
 788   (condition-case err
 789       (if (functionp company-backend)
 790           (apply company-backend args)
 791         (apply 'company--multi-backend-adapter company-backend args))
 792     (error (error "Company: Back-end %s error \"%s\" with args %s"
 793                     company-backend (error-message-string err) args))))
 794
 795 (defun company--multi-backend-adapter (backends command &rest args)
 796   (let ((backends (loop for b in backends
 797                         when (not (and (symbolp b)
 798                                        (eq 'failed (get b 'company-init))))
 799                         collect b)))
 800     (setq backends
 801           (if (eq command 'prefix)
 802               (butlast backends (length (member :with backends)))
 803             (delq :with backends)))
 804     (pcase command
 805       (`candidates
 806        ;; Small perf optimization: don't tag the candidates received
 807        ;; from the first backend in the group.
 808        (append (apply (car backends) 'candidates args)
 809                (loop for backend in (cdr backends)
 810                      when (equal (funcall backend 'prefix)
 811                                  (car args))
 812                      append (mapcar
 813                              (lambda (str)
 814                                (propertize str 'company-backend backend))
 815                              (apply backend 'candidates args)))))
 816       (`sorted nil)
 817       (`duplicates t)
 818       ((or `prefix `ignore-case `no-cache `require-match)
 819        (let (value)
 820          (dolist (backend backends)
 821            (when (setq value (apply backend command args))
 822              (return value)))))
 823       (_
 824        (let ((arg (car args)))
 825          (when (> (length arg) 0)
 826            (let ((backend (or (get-text-property 0 'company-backend arg)
 827                               (car backends))))
 828              (apply backend command args))))))))
 829
 830 ;;; completion mechanism ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 831
 832 (defvar company-prefix nil)
 833 (make-variable-buffer-local 'company-prefix)
 834
 835 (defvar company-candidates nil)
 836 (make-variable-buffer-local 'company-candidates)
 837
 838 (defvar company-candidates-length nil)
 839 (make-variable-buffer-local 'company-candidates-length)
 840
 841 (defvar company-candidates-cache nil)
 842 (make-variable-buffer-local 'company-candidates-cache)
 843
 844 (defvar company-candidates-predicate nil)
 845 (make-variable-buffer-local 'company-candidates-predicate)
 846
 847 (defvar company-common nil)
 848 (make-variable-buffer-local 'company-common)
 849
 850 (defvar company-selection 0)
 851 (make-variable-buffer-local 'company-selection)
 852
 853 (defvar company-selection-changed nil)
 854 (make-variable-buffer-local 'company-selection-changed)
 855
 856 (defvar company--manual-action nil
 857   "Non-nil, if manual completion took place.")
 858 (make-variable-buffer-local 'company--manual-action)
 859
 860 (defvar company--manual-prefix nil)
 861 (make-variable-buffer-local 'company--manual-prefix)
 862
 863 (defvar company--auto-completion nil
 864   "Non-nil when current candidate is being inserted automatically.
 865 Controlled by `company-auto-complete'.")
 866
 867 (defvar company--point-max nil)
 868 (make-variable-buffer-local 'company--point-max)
 869
 870 (defvar company-point nil)
 871 (make-variable-buffer-local 'company-point)
 872
 873 (defvar company-timer nil)
 874
 875 (defvar company-added-newline nil)
 876 (make-variable-buffer-local 'company-added-newline)
 877
 878 (defsubst company-strip-prefix (str)
 879   (substring str (length company-prefix)))
 880
 881 (defun company--insert-candidate (candidate)
 882   (setq candidate (substring-no-properties candidate))
 883   ;; XXX: Return value we check here is subject to change.
 884   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 885       (insert (company-strip-prefix candidate))
 886     (delete-region (- (point) (length company-prefix)) (point))
 887     (insert candidate)))
 888
 889 (defmacro company-with-candidate-inserted (candidate &rest body)
 890   "Evaluate BODY with CANDIDATE temporarily inserted.
 891 This is a tool for back-ends that need candidates inserted before they
 892 can retrieve meta-data for them."
 893   (declare (indent 1))
 894   `(let ((inhibit-modification-hooks t)
 895          (inhibit-point-motion-hooks t)
 896          (modified-p (buffer-modified-p)))
 897      (company--insert-candidate ,candidate)
 898      (unwind-protect
 899          (progn ,@body)
 900        (delete-region company-point (point)))))
 901
 902 (defun company-explicit-action-p ()
 903   "Return whether explicit completion action was taken by the user."
 904   (or company--manual-action
 905       company-selection-changed))
 906
 907 (defun company-reformat (candidate)
 908   ;; company-ispell needs this, because the results are always lower-case
 909   ;; It's mory efficient to fix it only when they are displayed.
 910   ;; FIXME: Adopt the current text's capitalization instead?
 911   (if (eq (company-call-backend 'ignore-case) 'keep-prefix)
 912       (concat company-prefix (substring candidate (length company-prefix)))
 913     candidate))
 914
 915 (defun company--should-complete ()
 916   (and (not (or buffer-read-only overriding-terminal-local-map
 917                 overriding-local-map))
 918        ;; Check if in the middle of entering a key combination.
 919        (or (equal (this-command-keys-vector) [])
 920            (not (keymapp (key-binding (this-command-keys-vector)))))
 921        (eq company-idle-delay t)
 922        (or (eq t company-begin-commands)
 923            (memq this-command company-begin-commands)
 924            (and (symbolp this-command) (get this-command 'company-begin)))
 925        (not (and transient-mark-mode mark-active))))
 926
 927 (defun company--should-continue ()
 928   (or (eq t company-begin-commands)
 929       (eq t company-continue-commands)
 930       (if (eq 'not (car company-continue-commands))
 931           (not (memq this-command (cdr company-continue-commands)))
 932         (or (memq this-command company-begin-commands)
 933             (memq this-command company-continue-commands)
 934             (string-match-p "\\`company-" (symbol-name this-command))))))
 935
 936 (defun company-call-frontends (command)
 937   (dolist (frontend company-frontends)
 938     (condition-case err
 939         (funcall frontend command)
 940       (error (error "Company: Front-end %s error \"%s\" on command %s"
 941                     frontend (error-message-string err) command)))))
 942
 943 (defun company-set-selection (selection &optional force-update)
 944   (setq selection
 945         (if company-selection-wrap-around
 946             (mod selection company-candidates-length)
 947           (max 0 (min (1- company-candidates-length) selection))))
 948   (when (or force-update (not (equal selection company-selection)))
 949     (setq company-selection selection
 950           company-selection-changed t)
 951     (company-call-frontends 'update)))
 952
 953 (defun company-apply-predicate (candidates predicate)
 954   (let (new)
 955     (dolist (c candidates)
 956       (when (funcall predicate c)
 957         (push c new)))
 958     (nreverse new)))
 959
 960 (defun company-update-candidates (candidates)
 961   (setq company-candidates-length (length candidates))
 962   (if (> company-selection 0)
 963       ;; Try to restore the selection
 964       (let ((selected (nth company-selection company-candidates)))
 965         (setq company-selection 0
 966               company-candidates candidates)
 967         (when selected
 968           (while (and candidates (string< (pop candidates) selected))
 969             (incf company-selection))
 970           (unless candidates
 971             ;; Make sure selection isn't out of bounds.
 972             (setq company-selection (min (1- company-candidates-length)
 973                                          company-selection)))))
 974     (setq company-selection 0
 975           company-candidates candidates))
 976   ;; Save in cache:
 977   (push (cons company-prefix company-candidates) company-candidates-cache)
 978   ;; Calculate common.
 979   (let ((completion-ignore-case (company-call-backend 'ignore-case)))
 980     ;; We want to support non-prefix completion, so filtering is the
 981     ;; responsibility of each respective backend, not ours.
 982     ;; On the other hand, we don't want to replace non-prefix input in
 983     ;; `company-complete-common'.
 984     (setq company-common
 985           (if (cdr company-candidates)
 986               (let ((common (try-completion company-prefix company-candidates)))
 987                 (if (eq common t)
 988                     ;; Mulple equal strings, probably with different
 989                     ;; annotations.
 990                     company-prefix
 991                   common))
 992             (car company-candidates)))))
 993
 994 (defun company-calculate-candidates (prefix)
 995   (let ((candidates (cdr (assoc prefix company-candidates-cache)))
 996         (ignore-case (company-call-backend 'ignore-case)))
 997     (or candidates
 998         (when company-candidates-cache
 999           (let ((len (length prefix))
1000                 (completion-ignore-case ignore-case)
1001                 prev)
1002             (dotimes (i (1+ len))
1003               (when (setq prev (cdr (assoc (substring prefix 0 (- len i))
1004                                            company-candidates-cache)))
1005                 (setq candidates (all-completions prefix prev))
1006                 (return t)))))
1007         ;; no cache match, call back-end
1008         (progn
1009           (setq candidates (company-call-backend 'candidates prefix))
1010           (when company-candidates-predicate
1011             (setq candidates
1012                   (company-apply-predicate candidates
1013                                            company-candidates-predicate)))
1014           (unless (company-call-backend 'sorted)
1015             (setq candidates (sort candidates 'string<)))
1016           (when (company-call-backend 'duplicates)
1017             (company--strip-duplicates candidates))))
1018     (setq candidates (company--transform-candidates candidates))
1019     (when candidates
1020       (if (or (cdr candidates)
1021               (not (eq t (compare-strings (car candidates) nil nil
1022                                           prefix nil nil ignore-case))))
1023           candidates
1024         ;; Already completed and unique; don't start.
1025         t))))
1026
1027 (defun company--strip-duplicates (candidates)
1028   (let ((c2 candidates))
1029     (while c2
1030       (setcdr c2
1031               (let ((str (car c2))
1032                     (anno 'unk))
1033                 (pop c2)
1034                 (while (let ((str2 (car c2)))
1035                          (if (not (equal str str2))
1036                              nil
1037                            (when (eq anno 'unk)
1038                              (setq anno (company-call-backend
1039                                          'annotation str)))
1040                            (equal anno
1041                                   (company-call-backend
1042                                    'annotation str2))))
1043                   (pop c2))
1044                 c2)))))
1045
1046 (defun company--transform-candidates (candidates)
1047   (let ((c candidates))
1048     (dolist (tr company-transformers)
1049       (setq c (funcall tr c)))
1050     c))
1051
1052 (defun company-sort-by-occurrence (candidates)
1053   "Sort CANDIDATES according to their occurrences.
1054 Searches for each in the currently visible part of the current buffer and
1055 gives priority to the closest ones above point, then closest ones below
1056 point. The rest of the list is appended unchanged.
1057 Keywords and function definition names are ignored."
1058   (let* (occurs
1059          (noccurs
1060           (delete-if
1061            (lambda (candidate)
1062              (when (or
1063                     (save-excursion
1064                       (progn (forward-line 0)
1065                              (search-backward candidate (window-start) t)))
1066                     (save-excursion
1067                       (search-forward candidate (window-end) t)))
1068                (let ((beg (match-beginning 0))
1069                      (end (match-end 0)))
1070                  (when (save-excursion
1071                          (goto-char end)
1072                          (and (not (memq (get-text-property (point) 'face)
1073                                          '(font-lock-function-name-face
1074                                            font-lock-keyword-face)))
1075                               (let* ((prefix (company-call-backend 'prefix))
1076                                      (prefix (or (car-safe prefix) prefix)))
1077                                 (and (stringp prefix)
1078                                      (= (length prefix) (- end beg))))))
1079                    (push (cons candidate (if (< beg (point))
1080                                              (- (point) end)
1081                                            (- beg (window-start))))
1082                          occurs)
1083                    t))))
1084            candidates)))
1085     (nconc
1086      (mapcar #'car (sort occurs (lambda (e1 e2) (<= (cdr e1) (cdr e2)))))
1087      noccurs)))
1088
1089 (defun company-idle-begin (buf win tick pos)
1090   (and (eq buf (current-buffer))
1091        (eq win (selected-window))
1092        (eq tick (buffer-chars-modified-tick))
1093        (eq pos (point))
1094        (not (equal (point) company-point))
1095        (when (company-auto-begin)
1096          (when (version< emacs-version "24.3.50")
1097            (company-input-noop))
1098          (company-post-command))))
1099
1100 (defun company-auto-begin ()
1101   (and company-mode
1102        (not company-candidates)
1103        (let ((company-idle-delay t)
1104              (company-begin-commands t))
1105          (condition-case-no-debug err
1106              (company-begin)
1107            (error (message "Company: An error occurred in auto-begin")
1108                   (message "%s" (error-message-string err))
1109                   (company-cancel))
1110            (quit (company-cancel)))))
1111   (unless company-candidates
1112     (setq company-backend nil))
1113   ;; Return non-nil if active.
1114   company-candidates)
1115
1116 (defun company-manual-begin ()
1117   (interactive)
1118   (company-assert-enabled)
1119   (setq company--manual-action t)
1120   (unwind-protect
1121       (let ((company-minimum-prefix-length 0))
1122         (company-auto-begin))
1123     (unless company-candidates
1124       (setq company--manual-action nil))))
1125
1126 (defun company-other-backend (&optional backward)
1127   (interactive (list current-prefix-arg))
1128   (company-assert-enabled)
1129   (if company-backend
1130       (let* ((after (cdr (member company-backend company-backends)))
1131              (before (cdr (member company-backend (reverse company-backends))))
1132              (next (if backward
1133                        (append before (reverse after))
1134                      (append after (reverse before)))))
1135         (company-cancel)
1136         (dolist (backend next)
1137           (when (ignore-errors (company-begin-backend backend))
1138             (return t))))
1139     (company-manual-begin))
1140   (unless company-candidates
1141     (error "No other back-end")))
1142
1143 (defun company-require-match-p ()
1144   (let ((backend-value (company-call-backend 'require-match)))
1145     (or (eq backend-value t)
1146         (and (not (eq backend-value 'never))
1147              (if (functionp company-require-match)
1148                  (funcall company-require-match)
1149                (eq company-require-match t))))))
1150
1151 (defun company-auto-complete-p (input)
1152   "Return non-nil, if input starts with punctuation or parentheses."
1153   (and (if (functionp company-auto-complete)
1154            (funcall company-auto-complete)
1155          company-auto-complete)
1156        (if (functionp company-auto-complete-chars)
1157            (funcall company-auto-complete-chars input)
1158          (if (consp company-auto-complete-chars)
1159              (memq (char-syntax (string-to-char input))
1160                    company-auto-complete-chars)
1161            (string-match (substring input 0 1) company-auto-complete-chars)))))
1162
1163 (defun company--incremental-p ()
1164   (and (> (point) company-point)
1165        (> (point-max) company--point-max)
1166        (not (eq this-command 'backward-delete-char-untabify))
1167        (equal (buffer-substring (- company-point (length company-prefix))
1168                                 company-point)
1169               company-prefix)))
1170
1171 (defun company--continue-failed ()
1172   (let ((input (buffer-substring-no-properties (point) company-point)))
1173     (cond
1174      ((company-auto-complete-p input)
1175       ;; auto-complete
1176       (save-excursion
1177         (goto-char company-point)
1178         (let ((company--auto-completion t))
1179           (company-complete-selection))
1180         nil))
1181      ((company-require-match-p)
1182       ;; wrong incremental input, but required match
1183       (delete-char (- (length input)))
1184       (ding)
1185       (message "Matching input is required")
1186       company-candidates)
1187      ((equal company-prefix (car company-candidates))
1188       ;; last input was actually success
1189       (company-cancel company-prefix))
1190      (t (company-cancel)))))
1191
1192 (defun company--good-prefix-p (prefix)
1193   (and (stringp (or (car-safe prefix) prefix)) ;excludes 'stop
1194        (or (eq (cdr-safe prefix) t)
1195            (let ((len (or (cdr-safe prefix) (length prefix))))
1196              (if company--manual-prefix
1197                  (or (not company-abort-manual-when-too-short)
1198                      ;; Must not be less than minimum or initial length.
1199                      (>= len (min company-minimum-prefix-length
1200                                   (length company--manual-prefix))))
1201                (>= len company-minimum-prefix-length))))))
1202
1203 (defun company--continue ()
1204   (when (company-call-backend 'no-cache company-prefix)
1205     ;; Don't complete existing candidates, fetch new ones.
1206     (setq company-candidates-cache nil))
1207   (let* ((new-prefix (company-call-backend 'prefix))
1208          (c (when (and (company--good-prefix-p new-prefix)
1209                        (setq new-prefix (or (car-safe new-prefix) new-prefix))
1210                        (= (- (point) (length new-prefix))
1211                           (- company-point (length company-prefix))))
1212               (company-calculate-candidates new-prefix))))
1213     (cond
1214      ((eq c t)
1215       ;; t means complete/unique.
1216       (company-cancel new-prefix))
1217      ((consp c)
1218       ;; incremental match
1219       (setq company-prefix new-prefix)
1220       (company-update-candidates c)
1221       c)
1222      ((not (company--incremental-p))
1223       (company-cancel))
1224      (t (company--continue-failed)))))
1225
1226 (defun company--begin-new ()
1227   (let (prefix c)
1228     (dolist (backend (if company-backend
1229                          ;; prefer manual override
1230                          (list company-backend)
1231                        company-backends))
1232       (setq prefix
1233             (if (or (symbolp backend)
1234                     (functionp backend))
1235                 (when (or (not (symbolp backend))
1236                           (eq t (get backend 'company-init))
1237                           (unless (get backend 'company-init)
1238                             (company-init-backend backend)))
1239                   (funcall backend 'prefix))
1240               (company--multi-backend-adapter backend 'prefix)))
1241       (when prefix
1242         (when (company--good-prefix-p prefix)
1243           (setq prefix (or (car-safe prefix) prefix)
1244                 company-backend backend
1245                 c (company-calculate-candidates prefix))
1246           ;; t means complete/unique.  We don't start, so no hooks.
1247           (if (not (consp c))
1248               (when company--manual-action
1249                 (message "No completion found"))
1250             (setq company-prefix prefix)
1251             (when company--manual-action
1252               (setq company--manual-prefix prefix))
1253             (when (symbolp backend)
1254               (setq company-lighter (concat " " (symbol-name backend))))
1255             (company-update-candidates c)
1256             (run-hook-with-args 'company-completion-started-hook
1257                                 (company-explicit-action-p))
1258             (company-call-frontends 'show)))
1259         (return c)))))
1260
1261 (defun company-begin ()
1262   (or (and company-candidates (company--continue))
1263       (and (company--should-complete) (company--begin-new)))
1264   (when company-candidates
1265     (let ((modified (buffer-modified-p)))
1266       (when (and company-end-of-buffer-workaround (eobp))
1267         (save-excursion (insert "\n"))
1268         (setq company-added-newline
1269               (or modified (buffer-chars-modified-tick)))))
1270     (setq company-point (point)
1271           company--point-max (point-max))
1272     (company-ensure-emulation-alist)
1273     (company-enable-overriding-keymap company-active-map)
1274     (company-call-frontends 'update)))
1275
1276 (defun company-cancel (&optional result)
1277   (and company-added-newline
1278        (> (point-max) (point-min))
1279        (let ((tick (buffer-chars-modified-tick)))
1280          (delete-region (1- (point-max)) (point-max))
1281          (equal tick company-added-newline))
1282        ;; Only set unmodified when tick remained the same since insert,
1283        ;; and the buffer wasn't modified before.
1284        (set-buffer-modified-p nil))
1285   (when company-prefix
1286     (if (stringp result)
1287         (progn
1288           (company-call-backend 'pre-completion result)
1289           (run-hook-with-args 'company-completion-finished-hook result)
1290           (company-call-backend 'post-completion result))
1291       (run-hook-with-args 'company-completion-cancelled-hook result)))
1292   (setq company-added-newline nil
1293         company-backend nil
1294         company-prefix nil
1295         company-candidates nil
1296         company-candidates-length nil
1297         company-candidates-cache nil
1298         company-candidates-predicate nil
1299         company-common nil
1300         company-selection 0
1301         company-selection-changed nil
1302         company--manual-action nil
1303         company--manual-prefix nil
1304         company-lighter company-default-lighter
1305         company--point-max nil
1306         company-point nil)
1307   (when company-timer
1308     (cancel-timer company-timer))
1309   (company-search-mode 0)
1310   (company-call-frontends 'hide)
1311   (company-enable-overriding-keymap nil)
1312   ;; Make return value explicit.
1313   nil)
1314
1315 (defun company-abort ()
1316   (interactive)
1317   (company-cancel t)
1318   ;; Don't start again, unless started manually.
1319   (setq company-point (point)))
1320
1321 (defun company-finish (result)
1322   (company--insert-candidate result)
1323   (company-cancel result)
1324   ;; Don't start again, unless started manually.
1325   (setq company-point (point)))
1326
1327 (defsubst company-keep (command)
1328   (and (symbolp command) (get command 'company-keep)))
1329
1330 (defun company-pre-command ()
1331   (unless (company-keep this-command)
1332     (condition-case err
1333         (when company-candidates
1334           (company-call-frontends 'pre-command)
1335           (unless (company--should-continue)
1336             (company-abort)))
1337       (error (message "Company: An error occurred in pre-command")
1338              (message "%s" (error-message-string err))
1339              (company-cancel))))
1340   (when company-timer
1341     (cancel-timer company-timer)
1342     (setq company-timer nil))
1343   (company-uninstall-map))
1344
1345 (defun company-post-command ()
1346   (unless (company-keep this-command)
1347     (condition-case err
1348         (progn
1349           (unless (equal (point) company-point)
1350             (company-begin))
1351           (if company-candidates
1352               (company-call-frontends 'post-command)
1353             (and (numberp company-idle-delay)
1354                  (or (eq t company-begin-commands)
1355                      (memq this-command company-begin-commands))
1356                  (setq company-timer
1357                        (run-with-timer company-idle-delay nil
1358                                        'company-idle-begin
1359                                        (current-buffer) (selected-window)
1360                                        (buffer-chars-modified-tick) (point))))))
1361       (error (message "Company: An error occurred in post-command")
1362              (message "%s" (error-message-string err))
1363              (company-cancel))))
1364   (company-install-map))
1365
1366 ;;; search ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1367
1368 (defvar company-search-string nil)
1369 (make-variable-buffer-local 'company-search-string)
1370
1371 (defvar company-search-lighter " Search: \"\"")
1372 (make-variable-buffer-local 'company-search-lighter)
1373
1374 (defvar company-search-old-map nil)
1375 (make-variable-buffer-local 'company-search-old-map)
1376
1377 (defvar company-search-old-selection 0)
1378 (make-variable-buffer-local 'company-search-old-selection)
1379
1380 (defun company-search (text lines)
1381   (let ((quoted (regexp-quote text))
1382         (i 0))
1383     (dolist (line lines)
1384       (when (string-match quoted line (length company-prefix))
1385         (return i))
1386       (incf i))))
1387
1388 (defun company-search-printing-char ()
1389   (interactive)
1390   (company-search-assert-enabled)
1391   (setq company-search-string
1392         (concat (or company-search-string "") (string last-command-event))
1393         company-search-lighter (concat " Search: \"" company-search-string
1394                                         "\""))
1395   (let ((pos (company-search company-search-string
1396                               (nthcdr company-selection company-candidates))))
1397     (if (null pos)
1398         (ding)
1399       (company-set-selection (+ company-selection pos) t))))
1400
1401 (defun company-search-repeat-forward ()
1402   "Repeat the incremental search in completion candidates forward."
1403   (interactive)
1404   (company-search-assert-enabled)
1405   (let ((pos (company-search company-search-string
1406                               (cdr (nthcdr company-selection
1407                                            company-candidates)))))
1408     (if (null pos)
1409         (ding)
1410       (company-set-selection (+ company-selection pos 1) t))))
1411
1412 (defun company-search-repeat-backward ()
1413   "Repeat the incremental search in completion candidates backwards."
1414   (interactive)
1415   (company-search-assert-enabled)
1416   (let ((pos (company-search company-search-string
1417                               (nthcdr (- company-candidates-length
1418                                          company-selection)
1419                                       (reverse company-candidates)))))
1420     (if (null pos)
1421         (ding)
1422       (company-set-selection (- company-selection pos 1) t))))
1423
1424 (defun company-create-match-predicate ()
1425   (setq company-candidates-predicate
1426         `(lambda (candidate)
1427            ,(if company-candidates-predicate
1428                 `(and (string-match ,company-search-string candidate)
1429                       (funcall ,company-candidates-predicate
1430                                candidate))
1431               `(string-match ,company-search-string candidate))))
1432   (company-update-candidates
1433    (company-apply-predicate company-candidates company-candidates-predicate))
1434   ;; Invalidate cache.
1435   (setq company-candidates-cache (cons company-prefix company-candidates)))
1436
1437 (defun company-filter-printing-char ()
1438   (interactive)
1439   (company-search-assert-enabled)
1440   (company-search-printing-char)
1441   (company-create-match-predicate)
1442   (company-call-frontends 'update))
1443
1444 (defun company-search-kill-others ()
1445   "Limit the completion candidates to the ones matching the search string."
1446   (interactive)
1447   (company-search-assert-enabled)
1448   (company-create-match-predicate)
1449   (company-search-mode 0)
1450   (company-call-frontends 'update))
1451
1452 (defun company-search-abort ()
1453   "Abort searching the completion candidates."
1454   (interactive)
1455   (company-search-assert-enabled)
1456   (company-set-selection company-search-old-selection t)
1457   (company-search-mode 0))
1458
1459 (defun company-search-other-char ()
1460   (interactive)
1461   (company-search-assert-enabled)
1462   (company-search-mode 0)
1463   (company--unread-last-input))
1464
1465 (defvar company-search-map
1466   (let ((i 0)
1467         (keymap (make-keymap)))
1468     (if (fboundp 'max-char)
1469         (set-char-table-range (nth 1 keymap) (cons #x100 (max-char))
1470                               'company-search-printing-char)
1471       (with-no-warnings
1472         ;; obsolete in Emacs 23
1473         (let ((l (generic-character-list))
1474               (table (nth 1 keymap)))
1475           (while l
1476             (set-char-table-default table (car l) 'company-search-printing-char)
1477             (setq l (cdr l))))))
1478     (define-key keymap [t] 'company-search-other-char)
1479     (while (< i ?\s)
1480       (define-key keymap (make-string 1 i) 'company-search-other-char)
1481       (incf i))
1482     (while (< i 256)
1483       (define-key keymap (vector i) 'company-search-printing-char)
1484       (incf i))
1485     (let ((meta-map (make-sparse-keymap)))
1486       (define-key keymap (char-to-string meta-prefix-char) meta-map)
1487       (define-key keymap [escape] meta-map))
1488     (define-key keymap (vector meta-prefix-char t) 'company-search-other-char)
1489     (define-key keymap "\e\e\e" 'company-search-other-char)
1490     (define-key keymap  [escape escape escape] 'company-search-other-char)
1491
1492     (define-key keymap "\C-g" 'company-search-abort)
1493     (define-key keymap "\C-s" 'company-search-repeat-forward)
1494     (define-key keymap "\C-r" 'company-search-repeat-backward)
1495     (define-key keymap "\C-o" 'company-search-kill-others)
1496     keymap)
1497   "Keymap used for incrementally searching the completion candidates.")
1498
1499 (define-minor-mode company-search-mode
1500   "Search mode for completion candidates.
1501 Don't start this directly, use `company-search-candidates' or
1502 `company-filter-candidates'."
1503   nil company-search-lighter nil
1504   (if company-search-mode
1505       (if (company-manual-begin)
1506           (progn
1507             (setq company-search-old-selection company-selection)
1508             (company-call-frontends 'update))
1509         (setq company-search-mode nil))
1510     (kill-local-variable 'company-search-string)
1511     (kill-local-variable 'company-search-lighter)
1512     (kill-local-variable 'company-search-old-selection)
1513     (company-enable-overriding-keymap company-active-map)))
1514
1515 (defun company-search-assert-enabled ()
1516   (company-assert-enabled)
1517   (unless company-search-mode
1518     (company-uninstall-map)
1519     (error "Company not in search mode")))
1520
1521 (defun company-search-candidates ()
1522   "Start searching the completion candidates incrementally.
1523
1524 \\<company-search-map>Search can be controlled with the commands:
1525 - `company-search-repeat-forward' (\\[company-search-repeat-forward])
1526 - `company-search-repeat-backward' (\\[company-search-repeat-backward])
1527 - `company-search-abort' (\\[company-search-abort])
1528
1529 Regular characters are appended to the search string.
1530
1531 The command `company-search-kill-others' (\\[company-search-kill-others])
1532 uses the search string to limit the completion candidates."
1533   (interactive)
1534   (company-search-mode 1)
1535   (company-enable-overriding-keymap company-search-map))
1536
1537 (defvar company-filter-map
1538   (let ((keymap (make-keymap)))
1539     (define-key keymap [remap company-search-printing-char]
1540       'company-filter-printing-char)
1541     (set-keymap-parent keymap company-search-map)
1542     keymap)
1543   "Keymap used for incrementally searching the completion candidates.")
1544
1545 (defun company-filter-candidates ()
1546   "Start filtering the completion candidates incrementally.
1547 This works the same way as `company-search-candidates' immediately
1548 followed by `company-search-kill-others' after each input."
1549   (interactive)
1550   (company-search-mode 1)
1551   (company-enable-overriding-keymap company-filter-map))
1552
1553 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1554
1555 (defun company-select-next ()
1556   "Select the next candidate in the list."
1557   (interactive)
1558   (when (company-manual-begin)
1559     (company-set-selection (1+ company-selection))))
1560
1561 (defun company-select-previous ()
1562   "Select the previous candidate in the list."
1563   (interactive)
1564   (when (company-manual-begin)
1565     (company-set-selection (1- company-selection))))
1566
1567 (defun company-select-next-or-abort ()
1568   "Select the next candidate if more than one, else abort
1569 and invoke the normal binding."
1570   (interactive)
1571   (if (> company-candidates-length 1)
1572       (company-select-next)
1573     (company-abort)
1574     (company--unread-last-input)))
1575
1576 (defun company-select-previous-or-abort ()
1577   "Select the previous candidate if more than one, else abort
1578 and invoke the normal binding."
1579   (interactive)
1580   (if (> company-candidates-length 1)
1581       (company-select-previous)
1582     (company-abort)
1583     (company--unread-last-input)))
1584
1585 (defvar company-pseudo-tooltip-overlay)
1586
1587 (defvar company-tooltip-offset)
1588
1589 (defun company--inside-tooltip-p (event-col-row row height)
1590   (let* ((ovl company-pseudo-tooltip-overlay)
1591          (column (overlay-get ovl 'company-column))
1592          (width (overlay-get ovl 'company-width))
1593          (evt-col (car event-col-row))
1594          (evt-row (cdr event-col-row)))
1595     (and (>= evt-col column)
1596          (< evt-col (+ column width))
1597          (if (> height 0)
1598              (and (> evt-row row)
1599                   (<= evt-row (+ row height) ))
1600            (and (< evt-row row)
1601                 (>= evt-row (+ row height)))))))
1602
1603 (defun company--event-col-row (event)
1604   (let* ((col-row (posn-actual-col-row (event-start event)))
1605          (col (car col-row))
1606          (row (cdr col-row)))
1607     (incf col (window-hscroll))
1608     (and header-line-format
1609          (version< "24" emacs-version)
1610          (decf row))
1611     (cons col row)))
1612
1613 (defun company-select-mouse (event)
1614   "Select the candidate picked by the mouse."
1615   (interactive "e")
1616   (let ((event-col-row (company--event-col-row event))
1617         (ovl-row (company--row))
1618         (ovl-height (and company-pseudo-tooltip-overlay
1619                          (min (overlay-get company-pseudo-tooltip-overlay
1620                                            'company-height)
1621                               company-candidates-length))))
1622     (if (and ovl-height
1623              (company--inside-tooltip-p event-col-row ovl-row ovl-height))
1624         (progn
1625           (company-set-selection (+ (cdr event-col-row)
1626                                     (1- company-tooltip-offset)
1627                                     (if (and (eq company-tooltip-offset-display 'lines)
1628                                              (not (zerop company-tooltip-offset)))
1629                                         -1 0)
1630                                     (- ovl-row)
1631                                     (if (< ovl-height 0)
1632                                         (- 1 ovl-height)
1633                                       0)))
1634           t)
1635       (company-abort)
1636       (company--unread-last-input)
1637       nil)))
1638
1639 (defun company-complete-mouse (event)
1640   "Insert the candidate picked by the mouse."
1641   (interactive "e")
1642   (when (company-select-mouse event)
1643     (company-complete-selection)))
1644
1645 (defun company-complete-selection ()
1646   "Insert the selected candidate."
1647   (interactive)
1648   (when (company-manual-begin)
1649     (let ((result (nth company-selection company-candidates)))
1650       (company-finish result))))
1651
1652 (defun company-complete-common ()
1653   "Insert the common part of all candidates."
1654   (interactive)
1655   (when (company-manual-begin)
1656     (if (and (not (cdr company-candidates))
1657              (equal company-common (car company-candidates)))
1658         (company-complete-selection)
1659       (when company-common
1660         (company--insert-candidate company-common)))))
1661
1662 (defun company-complete ()
1663   "Insert the common part of all candidates or the current selection.
1664 The first time this is called, the common part is inserted, the second
1665 time, or when the selection has been changed, the selected candidate is
1666 inserted."
1667   (interactive)
1668   (when (company-manual-begin)
1669     (if (or company-selection-changed
1670             (eq last-command 'company-complete-common))
1671         (call-interactively 'company-complete-selection)
1672       (call-interactively 'company-complete-common)
1673       (setq this-command 'company-complete-common))))
1674
1675 (defun company-complete-number (n)
1676   "Insert the Nth candidate.
1677 To show the number next to the candidates in some back-ends, enable
1678 `company-show-numbers'."
1679   (when (company-manual-begin)
1680     (and (< n 1) (> n company-candidates-length)
1681          (error "No candidate number %d" n))
1682     (decf n)
1683     (company-finish (nth n company-candidates))))
1684
1685 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1686
1687 (defconst company-space-strings-limit 100)
1688
1689 (defconst company-space-strings
1690   (let (lst)
1691     (dotimes (i company-space-strings-limit)
1692       (push (make-string (- company-space-strings-limit 1 i) ?\  ) lst))
1693     (apply 'vector lst)))
1694
1695 (defun company-space-string (len)
1696   (if (< len company-space-strings-limit)
1697       (aref company-space-strings len)
1698     (make-string len ?\ )))
1699
1700 (defun company-safe-substring (str from &optional to)
1701   (if (> from (string-width str))
1702       ""
1703     (with-temp-buffer
1704       (insert str)
1705       (move-to-column from)
1706       (let ((beg (point)))
1707         (if to
1708             (progn
1709               (move-to-column to)
1710               (concat (buffer-substring beg (point))
1711                       (let ((padding (- to (current-column))))
1712                         (when (> padding 0)
1713                           (company-space-string padding)))))
1714           (buffer-substring beg (point-max)))))))
1715
1716 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1717
1718 (defvar company-last-metadata nil)
1719 (make-variable-buffer-local 'company-last-metadata)
1720
1721 (defun company-fetch-metadata ()
1722   (let ((selected (nth company-selection company-candidates)))
1723     (unless (eq selected (car company-last-metadata))
1724       (setq company-last-metadata
1725             (cons selected (company-call-backend 'meta selected))))
1726     (cdr company-last-metadata)))
1727
1728 (defun company-doc-buffer (&optional string)
1729   (with-current-buffer (get-buffer-create "*company-documentation*")
1730     (erase-buffer)
1731     (when string
1732       (save-excursion
1733         (insert string)))
1734     (current-buffer)))
1735
1736 (defvar company--electric-commands
1737   '(scroll-other-window scroll-other-window-down)
1738   "List of Commands that won't break out of electric commands.")
1739
1740 (defmacro company--electric-do (&rest body)
1741   (declare (indent 0) (debug t))
1742   `(when (company-manual-begin)
1743      (save-window-excursion
1744        (let ((height (window-height))
1745              (row (company--row))
1746              cmd)
1747          ,@body
1748          (and (< (window-height) height)
1749               (< (- (window-height) row 2) company-tooltip-limit)
1750               (recenter (- (window-height) row 2)))
1751          (while (memq (setq cmd (key-binding (vector (list (read-event)))))
1752                       company--electric-commands)
1753            (call-interactively cmd))
1754          (company--unread-last-input)))))
1755
1756 (defun company--unread-last-input ()
1757   (when last-input-event
1758     (clear-this-command-keys t)
1759     (setq unread-command-events (list last-input-event))))
1760
1761 (defun company-show-doc-buffer ()
1762   "Temporarily show the documentation buffer for the selection."
1763   (interactive)
1764   (company--electric-do
1765     (let* ((selected (nth company-selection company-candidates))
1766            (doc-buffer (or (company-call-backend 'doc-buffer selected)
1767                            (error "No documentation available"))))
1768       (with-current-buffer doc-buffer
1769         (goto-char (point-min)))
1770       (display-buffer doc-buffer t))))
1771 (put 'company-show-doc-buffer 'company-keep t)
1772
1773 (defun company-show-location ()
1774   "Temporarily display a buffer showing the selected candidate in context."
1775   (interactive)
1776   (company--electric-do
1777     (let* ((selected (nth company-selection company-candidates))
1778            (location (company-call-backend 'location selected))
1779            (pos (or (cdr location) (error "No location available")))
1780            (buffer (or (and (bufferp (car location)) (car location))
1781                        (find-file-noselect (car location) t))))
1782       (with-selected-window (display-buffer buffer t)
1783         (save-restriction
1784           (widen)
1785           (if (bufferp (car location))
1786               (goto-char pos)
1787             (goto-char (point-min))
1788             (forward-line (1- pos))))
1789         (set-window-start nil (point))))))
1790 (put 'company-show-location 'company-keep t)
1791
1792 ;;; package functions ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1793
1794 (defvar company-callback nil)
1795 (make-variable-buffer-local 'company-callback)
1796
1797 (defun company-remove-callback (&optional ignored)
1798   (remove-hook 'company-completion-finished-hook company-callback t)
1799   (remove-hook 'company-completion-cancelled-hook 'company-remove-callback t)
1800   (remove-hook 'company-completion-finished-hook 'company-remove-callback t))
1801
1802 (defun company-begin-backend (backend &optional callback)
1803   "Start a completion at point using BACKEND."
1804   (interactive (let ((val (completing-read "Company back-end: "
1805                                            obarray
1806                                            'functionp nil "company-")))
1807                  (when val
1808                    (list (intern val)))))
1809   (when (setq company-callback callback)
1810     (add-hook 'company-completion-finished-hook company-callback nil t))
1811   (add-hook 'company-completion-cancelled-hook 'company-remove-callback nil t)
1812   (add-hook 'company-completion-finished-hook 'company-remove-callback nil t)
1813   (setq company-backend backend)
1814   ;; Return non-nil if active.
1815   (or (company-manual-begin)
1816       (error "Cannot complete at point")))
1817
1818 (defun company-begin-with (candidates
1819                            &optional prefix-length require-match callback)
1820   "Start a completion at point.
1821 CANDIDATES is the list of candidates to use and PREFIX-LENGTH is the length
1822 of the prefix that already is in the buffer before point.
1823 It defaults to 0.
1824
1825 CALLBACK is a function called with the selected result if the user
1826 successfully completes the input.
1827
1828 Example: \(company-begin-with '\(\"foo\" \"foobar\" \"foobarbaz\"\)\)"
1829   (let ((begin-marker (copy-marker (point) t)))
1830     (company-begin-backend
1831      (lambda (command &optional arg &rest ignored)
1832        (pcase command
1833         (`prefix
1834          (when (equal (point) (marker-position begin-marker))
1835            (buffer-substring (- (point) (or prefix-length 0)) (point))))
1836         (`candidates
1837          (all-completions arg candidates))
1838         (`require-match
1839          require-match)))
1840      callback)))
1841
1842 (defun company-version (&optional show-version)
1843   "Get the Company version as string.
1844
1845 If SHOW-VERSION is non-nil, show the version in the echo area."
1846   (interactive (list t))
1847   (with-temp-buffer
1848     (insert-file-contents (find-library-name "company"))
1849     (require 'lisp-mnt)
1850     (if show-version
1851         (message "Company version: %s" (lm-version))
1852       (lm-version))))
1853
1854 ;;; pseudo-tooltip ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1855
1856 (defvar company-pseudo-tooltip-overlay nil)
1857 (make-variable-buffer-local 'company-pseudo-tooltip-overlay)
1858
1859 (defvar company-tooltip-offset 0)
1860 (make-variable-buffer-local 'company-tooltip-offset)
1861
1862 (defun company-tooltip--lines-update-offset (selection num-lines limit)
1863   (decf limit 2)
1864   (setq company-tooltip-offset
1865         (max (min selection company-tooltip-offset)
1866              (- selection -1 limit)))
1867
1868   (when (<= company-tooltip-offset 1)
1869     (incf limit)
1870     (setq company-tooltip-offset 0))
1871
1872   (when (>= company-tooltip-offset (- num-lines limit 1))
1873     (incf limit)
1874     (when (= selection (1- num-lines))
1875       (decf company-tooltip-offset)
1876       (when (<= company-tooltip-offset 1)
1877         (setq company-tooltip-offset 0)
1878         (incf limit))))
1879
1880   limit)
1881
1882 (defun company-tooltip--simple-update-offset (selection num-lines limit)
1883   (setq company-tooltip-offset
1884         (if (< selection company-tooltip-offset)
1885             selection
1886           (max company-tooltip-offset
1887                (- selection limit -1)))))
1888
1889 ;;; propertize
1890
1891 (defsubst company-round-tab (arg)
1892   (* (/ (+ arg tab-width) tab-width) tab-width))
1893
1894 (defun company-plainify (str)
1895   (let ((prefix (get-text-property 0 'line-prefix str)))
1896     (when prefix ; Keep the original value unmodified, for no special reason.
1897       (setq str (concat prefix str))
1898       (remove-text-properties 0 (length str) '(line-prefix) str)))
1899   (let* ((pieces (split-string str "\t"))
1900          (copy pieces))
1901     (while (cdr copy)
1902       (setcar copy (company-safe-substring
1903                     (car copy) 0 (company-round-tab (string-width (car copy)))))
1904       (pop copy))
1905     (apply 'concat pieces)))
1906
1907 (defun company-fill-propertize (value annotation width selected left right)
1908   (let* ((margin (length left))
1909          (common (+ (or (company-call-backend 'match value)
1910                         (length company-common)) margin))
1911          (ann-ralign company-tooltip-align-annotations)
1912          (ann-truncate (< width
1913                           (+ (length value) (length annotation)
1914                              (if ann-ralign 1 0))))
1915          (ann-start (+ margin
1916                        (if ann-ralign
1917                            (if ann-truncate
1918                                (1+ (length value))
1919                              (- width (length annotation)))
1920                          (length value))))
1921          (ann-end (min (+ ann-start (length annotation)) (+ margin width)))
1922          (line (concat left
1923                        (if (or ann-truncate (not ann-ralign))
1924                            (company-safe-substring
1925                             (concat value
1926                                     (when (and annotation ann-ralign) " ")
1927                                     annotation)
1928                             0 width)
1929                          (concat
1930                           (company-safe-substring value 0
1931                                                   (- width (length annotation)))
1932                           annotation))
1933                        right)))
1934     (setq width (+ width margin (length right)))
1935
1936     (add-text-properties 0 width '(face company-tooltip
1937                                    mouse-face company-tooltip-mouse)
1938                          line)
1939     (add-text-properties margin common
1940                          '(face company-tooltip-common
1941                            mouse-face company-tooltip-mouse)
1942                          line)
1943     (when (< ann-start ann-end)
1944       (add-text-properties ann-start ann-end
1945                            '(face company-tooltip-annotation
1946                              mouse-face company-tooltip-mouse)
1947                            line))
1948     (when selected
1949       (if (and company-search-string
1950                (string-match (regexp-quote company-search-string) value
1951                              (length company-prefix)))
1952           (let ((beg (+ margin (match-beginning 0)))
1953                 (end (+ margin (match-end 0))))
1954             (add-text-properties beg end '(face company-tooltip-selection)
1955                                  line)
1956             (when (< beg common)
1957               (add-text-properties beg common
1958                                    '(face company-tooltip-common-selection)
1959                                    line)))
1960         (add-text-properties 0 width '(face company-tooltip-selection
1961                                        mouse-face company-tooltip-selection)
1962                              line)
1963         (add-text-properties margin common
1964                              '(face company-tooltip-common-selection
1965                                mouse-face company-tooltip-selection)
1966                              line)))
1967     line))
1968
1969 ;;; replace
1970
1971 (defun company-buffer-lines (beg end)
1972   (goto-char beg)
1973   (let (lines)
1974     (while (and (= 1 (vertical-motion 1))
1975                 (<= (point) end))
1976       (let ((bound (min end (1- (point)))))
1977         ;; A visual line can contain several physical lines (e.g. with outline's
1978         ;; folding overlay).  Take only the first one.
1979         (push (buffer-substring beg
1980                                 (save-excursion
1981                                   (goto-char beg)
1982                                   (re-search-forward "$" bound 'move)
1983                                   (point)))
1984               lines))
1985       (setq beg (point)))
1986     (unless (eq beg end)
1987       (push (buffer-substring beg end) lines))
1988     (nreverse lines)))
1989
1990 (defun company-modify-line (old new offset)
1991   (concat (company-safe-substring old 0 offset)
1992           new
1993           (company-safe-substring old (+ offset (length new)))))
1994
1995 (defsubst company--length-limit (lst limit)
1996   (if (nthcdr limit lst)
1997       limit
1998     (length lst)))
1999
2000 (defun company--replacement-string (lines old column nl &optional align-top)
2001   (decf column company-tooltip-margin)
2002
2003   (let ((width (length (car lines)))
2004         (remaining-cols (- (+ (company--window-width) (window-hscroll))
2005                            column)))
2006     (when (> width remaining-cols)
2007       (decf column (- width remaining-cols))))
2008
2009   (let ((offset (and (< column 0) (- column)))
2010         new)
2011     (when offset
2012       (setq column 0))
2013     (when align-top
2014       ;; untouched lines first
2015       (dotimes (_ (- (length old) (length lines)))
2016         (push (pop old) new)))
2017     ;; length into old lines.
2018     (while old
2019       (push (company-modify-line (pop old)
2020                                  (company--offset-line (pop lines) offset)
2021                                  column) new))
2022     ;; Append whole new lines.
2023     (while lines
2024       (push (concat (company-space-string column)
2025                     (company--offset-line (pop lines) offset))
2026             new))
2027
2028     (let ((str (concat (when nl "\n")
2029                        (mapconcat 'identity (nreverse new) "\n")
2030                        "\n")))
2031       (font-lock-append-text-property 0 (length str) 'face 'default str)
2032       str)))
2033
2034 (defun company--offset-line (line offset)
2035   (if (and offset line)
2036       (substring line offset)
2037     line))
2038
2039 (defun company--create-lines (selection limit)
2040   (let ((len company-candidates-length)
2041         (numbered 99999)
2042         (window-width (company--window-width))
2043         lines
2044         width
2045         lines-copy
2046         items
2047         previous
2048         remainder
2049         scrollbar-bounds)
2050
2051     ;; Maybe clear old offset.
2052     (when (< len (+ company-tooltip-offset limit))
2053       (setq company-tooltip-offset 0))
2054
2055     ;; Scroll to offset.
2056     (if (eq company-tooltip-offset-display 'lines)
2057         (setq limit (company-tooltip--lines-update-offset selection len limit))
2058       (company-tooltip--simple-update-offset selection len limit))
2059
2060     (cond
2061      ((eq company-tooltip-offset-display 'scrollbar)
2062       (setq scrollbar-bounds (company--scrollbar-bounds company-tooltip-offset
2063                                                         limit len)))
2064      ((eq company-tooltip-offset-display 'lines)
2065       (when (> company-tooltip-offset 0)
2066         (setq previous (format "...(%d)" company-tooltip-offset)))
2067       (setq remainder (- len limit company-tooltip-offset)
2068             remainder (when (> remainder 0)
2069                         (setq remainder (format "...(%d)" remainder))))))
2070
2071     (decf selection company-tooltip-offset)
2072     (setq width (max (length previous) (length remainder))
2073           lines (nthcdr company-tooltip-offset company-candidates)
2074           len (min limit len)
2075           lines-copy lines)
2076
2077     (decf window-width (* 2 company-tooltip-margin))
2078     (when scrollbar-bounds (decf window-width))
2079
2080     (dotimes (_ len)
2081       (let* ((value (pop lines-copy))
2082              (annotation (company-call-backend 'annotation value)))
2083         (when (and annotation company-tooltip-align-annotations)
2084           ;; `lisp-completion-at-point' adds a space.
2085           (setq annotation (comment-string-strip annotation t nil)))
2086         (push (cons value annotation) items)
2087         (setq width (max (+ (length value)
2088                             (if (and annotation company-tooltip-align-annotations)
2089                                 (1+ (length annotation))
2090                               (length annotation)))
2091                          width))))
2092
2093     (setq width (min window-width
2094                      (if (and company-show-numbers
2095                               (< company-tooltip-offset 10))
2096                          (+ 2 width)
2097                        width)))
2098
2099     ;; number can make tooltip too long
2100     (when company-show-numbers
2101       (setq numbered company-tooltip-offset))
2102
2103     (let ((items (nreverse items)) new)
2104       (when previous
2105         (push (company--scrollpos-line previous width) new))
2106
2107       (dotimes (i len)
2108         (let* ((item (pop items))
2109                (str (company-reformat (car item)))
2110                (annotation (cdr item))
2111                (right (company-space-string company-tooltip-margin))
2112                (width width))
2113           (when (< numbered 10)
2114             (decf width 2)
2115             (incf numbered)
2116             (setq right (concat (format " %d" (mod numbered 10)) right)))
2117           (push (concat
2118                  (company-fill-propertize str annotation
2119                                           width (equal i selection)
2120                                           (company-space-string
2121                                            company-tooltip-margin)
2122                                           right)
2123                  (when scrollbar-bounds
2124                    (company--scrollbar i scrollbar-bounds)))
2125                 new)))
2126
2127       (when remainder
2128         (push (company--scrollpos-line remainder width) new))
2129
2130       (nreverse new))))
2131
2132 (defun company--scrollbar-bounds (offset limit length)
2133   (when (> length limit)
2134     (let* ((size (ceiling (* limit (float limit)) length))
2135            (lower (floor (* limit (float offset)) length))
2136            (upper (+ lower size -1)))
2137       (cons lower upper))))
2138
2139 (defun company--scrollbar (i bounds)
2140   (propertize " " 'face
2141               (if (and (>= i (car bounds)) (<= i (cdr bounds)))
2142                   'company-scrollbar-fg
2143                 'company-scrollbar-bg)))
2144
2145 (defun company--scrollpos-line (text width)
2146   (propertize (concat (company-space-string company-tooltip-margin)
2147                       (company-safe-substring text 0 width)
2148                       (company-space-string company-tooltip-margin))
2149    'face 'company-tooltip))
2150
2151 ;; show
2152
2153 (defsubst company--window-inner-height ()
2154   (let ((edges (window-inside-edges)))
2155     (- (nth 3 edges) (nth 1 edges))))
2156
2157 (defsubst company--window-width ()
2158   (- (window-width)
2159      (cond
2160       ((display-graphic-p) 0)
2161       ;; Account for the line continuation column.
2162       ((version< "24.3.1" emacs-version) 1)
2163       ;; Emacs 24.3 and earlier included margins
2164       ;; in window-width when in TTY.
2165       (t (1+ (let ((margins (window-margins)))
2166                (+ (or (car margins) 0)
2167                   (or (cdr margins) 0))))))))
2168
2169 (defun company--pseudo-tooltip-height ()
2170   "Calculate the appropriate tooltip height.
2171 Returns a negative number if the tooltip should be displayed above point."
2172   (let* ((lines (company--row))
2173          (below (- (company--window-inner-height) 1 lines)))
2174     (if (and (< below (min company-tooltip-minimum company-candidates-length))
2175              (> lines below))
2176         (- (max 3 (min company-tooltip-limit lines)))
2177       (max 3 (min company-tooltip-limit below)))))
2178
2179 (defun company-pseudo-tooltip-show (row column selection)
2180   (company-pseudo-tooltip-hide)
2181   (save-excursion
2182
2183     (let* ((height (company--pseudo-tooltip-height))
2184            above)
2185
2186       (when (< height 0)
2187         (setq row (+ row height -1)
2188               above t))
2189
2190       (let* ((nl (< (move-to-window-line row) row))
2191              (beg (point))
2192              (end (save-excursion
2193                     (move-to-window-line (+ row (abs height)))
2194                     (point)))
2195              (ov (make-overlay beg end))
2196              (args (list (mapcar 'company-plainify
2197                                  (company-buffer-lines beg end))
2198                          column nl above)))
2199
2200         (setq company-pseudo-tooltip-overlay ov)
2201         (overlay-put ov 'company-replacement-args args)
2202
2203         (let ((lines (company--create-lines selection (abs height))))
2204           (overlay-put ov 'company-after
2205                        (apply 'company--replacement-string lines args))
2206           (overlay-put ov 'company-width (string-width (car lines))))
2207
2208         (overlay-put ov 'company-column column)
2209         (overlay-put ov 'company-height height)))))
2210
2211 (defun company-pseudo-tooltip-show-at-point (pos)
2212   (let ((row (company--row pos))
2213         (col (company--column pos)))
2214     (company-pseudo-tooltip-show (1+ row) col company-selection)))
2215
2216 (defun company-pseudo-tooltip-edit (selection)
2217   (let ((height (overlay-get company-pseudo-tooltip-overlay 'company-height)))
2218     (overlay-put company-pseudo-tooltip-overlay 'company-after
2219                  (apply 'company--replacement-string
2220                         (company--create-lines selection (abs height))
2221                         (overlay-get company-pseudo-tooltip-overlay
2222                                      'company-replacement-args)))))
2223
2224 (defun company-pseudo-tooltip-hide ()
2225   (when company-pseudo-tooltip-overlay
2226     (delete-overlay company-pseudo-tooltip-overlay)
2227     (setq company-pseudo-tooltip-overlay nil)))
2228
2229 (defun company-pseudo-tooltip-hide-temporarily ()
2230   (when (overlayp company-pseudo-tooltip-overlay)
2231     (overlay-put company-pseudo-tooltip-overlay 'invisible nil)
2232     (overlay-put company-pseudo-tooltip-overlay 'line-prefix nil)
2233     (overlay-put company-pseudo-tooltip-overlay 'after-string nil)))
2234
2235 (defun company-pseudo-tooltip-unhide ()
2236   (when company-pseudo-tooltip-overlay
2237     (overlay-put company-pseudo-tooltip-overlay 'invisible t)
2238     ;; Beat outline's folding overlays, at least.
2239     (overlay-put company-pseudo-tooltip-overlay 'priority 1)
2240     ;; No (extra) prefix for the first line.
2241     (overlay-put company-pseudo-tooltip-overlay 'line-prefix "")
2242     (overlay-put company-pseudo-tooltip-overlay 'after-string
2243                  (overlay-get company-pseudo-tooltip-overlay 'company-after))
2244     (overlay-put company-pseudo-tooltip-overlay 'window (selected-window))))
2245
2246 (defun company-pseudo-tooltip-guard ()
2247   (buffer-substring-no-properties
2248    (point) (overlay-start company-pseudo-tooltip-overlay)))
2249
2250 (defun company-pseudo-tooltip-frontend (command)
2251   "`company-mode' front-end similar to a tooltip but based on overlays."
2252   (case command
2253     (pre-command (company-pseudo-tooltip-hide-temporarily))
2254     (post-command
2255      (let ((old-height (if (overlayp company-pseudo-tooltip-overlay)
2256                            (overlay-get company-pseudo-tooltip-overlay
2257                                         'company-height)
2258                          0))
2259            (new-height (company--pseudo-tooltip-height)))
2260        (unless (and (>= (* old-height new-height) 0)
2261                     (>= (abs old-height) (abs new-height))
2262                     (equal (company-pseudo-tooltip-guard)
2263                            (overlay-get company-pseudo-tooltip-overlay
2264                                         'company-guard)))
2265          ;; Redraw needed.
2266          (company-pseudo-tooltip-show-at-point (- (point)
2267                                                   (length company-prefix)))
2268          (overlay-put company-pseudo-tooltip-overlay
2269                       'company-guard (company-pseudo-tooltip-guard))))
2270      (company-pseudo-tooltip-unhide))
2271     (hide (company-pseudo-tooltip-hide)
2272           (setq company-tooltip-offset 0))
2273     (update (when (overlayp company-pseudo-tooltip-overlay)
2274               (company-pseudo-tooltip-edit company-selection)))))
2275
2276 (defun company-pseudo-tooltip-unless-just-one-frontend (command)
2277   "`company-pseudo-tooltip-frontend', but not shown for single candidates."
2278   (unless (and (eq command 'post-command)
2279                (company--show-inline-p))
2280     (company-pseudo-tooltip-frontend command)))
2281
2282 ;;; overlay ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2283
2284 (defvar company-preview-overlay nil)
2285 (make-variable-buffer-local 'company-preview-overlay)
2286
2287 (defun company-preview-show-at-point (pos)
2288   (company-preview-hide)
2289
2290   (setq company-preview-overlay (make-overlay pos (1+ pos)))
2291
2292   (let ((completion (nth company-selection company-candidates)))
2293     (setq completion (propertize completion 'face 'company-preview))
2294     (add-text-properties 0 (length company-common)
2295                          '(face company-preview-common) completion)
2296
2297     ;; Add search string
2298     (and company-search-string
2299          (string-match (regexp-quote company-search-string) completion)
2300          (add-text-properties (match-beginning 0)
2301                               (match-end 0)
2302                               '(face company-preview-search)
2303                               completion))
2304
2305     (setq completion (company-strip-prefix completion))
2306
2307     (and (equal pos (point))
2308          (not (equal completion ""))
2309          (add-text-properties 0 1 '(cursor t) completion))
2310
2311     (overlay-put company-preview-overlay 'display
2312                  (concat completion (unless (eq pos (point-max))
2313                                       (buffer-substring pos (1+ pos)))))
2314     (overlay-put company-preview-overlay 'window (selected-window))))
2315
2316 (defun company-preview-hide ()
2317   (when company-preview-overlay
2318     (delete-overlay company-preview-overlay)
2319     (setq company-preview-overlay nil)))
2320
2321 (defun company-preview-frontend (command)
2322   "`company-mode' front-end showing the selection as if it had been inserted."
2323   (pcase command
2324     (`pre-command (company-preview-hide))
2325     (`post-command (company-preview-show-at-point (point)))
2326     (`hide (company-preview-hide))))
2327
2328 (defun company-preview-if-just-one-frontend (command)
2329   "`company-preview-frontend', but only shown for single candidates."
2330   (when (or (not (eq command 'post-command))
2331             (company--show-inline-p))
2332     (company-preview-frontend command)))
2333
2334 (defun company--show-inline-p ()
2335   (and (not (cdr company-candidates))
2336        company-common
2337        (string-prefix-p company-prefix company-common
2338                         (company-call-backend 'ignore-case))))
2339
2340 ;;; echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2341
2342 (defvar company-echo-last-msg nil)
2343 (make-variable-buffer-local 'company-echo-last-msg)
2344
2345 (defvar company-echo-timer nil)
2346
2347 (defvar company-echo-delay .01)
2348
2349 (defun company-echo-show (&optional getter)
2350   (when getter
2351     (setq company-echo-last-msg (funcall getter)))
2352   (let ((message-log-max nil))
2353     (if company-echo-last-msg
2354         (message "%s" company-echo-last-msg)
2355       (message ""))))
2356
2357 (defun company-echo-show-soon (&optional getter)
2358   (when company-echo-timer
2359     (cancel-timer company-echo-timer))
2360   (setq company-echo-timer (run-with-timer 0 nil 'company-echo-show getter)))
2361
2362 (defsubst company-echo-show-when-idle (&optional getter)
2363   (when (sit-for company-echo-delay)
2364     (company-echo-show getter)))
2365
2366 (defun company-echo-format ()
2367
2368   (let ((limit (window-width (minibuffer-window)))
2369         (len -1)
2370         ;; Roll to selection.
2371         (candidates (nthcdr company-selection company-candidates))
2372         (i (if company-show-numbers company-selection 99999))
2373         comp msg)
2374
2375     (while candidates
2376       (setq comp (company-reformat (pop candidates))
2377             len (+ len 1 (length comp)))
2378       (if (< i 10)
2379           ;; Add number.
2380           (progn
2381             (setq comp (propertize (format "%d: %s" i comp)
2382                                    'face 'company-echo))
2383             (incf len 3)
2384             (incf i)
2385             (add-text-properties 3 (+ 3 (length company-common))
2386                                  '(face company-echo-common) comp))
2387         (setq comp (propertize comp 'face 'company-echo))
2388         (add-text-properties 0 (length company-common)
2389                              '(face company-echo-common) comp))
2390       (if (>= len limit)
2391           (setq candidates nil)
2392         (push comp msg)))
2393
2394     (mapconcat 'identity (nreverse msg) " ")))
2395
2396 (defun company-echo-strip-common-format ()
2397
2398   (let ((limit (window-width (minibuffer-window)))
2399         (len (+ (length company-prefix) 2))
2400         ;; Roll to selection.
2401         (candidates (nthcdr company-selection company-candidates))
2402         (i (if company-show-numbers company-selection 99999))
2403         msg comp)
2404
2405     (while candidates
2406       (setq comp (company-strip-prefix (pop candidates))
2407             len (+ len 2 (length comp)))
2408       (when (< i 10)
2409         ;; Add number.
2410         (setq comp (format "%s (%d)" comp i))
2411         (incf len 4)
2412         (incf i))
2413       (if (>= len limit)
2414           (setq candidates nil)
2415         (push (propertize comp 'face 'company-echo) msg)))
2416
2417     (concat (propertize company-prefix 'face 'company-echo-common) "{"
2418             (mapconcat 'identity (nreverse msg) ", ")
2419             "}")))
2420
2421 (defun company-echo-hide ()
2422   (unless (equal company-echo-last-msg "")
2423     (setq company-echo-last-msg "")
2424     (company-echo-show)))
2425
2426 (defun company-echo-frontend (command)
2427   "`company-mode' front-end showing the candidates in the echo area."
2428   (pcase command
2429     (`post-command (company-echo-show-soon 'company-echo-format))
2430     (`hide (company-echo-hide))))
2431
2432 (defun company-echo-strip-common-frontend (command)
2433   "`company-mode' front-end showing the candidates in the echo area."
2434   (pcase command
2435     (`post-command (company-echo-show-soon 'company-echo-strip-common-format))
2436     (`hide (company-echo-hide))))
2437
2438 (defun company-echo-metadata-frontend (command)
2439   "`company-mode' front-end showing the documentation in the echo area."
2440   (pcase command
2441     (`post-command (company-echo-show-when-idle 'company-fetch-metadata))
2442     (`hide (company-echo-hide))))
2443
2444 (provide 'company)
2445 ;;; company.el ends here