company-dabbrev-code.el

   1 ;;; company-dabbrev-code.el --- a dabbrev-like company-mode back-end for code
   2 ;;
   3 ;; Copyright (C) 2009 Nikolaj Schumacher
   4 ;;
   5 ;; This file is part of company 0.3.1.
   6 ;;
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License
   9 ;; as published by the Free Software Foundation; either version 2
  10 ;; of the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (require 'company)
  21 (eval-when-compile (require 'cl))
  22
  23 (defcustom company-dabbrev-code-modes
  24   '(asm-mode batch-file-mode c++-mode c-mode cperl-mode csharp-mode css-mode
  25     emacs-lisp-mode erlang-mode espresso-mode f90-mode fortran-mode
  26     haskell-mode java-mode javascript-mode jde-mode js2-mode lisp-mode
  27     lua-mode objc-mode perl-mode php-mode python-mode ruby-mode scheme-mode
  28     shell-script-mode)
  29   "*Modes that use `company-dabbrev-code'.
  30 In all these modes `company-dabbrev-code' will complete only symbols, not text
  31 in comments or strings.  In other modes `company-dabbrev-code' will pass control
  32 to other back-ends \(e.g. `company-dabbrev'\).
  33 Value t means complete in all modes."
  34   :group 'company
  35   :type '(choice (repeat (symbol :tag "Major mode"))
  36                  (const tag "All modes" t)))
  37
  38 (defcustom company-dabbrev-code-other-buffers .5
  39   "*Determines whether `company-dabbrev-code' should search other buffers.
  40 If t, search all buffers with the same major-mode.  A numeric value means
  41 search other buffers for that many seconds and then return."
  42   :group 'company
  43   :type '(choice (const :tag "Off" nil)
  44                  (const :tag "Same major mode" t)
  45                  (number :tag "Seconds")))
  46
  47 (defun company-dabbrev-code--buffer-symbols (prefix &optional symbols
  48                                             start limit)
  49   (save-excursion
  50     (goto-char (point-min))
  51     (let ((regexp (concat "\\_<" (if (equal prefix "")
  52                                      "\\([a-zA-Z]\\|\\s_\\)"
  53                                    (regexp-quote prefix))
  54                           "\\(\\sw\\|\\s_\\)*\\_>"))
  55           (i 0)
  56           match)
  57       (while (re-search-forward regexp nil t)
  58         (setq match (match-string-no-properties 0))
  59         (unless (company-in-string-or-comment)
  60           (push match symbols))
  61         (and limit
  62              (eq (incf i) 25)
  63              (setq i 0)
  64              (> (float-time (time-since start)) limit)
  65              (return symbols)))
  66       symbols)))
  67
  68 (defun company-dabbrev-code--symbols (prefix &optional limit)
  69   (let ((start (current-time))
  70         (symbols (company-dabbrev-code--buffer-symbols prefix)))
  71     (dolist (buffer (delq (current-buffer) (buffer-list)))
  72       (and (eq (buffer-local-value 'major-mode buffer) major-mode)
  73            (with-current-buffer buffer
  74              (setq symbols
  75                    (company-dabbrev-code--buffer-symbols prefix symbols
  76                                                         start limit))))
  77       (and limit
  78            (> (float-time (time-since start)) limit)
  79            (return)))
  80     symbols))
  81
  82 ;;;###autoload
  83 (defun company-dabbrev-code (command &optional arg &rest ignored)
  84   "A dabbrev-like `company-mode' back-end for code.
  85 The back-end looks for all symbols in the current buffer that aren't in
  86 comments or strings."
  87   (interactive (list 'interactive))
  88   (case command
  89     ('interactive (company-begin-backend 'company-dabbrev-code))
  90     ('prefix (and (or (eq t company-dabbrev-code-modes)
  91                       (apply 'derived-mode-p company-dabbrev-code-modes))
  92                   (not (company-in-string-or-comment))
  93                   (or (company-grab-symbol) 'stop)))
  94     ('candidates (let ((case-fold-search nil))
  95                    (if company-dabbrev-code-other-buffers
  96                        (company-dabbrev-code--symbols
  97                         arg
  98                         (when (numberp company-dabbrev-code-other-buffers)
  99                           company-dabbrev-code-other-buffers))
 100                      (company-dabbrev-code--buffer-symbols arg))))
 101     ('duplicates t)))
 102
 103 (provide 'company-dabbrev-code)
 104 ;;; company-dabbrev-code.el ends here