opencv/CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # it _must_ go before PROJECT(OpenCV) in order to work
  15 if (NOT CMAKE_INSTALL_PREFIX)
  16     if (WIN32)
  17         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR} CACHE INTERNAL "" FORCE)
  18     elseif()
  19         set(CMAKE_INSTALL_PREFIX "/usr" CACHE INTERNAL "" FORCE)
  20     endif()
  21 endif()
  22
  23 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  24 set(CMAKE_C_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  25 set(CMAKE_C_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  26 set(CMAKE_CXX_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  27 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  28 set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  29 set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  30 set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  31 set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  32 set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  33 set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  34
  35 project(OpenCV)
  36
  37 cmake_minimum_required(VERSION 2.4)
  38
  39 if(MSVC)
  40     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  41 endif()
  42
  43 # --------------------------------------------------------------
  44 # Indicate CMake 2.7 and above that we don't want to mix relative
  45 #  and absolute paths in linker lib lists.
  46 # Run "cmake --help-policy CMP0003" for more information.
  47 # --------------------------------------------------------------
  48 if(COMMAND cmake_policy)
  49     cmake_policy(SET CMP0003 NEW)
  50 endif()
  51
  52 # ----------------------------------------------------------------------------
  53 #  Current version number:
  54 # ----------------------------------------------------------------------------
  55 set(OPENCV_VERSION "1.1.0")
  56
  57 string(REGEX MATCHALL "[0-9]" OPENCV_VERSION_PARTS "${OPENCV_VERSION}")
  58
  59 list(GET OPENCV_VERSION_PARTS 0 OPENCV_VERSION_MAJOR)
  60 list(GET OPENCV_VERSION_PARTS 1 OPENCV_VERSION_MINOR)
  61 list(GET OPENCV_VERSION_PARTS 2 OPENCV_VERSION_PATCH)
  62
  63 set(OPENCV_SOVERSION "${OPENCV_VERSION_MAJOR}.${OPENCV_VERSION_MINOR}")
  64
  65 if(WIN32)
  66         # Postfix of DLLs:
  67         set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
  68         set(OPENCV_DEBUG_POSTFIX d)
  69 else()
  70         # Postfix of so's:
  71         #set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
  72         set(OPENCV_DLLVERSION "")
  73         set(OPENCV_DEBUG_POSTFIX)
  74 endif()
  75
  76
  77 # ----------------------------------------------------------------------------
  78 #  Variables for cvconfig.h.cmake
  79 # ----------------------------------------------------------------------------
  80 set(PACKAGE "opencv")
  81 set(PACKAGE_BUGREPORT "opencvlibrary-devel@lists.sourceforge.net")
  82 set(PACKAGE_NAME "opencv")
  83 set(PACKAGE_STRING "${PACKAGE} ${OPENCV_VERSION}")
  84 set(PACKAGE_TARNAME "${PACKAGE}")
  85 set(PACKAGE_VERSION "${OPENCV_VERSION}")
  86
  87 # ----------------------------------------------------------------------------
  88 #  Autodetect if we are in a SVN repository
  89 # ----------------------------------------------------------------------------
  90 find_program(SVNVERSION_PATH svnversion)
  91 mark_as_advanced(force SVNVERSION_PATH)
  92 if(SVNVERSION_PATH)
  93     message(STATUS "Extracting svn version, please wait...")
  94     execute_process(COMMAND ${SVNVERSION_PATH} -n ${CMAKE_SOURCE_DIR} OUTPUT_VARIABLE SVNVERSION_RESULT)
  95
  96     if(SVNVERSION_RESULT MATCHES "exported")
  97        # This is NOT a svn repository:
  98        set(OPENCV_SVNVERSION "")
  99     else()
 100         set(OPENCV_SVNVERSION " svn:${SVNVERSION_RESULT}")
 101     endif()
 102
 103     message(STATUS "SVNVERSION: ${OPENCV_SVNVERSION}")
 104 else()
 105     # We don't have svnversion:
 106     set(OPENCV_SVNVERSION "")
 107 endif()
 108
 109 # ----------------------------------------------------------------------------
 110 # Detect GNU version:
 111 # ----------------------------------------------------------------------------
 112 if(CMAKE_COMPILER_IS_GNUCXX)
 113     execute_process(COMMAND ${CMAKE_CXX_COMPILER} --version
 114                   OUTPUT_VARIABLE CMAKE_OPENCV_GCC_VERSION_FULL
 115                   OUTPUT_STRIP_TRAILING_WHITESPACE)
 116
 117     # Typical output in CMAKE_OPENCV_GCC_VERSION_FULL: "c+//0 (whatever) 4.2.3 (...)"
 118     #  Look for the version number
 119     string(REGEX MATCH "[0-9].[0-9].[0-9]" CMAKE_GCC_REGEX_VERSION "${CMAKE_OPENCV_GCC_VERSION_FULL}")
 120
 121     # Split the three parts:
 122     string(REGEX MATCHALL "[0-9]" CMAKE_OPENCV_GCC_VERSIONS "${CMAKE_GCC_REGEX_VERSION}")
 123
 124     list(GET CMAKE_OPENCV_GCC_VERSIONS 0 CMAKE_OPENCV_GCC_VERSION_MAJOR)
 125     list(GET CMAKE_OPENCV_GCC_VERSIONS 1 CMAKE_OPENCV_GCC_VERSION_MINOR)
 126
 127     set(CMAKE_OPENCV_GCC_VERSION ${CMAKE_OPENCV_GCC_VERSION_MAJOR}${CMAKE_OPENCV_GCC_VERSION_MINOR})
 128     message(STATUS "Detected version of GNU GCC: ${CMAKE_OPENCV_GCC_VERSION}")
 129 endif()
 130
 131 # ----------------------------------------------------------------------------
 132 #               CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 133 # ----------------------------------------------------------------------------
 134
 135 # Build/install (or not) some apps:
 136 # ===================================================
 137 set(BUILD_EXAMPLES OFF CACHE BOOL "Build all examples")
 138 set(INSTALL_C_EXAMPLES OFF CACHE BOOL "Install C examples")
 139 set(INSTALL_PYTHON_EXAMPLES OFF CACHE BOOL "Install Python examples")
 140 set(INSTALL_OCTAVE_EXAMPLES OFF CACHE BOOL "Install Octave examples")
 141
 142 # Build tests:
 143 # ===================================================
 144 set(BUILD_TESTS ON CACHE BOOL "Build tests")
 145
 146 # Build 3rdparty libraries under unix
 147 # ===================================================
 148 if(WIN32)
 149         set(OPENCV_BUILD_3RDPARTY_LIBS TRUE  CACHE BOOL "Build 3rd party libraries")
 150 else()
 151         set(OPENCV_BUILD_3RDPARTY_LIBS FALSE CACHE BOOL "Build 3rd party libraries")
 152 endif()
 153
 154 include(OpenCVPCHSupport.cmake REQUIRED)
 155
 156 if(UNIX)
 157     include(OpenCVFindPkgConfig.cmake OPTIONAL)
 158     include(CheckFunctionExists)
 159     include(CheckIncludeFile)
 160 endif()
 161
 162 # Default value for OPENMP:
 163 #  MSVC: Yes
 164 #  Others: No
 165 # ===================================================
 166 if(MSVC)
 167         set(DEFAULT_OPENCV_ENABLE_OPENMP ON)
 168 else()
 169         set(DEFAULT_OPENCV_ENABLE_OPENMP OFF)
 170 endif()
 171
 172 set(OPENCV_ENABLE_OPENMP ${DEFAULT_OPENCV_ENABLE_OPENMP} CACHE BOOL "")
 173
 174 if(CMAKE_COMPILER_IS_GNUCXX)
 175     set(OPENCV_ENABLE_PROFILING OFF CACHE BOOL "Enable profiling in the GCC compiler (Add flags: -g -pg)")
 176     set(OPENCV_USE_OMIT_FRAME_POINTER ON CACHE BOOL "Enable -fomit-frame-pointer for GCC")
 177     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES arm*)
 178         # We can use only -O2 because the -O3 causes gcc crash
 179         set(OPENCV_USE_O2 ON CACHE BOOL "Enable -O2 for GCC")
 180         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 181     endif()
 182     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES amd64*)
 183         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 184         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 185         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 186         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 187         set(OPENCV_USE_SSE2 ON CACHE BOOL "Enable SSE2 for GCC")
 188         set(OPENCV_USE_SSE3 ON CACHE BOOL "Enable SSE3 for GCC")
 189     endif()
 190     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES x86_64*)
 191         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 192         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 193         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 194         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 195         set(OPENCV_USE_SSE2 ON CACHE BOOL "Enable SSE2 for GCC")
 196         set(OPENCV_USE_SSE3 ON CACHE BOOL "Enable SSE3 for GCC")
 197     endif()
 198     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES powerpc*)
 199         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 200         set(OPENCV_USE_POWERPC ON CACHE BOOL "Enable PowerPC for GCC")
 201     endif ()
 202     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES i686*)
 203         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 204         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 205         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 206                 set(OPENCV_USE_SSE OFF CACHE BOOL "Enable SSE for GCC")
 207         set(OPENCV_USE_SSE2 OFF CACHE BOOL "Enable SSE2 for GCC")
 208         set(OPENCV_USE_SSE3 OFF CACHE BOOL "Enable SSE3 for GCC")
 209         # SSE/SSE2 might probably be not available for some old AMD or VIA processors
 210     endif ()
 211     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES x86)
 212         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 213         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 214         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 215                 set(OPENCV_USE_SSE OFF CACHE BOOL "Enable SSE for GCC")
 216         set(OPENCV_USE_SSE2 OFF CACHE BOOL "Enable SSE2 for GCC")
 217         set(OPENCV_USE_SSE3 OFF CACHE BOOL "Enable SSE3 for GCC")
 218         # SSE/SSE2 might probably be not available for some old AMD or VIA processors
 219     endif ()
 220 endif()
 221
 222 # ===================================================
 223 # Macros that checks if module have been installed.
 224 # After it adds module to build and define
 225 # constants passed as second arg
 226 # ===================================================
 227
 228 macro(CHECK_MODULE module_name define)
 229     set(${define} 0)
 230     if(PKG_CONFIG_FOUND)
 231         set(ALIAS               ALIASOF_${module_name})
 232         set(ALIAS_FOUND                 ${ALIAS}_FOUND)
 233         set(ALIAS_INCLUDE_DIRS   ${ALIAS}_INCLUDE_DIRS)
 234         set(ALIAS_LIBRARY_DIRS   ${ALIAS}_LIBRARY_DIRS)
 235         set(ALIAS_LIBRARIES         ${ALIAS}_LIBRARIES)
 236
 237         PKG_CHECK_MODULES(${ALIAS} ${module_name})
 238
 239         if (${ALIAS_FOUND})
 240             set(${define} 1)
 241             foreach(P "${ALIAS_INCLUDE_DIRS}")
 242                 if (${P})
 243                     list(APPEND HIGHGUI_INCLUDE_DIRS ${${P}})
 244                 endif()
 245             endforeach()
 246
 247             foreach(P "${ALIAS_LIBRARY_DIRS}")
 248                 if (${P})
 249                     list(APPEND HIGHGUI_LIBRARY_DIRS ${${P}})
 250                 endif()
 251             endforeach()
 252
 253             list(APPEND HIGHGUI_LIBRARIES ${${ALIAS_LIBRARIES}})
 254         endif()
 255     endif()
 256 endmacro()
 257
 258 if(UNIX)
 259     if(NOT APPLE)
 260         CHECK_MODULE(gtk+-2.0 HAVE_GTK)
 261         CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
 262         CHECK_MODULE(gstreamer-base-0.10 HAVE_GSTREAMER)
 263     endif()
 264
 265     CHECK_MODULE(libunicap HAVE_UNICAP_)
 266     CHECK_MODULE(libucil HAVE_UNICAP_UCIL)
 267     if(HAVE_UNICAP_ AND HAVE_UNICAP_UCIL)
 268         set(HAVE_UNICAP 1)
 269     endif()
 270
 271     CHECK_MODULE(libavcodec HAVE_FFMPEG_CODEC)
 272     CHECK_MODULE(libavformat HAVE_FFMPEG_FORMAT)
 273     CHECK_MODULE(libavutil HAVE_FFMPEG_UTIL)
 274     CHECK_MODULE(libswscale HAVE_FFMPEG_SWSCALE)
 275     CHECK_INCLUDE_FILE(libavformat/avformat.h HAVE_GENTOO_FFMPEG)
 276     if(HAVE_FFMPEG_CODEC AND HAVE_FFMPEG_FORMAT AND HAVE_FFMPEG_UTIL)
 277         set(HAVE_FFMPEG 1)
 278     endif()
 279
 280     CHECK_MODULE(libdc1394-2 HAVE_DC1394_2)
 281     if(NOT HAVE_DC1394_2)
 282         CHECK_MODULE(libdc1394 HAVE_DC1394)
 283     endif()
 284
 285     if(NOT APPLE)
 286         CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 287         CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 288         CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 289         CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 290
 291         CHECK_MODULE(libxine HAVE_XINE)
 292                 CHECK_MODULE(libv4l1 HAVE_LIBV4L)
 293         CHECK_INCLUDE_FILE(linux/videodev.h HAVE_CAMV4L)
 294         CHECK_INCLUDE_FILE(linux/videodev2.h HAVE_CAMV4L2)
 295
 296                 if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 297                         include(FindPNG)
 298                         if(PNG_FOUND)
 299                                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/png.h HAVE_PNG_H)
 300                                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/libpng/png.h HAVE_LIBPNG_PNG_H)
 301                         endif()
 302                         include(FindJPEG)
 303                         include(FindTIFF)
 304                         include(FindJasper)
 305                 endif()
 306
 307         set(OPENCV_LINKER_LIBS dl m pthread rt)
 308     else()
 309         add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 310     endif()
 311 endif()
 312
 313 set(BUILD_PYTHON_SUPPORT OFF CACHE BOOL "Build with Python support")
 314 set(BUILD_OCTAVE_SUPPORT OFF CACHE BOOL "Build with Octave support")
 315
 316 find_package(SWIG)
 317 if(SWIG_FOUND)
 318
 319     find_package(PythonInterp)
 320     find_package(PythonLibs)
 321
 322     # cmake 2.4 (at least on Ubuntu 8.04 (hardy)) don't define PYTHONLIBS_FOUND
 323     if(NOT PYTHONLIBS_FOUND AND PYTHON_INCLUDE_PATH)
 324         set(PYTHONLIBS_FOUND ON)
 325     endif(NOT PYTHONLIBS_FOUND AND PYTHON_INCLUDE_PATH)
 326
 327     # Build with python if installed:
 328     # ===================================================
 329     if(PYTHONLIBS_FOUND AND BUILD_PYTHON_SUPPORT)
 330         execute_process(COMMAND ${PYTHON_EXECUTABLE} --version
 331                   ERROR_VARIABLE PYTHON_VERSION_FULL
 332                   OUTPUT_STRIP_TRAILING_WHITESPACE)
 333
 334         string(REGEX MATCH "[0-9].[0-9]" PYTHON_VERSION_MAJOR_MINOR "${PYTHON_VERSION_FULL}")
 335         if(UNIX)
 336             set(PYTHON_PLUGIN_INSTALL_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/site-packages/opencv)
 337         endif()
 338         if(WIN32)
 339             get_filename_component(PYTHON_PATH "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Python\\PythonCore\\${PYTHON_VERSION_MAJOR_MINOR}\\InstallPath]" ABSOLUTE CACHE)
 340             set(PYTHON_PLUGIN_INSTALL_PATH "${PYTHON_PATH}/Lib/site-packages/opencv")
 341         endif()
 342     endif()
 343
 344 endif()
 345
 346 if(WIN32)
 347
 348 set(IPP_FOUND)
 349 foreach(v "6.1" "6.0" "5.3" "5.2" "5.1")
 350     if(NOT IPP_FOUND)
 351         find_path(IPP_PATH "ippi-${v}.dll"
 352             PATHS ${CMAKE_PROGRAM_PATH} ${CMAKE_SYSTEM_PROGRAM_PATH}
 353             DOC "The path to IPP DLLs")
 354         if(IPP_PATH)
 355             file(GLOB IPP_HDRS "${IPP_PATH}/../include")
 356             if(IPP_HDRS)
 357                 set(IPP_FOUND TRUE)
 358             endif()
 359         endif()
 360     endif()
 361 endforeach()
 362
 363 message(STATUS "IPP detected: ${IPP_FOUND}")
 364 set(USE_IPP ${IPP_FOUND} CACHE BOOL "Use IPP when available")
 365
 366 if(IPP_FOUND AND USE_IPP)
 367     add_definitions(-DHAVE_IPP)
 368     include_directories("${IPP_PATH}/../include")
 369     link_directories("${IPP_PATH}/../lib")
 370     set(IPP_LIBS ippsmerged.lib ippsemerged.lib ippimerged.lib ippiemerged.lib
 371         ippvmmerged.lib ippvmemerged.lib ippccmerged.lib ippccemerged.lib
 372         ippcvmerged.lib ippcvemerged.lib ippcorel.lib)
 373 endif()
 374
 375 endif()
 376
 377 # ----------------------------------------------------------------------------
 378 #                               UPDATE CONFIG FILES & SCRIPTS:
 379 #
 380 #  CONFIGURE_FILE(InputFile OutputFile [COPYONLY] [ESCAPE_QUOTES] [@ONLY])
 381 # If @ONLY is specified, only variables of the form @VAR@ will be
 382 #  replaces and ${VAR} will be ignored.
 383 #
 384 #  A directory will be created for each platform so the "cvconfig.h" file is
 385 #   not overwritten if cmake generates code in the same path.
 386 # ----------------------------------------------------------------------------
 387 add_definitions(-DHAVE_CONFIG_H)
 388
 389 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 390
 391 message(STATUS "Parsing 'cvconfig.h.cmake'")
 392 configure_file("${CMAKE_SOURCE_DIR}/cvconfig.h.cmake" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}/cvconfig.h")
 393
 394 # ---------------------------------------------------------------------------
 395 # The C+//0 include & link directories:
 396 # ---------------------------------------------------------------------------
 397 include_directories("."
 398     "${OPENCV_CONFIG_FILE_INCLUDE_DIR}"
 399     "${CMAKE_SOURCE_DIR}/include"
 400     "${CMAKE_SOURCE_DIR}/include/opencv"
 401     )
 402
 403 # ----------------------------------------------------------------------------
 404 #                       Set the maximum level of warnings:
 405 # ----------------------------------------------------------------------------
 406 # Should be set to true for development
 407 set(OPENCV_WARNINGS_ARE_ERRORS OFF CACHE BOOL "Treat warnings as errors")
 408
 409 # Whole program optimization?
 410 set(OPENCV_WHOLE_PROGRAM_OPTIMIZATION OFF CACHE BOOL "Flags for whole program optimization.")
 411
 412 set(EXTRA_C_FLAGS "")
 413 set(EXTRA_C_FLAGS_RELEASE "")
 414 set(EXTRA_C_FLAGS_DEBUG "")
 415 set(EXTRA_EXE_LINKER_FLAGS "")
 416 set(EXTRA_EXE_LINKER_FLAGS_RELEASE "")
 417 set(EXTRA_EXE_LINKER_FLAGS_DEBUG "")
 418
 419 if(MSVC)
 420     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE")
 421     # 64-bit portability warnings, in MSVC8
 422     if(MSVC80)
 423         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} /Wp64")
 424     endif()
 425
 426     set(EXTRA_EXE_LINKER_FLAGS_RELEASE "${EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 427
 428     # Whole program optimization
 429     if(OPENCV_WHOLE_PROGRAM_OPTIMIZATION AND MSVC_VERSION GREATER 1300)
 430         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /GL")
 431         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 432         set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} /LTCG")
 433     endif()
 434
 435     if(OPENCV_ENABLE_OPENMP)
 436         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /openmp")
 437     endif()
 438
 439     # Remove unreferenced functions: function level linking
 440     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} /Gy")
 441     set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /Zi")
 442 endif()
 443
 444 if(CMAKE_COMPILER_IS_GNUCXX)
 445     # High level of warnings.
 446     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -Wall")
 447
 448     # The -Wno-long-long is required in 64bit systems when including sytem headers.
 449     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES amd64* OR ${CMAKE_SYSTEM_PROCESSOR} MATCHES x86_64*)
 450     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -Wno-long-long")
 451     endif()
 452
 453     # We need pthread's
 454     if(UNIX)
 455         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -pthread")
 456     endif()
 457
 458     if(OPENCV_WARNINGS_ARE_ERRORS)
 459         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -Werror")
 460     endif()
 461
 462     # Whole program optimization
 463     if(OPENCV_WHOLE_PROGRAM_OPTIMIZATION)
 464         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -fwhole-program --combine")
 465     endif()
 466
 467     # Other optimizations
 468     if(OPENCV_USE_OMIT_FRAME_POINTER)
 469        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -fomit-frame-pointer")
 470     endif()
 471     if(OPENCV_USE_O2)
 472        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -O2")
 473     endif()
 474     if(OPENCV_USE_O3)
 475        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -O3")
 476     endif()
 477     if(OPENCV_USE_FAST_MATH)
 478        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -ffast-math")
 479     endif()
 480     if(OPENCV_USE_POWERPC)
 481        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -mcpu=G3 -mtune=G5")
 482     endif()
 483     if(OPENCV_USE_MMX)
 484        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -mmmx")
 485     endif()
 486     # SSE should be disabled under MingW because it generates compiler errors
 487     if(OPENCV_USE_SSE)
 488        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse")
 489     endif()
 490     # SSE2 should be disabled under MingW because it generates compiler errors
 491     if(OPENCV_USE_SSE2)
 492        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse2")
 493     endif()
 494     # SSE3 should be disabled under MingW because it generates compiler errors
 495     if(OPENCV_USE_SSE3 AND NOT MINGW)
 496        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse3")
 497     endif()
 498
 499     # Profiling?
 500     if(OPENCV_ENABLE_PROFILING)
 501         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -pg -g")
 502     else()
 503         # Remove unreferenced functions: function level linking
 504         if(NOT APPLE)
 505             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -ffunction-sections")
 506         endif()
 507     endif()
 508
 509     # Parallel mode
 510     if(OPENCV_ENABLE_OPENMP)
 511         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -D_GLIBCXX_PARALLEL -fopenmp")
 512     endif()
 513
 514     set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -DNDEBUG")
 515     set(EXTRA_C_FLAGS_DEBUG "${EXTRA_C_FLAGS_DEBUG} -O0 -DDEBUG -D_DEBUG")
 516 endif()
 517
 518
 519 # Add user supplied extra options (optimization, etc...)
 520 # ==========================================================
 521 set(OPENCV_EXTRA_C_FLAGS ${EXTRA_C_FLAGS} CACHE STRING "Extra compiler options" FORCE)
 522 set(OPENCV_EXTRA_C_FLAGS_RELEASE ${EXTRA_C_FLAGS_RELEASE} CACHE STRING "Extra compiler options for Release build" FORCE)
 523 set(OPENCV_EXTRA_C_FLAGS_DEBUG ${EXTRA_C_FLAGS_DEBUG} CACHE STRING "Extra compiler options for Debug build" FORCE)
 524 set(OPENCV_EXTRA_EXE_LINKER_FLAGS ${EXTRA_EXE_LINKER_FLAGS} CACHE STRING "Extra linker flags" FORCE)
 525 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE ${EXTRA_EXE_LINKER_FLAGS_RELEASE} CACHE STRING "Extra linker flags for Release build" FORCE)
 526 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG ${EXTRA_EXE_LINKER_FLAGS_DEBUG} CACHE STRING "Extra linker flags for Debug build" FORCE)
 527
 528 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 529 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 530 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_C_FLAGS_RELEASE}")
 531 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_C_FLAGS_RELEASE}")
 532 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_C_FLAGS_DEBUG}")
 533 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_C_FLAGS_DEBUG}")
 534 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 535 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 536 set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 537
 538 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 539 if (${CMAKE_GENERATOR} MATCHES ".*Makefiles")
 540     if("${CMAKE_BUILD_TYPE}" STREQUAL "")
 541         set(CMAKE_BUILD_TYPE Release)
 542     endif()
 543 endif()
 544
 545 if (WIN32 AND MSVC)
 546     # avoid warnings from MSVC about overriding the /W* option
 547     # we replace /W3 with /W4 only for C++ files,
 548     # since all the 3rd-party libraries OpenCV uses are in C,
 549     # and we do not care about their warnings.
 550     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 551     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 552     string(REPLACE "/W3" "/W4" CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG}")
 553 endif()
 554
 555 if("${CMAKE_CONFIGURE_LDFLAGS}")
 556     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_CONFIGURE_LDFLAGS}")
 557 endif("${CMAKE_CONFIGURE_LDFLAGS}")
 558
 559 # ----------------------------------------------------------------------------
 560 #                                       PROCESS SUBDIRECTORIES:
 561 # ----------------------------------------------------------------------------
 562 # Save libs and executables in the same place
 563 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib CACHE PATH "Output directory for libraries" )
 564 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/bin CACHE PATH "Output directory for applications" )
 565
 566 if(WIN32)
 567 set(OPENCV_DOC_INSTALL_PATH doc)
 568 else()
 569 set(OPENCV_DOC_INSTALL_PATH share/opencv/doc)
 570 endif()
 571
 572 #-----------------------------------
 573 # Subdirectories:
 574 #-----------------------------------
 575 add_subdirectory(src)
 576 add_subdirectory(apps)
 577 add_subdirectory(doc)
 578 add_subdirectory(data)
 579
 580 if(BUILD_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_OCTAVE_EXAMPLES)
 581     add_subdirectory(samples)
 582 endif()
 583
 584 if(BUILD_TESTS)
 585     enable_testing()
 586     add_subdirectory(tests)
 587 endif()
 588
 589 add_subdirectory(interfaces)
 590 add_subdirectory(3rdparty)
 591
 592 # --------------------------------------------------------------------------------------------
 593 #   Installation for CMake Module:  OpenCVConfig.cmake
 594 #  Part 1/3: ${BIN_DIR}/OpenCVConfig.cmake              -> For use *without* "make install"
 595 #  Part 2/3: ${BIN_DIR}/unix-install/OpenCVConfig.cmake -> For use with "make install"
 596 #  Part 3/3: ${BIN_DIR}/win-install/OpenCVConfig.cmake  -> For use within binary installers/packages
 597 # -------------------------------------------------------------------------------------------
 598
 599 # -------------------------------------------------------------------------------------------
 600 #  Part 1/2: ${BIN_DIR}/OpenCVConfig.cmake              -> For use *without* "make install"
 601 # -------------------------------------------------------------------------------------------
 602
 603 # Name of libraries is: libcv.so.1.1.0, etc...
 604 #  OPENCV_DLLVERSION must be set to "110", etc..
 605 # Already done above.
 606
 607 # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 608 set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE)
 609 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 610 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_SOURCE_DIR}/include")
 611 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_SOURCE_DIR}/include/opencv")
 612
 613 set(CMAKE_LIB_DIRS_CONFIGCMAKE ${LIBRARY_OUTPUT_PATH})
 614
 615 configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 616
 617 # --------------------------------------------------------------------------------------------
 618 #  Part 2/2: ${BIN_DIR}/unix-install/OpenCVConfig.cmake -> For use *with* "make install"
 619 # -------------------------------------------------------------------------------------------
 620 # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 621
 622 set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_INSTALL_PREFIX}/include/opencv")
 623 set(CMAKE_LIB_DIRS_CONFIGCMAKE "${CMAKE_INSTALL_PREFIX}/lib")
 624
 625 #exec_program(${CMAKE_COMMAND} ARGS "-E make_directory \"${CMAKE_BINARY_DIR}/unix-install/\"")
 626 exec_program(mkdir ARGS "-p \"${CMAKE_BINARY_DIR}/unix-install/\"")
 627 configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/unix-install/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 628
 629 if(UNIX)
 630     # For a command "FIND_PACKAGE(FOO)", CMake will look at the directory /usr/share|lib/FOO/FOOConfig.cmake, so:
 631     install(FILES ${CMAKE_BINARY_DIR}/unix-install/OpenCVConfig.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/opencv/)
 632 endif()
 633
 634 # --------------------------------------------------------------------------------------------
 635 #  Part 3/3: ${BIN_DIR}/win-install/OpenCVConfig.cmake  -> For use within binary installers/packages
 636 # -------------------------------------------------------------------------------------------
 637 if(WIN32)
 638         # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 639
 640         # This will expand to, for example, <program files>/OpenCV 1.1.0/include
 641         set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE "\"\${THIS_OPENCV_CONFIG_PATH}/include\"")
 642
 643         # This will expand to, for example, <program files>/OpenCV 1.1.0/lib
 644         set(CMAKE_LIB_DIRS_CONFIGCMAKE "\"\${THIS_OPENCV_CONFIG_PATH}/lib\"")
 645
 646         #exec_program(${CMAKE_COMMAND} ARGS "-E make_directory \"${CMAKE_BINARY_DIR}/win-install/\"")
 647         exec_program(mkdir ARGS "-p \"${CMAKE_BINARY_DIR}/win-install/\"")
 648         configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/win-install/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 649 endif()
 650
 651
 652 # --------------------------------------------------------------------------------------------
 653 #  Part 2/2: ${BIN_DIR}/unix-install/opencv.pc -> For use *with* "make install"
 654 # prefix=/usr
 655 # exec_prefix=${prefix}
 656 # libdir=${exec_prefix}/lib
 657 # includedir=${prefix}/include/opencv
 658 # -------------------------------------------------------------------------------------------
 659 set(prefix              ${CMAKE_INSTALL_PREFIX})
 660 set(exec_prefix         "\${prefix}")
 661 set(libdir              "\${exec_prefix}/lib")
 662 set(includedir          "\${prefix}/include")
 663 set(VERSION             ${OPENCV_VERSION})
 664
 665 configure_file("${CMAKE_SOURCE_DIR}/opencv.pc.cmake.in" "${CMAKE_BINARY_DIR}/unix-install/opencv.pc" @ONLY IMMEDIATE)
 666
 667 if(UNIX)
 668     install(FILES ${CMAKE_BINARY_DIR}/unix-install/opencv.pc DESTINATION lib/pkgconfig)
 669 endif()
 670
 671
 672 # ----------------------------------------------------------------------------
 673 #   Uninstall target, for "make uninstall"
 674 # ----------------------------------------------------------------------------
 675 CONFIGURE_FILE(
 676   "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
 677   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 678   IMMEDIATE @ONLY)
 679
 680 ADD_CUSTOM_TARGET(uninstall
 681   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 682
 683
 684 # Make sure the system libraries are also copied when doing an "INSTALL":
 685 # ----------------------------------------------------------------------------
 686 include(InstallRequiredSystemLibraries)
 687
 688
 689 # ----------------------------------------------------------------------------
 690 #   CPack target
 691 # ----------------------------------------------------------------------------
 692
 693 option(BUILD_PACKAGE "Build a installer with the SDK")
 694
 695 if(BUILD_PACKAGE)
 696
 697         configure_file(
 698         Package.cmake.in
 699         ${CMAKE_BINARY_DIR}/.cpack/Package.cmake
 700         @ONLY
 701         )
 702
 703         install(FILES
 704                 AUTHORS
 705                 ChangeLog
 706                 COPYING
 707                 INSTALL
 708                 NEWS
 709                 README
 710                 THANKS
 711                 TODO
 712                 DESTINATION ${OPENCV_DOC_INSTALL_PATH}
 713         COMPONENT doc
 714                 )
 715
 716         include(${CMAKE_BINARY_DIR}/.cpack/Package.cmake)
 717
 718 endif()
 719
 720 # ----------------------------------------------------------------------------
 721 #   Sumary:
 722 # ----------------------------------------------------------------------------
 723 message(STATUS "")
 724 message(STATUS "General configuration for opencv ${OPENCV_VERSION} =====================================")
 725 message(STATUS "")
 726 message(STATUS "    Compiler:                  ${CMAKE_COMPILER}")
 727 message(STATUS "    C++ flags (Release):       ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
 728 message(STATUS "    C++ flags (Debug):         ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
 729 if(WIN32)
 730 message(STATUS "    Linker flags (Release):    ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 731 message(STATUS "    Linker flags (Debug):      ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 732 else()
 733 message(STATUS "    Linker flags (Release):    ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE}")
 734 message(STATUS "    Linker flags (Debug):      ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG}")
 735 endif()
 736
 737 if(UNIX)
 738 if(NOT APPLE)
 739 message(STATUS "")
 740 message(STATUS "  GUI: ")
 741 message(STATUS "    GTK+ 2.x:                  ${HAVE_GTK}")
 742 message(STATUS "    GThread:                   ${HAVE_GTHREAD}")
 743 message(STATUS "")
 744 if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 745 message(STATUS "  Image I/O: ")
 746 message(STATUS "    JPEG:                      ${JPEG_FOUND}")
 747 message(STATUS "    PNG:                       ${PNG_FOUND}")
 748 message(STATUS "    TIFF:                      ${TIFF_FOUND}")
 749 message(STATUS "    JASPER:                    ${JASPER_FOUND}")
 750 else()
 751 message(STATUS "  Image I/O: ")
 752 message(STATUS "    JPEG:                      build")
 753 message(STATUS "    PNG:                       build")
 754 message(STATUS "    TIFF:                      build")
 755 message(STATUS "    JASPER:                    build")
 756 endif()
 757 endif()
 758 message(STATUS "")
 759 message(STATUS "  Video I/O: ")
 760 message(STATUS "    DC1394 1.x:                ${HAVE_DC1394}")
 761 message(STATUS "    DC1394 2.x:                ${HAVE_DC1394_2}")
 762 message(STATUS "    FFMPEG:                    ${HAVE_FFMPEG}")
 763 message(STATUS "    GStreamer:                 ${HAVE_GSTREAMER}")
 764 message(STATUS "    UniCap:                    ${HAVE_UNICAP}")
 765 if(HAVE_LIBV4L)
 766 message(STATUS "    V4L/V4L2:                  Using libv4l")
 767 else()
 768 message(STATUS "    V4L/V4L2:                  ${HAVE_CAMV4L}/${HAVE_CAMV4L2}")
 769 endif()
 770 message(STATUS "    Xine:                      ${HAVE_XINE}")
 771 endif()
 772 message(STATUS "")
 773 message(STATUS "  Interfaces: ")
 774 if(PYTHONLIBS_FOUND AND BUILD_PYTHON_SUPPORT)
 775 message(STATUS "    Python:                    1")
 776 else()
 777 message(STATUS "    Python:                    0")
 778 endif()
 779 if(IPP_FOUND AND USE_IPP)
 780 message(STATUS "    Use IPP:                   1")
 781 else()
 782 message(STATUS "    Use IPP:                   0")
 783 endif()
 784 message(STATUS "")
 785 message(STATUS "    Install path:              ${CMAKE_INSTALL_PREFIX}")
 786 message(STATUS "")
 787 message(STATUS "    cvconfig.h is in:          ${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 788 message(STATUS "-----------------------------------------------------------------")
 789 message(STATUS "")
 790
 791 #----------------------------------------------------------------------------
 792 #   Generate the OpenCVConfig.cmake file for unix
 793 #      installation in CMAKE_INSTALL_PREFIX
 794 #----------------------------------------------------------------------------