novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 use strict;
  17 use warnings;
  18 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  19 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  20 use Pod::Usage;
  21 use File::Basename;
  22 use File::Spec;
  23 use IO::Handle;
  24 use Time::HiRes("usleep");
  25 use Socket;
  26 use FileHandle;
  27 use IPC::Open2;
  28 use POSIX qw(:errno_h);
  29 use Cwd qw(getcwd abs_path);
  30 use Expect;
  31
  32 # always flush
  33 $| = 1;
  34
  35 my $invocation_dir = $ENV{PWD} || getcwd();
  36
  37 ## Configuration file handling
  38
  39 # Default configuration
  40 $CFG::hypervisor = "";
  41 $CFG::hypervisor_params = "serial";
  42 $CFG::genisoimage = "genisoimage";
  43 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  44 $CFG::default_target = 'qemu';
  45 %CFG::targets = (
  46     'qemu' => '--qemu',
  47     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  48     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.86.92:2324',
  49     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  50     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  51     "ryuglab" => '--target ryu --server=pc-sojkam.felk.cvut.cz:/srv/tftp --remote-cmd="ssh -tt pc-sojkam.felk.cvut.cz \"sterm -d -s 115200 /dev/ttyUSB0\""',
  52     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  53     );
  54 chomp(my $nproc = `nproc`);
  55 $CFG::scons = "scons -j$nproc";
  56 $CFG::make = "make -j$nproc";
  57
  58 my $builddir;
  59
  60 sub read_config($) {
  61     my ($cfg) = @_;
  62     {
  63         package CFG; # Put config data into a separate namespace
  64
  65         my $rc = do($cfg);
  66
  67         # Check for errors
  68         if ($@) {
  69             die("ERROR: Failure compiling '$cfg' - $@");
  70         } elsif (! defined($rc)) {
  71             die("ERROR: Failure reading '$cfg' - $!");
  72         } elsif (! $rc) {
  73             die("ERROR: Failure processing '$cfg'");
  74         }
  75     }
  76     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  77     print STDERR "novaboot: Read $cfg\n";
  78 }
  79
  80 my @cfgs;
  81 {
  82     # We don't use $0 here, because it points to the novaboot itself and
  83     # not to the novaboot script. The problem with this approach is that
  84     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  85     # contains the first option. Hence the -f check.
  86     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  87     while ((-d $dir || -l $dir ) && $dir ne "/") {
  88         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  89         my @dirs = File::Spec->splitdir($dir);
  90         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  91     }
  92     @cfgs = reverse @cfgs;
  93     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
  94     if (opendir(my $dh, $dir)) {
  95         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
  96         closedir $dh;
  97         @etccfg = sort(@etccfg);
  98         @cfgs = ( @etccfg, @cfgs );
  99     }
 100 }
 101 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 102 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 103 GetOptions ("config|c=s" => \$cfg);
 104 read_config($_) foreach $cfg or @cfgs;
 105
 106 ## Command line handling
 107
 108 my $explicit_target;
 109 GetOptions ("target|t=s" => \$explicit_target);
 110
 111 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $iprelay, $iso_image, $interactive, $kernel_opt, $make, $man, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $reset, $reset_cmd, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, @uboot_init);
 112
 113 $rsync_flags = '';
 114 $rom_prefix = 'rom://';
 115 $stty = 'raw -crtscts -onlcr 115200';
 116 $reset = 1;                     # Reset target by default
 117
 118 my @expect_seen = ();
 119 sub handle_expect
 120 {
 121     my ($n, $v) = @_;
 122     push(@expect_seen, '-re') if $n eq "expect-re";
 123     push(@expect_seen, $v);
 124 }
 125
 126 sub handle_send
 127 {
 128     my ($n, $v) = @_;
 129     unless (@expect_seen) { die("No --expect before --send"); }
 130     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 131     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 132     unshift(@expect_raw, @expect_seen);
 133     @expect_seen = ();
 134 }
 135
 136 my %opt_spec;
 137 %opt_spec = (
 138     "amt=s"          => \$amt,
 139     "append|a=s"     => \@append,
 140     "bender|b"       => \$bender,
 141     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 142     "concat"         => \$concat,
 143     "chainloader=s"  => \@chainloaders,
 144     "dhcp-tftp|d"    => \$dhcp_tftp,
 145     "dump"           => \$dump_opt,
 146     "dump-config"    => \$dump_config,
 147     "exiton=s"       => \@exiton,
 148     "exiton-timeout=i"=> \$exiton_timeout,
 149     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 150     "expect=s"       => \&handle_expect,
 151     "expect-re=s"    => \&handle_expect,
 152     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 153     "gen-only"       => \$gen_only,
 154     "grub|g:s"       => \$grub_config,
 155     "grub-preamble=s"=> \$grub_preamble,
 156     "prefix|grub-prefix=s" => \$grub_prefix,
 157     "grub2:s"        => \$grub2_config,
 158     "grub2-prolog=s" => \$grub2_prolog,
 159     "ider"           => \$ider,
 160     "iprelay=s"      => \$iprelay,
 161     "iso:s"          => \$iso_image,
 162     "kernel|k=s"     => \$kernel_opt,
 163     "interactive|i"  => \$interactive,
 164     "name=s"         => \$config_name_opt,
 165     "make|m:s"       => \$make,
 166     "no-file-gen"    => \$no_file_gen,
 167     "off"            => \$off_opt,
 168     "on"             => \$on_opt,
 169     "pulsar|p:s"     => \$pulsar,
 170     "pulsar-root=s"  => \$pulsar_root,
 171     "qemu|Q:s"       => \$qemu,
 172     "qemu-append=s"  => \$qemu_append,
 173     "qemu-flags|q=s" => \$qemu_flags_cmd,
 174     "remote-cmd=s"   => \$remote_cmd,
 175     "remote-expect=s"=> \$remote_expect,
 176     "reset!"         => \$reset,
 177     "reset-cmd=s"    => \$reset_cmd,
 178     "rsync-flags=s"  => \$rsync_flags,
 179     "scons:s"        => \$scons,
 180     "scriptmod=s"    => \@scriptmod,
 181     "send=s"         => \&handle_send,
 182     "sendcont=s"     => \&handle_send,
 183     "serial|s:s"     => \$serial,
 184     "server:s"       => \$server,
 185     "strip-rom"      => sub { $rom_prefix = ''; },
 186     "stty=s"         => \$stty,
 187     "tftp"           => \$tftp,
 188     "tftp-port=i"    => \$tftp_port,
 189     "uboot:s"        => \$uboot,
 190     "uboot-addr=s"   => \%uboot_addr,
 191     "uboot-init=s"   => \@uboot_init,
 192     "h"              => \$help,
 193     "help"           => \$man,
 194     );
 195
 196 # First process target options
 197 {
 198     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 199     my @target_expanded;
 200     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 201     while ($t) {
 202         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 203
 204         undef $explicit_target;
 205         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 206         if (!$ret) { die "Error parsing target $t option"; }
 207         push(@target_expanded, @$remaining_args);
 208         $t = $explicit_target;
 209     }
 210     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 211     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 212 }
 213
 214 # Then process other command line options - some of them may override
 215 # what was specified by the target
 216 GetOptions %opt_spec or die("Error in command line arguments");
 217 pod2usage(1) if $help;
 218 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 219
 220 ### Dump sanitized configuration (if requested)
 221
 222 if ($dump_config) {
 223     use Data::Dumper;
 224     $Data::Dumper::Indent=1;
 225     print "# This file is in perl syntax.\n";
 226     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 227         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 228         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 229         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 230     }
 231     print "1;\n";
 232     exit;
 233 }
 234
 235 ### Sanitize configuration
 236
 237 if ($interactive && !-t STDIN) {
 238     die("novaboot: Interactive mode not supported when not on terminal");
 239 }
 240
 241 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 242
 243 if ($ider) {
 244     $iso_image //= ''; # IDE-R needs an ISO image
 245     if (!defined $amt) { die "Error: --ider requires --amt"; }
 246 }
 247
 248 # Default options
 249 if (defined $serial) {
 250     $serial ||= "/dev/ttyUSB0";
 251     $ENV{NB_SERIAL} = $serial;
 252 }
 253 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 254 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 255
 256 ## Parse the novaboot script(s)
 257 my @scripts;
 258 my $file;
 259 my $EOF;
 260 my $last_fn = '';
 261 my ($modules, $variables, $generated, $continuation) = ([], {}, []);
 262 my $skip_reading = defined($on_opt) || defined($off_opt);
 263 while (!$skip_reading && ($_ = <>)) {
 264     if ($ARGV ne $last_fn) { # New script
 265         die "Missing EOF in $last_fn" if $file;
 266         die "Unfinished line in $last_fn" if $continuation;
 267         $last_fn = $ARGV;
 268         push @scripts, { 'filename' => $ARGV,
 269                          'modules' => $modules = [],
 270                          'variables' => $variables = {},
 271                          'generated' => $generated = []};
 272
 273     }
 274     chomp();
 275     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 276
 277     $_ =~ s/^[[:space:]]*// if ($continuation);
 278
 279     if (/\\$/) {                # Line continuation
 280         $continuation .= substr($_, 0, length($_)-1);
 281         next;
 282     }
 283
 284     if ($continuation) {        # Last continuation line
 285         $_ = $continuation . $_;
 286         $continuation = '';
 287     }
 288
 289     foreach my $mod(@scriptmod) { eval $mod; }
 290
 291     if ($file && $_ eq $EOF) {  # Heredoc end
 292         undef $file;
 293         next;
 294     }
 295     if ($file) {                # Heredoc content
 296         push @{$file}, "$_\n";
 297         next;
 298     }
 299     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 300         $$variables{$1} = $2;
 301         push(@exiton, $2) if ($1 eq "EXITON");
 302         next;
 303     }
 304     if (s/^load *//) {          # Load line
 305         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 306         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 307             push @$modules, "$1$2";
 308             $file = [];
 309             push @$generated, {filename => $1, content => $file};
 310             $EOF = $3;
 311             next;
 312         }
 313         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 314             push @$modules, "$1$2";
 315             push @$generated, {filename => $1, command => $3};
 316             next;
 317         }
 318         push @$modules, $_;
 319         next;
 320     }
 321     if (/^run (.*)/) {          # run line
 322         push @$generated, {command => $1};
 323         next;
 324     }
 325     if (/^uboot(?::([0-9]+)s)? (.*)/) { # uboot line
 326         # TODO: If U-Boot supports some interactive menu, it might
 327         # make sense to store uboot lines per novaboot script.
 328         if ($1) {               # Command with explicit timeout
 329             push @uboot_init, { command => $2,
 330                                 timeout => $1 };
 331         } else {                # Command without explicit timeout
 332             push @uboot_init, $2;
 333         }
 334         next;
 335     }
 336
 337     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 338 }
 339 # use Data::Dumper;
 340 # print Dumper(\@scripts);
 341
 342 foreach my $script (@scripts) {
 343     $modules = $$script{modules};
 344     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 345     @$modules[0] .= ' ' . join(' ', @append) if @append;
 346
 347     my $kernel;
 348     if (exists $variables->{KERNEL}) {
 349         $kernel = $variables->{KERNEL};
 350     } else {
 351         if ($CFG::hypervisor) {
 352             $kernel = $CFG::hypervisor . " ";
 353             if (exists $variables->{HYPERVISOR_PARAMS}) {
 354                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 355             } else {
 356                 $kernel .= $CFG::hypervisor_params;
 357             }
 358         }
 359     }
 360     @$modules = ($kernel, @$modules) if $kernel;
 361     @$modules = (@chainloaders, @$modules);
 362     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 363 }
 364
 365 if ($dump_opt) {
 366     foreach my $script (@scripts) {
 367         print join("\n", @{$$script{modules}})."\n";
 368     }
 369     exit(0);
 370 }
 371
 372 ## Helper functions
 373
 374 sub generate_configs($$$) {
 375     my ($base, $generated, $filename) = @_;
 376     if ($base) { $base = "$base/"; };
 377     foreach my $g(@$generated) {
 378       if (exists $$g{content}) {
 379         my $config = $$g{content};
 380         my $fn = $$g{filename};
 381         open(my $f, '>', $fn) || die("$fn: $!");
 382         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 383         close($f);
 384         print "novaboot: Created $fn\n";
 385       } elsif (exists $$g{command} && ! $no_file_gen) {
 386         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 387         if (exists $$g{filename}) {
 388             system_verbose("( $$g{command} ) > $$g{filename}");
 389         } else {
 390             system_verbose($$g{command});
 391         }
 392       }
 393     }
 394 }
 395
 396 sub generate_grub_config($$$$;$)
 397 {
 398     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 399     if ($base) { $base = "$base/"; };
 400     open(my $fg, '>', $filename) or die "$filename: $!";
 401     print $fg "$preamble\n" if $preamble;
 402     print $fg "title $title\n" if $title;
 403     #print $fg "root $base\n"; # root doesn't really work for (nd)
 404     my $first = 1;
 405     foreach (@$modules_ref) {
 406         if ($first) {
 407             $first = 0;
 408             my ($kbin, $kcmd) = split(' ', $_, 2);
 409             $kcmd = '' if !defined $kcmd;
 410             print $fg "kernel ${base}$kbin $kcmd\n";
 411         } else {
 412             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 413             print $fg "module $base$_\n";
 414         }
 415     }
 416     close($fg);
 417     print("novaboot: Created $builddir/$filename\n");
 418     return $filename;
 419 }
 420
 421 sub generate_syslinux_config($$$$)
 422 {
 423     my ($filename, $title, $base, $modules_ref) = @_;
 424     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 425     open(my $fg, '>', $filename) or die "$filename: $!";
 426     print $fg "LABEL $title\n";
 427     #TODO print $fg "MENU LABEL $human_readable_title\n";
 428
 429     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 430
 431     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 432         my $initrd = @$modules_ref[1];
 433         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 434         print $fg "LINUX $base$kbin\n";
 435         print $fg "APPEND $kcmd\n";
 436         print $fg "INITRD $base$initrd\n";
 437     } else {
 438         print $fg "KERNEL mboot.c32\n";
 439         my @append;
 440         foreach (@$modules_ref) {
 441             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 442             push @append, "$base$_";
 443             print $fg "APPEND ".join(' --- ', @append)."\n";
 444         }
 445     }
 446     #TODO print $fg "TEXT HELP\n";
 447     #TODO print $fg "some help here\n";
 448     #TODO print $fg "ENDTEXT\n";
 449     close($fg);
 450     print("novaboot: Created $builddir/$filename\n");
 451     return $filename;
 452 }
 453
 454 sub generate_grub2_config($$$$;$$)
 455 {
 456     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 457     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 458     open(my $fg, '>', $filename) or die "$filename: $!";
 459     print $fg "$preamble\n" if $preamble;
 460     $title ||= 'novaboot';
 461     print $fg "menuentry $title {\n";
 462     print $fg "$prolog\n" if $prolog;
 463     my $first = 1;
 464     foreach (@$modules_ref) {
 465         if ($first) {
 466             $first = 0;
 467             my ($kbin, $kcmd) = split(' ', $_, 2);
 468             $kcmd = '' if !defined $kcmd;
 469             print $fg "  multiboot ${base}$kbin $kcmd\n";
 470         } else {
 471             my @args = split;
 472             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 473             $_ = join(' ', ($args[0], @args));
 474             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 475             print $fg "  module $base$_\n";
 476         }
 477     }
 478     print $fg "}\n";
 479     close($fg);
 480     print("novaboot: Created $builddir/$filename\n");
 481     return $filename;
 482 }
 483
 484 sub generate_pulsar_config($$)
 485 {
 486     my ($filename, $modules_ref) = @_;
 487     open(my $fg, '>', $filename) or die "$filename: $!";
 488     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 489     my $first = 1;
 490     my ($kbin, $kcmd);
 491     foreach (@$modules_ref) {
 492         if ($first) {
 493             $first = 0;
 494             ($kbin, $kcmd) = split(' ', $_, 2);
 495             $kcmd = '' if !defined $kcmd;
 496         } else {
 497             my @args = split;
 498             s|\brom://|$rom_prefix|g;
 499             print $fg "load $_\n";
 500         }
 501     }
 502     # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 503     print $fg "exec $kbin $kcmd\n";
 504     close($fg);
 505     print("novaboot: Created $builddir/$filename\n");
 506     return $filename;
 507 }
 508
 509 sub shell_cmd_string(@)
 510 {
 511     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 512 }
 513
 514 sub exec_verbose(@)
 515 {
 516     print "novaboot: Running: ".shell_cmd_string(@_)."\n";
 517     exec(@_);
 518     exit(1); # should not be reached
 519 }
 520
 521 sub system_verbose($)
 522 {
 523     my $cmd = shift;
 524     print "novaboot: Running: $cmd\n";
 525     my $ret = system($cmd);
 526     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 527     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 528     if ($ret) { die("Command failure $ret"); }
 529 }
 530
 531 ## WvTest headline
 532
 533 if (exists $variables->{WVDESC}) {
 534     print "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 535 } elsif ($last_fn =~ /\.wv$/) {
 536     print "Testing \"all\" in $last_fn:\n";
 537 }
 538
 539 ## Connect to the target and check whether it is not occupied
 540
 541 # We have to do this before file generation phase, because file
 542 # generation is intermixed with file deployment phase and we want to
 543 # check whether the target is not used by somebody else before
 544 # deploying files. Otherwise, we may rewrite other user's files on a
 545 # boot server.
 546
 547 my $exp; # Expect object to communicate with the target over serial line
 548
 549 my ($target_reset, $target_power_on, $target_power_off);
 550 my ($amt_user, $amt_password, $amt_host, $amt_port);
 551
 552 if (defined $iprelay) {
 553     my $IPRELAY;
 554     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 555     my $addr = $1;
 556     my $port = $3 || 23;
 557     my $paddr   = sockaddr_in($port, inet_aton($addr));
 558     my $proto   = getprotobyname('tcp');
 559     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 560     print "novaboot: Connecting to IP relay... ";
 561     connect($IPRELAY, $paddr)    || die "connect: $!";
 562     print "done\n";
 563     $exp = Expect->init(\*$IPRELAY);
 564     $exp->log_stdout(1);
 565
 566     while (1) {
 567         print $exp "\xFF\xF6";  # AYT
 568         my $connected = $exp->expect(20, # Timeout in seconds
 569                                      '<iprelayd: connected>',
 570                                      '-re', '<WEB51 HW[^>]*>');
 571         last if $connected;
 572     }
 573
 574     sub relaycmd($$) {
 575         my ($relay, $onoff) = @_;
 576         die unless ($relay == 1 || $relay == 2);
 577
 578         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 579         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 580     }
 581
 582     sub relayconf($$) {
 583         my ($relay, $onoff) = @_;
 584         die unless ($relay == 1 || $relay == 2);
 585         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 586         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 587     }
 588
 589     sub relay($$;$) {
 590         my ($relay, $onoff, $can_giveup) = @_;
 591         my $confirmation = '';
 592         $exp->log_stdout(0);
 593         print $exp relaycmd($relay, $onoff);
 594         my $confirmed = $exp->expect(20, # Timeout in seconds
 595                                      relayconf($relay, $onoff));
 596         if (!$confirmed) {
 597             if ($can_giveup) {
 598                 print("Relay confirmation timeout - ignoring\n");
 599             } else {
 600                 die "Relay confirmation timeout";
 601             }
 602         }
 603         $exp->log_stdout(1);
 604     }
 605
 606     $target_reset = sub {
 607         relay(2, 1, 1); # Reset the machine
 608         usleep(100000);
 609         relay(2, 0);
 610     };
 611
 612     $target_power_off = sub {
 613         relay(1, 1);            # Press power button
 614         usleep(6000000);        # Long press to switch off
 615         relay(1, 0);
 616     };
 617
 618     $target_power_on = sub {
 619         relay(1, 1);            # Press power button
 620         usleep(100000);         # Short press
 621         relay(1, 0);
 622     };
 623 }
 624 elsif ($serial) {
 625     my $CONN;
 626     system_verbose("stty -F $serial $stty");
 627     open($CONN, "+<", $serial) || die "open $serial: $!";
 628     $exp = Expect->init(\*$CONN);
 629 }
 630 elsif ($remote_cmd) {
 631     print "novaboot: Running: $remote_cmd\n";
 632     $exp = Expect->spawn($remote_cmd);
 633 }
 634 elsif (defined $amt) {
 635     require LWP::UserAgent;
 636     require LWP::Authen::Digest;
 637
 638     sub genXML {
 639         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 640         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 641         my %pstates = ("on"        => 2,
 642                        "standby"   => 4,
 643                        "hibernate" => 7,
 644                        "off"       => 8,
 645                        "reset"     => 10,
 646                        "MNI"       => 11);
 647         return <<END;
 648                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 649                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 650                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 651                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 652                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 653                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 654                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 655                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 656                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 657                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 658                 </s:Header><s:Body>
 659                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 660                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 661                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 662                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 663                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 664                 </a:ReferenceParameters></p:ManagedElement>
 665                 </p:RequestPowerStateChange_INPUT>
 666                 </s:Body></s:Envelope>
 667 END
 668     }
 669
 670     sub sendPOST {
 671         my ($host, $username, $password, $content) = @_;
 672
 673         my $ua = LWP::UserAgent->new();
 674         $ua->agent("novaboot");
 675
 676         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 677         my $res = $ua->request($req);
 678         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 679
 680         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 681         $ua->credentials("$host:16992", $realm, $username => $password);
 682
 683         # Create a request
 684         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 685         $req->content_type('application/x-www-form-urlencoded');
 686         $req->content($content);
 687         $res = $ua->request($req);
 688         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 689         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 690         return $1;
 691     }
 692
 693     sub powerChange  {
 694         my ($host, $username, $password, $pstate)=@_;
 695         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 696         my $className="/RequestPowerStateChange";
 697         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 698         return sendPOST($host, $username, $password, $content);
 699     }
 700
 701     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 702     $amt_user ||= "admin";
 703     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 704     $amt_host || die "AMT host not specified";
 705     $amt_port ||= 16994;
 706
 707
 708     $target_power_off = sub {
 709         $exp->close();
 710         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 711         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 712     };
 713
 714     $target_power_on = sub {
 715         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 716         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 717     };
 718
 719     $target_reset = sub {
 720         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 721         if ($result != 0) {
 722             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 723             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 724         }
 725         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 726     };
 727
 728     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 729     print "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 730     $exp = Expect->spawn($cmd);
 731     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL' timed out";
 732
 733 }
 734
 735
 736 if ($remote_expect) {
 737     $exp || die("No serial line connection");
 738     $exp->expect(180, $remote_expect) || die "Expect for '$remote_expect' timed out";
 739 }
 740
 741 if (defined $reset_cmd) {
 742     $target_reset = sub {
 743         system_verbose($reset_cmd);
 744     };
 745 }
 746
 747 if (defined $on_opt && defined $target_power_on) {
 748     &$target_power_on();
 749     exit;
 750 }
 751 if (defined $off_opt && defined $target_power_off) {
 752     print "novaboot: Switching the target off...\n";
 753     &$target_power_off();
 754     exit;
 755 }
 756
 757 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 758 if (defined $builddir) {
 759     chdir($builddir) or die "Can't change directory to $builddir: $!";
 760     print "novaboot: Entering directory `$builddir'\n";
 761 } else {
 762     $builddir = $invocation_dir;
 763 }
 764
 765 ## File generation phase
 766 my (%files_iso, $menu_iso, $filename);
 767 my $config_name = '';
 768 my $prefix = '';
 769
 770 foreach my $script (@scripts) {
 771     $filename = $$script{filename};
 772     $modules = $$script{modules};
 773     $generated = $$script{generated};
 774     $variables = $$script{variables};
 775
 776     ($config_name = $filename) =~ s#.*/##;
 777     $config_name = $config_name_opt if (defined $config_name_opt);
 778
 779     if (exists $variables->{BUILDDIR}) {
 780         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 781         chdir($builddir) or die "Can't change directory to $builddir: $!";
 782         print "novaboot: Entering directory `$builddir'\n";
 783     }
 784
 785     if ($grub_prefix) {
 786         $prefix = $grub_prefix;
 787         $prefix =~ s/\$NAME/$config_name/;
 788         $prefix =~ s/\$BUILDDIR/$builddir/;
 789     }
 790     # TODO: use $grub_prefix as first parameter if some switch is given
 791     generate_configs('', $generated, $filename);
 792
 793 ### Generate bootloader configuration files
 794     my @bootloader_configs;
 795     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 796     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 797     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules) if (defined $pulsar);
 798
 799 ### Run scons or make
 800     {
 801         my @files = map({ ($file) = m/([^ ]*)/; $file; } @$modules);
 802         # Filter-out generated files
 803         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 804
 805         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 806         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 807     }
 808
 809 ### Copy files (using rsync)
 810     if (defined $server && !defined($gen_only)) {
 811         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 812
 813         my ($hostname, $path) = split(":", $real_server, 2);
 814         if (! defined $path) {
 815             $path = $hostname;
 816             $hostname = "";
 817         }
 818         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs)));
 819         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 820         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 821         my $progress = $istty ? "--progress" : "";
 822         system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 823         if ($server =~ m|/\$NAME$| && $concat) {
 824             my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 825             system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 826         }
 827     }
 828
 829 ### Prepare ISO image generation
 830     if (defined $iso_image) {
 831         generate_configs("(cd)", $generated, $filename);
 832         my $menu;
 833         generate_syslinux_config(\$menu, $config_name, "/", $modules);
 834         $menu_iso .= "$menu\n";
 835         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 836     }
 837 }
 838
 839 ## Generate ISO image
 840 if (defined $iso_image) {
 841     system_verbose("mkdir -p isolinux");
 842
 843     my @files;
 844     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
 845         # Newer ISOLINUX version
 846         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
 847     } else {
 848         # Older ISOLINUX version
 849         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
 850     }
 851     system_verbose("cp @files isolinux");
 852     open(my $fh, ">isolinux/isolinux.cfg");
 853     if ($#scripts) {
 854         print $fh "TIMEOUT 50\n";
 855         print $fh "DEFAULT menu\n";
 856     } else {
 857         print $fh "DEFAULT $config_name\n";
 858     }
 859     print $fh "$menu_iso";
 860     close($fh);
 861
 862     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
 863     $iso_image ||= "$config_name.iso";
 864
 865     # Note: We use -U flag below to "Allow 'untranslated' filenames,
 866     # completely violating the ISO9660 standards". Without this
 867     # option, isolinux is not able to read files names for example
 868     # bzImage-3.0.
 869     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
 870     print("ISO image created: $builddir/$iso_image\n");
 871 }
 872
 873 exit(0) if defined $gen_only;
 874
 875 ## Boot the system using various methods and send serial output to stdout
 876
 877 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 878     die "You cannot do this with multiple scripts simultaneously";
 879 }
 880
 881 if ($variables->{WVTEST_TIMEOUT}) {
 882     print "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 883 }
 884
 885 sub trim($) {
 886     my ($str) = @_;
 887     $str =~ s/^\s+|\s+$//g;
 888     return $str
 889 }
 890
 891 ### Start in Qemu
 892
 893 if (defined $qemu) {
 894     # Qemu
 895     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 896     my @qemu_flags = split(" ", $qemu);
 897     $qemu = shift(@qemu_flags);
 898
 899     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 900     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 901     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 902
 903     if (defined $iso_image) {
 904         # Boot NOVA with grub (and test the iso image)
 905         push(@qemu_flags, ('-cdrom', $iso_image));
 906     } else {
 907         # Boot NOVA without GRUB
 908
 909         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 910         foreach (@$modules) {s/,/+/g;}
 911         generate_configs("", $generated, $filename);
 912
 913         if (scalar @$modules) {
 914             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 915             $kcmd = '' if !defined $kcmd;
 916             my $dtb;
 917             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 918             my $initrd = join ",", @$modules;
 919
 920             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
 921             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
 922             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
 923         }
 924     }
 925     push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
 926     unshift(@qemu_flags, ('-name', $config_name));
 927     print "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
 928     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
 929 }
 930
 931 ### Local DHCPD and TFTPD
 932
 933 my ($dhcpd_pid, $tftpd_pid);
 934
 935 $tftp=1 if $tftp_port;
 936
 937 if (defined $dhcp_tftp)
 938 {
 939     generate_configs("(nd)", $generated, $filename);
 940     system_verbose('mkdir -p tftpboot');
 941     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
 942     open(my $fh, '>', 'dhcpd.conf');
 943     my $mac = `cat /sys/class/net/eth0/address`;
 944     chomp $mac;
 945     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
 946                       range 10.23.23.10 10.23.23.100;
 947                       filename \"bin/boot/grub/pxegrub.pxe\";
 948                       next-server 10.23.23.1;
 949 }
 950 host server {
 951         hardware ethernet $mac;
 952         fixed-address 10.23.23.1;
 953 }";
 954     close($fh);
 955     system_verbose("sudo ip a add 10.23.23.1/24 dev eth0;
 956             sudo ip l set dev eth0 up;
 957             sudo touch dhcpd.leases");
 958
 959     # We run servers by forking ourselves, because the servers end up
 960     # in our process group and get killed by signals sent to the
 961     # process group (e.g. Ctrl-C on terminal).
 962     $dhcpd_pid = fork();
 963     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
 964 }
 965
 966 if (defined $dhcp_tftp || defined $tftp) {
 967     $tftp_port ||= 69;
 968     # Unfortunately, tftpd requires root privileges even with
 969     # non-privileged (>1023) port due to initgroups().
 970     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
 971
 972     # Kill server when we die
 973     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
 974                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
 975
 976     # We have to kill tftpd explicitely, because it is not in our process group
 977     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
 978 }
 979
 980 ### AMT IDE-R
 981 if (defined $ider) {
 982     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
 983     print "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
 984     my $ider_pid = fork();
 985     if ($ider_pid == 0) {
 986         exec($ider_cmd);
 987         die "IDE redirection failed";
 988     }
 989     # FIXME: This collides with --tftp option. Hopefully, nobody needs
 990     # to use both simultaneously.
 991     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
 992 }
 993
 994 ### Reset target (IP relay, AMT, ...)
 995
 996 if (defined $target_reset && $reset) {
 997     print "novaboot: Reseting the test box... ";
 998     &$target_reset();
 999     print "done\n";
1000 }
1001
1002 ### U-boot conversation
1003 if (defined $uboot) {
1004     my $uboot_prompt = $uboot || '=> ';
1005     print "novaboot: Waiting for U-Boot prompt...\n";
1006     $exp || die("No serial line connection");
1007     $exp->log_stdout(1);
1008     #$exp->exp_internal(1);
1009     $exp->expect(20,
1010                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
1011                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1012     foreach my $cmdspec (@uboot_init) {
1013         my ($cmd, $timeout);
1014         if (ref($cmdspec) eq "HASH") {
1015             $cmd = $cmdspec->{command};
1016             $timeout = $cmdspec->{timeout};
1017         } else {
1018             $cmd = $cmdspec;
1019             $timeout = 10;
1020         }
1021         if ($cmd =~ /\$NB_MYIP/) {
1022             my $ip = (grep /inet /, `ip addr show eth0`)[0] || die "Problem determining our IP address";
1023             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1024             $cmd =~ s/\$NB_MYIP/$ip/g;
1025         }
1026         if ($cmd =~ /\$NB_PREFIX/) {
1027             my $p = $prefix;
1028             $p =~ s|/*$||;
1029             $cmd =~ s/\$NB_PREFIX/$p/g;
1030         }
1031         chomp($cmd);
1032         $exp->send("$cmd\n");
1033         $exp->expect($timeout, $uboot_prompt) || die "U-Boot prompt timeout";
1034     }
1035
1036     # Boot the system if there are some load lines in the script
1037     if (scalar(@$modules) > 0 && !$variables->{NO_BOOT}) {
1038         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1039         my $dtb;
1040         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1041         my $initrd = shift @$modules;
1042
1043         my ($ramdisk_addr, $fdt_addr) = ('-', '');
1044
1045         die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1046         $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1047         $exp->expect(10,
1048                      [qr/##/, sub { exp_continue; }],
1049                      $uboot_prompt) || die "Kernel load timeout";
1050         if (defined $dtb) {
1051             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1052             $fdt_addr = $uboot_addr{fdt};
1053             $exp->send("tftpboot $fdt_addr $prefix$dtb\n");
1054             $exp->expect(10,
1055                          [qr/##/, sub { exp_continue; }],
1056                          $uboot_prompt) || die "Device tree load timeout";
1057         }
1058         if (defined $initrd) {
1059             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1060             $ramdisk_addr = $uboot_addr{ramdisk};
1061             $exp->send("tftpboot $ramdisk_addr $prefix$initrd\n");
1062             $exp->expect(10,
1063                          [qr/#/, sub { exp_continue; }],
1064                          $uboot_prompt) || die "Initrd load timeout";
1065         }
1066         $exp->send("echo $kcmd\n");
1067         $exp->expect(1, '-re', qr{echo .*\n(.*)\n$uboot_prompt})  || die "Command line test timeout";
1068         my $args = ($exp->matchlist)[0];
1069         if ($args =~ /^setenv\s+bootargs/) {
1070             $exp->send("$args\n");
1071         } else {
1072             $exp->send("setenv bootargs $kcmd\n");
1073         }
1074         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt timeout";
1075         $exp->send("bootm $uboot_addr{kernel} $ramdisk_addr $fdt_addr\n");
1076         $exp->expect(5, "\n")  || die "U-Boot command timeout";
1077     }
1078 }
1079
1080 ### Serial line interaction
1081 if (defined $exp) {
1082     # Serial line of the target is available
1083     my $interrupt = 'Ctrl-C';
1084     if ($interactive && !@exiton) {
1085         $interrupt = '"~~."';
1086     }
1087     my $note = (-t STDIN) ? '' : '- only target->host ';
1088     print "novaboot: Serial line interaction $note(press $interrupt to interrupt)...\n";
1089     $exp->log_stdout(1);
1090     if (@exiton) {
1091         $exp->expect($exiton_timeout, @expect_raw, @exiton) || die("exiton timeout");
1092     } else {
1093         my @inputs = ($exp);
1094         if (-t STDIN) { # Set up bi-directional communication if we run on terminal
1095             my $infile = new IO::File;
1096             $infile->IO::File::fdopen(*STDIN,'r');
1097             my $in_object = Expect->exp_init($infile);
1098             $in_object->set_group($exp);
1099
1100             if ($interactive) {
1101                 $in_object->set_seq('~~\.', sub { print "novaboot: Escape sequence detected\r\n"; undef; });
1102                 $in_object->manual_stty(0);       # Use raw terminal mode
1103             } else {
1104                 $in_object->manual_stty(1);       # Do not modify terminal settings
1105             }
1106             push(@inputs, $in_object);
1107         }
1108         #use Data::Dumper;
1109         #print Dumper(\@expect_raw);
1110         $exp->expect(undef, @expect_raw) if @expect_raw;
1111         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1112     }
1113 }
1114
1115 ## Kill dhcpc or tftpd
1116 if (defined $dhcp_tftp || defined $tftp) {
1117     die("novaboot: This should kill servers on background\n");
1118 }
1119
1120 ## Documentation
1121
1122 =head1 NAME
1123
1124 novaboot - Boots a locally compiled operating system on a remote
1125 target or in qemu
1126
1127 =head1 SYNOPSIS
1128
1129 B<novaboot> --help
1130
1131 B<novaboot> [option]... [--] script...
1132
1133 B<./script> [option]...
1134
1135 =head1 DESCRIPTION
1136
1137 This program makes booting of a locally compiled operating system (OS)
1138 (e.g. NOVA or Linux) on remote targets as simple as running a program
1139 locally. It automates things like copying OS images to a TFTP server,
1140 generation of bootloader configuration files, resetting of target
1141 hardware or redirection of target's serial line to stdin/out. Novaboot
1142 is highly configurable and it makes it easy to boot a single image on
1143 different targets or different images on a single target.
1144
1145 Novaboot operation is controlled by command line options and by a so
1146 called novaboot script, which can be thought as a generalization of
1147 bootloader configuration files (see L</"NOVABOOT SCRIPT SYNTAX">).
1148 Typical way of using novaboot is to make the novaboot script
1149 executable and set its first line to I<#!/usr/bin/env novaboot>. Then,
1150 booting a particular OS configuration becomes the same as executing a
1151 local program - the novaboot script.
1152
1153 Novaboot uses configuration files to, among other things, define
1154 command line options needed for different targets. Users typically use
1155 only the B<-t>/B<--target> command line option to select the target.
1156 Internally, this option expands to the pre-configured options.
1157 Configuration files are searched at multiple places, which allows to
1158 have per-system, per-user or per-project configurations. Configuration
1159 file syntax is described in section L</"CONFIGURATION FILE">.
1160
1161 Simple examples of using C<novaboot>:
1162
1163 =over 3
1164
1165 =item 1.
1166
1167 Run an OS in Qemu. This is the default action when no other action is
1168 specified by command line switches. Thus running C<novaboot myos> (or
1169 C<./myos> as described above) will run Qemu and make it boot the
1170 configuration specified in the F<myos> script.
1171
1172 =item 2.
1173
1174 Create a bootloader configuration file (currently supported
1175 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar and U-Boot) and copy it
1176 with all other files needed for booting to a remote boot server. Then
1177 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1178 target and receive its serial output.
1179
1180  ./myos --grub2 --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1181
1182 =item 3.
1183
1184 Run DHCP and TFTP server on developer's machine to boot the target
1185 from it.
1186
1187  ./myos --dhcp-tftp
1188
1189 This is useful when no network infrastructure is in place and
1190 the target is connected directly to developer's box.
1191
1192 =item 4.
1193
1194 Create bootable ISO image.
1195
1196  novaboot --iso -- script1 script2
1197
1198 The created ISO image will have ISOLINUX bootloader installed on it
1199 and the boot menu will allow selecting between I<script1> and
1200 I<script2> configurations.
1201
1202 =back
1203
1204 =head1 PHASES AND OPTIONS
1205
1206 Novaboot performs its work in several phases. Each phase can be
1207 influenced by several command line options, certain phases can be
1208 skipped. The list of phases (in the execution order) and the
1209 corresponding options follows.
1210
1211 =head2 Configuration reading phase
1212
1213 After starting, novaboot reads configuration files. Their content is
1214 described in section L</"CONFIGURATION FILE">. By default,
1215 configuration is read from two locations. First from the configuration
1216 directory and second from F<.novaboot> files along the path to the
1217 current directory. The latter read files override settings from the
1218 former ones.
1219
1220 Configuration directory is determined by the content of
1221 NOVABOOT_CONFIG_DIR environment variable and defaults to
1222 F</etc/novaboot.d>. Files in this directory with names consisting
1223 solely of English letters, numbers, dashes '-' and underscores '_'
1224 (note that dot '.' is not included) are read in alphabetical order.
1225
1226 Then novaboot searches for files named F<.novaboot> starting from the
1227 directory of the novaboot script (or working directory, see bellow)
1228 and continuing upwards up to the root directory. The found
1229 configuration files are then read in the opposite order (i.e. from the
1230 root directory downwards). This allows to have, for example, user
1231 specific configuration in F<~/.novaboot> and project specific one in
1232 F<~/project/.novaboot>.
1233
1234 In certain cases, the location of the novaboot script cannot be
1235 determined in this early phase. This happens either when the script is
1236 read from the standard input or when novaboot is invoked explicitly as
1237 in the example L</"4."> above. In this case the current working
1238 directory is used as a starting point for configuration file search
1239 instead of the novaboot script directory.
1240
1241 =over 8
1242
1243 =item -c, --config=I<filename>
1244
1245 Use the specified configuration file instead of the default one(s).
1246
1247 =back
1248
1249 =head2 Command line processing phase
1250
1251 =over 8
1252
1253 =item --dump-config
1254
1255 Dump the current configuration to stdout end exit. Useful as an
1256 initial template for a configuration file.
1257
1258 =item -h, --help
1259
1260 Print short (B<-h>) or long (B<--help>) help.
1261
1262 =item -t, --target=I<target>
1263
1264 This option serves as a user configurable shortcut for other novaboot
1265 options. The effect of this option is the same as the options stored
1266 in the C<%targets> configuration variable under key I<target>. See
1267 also L</"CONFIGURATION FILE">.
1268
1269 =back
1270
1271 =head2 Script preprocessing phase
1272
1273 This phases allows to modify the parsed novaboot script before it is
1274 used in the later phases.
1275
1276 =over 8
1277
1278 =item -a, --append=I<parameters>
1279
1280 Append a string to the first C<load> line in the novaboot script. This
1281 can be used to append parameters to the kernel's or root task's
1282 command line. This option can appear multiple times.
1283
1284 =item -b, --bender
1285
1286 Use F<bender> chainloader. Bender scans the PCI bus for PCI serial
1287 ports and stores the information about them in the BIOS data area for
1288 use by the kernel.
1289
1290 =item --chainloader=I<chainloader>
1291
1292 Specifies a chainloader that is loaded before the kernel and other
1293 files specified in the novaboot script. E.g. 'bin/boot/bender
1294 promisc'.
1295
1296 =item --dump
1297
1298 Print the modules to boot and their parameters after this phase
1299 finishes. Then exit. This is useful for seeing the effect of other
1300 options in this section.
1301
1302 =item -k, --kernel=F<file>
1303
1304 Replace the first word on the first C<load> line in the novaboot
1305 script with F<file>.
1306
1307 =item --scriptmod=I<perl expression>
1308
1309 When novaboot script is read, I<perl expression> is executed for every
1310 line (in $_ variable). For example, C<novaboot
1311 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1312 in the script with I<omega6>.
1313
1314 When this option is present, it overrides I<$script_modifier> variable
1315 from the configuration file, which has the same effect. If this option
1316 is given multiple times all expressions are evaluated in the command
1317 line order.
1318
1319 =back
1320
1321 =head2 File generation phase
1322
1323 In this phase, files needed for booting are generated in a so called
1324 I<build directory> (see L</--build-dir>). In most cases configuration
1325 for a bootloader is generated automatically by novaboot. It is also
1326 possible to generate other files using I<heredoc> or I<"<"> syntax in
1327 novaboot scripts. Finally, binaries can be generated in this phases by
1328 running C<scons> or C<make>.
1329
1330 =over 8
1331
1332 =item --build-dir=I<directory>
1333
1334 Overrides the default build directory location.
1335
1336 The default build directory location is determined as follows: If the
1337 configuration file defines the C<$builddir> variable, its value is
1338 used. Otherwise, it is the directory that contains the first processed
1339 novaboot script.
1340
1341 See also L</BUILDDIR> variable.
1342
1343 =item -g, --grub[=I<filename>]
1344
1345 Generates grub bootloader menu file. If the I<filename> is not
1346 specified, F<menu.lst> is used. The I<filename> is relative to the
1347 build directory (see B<--build-dir>).
1348
1349 =item --grub-preamble=I<prefix>
1350
1351 Specifies the I<preable> that is at the beginning of the generated
1352 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1353 timeout.
1354
1355 =item --prefix=I<prefix>
1356
1357 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1358 file name in generated bootloader configuration files (or in U-Boot
1359 commands).
1360
1361 If the I<prefix> contains string $NAME, it will be replaced with the
1362 name of the novaboot script (see also B<--name>).
1363
1364 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1365 the build directory (see also B<--build-dir>).
1366
1367 =item --grub-prefix
1368
1369 Alias for B<--prefix>.
1370
1371 =item --grub2[=I<filename>]
1372
1373 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1374 specified F<grub.cfg> is used. The content of the menu entry can be
1375 customized with B<--grub-preamble>, B<--grub2-prolog> or
1376 B<--grub_prefix> options.
1377
1378 In order to use the the generated menu entry on your development
1379 machine that uses GRUB2, append the following snippet to
1380 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1381 i.e. run update-grub on Debian/Ubuntu.
1382
1383   if [ -f /path/to/nul/build/grub.cfg ]; then
1384     source /path/to/nul/build/grub.cfg
1385   fi
1386
1387 =item --grub2-prolog=I<prolog>
1388
1389 Specifies text that is put at the beginning of the GRUB2 menu entry.
1390
1391 =item -m, --make[=make command]
1392
1393 Runs C<make> to build files that are not generated by novaboot itself.
1394
1395 =item --name=I<string>
1396
1397 Use the name I<string> instead of the name of the novaboot script.
1398 This name is used for things like a title of grub menu or for the
1399 server directory where the boot files are copied to.
1400
1401 =item --no-file-gen
1402
1403 Do not run external commands to generate files (i.e. "<" syntax and
1404 C<run> keyword). This switch does not influence generation of files
1405 specified with "<<WORD" syntax.
1406
1407 =item -p, --pulsar[=mac]
1408
1409 Generates pulsar bootloader configuration file named F<config-I<mac>>
1410 The I<mac> string is typically a MAC address and defaults to
1411 I<novaboot>.
1412
1413 =item --scons[=scons command]
1414
1415 Runs C<scons> to build files that are not generated by novaboot
1416 itself.
1417
1418 =item --strip-rom
1419
1420 Strip I<rom://> prefix from command lines and generated config files.
1421 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1422
1423 =item --gen-only
1424
1425 Exit novaboot after file generation phase.
1426
1427 =back
1428
1429 =head2 Target connection check
1430
1431 If supported by the target, the connection to it is made and it is
1432 checked whether the target is not occupied by another novaboot
1433 user/instance.
1434
1435 =over 8
1436
1437 =item --amt=I<"[user[:password]@]host[:port]>
1438
1439 Use Intel AMT technology to control the target machine. WS management
1440 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1441 The hostname or (IP address) is given by the I<host> parameter. If
1442 I<password> is not specified, environment variable AMT_PASSWORD is
1443 used. The I<port> specifies a TCP port for SOL. If not specified, the
1444 default is 16992. Default I<user> is admin.
1445
1446 =item --iprelay=I<addr[:port]>
1447
1448 Use TCP/IP relay and serial port to access the target's serial port
1449 and powercycle it. The IP address of the relay is given by I<addr>
1450 parameter. If I<port> is not specified, it default to 23.
1451
1452 Note: This option is supposed to work with HWG-ER02a IP relays.
1453
1454 =item -s, --serial[=device]
1455
1456 Target's serial line is connected to host's serial line (device). The
1457 default value for device is F</dev/ttyUSB0>.
1458
1459 The value of this option is exported in NB_NOVABOOT environment
1460 variable to all subprocesses run by C<novaboot>.
1461
1462 =item --stty=I<settings>
1463
1464 Specifies settings passed to C<stty> invoked on the serial line
1465 specified with B<--serial> option. If this option is not given,
1466 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1467
1468 =item --remote-cmd=I<cmd>
1469
1470 Command that mediates connection to the target's serial line. For
1471 example C<ssh server 'cu -l /dev/ttyS0'>.
1472
1473 =item --remote-expect=I<string>
1474
1475 Wait for reception of I<string> after establishing the the remote
1476 connection before continuing.
1477
1478
1479 =back
1480
1481 =head2 File deployment phase
1482
1483 In some setups, it is necessary to copy the files needed for booting
1484 to a particular location, e.g. to a TFTP boot server or to the
1485 F</boot> partition.
1486
1487 =over 8
1488
1489 =item -d, --dhcp-tftp
1490
1491 Turns your workstation into a DHCP and TFTP server so that the OS can
1492 be booted via PXE BIOS (or similar mechanism) on the test machine
1493 directly connected by a plain Ethernet cable to your workstation.
1494
1495 The DHCP and TFTP servers requires root privileges and C<novaboot>
1496 uses C<sudo> command to obtain those. You can put the following to
1497 I</etc/sudoers> to allow running the necessary commands without asking
1498 for password.
1499
1500  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1501  your_login ALL=NOPASSWD: NOVABOOT
1502
1503 =item --tftp
1504
1505 Starts a TFTP server on your workstation. This is similar to
1506 B<--dhcp-tftp> except that DHCP server is not started.
1507
1508 The TFTP server require root privileges and C<novaboot> uses C<sudo>
1509 command to obtain those. You can put the following to I</etc/sudoers>
1510 to allow running the necessary commands without asking for password.
1511
1512  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1513  your_login ALL=NOPASSWD: NOVABOOT
1514
1515 =item --tftp-port=I<port>
1516
1517 Port to run the TFTP server on. Implies B<--tftp>.
1518
1519 =item --iso[=filename]
1520
1521 Generates the ISO image that boots NOVA system via GRUB. If no filename
1522 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1523 of the novaboot script (see also B<--name>).
1524
1525 =item --server[=[[user@]server:]path]
1526
1527 Copy all files needed for booting to another location. The files will
1528 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1529 contains string $NAME, it will be replaced with the name of the
1530 novaboot script (see also B<--name>).
1531
1532 =item --rsync-flags=I<flags>
1533
1534 Specifies which I<flags> are appended to F<rsync> command line when
1535 copying files as a result of I<--server> option.
1536
1537 =item --concat
1538
1539 If B<--server> is used and its value ends with $NAME, then after
1540 copying the files, a new bootloader configuration file (e.g. menu.lst)
1541 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1542 with $NAME part removed. The content of the file is created by
1543 concatenating all files of the same name from all subdirectories of
1544 I<path-wo-name> found on the "server".
1545
1546 =item --ider
1547
1548 Use Intel AMT technology for IDE redirection. This allows the target
1549 machine to boot from novaboot created ISO image. Implies B<--iso>.
1550
1551 The experimental C<amtider> utility needed by this option can be
1552 obtained from https://github.com/wentasah/amtterm.
1553
1554 =back
1555
1556 =head2 Target power-on and reset phase
1557
1558 At this point, the target is reset (or switched on/off). There is
1559 several ways how this can be accomplished. Resetting a physical target
1560 can currently be accomplished by the following options: B<--amt>,
1561 B<--iprelay>, B<--reset-cmd>.
1562
1563 =over 8
1564
1565 =item --on, --off
1566
1567 Switch on/off the target machine and exit. The script (if any) is
1568 completely ignored. Currently it works only with B<--iprelay> or
1569 B<--amt>.
1570
1571 =item -Q, --qemu[=I<qemu-binary>]
1572
1573 Boot the configuration in qemu. Optionally, the name of qemu binary
1574 can be specified as a parameter.
1575
1576 =item --qemu-append=I<flags>
1577
1578 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1579 C<-cpu coreduo -smp 2>).
1580
1581 =item -q, --qemu-flags=I<flags>
1582
1583 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1584 -smp 2>) with I<flags> specified here.
1585
1586 =item --reset-cmd=I<cmd>
1587
1588 Command that resets the target.
1589
1590 =item --no-reset, --reset
1591
1592 Disable/enable reseting of the target.
1593
1594 =back
1595
1596 =head2 Interaction with the bootloader on the target
1597
1598 =over 8
1599
1600 =item --uboot[=I<prompt>]
1601
1602 Interact with U-Boot bootloader to boot the thing described in the
1603 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1604 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1605 Implementation of this option is currently tied to a particular board
1606 that we use. It may be subject to changes in the future!
1607
1608 =item --uboot-init
1609
1610 Command(s) to send the U-Boot bootloader before loading the images and
1611 booting them. This option can be given multiple times. After sending
1612 commands from each option novaboot waits for U-Boot I<prompt>.
1613
1614 If the command contains string I<$NB_MYIP> then this string is
1615 replaced by IPv4 address of eth0 interface. Similarly I<$NB_PREFIX> is
1616 replaced with prefix given by B<--prefix>.
1617
1618 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
1619
1620 =item --uboot-addr I<name>=I<address>
1621
1622 Load address of U-Boot's C<tftpboot> command for loading I<name>,
1623 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
1624 tree).
1625
1626 =back
1627
1628 =head2 Target interaction phase
1629
1630 In this phase, target's serial output is redirected to stdout and if
1631 stdin is a TTY, it is redirected to the target's serial input allowing
1632 interactive work with the target.
1633
1634 =over 8
1635
1636 =item --exiton=I<string>
1637
1638 When I<string> is sent by the target, novaboot exits. This option can
1639 be specified multiple times, in which case novaboot exits whenever
1640 either of the specified strings is sent.
1641
1642 If I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1643 treated as regular expression. For example:
1644
1645     --exiton -re --exiton 'error:.*failed'
1646
1647 =item --exiton-re=I<regex>
1648
1649 The same as --exiton -re --exiton I<regex>.
1650
1651 =item --exiton-timeout=I<seconds>
1652
1653 By default B<--exiton> waits for the string match forever. When this
1654 option is specified, "exiton" timeouts after the specifies number of
1655 seconds and novaboot returns non-zero exit code.
1656
1657 =item -i, --interactive
1658
1659 Setup things for interactive use of target. Your terminal will be
1660 switched to raw mode. In raw mode, your system does not process input
1661 in any way (no echoing of entered characters, no interpretation
1662 special characters). This, among others, means that Ctrl-C is passed
1663 to the target and does no longer interrupt novaboot. Use "~~."
1664 sequence to exit novaboot.
1665
1666 =item --expect=I<string>
1667
1668 When I<string> is received from the target, send the string specified
1669 with the subsequent B<--send*> option to the target.
1670
1671 =item --expect-re=I<regex>
1672
1673 When target's output matches regular expression I<regex>, send the
1674 string specified with the subsequent B<--send*> option to the target.
1675
1676 =item --expect-raw=I<perl-code>
1677
1678 Provides direct control over Perl's Expect module.
1679
1680 =item --send=I<string>
1681
1682 Send I<string> to the target after the previously specified
1683 B<--expect*> was matched in the target's output. The I<string> may
1684 contain escape sequences such as "\n".
1685
1686 Note that I<string> is actually interpreted by Perl, so it can contain
1687 much more that escape sequences. This behavior may change in the
1688 future.
1689
1690 Example: C<--expect='login: ' --send='root\n'>
1691
1692 =item --sendcont=I<string>
1693
1694 Similar to B<--send> but continue expecting more input.
1695
1696 Example: C<--expect='Continue?' --sendcont='yes\n'>
1697
1698 =back
1699
1700 =head1 NOVABOOT SCRIPT SYNTAX
1701
1702 The syntax tries to mimic POSIX shell syntax. The syntax is defined
1703 with the following rules.
1704
1705 Lines starting with "#" and empty lines are ignored.
1706
1707 Lines that end with "\" are concatenated with the following line after
1708 removal of the final "\" and leading whitespace of the following line.
1709
1710 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1711 expression) assign values to internal variables. See L</VARIABLES>
1712 section.
1713
1714 Lines starting with C<load> keyword represent modules to boot. The
1715 word after C<load> is a file name (relative to the build directory
1716 (see B<--build-dir>) of the module to load and the remaining words are
1717 passed to it as the command line parameters.
1718
1719 When the C<load> line ends with "<<WORD" then the subsequent lines
1720 until the line containing solely WORD are copied literally to the file
1721 named on that line. This is similar to shell's heredoc feature.
1722
1723 When the C<load> line ends with "< CMD" then command CMD is executed
1724 with F</bin/sh> and its standard output is stored in the file named on
1725 that line. The SRCDIR variable in CMD's environment is set to the
1726 absolute path of the directory containing the interpreted novaboot
1727 script.
1728
1729 Lines starting with C<run> keyword contain shell commands that are run
1730 during file generation phase. This is the same as the "< CMD" syntax
1731 for C<load> keyboard except that the command's output is not
1732 redirected to a file. The ordering of commands is the same as they
1733 appear in the novaboot script.
1734
1735 Lines starting with C<uboot> represent U-Boot commands that are sent
1736 to the target if B<--uboot> option is given. Having a U-Boot line in
1737 the novaboot script is the same as passing an equivalent
1738 B<--uboot-init> option to novaboot. The C<uboot> keyword can be
1739 suffixed with timeout specification. The syntax is C<uboot:Ns>, where
1740 C<N> is the whole number of seconds. If the U-Boot command prompt does
1741 not appear before the timeout, novaboot fails. The default timeout is
1742 10 seconds.
1743
1744 Example (Linux):
1745
1746   #!/usr/bin/env novaboot
1747   load bzImage console=ttyS0,115200
1748   run  make -C buildroot
1749   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
1750
1751 Example (NOVA User Land - NUL):
1752
1753   #!/usr/bin/env novaboot
1754   WVDESC=Example program
1755   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
1756                            verbose hostkeyb:0,0x60,1,12,2
1757   load bin/apps/hello.nul
1758   load hello.nulconfig <<EOF
1759   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
1760   rom://bin/apps/hello.nul
1761   EOF
1762
1763 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
1764 F<hello.nulconfig>. sigma0 receives some command line parameters and
1765 F<hello.nulconfig> file is generated on the fly from the lines between
1766 C<<<EOF> and C<EOF>.
1767
1768 =head2 VARIABLES
1769
1770 The following variables are interpreted in the novaboot script:
1771
1772 =over 8
1773
1774 =item BUILDDIR
1775
1776 Novaboot chdir()s to this directory before file generation phase. The
1777 directory name specified here is relative to the build directory
1778 specified by other means (see L</--build-dir>).
1779
1780 =item EXITON
1781
1782 Assigning this variable has the same effect as specifying L</--exiton>
1783 option.
1784
1785 =item HYPERVISOR_PARAMS
1786
1787 Parameters passed to hypervisor. The default value is "serial", unless
1788 overridden in configuration file.
1789
1790 =item KERNEL
1791
1792 The kernel to use instead of the hypervisor specified in the
1793 configuration file with the C<$hypervisor> variable. The value should
1794 contain the name of the kernel image as well as its command line
1795 parameters. If this variable is defined and non-empty, the variable
1796 HYPERVISOR_PARAMS is not used.
1797
1798 =item NO_BOOT
1799
1800 If this variable is 1, the system is not booted. This is currently
1801 only implemented for U-Boot bootloader where it is useful for
1802 interacting with the bootloader without booting the system - e.g. for
1803 flashing.
1804
1805 =item QEMU
1806
1807 Use a specific qemu binary (can be overridden with B<-Q>) and flags
1808 when booting this script under qemu. If QEMU_FLAGS variable is also
1809 specified flags specified in QEMU variable are replaced by those in
1810 QEMU_FLAGS.
1811
1812 =item QEMU_FLAGS
1813
1814 Use specific qemu flags (can be overridden with B<-q>).
1815
1816 =item WVDESC
1817
1818 Description of the WvTest-compliant program.
1819
1820 =item WVTEST_TIMEOUT
1821
1822 The timeout in seconds for WvTest harness. If no complete line appears
1823 in the test output within the time specified here, the test fails. It
1824 is necessary to specify this for long running tests that produce no
1825 intermediate output.
1826
1827 =back
1828
1829 =head1 CONFIGURATION FILE
1830
1831 Novaboot can read its configuration from one or more files. By
1832 default, novaboot looks for files in F</etc/novaboot.d> and files
1833 named F<.novaboot> as described in L</Configuration reading phase>.
1834 Alternatively, configuration file location can be specified with the
1835 B<-c> switch or with the NOVABOOT_CONFIG environment variable. The
1836 configuration file has Perl syntax (i.e. it is better to put C<1;> as
1837 a last line) and should set values of certain Perl variables. The
1838 current configuration can be dumped with the B<--dump-config> switch.
1839 Some configuration variables can be overridden by environment
1840 variables (see below) or by command line switches.
1841
1842 Supported configuration variables include:
1843
1844 =over 8
1845
1846 =item $builddir
1847
1848 Build directory location relative to the location of the configuration
1849 file.
1850
1851 =item $default_target
1852
1853 Default target (see below) to use when no target is explicitly
1854 specified on command line with the B<--target> option.
1855
1856 =item %targets
1857
1858 Hash of target definitions to be used with the B<--target> option. The
1859 key is the identifier of the target, the value is the string with
1860 command line options. For instance, if the configuration file contains:
1861
1862  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
1863
1864 then the following two commands are equivalent:
1865
1866  ./myos --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
1867  ./myos -t mybox
1868
1869 =back
1870
1871 =head1 ENVIRONMENT VARIABLES
1872
1873 Some options can be specified not only via config file or command line
1874 but also through environment variables. Environment variables override
1875 the values from configuration file and command line parameters
1876 override the environment variables.
1877
1878 =over 8
1879
1880 =item NOVABOOT_CONFIG
1881
1882 Name of the novaboot configuration file to use instead of the default
1883 one(s).
1884
1885 =item NOVABOOT_CONFIG_DIR
1886
1887 Name of the novaboot configuration directory. When not specified
1888 F</etc/novaboot.d> is used.
1889
1890 =item NOVABOOT_BENDER
1891
1892 Defining this variable has the same meaning as B<--bender> option.
1893
1894 =back
1895
1896 =head1 AUTHORS
1897
1898 Michal Sojka <sojka@os.inf.tu-dresden.de>
1899
1900 =cut
1901
1902 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
1903 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
1904 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
1905 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest