novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use IO::Handle;
  26 use Time::HiRes("usleep");
  27 use Socket;
  28 use FileHandle;
  29 use IPC::Open2;
  30 use POSIX qw(:errno_h sysconf);
  31 use Cwd qw(getcwd abs_path);
  32 use Expect;
  33
  34 # always flush
  35 $| = 1;
  36
  37 my $invocation_dir = $ENV{PWD} || getcwd();
  38
  39 ## Configuration file handling
  40
  41 # Default configuration
  42 $CFG::hypervisor = "";
  43 $CFG::hypervisor_params = "serial";
  44 $CFG::genisoimage = "genisoimage";
  45 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  46 $CFG::default_target = '';
  47 %CFG::targets = (
  48     'qemu' => '--qemu',
  49     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  50     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.87.159:2324',
  51     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  52     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  53     "ryuglab" => '--target ryu --server=pc-sojkam.felk.cvut.cz:/srv/tftp --remote-cmd="ssh -tt pc-sojkam.felk.cvut.cz \"sterm -d -s 115200 /dev/ttyUSB0\""',
  54     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  55     );
  56
  57 {
  58     my %const;
  59     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  60     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  61
  62     $CFG::scons = "scons -j$nproc";
  63     $CFG::make = "make -j$nproc";
  64 }
  65
  66 my $builddir;
  67
  68 sub read_config($) {
  69     my ($cfg) = @_;
  70     {
  71         package CFG; # Put config data into a separate namespace
  72
  73         my $rc = do($cfg);
  74
  75         # Check for errors
  76         if ($@) {
  77             die("ERROR: Failure compiling '$cfg' - $@");
  78         } elsif (! defined($rc)) {
  79             die("ERROR: Failure reading '$cfg' - $!");
  80         } elsif (! $rc) {
  81             die("ERROR: Failure processing '$cfg'");
  82         }
  83     }
  84     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  85     print STDERR "novaboot: Read $cfg\n";
  86 }
  87
  88 my @cfgs;
  89 {
  90     # We don't use $0 here, because it points to the novaboot itself and
  91     # not to the novaboot script. The problem with this approach is that
  92     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  93     # contains the first option. Hence the -f check.
  94     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  95     while ((-d $dir || -l $dir ) && $dir ne "/") {
  96         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  97         my @dirs = File::Spec->splitdir($dir);
  98         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  99     }
 100     @cfgs = reverse @cfgs;
 101
 102     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 103     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 104
 105     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 106     if (opendir(my $dh, $dir)) {
 107         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 108         closedir $dh;
 109         @etccfg = sort(@etccfg);
 110         @cfgs = ( @etccfg, @cfgs );
 111     }
 112 }
 113 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 114 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 115 GetOptions ("config|c=s" => \$cfg);
 116 read_config($_) foreach $cfg or @cfgs;
 117
 118 ## Command line handling
 119
 120 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 121 GetOptions ("target|t=s" => \$explicit_target);
 122
 123 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $final_eol, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iso_image, $interactive, $kernel_opt, $make, $man, $netif, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $remote_expect_silent, $reset, $reset_cmd, $reset_send, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init);
 124
 125 # Default values of certain command line options
 126 %uboot_addr = (
 127     'kernel'  => '${kernel_addr_r}',
 128     'ramdisk' => '${ramdisk_addr_r}',
 129     'fdt'     => '${fdt_addr_r}',
 130     );
 131 $rsync_flags = '';
 132 $rom_prefix = 'rom://';
 133 $stty = 'raw -crtscts -onlcr 115200';
 134 $reset = 1;                     # Reset target by default
 135 $interaction = 1;               # Perform target interaction by default
 136 $final_eol = 1;
 137 $netif = 'eth0';
 138
 139 my @expect_seen = ();
 140 sub handle_expect
 141 {
 142     my ($n, $v) = @_;
 143     push(@expect_seen, '-re') if $n eq "expect-re";
 144     push(@expect_seen, $v);
 145 }
 146
 147 sub handle_send
 148 {
 149     my ($n, $v) = @_;
 150     unless (@expect_seen) { die("No --expect before --send"); }
 151     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 152     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 153     unshift(@expect_raw, @expect_seen);
 154     @expect_seen = ();
 155 }
 156
 157 my %opt_spec;
 158 %opt_spec = (
 159     "amt=s"          => \$amt,
 160     "append|a=s"     => \@append,
 161     "bender|b"       => \$bender,
 162     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 163     "concat"         => \$concat,
 164     "chainloader=s"  => \@chainloaders,
 165     "dhcp-tftp|d"    => \$dhcp_tftp,
 166     "dump"           => \$dump_opt,
 167     "dump-config"    => \$dump_config,
 168     "exiton=s"       => \@exiton,
 169     "exiton-timeout=i"=> \$exiton_timeout,
 170     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 171     "expect=s"       => \&handle_expect,
 172     "expect-re=s"    => \&handle_expect,
 173     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 174     "final-eol!"     => \$final_eol,
 175     "gen-only"       => \$gen_only,
 176     "grub|g:s"       => \$grub_config,
 177     "grub-preamble=s"=> \$grub_preamble,
 178     "prefix|grub-prefix=s" => \$grub_prefix,
 179     "grub2:s"        => \$grub2_config,
 180     "grub2-prolog=s" => \$grub2_prolog,
 181     "ider"           => \$ider,
 182     "interaction!"   => \$interaction,
 183     "iprelay=s"      => \$iprelay,
 184     "iso:s"          => \$iso_image,
 185     "kernel|k=s"     => \$kernel_opt,
 186     "interactive|i"  => \$interactive,
 187     "name=s"         => \$config_name_opt,
 188     "make|m:s"       => \$make,
 189     "netif=s"        => \$netif,
 190     "no-file-gen"    => \$no_file_gen,
 191     "off"            => \$off_opt,
 192     "on"             => \$on_opt,
 193     "pulsar|p:s"     => \$pulsar,
 194     "pulsar-root=s"  => \$pulsar_root,
 195     "qemu|Q:s"       => \$qemu,
 196     "qemu-append=s"  => \$qemu_append,
 197     "qemu-flags|q=s" => \$qemu_flags_cmd,
 198     "remote-cmd=s"   => \$remote_cmd,
 199     "remote-expect=s"=> \$remote_expect,
 200     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 201     "reset!"         => \$reset,
 202     "reset-cmd=s"    => \$reset_cmd,
 203     "reset-send=s"   => \$reset_send,
 204     "rsync-flags=s"  => \$rsync_flags,
 205     "scons:s"        => \$scons,
 206     "scriptmod=s"    => \@scriptmod,
 207     "send=s"         => \&handle_send,
 208     "sendcont=s"     => \&handle_send,
 209     "serial|s:s"     => \$serial,
 210     "server:s"       => \$server,
 211     "strip-rom"      => sub { $rom_prefix = ''; },
 212     "stty=s"         => \$stty,
 213     "tftp"           => \$tftp,
 214     "tftp-port=i"    => \$tftp_port,
 215     "uboot:s"        => \$uboot,
 216     "no-uboot"       => sub { undef $uboot; },
 217     "uboot-addr=s"   => \%uboot_addr,
 218     "uboot-cmd=s"    => \$uboot_cmd,
 219     "uboot-init=s"   => sub { push @uboot_init, { command => $_[1] }; },
 220     "h"              => \$help,
 221     "help"           => \$man,
 222     );
 223
 224 # First process target options
 225 {
 226     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 227     my @target_expanded;
 228     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 229     while ($t) {
 230         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 231
 232         undef $explicit_target;
 233         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 234         if (!$ret) { die "Error parsing target $t option"; }
 235         push(@target_expanded, @$remaining_args);
 236         $t = $explicit_target;
 237     }
 238
 239     (undef, my @args) = @ARGV;
 240     @args = (@target_expanded, @args);
 241     print STDERR "novaboot: Effective options: @args\n";
 242
 243     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 244     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 245 }
 246
 247 # Then process other command line options - some of them may override
 248 # what was specified by the target
 249 GetOptions %opt_spec or die("Error in command line arguments");
 250 pod2usage(1) if $help;
 251 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 252
 253 ### Dump sanitized configuration (if requested)
 254
 255 if ($dump_config) {
 256     use Data::Dumper;
 257     $Data::Dumper::Indent=1;
 258     print "# This file is in perl syntax.\n";
 259     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 260         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 261         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 262         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 263     }
 264     print "1;\n";
 265     exit;
 266 }
 267
 268 ### Sanitize configuration
 269
 270 if ($interactive && !-t STDIN) {
 271     die("novaboot: Interactive mode not supported when not on terminal");
 272 }
 273
 274 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 275
 276 if ($ider) {
 277     $iso_image //= ''; # IDE-R needs an ISO image
 278     if (!defined $amt) { die "Error: --ider requires --amt"; }
 279 }
 280
 281 {
 282     my %input_opts = ('--iprelay'    => \$iprelay,
 283                       '--serial'     => \$serial,
 284                       '--remote-cmd' => \$remote_cmd,
 285                       '--amt'        => \$amt);
 286     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 287
 288     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 289 }
 290
 291 # Default options
 292 if (defined $serial) {
 293     $serial ||= "/dev/ttyUSB0";
 294     $ENV{NB_SERIAL} = $serial;
 295 }
 296 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 297 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 298
 299 ## Parse the novaboot script(s)
 300 my @scripts;
 301 my $file;
 302 my $EOF;
 303 my $last_fn = '';
 304 my ($modules, $variables, $generated, $copy, $chainload, $continuation) = ([], {}, [], []);
 305 my $skip_reading = defined($on_opt) || defined($off_opt);
 306 while (!$skip_reading && ($_ = <>)) {
 307     if ($ARGV ne $last_fn) { # New script
 308         die "Missing EOF in $last_fn" if $file;
 309         die "Unfinished line in $last_fn" if $continuation;
 310         $last_fn = $ARGV;
 311         push @scripts, { 'filename' => $ARGV,
 312                          'modules' => $modules = [],
 313                          'variables' => $variables = {},
 314                          'generated' => $generated = [],
 315                          'copy' => $copy = [],
 316                          'chainload' => $chainload = [],
 317         };
 318
 319     }
 320     chomp();
 321     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 322
 323     $_ =~ s/^[[:space:]]*// if ($continuation);
 324
 325     if (/\\$/) {                # Line continuation
 326         $continuation .= substr($_, 0, length($_)-1);
 327         next;
 328     }
 329
 330     if ($continuation) {        # Last continuation line
 331         $_ = $continuation . $_;
 332         $continuation = '';
 333     }
 334
 335     foreach my $mod(@scriptmod) { eval $mod; }
 336
 337     if ($file && $_ eq $EOF) {  # Heredoc end
 338         undef $file;
 339         next;
 340     }
 341     if ($file) {                # Heredoc content
 342         push @{$file}, "$_\n";
 343         next;
 344     }
 345     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 346         $$variables{$1} = $2;
 347         push(@exiton, $2) if ($1 eq "EXITON");
 348         next;
 349     }
 350     sub process_load_copy($) {
 351         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 352         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 353             $file = [];
 354             push @$generated, {filename => $1, content => $file};
 355             $EOF = $3;
 356             return "$1$2";
 357         }
 358         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 359             push @$generated, {filename => $1, command => $3};
 360             return "$1$2";
 361         }
 362         return $_;
 363     }
 364     if (s/^load *//) {          # Load line
 365         push @$modules, process_load_copy($_);
 366         next;
 367     }
 368     if (s/^copy *//) {          # Copy line
 369         push @$copy, process_load_copy($_);
 370         next;
 371     }
 372     if (s/^chld *//) {          # Chainload line
 373         push @$chainload, process_load_copy($_);
 374         next;
 375     }
 376     if (/^run (.*)/) {          # run line
 377         push @$generated, {command => $1};
 378         next;
 379     }
 380     if (/^uboot(?::([0-9]+)s)? +(< *)?(.*)/) {  # uboot line
 381         # TODO: If U-Boot supports some interactive menu, it might
 382         # make sense to store uboot lines per novaboot script.
 383         my ($timeout, $redir, $string, $dest) = ($1, $2, $3);
 384         if ($string =~ /(.*) *> *(.*)/) {
 385             $string = $1;
 386             $dest = $2;
 387         }
 388         push @uboot_init, { command => $redir ? "" : $string,
 389                             system =>  $redir ? $string : "",
 390                             timeout => $timeout,
 391                             dest => $dest,
 392         };
 393         next;
 394     }
 395
 396     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 397 }
 398 # use Data::Dumper;
 399 # print Dumper(\@scripts);
 400
 401 foreach my $script (@scripts) {
 402     $modules = $$script{modules};
 403     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 404     @$modules[0] .= ' ' . join(' ', @append) if @append;
 405
 406     my $kernel;
 407     if (exists $variables->{KERNEL}) {
 408         $kernel = $variables->{KERNEL};
 409     } else {
 410         if ($CFG::hypervisor) {
 411             $kernel = $CFG::hypervisor . " ";
 412             if (exists $variables->{HYPERVISOR_PARAMS}) {
 413                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 414             } else {
 415                 $kernel .= $CFG::hypervisor_params;
 416             }
 417         }
 418     }
 419     @$modules = ($kernel, @$modules) if $kernel;
 420     @$modules = (@chainloaders, @$modules);
 421     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 422 }
 423
 424 if ($dump_opt) {
 425     foreach my $script (@scripts) {
 426         print join("\n", @{$$script{modules}})."\n";
 427     }
 428     exit(0);
 429 }
 430
 431 ## Helper functions
 432
 433 sub generate_configs($$$) {
 434     my ($base, $generated, $filename) = @_;
 435     if ($base) { $base = "$base/"; };
 436     foreach my $g(@$generated) {
 437       if (exists $$g{content}) {
 438         my $config = $$g{content};
 439         my $fn = $$g{filename};
 440         open(my $f, '>', $fn) || die("$fn: $!");
 441         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 442         close($f);
 443         print STDERR "novaboot: Created $fn\n";
 444       } elsif (exists $$g{command} && ! $no_file_gen) {
 445         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 446         if (exists $$g{filename}) {
 447             system_verbose("( $$g{command} ) > $$g{filename}");
 448         } else {
 449             system_verbose($$g{command});
 450         }
 451       }
 452     }
 453 }
 454
 455 sub generate_grub_config($$$$;$)
 456 {
 457     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 458     if ($base) { $base = "$base/"; };
 459     open(my $fg, '>', $filename) or die "$filename: $!";
 460     print $fg "$preamble\n" if $preamble;
 461     print $fg "title $title\n" if $title;
 462     #print $fg "root $base\n"; # root doesn't really work for (nd)
 463     my $first = 1;
 464     foreach (@$modules_ref) {
 465         if ($first) {
 466             $first = 0;
 467             my ($kbin, $kcmd) = split(' ', $_, 2);
 468             $kcmd = '' if !defined $kcmd;
 469             print $fg "kernel ${base}$kbin $kcmd\n";
 470         } else {
 471             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 472             print $fg "module $base$_\n";
 473         }
 474     }
 475     close($fg);
 476     print("novaboot: Created $builddir/$filename\n");
 477     return $filename;
 478 }
 479
 480 sub generate_syslinux_config($$$$)
 481 {
 482     my ($filename, $title, $base, $modules_ref) = @_;
 483     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 484     open(my $fg, '>', $filename) or die "$filename: $!";
 485     print $fg "LABEL $title\n";
 486     #TODO print $fg "MENU LABEL $human_readable_title\n";
 487
 488     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 489
 490     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 491         my $initrd = @$modules_ref[1];
 492         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 493         print $fg "LINUX $base$kbin\n";
 494         print $fg "APPEND $kcmd\n";
 495         print $fg "INITRD $base$initrd\n";
 496     } else {
 497         print $fg "KERNEL mboot.c32\n";
 498         my @append;
 499         foreach (@$modules_ref) {
 500             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 501             push @append, "$base$_";
 502             print $fg "APPEND ".join(' --- ', @append)."\n";
 503         }
 504     }
 505     #TODO print $fg "TEXT HELP\n";
 506     #TODO print $fg "some help here\n";
 507     #TODO print $fg "ENDTEXT\n";
 508     close($fg);
 509     print("novaboot: Created $builddir/$filename\n");
 510     return $filename;
 511 }
 512
 513 sub generate_grub2_config($$$$;$$)
 514 {
 515     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 516     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 517     open(my $fg, '>', $filename) or die "$filename: $!";
 518     print $fg "$preamble\n" if $preamble;
 519     $title ||= 'novaboot';
 520     print $fg "menuentry $title {\n";
 521     print $fg "$prolog\n" if $prolog;
 522     my $first = 1;
 523     foreach (@$modules_ref) {
 524         if ($first) {
 525             $first = 0;
 526             my ($kbin, $kcmd) = split(' ', $_, 2);
 527             $kcmd = '' if !defined $kcmd;
 528             print $fg "  multiboot ${base}$kbin $kcmd\n";
 529         } else {
 530             my @args = split;
 531             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 532             $_ = join(' ', ($args[0], @args));
 533             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 534             print $fg "  module $base$_\n";
 535         }
 536     }
 537     print $fg "}\n";
 538     close($fg);
 539     print("novaboot: Created $builddir/$filename\n");
 540     return $filename;
 541 }
 542
 543 sub generate_pulsar_config($$$)
 544 {
 545     my ($filename, $modules_ref, $chainload_ref) = @_;
 546     open(my $fg, '>', $filename) or die "$filename: $!";
 547     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 548     if (scalar(@$chainload_ref) > 0) {
 549         print $fg "chld $$chainload_ref[0]\n";
 550     } else {
 551         my $first = 1;
 552         my ($kbin, $kcmd);
 553         foreach (@$modules_ref) {
 554             if ($first) {
 555                 $first = 0;
 556                 ($kbin, $kcmd) = split(' ', $_, 2);
 557                 $kcmd = '' if !defined $kcmd;
 558             } else {
 559                 my @args = split;
 560                 s|\brom://|$rom_prefix|g;
 561                 print $fg "load $_\n";
 562             }
 563         }
 564         # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 565         print $fg "exec $kbin $kcmd\n";
 566     }
 567     close($fg);
 568     print("novaboot: Created $builddir/$filename\n");
 569     return $filename;
 570 }
 571
 572 sub shell_cmd_string(@)
 573 {
 574     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 575 }
 576
 577 sub exec_verbose(@)
 578 {
 579     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 580     exec(@_);
 581     exit(1); # should not be reached
 582 }
 583
 584 sub system_verbose($)
 585 {
 586     my $cmd = shift;
 587     print STDERR "novaboot: Running: $cmd\n";
 588     my $ret = system($cmd);
 589     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 590     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 591     if ($ret) { die("Command failure $ret"); }
 592 }
 593
 594 sub trim($) {
 595     my ($str) = @_;
 596     $str =~ s/^\s+|\s+$//g;
 597     return $str
 598 }
 599
 600 ## WvTest headline
 601
 602 if (exists $variables->{WVDESC}) {
 603     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 604 } elsif ($last_fn =~ /\.wv$/) {
 605     print STDERR "Testing \"all\" in $last_fn:\n";
 606 }
 607
 608 ## Connect to the target and check whether it is not occupied
 609
 610 # We have to do this before file generation phase, because file
 611 # generation is intermixed with file deployment phase and we want to
 612 # check whether the target is not used by somebody else before
 613 # deploying files. Otherwise, we may rewrite other user's files on a
 614 # boot server.
 615
 616 my $exp; # Expect object to communicate with the target over serial line
 617
 618 my ($target_reset, $target_power_on, $target_power_off);
 619 my ($amt_user, $amt_password, $amt_host, $amt_port);
 620
 621 if (defined $iprelay) {
 622     my $IPRELAY;
 623     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 624     my $addr = $1;
 625     my $port = $3 || 23;
 626     my $paddr   = sockaddr_in($port, inet_aton($addr));
 627     my $proto   = getprotobyname('tcp');
 628     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 629     print STDERR "novaboot: Connecting to IP relay... ";
 630     connect($IPRELAY, $paddr)    || die "connect: $!";
 631     print STDERR "done\n";
 632     $exp = Expect->init(\*$IPRELAY);
 633     $exp->log_stdout(1);
 634
 635     while (1) {
 636         print $exp "\xFF\xF6";  # AYT
 637         my $connected = $exp->expect(20, # Timeout in seconds
 638                                      '<iprelayd: connected>',
 639                                      '-re', '<WEB51 HW[^>]*>');
 640         last if $connected;
 641     }
 642
 643     sub relaycmd($$) {
 644         my ($relay, $onoff) = @_;
 645         die unless ($relay == 1 || $relay == 2);
 646
 647         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 648         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 649     }
 650
 651     sub relayconf($$) {
 652         my ($relay, $onoff) = @_;
 653         die unless ($relay == 1 || $relay == 2);
 654         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 655         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 656     }
 657
 658     sub relay($$;$) {
 659         my ($relay, $onoff, $can_giveup) = @_;
 660         my $confirmation = '';
 661         $exp->log_stdout(0);
 662         print $exp relaycmd($relay, $onoff);
 663         my $confirmed = $exp->expect(20, # Timeout in seconds
 664                                      relayconf($relay, $onoff));
 665         if (!$confirmed) {
 666             if ($can_giveup) {
 667                 print("Relay confirmation timeout - ignoring\n");
 668             } else {
 669                 die "Relay confirmation timeout";
 670             }
 671         }
 672         $exp->log_stdout(1);
 673     }
 674
 675     $target_reset = sub {
 676         relay(2, 1, 1); # Reset the machine
 677         usleep(100000);
 678         relay(2, 0);
 679     };
 680
 681     $target_power_off = sub {
 682         relay(1, 1);            # Press power button
 683         usleep(6000000);        # Long press to switch off
 684         relay(1, 0);
 685     };
 686
 687     $target_power_on = sub {
 688         relay(1, 1);            # Press power button
 689         usleep(100000);         # Short press
 690         relay(1, 0);
 691     };
 692 }
 693 elsif ($serial) {
 694     my $CONN;
 695     system_verbose("stty -F $serial $stty");
 696     open($CONN, "+<", $serial) || die "open $serial: $!";
 697     $exp = Expect->init(\*$CONN);
 698 }
 699 elsif ($remote_cmd) {
 700     print STDERR "novaboot: Running: $remote_cmd\n";
 701     $exp = Expect->spawn($remote_cmd);
 702 }
 703 elsif (defined $amt) {
 704     require LWP::UserAgent;
 705     require LWP::Authen::Digest;
 706
 707     sub genXML {
 708         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 709         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 710         my %pstates = ("on"        => 2,
 711                        "standby"   => 4,
 712                        "hibernate" => 7,
 713                        "off"       => 8,
 714                        "reset"     => 10,
 715                        "MNI"       => 11);
 716         return <<END;
 717                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 718                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 719                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 720                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 721                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 722                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 723                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 724                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 725                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 726                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 727                 </s:Header><s:Body>
 728                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 729                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 730                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 731                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 732                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 733                 </a:ReferenceParameters></p:ManagedElement>
 734                 </p:RequestPowerStateChange_INPUT>
 735                 </s:Body></s:Envelope>
 736 END
 737     }
 738
 739     sub sendPOST {
 740         my ($host, $username, $password, $content) = @_;
 741
 742         my $ua = LWP::UserAgent->new();
 743         $ua->agent("novaboot");
 744
 745         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 746         my $res = $ua->request($req);
 747         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 748
 749         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 750         $ua->credentials("$host:16992", $realm, $username => $password);
 751
 752         # Create a request
 753         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 754         $req->content_type('application/x-www-form-urlencoded');
 755         $req->content($content);
 756         $res = $ua->request($req);
 757         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 758         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 759         return $1;
 760     }
 761
 762     sub powerChange  {
 763         my ($host, $username, $password, $pstate)=@_;
 764         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 765         my $className="/RequestPowerStateChange";
 766         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 767         return sendPOST($host, $username, $password, $content);
 768     }
 769
 770     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 771     $amt_user ||= "admin";
 772     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 773     $amt_host || die "AMT host not specified";
 774     $amt_port ||= 16994;
 775
 776
 777     $target_power_off = sub {
 778         $exp->close();
 779         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 780         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 781     };
 782
 783     $target_power_on = sub {
 784         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 785         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 786     };
 787
 788     $target_reset = sub {
 789         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 790         if ($result != 0) {
 791             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 792             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 793         }
 794         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 795     };
 796
 797     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 798     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 799     $exp = Expect->spawn($cmd);
 800     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL' timed out";
 801
 802 }
 803
 804
 805 if ($remote_expect) {
 806     $exp || die("No serial line connection");
 807     my $log = $exp->log_stdout;
 808     if (defined $remote_expect_silent) {
 809         $exp->log_stdout(0);
 810     }
 811     $exp->expect(180, $remote_expect) || die "Expect for '$remote_expect' timed out";
 812     if (defined $remote_expect_silent) {
 813         $exp->log_stdout($log);
 814         print $exp->after() if $log;
 815     }
 816 }
 817
 818 if (defined $reset_cmd) {
 819     $target_reset = sub {
 820         system_verbose($reset_cmd);
 821     };
 822 }
 823
 824 if (defined $reset_send) {
 825     $target_reset = sub {
 826         $reset_send =~ s/\\n/\n/g;
 827         $exp->send($reset_send);
 828     };
 829 }
 830
 831 if (defined $on_opt && defined $target_power_on) {
 832     &$target_power_on();
 833     exit;
 834 }
 835 if (defined $off_opt && defined $target_power_off) {
 836     print STDERR "novaboot: Switching the target off...\n";
 837     &$target_power_off();
 838     exit;
 839 }
 840
 841 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 842 if (defined $builddir) {
 843     chdir($builddir) or die "Can't change directory to $builddir: $!";
 844     print STDERR "novaboot: Entering directory `$builddir'\n";
 845 } else {
 846     $builddir = $invocation_dir;
 847 }
 848
 849 ## File generation phase
 850 my (%files_iso, $menu_iso, $filename);
 851 my $config_name = '';
 852 my $prefix = '';
 853
 854 foreach my $script (@scripts) {
 855     $filename = $$script{filename};
 856     $modules = $$script{modules};
 857     $generated = $$script{generated};
 858     $variables = $$script{variables};
 859
 860     ($config_name = $filename) =~ s#.*/##;
 861     $config_name = $config_name_opt if (defined $config_name_opt);
 862
 863     if (exists $variables->{BUILDDIR}) {
 864         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 865         chdir($builddir) or die "Can't change directory to $builddir: $!";
 866         print STDERR "novaboot: Entering directory `$builddir'\n";
 867     }
 868
 869     if ($grub_prefix) {
 870         $prefix = $grub_prefix;
 871         $prefix =~ s/\$NAME/$config_name/;
 872         $prefix =~ s/\$BUILDDIR/$builddir/;
 873     }
 874     # TODO: use $grub_prefix as first parameter if some switch is given
 875     generate_configs('', $generated, $filename);
 876
 877 ### Generate bootloader configuration files
 878     my @bootloader_configs;
 879     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 880     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 881     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules, $chainload) if (defined $pulsar);
 882
 883 ### Run scons or make
 884     {
 885         my @all;
 886         push @all, @$modules;
 887         push @all, @$copy;
 888         push @all, @$chainload;
 889         my @files = map({ ($file) = m/([^ ]*)/; $file; } @all);
 890
 891         # Filter-out generated files
 892         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 893
 894         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 895         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 896     }
 897
 898 ### Copy files (using rsync)
 899     if (defined $server && !defined($gen_only)) {
 900         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 901
 902         my ($hostname, $path) = split(":", $real_server, 2);
 903         if (! defined $path) {
 904             $path = $hostname;
 905             $hostname = "";
 906         }
 907         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs, @$copy)));
 908         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 909         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 910         my $progress = $istty ? "--progress" : "";
 911         if ($files) {
 912             system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 913             if ($server =~ m|/\$NAME$| && $concat) {
 914                 my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 915                 system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 916             }
 917         }
 918     }
 919
 920 ### Prepare ISO image generation
 921     if (defined $iso_image) {
 922         generate_configs("(cd)", $generated, $filename);
 923         my $menu;
 924         generate_syslinux_config(\$menu, $config_name, "/", $modules);
 925         $menu_iso .= "$menu\n";
 926         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 927     }
 928 }
 929
 930 ## Generate ISO image
 931 if (defined $iso_image) {
 932     system_verbose("mkdir -p isolinux");
 933
 934     my @files;
 935     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
 936         # Newer ISOLINUX version
 937         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
 938     } else {
 939         # Older ISOLINUX version
 940         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
 941     }
 942     system_verbose("cp @files isolinux");
 943     open(my $fh, ">isolinux/isolinux.cfg");
 944     if ($#scripts) {
 945         print $fh "TIMEOUT 50\n";
 946         print $fh "DEFAULT menu\n";
 947     } else {
 948         print $fh "DEFAULT $config_name\n";
 949     }
 950     print $fh "$menu_iso";
 951     close($fh);
 952
 953     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
 954     $iso_image ||= "$config_name.iso";
 955
 956     # Note: We use -U flag below to "Allow 'untranslated' filenames,
 957     # completely violating the ISO9660 standards". Without this
 958     # option, isolinux is not able to read files names for example
 959     # bzImage-3.0.
 960     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
 961     print("ISO image created: $builddir/$iso_image\n");
 962 }
 963
 964 exit(0) if defined $gen_only;
 965
 966 ## Boot the system using various methods and send serial output to stdout
 967
 968 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 969     die "You cannot do this with multiple scripts simultaneously";
 970 }
 971
 972 if ($variables->{WVTEST_TIMEOUT}) {
 973     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 974 }
 975
 976 ### Start in Qemu
 977
 978 if (defined $qemu) {
 979     # Qemu
 980     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 981     my @qemu_flags = split(" ", $qemu);
 982     $qemu = shift(@qemu_flags);
 983
 984     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 985     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 986     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 987
 988     if (defined $iso_image) {
 989         # Boot NOVA with grub (and test the iso image)
 990         push(@qemu_flags, ('-cdrom', $iso_image));
 991     } else {
 992         # Boot NOVA without GRUB
 993
 994         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 995         foreach (@$modules) {s/,/+/g;}
 996         generate_configs("", $generated, $filename);
 997
 998         if (scalar @$modules) {
 999             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1000             $kcmd = '' if !defined $kcmd;
1001             my $dtb;
1002             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1003             my $initrd = join ",", @$modules;
1004
1005             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
1006             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
1007             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
1008         }
1009     }
1010     if (!grep /^-serial$/, @qemu_flags) {
1011         push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
1012     }
1013     unshift(@qemu_flags, ('-name', $config_name));
1014     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
1015     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
1016 }
1017
1018 ### Local DHCPD and TFTPD
1019
1020 my ($dhcpd_pid, $tftpd_pid);
1021
1022 $tftp=1 if $tftp_port;
1023
1024 if (defined $dhcp_tftp)
1025 {
1026     generate_configs("(nd)", $generated, $filename);
1027     system_verbose('mkdir -p tftpboot');
1028     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
1029     open(my $fh, '>', 'dhcpd.conf');
1030     my $mac = `cat /sys/class/net/$netif/address`;
1031     chomp $mac;
1032     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
1033                       range 10.23.23.10 10.23.23.100;
1034                       filename \"bin/boot/grub/pxegrub.pxe\";
1035                       next-server 10.23.23.1;
1036 }
1037 host server {
1038         hardware ethernet $mac;
1039         fixed-address 10.23.23.1;
1040 }";
1041     close($fh);
1042     system_verbose("sudo ip a add 10.23.23.1/24 dev $netif;
1043             sudo ip l set dev $netif up;
1044             sudo touch dhcpd.leases");
1045
1046     # We run servers by forking ourselves, because the servers end up
1047     # in our process group and get killed by signals sent to the
1048     # process group (e.g. Ctrl-C on terminal).
1049     $dhcpd_pid = fork();
1050     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1051 }
1052
1053 if (defined $dhcp_tftp || defined $tftp) {
1054     $tftp_port ||= 69;
1055     # Unfortunately, tftpd requires root privileges even with
1056     # non-privileged (>1023) port due to initgroups().
1057     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
1058
1059     # Kill server when we die
1060     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1061                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1062
1063     # We have to kill tftpd explicitely, because it is not in our process group
1064     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1065 }
1066
1067 ### AMT IDE-R
1068 if (defined $ider) {
1069     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1070     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1071     my $ider_pid = fork();
1072     if ($ider_pid == 0) {
1073         exec($ider_cmd);
1074         die "IDE redirection failed";
1075     }
1076     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1077     # to use both simultaneously.
1078     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1079 }
1080
1081 ### Reset target (IP relay, AMT, ...)
1082
1083 if (defined $target_reset && $reset) {
1084     print STDERR "novaboot: Reseting the test box... ";
1085     &$target_reset();
1086     print STDERR "done\n";
1087     if (defined $exp) {
1088         # We don't want to output anything printed by the target
1089         # before reset so we clear the buffers now. This is, however,
1090         # not ideal because we may loose some data that were sent
1091         # after the reset. If this is a problem, one should reset and
1092         # connect to serial line in atomic manner. For example, if
1093         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1094         # do not use separate --reset-cmd.
1095         my $log = $exp->log_stdout;
1096         $exp->log_stdout(0);
1097         $exp->expect(0); # Read data from target
1098         $exp->clear_accum();    # Clear the read data
1099         $exp->log_stdout($log);
1100     }
1101 }
1102
1103 ### U-boot conversation
1104 if (defined $uboot) {
1105     my $uboot_prompt = $uboot || '=> ';
1106     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1107     $exp || die("No serial line connection");
1108     $exp->log_stdout(1);
1109     #$exp->exp_internal(1);
1110     $exp->expect(20,
1111                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
1112                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1113     foreach my $cmdspec (@uboot_init) {
1114         my ($cmd, $timeout);
1115         die "Internal error - please report a bug" unless ref($cmdspec) eq "HASH";
1116
1117         if ($cmdspec->{system}) {
1118             $cmd = `$cmdspec->{system}`;
1119         } else {
1120             $cmd = $cmdspec->{command};
1121         }
1122         $timeout = $cmdspec->{timeout} // 10;
1123
1124         if ($cmd =~ /\$NB_MYIP/) {
1125             my $ip = (grep /inet /, `ip addr show $netif`)[0] || die "Problem determining IP address of $netif";
1126             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1127             $cmd =~ s/\$NB_MYIP/$ip/g;
1128         }
1129         if ($cmd =~ /\$NB_PREFIX/) {
1130             my $p = $prefix;
1131             $p =~ s|/*$||;
1132             $cmd =~ s/\$NB_PREFIX/$p/g;
1133         }
1134         chomp($cmd);
1135         $exp->send("$cmd\n");
1136
1137         my ($matched_pattern_position, $error,
1138             $successfully_matching_string,
1139             $before_match, $after_match) =
1140                 $exp->expect($timeout, $uboot_prompt);
1141         die "No U-Boot prompt: $error" if $error;
1142
1143         if ($cmdspec->{dest}) {
1144             open(my $fh, ">", $cmdspec->{dest}) or die "Cannot open '$cmdspec->{dest}': $!";
1145             print $fh $before_match;
1146             close($fh);
1147         }
1148     }
1149
1150     # Load files if there are some load lines in the script
1151     if (scalar(@$modules) > 0  && !$variables->{NO_BOOT}) {
1152         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1153         my $dtb;
1154         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1155         my $initrd = shift @$modules;
1156
1157         if (defined $kbin) {
1158             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1159             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1160             $exp->expect(10,
1161                          [qr/##/, sub { exp_continue; }],
1162                          $uboot_prompt) || die "Kernel load timeout";
1163         }
1164         if (defined $dtb) {
1165             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1166             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1167             $exp->expect(10,
1168                          [qr/##/, sub { exp_continue; }],
1169                          $uboot_prompt) || die "Device tree load timeout";
1170         }
1171         if (defined $initrd) {
1172             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1173             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1174             $exp->expect(10,
1175                          [qr/##/, sub { exp_continue; }],
1176                          $uboot_prompt) || die "Initrd load timeout";
1177         } else {
1178             $uboot_addr{ramdisk} = '-';
1179         }
1180
1181         $kcmd //= '';
1182         $exp->send("setenv bootargs $kcmd\n");
1183         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt timeout";
1184
1185     }
1186     $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1187     if (!$variables->{NO_BOOT} && $uboot_cmd ne '') {
1188         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1189         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1190         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1191
1192         $exp->send($uboot_cmd . "\n");
1193         $exp->expect(5, "\n")  || die "U-Boot command timeout";
1194     }
1195 }
1196
1197 ### Serial line interaction
1198 if ($interaction && defined $exp) {
1199     # Serial line of the target is available
1200     my $interrupt = 'Ctrl-C';
1201     if ($interactive && !@exiton) {
1202         $interrupt = '"~~."';
1203     }
1204     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1205     $exp->log_stdout(1);
1206     if (@exiton) {
1207         $exp->expect($exiton_timeout, @expect_raw, @exiton) || die("exiton timeout");
1208     } else {
1209         my @inputs = ($exp);
1210         my $infile = new IO::File;
1211         $infile->IO::File::fdopen(*STDIN,'r');
1212         my $in_object = Expect->exp_init($infile);
1213         $in_object->set_group($exp);
1214
1215         if ($interactive) {
1216             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1217             $in_object->manual_stty(0);   # Use raw terminal mode
1218         } else {
1219             $in_object->manual_stty(1);   # Do not modify terminal settings
1220         }
1221         push(@inputs, $in_object);
1222         #use Data::Dumper;
1223         #print Dumper(\@expect_raw);
1224         $exp->expect(undef, @expect_raw) if @expect_raw;
1225
1226         $^W = 0; # Suppress Expect warning: handle id(3) is not a tty. Not changing mode at /usr/share/perl5/Expect.pm line 393, <> line 8.
1227         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1228         $^W = 1;
1229     }
1230 }
1231
1232 ## Kill dhcpc or tftpd
1233 if (defined $dhcp_tftp || defined $tftp) {
1234     die("novaboot: This should kill servers on background\n");
1235 }
1236
1237 # Always finish novaboot output with newline
1238 print "\n" if $final_eol;
1239
1240 ## Documentation
1241
1242 =encoding utf8
1243 =head1 NAME
1244
1245 novaboot - Boots a locally compiled operating system on a remote
1246 target or in qemu
1247
1248 =head1 SYNOPSIS
1249
1250 B<novaboot> --help
1251
1252 B<novaboot> [option]... [--] script...
1253
1254 B<./script> [option]...
1255
1256 =head1 DESCRIPTION
1257
1258 Novaboot makes booting of a locally compiled operating system (OS)
1259 (e.g. NOVA or Linux) on remote targets as simple as running a program
1260 locally. It automates things like copying OS images to a TFTP server,
1261 generation of bootloader configuration files, resetting of target
1262 hardware or redirection of target's serial line to stdin/out. Novaboot
1263 is highly configurable and makes it easy to boot a single image on
1264 different targets or different images on a single target.
1265
1266 Novaboot operation is controlled by configuration files, command line
1267 options and by a so-called novaboot script, which can be thought as a
1268 generalization of bootloader configuration files (see L</"NOVABOOT
1269 SCRIPT SYNTAX">). The typical way of using novaboot is to make the
1270 novaboot script executable and set its first line to I<#!/usr/bin/env
1271 novaboot>. Then, booting a particular OS configuration becomes the
1272 same as executing a local program – the novaboot script.
1273
1274 Novaboot uses configuration files to, among other things, define
1275 command line options needed for different targets. Users typically use
1276 only the B<-t>/B<--target> command line option to select the target.
1277 Internally, this option expands to the pre-configured options.
1278 Configuration files are searched at multiple places, which allows to
1279 have per-system, per-user or per-project configurations. Configuration
1280 file syntax is described in section L</"CONFIGURATION FILES">.
1281
1282 Simple examples of using C<novaboot>:
1283
1284 =over 3
1285
1286 =item 1.
1287
1288 Run an OS in Qemu. This can be specified with the B<--qemu> option.
1289 Thus running
1290
1291  novaboot --qemu myos
1292
1293 (or C<./myos --qemu> as described above) will run Qemu and make it
1294 boot the configuration specified in the F<myos> script.
1295
1296 =item 2.
1297
1298 Create a bootloader configuration file (currently supported
1299 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar and U-Boot) and copy it
1300 with all other files needed for booting to a remote boot server. Then
1301 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1302 target and receive its serial output.
1303
1304  ./myos --grub2 --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1305
1306 Alternatively, you can put these switches to the configuration file
1307 and run:
1308
1309  ./myos --target mytarget
1310
1311 =item 3.
1312
1313 Run DHCP and TFTP server on developer's machine to boot the target
1314 from it.
1315
1316  ./myos --dhcp-tftp
1317
1318 This is useful when no network infrastructure is in place and
1319 the target is connected directly to developer's box.
1320
1321 =item 4.
1322
1323 Create bootable ISO image.
1324
1325  novaboot --iso -- script1 script2
1326
1327 The created ISO image will have ISOLINUX bootloader installed on it
1328 and the boot menu will allow selecting between I<script1> and
1329 I<script2> configurations.
1330
1331 =back
1332
1333 =head1 PHASES AND OPTIONS
1334
1335 Novaboot performs its work in several phases. Each phase can be
1336 influenced by several command line options, certain phases can be
1337 skipped. The list of phases (in the execution order) is as follows.
1338
1339 =over
1340
1341 =item 1. L<Configuration reading|/Configuration reading phase>
1342
1343 =item 2. L<Command line processing|/Command line processing phase>
1344
1345 =item 3. L<Script preprocessing|/Script preprocessing phase>
1346
1347 =item 4. L<File generation|/File generation phase>
1348
1349 =item 5. L<Target connection|/Target connection check>
1350
1351 =item 6. L<File deployment|/File deployment phase>
1352
1353 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1354
1355 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1356
1357 =item 9. L<Target interaction|/Target interaction phase>
1358
1359 =back
1360
1361 Each phase is described in the following sections together with the
1362 command line options that control it.
1363
1364 =head2 Configuration reading phase
1365
1366 After starting, novaboot reads configuration files. Their content is
1367 described in section L</"CONFIGURATION FILES">. By default,
1368 the configuration is read from multiple locations. First from the system
1369 configuration directory (F</etc/novaboot.d/>), second from the user
1370 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1371 files along the path to the current directory. Alternatively, a single
1372 configuration file specified with the B<-c> switch or with the
1373 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1374 override settings from the former ones.
1375
1376 The system configuration directory is determined by the content of
1377 NOVABOOT_CONFIG_DIR environment variable and defaults to
1378 F</etc/novaboot.d>. Files in this directory with names consisting
1379 solely of English letters, numbers, dashes '-' and underscores '_'
1380 (note that dot '.' is not included) are read in alphabetical order.
1381
1382 Then, the user configuration file is read from
1383 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environment
1384 variable is not set F<~/.config/novaboot> is read instead.
1385
1386 Finally, novaboot searches for files named F<.novaboot> starting from the
1387 directory of the novaboot script (or working directory, see bellow)
1388 and continuing upwards up to the root directory. The found
1389 configuration files are then read in the opposite order (i.e. from the
1390 root directory downwards). This allows having, for example, a project
1391 specific configuration in F<~/project/.novaboot>.
1392
1393 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1394 The former one is read always, whereas the latter only when novaboot
1395 script or working directory is under the C<$HOME> directory.
1396
1397 In certain cases, the location of the novaboot script cannot be
1398 determined in this early phase. This happens either when the script is
1399 read from the standard input or when novaboot is invoked explicitly as
1400 in the example L</"4."> above. In this case, the current working
1401 directory is used as a starting point for configuration file search
1402 instead of the novaboot script directory.
1403
1404 =over 8
1405
1406 =item -c, --config=I<filename>
1407
1408 Use the specified configuration file instead of the default one(s).
1409
1410 =back
1411
1412 =head2 Command line processing phase
1413
1414 =over 8
1415
1416 =item --dump-config
1417
1418 Dump the current configuration to stdout end exit. Useful as an
1419 initial template for a configuration file.
1420
1421 =item -h, --help
1422
1423 Print short (B<-h>) or long (B<--help>) help.
1424
1425 =item -t, --target=I<target>
1426
1427 This option serves as a user configurable shortcut for other novaboot
1428 options. The effect of this option is the same as specifying the
1429 options stored in the C<%targets> configuration variable under key
1430 I<target>. See also L</"CONFIGURATION FILES">.
1431
1432 When this option is not given, novaboot tries to determine the target
1433 to use from either B<NOVABOOT_TARGET> environment variable or from
1434 B<$default_target> configuration file variable.
1435
1436 =back
1437
1438 =head2 Script preprocessing phase
1439
1440 This phase allows modifying the parsed novaboot script before it is
1441 used in the later phases.
1442
1443 =over 8
1444
1445 =item -a, --append=I<parameters>
1446
1447 Append a string to the first C<load> line in the novaboot script. This
1448 can be used to append parameters to the kernel's or root task's
1449 command line. This option can appear multiple times.
1450
1451 =item -b, --bender
1452
1453 Use L<bender|https://github.com/TUD-OS/morbo/blob/master/standalone/bender.c>
1454 chainloader. Bender scans the PCI bus for PCI serial ports and stores
1455 the information about them in the BIOS data area for use by the
1456 kernel.
1457
1458 =item --chainloader=I<chainloader>
1459
1460 Specifies a chainloader that is loaded before the kernel and other
1461 files specified in the novaboot script. E.g. 'bin/boot/bender
1462 promisc'.
1463
1464 =item --dump
1465
1466 Print the modules to boot and their parameters, after this phase
1467 finishes. Then exit. This is useful for seeing the effect of other
1468 options in this section.
1469
1470 =item -k, --kernel=F<file>
1471
1472 Replace the first word on the first C<load> line in the novaboot
1473 script with F<file>.
1474
1475 =item --scriptmod=I<Perl expression>
1476
1477 When novaboot script is read, I<Perl expression> is executed for every
1478 line (in $_ variable). For example, C<novaboot
1479 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1480 in the script with I<omega6>.
1481
1482 When this option is present, it overrides I<$script_modifier> variable
1483 from the configuration file, which has the same effect. If this option
1484 is given multiple times all expressions are evaluated in the command
1485 line order.
1486
1487 =back
1488
1489 =head2 File generation phase
1490
1491 In this phase, files needed for booting are generated in a so-called
1492 I<build directory> (see L</--build-dir>). In most cases configuration
1493 for a bootloader is generated automatically by novaboot. It is also
1494 possible to generate other files using I<heredoc> or I<"<"> syntax in
1495 novaboot scripts. Finally, binaries can be generated in this phases by
1496 running C<scons> or C<make>.
1497
1498 =over 8
1499
1500 =item --build-dir=I<directory>
1501
1502 Overrides the default build directory location.
1503
1504 The default build directory location is determined as follows: If the
1505 configuration file defines the C<$builddir> variable, its value is
1506 used. Otherwise, it is the directory that contains the first processed
1507 novaboot script.
1508
1509 See also L</BUILDDIR> variable.
1510
1511 =item -g, --grub[=I<filename>]
1512
1513 Generates grub bootloader menu file. If the I<filename> is not
1514 specified, F<menu.lst> is used. The I<filename> is relative to the
1515 build directory (see B<--build-dir>).
1516
1517 =item --grub-preamble=I<prefix>
1518
1519 Specifies the I<preamble> that is at the beginning of the generated
1520 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1521 timeout.
1522
1523 =item --prefix=I<prefix>
1524
1525 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1526 filename in generated bootloader configuration files (or in U-Boot
1527 commands).
1528
1529 If the I<prefix> contains string $NAME, it will be replaced with the
1530 name of the novaboot script (see also B<--name>).
1531
1532 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1533 the build directory (see also B<--build-dir>).
1534
1535 =item --grub-prefix
1536
1537 Alias for B<--prefix>.
1538
1539 =item --grub2[=I<filename>]
1540
1541 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1542 specified F<grub.cfg> is used. The content of the menu entry can be
1543 customized with B<--grub-preamble>, B<--grub2-prolog> or
1544 B<--grub_prefix> options.
1545
1546 In order to use the generated menu entry on your development
1547 machine that uses GRUB2, append the following snippet to
1548 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1549 i.e. run update-grub on Debian/Ubuntu.
1550
1551   if [ -f /path/to/nul/build/grub.cfg ]; then
1552     source /path/to/nul/build/grub.cfg
1553   fi
1554
1555 =item --grub2-prolog=I<prolog>
1556
1557 Specifies text that is put at the beginning of the GRUB2 menu entry.
1558
1559 =item -m, --make[=make command]
1560
1561 Runs C<make> to build files that are not generated by novaboot itself.
1562
1563 =item --name=I<string>
1564
1565 Use the name I<string> instead of the name of the novaboot script.
1566 This name is used for things like a title of grub menu or for the
1567 server directory where the boot files are copied to.
1568
1569 =item --no-file-gen
1570
1571 Do not run external commands to generate files (i.e. "<" syntax and
1572 C<run> keyword). This switch does not influence generation of files
1573 specified with "<<WORD" syntax.
1574
1575 =item -p, --pulsar[=mac]
1576
1577 Generates pulsar bootloader configuration file named F<config-I<mac>>
1578 The I<mac> string is typically a MAC address and defaults to
1579 I<novaboot>.
1580
1581 =item --scons[=scons command]
1582
1583 Runs C<scons> to build files that are not generated by novaboot
1584 itself.
1585
1586 =item --strip-rom
1587
1588 Strip I<rom://> prefix from command lines and generated config files.
1589 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1590
1591 =item --gen-only
1592
1593 Exit novaboot after file generation phase.
1594
1595 =back
1596
1597 =head2 Target connection check
1598
1599 If supported by the target, the connection to it is made and it is
1600 checked whether the target is not occupied by another novaboot
1601 user/instance.
1602
1603 =over 8
1604
1605 =item --amt=I<"[user[:password]@]host[:port]>
1606
1607 Use Intel AMT technology to control the target machine. WS management
1608 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1609 The hostname or (IP address) is given by the I<host> parameter. If
1610 I<password> is not specified, environment variable AMT_PASSWORD is
1611 used. The I<port> specifies a TCP port for SOL. If not specified, the
1612 default is 16992. Default I<user> is admin.
1613
1614 =item --iprelay=I<addr[:port]>
1615
1616 Use TCP/IP relay and serial port to access the target's serial port
1617 and powercycle it. The IP address of the relay is given by I<addr>
1618 parameter. If I<port> is not specified, it defaults to 23.
1619
1620 Note: This option is supposed to work with HWG-ER02a IP relays.
1621
1622 =item -s, --serial[=device]
1623
1624 Target's serial line is connected to host's serial line (device). The
1625 default value for device is F</dev/ttyUSB0>.
1626
1627 The value of this option is exported in NB_NOVABOOT environment
1628 variable to all subprocesses run by C<novaboot>.
1629
1630 =item --stty=I<settings>
1631
1632 Specifies settings passed to C<stty> invoked on the serial line
1633 specified with B<--serial> option. If this option is not given,
1634 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1635
1636 =item --remote-cmd=I<cmd>
1637
1638 Command that mediates connection to the target's serial line. For
1639 example C<ssh server 'cu -l /dev/ttyS0'>.
1640
1641 =item --remote-expect=I<string>
1642
1643 Wait for reception of I<string> after establishing the remote
1644 connection.
1645
1646 =item --remote-expect-silent=I<string>
1647
1648 The same as B<--remote-expect> except that the remote output is not
1649 echoed to stdout while waiting for the I<string>. Everything after the
1650 matched string is printed to stdout, so you may want to include line
1651 end characters in the I<string> as well.
1652
1653 =back
1654
1655 =head2 File deployment phase
1656
1657 In some setups, it is necessary to copy the files needed for booting
1658 to a particular location, e.g. to a TFTP boot server or to the
1659 F</boot> partition.
1660
1661 =over 8
1662
1663 =item -d, --dhcp-tftp
1664
1665 Turns your workstation into a DHCP and TFTP server so that the OS can
1666 be booted via PXE BIOS (or similar mechanism) on the test machine
1667 directly connected by a plain Ethernet cable to your workstation.
1668
1669 The DHCP and TFTP servers require root privileges and C<novaboot>
1670 uses C<sudo> command to obtain those. You can put the following to
1671 I</etc/sudoers> to allow running the necessary commands without asking
1672 for password.
1673
1674  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1675  your_login ALL=NOPASSWD: NOVABOOT
1676
1677 =item --tftp
1678
1679 Starts a TFTP server on your workstation. This is similar to
1680 B<--dhcp-tftp> except that DHCP server is not started.
1681
1682 The TFTP server requires root privileges and C<novaboot> uses C<sudo>
1683 command to obtain those. You can put the following to I</etc/sudoers>
1684 to allow running the necessary commands without asking for password.
1685
1686  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1687  your_login ALL=NOPASSWD: NOVABOOT
1688
1689 =item --tftp-port=I<port>
1690
1691 Port to run the TFTP server on. Implies B<--tftp>.
1692
1693 =item --netif=I<network interface>
1694
1695 Network interface used to deploy files to the target. Default value is
1696 I<eth0>. This influences the configuration of the DHCP server started
1697 by B<--dhcp-tftp> and the value that B<$NB_MYIP> get replaced with during
1698 U-Boot conversation.
1699
1700 =item --iso[=filename]
1701
1702 Generates the ISO image that boots NOVA system via GRUB. If no filename
1703 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1704 of the novaboot script (see also B<--name>).
1705
1706 =item --server[=[[user@]server:]path]
1707
1708 Copy all files needed for booting to another location. The files will
1709 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1710 contains string $NAME, it will be replaced with the name of the
1711 novaboot script (see also B<--name>).
1712
1713 =item --rsync-flags=I<flags>
1714
1715 Specifies which I<flags> are appended to F<rsync> command line when
1716 copying files as a result of I<--server> option.
1717
1718 =item --concat
1719
1720 If B<--server> is used and its value ends with $NAME, then after
1721 copying the files, a new bootloader configuration file (e.g. menu.lst)
1722 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1723 with $NAME part removed. The content of the file is created by
1724 concatenating all files of the same name from all subdirectories of
1725 I<path-wo-name> found on the "server".
1726
1727 =item --ider
1728
1729 Use Intel AMT technology for IDE redirection. This allows the target
1730 machine to boot from novaboot created ISO image. Implies B<--iso>.
1731
1732 The experimental C<amtider> utility needed by this option can be
1733 obtained from https://github.com/wentasah/amtterm.
1734
1735 =back
1736
1737 =head2 Target power-on and reset phase
1738
1739 At this point, the target is reset (or switched on/off). There are
1740 several ways how this can be accomplished. Resetting a physical target
1741 can currently be accomplished by the following options: B<--amt>,
1742 B<--iprelay>, B<--reset-cmd> and B<--reset-send>.
1743
1744 =over 8
1745
1746 =item --on, --off
1747
1748 Switch on/off the target machine and exit. The script (if any) is
1749 completely ignored. Currently, it works only with B<--iprelay> or
1750 B<--amt>.
1751
1752 =item -Q, --qemu[=I<qemu-binary>]
1753
1754 Boot the configuration in qemu. Optionally, the name of qemu binary
1755 can be specified as a parameter.
1756
1757 =item --qemu-append=I<flags>
1758
1759 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1760 C<-cpu coreduo -smp 2>).
1761
1762 =item -q, --qemu-flags=I<flags>
1763
1764 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1765 -smp 2>) with I<flags> specified here.
1766
1767 =item --reset-cmd=I<cmd>
1768
1769 Command that resets the target.
1770
1771 =item --reset-send=I<string>
1772
1773 Reset the target by sending the given I<string> to the remote serial
1774 line. "\n" sequences are replaced with the newline character.
1775
1776 =item --no-reset, --reset
1777
1778 Disable/enable resetting of the target.
1779
1780 =back
1781
1782 =head2 Interaction with the bootloader on the target
1783
1784 =over 8
1785
1786 =item --uboot[=I<prompt>]
1787
1788 Interact with U-Boot bootloader to boot the thing described in the
1789 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1790 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1791 Implementation of this option is currently tied to a particular board
1792 that we use. It may be subject to changes in the future!
1793
1794 =item --no-uboot
1795
1796 Disable U-Boot interaction previously enabled with B<--uboot>.
1797
1798 =item --uboot-init
1799
1800 Command(s) to send the U-Boot bootloader before loading the images and
1801 booting them. This option can be given multiple times. After sending
1802 commands from each option novaboot waits for U-Boot I<prompt>.
1803
1804 If the command contains string I<$NB_MYIP> then this string is
1805 replaced by IPv4 address of eth0 interface (see also B<--netif>).
1806 Similarly, I<$NB_PREFIX> is replaced with prefix given by B<--prefix>.
1807
1808 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
1809
1810 =item --uboot-addr I<name>=I<address>
1811
1812 Load address of U-Boot's C<tftpboot> command for loading I<name>,
1813 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
1814 tree).
1815
1816 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
1817 variables used by convention for this purpose.
1818
1819 =item --uboot-cmd=I<command>
1820
1821 Specifies U-Boot command used to execute the OS. If the command
1822 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
1823 these are replaced with the addresses configured with B<--uboot-addr>.
1824
1825 The default value is
1826
1827     bootm $kernel_addr $ramdisk_addr $fdt_addr
1828
1829 or the C<UBOOT_CMD> variable if defined in the novaboot script.
1830
1831 =back
1832
1833 =head2 Target interaction phase
1834
1835 In this phase, target's serial output is redirected to stdout and if
1836 stdin is a TTY, it is redirected to the target's serial input allowing
1837 interactive work with the target.
1838
1839 =over 8
1840
1841 =item --exiton=I<string>
1842
1843 When the I<string> is sent by the target, novaboot exits. This option can
1844 be specified multiple times, in which case novaboot exits whenever
1845 either of the specified strings is sent.
1846
1847 If the I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1848 treated as a regular expression. For example:
1849
1850     --exiton -re --exiton 'error:.*failed'
1851
1852 =item --exiton-re=I<regex>
1853
1854 The same as --exiton -re --exiton I<regex>.
1855
1856 =item --exiton-timeout=I<seconds>
1857
1858 By default B<--exiton> waits for the string match forever. When this
1859 option is specified, "exiton" timeouts after the specifies the number of
1860 seconds and novaboot returns non-zero exit code.
1861
1862 =item -i, --interactive
1863
1864 Setup things for the interactive use of the target. Your terminal will be
1865 switched to raw mode. In raw mode, your system does not process input
1866 in any way (no echoing of entered characters, no interpretation
1867 special characters). This, among others, means that Ctrl-C is passed
1868 to the target and does no longer interrupt novaboot. Use "~~."
1869 sequence to exit novaboot.
1870
1871 =item --no-interaction, --interaction
1872
1873 Skip resp. force target interaction phase. When skipped, novaboot exits
1874 immediately when boot is initiated.
1875
1876 =item --expect=I<string>
1877
1878 When the I<string> is received from the target, send the string specified
1879 with the subsequent B<--send*> option to the target.
1880
1881 =item --expect-re=I<regex>
1882
1883 When target's output matches regular expression I<regex>, send the
1884 string specified with the subsequent B<--send*> option to the target.
1885
1886 =item --expect-raw=I<perl-code>
1887
1888 Provides direct control over Perl's Expect module.
1889
1890 =item --send=I<string>
1891
1892 Send I<string> to the target after the previously specified
1893 B<--expect*> was matched in the target's output. The I<string> may
1894 contain escape sequences such as "\n".
1895
1896 Note that I<string> is actually interpreted by Perl, so it can contain
1897 much more that escape sequences. This behavior may change in the
1898 future.
1899
1900 Example: C<--expect='login: ' --send='root\n'>
1901
1902 =item --sendcont=I<string>
1903
1904 Similar to B<--send> but continue expecting more input.
1905
1906 Example: C<--expect='Continue?' --sendcont='yes\n'>
1907
1908 =item --final-eol, --no-final-eol
1909
1910 By default, B<novaboot> always prints an end-of-line character at the
1911 end of its execution in order to ensure that the output of programs
1912 started after novaboot appears at the beginning of the line. When this
1913 is not desired B<--no-final-eol> option can be used to override this
1914 behavior.
1915
1916 =back
1917
1918 =head1 NOVABOOT SCRIPT SYNTAX
1919
1920 The syntax tries to mimic POSIX shell syntax. The syntax is defined
1921 by the following rules.
1922
1923 Lines starting with "#" and empty lines are ignored.
1924
1925 Lines that end with "\" are concatenated with the following line after
1926 removal of the final "\" and leading whitespace of the following line.
1927
1928 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1929 expression) assign values to internal variables. See L</VARIABLES>
1930 section.
1931
1932 Otherwise, the first word on the line defines the meaning of the line.
1933 The following keywords are supported:
1934
1935 =over 4
1936
1937 =item C<load>
1938
1939 These lines represent modules to boot. The
1940 word after C<load> is a file name (relative to the build directory
1941 (see B<--build-dir>) of the module to load and the remaining words are
1942 passed to it as the command line parameters.
1943
1944 When the C<load> line ends with "<<WORD" then the subsequent lines
1945 until the line containing solely WORD are copied literally to the file
1946 named on that line. This is similar to shell's heredoc feature.
1947
1948 When the C<load> line ends with "< CMD" then command CMD is executed
1949 with F</bin/sh> and its standard output is stored in the file named on
1950 that line. The SRCDIR variable in CMD's environment is set to the
1951 absolute path of the directory containing the interpreted novaboot
1952 script.
1953
1954 =item C<copy>
1955
1956 These lines are similar to C<load> lines. The
1957 file mentioned there is copied to the same place as in the case of C<load>
1958 (e.g. tftp server), but the file is not used in the bootloader
1959 configuration. Such a file can be used by the target for other
1960 purposes than booting, e.g. at OS runtime or for firmware update.
1961
1962 =item C<chld>
1963
1964 Chainload another bootloader. Instead of loading multiboot modules
1965 identified with C<load> keyword, run another bootloader. This is
1966 currently supported only by pulsar and can be used to load e.g. Grub
1967 as in the example below:
1968
1969  chld boot/grub/i386-pc/core.0
1970
1971
1972 =item C<run>
1973
1974 Lines starting with C<run> keyword contain shell commands that are run
1975 during file generation phase. This is the same as the "< CMD" syntax
1976 for C<load> keyboard except that the command's output is not
1977 redirected to a file. The ordering of commands is the same as they
1978 appear in the novaboot script.
1979
1980 =item C<uboot>
1981
1982 These lines represent U-Boot commands that are sent to the target if
1983 B<--uboot> option is given. Having a U-Boot line in the novaboot
1984 script is the same as giving B<--uboot-init> option to novaboot. The
1985 following syntax variants are supported:
1986
1987
1988   uboot[:<timeout>] <string> [> <file>]
1989   uboot[:<timeout>] < <shell> [> <file>]
1990
1991 C<string> is the literal U-Boot command.
1992
1993 The C<uboot> keyword can be suffixed with timeout specification. The
1994 syntax is C<uboot:Ns>, where C<N> is the whole number of seconds. If
1995 the U-Boot command prompt does not appear before the timeout, novaboot
1996 fails. The default timeout is 10 seconds.
1997
1998 In the second variant with the C<<> character the shell code is
1999 executed and its standard output is sent to U-Boot. Example:
2000
2001   uboot < printf "mmc write \$loadaddr 1 %x" $(($(/usr/bin/stat -c%s rootfs.ext4) / 512))
2002
2003 When C<E<gt> file> part is present, the output of the U-Boot command
2004 is written into the given file.
2005
2006 =back
2007
2008 Example (Linux):
2009
2010   #!/usr/bin/env novaboot
2011   load bzImage console=ttyS0,115200
2012   run  make -C buildroot
2013   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
2014
2015 Example (NOVA User Land - NUL):
2016
2017   #!/usr/bin/env novaboot
2018   WVDESC=Example program
2019   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
2020                            verbose hostkeyb:0,0x60,1,12,2
2021   load bin/apps/hello.nul
2022   load hello.nulconfig <<EOF
2023   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
2024   rom://bin/apps/hello.nul
2025   EOF
2026
2027 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
2028 F<hello.nulconfig>. sigma0 receives some command line parameters and
2029 F<hello.nulconfig> file is generated on the fly from the lines between
2030 C<<<EOF> and C<EOF>.
2031
2032 Example (Zynq system update via U-Boot):
2033
2034   #!/usr/bin/env novaboot
2035
2036   uboot dhcp
2037
2038   # Write kernel to FAT filesystem on the 1st SD card partition
2039   run mkimage -f uboot-image.its image.ub
2040   copy image.ub
2041   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/image.ub
2042   uboot fatwrite mmc 0:1 ${loadaddr} image.ub $filesize
2043   uboot set bootargs console=ttyPS0,115200 root=/dev/mmcblk0p2
2044
2045   # Write root FS image to the 2nd SD card partition
2046   copy rootfs/images/rootfs.ext4
2047   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/rootfs/images/rootfs.ext4
2048   uboot mmc part > mmc-part.txt
2049   uboot < printf "mmc write \$loadaddr %x %x" $(awk '{ if ($1 == "2") { print $2 }}' mmc-part.txt) $(($(/usr/bin/stat -L --printf=%s rootfs/images/rootfs.ext4) / 512))
2050
2051   UBOOT_CMD=boot
2052
2053
2054 =head2 VARIABLES
2055
2056 The following variables are interpreted in the novaboot script:
2057
2058 =over 8
2059
2060 =item BUILDDIR
2061
2062 Novaboot chdir()s to this directory before file generation phase. The
2063 directory name specified here is relative to the build directory
2064 specified by other means (see L</--build-dir>).
2065
2066 =item EXITON
2067
2068 Assigning this variable has the same effect as specifying L</--exiton>
2069 option.
2070
2071 =item HYPERVISOR_PARAMS
2072
2073 Parameters passed to the hypervisor. The default value is "serial", unless
2074 overridden in the configuration file.
2075
2076 =item KERNEL
2077
2078 The kernel to use instead of the hypervisor specified in the
2079 configuration file with the C<$hypervisor> variable. The value should
2080 contain the name of the kernel image as well as its command line
2081 parameters. If this variable is defined and non-empty, the variable
2082 HYPERVISOR_PARAMS is not used.
2083
2084 =item NO_BOOT
2085
2086 If this variable is 1, the system is not booted. This is currently
2087 only implemented for U-Boot bootloader where it is useful for
2088 interacting with the bootloader without booting the system - e.g. for
2089 flashing.
2090
2091 =item QEMU
2092
2093 Use a specific qemu binary (can be overridden with B<-Q>) and flags
2094 when booting this script under qemu. If QEMU_FLAGS variable is also
2095 specified flags specified in QEMU variable are replaced by those in
2096 QEMU_FLAGS.
2097
2098 =item QEMU_FLAGS
2099
2100 Use specific qemu flags (can be overridden with B<-q>).
2101
2102 =item UBOOT_CMD
2103
2104 See L</--uboot-cmd>.
2105
2106 =item WVDESC
2107
2108 Description of the WvTest-compliant program.
2109
2110 =item WVTEST_TIMEOUT
2111
2112 The timeout in seconds for WvTest harness. If no complete line appears
2113 in the test output within the time specified here, the test fails. It
2114 is necessary to specify this for long running tests that produce no
2115 intermediate output.
2116
2117 =back
2118
2119 =head1 CONFIGURATION FILES
2120
2121 Novaboot can read its configuration from one or more files. By
2122 default, novaboot looks for files in F</etc/novaboot.d>, file
2123 F<~/.config/novaboot> and files named F<.novaboot> as described in
2124 L</Configuration reading phase>. Alternatively, configuration file
2125 location can be specified with the B<-c> switch or with the
2126 NOVABOOT_CONFIG environment variable. The configuration file has Perl
2127 syntax (i.e. it is better to put C<1;> as the last line) and should set
2128 values of certain Perl variables. The current configuration can be
2129 dumped with the B<--dump-config> switch. Some configuration variables
2130 can be overridden by environment variables (see below) or by command
2131 line switches.
2132
2133 Supported configuration variables include:
2134
2135 =over 8
2136
2137 =item $builddir
2138
2139 Build directory location relative to the location of the configuration
2140 file.
2141
2142 =item $default_target
2143
2144 Default target (see below) to use when no target is explicitly
2145 specified with the B<--target> command line option or
2146 B<NOVABOOT_TARGET> environment variable.
2147
2148 =item %targets
2149
2150 Hash of target definitions to be used with the B<--target> option. The
2151 key is the identifier of the target, the value is the string with
2152 command line options. For instance, if the configuration file contains:
2153
2154  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
2155
2156 then the following two commands are equivalent:
2157
2158  ./myos --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
2159  ./myos -t mybox
2160
2161 =back
2162
2163 =head1 ENVIRONMENT VARIABLES
2164
2165 Some options can be specified not only via config file or command line
2166 but also through environment variables. Environment variables override
2167 the values from the configuration file and command line parameters
2168 override the environment variables.
2169
2170 =over 8
2171
2172 =item NOVABOOT_CONFIG
2173
2174 Name of the novaboot configuration file to use instead of the default
2175 one(s).
2176
2177 =item NOVABOOT_CONFIG_DIR
2178
2179 Name of the novaboot configuration directory. When not specified
2180 F</etc/novaboot.d> is used.
2181
2182 =item NOVABOOT_TARGET
2183
2184 Name of the novaboot target to use. This overrides the value of
2185 B<$default_target> from the configuration file and can be overridden
2186 with the B<--target> command line option.
2187
2188 =item NOVABOOT_BENDER
2189
2190 Defining this variable has the same effect as using B<--bender>
2191 option.
2192
2193 =back
2194
2195 =head1 AUTHORS
2196
2197 Michal Sojka <sojka@os.inf.tu-dresden.de>
2198
2199 Latest novaboot version can be found at
2200 L<https://github.com/wentasah/novaboot>.
2201
2202 =cut
2203
2204 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2205 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2206 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2207 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest