novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use IO::Handle;
  26 use Time::HiRes("usleep");
  27 use Socket;
  28 use FileHandle;
  29 use IPC::Open2;
  30 use POSIX qw(:errno_h sysconf);
  31 use Cwd qw(getcwd abs_path);
  32 use Expect;
  33
  34 # always flush
  35 $| = 1;
  36
  37 my $invocation_dir = $ENV{PWD} || getcwd();
  38
  39 ## Configuration file handling
  40
  41 # Default configuration
  42 $CFG::hypervisor = "";
  43 $CFG::hypervisor_params = "serial";
  44 $CFG::genisoimage = "genisoimage";
  45 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  46 $CFG::default_target = '';
  47 %CFG::targets = (
  48     'qemu' => '--qemu',
  49     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  50     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.86.92:2324',
  51     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  52     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  53     "ryuglab" => '--target ryu --server=pc-sojkam.felk.cvut.cz:/srv/tftp --remote-cmd="ssh -tt pc-sojkam.felk.cvut.cz \"sterm -d -s 115200 /dev/ttyUSB0\""',
  54     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  55     );
  56
  57 {
  58     my %const;
  59     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  60     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  61
  62     $CFG::scons = "scons -j$nproc";
  63     $CFG::make = "make -j$nproc";
  64 }
  65
  66 my $builddir;
  67
  68 sub read_config($) {
  69     my ($cfg) = @_;
  70     {
  71         package CFG; # Put config data into a separate namespace
  72
  73         my $rc = do($cfg);
  74
  75         # Check for errors
  76         if ($@) {
  77             die("ERROR: Failure compiling '$cfg' - $@");
  78         } elsif (! defined($rc)) {
  79             die("ERROR: Failure reading '$cfg' - $!");
  80         } elsif (! $rc) {
  81             die("ERROR: Failure processing '$cfg'");
  82         }
  83     }
  84     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  85     print STDERR "novaboot: Read $cfg\n";
  86 }
  87
  88 my @cfgs;
  89 {
  90     # We don't use $0 here, because it points to the novaboot itself and
  91     # not to the novaboot script. The problem with this approach is that
  92     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  93     # contains the first option. Hence the -f check.
  94     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  95     while ((-d $dir || -l $dir ) && $dir ne "/") {
  96         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  97         my @dirs = File::Spec->splitdir($dir);
  98         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  99     }
 100     @cfgs = reverse @cfgs;
 101
 102     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 103     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 104
 105     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 106     if (opendir(my $dh, $dir)) {
 107         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 108         closedir $dh;
 109         @etccfg = sort(@etccfg);
 110         @cfgs = ( @etccfg, @cfgs );
 111     }
 112 }
 113 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 114 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 115 GetOptions ("config|c=s" => \$cfg);
 116 read_config($_) foreach $cfg or @cfgs;
 117
 118 ## Command line handling
 119
 120 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 121 GetOptions ("target|t=s" => \$explicit_target);
 122
 123 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iso_image, $interactive, $kernel_opt, $make, $man, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $remote_expect_silent, $reset, $reset_cmd, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init);
 124
 125 %uboot_addr = (
 126     'kernel'  => '${kernel_addr_r}',
 127     'ramdisk' => '${ramdisk_addr_r}',
 128     'fdt'     => '${fdt_addr_r}',
 129     );
 130
 131 $rsync_flags = '';
 132 $rom_prefix = 'rom://';
 133 $stty = 'raw -crtscts -onlcr 115200';
 134 $reset = 1;                     # Reset target by default
 135 $interaction = 1;               # Perform target interaction by default
 136
 137 my @expect_seen = ();
 138 sub handle_expect
 139 {
 140     my ($n, $v) = @_;
 141     push(@expect_seen, '-re') if $n eq "expect-re";
 142     push(@expect_seen, $v);
 143 }
 144
 145 sub handle_send
 146 {
 147     my ($n, $v) = @_;
 148     unless (@expect_seen) { die("No --expect before --send"); }
 149     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 150     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 151     unshift(@expect_raw, @expect_seen);
 152     @expect_seen = ();
 153 }
 154
 155 my %opt_spec;
 156 %opt_spec = (
 157     "amt=s"          => \$amt,
 158     "append|a=s"     => \@append,
 159     "bender|b"       => \$bender,
 160     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 161     "concat"         => \$concat,
 162     "chainloader=s"  => \@chainloaders,
 163     "dhcp-tftp|d"    => \$dhcp_tftp,
 164     "dump"           => \$dump_opt,
 165     "dump-config"    => \$dump_config,
 166     "exiton=s"       => \@exiton,
 167     "exiton-timeout=i"=> \$exiton_timeout,
 168     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 169     "expect=s"       => \&handle_expect,
 170     "expect-re=s"    => \&handle_expect,
 171     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 172     "gen-only"       => \$gen_only,
 173     "grub|g:s"       => \$grub_config,
 174     "grub-preamble=s"=> \$grub_preamble,
 175     "prefix|grub-prefix=s" => \$grub_prefix,
 176     "grub2:s"        => \$grub2_config,
 177     "grub2-prolog=s" => \$grub2_prolog,
 178     "ider"           => \$ider,
 179     "interaction!"   => \$interaction,
 180     "iprelay=s"      => \$iprelay,
 181     "iso:s"          => \$iso_image,
 182     "kernel|k=s"     => \$kernel_opt,
 183     "interactive|i"  => \$interactive,
 184     "name=s"         => \$config_name_opt,
 185     "make|m:s"       => \$make,
 186     "no-file-gen"    => \$no_file_gen,
 187     "off"            => \$off_opt,
 188     "on"             => \$on_opt,
 189     "pulsar|p:s"     => \$pulsar,
 190     "pulsar-root=s"  => \$pulsar_root,
 191     "qemu|Q:s"       => \$qemu,
 192     "qemu-append=s"  => \$qemu_append,
 193     "qemu-flags|q=s" => \$qemu_flags_cmd,
 194     "remote-cmd=s"   => \$remote_cmd,
 195     "remote-expect=s"=> \$remote_expect,
 196     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 197     "reset!"         => \$reset,
 198     "reset-cmd=s"    => \$reset_cmd,
 199     "rsync-flags=s"  => \$rsync_flags,
 200     "scons:s"        => \$scons,
 201     "scriptmod=s"    => \@scriptmod,
 202     "send=s"         => \&handle_send,
 203     "sendcont=s"     => \&handle_send,
 204     "serial|s:s"     => \$serial,
 205     "server:s"       => \$server,
 206     "strip-rom"      => sub { $rom_prefix = ''; },
 207     "stty=s"         => \$stty,
 208     "tftp"           => \$tftp,
 209     "tftp-port=i"    => \$tftp_port,
 210     "uboot:s"        => \$uboot,
 211     "no-uboot"       => sub { undef $uboot; },
 212     "uboot-addr=s"   => \%uboot_addr,
 213     "uboot-cmd=s"    => \$uboot_cmd,
 214     "uboot-init=s"   => \@uboot_init,
 215     "h"              => \$help,
 216     "help"           => \$man,
 217     );
 218
 219 # First process target options
 220 {
 221     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 222     my @target_expanded;
 223     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 224     while ($t) {
 225         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 226
 227         undef $explicit_target;
 228         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 229         if (!$ret) { die "Error parsing target $t option"; }
 230         push(@target_expanded, @$remaining_args);
 231         $t = $explicit_target;
 232     }
 233     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 234     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 235 }
 236
 237 # Then process other command line options - some of them may override
 238 # what was specified by the target
 239 GetOptions %opt_spec or die("Error in command line arguments");
 240 pod2usage(1) if $help;
 241 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 242
 243 ### Dump sanitized configuration (if requested)
 244
 245 if ($dump_config) {
 246     use Data::Dumper;
 247     $Data::Dumper::Indent=1;
 248     print "# This file is in perl syntax.\n";
 249     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 250         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 251         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 252         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 253     }
 254     print "1;\n";
 255     exit;
 256 }
 257
 258 ### Sanitize configuration
 259
 260 if ($interactive && !-t STDIN) {
 261     die("novaboot: Interactive mode not supported when not on terminal");
 262 }
 263
 264 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 265
 266 if ($ider) {
 267     $iso_image //= ''; # IDE-R needs an ISO image
 268     if (!defined $amt) { die "Error: --ider requires --amt"; }
 269 }
 270
 271 {
 272     my %input_opts = ('--iprelay'    => \$iprelay,
 273                       '--serial'     => \$serial,
 274                       '--remote-cmd' => \$remote_cmd,
 275                       '--amt'        => \$amt);
 276     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 277
 278     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 279 }
 280
 281 # Default options
 282 if (defined $serial) {
 283     $serial ||= "/dev/ttyUSB0";
 284     $ENV{NB_SERIAL} = $serial;
 285 }
 286 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 287 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 288
 289 ## Parse the novaboot script(s)
 290 my @scripts;
 291 my $file;
 292 my $EOF;
 293 my $last_fn = '';
 294 my ($modules, $variables, $generated, $continuation) = ([], {}, []);
 295 my $skip_reading = defined($on_opt) || defined($off_opt);
 296 while (!$skip_reading && ($_ = <>)) {
 297     if ($ARGV ne $last_fn) { # New script
 298         die "Missing EOF in $last_fn" if $file;
 299         die "Unfinished line in $last_fn" if $continuation;
 300         $last_fn = $ARGV;
 301         push @scripts, { 'filename' => $ARGV,
 302                          'modules' => $modules = [],
 303                          'variables' => $variables = {},
 304                          'generated' => $generated = []};
 305
 306     }
 307     chomp();
 308     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 309
 310     $_ =~ s/^[[:space:]]*// if ($continuation);
 311
 312     if (/\\$/) {                # Line continuation
 313         $continuation .= substr($_, 0, length($_)-1);
 314         next;
 315     }
 316
 317     if ($continuation) {        # Last continuation line
 318         $_ = $continuation . $_;
 319         $continuation = '';
 320     }
 321
 322     foreach my $mod(@scriptmod) { eval $mod; }
 323
 324     if ($file && $_ eq $EOF) {  # Heredoc end
 325         undef $file;
 326         next;
 327     }
 328     if ($file) {                # Heredoc content
 329         push @{$file}, "$_\n";
 330         next;
 331     }
 332     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 333         $$variables{$1} = $2;
 334         push(@exiton, $2) if ($1 eq "EXITON");
 335         next;
 336     }
 337     if (s/^load *//) {          # Load line
 338         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 339         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 340             push @$modules, "$1$2";
 341             $file = [];
 342             push @$generated, {filename => $1, content => $file};
 343             $EOF = $3;
 344             next;
 345         }
 346         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 347             push @$modules, "$1$2";
 348             push @$generated, {filename => $1, command => $3};
 349             next;
 350         }
 351         push @$modules, $_;
 352         next;
 353     }
 354     if (/^run (.*)/) {          # run line
 355         push @$generated, {command => $1};
 356         next;
 357     }
 358     if (/^uboot(?::([0-9]+)s)? (.*)/) { # uboot line
 359         # TODO: If U-Boot supports some interactive menu, it might
 360         # make sense to store uboot lines per novaboot script.
 361         if ($1) {               # Command with explicit timeout
 362             push @uboot_init, { command => $2,
 363                                 timeout => $1 };
 364         } else {                # Command without explicit timeout
 365             push @uboot_init, $2;
 366         }
 367         next;
 368     }
 369
 370     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 371 }
 372 # use Data::Dumper;
 373 # print Dumper(\@scripts);
 374
 375 foreach my $script (@scripts) {
 376     $modules = $$script{modules};
 377     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 378     @$modules[0] .= ' ' . join(' ', @append) if @append;
 379
 380     my $kernel;
 381     if (exists $variables->{KERNEL}) {
 382         $kernel = $variables->{KERNEL};
 383     } else {
 384         if ($CFG::hypervisor) {
 385             $kernel = $CFG::hypervisor . " ";
 386             if (exists $variables->{HYPERVISOR_PARAMS}) {
 387                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 388             } else {
 389                 $kernel .= $CFG::hypervisor_params;
 390             }
 391         }
 392     }
 393     @$modules = ($kernel, @$modules) if $kernel;
 394     @$modules = (@chainloaders, @$modules);
 395     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 396 }
 397
 398 if ($dump_opt) {
 399     foreach my $script (@scripts) {
 400         print join("\n", @{$$script{modules}})."\n";
 401     }
 402     exit(0);
 403 }
 404
 405 ## Helper functions
 406
 407 sub generate_configs($$$) {
 408     my ($base, $generated, $filename) = @_;
 409     if ($base) { $base = "$base/"; };
 410     foreach my $g(@$generated) {
 411       if (exists $$g{content}) {
 412         my $config = $$g{content};
 413         my $fn = $$g{filename};
 414         open(my $f, '>', $fn) || die("$fn: $!");
 415         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 416         close($f);
 417         print STDERR "novaboot: Created $fn\n";
 418       } elsif (exists $$g{command} && ! $no_file_gen) {
 419         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 420         if (exists $$g{filename}) {
 421             system_verbose("( $$g{command} ) > $$g{filename}");
 422         } else {
 423             system_verbose($$g{command});
 424         }
 425       }
 426     }
 427 }
 428
 429 sub generate_grub_config($$$$;$)
 430 {
 431     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 432     if ($base) { $base = "$base/"; };
 433     open(my $fg, '>', $filename) or die "$filename: $!";
 434     print $fg "$preamble\n" if $preamble;
 435     print $fg "title $title\n" if $title;
 436     #print $fg "root $base\n"; # root doesn't really work for (nd)
 437     my $first = 1;
 438     foreach (@$modules_ref) {
 439         if ($first) {
 440             $first = 0;
 441             my ($kbin, $kcmd) = split(' ', $_, 2);
 442             $kcmd = '' if !defined $kcmd;
 443             print $fg "kernel ${base}$kbin $kcmd\n";
 444         } else {
 445             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 446             print $fg "module $base$_\n";
 447         }
 448     }
 449     close($fg);
 450     print("novaboot: Created $builddir/$filename\n");
 451     return $filename;
 452 }
 453
 454 sub generate_syslinux_config($$$$)
 455 {
 456     my ($filename, $title, $base, $modules_ref) = @_;
 457     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 458     open(my $fg, '>', $filename) or die "$filename: $!";
 459     print $fg "LABEL $title\n";
 460     #TODO print $fg "MENU LABEL $human_readable_title\n";
 461
 462     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 463
 464     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 465         my $initrd = @$modules_ref[1];
 466         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 467         print $fg "LINUX $base$kbin\n";
 468         print $fg "APPEND $kcmd\n";
 469         print $fg "INITRD $base$initrd\n";
 470     } else {
 471         print $fg "KERNEL mboot.c32\n";
 472         my @append;
 473         foreach (@$modules_ref) {
 474             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 475             push @append, "$base$_";
 476             print $fg "APPEND ".join(' --- ', @append)."\n";
 477         }
 478     }
 479     #TODO print $fg "TEXT HELP\n";
 480     #TODO print $fg "some help here\n";
 481     #TODO print $fg "ENDTEXT\n";
 482     close($fg);
 483     print("novaboot: Created $builddir/$filename\n");
 484     return $filename;
 485 }
 486
 487 sub generate_grub2_config($$$$;$$)
 488 {
 489     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 490     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 491     open(my $fg, '>', $filename) or die "$filename: $!";
 492     print $fg "$preamble\n" if $preamble;
 493     $title ||= 'novaboot';
 494     print $fg "menuentry $title {\n";
 495     print $fg "$prolog\n" if $prolog;
 496     my $first = 1;
 497     foreach (@$modules_ref) {
 498         if ($first) {
 499             $first = 0;
 500             my ($kbin, $kcmd) = split(' ', $_, 2);
 501             $kcmd = '' if !defined $kcmd;
 502             print $fg "  multiboot ${base}$kbin $kcmd\n";
 503         } else {
 504             my @args = split;
 505             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 506             $_ = join(' ', ($args[0], @args));
 507             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 508             print $fg "  module $base$_\n";
 509         }
 510     }
 511     print $fg "}\n";
 512     close($fg);
 513     print("novaboot: Created $builddir/$filename\n");
 514     return $filename;
 515 }
 516
 517 sub generate_pulsar_config($$)
 518 {
 519     my ($filename, $modules_ref) = @_;
 520     open(my $fg, '>', $filename) or die "$filename: $!";
 521     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 522     my $first = 1;
 523     my ($kbin, $kcmd);
 524     foreach (@$modules_ref) {
 525         if ($first) {
 526             $first = 0;
 527             ($kbin, $kcmd) = split(' ', $_, 2);
 528             $kcmd = '' if !defined $kcmd;
 529         } else {
 530             my @args = split;
 531             s|\brom://|$rom_prefix|g;
 532             print $fg "load $_\n";
 533         }
 534     }
 535     # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 536     print $fg "exec $kbin $kcmd\n";
 537     close($fg);
 538     print("novaboot: Created $builddir/$filename\n");
 539     return $filename;
 540 }
 541
 542 sub shell_cmd_string(@)
 543 {
 544     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 545 }
 546
 547 sub exec_verbose(@)
 548 {
 549     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 550     exec(@_);
 551     exit(1); # should not be reached
 552 }
 553
 554 sub system_verbose($)
 555 {
 556     my $cmd = shift;
 557     print STDERR "novaboot: Running: $cmd\n";
 558     my $ret = system($cmd);
 559     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 560     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 561     if ($ret) { die("Command failure $ret"); }
 562 }
 563
 564 sub trim($) {
 565     my ($str) = @_;
 566     $str =~ s/^\s+|\s+$//g;
 567     return $str
 568 }
 569
 570 ## WvTest headline
 571
 572 if (exists $variables->{WVDESC}) {
 573     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 574 } elsif ($last_fn =~ /\.wv$/) {
 575     print STDERR "Testing \"all\" in $last_fn:\n";
 576 }
 577
 578 ## Connect to the target and check whether it is not occupied
 579
 580 # We have to do this before file generation phase, because file
 581 # generation is intermixed with file deployment phase and we want to
 582 # check whether the target is not used by somebody else before
 583 # deploying files. Otherwise, we may rewrite other user's files on a
 584 # boot server.
 585
 586 my $exp; # Expect object to communicate with the target over serial line
 587
 588 my ($target_reset, $target_power_on, $target_power_off);
 589 my ($amt_user, $amt_password, $amt_host, $amt_port);
 590
 591 if (defined $iprelay) {
 592     my $IPRELAY;
 593     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 594     my $addr = $1;
 595     my $port = $3 || 23;
 596     my $paddr   = sockaddr_in($port, inet_aton($addr));
 597     my $proto   = getprotobyname('tcp');
 598     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 599     print STDERR "novaboot: Connecting to IP relay... ";
 600     connect($IPRELAY, $paddr)    || die "connect: $!";
 601     print STDERR "done\n";
 602     $exp = Expect->init(\*$IPRELAY);
 603     $exp->log_stdout(1);
 604
 605     while (1) {
 606         print $exp "\xFF\xF6";  # AYT
 607         my $connected = $exp->expect(20, # Timeout in seconds
 608                                      '<iprelayd: connected>',
 609                                      '-re', '<WEB51 HW[^>]*>');
 610         last if $connected;
 611     }
 612
 613     sub relaycmd($$) {
 614         my ($relay, $onoff) = @_;
 615         die unless ($relay == 1 || $relay == 2);
 616
 617         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 618         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 619     }
 620
 621     sub relayconf($$) {
 622         my ($relay, $onoff) = @_;
 623         die unless ($relay == 1 || $relay == 2);
 624         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 625         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 626     }
 627
 628     sub relay($$;$) {
 629         my ($relay, $onoff, $can_giveup) = @_;
 630         my $confirmation = '';
 631         $exp->log_stdout(0);
 632         print $exp relaycmd($relay, $onoff);
 633         my $confirmed = $exp->expect(20, # Timeout in seconds
 634                                      relayconf($relay, $onoff));
 635         if (!$confirmed) {
 636             if ($can_giveup) {
 637                 print("Relay confirmation timeout - ignoring\n");
 638             } else {
 639                 die "Relay confirmation timeout";
 640             }
 641         }
 642         $exp->log_stdout(1);
 643     }
 644
 645     $target_reset = sub {
 646         relay(2, 1, 1); # Reset the machine
 647         usleep(100000);
 648         relay(2, 0);
 649     };
 650
 651     $target_power_off = sub {
 652         relay(1, 1);            # Press power button
 653         usleep(6000000);        # Long press to switch off
 654         relay(1, 0);
 655     };
 656
 657     $target_power_on = sub {
 658         relay(1, 1);            # Press power button
 659         usleep(100000);         # Short press
 660         relay(1, 0);
 661     };
 662 }
 663 elsif ($serial) {
 664     my $CONN;
 665     system_verbose("stty -F $serial $stty");
 666     open($CONN, "+<", $serial) || die "open $serial: $!";
 667     $exp = Expect->init(\*$CONN);
 668 }
 669 elsif ($remote_cmd) {
 670     print STDERR "novaboot: Running: $remote_cmd\n";
 671     $exp = Expect->spawn($remote_cmd);
 672 }
 673 elsif (defined $amt) {
 674     require LWP::UserAgent;
 675     require LWP::Authen::Digest;
 676
 677     sub genXML {
 678         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 679         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 680         my %pstates = ("on"        => 2,
 681                        "standby"   => 4,
 682                        "hibernate" => 7,
 683                        "off"       => 8,
 684                        "reset"     => 10,
 685                        "MNI"       => 11);
 686         return <<END;
 687                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 688                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 689                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 690                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 691                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 692                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 693                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 694                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 695                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 696                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 697                 </s:Header><s:Body>
 698                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 699                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 700                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 701                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 702                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 703                 </a:ReferenceParameters></p:ManagedElement>
 704                 </p:RequestPowerStateChange_INPUT>
 705                 </s:Body></s:Envelope>
 706 END
 707     }
 708
 709     sub sendPOST {
 710         my ($host, $username, $password, $content) = @_;
 711
 712         my $ua = LWP::UserAgent->new();
 713         $ua->agent("novaboot");
 714
 715         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 716         my $res = $ua->request($req);
 717         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 718
 719         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 720         $ua->credentials("$host:16992", $realm, $username => $password);
 721
 722         # Create a request
 723         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 724         $req->content_type('application/x-www-form-urlencoded');
 725         $req->content($content);
 726         $res = $ua->request($req);
 727         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 728         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 729         return $1;
 730     }
 731
 732     sub powerChange  {
 733         my ($host, $username, $password, $pstate)=@_;
 734         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 735         my $className="/RequestPowerStateChange";
 736         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 737         return sendPOST($host, $username, $password, $content);
 738     }
 739
 740     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 741     $amt_user ||= "admin";
 742     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 743     $amt_host || die "AMT host not specified";
 744     $amt_port ||= 16994;
 745
 746
 747     $target_power_off = sub {
 748         $exp->close();
 749         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 750         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 751     };
 752
 753     $target_power_on = sub {
 754         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 755         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 756     };
 757
 758     $target_reset = sub {
 759         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 760         if ($result != 0) {
 761             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 762             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 763         }
 764         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 765     };
 766
 767     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 768     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 769     $exp = Expect->spawn($cmd);
 770     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL' timed out";
 771
 772 }
 773
 774
 775 if ($remote_expect) {
 776     $exp || die("No serial line connection");
 777     my $log = $exp->log_stdout;
 778     if (defined $remote_expect_silent) {
 779         $exp->log_stdout(0);
 780     }
 781     $exp->expect(180, $remote_expect) || die "Expect for '$remote_expect' timed out";
 782     if (defined $remote_expect_silent) {
 783         $exp->log_stdout($log);
 784         print $exp->after() if $log;
 785     }
 786 }
 787
 788 if (defined $reset_cmd) {
 789     $target_reset = sub {
 790         system_verbose($reset_cmd);
 791     };
 792 }
 793
 794 if (defined $on_opt && defined $target_power_on) {
 795     &$target_power_on();
 796     exit;
 797 }
 798 if (defined $off_opt && defined $target_power_off) {
 799     print STDERR "novaboot: Switching the target off...\n";
 800     &$target_power_off();
 801     exit;
 802 }
 803
 804 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 805 if (defined $builddir) {
 806     chdir($builddir) or die "Can't change directory to $builddir: $!";
 807     print STDERR "novaboot: Entering directory `$builddir'\n";
 808 } else {
 809     $builddir = $invocation_dir;
 810 }
 811
 812 ## File generation phase
 813 my (%files_iso, $menu_iso, $filename);
 814 my $config_name = '';
 815 my $prefix = '';
 816
 817 foreach my $script (@scripts) {
 818     $filename = $$script{filename};
 819     $modules = $$script{modules};
 820     $generated = $$script{generated};
 821     $variables = $$script{variables};
 822
 823     ($config_name = $filename) =~ s#.*/##;
 824     $config_name = $config_name_opt if (defined $config_name_opt);
 825
 826     if (exists $variables->{BUILDDIR}) {
 827         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 828         chdir($builddir) or die "Can't change directory to $builddir: $!";
 829         print STDERR "novaboot: Entering directory `$builddir'\n";
 830     }
 831
 832     if ($grub_prefix) {
 833         $prefix = $grub_prefix;
 834         $prefix =~ s/\$NAME/$config_name/;
 835         $prefix =~ s/\$BUILDDIR/$builddir/;
 836     }
 837     # TODO: use $grub_prefix as first parameter if some switch is given
 838     generate_configs('', $generated, $filename);
 839
 840 ### Generate bootloader configuration files
 841     my @bootloader_configs;
 842     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 843     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 844     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules) if (defined $pulsar);
 845
 846 ### Run scons or make
 847     {
 848         my @files = map({ ($file) = m/([^ ]*)/; $file; } @$modules);
 849         # Filter-out generated files
 850         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 851
 852         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 853         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 854     }
 855
 856 ### Copy files (using rsync)
 857     if (defined $server && !defined($gen_only)) {
 858         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 859
 860         my ($hostname, $path) = split(":", $real_server, 2);
 861         if (! defined $path) {
 862             $path = $hostname;
 863             $hostname = "";
 864         }
 865         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs)));
 866         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 867         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 868         my $progress = $istty ? "--progress" : "";
 869         system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 870         if ($server =~ m|/\$NAME$| && $concat) {
 871             my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 872             system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 873         }
 874     }
 875
 876 ### Prepare ISO image generation
 877     if (defined $iso_image) {
 878         generate_configs("(cd)", $generated, $filename);
 879         my $menu;
 880         generate_syslinux_config(\$menu, $config_name, "/", $modules);
 881         $menu_iso .= "$menu\n";
 882         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 883     }
 884 }
 885
 886 ## Generate ISO image
 887 if (defined $iso_image) {
 888     system_verbose("mkdir -p isolinux");
 889
 890     my @files;
 891     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
 892         # Newer ISOLINUX version
 893         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
 894     } else {
 895         # Older ISOLINUX version
 896         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
 897     }
 898     system_verbose("cp @files isolinux");
 899     open(my $fh, ">isolinux/isolinux.cfg");
 900     if ($#scripts) {
 901         print $fh "TIMEOUT 50\n";
 902         print $fh "DEFAULT menu\n";
 903     } else {
 904         print $fh "DEFAULT $config_name\n";
 905     }
 906     print $fh "$menu_iso";
 907     close($fh);
 908
 909     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
 910     $iso_image ||= "$config_name.iso";
 911
 912     # Note: We use -U flag below to "Allow 'untranslated' filenames,
 913     # completely violating the ISO9660 standards". Without this
 914     # option, isolinux is not able to read files names for example
 915     # bzImage-3.0.
 916     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
 917     print("ISO image created: $builddir/$iso_image\n");
 918 }
 919
 920 exit(0) if defined $gen_only;
 921
 922 ## Boot the system using various methods and send serial output to stdout
 923
 924 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 925     die "You cannot do this with multiple scripts simultaneously";
 926 }
 927
 928 if ($variables->{WVTEST_TIMEOUT}) {
 929     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 930 }
 931
 932 ### Start in Qemu
 933
 934 if (defined $qemu) {
 935     # Qemu
 936     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 937     my @qemu_flags = split(" ", $qemu);
 938     $qemu = shift(@qemu_flags);
 939
 940     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 941     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 942     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 943
 944     if (defined $iso_image) {
 945         # Boot NOVA with grub (and test the iso image)
 946         push(@qemu_flags, ('-cdrom', $iso_image));
 947     } else {
 948         # Boot NOVA without GRUB
 949
 950         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 951         foreach (@$modules) {s/,/+/g;}
 952         generate_configs("", $generated, $filename);
 953
 954         if (scalar @$modules) {
 955             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 956             $kcmd = '' if !defined $kcmd;
 957             my $dtb;
 958             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 959             my $initrd = join ",", @$modules;
 960
 961             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
 962             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
 963             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
 964         }
 965     }
 966     push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
 967     unshift(@qemu_flags, ('-name', $config_name));
 968     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
 969     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
 970 }
 971
 972 ### Local DHCPD and TFTPD
 973
 974 my ($dhcpd_pid, $tftpd_pid);
 975
 976 $tftp=1 if $tftp_port;
 977
 978 if (defined $dhcp_tftp)
 979 {
 980     generate_configs("(nd)", $generated, $filename);
 981     system_verbose('mkdir -p tftpboot');
 982     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
 983     open(my $fh, '>', 'dhcpd.conf');
 984     my $mac = `cat /sys/class/net/eth0/address`;
 985     chomp $mac;
 986     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
 987                       range 10.23.23.10 10.23.23.100;
 988                       filename \"bin/boot/grub/pxegrub.pxe\";
 989                       next-server 10.23.23.1;
 990 }
 991 host server {
 992         hardware ethernet $mac;
 993         fixed-address 10.23.23.1;
 994 }";
 995     close($fh);
 996     system_verbose("sudo ip a add 10.23.23.1/24 dev eth0;
 997             sudo ip l set dev eth0 up;
 998             sudo touch dhcpd.leases");
 999
1000     # We run servers by forking ourselves, because the servers end up
1001     # in our process group and get killed by signals sent to the
1002     # process group (e.g. Ctrl-C on terminal).
1003     $dhcpd_pid = fork();
1004     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1005 }
1006
1007 if (defined $dhcp_tftp || defined $tftp) {
1008     $tftp_port ||= 69;
1009     # Unfortunately, tftpd requires root privileges even with
1010     # non-privileged (>1023) port due to initgroups().
1011     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
1012
1013     # Kill server when we die
1014     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1015                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1016
1017     # We have to kill tftpd explicitely, because it is not in our process group
1018     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1019 }
1020
1021 ### AMT IDE-R
1022 if (defined $ider) {
1023     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1024     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1025     my $ider_pid = fork();
1026     if ($ider_pid == 0) {
1027         exec($ider_cmd);
1028         die "IDE redirection failed";
1029     }
1030     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1031     # to use both simultaneously.
1032     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1033 }
1034
1035 ### Reset target (IP relay, AMT, ...)
1036
1037 if (defined $target_reset && $reset) {
1038     print STDERR "novaboot: Reseting the test box... ";
1039     &$target_reset();
1040     print STDERR "done\n";
1041     if (defined $exp) {
1042         # We don't want to output anything printed by the target
1043         # before reset so we clear the buffers now. This is, however,
1044         # not ideal because we may loose some data that were sent
1045         # after the reset. If this is a problem, one should reset and
1046         # connect to serial line in atomic manner. For example, if
1047         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1048         # do not use separate --reset-cmd.
1049         my $log = $exp->log_stdout;
1050         $exp->log_stdout(0);
1051         $exp->expect(0); # Read data from target
1052         $exp->clear_accum();    # Clear the read data
1053         $exp->log_stdout($log);
1054     }
1055 }
1056
1057 ### U-boot conversation
1058 if (defined $uboot) {
1059     my $uboot_prompt = $uboot || '=> ';
1060     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1061     $exp || die("No serial line connection");
1062     $exp->log_stdout(1);
1063     #$exp->exp_internal(1);
1064     $exp->expect(20,
1065                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
1066                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1067     foreach my $cmdspec (@uboot_init) {
1068         my ($cmd, $timeout);
1069         if (ref($cmdspec) eq "HASH") {
1070             $cmd = $cmdspec->{command};
1071             $timeout = $cmdspec->{timeout};
1072         } else {
1073             $cmd = $cmdspec;
1074             $timeout = 10;
1075         }
1076         if ($cmd =~ /\$NB_MYIP/) {
1077             my $ip = (grep /inet /, `ip addr show eth0`)[0] || die "Problem determining our IP address";
1078             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1079             $cmd =~ s/\$NB_MYIP/$ip/g;
1080         }
1081         if ($cmd =~ /\$NB_PREFIX/) {
1082             my $p = $prefix;
1083             $p =~ s|/*$||;
1084             $cmd =~ s/\$NB_PREFIX/$p/g;
1085         }
1086         chomp($cmd);
1087         $exp->send("$cmd\n");
1088         $exp->expect($timeout, $uboot_prompt) || die "U-Boot prompt timeout";
1089     }
1090
1091     # Boot the system if there are some load lines in the script
1092     if ((scalar(@$modules) > 0 && !$variables->{NO_BOOT}) ||
1093         defined $uboot_cmd) {
1094         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1095         my $dtb;
1096         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1097         my $initrd = shift @$modules;
1098
1099         if (defined $kbin) {
1100             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1101             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1102             $exp->expect(10,
1103                          [qr/##/, sub { exp_continue; }],
1104                          $uboot_prompt) || die "Kernel load timeout";
1105         }
1106         if (defined $dtb) {
1107             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1108             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1109             $exp->expect(10,
1110                          [qr/##/, sub { exp_continue; }],
1111                          $uboot_prompt) || die "Device tree load timeout";
1112         }
1113         if (defined $initrd) {
1114             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1115             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1116             $exp->expect(10,
1117                          [qr/##/, sub { exp_continue; }],
1118                          $uboot_prompt) || die "Initrd load timeout";
1119         } else {
1120             $uboot_addr{ramdisk} = '-';
1121         }
1122
1123         $kcmd //= '';
1124         $exp->send("setenv bootargs $kcmd\n");
1125         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt timeout";
1126
1127         $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1128         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1129         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1130         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1131
1132         $exp->send($uboot_cmd . "\n");
1133         $exp->expect(5, "\n")  || die "U-Boot command timeout";
1134     }
1135 }
1136
1137 ### Serial line interaction
1138 if ($interaction && defined $exp) {
1139     # Serial line of the target is available
1140     my $interrupt = 'Ctrl-C';
1141     if ($interactive && !@exiton) {
1142         $interrupt = '"~~."';
1143     }
1144     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1145     $exp->log_stdout(1);
1146     if (@exiton) {
1147         $exp->expect($exiton_timeout, @expect_raw, @exiton) || die("exiton timeout");
1148     } else {
1149         my @inputs = ($exp);
1150         my $infile = new IO::File;
1151         $infile->IO::File::fdopen(*STDIN,'r');
1152         my $in_object = Expect->exp_init($infile);
1153         $in_object->set_group($exp);
1154
1155         if ($interactive) {
1156             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1157             $in_object->manual_stty(0);   # Use raw terminal mode
1158         } else {
1159             $in_object->manual_stty(1);   # Do not modify terminal settings
1160         }
1161         push(@inputs, $in_object);
1162         #use Data::Dumper;
1163         #print Dumper(\@expect_raw);
1164         $exp->expect(undef, @expect_raw) if @expect_raw;
1165         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1166     }
1167 }
1168
1169 ## Kill dhcpc or tftpd
1170 if (defined $dhcp_tftp || defined $tftp) {
1171     die("novaboot: This should kill servers on background\n");
1172 }
1173
1174 # Always finish novaboot output with newline
1175 print "\n";
1176
1177 ## Documentation
1178
1179 =head1 NAME
1180
1181 novaboot - Boots a locally compiled operating system on a remote
1182 target or in qemu
1183
1184 =head1 SYNOPSIS
1185
1186 B<novaboot> --help
1187
1188 B<novaboot> [option]... [--] script...
1189
1190 B<./script> [option]...
1191
1192 =head1 DESCRIPTION
1193
1194 This program makes booting of a locally compiled operating system (OS)
1195 (e.g. NOVA or Linux) on remote targets as simple as running a program
1196 locally. It automates things like copying OS images to a TFTP server,
1197 generation of bootloader configuration files, resetting of target
1198 hardware or redirection of target's serial line to stdin/out. Novaboot
1199 is highly configurable and it makes it easy to boot a single image on
1200 different targets or different images on a single target.
1201
1202 Novaboot operation is controlled by command line options and by a so
1203 called novaboot script, which can be thought as a generalization of
1204 bootloader configuration files (see L</"NOVABOOT SCRIPT SYNTAX">).
1205 Typical way of using novaboot is to make the novaboot script
1206 executable and set its first line to I<#!/usr/bin/env novaboot>. Then,
1207 booting a particular OS configuration becomes the same as executing a
1208 local program - the novaboot script.
1209
1210 Novaboot uses configuration files to, among other things, define
1211 command line options needed for different targets. Users typically use
1212 only the B<-t>/B<--target> command line option to select the target.
1213 Internally, this option expands to the pre-configured options.
1214 Configuration files are searched at multiple places, which allows to
1215 have per-system, per-user or per-project configurations. Configuration
1216 file syntax is described in section L</"CONFIGURATION FILE">.
1217
1218 Simple examples of using C<novaboot>:
1219
1220 =over 3
1221
1222 =item 1.
1223
1224 Run an OS in Qemu. This is can be specified with the B<--qemu> option.
1225 Thus running C<novaboot --qemu myos> (or C<./myos --qemu> as described
1226 above) will run Qemu and make it boot the configuration specified in
1227 the F<myos> script.
1228
1229 =item 2.
1230
1231 Create a bootloader configuration file (currently supported
1232 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar and U-Boot) and copy it
1233 with all other files needed for booting to a remote boot server. Then
1234 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1235 target and receive its serial output.
1236
1237  ./myos --grub2 --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1238
1239 =item 3.
1240
1241 Run DHCP and TFTP server on developer's machine to boot the target
1242 from it.
1243
1244  ./myos --dhcp-tftp
1245
1246 This is useful when no network infrastructure is in place and
1247 the target is connected directly to developer's box.
1248
1249 =item 4.
1250
1251 Create bootable ISO image.
1252
1253  novaboot --iso -- script1 script2
1254
1255 The created ISO image will have ISOLINUX bootloader installed on it
1256 and the boot menu will allow selecting between I<script1> and
1257 I<script2> configurations.
1258
1259 =back
1260
1261 =head1 PHASES AND OPTIONS
1262
1263 Novaboot performs its work in several phases. Each phase can be
1264 influenced by several command line options, certain phases can be
1265 skipped. The list of phases (in the execution order) is as follows.
1266
1267 =over
1268
1269 =item 1. L<Configuration reading|/Configuration reading phase>
1270
1271 =item 2. L<Command line processing|/Command line processing phase>
1272
1273 =item 3. L<Script preprocessing|/Script preprocessing phase>
1274
1275 =item 4. L<File generation|/File generation phase>
1276
1277 =item 5. L<Target connection|/Target connection check>
1278
1279 =item 6. L<File deployment|/File deployment phase>
1280
1281 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1282
1283 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1284
1285 =item 9. L<Target interaction|/Target interaction phase>
1286
1287 =back
1288
1289 Each phase is described in the following sections together with the
1290 command line options that control it.
1291
1292 =head2 Configuration reading phase
1293
1294 After starting, novaboot reads configuration files. Their content is
1295 described in section L</"CONFIGURATION FILE">. By default,
1296 configuration is read from multiple locations. First from the system
1297 configuration directory (F</etc/novaboot.d/>), second from the user
1298 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1299 files along the path to the current directory. Alternatively, a single
1300 configuration file specified with the B<-c> switch or with the
1301 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1302 override settings from the former ones.
1303
1304 The system configuration directory is determined by the content of
1305 NOVABOOT_CONFIG_DIR environment variable and defaults to
1306 F</etc/novaboot.d>. Files in this directory with names consisting
1307 solely of English letters, numbers, dashes '-' and underscores '_'
1308 (note that dot '.' is not included) are read in alphabetical order.
1309
1310 Then, the user configuration file is read from
1311 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environemnt
1312 variable is not set F<~/.config/novaboot> is read instead.
1313
1314 Finally, novaboot searches for files named F<.novaboot> starting from the
1315 directory of the novaboot script (or working directory, see bellow)
1316 and continuing upwards up to the root directory. The found
1317 configuration files are then read in the opposite order (i.e. from the
1318 root directory downwards). This allows to have, for example, a project
1319 specific configuration in F<~/project/.novaboot>.
1320
1321 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1322 The former one is read always, whereas the latter only when novaboot
1323 script or working directory is under the C<$HOME> directory.
1324
1325 In certain cases, the location of the novaboot script cannot be
1326 determined in this early phase. This happens either when the script is
1327 read from the standard input or when novaboot is invoked explicitly as
1328 in the example L</"4."> above. In this case the current working
1329 directory is used as a starting point for configuration file search
1330 instead of the novaboot script directory.
1331
1332 =over 8
1333
1334 =item -c, --config=I<filename>
1335
1336 Use the specified configuration file instead of the default one(s).
1337
1338 =back
1339
1340 =head2 Command line processing phase
1341
1342 =over 8
1343
1344 =item --dump-config
1345
1346 Dump the current configuration to stdout end exit. Useful as an
1347 initial template for a configuration file.
1348
1349 =item -h, --help
1350
1351 Print short (B<-h>) or long (B<--help>) help.
1352
1353 =item -t, --target=I<target>
1354
1355 This option serves as a user configurable shortcut for other novaboot
1356 options. The effect of this option is the same as specifying the
1357 options stored in the C<%targets> configuration variable under key
1358 I<target>. See also L</"CONFIGURATION FILE">.
1359
1360 When this option is not given, novaboot tries to determine the target
1361 to use from either B<NOVABOOT_TARGET> environment variable or from
1362 B<$default_target> configuration file variable.
1363
1364 =back
1365
1366 =head2 Script preprocessing phase
1367
1368 This phases allows to modify the parsed novaboot script before it is
1369 used in the later phases.
1370
1371 =over 8
1372
1373 =item -a, --append=I<parameters>
1374
1375 Append a string to the first C<load> line in the novaboot script. This
1376 can be used to append parameters to the kernel's or root task's
1377 command line. This option can appear multiple times.
1378
1379 =item -b, --bender
1380
1381 Use F<bender> chainloader. Bender scans the PCI bus for PCI serial
1382 ports and stores the information about them in the BIOS data area for
1383 use by the kernel.
1384
1385 =item --chainloader=I<chainloader>
1386
1387 Specifies a chainloader that is loaded before the kernel and other
1388 files specified in the novaboot script. E.g. 'bin/boot/bender
1389 promisc'.
1390
1391 =item --dump
1392
1393 Print the modules to boot and their parameters after this phase
1394 finishes. Then exit. This is useful for seeing the effect of other
1395 options in this section.
1396
1397 =item -k, --kernel=F<file>
1398
1399 Replace the first word on the first C<load> line in the novaboot
1400 script with F<file>.
1401
1402 =item --scriptmod=I<perl expression>
1403
1404 When novaboot script is read, I<perl expression> is executed for every
1405 line (in $_ variable). For example, C<novaboot
1406 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1407 in the script with I<omega6>.
1408
1409 When this option is present, it overrides I<$script_modifier> variable
1410 from the configuration file, which has the same effect. If this option
1411 is given multiple times all expressions are evaluated in the command
1412 line order.
1413
1414 =back
1415
1416 =head2 File generation phase
1417
1418 In this phase, files needed for booting are generated in a so called
1419 I<build directory> (see L</--build-dir>). In most cases configuration
1420 for a bootloader is generated automatically by novaboot. It is also
1421 possible to generate other files using I<heredoc> or I<"<"> syntax in
1422 novaboot scripts. Finally, binaries can be generated in this phases by
1423 running C<scons> or C<make>.
1424
1425 =over 8
1426
1427 =item --build-dir=I<directory>
1428
1429 Overrides the default build directory location.
1430
1431 The default build directory location is determined as follows: If the
1432 configuration file defines the C<$builddir> variable, its value is
1433 used. Otherwise, it is the directory that contains the first processed
1434 novaboot script.
1435
1436 See also L</BUILDDIR> variable.
1437
1438 =item -g, --grub[=I<filename>]
1439
1440 Generates grub bootloader menu file. If the I<filename> is not
1441 specified, F<menu.lst> is used. The I<filename> is relative to the
1442 build directory (see B<--build-dir>).
1443
1444 =item --grub-preamble=I<prefix>
1445
1446 Specifies the I<preable> that is at the beginning of the generated
1447 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1448 timeout.
1449
1450 =item --prefix=I<prefix>
1451
1452 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1453 file name in generated bootloader configuration files (or in U-Boot
1454 commands).
1455
1456 If the I<prefix> contains string $NAME, it will be replaced with the
1457 name of the novaboot script (see also B<--name>).
1458
1459 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1460 the build directory (see also B<--build-dir>).
1461
1462 =item --grub-prefix
1463
1464 Alias for B<--prefix>.
1465
1466 =item --grub2[=I<filename>]
1467
1468 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1469 specified F<grub.cfg> is used. The content of the menu entry can be
1470 customized with B<--grub-preamble>, B<--grub2-prolog> or
1471 B<--grub_prefix> options.
1472
1473 In order to use the the generated menu entry on your development
1474 machine that uses GRUB2, append the following snippet to
1475 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1476 i.e. run update-grub on Debian/Ubuntu.
1477
1478   if [ -f /path/to/nul/build/grub.cfg ]; then
1479     source /path/to/nul/build/grub.cfg
1480   fi
1481
1482 =item --grub2-prolog=I<prolog>
1483
1484 Specifies text that is put at the beginning of the GRUB2 menu entry.
1485
1486 =item -m, --make[=make command]
1487
1488 Runs C<make> to build files that are not generated by novaboot itself.
1489
1490 =item --name=I<string>
1491
1492 Use the name I<string> instead of the name of the novaboot script.
1493 This name is used for things like a title of grub menu or for the
1494 server directory where the boot files are copied to.
1495
1496 =item --no-file-gen
1497
1498 Do not run external commands to generate files (i.e. "<" syntax and
1499 C<run> keyword). This switch does not influence generation of files
1500 specified with "<<WORD" syntax.
1501
1502 =item -p, --pulsar[=mac]
1503
1504 Generates pulsar bootloader configuration file named F<config-I<mac>>
1505 The I<mac> string is typically a MAC address and defaults to
1506 I<novaboot>.
1507
1508 =item --scons[=scons command]
1509
1510 Runs C<scons> to build files that are not generated by novaboot
1511 itself.
1512
1513 =item --strip-rom
1514
1515 Strip I<rom://> prefix from command lines and generated config files.
1516 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1517
1518 =item --gen-only
1519
1520 Exit novaboot after file generation phase.
1521
1522 =back
1523
1524 =head2 Target connection check
1525
1526 If supported by the target, the connection to it is made and it is
1527 checked whether the target is not occupied by another novaboot
1528 user/instance.
1529
1530 =over 8
1531
1532 =item --amt=I<"[user[:password]@]host[:port]>
1533
1534 Use Intel AMT technology to control the target machine. WS management
1535 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1536 The hostname or (IP address) is given by the I<host> parameter. If
1537 I<password> is not specified, environment variable AMT_PASSWORD is
1538 used. The I<port> specifies a TCP port for SOL. If not specified, the
1539 default is 16992. Default I<user> is admin.
1540
1541 =item --iprelay=I<addr[:port]>
1542
1543 Use TCP/IP relay and serial port to access the target's serial port
1544 and powercycle it. The IP address of the relay is given by I<addr>
1545 parameter. If I<port> is not specified, it default to 23.
1546
1547 Note: This option is supposed to work with HWG-ER02a IP relays.
1548
1549 =item -s, --serial[=device]
1550
1551 Target's serial line is connected to host's serial line (device). The
1552 default value for device is F</dev/ttyUSB0>.
1553
1554 The value of this option is exported in NB_NOVABOOT environment
1555 variable to all subprocesses run by C<novaboot>.
1556
1557 =item --stty=I<settings>
1558
1559 Specifies settings passed to C<stty> invoked on the serial line
1560 specified with B<--serial> option. If this option is not given,
1561 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1562
1563 =item --remote-cmd=I<cmd>
1564
1565 Command that mediates connection to the target's serial line. For
1566 example C<ssh server 'cu -l /dev/ttyS0'>.
1567
1568 =item --remote-expect=I<string>
1569
1570 Wait for reception of I<string> after establishing the remote
1571 connection.
1572
1573 =item --remote-expect-silent=I<string>
1574
1575 The same as B<--remote-expect> except that the remote output is not
1576 echoed to stdout while waiting for the I<string>. Everything after the
1577 matched string is printed to stdout, so you may want to include line
1578 end characters in the I<string> as well.
1579
1580 =back
1581
1582 =head2 File deployment phase
1583
1584 In some setups, it is necessary to copy the files needed for booting
1585 to a particular location, e.g. to a TFTP boot server or to the
1586 F</boot> partition.
1587
1588 =over 8
1589
1590 =item -d, --dhcp-tftp
1591
1592 Turns your workstation into a DHCP and TFTP server so that the OS can
1593 be booted via PXE BIOS (or similar mechanism) on the test machine
1594 directly connected by a plain Ethernet cable to your workstation.
1595
1596 The DHCP and TFTP servers requires root privileges and C<novaboot>
1597 uses C<sudo> command to obtain those. You can put the following to
1598 I</etc/sudoers> to allow running the necessary commands without asking
1599 for password.
1600
1601  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1602  your_login ALL=NOPASSWD: NOVABOOT
1603
1604 =item --tftp
1605
1606 Starts a TFTP server on your workstation. This is similar to
1607 B<--dhcp-tftp> except that DHCP server is not started.
1608
1609 The TFTP server require root privileges and C<novaboot> uses C<sudo>
1610 command to obtain those. You can put the following to I</etc/sudoers>
1611 to allow running the necessary commands without asking for password.
1612
1613  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1614  your_login ALL=NOPASSWD: NOVABOOT
1615
1616 =item --tftp-port=I<port>
1617
1618 Port to run the TFTP server on. Implies B<--tftp>.
1619
1620 =item --iso[=filename]
1621
1622 Generates the ISO image that boots NOVA system via GRUB. If no filename
1623 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1624 of the novaboot script (see also B<--name>).
1625
1626 =item --server[=[[user@]server:]path]
1627
1628 Copy all files needed for booting to another location. The files will
1629 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1630 contains string $NAME, it will be replaced with the name of the
1631 novaboot script (see also B<--name>).
1632
1633 =item --rsync-flags=I<flags>
1634
1635 Specifies which I<flags> are appended to F<rsync> command line when
1636 copying files as a result of I<--server> option.
1637
1638 =item --concat
1639
1640 If B<--server> is used and its value ends with $NAME, then after
1641 copying the files, a new bootloader configuration file (e.g. menu.lst)
1642 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1643 with $NAME part removed. The content of the file is created by
1644 concatenating all files of the same name from all subdirectories of
1645 I<path-wo-name> found on the "server".
1646
1647 =item --ider
1648
1649 Use Intel AMT technology for IDE redirection. This allows the target
1650 machine to boot from novaboot created ISO image. Implies B<--iso>.
1651
1652 The experimental C<amtider> utility needed by this option can be
1653 obtained from https://github.com/wentasah/amtterm.
1654
1655 =back
1656
1657 =head2 Target power-on and reset phase
1658
1659 At this point, the target is reset (or switched on/off). There is
1660 several ways how this can be accomplished. Resetting a physical target
1661 can currently be accomplished by the following options: B<--amt>,
1662 B<--iprelay>, B<--reset-cmd>.
1663
1664 =over 8
1665
1666 =item --on, --off
1667
1668 Switch on/off the target machine and exit. The script (if any) is
1669 completely ignored. Currently it works only with B<--iprelay> or
1670 B<--amt>.
1671
1672 =item -Q, --qemu[=I<qemu-binary>]
1673
1674 Boot the configuration in qemu. Optionally, the name of qemu binary
1675 can be specified as a parameter.
1676
1677 =item --qemu-append=I<flags>
1678
1679 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1680 C<-cpu coreduo -smp 2>).
1681
1682 =item -q, --qemu-flags=I<flags>
1683
1684 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1685 -smp 2>) with I<flags> specified here.
1686
1687 =item --reset-cmd=I<cmd>
1688
1689 Command that resets the target.
1690
1691 =item --no-reset, --reset
1692
1693 Disable/enable resetting of the target.
1694
1695 =back
1696
1697 =head2 Interaction with the bootloader on the target
1698
1699 =over 8
1700
1701 =item --uboot[=I<prompt>]
1702
1703 Interact with U-Boot bootloader to boot the thing described in the
1704 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1705 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1706 Implementation of this option is currently tied to a particular board
1707 that we use. It may be subject to changes in the future!
1708
1709 =item --no-uboot
1710
1711 Disable U-Boot interaction previously enabled with B<--uboot>.
1712
1713 =item --uboot-init
1714
1715 Command(s) to send the U-Boot bootloader before loading the images and
1716 booting them. This option can be given multiple times. After sending
1717 commands from each option novaboot waits for U-Boot I<prompt>.
1718
1719 If the command contains string I<$NB_MYIP> then this string is
1720 replaced by IPv4 address of eth0 interface. Similarly I<$NB_PREFIX> is
1721 replaced with prefix given by B<--prefix>.
1722
1723 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
1724
1725 =item --uboot-addr I<name>=I<address>
1726
1727 Load address of U-Boot's C<tftpboot> command for loading I<name>,
1728 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
1729 tree).
1730
1731 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
1732 variables used by convention for this purpose.
1733
1734 =item --uboot-cmd=I<command>
1735
1736 Specifies U-Boot command used to execute the OS. If the command
1737 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
1738 these are replaced with the addresses configured with B<--uboot-addr>.
1739
1740 The default value is
1741
1742     bootm $kernel_addr $ramdisk_addr $fdt_addr
1743
1744 or the C<UBOOT_CMD> variable if defined in the novaboot script.
1745
1746 =back
1747
1748 =head2 Target interaction phase
1749
1750 In this phase, target's serial output is redirected to stdout and if
1751 stdin is a TTY, it is redirected to the target's serial input allowing
1752 interactive work with the target.
1753
1754 =over 8
1755
1756 =item --exiton=I<string>
1757
1758 When I<string> is sent by the target, novaboot exits. This option can
1759 be specified multiple times, in which case novaboot exits whenever
1760 either of the specified strings is sent.
1761
1762 If I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1763 treated as regular expression. For example:
1764
1765     --exiton -re --exiton 'error:.*failed'
1766
1767 =item --exiton-re=I<regex>
1768
1769 The same as --exiton -re --exiton I<regex>.
1770
1771 =item --exiton-timeout=I<seconds>
1772
1773 By default B<--exiton> waits for the string match forever. When this
1774 option is specified, "exiton" timeouts after the specifies number of
1775 seconds and novaboot returns non-zero exit code.
1776
1777 =item -i, --interactive
1778
1779 Setup things for interactive use of target. Your terminal will be
1780 switched to raw mode. In raw mode, your system does not process input
1781 in any way (no echoing of entered characters, no interpretation
1782 special characters). This, among others, means that Ctrl-C is passed
1783 to the target and does no longer interrupt novaboot. Use "~~."
1784 sequence to exit novaboot.
1785
1786 =item --no-interaction, --interaction
1787
1788 Skip resp. force target interaction phase. When skipped, novaboot exits
1789 immediately when boot is initiated.
1790
1791 =item --expect=I<string>
1792
1793 When I<string> is received from the target, send the string specified
1794 with the subsequent B<--send*> option to the target.
1795
1796 =item --expect-re=I<regex>
1797
1798 When target's output matches regular expression I<regex>, send the
1799 string specified with the subsequent B<--send*> option to the target.
1800
1801 =item --expect-raw=I<perl-code>
1802
1803 Provides direct control over Perl's Expect module.
1804
1805 =item --send=I<string>
1806
1807 Send I<string> to the target after the previously specified
1808 B<--expect*> was matched in the target's output. The I<string> may
1809 contain escape sequences such as "\n".
1810
1811 Note that I<string> is actually interpreted by Perl, so it can contain
1812 much more that escape sequences. This behavior may change in the
1813 future.
1814
1815 Example: C<--expect='login: ' --send='root\n'>
1816
1817 =item --sendcont=I<string>
1818
1819 Similar to B<--send> but continue expecting more input.
1820
1821 Example: C<--expect='Continue?' --sendcont='yes\n'>
1822
1823 =back
1824
1825 =head1 NOVABOOT SCRIPT SYNTAX
1826
1827 The syntax tries to mimic POSIX shell syntax. The syntax is defined
1828 with the following rules.
1829
1830 Lines starting with "#" and empty lines are ignored.
1831
1832 Lines that end with "\" are concatenated with the following line after
1833 removal of the final "\" and leading whitespace of the following line.
1834
1835 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1836 expression) assign values to internal variables. See L</VARIABLES>
1837 section.
1838
1839 Lines starting with C<load> keyword represent modules to boot. The
1840 word after C<load> is a file name (relative to the build directory
1841 (see B<--build-dir>) of the module to load and the remaining words are
1842 passed to it as the command line parameters.
1843
1844 When the C<load> line ends with "<<WORD" then the subsequent lines
1845 until the line containing solely WORD are copied literally to the file
1846 named on that line. This is similar to shell's heredoc feature.
1847
1848 When the C<load> line ends with "< CMD" then command CMD is executed
1849 with F</bin/sh> and its standard output is stored in the file named on
1850 that line. The SRCDIR variable in CMD's environment is set to the
1851 absolute path of the directory containing the interpreted novaboot
1852 script.
1853
1854 Lines starting with C<run> keyword contain shell commands that are run
1855 during file generation phase. This is the same as the "< CMD" syntax
1856 for C<load> keyboard except that the command's output is not
1857 redirected to a file. The ordering of commands is the same as they
1858 appear in the novaboot script.
1859
1860 Lines starting with C<uboot> represent U-Boot commands that are sent
1861 to the target if B<--uboot> option is given. Having a U-Boot line in
1862 the novaboot script is the same as passing an equivalent
1863 B<--uboot-init> option to novaboot. The C<uboot> keyword can be
1864 suffixed with timeout specification. The syntax is C<uboot:Ns>, where
1865 C<N> is the whole number of seconds. If the U-Boot command prompt does
1866 not appear before the timeout, novaboot fails. The default timeout is
1867 10 seconds.
1868
1869 Example (Linux):
1870
1871   #!/usr/bin/env novaboot
1872   load bzImage console=ttyS0,115200
1873   run  make -C buildroot
1874   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
1875
1876 Example (NOVA User Land - NUL):
1877
1878   #!/usr/bin/env novaboot
1879   WVDESC=Example program
1880   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
1881                            verbose hostkeyb:0,0x60,1,12,2
1882   load bin/apps/hello.nul
1883   load hello.nulconfig <<EOF
1884   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
1885   rom://bin/apps/hello.nul
1886   EOF
1887
1888 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
1889 F<hello.nulconfig>. sigma0 receives some command line parameters and
1890 F<hello.nulconfig> file is generated on the fly from the lines between
1891 C<<<EOF> and C<EOF>.
1892
1893 =head2 VARIABLES
1894
1895 The following variables are interpreted in the novaboot script:
1896
1897 =over 8
1898
1899 =item BUILDDIR
1900
1901 Novaboot chdir()s to this directory before file generation phase. The
1902 directory name specified here is relative to the build directory
1903 specified by other means (see L</--build-dir>).
1904
1905 =item EXITON
1906
1907 Assigning this variable has the same effect as specifying L</--exiton>
1908 option.
1909
1910 =item HYPERVISOR_PARAMS
1911
1912 Parameters passed to hypervisor. The default value is "serial", unless
1913 overridden in configuration file.
1914
1915 =item KERNEL
1916
1917 The kernel to use instead of the hypervisor specified in the
1918 configuration file with the C<$hypervisor> variable. The value should
1919 contain the name of the kernel image as well as its command line
1920 parameters. If this variable is defined and non-empty, the variable
1921 HYPERVISOR_PARAMS is not used.
1922
1923 =item NO_BOOT
1924
1925 If this variable is 1, the system is not booted. This is currently
1926 only implemented for U-Boot bootloader where it is useful for
1927 interacting with the bootloader without booting the system - e.g. for
1928 flashing.
1929
1930 =item QEMU
1931
1932 Use a specific qemu binary (can be overridden with B<-Q>) and flags
1933 when booting this script under qemu. If QEMU_FLAGS variable is also
1934 specified flags specified in QEMU variable are replaced by those in
1935 QEMU_FLAGS.
1936
1937 =item QEMU_FLAGS
1938
1939 Use specific qemu flags (can be overridden with B<-q>).
1940
1941 =item UBOOT_CMD
1942
1943 See L</--uboot-cmd>.
1944
1945 =item WVDESC
1946
1947 Description of the WvTest-compliant program.
1948
1949 =item WVTEST_TIMEOUT
1950
1951 The timeout in seconds for WvTest harness. If no complete line appears
1952 in the test output within the time specified here, the test fails. It
1953 is necessary to specify this for long running tests that produce no
1954 intermediate output.
1955
1956 =back
1957
1958 =head1 CONFIGURATION FILE
1959
1960 Novaboot can read its configuration from one or more files. By
1961 default, novaboot looks for files in F</etc/novaboot.d>, file
1962 F<~/.config/novaboot> and files named F<.novaboot> as described in
1963 L</Configuration reading phase>. Alternatively, configuration file
1964 location can be specified with the B<-c> switch or with the
1965 NOVABOOT_CONFIG environment variable. The configuration file has Perl
1966 syntax (i.e. it is better to put C<1;> as the last line) and should set
1967 values of certain Perl variables. The current configuration can be
1968 dumped with the B<--dump-config> switch. Some configuration variables
1969 can be overridden by environment variables (see below) or by command
1970 line switches.
1971
1972 Supported configuration variables include:
1973
1974 =over 8
1975
1976 =item $builddir
1977
1978 Build directory location relative to the location of the configuration
1979 file.
1980
1981 =item $default_target
1982
1983 Default target (see below) to use when no target is explicitly
1984 specified with the B<--target> command line option or
1985 B<NOVABOOT_TARGET> environment variable.
1986
1987 =item %targets
1988
1989 Hash of target definitions to be used with the B<--target> option. The
1990 key is the identifier of the target, the value is the string with
1991 command line options. For instance, if the configuration file contains:
1992
1993  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
1994
1995 then the following two commands are equivalent:
1996
1997  ./myos --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
1998  ./myos -t mybox
1999
2000 =back
2001
2002 =head1 ENVIRONMENT VARIABLES
2003
2004 Some options can be specified not only via config file or command line
2005 but also through environment variables. Environment variables override
2006 the values from configuration file and command line parameters
2007 override the environment variables.
2008
2009 =over 8
2010
2011 =item NOVABOOT_CONFIG
2012
2013 Name of the novaboot configuration file to use instead of the default
2014 one(s).
2015
2016 =item NOVABOOT_CONFIG_DIR
2017
2018 Name of the novaboot configuration directory. When not specified
2019 F</etc/novaboot.d> is used.
2020
2021 =item NOVABOOT_TARGET
2022
2023 Name of the novaboot target to use. This overrides the value of
2024 B<$default_target> from the configuration file and can be overriden
2025 with the B<--target> command line option.
2026
2027 =item NOVABOOT_BENDER
2028
2029 Defining this variable has the same meaning as B<--bender> option.
2030
2031 =back
2032
2033 =head1 AUTHORS
2034
2035 Michal Sojka <sojka@os.inf.tu-dresden.de>
2036
2037 =cut
2038
2039 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2040 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2041 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2042 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest