arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36 #include <asm/context_tracking.h>
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 .SYS_CALL_TABLE:
  43         .tc .sys_call_table[TC],.sys_call_table
  44
  45 /* This value is used to mark exception frames on the stack. */
  46 exception_marker:
  47         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  48
  49         .section        ".text"
  50         .align 7
  51
  52 #undef SHOW_SYSCALLS
  53
  54         .globl system_call_common
  55 system_call_common:
  56         andi.   r10,r12,MSR_PR
  57         mr      r10,r1
  58         addi    r1,r1,-INT_FRAME_SIZE
  59         beq-    1f
  60         ld      r1,PACAKSAVE(r13)
  61 1:      std     r10,0(r1)
  62         std     r11,_NIP(r1)
  63         std     r12,_MSR(r1)
  64         std     r0,GPR0(r1)
  65         std     r10,GPR1(r1)
  66         beq     2f                      /* if from kernel mode */
  67         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  68 2:      std     r2,GPR2(r1)
  69         std     r3,GPR3(r1)
  70         mfcr    r2
  71         std     r4,GPR4(r1)
  72         std     r5,GPR5(r1)
  73         std     r6,GPR6(r1)
  74         std     r7,GPR7(r1)
  75         std     r8,GPR8(r1)
  76         li      r11,0
  77         std     r11,GPR9(r1)
  78         std     r11,GPR10(r1)
  79         std     r11,GPR11(r1)
  80         std     r11,GPR12(r1)
  81         std     r11,_XER(r1)
  82         std     r11,_CTR(r1)
  83         std     r9,GPR13(r1)
  84         mflr    r10
  85         /*
  86          * This clears CR0.SO (bit 28), which is the error indication on
  87          * return from this system call.
  88          */
  89         rldimi  r2,r11,28,(63-28)
  90         li      r11,0xc01
  91         std     r10,_LINK(r1)
  92         std     r11,_TRAP(r1)
  93         std     r3,ORIG_GPR3(r1)
  94         std     r2,_CCR(r1)
  95         ld      r2,PACATOC(r13)
  96         addi    r9,r1,STACK_FRAME_OVERHEAD
  97         ld      r11,exception_marker@toc(r2)
  98         std     r11,-16(r9)             /* "regshere" marker */
  99 #if defined(CONFIG_VIRT_CPU_ACCOUNTING_NATIVE) && defined(CONFIG_PPC_SPLPAR)
 100 BEGIN_FW_FTR_SECTION
 101         beq     33f
 102         /* if from user, see if there are any DTL entries to process */
 103         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 104         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 105         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 106         cmpd    cr1,r11,r10
 107         beq+    cr1,33f
 108         bl      .accumulate_stolen_time
 109         REST_GPR(0,r1)
 110         REST_4GPRS(3,r1)
 111         REST_2GPRS(7,r1)
 112         addi    r9,r1,STACK_FRAME_OVERHEAD
 113 33:
 114 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 115 #endif /* CONFIG_VIRT_CPU_ACCOUNTING_NATIVE && CONFIG_PPC_SPLPAR */
 116
 117         /*
 118          * A syscall should always be called with interrupts enabled
 119          * so we just unconditionally hard-enable here. When some kind
 120          * of irq tracing is used, we additionally check that condition
 121          * is correct
 122          */
 123 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 124         lbz     r10,PACASOFTIRQEN(r13)
 125         xori    r10,r10,1
 126 1:      tdnei   r10,0
 127         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 128 #endif
 129
 130 #ifdef CONFIG_PPC_BOOK3E
 131         wrteei  1
 132 #else
 133         ld      r11,PACAKMSR(r13)
 134         ori     r11,r11,MSR_EE
 135         mtmsrd  r11,1
 136 #endif /* CONFIG_PPC_BOOK3E */
 137
 138         /* We do need to set SOFTE in the stack frame or the return
 139          * from interrupt will be painful
 140          */
 141         li      r10,1
 142         std     r10,SOFTE(r1)
 143
 144 #ifdef SHOW_SYSCALLS
 145         bl      .do_show_syscall
 146         REST_GPR(0,r1)
 147         REST_4GPRS(3,r1)
 148         REST_2GPRS(7,r1)
 149         addi    r9,r1,STACK_FRAME_OVERHEAD
 150 #endif
 151         CURRENT_THREAD_INFO(r11, r1)
 152         ld      r10,TI_FLAGS(r11)
 153         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 154         bne     syscall_dotrace
 155 .Lsyscall_dotrace_cont:
 156         cmpldi  0,r0,NR_syscalls
 157         bge-    syscall_enosys
 158
 159 system_call:                    /* label this so stack traces look sane */
 160 /*
 161  * Need to vector to 32 Bit or default sys_call_table here,
 162  * based on caller's run-mode / personality.
 163  */
 164         ld      r11,.SYS_CALL_TABLE@toc(2)
 165         andi.   r10,r10,_TIF_32BIT
 166         beq     15f
 167         addi    r11,r11,8       /* use 32-bit syscall entries */
 168         clrldi  r3,r3,32
 169         clrldi  r4,r4,32
 170         clrldi  r5,r5,32
 171         clrldi  r6,r6,32
 172         clrldi  r7,r7,32
 173         clrldi  r8,r8,32
 174 15:
 175         slwi    r0,r0,4
 176         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 177         mtctr   r10
 178         bctrl                   /* Call handler */
 179
 180 syscall_exit:
 181         std     r3,RESULT(r1)
 182 #ifdef SHOW_SYSCALLS
 183         bl      .do_show_syscall_exit
 184         ld      r3,RESULT(r1)
 185 #endif
 186         CURRENT_THREAD_INFO(r12, r1)
 187
 188         ld      r8,_MSR(r1)
 189 #ifdef CONFIG_PPC_BOOK3S
 190         /* No MSR:RI on BookE */
 191         andi.   r10,r8,MSR_RI
 192         beq-    unrecov_restore
 193 #endif
 194         /*
 195          * Disable interrupts so current_thread_info()->flags can't change,
 196          * and so that we don't get interrupted after loading SRR0/1.
 197          */
 198 #ifdef CONFIG_PPC_BOOK3E
 199         wrteei  0
 200 #else
 201         ld      r10,PACAKMSR(r13)
 202         /*
 203          * For performance reasons we clear RI the same time that we
 204          * clear EE. We only need to clear RI just before we restore r13
 205          * below, but batching it with EE saves us one expensive mtmsrd call.
 206          * We have to be careful to restore RI if we branch anywhere from
 207          * here (eg syscall_exit_work).
 208          */
 209         li      r9,MSR_RI
 210         andc    r11,r10,r9
 211         mtmsrd  r11,1
 212 #endif /* CONFIG_PPC_BOOK3E */
 213
 214         ld      r9,TI_FLAGS(r12)
 215         li      r11,-_LAST_ERRNO
 216         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 217         bne-    syscall_exit_work
 218         cmpld   r3,r11
 219         ld      r5,_CCR(r1)
 220         bge-    syscall_error
 221 .Lsyscall_error_cont:
 222         ld      r7,_NIP(r1)
 223 BEGIN_FTR_SECTION
 224         stdcx.  r0,0,r1                 /* to clear the reservation */
 225 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 226         andi.   r6,r8,MSR_PR
 227         ld      r4,_LINK(r1)
 228
 229         beq-    1f
 230         ACCOUNT_CPU_USER_EXIT(r11, r12)
 231         HMT_MEDIUM_LOW_HAS_PPR
 232         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 233 1:      ld      r2,GPR2(r1)
 234         ld      r1,GPR1(r1)
 235         mtlr    r4
 236         mtcr    r5
 237         mtspr   SPRN_SRR0,r7
 238         mtspr   SPRN_SRR1,r8
 239         RFI
 240         b       .       /* prevent speculative execution */
 241
 242 syscall_error:
 243         oris    r5,r5,0x1000    /* Set SO bit in CR */
 244         neg     r3,r3
 245         std     r5,_CCR(r1)
 246         b       .Lsyscall_error_cont
 247
 248 /* Traced system call support */
 249 syscall_dotrace:
 250         bl      .save_nvgprs
 251         addi    r3,r1,STACK_FRAME_OVERHEAD
 252         bl      .do_syscall_trace_enter
 253         /*
 254          * Restore argument registers possibly just changed.
 255          * We use the return value of do_syscall_trace_enter
 256          * for the call number to look up in the table (r0).
 257          */
 258         mr      r0,r3
 259         ld      r3,GPR3(r1)
 260         ld      r4,GPR4(r1)
 261         ld      r5,GPR5(r1)
 262         ld      r6,GPR6(r1)
 263         ld      r7,GPR7(r1)
 264         ld      r8,GPR8(r1)
 265         addi    r9,r1,STACK_FRAME_OVERHEAD
 266         CURRENT_THREAD_INFO(r10, r1)
 267         ld      r10,TI_FLAGS(r10)
 268         b       .Lsyscall_dotrace_cont
 269
 270 syscall_enosys:
 271         li      r3,-ENOSYS
 272         b       syscall_exit
 273
 274 syscall_exit_work:
 275 #ifdef CONFIG_PPC_BOOK3S
 276         mtmsrd  r10,1           /* Restore RI */
 277 #endif
 278         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 279          If TIF_NOERROR is set, just save r3 as it is. */
 280
 281         andi.   r0,r9,_TIF_RESTOREALL
 282         beq+    0f
 283         REST_NVGPRS(r1)
 284         b       2f
 285 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 286         blt+    1f
 287         andi.   r0,r9,_TIF_NOERROR
 288         bne-    1f
 289         ld      r5,_CCR(r1)
 290         neg     r3,r3
 291         oris    r5,r5,0x1000    /* Set SO bit in CR */
 292         std     r5,_CCR(r1)
 293 1:      std     r3,GPR3(r1)
 294 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 295         beq     4f
 296
 297         /* Clear per-syscall TIF flags if any are set.  */
 298
 299         li      r11,_TIF_PERSYSCALL_MASK
 300         addi    r12,r12,TI_FLAGS
 301 3:      ldarx   r10,0,r12
 302         andc    r10,r10,r11
 303         stdcx.  r10,0,r12
 304         bne-    3b
 305         subi    r12,r12,TI_FLAGS
 306
 307 4:      /* Anything else left to do? */
 308         SET_DEFAULT_THREAD_PPR(r3, r10)         /* Set thread.ppr = 3 */
 309         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 310         beq     .ret_from_except_lite
 311
 312         /* Re-enable interrupts */
 313 #ifdef CONFIG_PPC_BOOK3E
 314         wrteei  1
 315 #else
 316         ld      r10,PACAKMSR(r13)
 317         ori     r10,r10,MSR_EE
 318         mtmsrd  r10,1
 319 #endif /* CONFIG_PPC_BOOK3E */
 320
 321         bl      .save_nvgprs
 322         addi    r3,r1,STACK_FRAME_OVERHEAD
 323         bl      .do_syscall_trace_leave
 324         b       .ret_from_except
 325
 326 /* Save non-volatile GPRs, if not already saved. */
 327 _GLOBAL(save_nvgprs)
 328         ld      r11,_TRAP(r1)
 329         andi.   r0,r11,1
 330         beqlr-
 331         SAVE_NVGPRS(r1)
 332         clrrdi  r0,r11,1
 333         std     r0,_TRAP(r1)
 334         blr
 335
 336
 337 /*
 338  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 339  * and thus put the process into the stopped state where we might
 340  * want to examine its user state with ptrace.  Therefore we need
 341  * to save all the nonvolatile registers (r14 - r31) before calling
 342  * the C code.  Similarly, fork, vfork and clone need the full
 343  * register state on the stack so that it can be copied to the child.
 344  */
 345
 346 _GLOBAL(ppc_fork)
 347         bl      .save_nvgprs
 348         bl      .sys_fork
 349         b       syscall_exit
 350
 351 _GLOBAL(ppc_vfork)
 352         bl      .save_nvgprs
 353         bl      .sys_vfork
 354         b       syscall_exit
 355
 356 _GLOBAL(ppc_clone)
 357         bl      .save_nvgprs
 358         bl      .sys_clone
 359         b       syscall_exit
 360
 361 _GLOBAL(ppc32_swapcontext)
 362         bl      .save_nvgprs
 363         bl      .compat_sys_swapcontext
 364         b       syscall_exit
 365
 366 _GLOBAL(ppc64_swapcontext)
 367         bl      .save_nvgprs
 368         bl      .sys_swapcontext
 369         b       syscall_exit
 370
 371 _GLOBAL(ret_from_fork)
 372         bl      .schedule_tail
 373         REST_NVGPRS(r1)
 374         li      r3,0
 375         b       syscall_exit
 376
 377 _GLOBAL(ret_from_kernel_thread)
 378         bl      .schedule_tail
 379         REST_NVGPRS(r1)
 380         ld      r14, 0(r14)
 381         mtlr    r14
 382         mr      r3,r15
 383         blrl
 384         li      r3,0
 385         b       syscall_exit
 386
 387         .section        ".toc","aw"
 388 DSCR_DEFAULT:
 389         .tc dscr_default[TC],dscr_default
 390
 391         .section        ".text"
 392
 393 /*
 394  * This routine switches between two different tasks.  The process
 395  * state of one is saved on its kernel stack.  Then the state
 396  * of the other is restored from its kernel stack.  The memory
 397  * management hardware is updated to the second process's state.
 398  * Finally, we can return to the second process, via ret_from_except.
 399  * On entry, r3 points to the THREAD for the current task, r4
 400  * points to the THREAD for the new task.
 401  *
 402  * Note: there are two ways to get to the "going out" portion
 403  * of this code; either by coming in via the entry (_switch)
 404  * or via "fork" which must set up an environment equivalent
 405  * to the "_switch" path.  If you change this you'll have to change
 406  * the fork code also.
 407  *
 408  * The code which creates the new task context is in 'copy_thread'
 409  * in arch/powerpc/kernel/process.c
 410  */
 411         .align  7
 412 _GLOBAL(_switch)
 413         mflr    r0
 414         std     r0,16(r1)
 415         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 416         /* r3-r13 are caller saved -- Cort */
 417         SAVE_8GPRS(14, r1)
 418         SAVE_10GPRS(22, r1)
 419         mflr    r20             /* Return to switch caller */
 420         mfmsr   r22
 421         li      r0, MSR_FP
 422 #ifdef CONFIG_VSX
 423 BEGIN_FTR_SECTION
 424         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 425 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 426 #endif /* CONFIG_VSX */
 427 #ifdef CONFIG_ALTIVEC
 428 BEGIN_FTR_SECTION
 429         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 430         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 431         std     r24,THREAD_VRSAVE(r3)
 432 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 433 #endif /* CONFIG_ALTIVEC */
 434 #ifdef CONFIG_PPC64
 435 BEGIN_FTR_SECTION
 436         mfspr   r25,SPRN_DSCR
 437         std     r25,THREAD_DSCR(r3)
 438 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 439 #endif
 440         and.    r0,r0,r22
 441         beq+    1f
 442         andc    r22,r22,r0
 443         MTMSRD(r22)
 444         isync
 445 1:      std     r20,_NIP(r1)
 446         mfcr    r23
 447         std     r23,_CCR(r1)
 448         std     r1,KSP(r3)      /* Set old stack pointer */
 449
 450 #ifdef CONFIG_PPC_BOOK3S_64
 451 BEGIN_FTR_SECTION
 452         /*
 453          * Back up the TAR across context switches.  Note that the TAR is not
 454          * available for use in the kernel.  (To provide this, the TAR should
 455          * be backed up/restored on exception entry/exit instead, and be in
 456          * pt_regs.  FIXME, this should be in pt_regs anyway (for debug).)
 457          */
 458         mfspr   r0,SPRN_TAR
 459         std     r0,THREAD_TAR(r3)
 460
 461         /* Event based branch registers */
 462         mfspr   r0, SPRN_BESCR
 463         std     r0, THREAD_BESCR(r3)
 464         mfspr   r0, SPRN_EBBHR
 465         std     r0, THREAD_EBBHR(r3)
 466         mfspr   r0, SPRN_EBBRR
 467         std     r0, THREAD_EBBRR(r3)
 468 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 469 #endif
 470
 471 #ifdef CONFIG_SMP
 472         /* We need a sync somewhere here to make sure that if the
 473          * previous task gets rescheduled on another CPU, it sees all
 474          * stores it has performed on this one.
 475          */
 476         sync
 477 #endif /* CONFIG_SMP */
 478
 479         /*
 480          * If we optimise away the clear of the reservation in system
 481          * calls because we know the CPU tracks the address of the
 482          * reservation, then we need to clear it here to cover the
 483          * case that the kernel context switch path has no larx
 484          * instructions.
 485          */
 486 BEGIN_FTR_SECTION
 487         ldarx   r6,0,r1
 488 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 489
 490 #ifdef CONFIG_PPC_BOOK3S
 491 /* Cancel all explict user streams as they will have no use after context
 492  * switch and will stop the HW from creating streams itself
 493  */
 494         DCBT_STOP_ALL_STREAM_IDS(r6)
 495 #endif
 496
 497         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 498         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 499
 500         ld      r8,KSP(r4)      /* new stack pointer */
 501 #ifdef CONFIG_PPC_BOOK3S
 502 BEGIN_FTR_SECTION
 503   BEGIN_FTR_SECTION_NESTED(95)
 504         clrrdi  r6,r8,28        /* get its ESID */
 505         clrrdi  r9,r1,28        /* get current sp ESID */
 506   FTR_SECTION_ELSE_NESTED(95)
 507         clrrdi  r6,r8,40        /* get its 1T ESID */
 508         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 509   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 510 FTR_SECTION_ELSE
 511         b       2f
 512 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 513         clrldi. r0,r6,2         /* is new ESID c00000000? */
 514         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 515         cror    eq,4*cr1+eq,eq
 516         beq     2f              /* if yes, don't slbie it */
 517
 518         /* Bolt in the new stack SLB entry */
 519         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 520         oris    r0,r6,(SLB_ESID_V)@h
 521         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 522 BEGIN_FTR_SECTION
 523         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 524         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 525         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 526 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 527
 528         /* Update the last bolted SLB.  No write barriers are needed
 529          * here, provided we only update the current CPU's SLB shadow
 530          * buffer.
 531          */
 532         ld      r9,PACA_SLBSHADOWPTR(r13)
 533         li      r12,0
 534         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 535         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 536         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 537
 538         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 539          * we have 1TB segments, the only CPUs known to have the errata
 540          * only support less than 1TB of system memory and we'll never
 541          * actually hit this code path.
 542          */
 543
 544         slbie   r6
 545         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 546         slbmte  r7,r0
 547         isync
 548 2:
 549 #endif /* !CONFIG_PPC_BOOK3S */
 550
 551         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 552         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 553            because we don't need to leave the 288-byte ABI gap at the
 554            top of the kernel stack. */
 555         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 556
 557         mr      r1,r8           /* start using new stack pointer */
 558         std     r7,PACAKSAVE(r13)
 559
 560 #ifdef CONFIG_PPC_BOOK3S_64
 561 BEGIN_FTR_SECTION
 562         /* Event based branch registers */
 563         ld      r0, THREAD_BESCR(r4)
 564         mtspr   SPRN_BESCR, r0
 565         ld      r0, THREAD_EBBHR(r4)
 566         mtspr   SPRN_EBBHR, r0
 567         ld      r0, THREAD_EBBRR(r4)
 568         mtspr   SPRN_EBBRR, r0
 569
 570         ld      r0,THREAD_TAR(r4)
 571         mtspr   SPRN_TAR,r0
 572 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 573 #endif
 574
 575 #ifdef CONFIG_ALTIVEC
 576 BEGIN_FTR_SECTION
 577         ld      r0,THREAD_VRSAVE(r4)
 578         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 579 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 580 #endif /* CONFIG_ALTIVEC */
 581 #ifdef CONFIG_PPC64
 582 BEGIN_FTR_SECTION
 583         lwz     r6,THREAD_DSCR_INHERIT(r4)
 584         ld      r7,DSCR_DEFAULT@toc(2)
 585         ld      r0,THREAD_DSCR(r4)
 586         cmpwi   r6,0
 587         bne     1f
 588         ld      r0,0(r7)
 589 1:      cmpd    r0,r25
 590         beq     2f
 591         mtspr   SPRN_DSCR,r0
 592 2:
 593 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 594 #endif
 595
 596         ld      r6,_CCR(r1)
 597         mtcrf   0xFF,r6
 598
 599         /* r3-r13 are destroyed -- Cort */
 600         REST_8GPRS(14, r1)
 601         REST_10GPRS(22, r1)
 602
 603         /* convert old thread to its task_struct for return value */
 604         addi    r3,r3,-THREAD
 605         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 606         mtlr    r7
 607         addi    r1,r1,SWITCH_FRAME_SIZE
 608         blr
 609
 610         .align  7
 611 _GLOBAL(ret_from_except)
 612         ld      r11,_TRAP(r1)
 613         andi.   r0,r11,1
 614         bne     .ret_from_except_lite
 615         REST_NVGPRS(r1)
 616
 617 _GLOBAL(ret_from_except_lite)
 618         /*
 619          * Disable interrupts so that current_thread_info()->flags
 620          * can't change between when we test it and when we return
 621          * from the interrupt.
 622          */
 623 #ifdef CONFIG_PPC_BOOK3E
 624         wrteei  0
 625 #else
 626         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 627         mtmsrd  r10,1             /* Update machine state */
 628 #endif /* CONFIG_PPC_BOOK3E */
 629
 630         CURRENT_THREAD_INFO(r9, r1)
 631         ld      r3,_MSR(r1)
 632         ld      r4,TI_FLAGS(r9)
 633         andi.   r3,r3,MSR_PR
 634         beq     resume_kernel
 635
 636         /* Check current_thread_info()->flags */
 637         andi.   r0,r4,_TIF_USER_WORK_MASK
 638         beq     restore
 639
 640         andi.   r0,r4,_TIF_NEED_RESCHED
 641         beq     1f
 642         bl      .restore_interrupts
 643         SCHEDULE_USER
 644         b       .ret_from_except_lite
 645
 646 1:      bl      .save_nvgprs
 647         bl      .restore_interrupts
 648         addi    r3,r1,STACK_FRAME_OVERHEAD
 649         bl      .do_notify_resume
 650         b       .ret_from_except
 651
 652 resume_kernel:
 653         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 654         CURRENT_THREAD_INFO(r9, r1)
 655         ld      r8,TI_FLAGS(r9)
 656         andis.  r8,r8,_TIF_EMULATE_STACK_STORE@h
 657         beq+    1f
 658
 659         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 660
 661         lwz     r3,GPR1(r1)
 662         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 663         mr      r4,r1                   /* src:  current exception frame */
 664         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 665
 666         /* Copy from the original to the trampoline. */
 667         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 668         li      r6,0                    /* start offset: 0 */
 669         mtctr   r5
 670 2:      ldx     r0,r6,r4
 671         stdx    r0,r6,r3
 672         addi    r6,r6,8
 673         bdnz    2b
 674
 675         /* Do real store operation to complete stwu */
 676         lwz     r5,GPR1(r1)
 677         std     r8,0(r5)
 678
 679         /* Clear _TIF_EMULATE_STACK_STORE flag */
 680         lis     r11,_TIF_EMULATE_STACK_STORE@h
 681         addi    r5,r9,TI_FLAGS
 682 0:      ldarx   r4,0,r5
 683         andc    r4,r4,r11
 684         stdcx.  r4,0,r5
 685         bne-    0b
 686 1:
 687
 688 #ifdef CONFIG_PREEMPT
 689         /* Check if we need to preempt */
 690         andi.   r0,r4,_TIF_NEED_RESCHED
 691         beq+    restore
 692         /* Check that preempt_count() == 0 and interrupts are enabled */
 693         lwz     r8,TI_PREEMPT(r9)
 694         cmpwi   cr1,r8,0
 695         ld      r0,SOFTE(r1)
 696         cmpdi   r0,0
 697         crandc  eq,cr1*4+eq,eq
 698         bne     restore
 699
 700         /*
 701          * Here we are preempting the current task. We want to make
 702          * sure we are soft-disabled first
 703          */
 704         SOFT_DISABLE_INTS(r3,r4)
 705 1:      bl      .preempt_schedule_irq
 706
 707         /* Re-test flags and eventually loop */
 708         CURRENT_THREAD_INFO(r9, r1)
 709         ld      r4,TI_FLAGS(r9)
 710         andi.   r0,r4,_TIF_NEED_RESCHED
 711         bne     1b
 712
 713         /*
 714          * arch_local_irq_restore() from preempt_schedule_irq above may
 715          * enable hard interrupt but we really should disable interrupts
 716          * when we return from the interrupt, and so that we don't get
 717          * interrupted after loading SRR0/1.
 718          */
 719 #ifdef CONFIG_PPC_BOOK3E
 720         wrteei  0
 721 #else
 722         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 723         mtmsrd  r10,1             /* Update machine state */
 724 #endif /* CONFIG_PPC_BOOK3E */
 725 #endif /* CONFIG_PREEMPT */
 726
 727         .globl  fast_exc_return_irq
 728 fast_exc_return_irq:
 729 restore:
 730         /*
 731          * This is the main kernel exit path. First we check if we
 732          * are about to re-enable interrupts
 733          */
 734         ld      r5,SOFTE(r1)
 735         lbz     r6,PACASOFTIRQEN(r13)
 736         cmpwi   cr0,r5,0
 737         beq     restore_irq_off
 738
 739         /* We are enabling, were we already enabled ? Yes, just return */
 740         cmpwi   cr0,r6,1
 741         beq     cr0,do_restore
 742
 743         /*
 744          * We are about to soft-enable interrupts (we are hard disabled
 745          * at this point). We check if there's anything that needs to
 746          * be replayed first.
 747          */
 748         lbz     r0,PACAIRQHAPPENED(r13)
 749         cmpwi   cr0,r0,0
 750         bne-    restore_check_irq_replay
 751
 752         /*
 753          * Get here when nothing happened while soft-disabled, just
 754          * soft-enable and move-on. We will hard-enable as a side
 755          * effect of rfi
 756          */
 757 restore_no_replay:
 758         TRACE_ENABLE_INTS
 759         li      r0,1
 760         stb     r0,PACASOFTIRQEN(r13);
 761
 762         /*
 763          * Final return path. BookE is handled in a different file
 764          */
 765 do_restore:
 766 #ifdef CONFIG_PPC_BOOK3E
 767         b       .exception_return_book3e
 768 #else
 769         /*
 770          * Clear the reservation. If we know the CPU tracks the address of
 771          * the reservation then we can potentially save some cycles and use
 772          * a larx. On POWER6 and POWER7 this is significantly faster.
 773          */
 774 BEGIN_FTR_SECTION
 775         stdcx.  r0,0,r1         /* to clear the reservation */
 776 FTR_SECTION_ELSE
 777         ldarx   r4,0,r1
 778 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 779
 780         /*
 781          * Some code path such as load_up_fpu or altivec return directly
 782          * here. They run entirely hard disabled and do not alter the
 783          * interrupt state. They also don't use lwarx/stwcx. and thus
 784          * are known not to leave dangling reservations.
 785          */
 786         .globl  fast_exception_return
 787 fast_exception_return:
 788         ld      r3,_MSR(r1)
 789         ld      r4,_CTR(r1)
 790         ld      r0,_LINK(r1)
 791         mtctr   r4
 792         mtlr    r0
 793         ld      r4,_XER(r1)
 794         mtspr   SPRN_XER,r4
 795
 796         REST_8GPRS(5, r1)
 797
 798         andi.   r0,r3,MSR_RI
 799         beq-    unrecov_restore
 800
 801         /*
 802          * Clear RI before restoring r13.  If we are returning to
 803          * userspace and we take an exception after restoring r13,
 804          * we end up corrupting the userspace r13 value.
 805          */
 806         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 807         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 808         mtmsrd  r4,1
 809
 810 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 811         /* TM debug */
 812         std     r3, PACATMSCRATCH(r13) /* Stash returned-to MSR */
 813 #endif
 814         /*
 815          * r13 is our per cpu area, only restore it if we are returning to
 816          * userspace the value stored in the stack frame may belong to
 817          * another CPU.
 818          */
 819         andi.   r0,r3,MSR_PR
 820         beq     1f
 821         ACCOUNT_CPU_USER_EXIT(r2, r4)
 822         RESTORE_PPR(r2, r4)
 823         REST_GPR(13, r1)
 824 1:
 825         mtspr   SPRN_SRR1,r3
 826
 827         ld      r2,_CCR(r1)
 828         mtcrf   0xFF,r2
 829         ld      r2,_NIP(r1)
 830         mtspr   SPRN_SRR0,r2
 831
 832         ld      r0,GPR0(r1)
 833         ld      r2,GPR2(r1)
 834         ld      r3,GPR3(r1)
 835         ld      r4,GPR4(r1)
 836         ld      r1,GPR1(r1)
 837
 838         rfid
 839         b       .       /* prevent speculative execution */
 840
 841 #endif /* CONFIG_PPC_BOOK3E */
 842
 843         /*
 844          * We are returning to a context with interrupts soft disabled.
 845          *
 846          * However, we may also about to hard enable, so we need to
 847          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 848          * or that bit can get out of sync and bad things will happen
 849          */
 850 restore_irq_off:
 851         ld      r3,_MSR(r1)
 852         lbz     r7,PACAIRQHAPPENED(r13)
 853         andi.   r0,r3,MSR_EE
 854         beq     1f
 855         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 856         stb     r7,PACAIRQHAPPENED(r13)
 857 1:      li      r0,0
 858         stb     r0,PACASOFTIRQEN(r13);
 859         TRACE_DISABLE_INTS
 860         b       do_restore
 861
 862         /*
 863          * Something did happen, check if a re-emit is needed
 864          * (this also clears paca->irq_happened)
 865          */
 866 restore_check_irq_replay:
 867         /* XXX: We could implement a fast path here where we check
 868          * for irq_happened being just 0x01, in which case we can
 869          * clear it and return. That means that we would potentially
 870          * miss a decrementer having wrapped all the way around.
 871          *
 872          * Still, this might be useful for things like hash_page
 873          */
 874         bl      .__check_irq_replay
 875         cmpwi   cr0,r3,0
 876         beq     restore_no_replay
 877
 878         /*
 879          * We need to re-emit an interrupt. We do so by re-using our
 880          * existing exception frame. We first change the trap value,
 881          * but we need to ensure we preserve the low nibble of it
 882          */
 883         ld      r4,_TRAP(r1)
 884         clrldi  r4,r4,60
 885         or      r4,r4,r3
 886         std     r4,_TRAP(r1)
 887
 888         /*
 889          * Then find the right handler and call it. Interrupts are
 890          * still soft-disabled and we keep them that way.
 891         */
 892         cmpwi   cr0,r3,0x500
 893         bne     1f
 894         addi    r3,r1,STACK_FRAME_OVERHEAD;
 895         bl      .do_IRQ
 896         b       .ret_from_except
 897 1:      cmpwi   cr0,r3,0x900
 898         bne     1f
 899         addi    r3,r1,STACK_FRAME_OVERHEAD;
 900         bl      .timer_interrupt
 901         b       .ret_from_except
 902 #ifdef CONFIG_PPC_DOORBELL
 903 1:
 904 #ifdef CONFIG_PPC_BOOK3E
 905         cmpwi   cr0,r3,0x280
 906 #else
 907         BEGIN_FTR_SECTION
 908                 cmpwi   cr0,r3,0xe80
 909         FTR_SECTION_ELSE
 910                 cmpwi   cr0,r3,0xa00
 911         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 912 #endif /* CONFIG_PPC_BOOK3E */
 913         bne     1f
 914         addi    r3,r1,STACK_FRAME_OVERHEAD;
 915         bl      .doorbell_exception
 916         b       .ret_from_except
 917 #endif /* CONFIG_PPC_DOORBELL */
 918 1:      b       .ret_from_except /* What else to do here ? */
 919
 920 unrecov_restore:
 921         addi    r3,r1,STACK_FRAME_OVERHEAD
 922         bl      .unrecoverable_exception
 923         b       unrecov_restore
 924
 925 #ifdef CONFIG_PPC_RTAS
 926 /*
 927  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 928  * called with the MMU off.
 929  *
 930  * In addition, we need to be in 32b mode, at least for now.
 931  *
 932  * Note: r3 is an input parameter to rtas, so don't trash it...
 933  */
 934 _GLOBAL(enter_rtas)
 935         mflr    r0
 936         std     r0,16(r1)
 937         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 938
 939         /* Because RTAS is running in 32b mode, it clobbers the high order half
 940          * of all registers that it saves.  We therefore save those registers
 941          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 942          */
 943         SAVE_GPR(2, r1)                 /* Save the TOC */
 944         SAVE_GPR(13, r1)                /* Save paca */
 945         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 946         SAVE_10GPRS(22, r1)             /* ditto */
 947
 948         mfcr    r4
 949         std     r4,_CCR(r1)
 950         mfctr   r5
 951         std     r5,_CTR(r1)
 952         mfspr   r6,SPRN_XER
 953         std     r6,_XER(r1)
 954         mfdar   r7
 955         std     r7,_DAR(r1)
 956         mfdsisr r8
 957         std     r8,_DSISR(r1)
 958
 959         /* Temporary workaround to clear CR until RTAS can be modified to
 960          * ignore all bits.
 961          */
 962         li      r0,0
 963         mtcr    r0
 964
 965 #ifdef CONFIG_BUG
 966         /* There is no way it is acceptable to get here with interrupts enabled,
 967          * check it with the asm equivalent of WARN_ON
 968          */
 969         lbz     r0,PACASOFTIRQEN(r13)
 970 1:      tdnei   r0,0
 971         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 972 #endif
 973
 974         /* Hard-disable interrupts */
 975         mfmsr   r6
 976         rldicl  r7,r6,48,1
 977         rotldi  r7,r7,16
 978         mtmsrd  r7,1
 979
 980         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 981          * so they are saved in the PACA which allows us to restore
 982          * our original state after RTAS returns.
 983          */
 984         std     r1,PACAR1(r13)
 985         std     r6,PACASAVEDMSR(r13)
 986
 987         /* Setup our real return addr */
 988         LOAD_REG_ADDR(r4,.rtas_return_loc)
 989         clrldi  r4,r4,2                 /* convert to realmode address */
 990         mtlr    r4
 991
 992         li      r0,0
 993         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 994         andc    r0,r6,r0
 995
 996         li      r9,1
 997         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 998         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 999         andc    r6,r0,r9
1000         sync                            /* disable interrupts so SRR0/1 */
1001         mtmsrd  r0                      /* don't get trashed */
1002
1003         LOAD_REG_ADDR(r4, rtas)
1004         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
1005         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
1006
1007         mtspr   SPRN_SRR0,r5
1008         mtspr   SPRN_SRR1,r6
1009         rfid
1010         b       .       /* prevent speculative execution */
1011
1012 _STATIC(rtas_return_loc)
1013         /* relocation is off at this point */
1014         GET_PACA(r4)
1015         clrldi  r4,r4,2                 /* convert to realmode address */
1016
1017         bcl     20,31,$+4
1018 0:      mflr    r3
1019         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
1020
1021         mfmsr   r6
1022         li      r0,MSR_RI
1023         andc    r6,r6,r0
1024         sync
1025         mtmsrd  r6
1026
1027         ld      r1,PACAR1(r4)           /* Restore our SP */
1028         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
1029
1030         mtspr   SPRN_SRR0,r3
1031         mtspr   SPRN_SRR1,r4
1032         rfid
1033         b       .       /* prevent speculative execution */
1034
1035         .align  3
1036 1:      .llong  .rtas_restore_regs
1037
1038 _STATIC(rtas_restore_regs)
1039         /* relocation is on at this point */
1040         REST_GPR(2, r1)                 /* Restore the TOC */
1041         REST_GPR(13, r1)                /* Restore paca */
1042         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
1043         REST_10GPRS(22, r1)             /* ditto */
1044
1045         GET_PACA(r13)
1046
1047         ld      r4,_CCR(r1)
1048         mtcr    r4
1049         ld      r5,_CTR(r1)
1050         mtctr   r5
1051         ld      r6,_XER(r1)
1052         mtspr   SPRN_XER,r6
1053         ld      r7,_DAR(r1)
1054         mtdar   r7
1055         ld      r8,_DSISR(r1)
1056         mtdsisr r8
1057
1058         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
1059         ld      r0,16(r1)               /* get return address */
1060
1061         mtlr    r0
1062         blr                             /* return to caller */
1063
1064 #endif /* CONFIG_PPC_RTAS */
1065
1066 _GLOBAL(enter_prom)
1067         mflr    r0
1068         std     r0,16(r1)
1069         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1070
1071         /* Because PROM is running in 32b mode, it clobbers the high order half
1072          * of all registers that it saves.  We therefore save those registers
1073          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1074          */
1075         SAVE_GPR(2, r1)
1076         SAVE_GPR(13, r1)
1077         SAVE_8GPRS(14, r1)
1078         SAVE_10GPRS(22, r1)
1079         mfcr    r10
1080         mfmsr   r11
1081         std     r10,_CCR(r1)
1082         std     r11,_MSR(r1)
1083
1084         /* Get the PROM entrypoint */
1085         mtlr    r4
1086
1087         /* Switch MSR to 32 bits mode
1088          */
1089 #ifdef CONFIG_PPC_BOOK3E
1090         rlwinm  r11,r11,0,1,31
1091         mtmsr   r11
1092 #else /* CONFIG_PPC_BOOK3E */
1093         mfmsr   r11
1094         li      r12,1
1095         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
1096         andc    r11,r11,r12
1097         li      r12,1
1098         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
1099         andc    r11,r11,r12
1100         mtmsrd  r11
1101 #endif /* CONFIG_PPC_BOOK3E */
1102         isync
1103
1104         /* Enter PROM here... */
1105         blrl
1106
1107         /* Just make sure that r1 top 32 bits didn't get
1108          * corrupt by OF
1109          */
1110         rldicl  r1,r1,0,32
1111
1112         /* Restore the MSR (back to 64 bits) */
1113         ld      r0,_MSR(r1)
1114         MTMSRD(r0)
1115         isync
1116
1117         /* Restore other registers */
1118         REST_GPR(2, r1)
1119         REST_GPR(13, r1)
1120         REST_8GPRS(14, r1)
1121         REST_10GPRS(22, r1)
1122         ld      r4,_CCR(r1)
1123         mtcr    r4
1124
1125         addi    r1,r1,PROM_FRAME_SIZE
1126         ld      r0,16(r1)
1127         mtlr    r0
1128         blr
1129
1130 #ifdef CONFIG_FUNCTION_TRACER
1131 #ifdef CONFIG_DYNAMIC_FTRACE
1132 _GLOBAL(mcount)
1133 _GLOBAL(_mcount)
1134         blr
1135
1136 _GLOBAL(ftrace_caller)
1137         /* Taken from output of objdump from lib64/glibc */
1138         mflr    r3
1139         ld      r11, 0(r1)
1140         stdu    r1, -112(r1)
1141         std     r3, 128(r1)
1142         ld      r4, 16(r11)
1143         subi    r3, r3, MCOUNT_INSN_SIZE
1144 .globl ftrace_call
1145 ftrace_call:
1146         bl      ftrace_stub
1147         nop
1148 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1149 .globl ftrace_graph_call
1150 ftrace_graph_call:
1151         b       ftrace_graph_stub
1152 _GLOBAL(ftrace_graph_stub)
1153 #endif
1154         ld      r0, 128(r1)
1155         mtlr    r0
1156         addi    r1, r1, 112
1157 _GLOBAL(ftrace_stub)
1158         blr
1159 #else
1160 _GLOBAL(mcount)
1161         blr
1162
1163 _GLOBAL(_mcount)
1164         /* Taken from output of objdump from lib64/glibc */
1165         mflr    r3
1166         ld      r11, 0(r1)
1167         stdu    r1, -112(r1)
1168         std     r3, 128(r1)
1169         ld      r4, 16(r11)
1170
1171         subi    r3, r3, MCOUNT_INSN_SIZE
1172         LOAD_REG_ADDR(r5,ftrace_trace_function)
1173         ld      r5,0(r5)
1174         ld      r5,0(r5)
1175         mtctr   r5
1176         bctrl
1177         nop
1178
1179
1180 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1181         b       ftrace_graph_caller
1182 #endif
1183         ld      r0, 128(r1)
1184         mtlr    r0
1185         addi    r1, r1, 112
1186 _GLOBAL(ftrace_stub)
1187         blr
1188
1189 #endif /* CONFIG_DYNAMIC_FTRACE */
1190
1191 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1192 _GLOBAL(ftrace_graph_caller)
1193         /* load r4 with local address */
1194         ld      r4, 128(r1)
1195         subi    r4, r4, MCOUNT_INSN_SIZE
1196
1197         /* get the parent address */
1198         ld      r11, 112(r1)
1199         addi    r3, r11, 16
1200
1201         bl      .prepare_ftrace_return
1202         nop
1203
1204         ld      r0, 128(r1)
1205         mtlr    r0
1206         addi    r1, r1, 112
1207         blr
1208
1209 _GLOBAL(return_to_handler)
1210         /* need to save return values */
1211         std     r4,  -24(r1)
1212         std     r3,  -16(r1)
1213         std     r31, -8(r1)
1214         mr      r31, r1
1215         stdu    r1, -112(r1)
1216
1217         bl      .ftrace_return_to_handler
1218         nop
1219
1220         /* return value has real return address */
1221         mtlr    r3
1222
1223         ld      r1, 0(r1)
1224         ld      r4,  -24(r1)
1225         ld      r3,  -16(r1)
1226         ld      r31, -8(r1)
1227
1228         /* Jump back to real return address */
1229         blr
1230
1231 _GLOBAL(mod_return_to_handler)
1232         /* need to save return values */
1233         std     r4,  -32(r1)
1234         std     r3,  -24(r1)
1235         /* save TOC */
1236         std     r2,  -16(r1)
1237         std     r31, -8(r1)
1238         mr      r31, r1
1239         stdu    r1, -112(r1)
1240
1241         /*
1242          * We are in a module using the module's TOC.
1243          * Switch to our TOC to run inside the core kernel.
1244          */
1245         ld      r2, PACATOC(r13)
1246
1247         bl      .ftrace_return_to_handler
1248         nop
1249
1250         /* return value has real return address */
1251         mtlr    r3
1252
1253         ld      r1, 0(r1)
1254         ld      r4,  -32(r1)
1255         ld      r3,  -24(r1)
1256         ld      r2,  -16(r1)
1257         ld      r31, -8(r1)
1258
1259         /* Jump back to real return address */
1260         blr
1261 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1262 #endif /* CONFIG_FUNCTION_TRACER */