l4/pkg/libpng/lib/dist/configure.ac

   1 # configure.ac
   2
   3 dnl Process this file with autoconf to produce a configure script.
   4 dnl
   5 dnl Minor upgrades (compatible ABI): increment the package version
   6 dnl (third field in two places below) and set the PNGLIB_RELEASE
   7 dnl variable.
   8 dnl
   9 dnl Major upgrades (incompatible ABI): increment the package major
  10 dnl version (second field, or first if desired), set the minor
  11 dnl to 0, set PNGLIB_MAJOR below *and* follow the instructions in
  12 dnl Makefile.am to upgrade the package name.
  13
  14 dnl This is here to prevent earlier autoconf from being used, it
  15 dnl should not be necessary to regenerate configure if the time
  16 dnl stamps are correct
  17 AC_PREREQ(2.59)
  18
  19 dnl Version number stuff here:
  20
  21 AC_INIT([libpng], [1.4.3], [png-mng-implement@lists.sourceforge.net])
  22 AM_INIT_AUTOMAKE
  23 dnl stop configure from automagically running automake
  24 AM_MAINTAINER_MODE
  25
  26 PNGLIB_VERSION=1.4.3
  27 PNGLIB_MAJOR=1
  28 PNGLIB_MINOR=4
  29 PNGLIB_RELEASE=3
  30
  31 dnl End of version number stuff
  32
  33 AC_CONFIG_SRCDIR([pngget.c])
  34 AM_CONFIG_HEADER(config.h)
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_LD
  39 AC_PROG_CPP
  40 AC_CHECK_TOOL(SED, sed, :)
  41 AC_LIBTOOL_WIN32_DLL
  42 AC_PROG_INSTALL
  43 AC_PROG_LN_S
  44 AC_PROG_MAKE_SET
  45 AC_PROG_LIBTOOL
  46
  47 # Checks for header files.
  48 AC_HEADER_STDC
  49 AC_CHECK_HEADERS([malloc.h stdlib.h string.h strings.h])
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_CONST
  53 AC_TYPE_SIZE_T
  54 AC_STRUCT_TM
  55
  56 # Checks for library functions.
  57 AC_FUNC_STRTOD
  58 AC_CHECK_FUNCS([memset], , AC_ERROR([memset not found in libc]))
  59 AC_CHECK_FUNCS([pow], , AC_CHECK_LIB(m, pow, , AC_ERROR([cannot find pow])) )
  60 AC_CHECK_LIB(z, zlibVersion, , AC_ERROR([zlib not installed]))
  61
  62 case $host_os in
  63   aix*)
  64    LIBPNG_DEFINES="-DPNG_CONFIGURE_LIBPNG -D_ALL_SOURCE";;
  65   *)
  66    LIBPNG_DEFINES=-DPNG_CONFIGURE_LIBPNG;;
  67 esac
  68 LIBPNG_DEFINES=$LIBPNG_DEFINES
  69 AC_SUBST(LIBPNG_DEFINES)
  70
  71 AC_MSG_CHECKING([if libraries can be versioned])
  72 GLD=`$LD --help < /dev/null 2>/dev/null | grep version-script`
  73 if test "$GLD"; then
  74     have_ld_version_script=yes
  75     AC_MSG_RESULT(yes)
  76 else
  77     have_ld_version_script=no
  78     AC_MSG_RESULT(no)
  79     AC_MSG_WARN(*** You have not enabled versioned symbols.)
  80 fi
  81 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
  82
  83 if test "$have_ld_version_script" = "yes"; then
  84     AC_MSG_CHECKING([for symbol prefix])
  85     SYMBOL_PREFIX=`echo "PREFIX=__USER_LABEL_PREFIX__" \
  86                    | ${CPP-${CC-gcc} -E} - 2>&1 \
  87                    | ${EGREP-grep} "^PREFIX=" \
  88                    | ${SED-sed} "s:^PREFIX=::"`
  89     AC_SUBST(SYMBOL_PREFIX)
  90     AC_MSG_RESULT($SYMBOL_PREFIX)
  91 fi
  92
  93 # Substitutions for .in files
  94 AC_SUBST(PNGLIB_VERSION)
  95 AC_SUBST(PNGLIB_MAJOR)
  96 AC_SUBST(PNGLIB_MINOR)
  97 AC_SUBST(PNGLIB_RELEASE)
  98
  99 # Additional arguments (and substitutions)
 100 # Allow the pkg-config directory to be set
 101 AC_ARG_WITH(pkgconfigdir,
 102         AC_HELP_STRING([--with-pkgconfigdir],
 103         [Use the specified pkgconfig dir (default is libdir/pkgconfig)]),
 104         [pkgconfigdir=${withval}],
 105         [pkgconfigdir='${libdir}/pkgconfig'])
 106
 107 AC_SUBST([pkgconfigdir])
 108 AC_MSG_NOTICE([pkgconfig directory is ${pkgconfigdir}])
 109
 110 # Make the *-config binary config scripts optional
 111 AC_ARG_WITH(binconfigs,
 112         AC_HELP_STRING([--with-binconfigs],
 113                 [Generate shell libpng-config scripts as well as pkg-config data]
 114                 [@<:@default=yes@:>@]),
 115         [if test "${withval}" = no; then
 116                 binconfigs=
 117                 AC_MSG_NOTICE([libpng-config scripts will not be built])
 118         else
 119                 binconfigs='${binconfigs}'
 120         fi],
 121         [binconfigs='${binconfigs}'])
 122 AC_SUBST([binconfigs])
 123
 124 # Config files, substituting as above
 125 AC_CONFIG_FILES([Makefile libpng.pc:libpng.pc.in])
 126 AC_CONFIG_FILES([libpng-config:libpng-config.in],
 127                 [chmod +x libpng-config])
 128
 129 AC_OUTPUT