l4/pkg/bootstrap/server/src/ARCH-sparc/bootstrap.ld.in

   1
   2 #include "ldscript.inc"
   3
   4 ENTRY(_start)
   5
   6 PHDRS {
   7   common PT_LOAD;
   8 #ifdef IMAGE_MODE
   9   mods PT_LOAD;
  10 #endif
  11 }
  12
  13 SECTIONS
  14 {
  15   . = LINKADDR;
  16   /* Merge .text, .rodata, and .data in one segment to save space */
  17   .text :
  18   {
  19         _stext = .;
  20     *(.init)
  21     *(.text .text.* .gnu.linkonce.t.*)
  22   } : common
  23
  24   .data :
  25   {
  26     *(.rodata* .gnu.linkonce.r.*)
  27     . = ALIGN(8);
  28     *(.data)
  29     *(.data.*)
  30
  31     CTORS
  32     PLATFORMS
  33
  34     _module_info_start = .;
  35     *(.module_info)
  36     _module_info_end = .;
  37
  38     . = ALIGN(4096);
  39     _modules_start = .;
  40     *(.module.data)
  41     . = ALIGN(4096);
  42     _modules_end = .;
  43
  44   } : common
  45
  46   _edata  =  .;
  47   PROVIDE (edata = .);
  48   . = ALIGN(4096);
  49   __bss_start = .;
  50   .bss :
  51   {
  52    *(.bss)
  53    *(COMMON)
  54    *(.bss_memmap)
  55   } : common
  56   _end = . ;
  57   PROVIDE (end = .);
  58
  59 /* Only move modules to modaddr if bootstrap is being loaded by an elf
  60  * loader, and we do not need to copy images around at runtime (e.g. with
  61  * compression) */
  62 #ifdef IMAGE_MODE
  63 #if defined(PLACE_MODULES_AT_MODADDR) && !defined(SINGLE_SECTION)
  64   . = RAM_BASE + MODADDR;
  65 #endif
  66   _module_data_start = .;
  67   .module_data : { *(.module_data) } : mods
  68   _module_data_end = .;
  69 #endif
  70
  71   /DISCARD/ : {
  72     *(.interp)
  73     *(.comment)
  74     *(.note)
  75     *(.eh_frame)
  76     *(.stab)
  77     *(.stabstr)
  78     *(.fini)
  79   }
  80 }