l4/pkg/uclibc/lib/contrib/uclibc/libc/sysdeps/linux/sparc/__longjmp.S

   1 /* Copyright (C) 1991, 93, 96, 97, 98, 99, 2000 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <features.h>
  20 #include <sys/syscall.h>
  21
  22 #define _ASM 1
  23 #define _SETJMP_H
  24 #include <bits/setjmp.h>
  25 #define ENV(base,reg) [%base + (reg * 4)]
  26 #define ST_FLUSH_WINDOWS 3
  27 #define RW_FP [%fp + 0x48]
  28
  29 .global __longjmp
  30 .type   __longjmp,%function
  31 .align 4
  32 __longjmp:
  33         .register %g2, #scratch
  34         .register %g3, #scratch
  35         /* Store our arguments in global registers so we can still
  36          * use them while unwinding frames and their register windows.  */
  37
  38         ld ENV(o0,JB_FP), %g3   /* Cache target FP in register %g3.  */
  39         mov %o0, %g1            /* ENV in %g1 */
  40         orcc %o1, %g0, %g2      /* VAL in %g2 */
  41         be,a 0f                 /* Branch if zero; else skip delay slot.  */
  42         mov 1, %g2              /* Delay slot only hit if zero: VAL = 1.  */
  43 0:
  44         xor %fp, %g3, %o0
  45         add %fp, 512, %o1
  46         andncc %o0, 4095, %o0
  47         bne .Lthread
  48         cmp %o1, %g3
  49         bl .Lthread
  50
  51         /* Now we will loop, unwinding the register windows up the stack
  52          * until the restored %fp value matches the target value in %g3.  */
  53
  54 .Lloop:
  55         cmp %fp, %g3            /* Have we reached the target frame? */
  56         bl,a .Lloop             /* Loop while current fp is below target.  */
  57          restore                /* Unwind register window in delay slot.  */
  58         be,a .Lfound            /* Better have hit it exactly.  */
  59          ld ENV(g1,JB_SP), %o0  /* Delay slot: extract target SP.  */
  60
  61 .Lthread:
  62         /*
  63          * Do a "flush register windows trap".  The trap handler in the
  64          * kernel writes all the register windows to their stack slots, and
  65          * marks them all as invalid (needing to be sucked up from the
  66          * stack when used).  This ensures that all information needed to
  67          * unwind to these callers is in memory, not in the register
  68          * windows.
  69          */
  70         ta      ST_FLUSH_WINDOWS
  71         ld      ENV(g1,JB_PC), %o7 /* Set return PC. */
  72         ld      ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */
  73         sub     %fp, 64, %sp    /* Allocate a register frame. */
  74         st      %g3, RW_FP      /* Set saved FP on restore below. */
  75         retl
  76         restore %g2, 0, %o0     /* Restore values from above register frame. */
  77
  78 .Lfound:
  79         /* We have unwound register windows so %fp matches the target.  */
  80         mov %o0, %sp            /* OK, install new SP.  */
  81
  82 .Lsp_ok:
  83         ld ENV(g1,JB_PC), %o0   /* Extract target return PC.  */
  84         jmp %o0 + 8             /* Return there.  */
  85          mov %g2, %o0           /* Delay slot: set return value.  */
  86
  87 .size __longjmp,.-__longjmp
  88
  89 libc_hidden_def(__longjmp)