l4/pkg/uclibc/lib/contrib/uclibc/libc/sysdeps/linux/m68k/crt1.S

   1 /* Startup code compliant to the ELF m68k ABI.
   2    Copyright (C) 1996, 1997, 1998, 2001, 2002 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, write to the Free
  34    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  35    02111-1307 USA.  */
  36
  37 #include <features.h>
  38 #include "m68k_pic.S"
  39
  40 #ifndef L_Scrt1
  41 /* This is the canonical entry point, usually the first thing in the text
  42    segment.  The SVR4/m68k ABI says that when the entry point runs,
  43    most registers' values are unspecified, except for:
  44
  45    %a1          Contains a function pointer to be registered with `atexit'.
  46                 This is how the dynamic linker arranges to have DT_FINI
  47                 functions called for shared libraries that have been loaded
  48                 before this code runs.
  49
  50    %sp          The stack contains the arguments and environment:
  51                 0(%sp)                  argc
  52                 4(%sp)                  argv[0]
  53                 ...
  54                 (4*argc)(%sp)           NULL
  55                 (4*(argc+1))(%sp)       envp[0]
  56                 ...
  57                                         NULL
  58
  59    The uclinux conventions are different.  %a1 is not defined on entry
  60    and the stack is laid out as follows:
  61
  62                 0(%sp)                  argc
  63                 4(%sp)                  argv
  64                 8(%sp)                  envp
  65 */
  66
  67         .text
  68         .type   _init,%function
  69         .type   _fini,%function
  70 #ifndef __UCLIBC_CTOR_DTOR__
  71         .weak   _init
  72         .weak   _fini
  73 #endif
  74         .globl _start
  75         .type _start,@function
  76 _start:
  77         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  78            the outermost frame obviously.  */
  79         sub.l %fp, %fp
  80
  81 #if !defined __ARCH_USE_MMU__ && defined __PIC__
  82         /* Set up the global pointer.  The GOT is at the beginning of the
  83            data segment, whose address is in %d5.  */
  84         move.l %d5,%a5
  85         .equ have_current_got, 1
  86 #endif
  87
  88 #ifdef __UCLIBC_FORMAT_SHARED_FLAT__
  89         CALL __shared_flat_add_library,%a1
  90 #endif
  91
  92         /* Extract the arguments as encoded on the stack and set up the
  93            arguments for `main': argc, argv.  envp will be determined
  94            later in __libc_start_main.  */
  95         move.l (%sp)+, %d0      /* Pop the argument count.  */
  96 #ifndef __ARCH_USE_MMU__
  97         move.l (%sp)+, %a0
  98 #else
  99         move.l %sp, %a0         /* The argument vector starts just at the
 100                                    current stack top.  */
 101 #endif
 102
 103         /* Provide the highest stack address to the user code (for stacks
 104            which grow downward).  */
 105         pea (%sp)
 106
 107 #ifndef __ARCH_USE_MMU__
 108         clr.l -(%sp)
 109 #else
 110         pea (%a1)               /* Push address of the shared library
 111                                    termination function.  */
 112 #endif
 113
 114         /* Push the address of our own entry points to `.fini' and
 115            `.init'.  */
 116 #if defined __UCLIBC_FORMAT_SHARED_FLAT__
 117         PEA_TEXT __shared_flat_fini,%a1
 118         PEA_TEXT __shared_flat_init,%a1
 119 #else
 120         PEA_TEXT _fini,%a1
 121         PEA_TEXT _init,%a1
 122 #endif
 123
 124         pea (%a0)               /* Push second argument: argv.  */
 125         move.l %d0, -(%sp)      /* Push first argument: argc.  */
 126
 127         PEA_TEXT main,%a1
 128
 129         /* Call the user's main function, and exit with its value.  But
 130            let the libc call main.  */
 131         CALL __uClibc_main,%a1
 132
 133         illegal                 /* Crash if somehow `exit' does return.  */
 134 #else
 135         .text
 136         .globl lib_main
 137         .hidden lib_main
 138         .type lib_main,@function
 139 lib_main:
 140         move.l %d5,%a5
 141         JUMP __shared_flat_add_library,%a0
 142
 143         .hidden _current_shared_library_a5_offset_
 144 #endif
 145
 146 /* Define a symbol for the first piece of initialized data.  */
 147         .data
 148         .globl __data_start
 149 __data_start:
 150         .long 0
 151         .weak data_start
 152         data_start = __data_start