l4/pkg/bootstrap/server/src/ARCH-sparc/bootstrap.ld.in

   1
   2 #include "ldscript.inc"
   3
   4 ENTRY(_start)
   5
   6 PHDRS {
   7   data PT_LOAD;
   8 #ifdef IMAGE_MODE
   9   mods PT_LOAD;
  10 #endif
  11 }
  12
  13 SECTIONS
  14 {
  15   . = LINKADDR;
  16   /* Merge .text, .rodata, and .data in one segment to save space */
  17   .data :
  18   {
  19     *(.init)
  20     *(.text .text.* .gnu.linkonce.t*)
  21     *(.rodata*)
  22     . = ALIGN(8);
  23     *(.data)
  24     *(.data.*)
  25
  26     CTORS
  27     PLATFORMS
  28
  29     _module_info_start = .;
  30     *(.module_info)
  31     _module_info_end = .;
  32
  33     . = ALIGN(4096);
  34     _modules_start = .;
  35     *(.module.data)
  36     . = ALIGN(4096);
  37     _modules_end = .;
  38
  39   } : data
  40   _edata  =  .;
  41   PROVIDE (edata = .);
  42   . = ALIGN(4096);
  43   __bss_start = .;
  44   .bss :
  45   {
  46    *(.bss)
  47    *(COMMON)
  48    *(.bss_memmap)
  49   } : data
  50   _end = . ;
  51   PROVIDE (end = .);
  52
  53 /* Only move modules to modaddr if bootstrap is being loaded by an elf
  54  * loader, and we do not need to copy images around at runtime (e.g. with
  55  * compression) */
  56 #ifdef IMAGE_MODE
  57 #if defined(PLACE_MODULES_AT_MODADDR) && !defined(SINGLE_SECTION)
  58   . = RAM_BASE + MODADDR;
  59 #endif
  60   _module_data_start = .;
  61   .module_data : { *(.module_data) } : mods
  62   _module_data_end = .;
  63 #endif
  64
  65   /DISCARD/ : {
  66     *(.interp)
  67     *(.comment)
  68     *(.note)
  69     *(.eh_frame)
  70     *(.stab)
  71     *(.stabstr)
  72     *(.fini)
  73   }
  74 }