l4/pkg/uclibc/lib/contrib/uclibc/libc/sysdeps/linux/x86_64/crt1.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001, 2002, 2003, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 /* Originally based on glibc's sysdeps/x86_64/elf/start.S */
  38
  39 /* This is the canonical entry point, usually the first thing in the text
  40    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  41    point runs, most registers' values are unspecified, except for:
  42
  43    %rdx         Contains a function pointer to be registered with `atexit'.
  44                 This is how the dynamic linker arranges to have DT_FINI
  45                 functions called for shared libraries that have been loaded
  46                 before this code runs.
  47
  48    %rsp         The stack contains the arguments and environment:
  49                 0(%rsp)                 argc
  50                 8(%rsp)                 argv[0]
  51                 ...
  52                 (8*argc)(%rsp)          NULL
  53                 (8*(argc+1))(%rsp)      envp[0]
  54                 ...
  55                                         NULL
  56 */
  57
  58 #include <features.h>
  59
  60 .text
  61 .global _start
  62 .type   _start,%function
  63 #if defined(__UCLIBC_CTOR_DTOR__)
  64 .type   _init,%function
  65 .type   _fini,%function
  66 #else
  67 .weak   _init
  68 .weak   _fini
  69 #endif
  70 .type   __uClibc_main,%function
  71 /* Stick in a dummy reference to main(), so that if an application
  72  * is linking when the main() function is in a static library (.a)
  73  * we can be sure that main() actually gets linked in */
  74 .type   main,%function
  75
  76 _start:
  77         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  78            the outermost frame obviously.  */
  79         xorl %ebp, %ebp
  80
  81         /* Extract the arguments as encoded on the stack and set up
  82            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  83                    int argc, char *argv,
  84                    void (*init) (void), void (*fini) (void),
  85                    void (*rtld_fini) (void), void *stack_end).
  86            The arguments are passed via registers and on the stack:
  87         main:           %rdi
  88         argc:           %rsi
  89         argv:           %rdx
  90         init:           %rcx
  91         fini:           %r8
  92         rtld_fini:      %r9
  93         stack_end:      stack.  */
  94
  95         movq %rdx, %r9   /* Address of the shared library termination function. */
  96         popq %rsi        /* Pop the argument count. */
  97         movq %rsp, %rdx  /* argv starts just at the current stack top. */
  98
  99         /* Align the stack to a 16 byte boundary to follow the ABI. */
 100         andq $~15, %rsp
 101
 102         pushq %rax              /* Push garbage because we push 8 more bytes.  */
 103
 104         /* Provide the highest stack address to the user code (for stacks
 105            which grow downwards).  */
 106         pushq %rsp
 107
 108 #if defined(L_Scrt1)
 109         /* Give address for main() */
 110         movq main@GOTPCREL(%rip), %rdi
 111
 112         /* setup init/fini address */
 113         movq _init@GOTPCREL(%rip), %rcx
 114         movq _fini@GOTPCREL(%rip), %r8
 115
 116         /* start the fun */
 117         call __uClibc_main@PLT
 118 #else
 119         /* Give address for main() */
 120         movq $main, %rdi
 121
 122         /* setup init/fini address */
 123         movq $_init, %rcx
 124         movq $_fini, %r8
 125
 126         /* start the fun */
 127         call __uClibc_main
 128 #endif
 129
 130         hlt        /* Crash if somehow `exit' does return.  */
 131 .size _start,.-_start
 132
 133 /* Define a symbol for the first piece of initialized data. */
 134 .data
 135 .global __data_start
 136 __data_start:
 137 .long 0
 138 .weak data_start
 139         data_start = __data_start