l4/pkg/uclibc/lib/contrib/uclibc/libc/sysdeps/linux/ia64/crt1.S

   1 /* Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Written by Jes Sorensen, <Jes.Sorensen@cern.ch>, April 1999.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 #define __ASSEMBLY__
  37 #include "sysdep.h"
  38
  39 #include <asm/unistd.h>
  40 #include <asm/fpu.h>
  41
  42 /*
  43  * Arguments for __uClibc_main:
  44  *      out0:   main
  45  *      out1:   argc
  46  *      out2:   argv
  47  *      out3:   init
  48  *      out4:   fini
  49  *      out5:   rtld_fini
  50  *      out6:   stack_end
  51  */
  52
  53 #if defined(__UCLIBC_CTOR_DTOR__)
  54 .type   _init,%function
  55 .type   _fini,%function
  56 #else
  57 .weak   _init
  58 .weak   _fini
  59 #endif
  60
  61         .align 32
  62         .global _start
  63
  64         .proc _start
  65         .type _start,@function
  66 _start:
  67         .prologue
  68         .save rp, r0
  69         .body
  70         .prologue
  71         { .mlx
  72           alloc r2 = ar.pfs,0,0,7,0
  73           movl r3 = FPSR_DEFAULT
  74         }
  75         { .mlx
  76           adds out2 = 16, sp    /* get address of argc value */
  77           movl gp = @gprel(0f)
  78           ;;
  79         }
  80 0:      { .mmi
  81           ld8 out1 = [out2], 8  /* load argc and move out2 to become argv */
  82           mov.m r10 = ar.bsp    /* fetch rbs base address */
  83           mov r9 = ip
  84           ;;
  85         }
  86         { .mii
  87           mov ar.fpsr = r3
  88           sub gp = r9, gp       /* back-compute gp value */
  89           adds out6 = 16, sp    /* highest non-environment stack address */
  90           ;;
  91         }
  92         {
  93           addl r11 = @ltoff(__libc_ia64_register_backing_store_base), gp
  94           addl out0 = @ltoff(@fptr(main)), gp
  95           addl out3 = @ltoff(@fptr(_init)), gp
  96           ;;
  97         }
  98         { .mmi
  99           ld8 r3 = [r11]        /* pointer to __libc_ia64_register_backing_store_base */
 100           ld8 out0 = [out0]     /* pointer to `main' function descriptor */
 101           addl out4 = @ltoff(@fptr(_fini)), gp
 102           ;;
 103         }
 104         { .mmi
 105           ld8 out3 = [out3]     /* pointer to `init' function descriptor */
 106           ld8 out4 = [out4]     /* pointer to `fini' function descriptor */
 107           nop 0
 108         }
 109         .body
 110         { .mib
 111           st8 [r3] = r10
 112           mov out5 = ret0       /* dynamic linker destructor */
 113           br.call.sptk.few rp = __uClibc_main
 114         }
 115         { .mib
 116           break 0       /* break miserably if we ever return */
 117         }
 118         .endp _start
 119
 120 /* Define a symbol for the first piece of initialized data.  */
 121         .data
 122         .globl __data_start
 123 __data_start:
 124         .long 0
 125         .weak data_start
 126         data_start = __data_start
 127
 128         .common __libc_ia64_register_backing_store_base, 8, 8