l4/pkg/uclibc/lib/contrib/uclibc/libc/sysdeps/linux/bfin/bsd-_setjmp.S

   1 /* __setjmp for the Blackfin project
   2  *
   3  * Copyright (C) 2000-2006 Erik Andersen <andersen@uclibc.org>
   4  * Copyright (C) 2002, David McCullough <davidm@snapgear.com>
   5  *
   6  * Licensed under the LGPL v2.1, see the file COPYING.LIB in this tarball.
   7  */
   8
   9 .text
  10 .global __setjmp;
  11 .type   __setjmp,STT_FUNC;
  12 .align 4;
  13
  14 __setjmp:
  15         [--SP] = P0;    /* Save P0 */
  16         P0 = R0;
  17         R0 = [SP++];
  18         [P0 + 0x00] = R0;       /* Save saved P0 */
  19         [P0 + 0x04] = P1;
  20         [P0 + 0x08] = P2;
  21         [P0 + 0x0C] = P3;
  22         [P0 + 0x10] = P4;
  23         [P0 + 0x14] = P5;
  24
  25         [P0 + 0x18] = FP;       /* Frame Pointer */
  26         [P0 + 0x1C] = SP;       /* Stack Pointer */
  27
  28         [P0 + 0x20] = P0;       /* Data Registers */
  29         [P0 + 0x24] = R1;
  30         [P0 + 0x28] = R2;
  31         [P0 + 0x2C] = R3;
  32         [P0 + 0x30] = R4;
  33         [P0 + 0x34] = R5;
  34         [P0 + 0x38] = R6;
  35         [P0 + 0x3C] = R7;
  36
  37         R0 = ASTAT;
  38         [P0 + 0x40] = R0;
  39
  40         R0 = LC0;               /* Loop Counters */
  41         [P0 + 0x44] = R0;
  42         R0 = LC1;
  43         [P0 + 0x48] = R0;
  44
  45         R0 = A0.W;              /* Accumulators */
  46         [P0 + 0x4C] = R0;
  47         R0 = A0.X;
  48         [P0 + 0x50] = R0;
  49         R0 = A1.W;
  50         [P0 + 0x54] = R0;
  51         R0 = A1.X;
  52         [P0 + 0x58] = R0;
  53
  54         R0 = I0;                /* Index Registers */
  55         [P0 + 0x5C] = R0;
  56         R0 = I1;
  57         [P0 + 0x60] = R0;
  58         R0 = I2;
  59         [P0 + 0x64] = R0;
  60         R0 = I3;
  61         [P0 + 0x68] = R0;
  62
  63         R0 = M0;                /* Modifier Registers */
  64         [P0 + 0x6C] = R0;
  65         R0 = M1;
  66         [P0 + 0x70] = R0;
  67         R0 = M2;
  68         [P0 + 0x74] = R0;
  69         R0 = M3;
  70         [P0 + 0x78] = R0;
  71
  72         R0 = L0;                /* Length Registers */
  73         [P0 + 0x7c] = R0;
  74         R0 = L1;
  75         [P0 + 0x80] = R0;
  76         R0 = L2;
  77         [P0 + 0x84] = R0;
  78         R0 = L3;
  79         [P0 + 0x88] = R0;
  80
  81         R0 = B0;                /* Base Registers */
  82         [P0 + 0x8C] = R0;
  83         R0 = B1;
  84         [P0 + 0x90] = R0;
  85         R0 = B2;
  86         [P0 + 0x94] = R0;
  87         R0 = B3;
  88         [P0 + 0x98] = R0;
  89
  90         R0 = RETS;
  91         [P0 + 0x9C] = R0;
  92
  93         R0 = [P0 + 0x20];
  94         R1 = 0;
  95         JUMP.L ___sigjmp_save;
  96
  97 .size __setjmp,.-__setjmp
  98
  99 .section .note.GNU-stack,"",%progbits