l4/pkg/libstdc++-v3/contrib/libstdc++-v3-4.9/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 if test "$enable_vtable_verify" = yes; then
 101   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 102   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 103 fi
 104
 105
 106 # libtool variables for C++ shared and position-independent compiles.
 107 #
 108 # Use glibcxx_lt_pic_flag to designate the automake variable
 109 # used to encapsulate the default libtool approach to creating objects
 110 # with position-independent code. Default: -prefer-pic.
 111 #
 112 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 113 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 114 #
 115 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 116 # creating position-independent objects. This varies with the target
 117 # hardware and operating system, but is often: -DPIC -fPIC.
 118 if test "$enable_shared" = yes; then
 119   glibcxx_lt_pic_flag="-prefer-pic"
 120   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 121   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 122
 123 else
 124   glibcxx_lt_pic_flag=
 125   glibcxx_compiler_pic_flag=
 126   glibcxx_compiler_shared_flag=
 127 fi
 128 AC_SUBST(glibcxx_lt_pic_flag)
 129 AC_SUBST(glibcxx_compiler_pic_flag)
 130 AC_SUBST(glibcxx_compiler_shared_flag)
 131
 132 # Override the libtool's pic_flag and pic_mode.
 133 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 134 # NB: this impacts --with-pic and --without-pic.
 135 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 136 pic_mode='default'
 137
 138 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 139 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 140
 141 # Possibly disable most of the library.
 142 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 143 ## than just ignoring the results.  Faster /and/ more correct, win win.
 144 GLIBCXX_ENABLE_HOSTED
 145
 146 # Enable descriptive messages to standard output on termination.
 147 GLIBCXX_ENABLE_VERBOSE
 148
 149 # Enable compiler support that doesn't require linking.
 150 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_DECIMAL_FLOAT
 155 GLIBCXX_ENABLE_INT128_FLOAT128
 156
 157 # Checks for compiler support that doesn't require linking.
 158 GLIBCXX_CHECK_COMPILER_FEATURES
 159
 160 # Enable all the variable C++ runtime options that don't require linking.
 161 GLIBCXX_ENABLE_CSTDIO
 162 GLIBCXX_ENABLE_CLOCALE
 163 GLIBCXX_ENABLE_ALLOCATOR
 164 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 165 GLIBCXX_ENABLE_LONG_LONG([yes])
 166 GLIBCXX_ENABLE_WCHAR_T([yes])
 167 GLIBCXX_ENABLE_C99([yes])
 168 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 169 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 170 GLIBCXX_ENABLE_DEBUG([no])
 171 GLIBCXX_ENABLE_PARALLEL([yes])
 172 GLIBCXX_ENABLE_CXX_FLAGS
 173 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 174 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 175 GLIBCXX_ENABLE_PYTHON
 176 GLIBCXX_ENABLE_WERROR([yes])
 177 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 178
 179 # Checks for operating systems support that doesn't require linking.
 180 GLIBCXX_CHECK_STDIO_PROTO
 181 GLIBCXX_CHECK_SYSTEM_ERROR
 182
 183 # For the streamoff typedef.
 184 GLIBCXX_CHECK_INT64_T
 185
 186 # For LFS support.
 187 GLIBCXX_CHECK_LFS
 188
 189 # For showmanyc_helper().
 190 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 191 GLIBCXX_CHECK_POLL
 192 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 193
 194 # For xsputn_2().
 195 AC_CHECK_HEADERS(sys/uio.h)
 196 GLIBCXX_CHECK_WRITEV
 197
 198 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 199 # so that the check is done with the C compiler (not C++).
 200 # Checking with C++ can break a canadian cross build if either
 201 # file does not exist in C but does in C++.
 202 AC_CHECK_HEADERS(fenv.h complex.h)
 203
 204 # For C99 support to TR1.
 205 GLIBCXX_CHECK_C99_TR1
 206
 207 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 208 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 209
 210 # For gettimeofday support.
 211 GLIBCXX_CHECK_GETTIMEOFDAY
 212
 213 # For clock_gettime, nanosleep and sched_yield support.
 214 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 215
 216 # Check for tmpnam which is obsolescent in POSIX.1-2008
 217 GLIBCXX_CHECK_TMPNAM
 218
 219 AC_LC_MESSAGES
 220
 221 # For hardware_concurrency
 222 AC_CHECK_HEADERS(sys/sysinfo.h)
 223 GLIBCXX_CHECK_GET_NPROCS
 224 AC_CHECK_HEADERS(unistd.h)
 225 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 226 GLIBCXX_CHECK_SC_NPROC_ONLN
 227 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 228 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 229 GLIBCXX_CHECK_SDT_H
 230
 231 # Check for available headers.
 232 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 233 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 234 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 235 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 236 wchar.h wctype.h])
 237
 238 # Only do link tests if native. Else, hardcode.
 239 if $GLIBCXX_IS_NATIVE; then
 240
 241   # We can do more elaborate tests that assume a working linker.
 242   CANADIAN=no
 243
 244   GLIBCXX_CHECK_LINKER_FEATURES
 245   GLIBCXX_CHECK_MATH_SUPPORT
 246   GLIBCXX_CHECK_STDLIB_SUPPORT
 247
 248   # For /dev/random and /dev/urandom for TR1.
 249   GLIBCXX_CHECK_RANDOM_TR1
 250
 251   # For TLS support.
 252   GCC_CHECK_TLS
 253
 254   AC_CHECK_FUNCS(__cxa_thread_atexit_impl)
 255
 256   # For iconv support.
 257   AM_ICONV
 258
 259 else
 260
 261   # This lets us hard-code the functionality we know we'll have in the cross
 262   # target environment.  "Let" is a sugar-coated word placed on an especially
 263   # dull and tedious hack, actually.
 264   #
 265   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 266   # that involve linking, can't be used:
 267   #    "cannot open sim-crt0.o"
 268   #    "cannot open crt0.o"
 269   # etc.  All this is because there currently exists no unified, consistent
 270   # way for top level CC information to be passed down to target directories:
 271   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 272   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 273   # crosses can be removed.
 274
 275   # If Canadian cross, then don't pick up tools from the build directory.
 276   # Used only in GLIBCXX_EXPORT_INCLUDES.
 277   if test -n "$with_cross_host" &&
 278      test x"$build_alias" != x"$with_cross_host" &&
 279      test x"$build" != x"$target";
 280   then
 281     CANADIAN=yes
 282   else
 283     CANADIAN=no
 284   fi
 285
 286   # Construct crosses by hand, eliminating bits that need ld...
 287   # GLIBCXX_CHECK_MATH_SUPPORT
 288
 289   # First, test for "known" system libraries.  We may be using newlib even
 290   # on a hosted environment.
 291   if test "x${with_newlib}" = "xyes"; then
 292     os_include_dir="os/newlib"
 293     AC_DEFINE(HAVE_HYPOT)
 294
 295     # GLIBCXX_CHECK_STDLIB_SUPPORT
 296     AC_DEFINE(HAVE_STRTOF)
 297
 298     AC_DEFINE(HAVE_ACOSF)
 299     AC_DEFINE(HAVE_ASINF)
 300     AC_DEFINE(HAVE_ATAN2F)
 301     AC_DEFINE(HAVE_ATANF)
 302     AC_DEFINE(HAVE_CEILF)
 303     AC_DEFINE(HAVE_COSF)
 304     AC_DEFINE(HAVE_COSHF)
 305     AC_DEFINE(HAVE_EXPF)
 306     AC_DEFINE(HAVE_FABSF)
 307     AC_DEFINE(HAVE_FLOORF)
 308     AC_DEFINE(HAVE_FMODF)
 309     AC_DEFINE(HAVE_FREXPF)
 310     AC_DEFINE(HAVE_LDEXPF)
 311     AC_DEFINE(HAVE_LOG10F)
 312     AC_DEFINE(HAVE_LOGF)
 313     AC_DEFINE(HAVE_MODFF)
 314     AC_DEFINE(HAVE_POWF)
 315     AC_DEFINE(HAVE_SINF)
 316     AC_DEFINE(HAVE_SINHF)
 317     AC_DEFINE(HAVE_SQRTF)
 318     AC_DEFINE(HAVE_TANF)
 319     AC_DEFINE(HAVE_TANHF)
 320
 321     AC_DEFINE(HAVE_ICONV)
 322   else
 323     GLIBCXX_CROSSCONFIG
 324   fi
 325
 326   # At some point, we should differentiate between architectures
 327   # like x86, which have long double versions, and alpha/powerpc/etc.,
 328   # which don't. For the time being, punt.
 329   if test x"long_double_math_on_this_cpu" = x"yes"; then
 330     AC_DEFINE(HAVE_ACOSL)
 331     AC_DEFINE(HAVE_ASINL)
 332     AC_DEFINE(HAVE_ATAN2L)
 333     AC_DEFINE(HAVE_ATANL)
 334     AC_DEFINE(HAVE_CEILL)
 335     AC_DEFINE(HAVE_COSL)
 336     AC_DEFINE(HAVE_COSHL)
 337     AC_DEFINE(HAVE_EXPL)
 338     AC_DEFINE(HAVE_FABSL)
 339     AC_DEFINE(HAVE_FLOORL)
 340     AC_DEFINE(HAVE_FMODL)
 341     AC_DEFINE(HAVE_FREXPL)
 342     AC_DEFINE(HAVE_LDEXPL)
 343     AC_DEFINE(HAVE_LOG10L)
 344     AC_DEFINE(HAVE_LOGL)
 345     AC_DEFINE(HAVE_MODFL)
 346     AC_DEFINE(HAVE_POWL)
 347     AC_DEFINE(HAVE_SINCOSL)
 348     AC_DEFINE(HAVE_SINL)
 349     AC_DEFINE(HAVE_SINHL)
 350     AC_DEFINE(HAVE_SQRTL)
 351     AC_DEFINE(HAVE_TANL)
 352     AC_DEFINE(HAVE_TANHL)
 353   fi
 354 fi
 355
 356 # Check for _Unwind_GetIPInfo.
 357 GCC_CHECK_UNWIND_GETIPINFO
 358
 359 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 360
 361 GCC_HEADER_STDINT(include/gstdint.h)
 362
 363 GLIBCXX_ENABLE_SYMVERS([yes])
 364 AC_SUBST(libtool_VERSION)
 365
 366 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 367
 368 ac_ldbl_compat=no
 369 case "$target" in
 370   powerpc*-*-linux* | \
 371   sparc*-*-linux* | \
 372   s390*-*-linux* | \
 373   alpha*-*-linux*)
 374   AC_TRY_COMPILE(, [
 375 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 376 #error no need for long double compatibility
 377 #endif
 378   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 379   if test "$ac_ldbl_compat" = yes; then
 380     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 381               [Define if compatibility should be provided for -mlong-double-64.])
 382     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 383   fi
 384 esac
 385 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 386
 387 # Check if assembler supports disabling hardware capability support.
 388 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 389
 390 # Check if assembler supports rdrand opcode.
 391 GLIBCXX_CHECK_X86_RDRAND
 392
 393 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 394 GLIBCXX_CONFIGURE_TESTSUITE
 395
 396 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 397 GLIBCXX_CHECK_GTHREADS
 398
 399 # Define documentation rules conditionally.
 400
 401 # See if makeinfo has been installed and is modern enough
 402 # that we can use it.
 403 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 404                    [GNU texinfo.* \([0-9][0-9.]*\)],
 405                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 406 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 407
 408 # Check for doxygen
 409 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 410 AC_CHECK_PROG([DOT], dot, yes, no)
 411
 412 # Check for docbook
 413 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 414 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 415 GLIBCXX_CONFIGURE_DOCBOOK
 416
 417 # Check for xml/html dependencies.
 418 AM_CONDITIONAL(BUILD_XML,
 419                test $ac_cv_prog_DOXYGEN = "yes" &&
 420                test $ac_cv_prog_DOT = "yes" &&
 421                test $ac_cv_prog_XSLTPROC = "yes" &&
 422                test $ac_cv_prog_XMLLINT = "yes" &&
 423                test $glibcxx_stylesheets = "yes")
 424
 425 AM_CONDITIONAL(BUILD_HTML,
 426                test $ac_cv_prog_DOXYGEN = "yes" &&
 427                test $ac_cv_prog_DOT = "yes" &&
 428                test $ac_cv_prog_XSLTPROC = "yes" &&
 429                test $ac_cv_prog_XMLLINT = "yes" &&
 430                test $glibcxx_stylesheets = "yes")
 431
 432 # Check for man dependencies.
 433 AM_CONDITIONAL(BUILD_MAN,
 434                test $ac_cv_prog_DOXYGEN = "yes" &&
 435                test $ac_cv_prog_DOT = "yes")
 436
 437 # Check for pdf dependencies.
 438 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 439 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 440 AM_CONDITIONAL(BUILD_PDF,
 441                test $ac_cv_prog_DBLATEX = "yes" &&
 442                test $ac_cv_prog_PDFLATEX = "yes")
 443
 444
 445 # Propagate the target-specific source directories through the build chain.
 446 ATOMICITY_SRCDIR=config/${atomicity_dir}
 447 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 448 ATOMIC_FLAGS=${atomic_flags}
 449 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 450 OS_INC_SRCDIR=config/${os_include_dir}
 451 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 452 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 453 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 454 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 455 AC_SUBST(ATOMICITY_SRCDIR)
 456 AC_SUBST(ATOMIC_WORD_SRCDIR)
 457 AC_SUBST(ATOMIC_FLAGS)
 458 AC_SUBST(CPU_DEFINES_SRCDIR)
 459 AC_SUBST(ABI_TWEAKS_SRCDIR)
 460 AC_SUBST(OS_INC_SRCDIR)
 461 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 462 AC_SUBST(CPU_OPT_EXT_RANDOM)
 463 AC_SUBST(CPU_OPT_BITS_RANDOM)
 464
 465
 466 # Determine cross-compile flags and AM_CONDITIONALs.
 467 #AC_SUBST(GLIBCXX_IS_NATIVE)
 468 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 469 GLIBCXX_EVALUATE_CONDITIONALS
 470
 471 AC_CACHE_SAVE
 472
 473 if test ${multilib} = yes; then
 474   multilib_arg="--enable-multilib"
 475 else
 476   multilib_arg=
 477 fi
 478
 479 # Export all the install information.
 480 GLIBCXX_EXPORT_INSTALL_INFO
 481
 482 # Export all the include and flag information to Makefiles.
 483 GLIBCXX_EXPORT_INCLUDES
 484 GLIBCXX_EXPORT_FLAGS
 485
 486 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 487 dnl which can all be called multiple times as needed, plus one (different)
 488 dnl AC_OUTPUT macro.  This one lists the files to be created:
 489 AC_CONFIG_FILES(Makefile)
 490 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 491 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 492 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 493
 494 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 495 # that multilib installs will end up installed in the correct place.
 496 # The testsuite needs it for multilib-aware ABI baseline files.
 497 # To work around this not being passed down from config-ml.in ->
 498 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 499 # append it here.  Only modify Makefiles that have just been created.
 500 #
 501 # Also, get rid of this simulated-VPATH thing that automake does.
 502 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 503   [cat > vpsed$$ << \_EOF
 504 s!`test -f '$<' || echo '$(srcdir)/'`!!
 505 _EOF
 506    sed -f vpsed$$ $ac_file > tmp$$
 507    mv tmp$$ $ac_file
 508    rm vpsed$$
 509    echo 'MULTISUBDIR =' >> $ac_file
 510    ml_norecursion=yes
 511    . ${multi_basedir}/config-ml.in
 512    AS_UNSET([ml_norecursion])
 513 ])
 514
 515 AC_CONFIG_COMMANDS([generate-headers],
 516   [(cd include && ${MAKE-make} pch_build= )])
 517
 518 dnl And this actually makes things happen:
 519 AC_OUTPUT