l4/pkg/uclibc/lib/contrib/uclibc/libpthread/linuxthreads/sysdeps/unix/sysv/linux/m68k/vfork.S

   1 /* Copyright (C) 1999, 2002, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep-cancel.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <bits/kernel-features.h>
  23
  24 /* Clone the calling process, but without copying the whole address space.
  25    The calling process is suspended until the new process exits or is
  26    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  27    and the process ID of the new process to the old process.  */
  28
  29 ENTRY (__vfork)
  30
  31 #ifdef SHARED
  32         tstl    (__libc_pthread_functions@GOTPC, %pc)
  33 #else
  34         .weak   pthread_create
  35         movel   #pthread_create, %d0
  36 #endif
  37         jbne    HIDDEN_JUMPTARGET (fork)
  38
  39 #ifdef __NR_vfork
  40
  41         /* Pop the return PC value into A0.  */
  42         movel   %sp@+, %a0
  43
  44         /* Stuff the syscall number in D0 and trap into the kernel.  */
  45         movel   #SYS_ify (vfork), %d0
  46         trap    #0
  47         tstl    %d0
  48         jmi     .Lerror         /* Branch forward if it failed.  */
  49
  50         /* Jump to the return PC.  */
  51         jmp     %a0@
  52
  53 .Lerror:
  54         /* Push back the return PC.  */
  55         movel   %a0,%sp@-
  56
  57 # ifdef __ASSUME_VFORK_SYSCALL
  58 #  ifndef __PIC__
  59         jbra    SYSCALL_ERROR_LABEL
  60 #  endif
  61 # else
  62         /* Check if vfork syscall is known at all.  */
  63         movel   #-ENOSYS,%d1
  64         cmpl    %d0,%d1
  65         jne     SYSCALL_ERROR_LABEL
  66
  67 # endif
  68 #endif
  69
  70 #ifndef __ASSUME_VFORK_SYSCALL
  71         /* If we don't have vfork, fork is close enough.  */
  72
  73         movel   #SYS_ify (fork), %d0
  74         trap    #0
  75         tstl    %d0
  76         jmi     SYSCALL_ERROR_LABEL
  77         rts
  78 #endif
  79
  80 PSEUDO_END (__vfork)
  81 libc_hidden_def (__vfork)
  82
  83 weak_alias (__vfork, vfork)