l4/pkg/l4re-core/uclibc/lib/contrib/uclibc/libpthread/nptl/sysdeps/unix/sysv/linux/i386/i486/pthread_rwlock_unlock.S

   1 /* Copyright (C) 2002, 2003, 2007 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <lowlevellock.h>
  21 #include <lowlevelrwlock.h>
  22 #include <bits/kernel-features.h>
  23 #include <tls.h>
  24
  25
  26         .text
  27
  28         .globl  __pthread_rwlock_unlock
  29         .type   __pthread_rwlock_unlock,@function
  30         .protected      __pthread_rwlock_unlock
  31         .align  16
  32 __pthread_rwlock_unlock:
  33         cfi_startproc
  34         pushl   %ebx
  35         cfi_adjust_cfa_offset(4)
  36         pushl   %edi
  37         cfi_adjust_cfa_offset(4)
  38         cfi_offset(%ebx, -8)
  39         cfi_offset(%edi, -12)
  40
  41         movl    12(%esp), %edi
  42
  43         /* Get the lock.  */
  44         movl    $1, %edx
  45         xorl    %eax, %eax
  46         LOCK
  47 #if MUTEX == 0
  48         cmpxchgl %edx, (%edi)
  49 #else
  50         cmpxchgl %edx, MUTEX(%edi)
  51 #endif
  52         jnz     1f
  53
  54 2:      cmpl    $0, WRITER(%edi)
  55         jne     5f
  56         subl    $1, NR_READERS(%edi)
  57         jnz     6f
  58
  59 5:      movl    $0, WRITER(%edi)
  60
  61         movl    $1, %edx
  62         leal    WRITERS_WAKEUP(%edi), %ebx
  63         cmpl    $0, WRITERS_QUEUED(%edi)
  64         jne     0f
  65
  66         /* If also no readers waiting nothing to do.  */
  67         cmpl    $0, READERS_QUEUED(%edi)
  68         je      6f
  69
  70         movl    $0x7fffffff, %edx
  71         leal    READERS_WAKEUP(%edi), %ebx
  72
  73 0:      addl    $1, (%ebx)
  74         LOCK
  75 #if MUTEX == 0
  76         subl    $1, (%edi)
  77 #else
  78         subl    $1, MUTEX(%edi)
  79 #endif
  80         jne     7f
  81
  82 8:
  83 #ifdef __ASSUME_PRIVATE_FUTEX
  84         movzbl  PSHARED(%edi), %ecx
  85         xorl    $FUTEX_PRIVATE_FLAG|FUTEX_WAKE, %ecx
  86 #else
  87         movzbl  PSHARED(%edi), %ecx
  88         orl     $FUTEX_WAKE, %ecx
  89         xorl    %gs:PRIVATE_FUTEX, %ecx
  90 #endif
  91         movl    $SYS_futex, %eax
  92         ENTER_KERNEL
  93
  94         xorl    %eax, %eax
  95         popl    %edi
  96         cfi_adjust_cfa_offset(-4)
  97         cfi_restore(%edi)
  98         popl    %ebx
  99         cfi_adjust_cfa_offset(-4)
 100         cfi_restore(%ebx)
 101         ret
 102
 103         cfi_adjust_cfa_offset(8)
 104         cfi_offset(%ebx, -8)
 105         cfi_offset(%edi, -12)
 106         .align  16
 107 6:      LOCK
 108 #if MUTEX == 0
 109         subl    $1, (%edi)
 110 #else
 111         subl    $1, MUTEX(%edi)
 112 #endif
 113         jne     3f
 114
 115 4:      xorl    %eax, %eax
 116         popl    %edi
 117         popl    %ebx
 118         ret
 119
 120 1:
 121 #if MUTEX == 0
 122         movl    %edi, %edx
 123 #else
 124         leal    MUTEX(%edi), %edx
 125 #endif
 126         movzbl  PSHARED(%edi), %ecx
 127         call    __lll_lock_wait
 128         jmp     2b
 129
 130 3:
 131 #if MUTEX == 0
 132         movl    %edi, %eax
 133 #else
 134         leal    MUTEX(%edi), %eax
 135 #endif
 136         movzbl  PSHARED(%edi), %ecx
 137         call    __lll_unlock_wake
 138         jmp     4b
 139
 140 7:
 141 #if MUTEX == 0
 142         movl    %edi, %eax
 143 #else
 144         leal    MUTEX(%edi), %eax
 145 #endif
 146         movzbl  PSHARED(%edi), %ecx
 147         call    __lll_unlock_wake
 148         jmp     8b
 149         cfi_endproc
 150         .size   __pthread_rwlock_unlock,.-__pthread_rwlock_unlock
 151
 152         .globl  pthread_rwlock_unlock
 153 pthread_rwlock_unlock = __pthread_rwlock_unlock
 154
 155         .globl  __pthread_rwlock_unlock_internal
 156 __pthread_rwlock_unlock_internal = __pthread_rwlock_unlock