l4/pkg/l4re-core/libstdc++-v3/contrib/libstdc++-v3-4.6/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 100 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 101
 102 # Possibly disable most of the library.
 103 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 104 ## than just ignoring the results.  Faster /and/ more correct, win win.
 105 GLIBCXX_ENABLE_HOSTED
 106
 107 # Enable compiler support that doesn't require linking.
 108 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 109 GLIBCXX_ENABLE_PCH($is_hosted)
 110 GLIBCXX_ENABLE_THREADS
 111 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 112 GLIBCXX_ENABLE_DECIMAL_FLOAT
 113
 114 # Checks for compiler support that doesn't require linking.
 115 GLIBCXX_CHECK_COMPILER_FEATURES
 116
 117 # Enable all the variable C++ runtime options that don't require linking.
 118 GLIBCXX_ENABLE_CSTDIO
 119 GLIBCXX_ENABLE_CLOCALE
 120 GLIBCXX_ENABLE_ALLOCATOR
 121 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 122 GLIBCXX_ENABLE_LONG_LONG([yes])
 123 GLIBCXX_ENABLE_WCHAR_T([yes])
 124 GLIBCXX_ENABLE_C99([yes])
 125 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 126 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 127 GLIBCXX_ENABLE_DEBUG([no])
 128 GLIBCXX_ENABLE_PARALLEL([yes])
 129 GLIBCXX_ENABLE_CXX_FLAGS
 130 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 131 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 132
 133 # Checks for operating systems support that doesn't require linking.
 134 GLIBCXX_CHECK_SYSTEM_ERROR
 135
 136 # For the streamoff typedef.
 137 GLIBCXX_CHECK_INT64_T
 138
 139 # For LFS support.
 140 GLIBCXX_CHECK_LFS
 141
 142 # For showmanyc_helper().
 143 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 144 GLIBCXX_CHECK_POLL
 145 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 146
 147 # For xsputn_2().
 148 AC_CHECK_HEADERS(sys/uio.h)
 149 GLIBCXX_CHECK_WRITEV
 150
 151 # For C99 support to TR1.
 152 GLIBCXX_CHECK_C99_TR1
 153
 154 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 155 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 156
 157 # For gettimeofday support.
 158 GLIBCXX_CHECK_GETTIMEOFDAY
 159
 160 # For clock_gettime, nanosleep and sched_yield support.
 161 # NB: The default is [no], because otherwise it requires linking.
 162 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 163
 164 # For gthread support
 165 GLIBCXX_CHECK_GTHREADS
 166
 167 # For copy-assignable gthreads types
 168 GLIBCXX_GTHREADS_CXX11_COPY_ASSIGN
 169
 170 AC_LC_MESSAGES
 171
 172 # Check for available headers.
 173 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 174 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 175 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 176 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 177 wchar.h wctype.h])
 178
 179 # Only do link tests if native. Else, hardcode.
 180 if $GLIBCXX_IS_NATIVE; then
 181
 182   # We can do more elaborate tests that assume a working linker.
 183   CANADIAN=no
 184
 185   GLIBCXX_CHECK_LINKER_FEATURES
 186   GLIBCXX_CHECK_MATH_SUPPORT
 187   GLIBCXX_CHECK_STDLIB_SUPPORT
 188
 189   # For /dev/random and /dev/urandom for TR1.
 190   GLIBCXX_CHECK_RANDOM_TR1
 191
 192   # For TLS support.
 193   GCC_CHECK_TLS
 194
 195   # For iconv support.
 196   AM_ICONV
 197
 198 else
 199
 200   # This lets us hard-code the functionality we know we'll have in the cross
 201   # target environment.  "Let" is a sugar-coated word placed on an especially
 202   # dull and tedious hack, actually.
 203   #
 204   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 205   # that involve linking, can't be used:
 206   #    "cannot open sim-crt0.o"
 207   #    "cannot open crt0.o"
 208   # etc.  All this is because there currently exists no unified, consistent
 209   # way for top level CC information to be passed down to target directories:
 210   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 211   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 212   # crosses can be removed.
 213
 214   # If Canadian cross, then don't pick up tools from the build directory.
 215   # Used only in GLIBCXX_EXPORT_INCLUDES.
 216   if test -n "$with_cross_host" &&
 217      test x"$build_alias" != x"$with_cross_host" &&
 218      test x"$build" != x"$target";
 219   then
 220     CANADIAN=yes
 221   else
 222     CANADIAN=no
 223   fi
 224
 225   # Construct crosses by hand, eliminating bits that need ld...
 226   # GLIBCXX_CHECK_MATH_SUPPORT
 227
 228   # First, test for "known" system libraries.  We may be using newlib even
 229   # on a hosted environment.
 230   if test "x${with_newlib}" = "xyes"; then
 231     os_include_dir="os/newlib"
 232     AC_DEFINE(HAVE_HYPOT)
 233
 234     # GLIBCXX_CHECK_STDLIB_SUPPORT
 235     AC_DEFINE(HAVE_STRTOF)
 236
 237     AC_DEFINE(HAVE_ACOSF)
 238     AC_DEFINE(HAVE_ASINF)
 239     AC_DEFINE(HAVE_ATAN2F)
 240     AC_DEFINE(HAVE_ATANF)
 241     AC_DEFINE(HAVE_CEILF)
 242     AC_DEFINE(HAVE_COSF)
 243     AC_DEFINE(HAVE_COSHF)
 244     AC_DEFINE(HAVE_EXPF)
 245     AC_DEFINE(HAVE_FABSF)
 246     AC_DEFINE(HAVE_FLOORF)
 247     AC_DEFINE(HAVE_FMODF)
 248     AC_DEFINE(HAVE_FREXPF)
 249     AC_DEFINE(HAVE_LDEXPF)
 250     AC_DEFINE(HAVE_LOG10F)
 251     AC_DEFINE(HAVE_LOGF)
 252     AC_DEFINE(HAVE_MODFF)
 253     AC_DEFINE(HAVE_POWF)
 254     AC_DEFINE(HAVE_SINF)
 255     AC_DEFINE(HAVE_SINHF)
 256     AC_DEFINE(HAVE_SQRTF)
 257     AC_DEFINE(HAVE_TANF)
 258     AC_DEFINE(HAVE_TANHF)
 259
 260     AC_DEFINE(HAVE_ICONV)
 261   else
 262     GLIBCXX_CROSSCONFIG
 263   fi
 264
 265   # At some point, we should differentiate between architectures
 266   # like x86, which have long double versions, and alpha/powerpc/etc.,
 267   # which don't. For the time being, punt.
 268   if test x"long_double_math_on_this_cpu" = x"yes"; then
 269     AC_DEFINE(HAVE_ACOSL)
 270     AC_DEFINE(HAVE_ASINL)
 271     AC_DEFINE(HAVE_ATAN2L)
 272     AC_DEFINE(HAVE_ATANL)
 273     AC_DEFINE(HAVE_CEILL)
 274     AC_DEFINE(HAVE_COSL)
 275     AC_DEFINE(HAVE_COSHL)
 276     AC_DEFINE(HAVE_EXPL)
 277     AC_DEFINE(HAVE_FABSL)
 278     AC_DEFINE(HAVE_FLOORL)
 279     AC_DEFINE(HAVE_FMODL)
 280     AC_DEFINE(HAVE_FREXPL)
 281     AC_DEFINE(HAVE_LDEXPL)
 282     AC_DEFINE(HAVE_LOG10L)
 283     AC_DEFINE(HAVE_LOGL)
 284     AC_DEFINE(HAVE_MODFL)
 285     AC_DEFINE(HAVE_POWL)
 286     AC_DEFINE(HAVE_SINCOSL)
 287     AC_DEFINE(HAVE_SINL)
 288     AC_DEFINE(HAVE_SINHL)
 289     AC_DEFINE(HAVE_SQRTL)
 290     AC_DEFINE(HAVE_TANL)
 291     AC_DEFINE(HAVE_TANHL)
 292   fi
 293 fi
 294
 295 # Check for _Unwind_GetIPInfo.
 296 GCC_CHECK_UNWIND_GETIPINFO
 297
 298
 299 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 300
 301 GCC_HEADER_STDINT(include/gstdint.h)
 302
 303 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 304 GLIBCXX_ENABLE_SYMVERS([yes])
 305 AC_SUBST(libtool_VERSION)
 306
 307 GLIBCXX_ENABLE_VISIBILITY([yes])
 308
 309 ac_ldbl_compat=no
 310 case "$target" in
 311   powerpc*-*-linux* | \
 312   powerpc*-*-gnu* | \
 313   sparc*-*-linux* | \
 314   s390*-*-linux* | \
 315   alpha*-*-linux*)
 316   AC_TRY_COMPILE(, [
 317 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 318 #error no need for long double compatibility
 319 #endif
 320   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 321   if test "$ac_ldbl_compat" = yes; then
 322     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 323               [Define if compatibility should be provided for -mlong-double-64.])
 324     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 325   fi
 326 esac
 327 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 328
 329 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 330 GLIBCXX_CONFIGURE_TESTSUITE
 331
 332 # Define documentation rules conditionally.
 333
 334 # See if makeinfo has been installed and is modern enough
 335 # that we can use it.
 336 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 337                    [GNU texinfo.* \([0-9][0-9.]*\)],
 338                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 339 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 340
 341 # Check for doxygen
 342 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 343 AC_CHECK_PROG([DOT], dot, yes, no)
 344
 345 # Check for docbook
 346 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 347 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 348 GLIBCXX_CONFIGURE_DOCBOOK
 349
 350 # Check for xml/html dependencies.
 351 AM_CONDITIONAL(BUILD_XML,
 352                test $ac_cv_prog_DOXYGEN = "yes" &&
 353                test $ac_cv_prog_DOT = "yes" &&
 354                test $ac_cv_prog_XSLTPROC = "yes" &&
 355                test $ac_cv_prog_XMLLINT = "yes" &&
 356                test $glibcxx_stylesheets = "yes")
 357
 358 AM_CONDITIONAL(BUILD_HTML,
 359                test $ac_cv_prog_DOXYGEN = "yes" &&
 360                test $ac_cv_prog_DOT = "yes" &&
 361                test $ac_cv_prog_XSLTPROC = "yes" &&
 362                test $ac_cv_prog_XMLLINT = "yes" &&
 363                test $glibcxx_stylesheets = "yes")
 364
 365 # Check for man dependencies.
 366 AM_CONDITIONAL(BUILD_MAN,
 367                test $ac_cv_prog_DOXYGEN = "yes" &&
 368                test $ac_cv_prog_DOT = "yes")
 369
 370 # Check for pdf/epub dependencies.
 371 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 372 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 373 AM_CONDITIONAL(BUILD_PDF,
 374                test $ac_cv_prog_DBLATEX = "yes" &&
 375                test $ac_cv_prog_PDFLATEX = "yes")
 376
 377 AC_CHECK_PROG([RUBY], ruby, yes, no)
 378 AC_CHECK_PROG([DBTOEPUB], dbtoepub, yes, no)
 379 AM_CONDITIONAL(BUILD_EPUB,
 380                test $ac_cv_prog_RUBY = "yes" &&
 381                test $ac_cv_prog_DBTOEPUB = "yes")
 382
 383
 384 # Propagate the target-specific source directories through the build chain.
 385 ATOMICITY_SRCDIR=config/${atomicity_dir}
 386 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 387 ATOMIC_FLAGS=${atomic_flags}
 388 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 389 OS_INC_SRCDIR=config/${os_include_dir}
 390 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 391 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 392 AC_SUBST(ATOMICITY_SRCDIR)
 393 AC_SUBST(ATOMIC_WORD_SRCDIR)
 394 AC_SUBST(ATOMIC_FLAGS)
 395 AC_SUBST(CPU_DEFINES_SRCDIR)
 396 AC_SUBST(ABI_TWEAKS_SRCDIR)
 397 AC_SUBST(OS_INC_SRCDIR)
 398 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 399
 400
 401 # Determine cross-compile flags and AM_CONDITIONALs.
 402 #AC_SUBST(GLIBCXX_IS_NATIVE)
 403 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 404 GLIBCXX_EVALUATE_CONDITIONALS
 405
 406 AC_CACHE_SAVE
 407
 408 if test ${multilib} = yes; then
 409   multilib_arg="--enable-multilib"
 410 else
 411   multilib_arg=
 412 fi
 413
 414 # Export all the install information.
 415 GLIBCXX_EXPORT_INSTALL_INFO
 416
 417 # Export all the include and flag information to Makefiles.
 418 GLIBCXX_EXPORT_INCLUDES
 419 GLIBCXX_EXPORT_FLAGS
 420
 421 if test "$enable_shared" = yes; then
 422   LIBSUPCXX_PICFLAGS="-prefer-pic"
 423 else
 424   LIBSUPCXX_PICFLAGS=
 425 fi
 426 AC_SUBST(LIBSUPCXX_PICFLAGS)
 427
 428 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 429 dnl which can all be called multiple times as needed, plus one (different)
 430 dnl AC_OUTPUT macro.  This one lists the files to be created:
 431 AC_CONFIG_FILES(Makefile)
 432 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 433 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 434
 435 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 436 # that multilib installs will end up installed in the correct place.
 437 # The testsuite needs it for multilib-aware ABI baseline files.
 438 # To work around this not being passed down from config-ml.in ->
 439 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 440 # append it here.  Only modify Makefiles that have just been created.
 441 #
 442 # Also, get rid of this simulated-VPATH thing that automake does.
 443 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 444   [cat > vpsed$$ << \_EOF
 445 s!`test -f '$<' || echo '$(srcdir)/'`!!
 446 _EOF
 447    sed -f vpsed$$ $ac_file > tmp$$
 448    mv tmp$$ $ac_file
 449    rm vpsed$$
 450    echo 'MULTISUBDIR =' >> $ac_file
 451    ml_norecursion=yes
 452    . ${multi_basedir}/config-ml.in
 453    AS_UNSET([ml_norecursion])
 454 ])
 455
 456 AC_CONFIG_COMMANDS([generate-headers],
 457   [(cd include && ${MAKE-make} pch_build= )])
 458
 459 dnl And this actually makes things happen:
 460 AC_OUTPUT