inmates/inmate.lds

   1 /*
   2  * Jailhouse, a Linux-based partitioning hypervisor
   3  *
   4  * Copyright (c) Siemens AG, 2013
   5  *
   6  * Authors:
   7  *  Jan Kiszka <jan.kiszka@siemens.com>
   8  *
   9  * This work is licensed under the terms of the GNU GPL, version 2.  See
  10  * the COPYING file in the top-level directory.
  11  */
  12
  13 SECTIONS
  14 {
  15         /* 16-bit sections */
  16         . = 0;
  17         .startup        : { *(.startup) }
  18
  19         . = 0xfff0;
  20         .boot           : {
  21                 *(.boot)
  22                 . = ALIGN(16);
  23         }
  24
  25         /* 32/64-bit sections */
  26         . = 0xe0000;
  27         stack_top = .;
  28         bss_start = .;
  29         .bss            : {
  30                 *(.bss)
  31                 . = ALIGN(8);
  32         }
  33         bss_dwords = SIZEOF(.bss) / 4;
  34         bss_qwords = SIZEOF(.bss) / 8;
  35
  36         . = 0xf0000 + SIZEOF(.startup);
  37         .text           : AT (ADDR(.text) & 0xffff) {
  38                 *(.text)
  39         }
  40
  41         . = ALIGN(16);
  42         .rodata         : AT (ADDR(.rodata) & 0xffff) {
  43                 *(.rodata)
  44         }
  45
  46         . = ALIGN(16);
  47         .data           : AT (ADDR(.data) & 0xffff) {
  48                 *(.data)
  49         }
  50
  51         /DISCARD/ : {
  52                 *(.eh_frame*)
  53         }
  54 }