git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22
  23 $Git::SVN::Log::TZ = $ENV{TZ};
  24 $ENV{TZ} = 'UTC';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use Digest::MD5;
  39 use IO::File qw//;
  40 use File::Basename qw/dirname basename/;
  41 use File::Path qw/mkpath/;
  42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43 use IPC::Open3;
  44 use Git;
  45
  46 BEGIN {
  47         # import functions from Git into our packages, en masse
  48         no strict 'refs';
  49         foreach (qw/command command_oneline command_noisy command_output_pipe
  50                     command_input_pipe command_close_pipe/) {
  51                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                         __PACKAGE__) {
  54                         *{"${package}::$_"} = \&{"Git::$_"};
  55                 }
  56         }
  57 }
  58
  59 my ($SVN);
  60
  61 $sha1 = qr/[a-f\d]{40}/;
  62 $sha1_short = qr/[a-f\d]{4,40}/;
  63 my ($_stdin, $_help, $_edit,
  64         $_message, $_file,
  65         $_template, $_shared,
  66         $_version, $_fetch_all, $_no_rebase,
  67         $_merge, $_strategy, $_dry_run, $_local,
  68         $_prefix, $_no_checkout, $_url, $_verbose);
  69 $Git::SVN::_follow_parent = 1;
  70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  71                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  72                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  74                 'authors-file|A=s' => \$_authors,
  75                 'repack:i' => \$Git::SVN::_repack,
  76                 'noMetadata' => \$Git::SVN::_no_metadata,
  77                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  78                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  79                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  80                 'no-checkout' => \$_no_checkout,
  81                 'quiet|q' => \$_q,
  82                 'repack-flags|repack-args|repack-opts=s' =>
  83                    \$Git::SVN::_repack_flags,
  84                 'use-log-author' => \$Git::SVN::_use_log_author,
  85                 %remote_opts );
  86
  87 my ($_trunk, $_tags, $_branches, $_stdlayout);
  88 my %icv;
  89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  90                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  91                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  92                   'stdlayout|s' => \$_stdlayout,
  93                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  94                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  95                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  96                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  97                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  98                   %remote_opts );
  99 my %cmt_opts = ( 'edit|e' => \$_edit,
 100                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 101                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 102                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 103                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 104 );
 105
 106 my %cmd = (
 107         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 108                         { 'revision|r=s' => \$_revision,
 109                           'fetch-all|all' => \$_fetch_all,
 110                            %fc_opts } ],
 111         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 112                         { 'revision|r=s' => \$_revision,
 113                            %fc_opts, %init_opts } ],
 114         init => [ \&cmd_init, "Initialize a repo for tracking" .
 115                           " (requires URL argument)",
 116                           \%init_opts ],
 117         'multi-init' => [ \&cmd_multi_init,
 118                           "Deprecated alias for ".
 119                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 120                           \%init_opts ],
 121         dcommit => [ \&cmd_dcommit,
 122                      'Commit several diffs to merge with upstream',
 123                         { 'merge|m|M' => \$_merge,
 124                           'strategy|s=s' => \$_strategy,
 125                           'verbose|v' => \$_verbose,
 126                           'dry-run|n' => \$_dry_run,
 127                           'fetch-all|all' => \$_fetch_all,
 128                           'no-rebase' => \$_no_rebase,
 129                         %cmt_opts, %fc_opts } ],
 130         'set-tree' => [ \&cmd_set_tree,
 131                         "Set an SVN repository to a git tree-ish",
 132                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 133         'create-ignore' => [ \&cmd_create_ignore,
 134                              'Create a .gitignore per svn:ignore',
 135                              { 'revision|r=i' => \$_revision
 136                              } ],
 137         'propget' => [ \&cmd_propget,
 138                        'Print the value of a property on a file or directory',
 139                        { 'revision|r=i' => \$_revision } ],
 140         'proplist' => [ \&cmd_proplist,
 141                        'List all properties of a file or directory',
 142                        { 'revision|r=i' => \$_revision } ],
 143         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 144                         { 'revision|r=i' => \$_revision
 145                         } ],
 146         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 147                         { 'revision|r=i' => \$_revision
 148                         } ],
 149         'multi-fetch' => [ \&cmd_multi_fetch,
 150                            "Deprecated alias for $0 fetch --all",
 151                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 152         'migrate' => [ sub { },
 153                        # no-op, we automatically run this anyways,
 154                        'Migrate configuration/metadata/layout from
 155                         previous versions of git-svn',
 156                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 157                          %remote_opts } ],
 158         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 159                         { 'limit=i' => \$Git::SVN::Log::limit,
 160                           'revision|r=s' => \$_revision,
 161                           'verbose|v' => \$Git::SVN::Log::verbose,
 162                           'incremental' => \$Git::SVN::Log::incremental,
 163                           'oneline' => \$Git::SVN::Log::oneline,
 164                           'show-commit' => \$Git::SVN::Log::show_commit,
 165                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 166                           'authors-file|A=s' => \$_authors,
 167                           'color' => \$Git::SVN::Log::color,
 168                           'pager=s' => \$Git::SVN::Log::pager
 169                         } ],
 170         'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
 171                         {} ],
 172         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 173                         { 'merge|m|M' => \$_merge,
 174                           'verbose|v' => \$_verbose,
 175                           'strategy|s=s' => \$_strategy,
 176                           'local|l' => \$_local,
 177                           'fetch-all|all' => \$_fetch_all,
 178                           %fc_opts } ],
 179         'commit-diff' => [ \&cmd_commit_diff,
 180                            'Commit a diff between two trees',
 181                         { 'message|m=s' => \$_message,
 182                           'file|F=s' => \$_file,
 183                           'revision|r=s' => \$_revision,
 184                         %cmt_opts } ],
 185         'info' => [ \&cmd_info,
 186                     "Show info about the latest SVN revision
 187                      on the current branch",
 188                     { 'url' => \$_url, } ],
 189         'blame' => [ \&Git::SVN::Log::cmd_blame,
 190                     "Show what revision and author last modified each line of a file",
 191                     {} ],
 192 );
 193
 194 my $cmd;
 195 for (my $i = 0; $i < @ARGV; $i++) {
 196         if (defined $cmd{$ARGV[$i]}) {
 197                 $cmd = $ARGV[$i];
 198                 splice @ARGV, $i, 1;
 199                 last;
 200         }
 201 };
 202
 203 # make sure we're always running at the top-level working directory
 204 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 205         unless (-d $ENV{GIT_DIR}) {
 206                 if ($git_dir_user_set) {
 207                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 208                             "but it is not a directory\n";
 209                 }
 210                 my $git_dir = delete $ENV{GIT_DIR};
 211                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 212                 unless (length $cdup) {
 213                         die "Already at toplevel, but $git_dir ",
 214                             "not found '$cdup'\n";
 215                 }
 216                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 217                 unless (-d $git_dir) {
 218                         die "$git_dir still not found after going to ",
 219                             "'$cdup'\n";
 220                 }
 221                 $ENV{GIT_DIR} = $git_dir;
 222         }
 223 }
 224
 225 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 226
 227 read_repo_config(\%opts);
 228 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 229 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 230                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 231                     'id|i=s' => \$Git::SVN::default_ref_id,
 232                     'svn-remote|remote|R=s' => sub {
 233                        $Git::SVN::no_reuse_existing = 1;
 234                        $Git::SVN::default_repo_id = $_[1] });
 235 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 236
 237 usage(0) if $_help;
 238 version() if $_version;
 239 usage(1) unless defined $cmd;
 240 load_authors() if $_authors;
 241
 242 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 243         Git::SVN::Migration::migration_check();
 244 }
 245 Git::SVN::init_vars();
 246 eval {
 247         Git::SVN::verify_remotes_sanity();
 248         $cmd{$cmd}->[0]->(@ARGV);
 249 };
 250 fatal $@ if $@;
 251 post_fetch_checkout();
 252 exit 0;
 253
 254 ####################### primary functions ######################
 255 sub usage {
 256         my $exit = shift || 0;
 257         my $fd = $exit ? \*STDERR : \*STDOUT;
 258         print $fd <<"";
 259 git-svn - bidirectional operations between a single Subversion tree and git
 260 Usage: $0 <command> [options] [arguments]\n
 261
 262         print $fd "Available commands:\n" unless $cmd;
 263
 264         foreach (sort keys %cmd) {
 265                 next if $cmd && $cmd ne $_;
 266                 next if /^multi-/; # don't show deprecated commands
 267                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 268                 foreach (sort keys %{$cmd{$_}->[2]}) {
 269                         # mixed-case options are for .git/config only
 270                         next if /[A-Z]/ && /^[a-z]+$/i;
 271                         # prints out arguments as they should be passed:
 272                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 273                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 274                                                         "--$_" : "-$_" }
 275                                                 split /\|/,$_)," $x\n";
 276                 }
 277         }
 278         print $fd <<"";
 279 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 280 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 281 one git repository and want to keep them separate.  See git-svn(1) for more
 282 information.
 283
 284         exit $exit;
 285 }
 286
 287 sub version {
 288         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 289         exit 0;
 290 }
 291
 292 sub do_git_init_db {
 293         unless (-d $ENV{GIT_DIR}) {
 294                 my @init_db = ('init');
 295                 push @init_db, "--template=$_template" if defined $_template;
 296                 if (defined $_shared) {
 297                         if ($_shared =~ /[a-z]/) {
 298                                 push @init_db, "--shared=$_shared";
 299                         } else {
 300                                 push @init_db, "--shared";
 301                         }
 302                 }
 303                 command_noisy(@init_db);
 304         }
 305         my $set;
 306         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 307         foreach my $i (keys %icv) {
 308                 die "'$set' and '$i' cannot both be set\n" if $set;
 309                 next unless defined $icv{$i};
 310                 command_noisy('config', "$pfx.$i", $icv{$i});
 311                 $set = $i;
 312         }
 313 }
 314
 315 sub init_subdir {
 316         my $repo_path = shift or return;
 317         mkpath([$repo_path]) unless -d $repo_path;
 318         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 319         $ENV{GIT_DIR} = '.git';
 320 }
 321
 322 sub cmd_clone {
 323         my ($url, $path) = @_;
 324         if (!defined $path &&
 325             (defined $_trunk || defined $_branches || defined $_tags ||
 326              defined $_stdlayout) &&
 327             $url !~ m#^[a-z\+]+://#) {
 328                 $path = $url;
 329         }
 330         $path = basename($url) if !defined $path || !length $path;
 331         cmd_init($url, $path);
 332         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 333 }
 334
 335 sub cmd_init {
 336         if (defined $_stdlayout) {
 337                 $_trunk = 'trunk' if (!defined $_trunk);
 338                 $_tags = 'tags' if (!defined $_tags);
 339                 $_branches = 'branches' if (!defined $_branches);
 340         }
 341         if (defined $_trunk || defined $_branches || defined $_tags) {
 342                 return cmd_multi_init(@_);
 343         }
 344         my $url = shift or die "SVN repository location required ",
 345                                "as a command-line argument\n";
 346         init_subdir(@_);
 347         do_git_init_db();
 348
 349         Git::SVN->init($url);
 350 }
 351
 352 sub cmd_fetch {
 353         if (grep /^\d+=./, @_) {
 354                 die "'<rev>=<commit>' fetch arguments are ",
 355                     "no longer supported.\n";
 356         }
 357         my ($remote) = @_;
 358         if (@_ > 1) {
 359                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 360         }
 361         $remote ||= $Git::SVN::default_repo_id;
 362         if ($_fetch_all) {
 363                 cmd_multi_fetch();
 364         } else {
 365                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 366         }
 367 }
 368
 369 sub cmd_set_tree {
 370         my (@commits) = @_;
 371         if ($_stdin || !@commits) {
 372                 print "Reading from stdin...\n";
 373                 @commits = ();
 374                 while (<STDIN>) {
 375                         if (/\b($sha1_short)\b/o) {
 376                                 unshift @commits, $1;
 377                         }
 378                 }
 379         }
 380         my @revs;
 381         foreach my $c (@commits) {
 382                 my @tmp = command('rev-parse',$c);
 383                 if (scalar @tmp == 1) {
 384                         push @revs, $tmp[0];
 385                 } elsif (scalar @tmp > 1) {
 386                         push @revs, reverse(command('rev-list',@tmp));
 387                 } else {
 388                         fatal "Failed to rev-parse $c";
 389                 }
 390         }
 391         my $gs = Git::SVN->new;
 392         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 393         $gs->fetch;
 394         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 395                 fatal "There are new revisions that were fetched ",
 396                       "and need to be merged (or acknowledged) ",
 397                       "before committing.\nlast rev: $r_last\n",
 398                       " current: $gs->{last_rev}";
 399         }
 400         $gs->set_tree($_) foreach @revs;
 401         print "Done committing ",scalar @revs," revisions to SVN\n";
 402         unlink $gs->{index};
 403 }
 404
 405 sub cmd_dcommit {
 406         my $head = shift;
 407         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 408                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 409                 . "or stash them with `git stash'.\n";
 410         $head ||= 'HEAD';
 411         my @refs;
 412         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 413         print "Committing to $url ...\n";
 414         unless ($gs) {
 415                 die "Unable to determine upstream SVN information from ",
 416                     "$head history\n";
 417         }
 418         my $last_rev;
 419         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 420         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 421                 warn "Attempting to commit more than one change while ",
 422                      "--no-rebase is enabled.\n",
 423                      "If these changes depend on each other, re-running ",
 424                      "without --no-rebase may be required."
 425         }
 426         while (1) {
 427                 my $d = shift @$linear_refs or last;
 428                 unless (defined $last_rev) {
 429                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 430                         unless (defined $last_rev) {
 431                                 fatal "Unable to extract revision information ",
 432                                       "from commit $d~1";
 433                         }
 434                 }
 435                 if ($_dry_run) {
 436                         print "diff-tree $d~1 $d\n";
 437                 } else {
 438                         my $cmt_rev;
 439                         my %ed_opts = ( r => $last_rev,
 440                                         log => get_commit_entry($d)->{log},
 441                                         ra => Git::SVN::Ra->new($gs->full_url),
 442                                         config => SVN::Core::config_get_config(
 443                                                 $Git::SVN::Ra::config_dir
 444                                         ),
 445                                         tree_a => "$d~1",
 446                                         tree_b => $d,
 447                                         editor_cb => sub {
 448                                                print "Committed r$_[0]\n";
 449                                                $cmt_rev = $_[0];
 450                                         },
 451                                         svn_path => '');
 452                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 453                                 print "No changes\n$d~1 == $d\n";
 454                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 455                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 456                                                                $parents->{$d};
 457                         }
 458                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 459                         $last_rev = $cmt_rev;
 460                         next if $_no_rebase;
 461
 462                         # we always want to rebase against the current HEAD,
 463                         # not any head that was passed to us
 464                         my @diff = command('diff-tree', $d,
 465                                            $gs->refname, '--');
 466                         my @finish;
 467                         if (@diff) {
 468                                 @finish = rebase_cmd();
 469                                 print STDERR "W: $d and ", $gs->refname,
 470                                              " differ, using @finish:\n",
 471                                              join("\n", @diff), "\n";
 472                         } else {
 473                                 print "No changes between current HEAD and ",
 474                                       $gs->refname,
 475                                       "\nResetting to the latest ",
 476                                       $gs->refname, "\n";
 477                                 @finish = qw/reset --mixed/;
 478                         }
 479                         command_noisy(@finish, $gs->refname);
 480                         if (@diff) {
 481                                 @refs = ();
 482                                 my ($url_, $rev_, $uuid_, $gs_) =
 483                                               working_head_info($head, \@refs);
 484                                 my ($linear_refs_, $parents_) =
 485                                               linearize_history($gs_, \@refs);
 486                                 if (scalar(@$linear_refs) !=
 487                                     scalar(@$linear_refs_)) {
 488                                         fatal "# of revisions changed ",
 489                                           "\nbefore:\n",
 490                                           join("\n", @$linear_refs),
 491                                           "\n\nafter:\n",
 492                                           join("\n", @$linear_refs_), "\n",
 493                                           'If you are attempting to commit ',
 494                                           "merges, try running:\n\t",
 495                                           'git rebase --interactive',
 496                                           '--preserve-merges ',
 497                                           $gs->refname,
 498                                           "\nBefore dcommitting";
 499                                 }
 500                                 if ($url_ ne $url) {
 501                                         fatal "URL mismatch after rebase: ",
 502                                               "$url_ != $url";
 503                                 }
 504                                 if ($uuid_ ne $uuid) {
 505                                         fatal "uuid mismatch after rebase: ",
 506                                               "$uuid_ != $uuid";
 507                                 }
 508                                 # remap parents
 509                                 my (%p, @l, $i);
 510                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 511                                         my $new = $linear_refs_->[$i] or next;
 512                                         $p{$new} =
 513                                                 $parents->{$linear_refs->[$i]};
 514                                         push @l, $new;
 515                                 }
 516                                 $parents = \%p;
 517                                 $linear_refs = \@l;
 518                         }
 519                 }
 520         }
 521         unlink $gs->{index};
 522 }
 523
 524 sub cmd_find_rev {
 525         my $revision_or_hash = shift;
 526         my $result;
 527         if ($revision_or_hash =~ /^r\d+$/) {
 528                 my $head = shift;
 529                 $head ||= 'HEAD';
 530                 my @refs;
 531                 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
 532                 unless ($gs) {
 533                         die "Unable to determine upstream SVN information from ",
 534                             "$head history\n";
 535                 }
 536                 my $desired_revision = substr($revision_or_hash, 1);
 537                 $result = $gs->rev_map_get($desired_revision);
 538         } else {
 539                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 540                 $result = $rev;
 541         }
 542         print "$result\n" if $result;
 543 }
 544
 545 sub cmd_rebase {
 546         command_noisy(qw/update-index --refresh/);
 547         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 548         unless ($gs) {
 549                 die "Unable to determine upstream SVN information from ",
 550                     "working tree history\n";
 551         }
 552         if (command(qw/diff-index HEAD --/)) {
 553                 print STDERR "Cannot rebase with uncommited changes:\n";
 554                 command_noisy('status');
 555                 exit 1;
 556         }
 557         unless ($_local) {
 558                 # rebase will checkout for us, so no need to do it explicitly
 559                 $_no_checkout = 'true';
 560                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 561         }
 562         command_noisy(rebase_cmd(), $gs->refname);
 563 }
 564
 565 sub cmd_show_ignore {
 566         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 567         $gs ||= Git::SVN->new;
 568         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 569         $gs->prop_walk($gs->{path}, $r, sub {
 570                 my ($gs, $path, $props) = @_;
 571                 print STDOUT "\n# $path\n";
 572                 my $s = $props->{'svn:ignore'} or return;
 573                 $s =~ s/[\r\n]+/\n/g;
 574                 chomp $s;
 575                 $s =~ s#^#$path#gm;
 576                 print STDOUT "$s\n";
 577         });
 578 }
 579
 580 sub cmd_show_externals {
 581         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 582         $gs ||= Git::SVN->new;
 583         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 584         $gs->prop_walk($gs->{path}, $r, sub {
 585                 my ($gs, $path, $props) = @_;
 586                 print STDOUT "\n# $path\n";
 587                 my $s = $props->{'svn:externals'} or return;
 588                 $s =~ s/[\r\n]+/\n/g;
 589                 chomp $s;
 590                 $s =~ s#^#$path#gm;
 591                 print STDOUT "$s\n";
 592         });
 593 }
 594
 595 sub cmd_create_ignore {
 596         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 597         $gs ||= Git::SVN->new;
 598         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 599         $gs->prop_walk($gs->{path}, $r, sub {
 600                 my ($gs, $path, $props) = @_;
 601                 # $path is of the form /path/to/dir/
 602                 my $ignore = '.' . $path . '.gitignore';
 603                 my $s = $props->{'svn:ignore'} or return;
 604                 open(GITIGNORE, '>', $ignore)
 605                   or fatal("Failed to open `$ignore' for writing: $!");
 606                 $s =~ s/[\r\n]+/\n/g;
 607                 chomp $s;
 608                 # Prefix all patterns so that the ignore doesn't apply
 609                 # to sub-directories.
 610                 $s =~ s#^#/#gm;
 611                 print GITIGNORE "$s\n";
 612                 close(GITIGNORE)
 613                   or fatal("Failed to close `$ignore': $!");
 614                 command_noisy('add', $ignore);
 615         });
 616 }
 617
 618 sub canonicalize_path {
 619         my ($path) = @_;
 620         my $dot_slash_added = 0;
 621         if (substr($path, 0, 1) ne "/") {
 622                 $path = "./" . $path;
 623                 $dot_slash_added = 1;
 624         }
 625         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 626         # good reason), so let's do this manually.
 627         $path =~ s#/+#/#g;
 628         $path =~ s#/\.(?:/|$)#/#g;
 629         $path =~ s#/[^/]+/\.\.##g;
 630         $path =~ s#/$##g;
 631         $path =~ s#^\./## if $dot_slash_added;
 632         return $path;
 633 }
 634
 635 # get_svnprops(PATH)
 636 # ------------------
 637 # Helper for cmd_propget and cmd_proplist below.
 638 sub get_svnprops {
 639         my $path = shift;
 640         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 641         $gs ||= Git::SVN->new;
 642
 643         # prefix THE PATH by the sub-directory from which the user
 644         # invoked us.
 645         $path = $cmd_dir_prefix . $path;
 646         fatal("No such file or directory: $path") unless -e $path;
 647         my $is_dir = -d $path ? 1 : 0;
 648         $path = $gs->{path} . '/' . $path;
 649
 650         # canonicalize the path (otherwise libsvn will abort or fail to
 651         # find the file)
 652         $path = canonicalize_path($path);
 653
 654         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 655         my $props;
 656         if ($is_dir) {
 657                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 658         }
 659         else {
 660                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 661         }
 662         return $props;
 663 }
 664
 665 # cmd_propget (PROP, PATH)
 666 # ------------------------
 667 # Print the SVN property PROP for PATH.
 668 sub cmd_propget {
 669         my ($prop, $path) = @_;
 670         $path = '.' if not defined $path;
 671         usage(1) if not defined $prop;
 672         my $props = get_svnprops($path);
 673         if (not defined $props->{$prop}) {
 674                 fatal("`$path' does not have a `$prop' SVN property.");
 675         }
 676         print $props->{$prop} . "\n";
 677 }
 678
 679 # cmd_proplist (PATH)
 680 # -------------------
 681 # Print the list of SVN properties for PATH.
 682 sub cmd_proplist {
 683         my $path = shift;
 684         $path = '.' if not defined $path;
 685         my $props = get_svnprops($path);
 686         print "Properties on '$path':\n";
 687         foreach (sort keys %{$props}) {
 688                 print "  $_\n";
 689         }
 690 }
 691
 692 sub cmd_multi_init {
 693         my $url = shift;
 694         unless (defined $_trunk || defined $_branches || defined $_tags) {
 695                 usage(1);
 696         }
 697
 698         # there are currently some bugs that prevent multi-init/multi-fetch
 699         # setups from working well without this.
 700         $Git::SVN::_minimize_url = 1;
 701
 702         $_prefix = '' unless defined $_prefix;
 703         if (defined $url) {
 704                 $url =~ s#/+$##;
 705                 init_subdir(@_);
 706         }
 707         do_git_init_db();
 708         if (defined $_trunk) {
 709                 my $trunk_ref = $_prefix . 'trunk';
 710                 # try both old-style and new-style lookups:
 711                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 712                 unless ($gs_trunk) {
 713                         my ($trunk_url, $trunk_path) =
 714                                               complete_svn_url($url, $_trunk);
 715                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 716                                                    undef, $trunk_ref);
 717                 }
 718         }
 719         return unless defined $_branches || defined $_tags;
 720         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 721         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 722         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 723 }
 724
 725 sub cmd_multi_fetch {
 726         my $remotes = Git::SVN::read_all_remotes();
 727         foreach my $repo_id (sort keys %$remotes) {
 728                 if ($remotes->{$repo_id}->{url}) {
 729                         Git::SVN::fetch_all($repo_id, $remotes);
 730                 }
 731         }
 732 }
 733
 734 # this command is special because it requires no metadata
 735 sub cmd_commit_diff {
 736         my ($ta, $tb, $url) = @_;
 737         my $usage = "Usage: $0 commit-diff -r<revision> ".
 738                     "<tree-ish> <tree-ish> [<URL>]";
 739         fatal($usage) if (!defined $ta || !defined $tb);
 740         my $svn_path;
 741         if (!defined $url) {
 742                 my $gs = eval { Git::SVN->new };
 743                 if (!$gs) {
 744                         fatal("Needed URL or usable git-svn --id in ",
 745                               "the command-line\n", $usage);
 746                 }
 747                 $url = $gs->{url};
 748                 $svn_path = $gs->{path};
 749         }
 750         unless (defined $_revision) {
 751                 fatal("-r|--revision is a required argument\n", $usage);
 752         }
 753         if (defined $_message && defined $_file) {
 754                 fatal("Both --message/-m and --file/-F specified ",
 755                       "for the commit message.\n",
 756                       "I have no idea what you mean");
 757         }
 758         if (defined $_file) {
 759                 $_message = file_to_s($_file);
 760         } else {
 761                 $_message ||= get_commit_entry($tb)->{log};
 762         }
 763         my $ra ||= Git::SVN::Ra->new($url);
 764         $svn_path ||= $ra->{svn_path};
 765         my $r = $_revision;
 766         if ($r eq 'HEAD') {
 767                 $r = $ra->get_latest_revnum;
 768         } elsif ($r !~ /^\d+$/) {
 769                 die "revision argument: $r not understood by git-svn\n";
 770         }
 771         my %ed_opts = ( r => $r,
 772                         log => $_message,
 773                         ra => $ra,
 774                         tree_a => $ta,
 775                         tree_b => $tb,
 776                         editor_cb => sub { print "Committed r$_[0]\n" },
 777                         svn_path => $svn_path );
 778         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 779                 print "No changes\n$ta == $tb\n";
 780         }
 781 }
 782
 783 sub cmd_info {
 784         my $path = canonicalize_path(shift or ".");
 785         unless (scalar(@_) == 0) {
 786                 die "Too many arguments specified\n";
 787         }
 788
 789         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 790
 791         if (!$file_type && !$diff_status) {
 792                 print STDERR "$path:  (Not a versioned resource)\n\n";
 793                 return;
 794         }
 795
 796         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 797         unless ($gs) {
 798                 die "Unable to determine upstream SVN information from ",
 799                     "working tree history\n";
 800         }
 801         my $full_url = $url . ($path eq "." ? "" : "/$path");
 802
 803         if ($_url) {
 804                 print $full_url, "\n";
 805                 return;
 806         }
 807
 808         my $result = "Path: $path\n";
 809         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 810         $result .= "URL: " . $full_url . "\n";
 811
 812         eval {
 813                 my $repos_root = $gs->repos_root;
 814                 Git::SVN::remove_username($repos_root);
 815                 $result .= "Repository Root: $repos_root\n";
 816         };
 817         if ($@) {
 818                 $result .= "Repository Root: (offline)\n";
 819         }
 820         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
 821         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 822
 823         $result .= "Node Kind: " .
 824                    ($file_type eq "dir" ? "directory" : "file") . "\n";
 825
 826         my $schedule = $diff_status eq "A"
 827                        ? "add"
 828                        : ($diff_status eq "D" ? "delete" : "normal");
 829         $result .= "Schedule: $schedule\n";
 830
 831         if ($diff_status eq "A") {
 832                 print $result, "\n";
 833                 return;
 834         }
 835
 836         my ($lc_author, $lc_rev, $lc_date_utc);
 837         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
 838         my $log = command_output_pipe(@args);
 839         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 840         while (<$log>) {
 841                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 842                         $lc_author = $1;
 843                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 844                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 845                         (undef, $lc_rev, undef) = ::extract_metadata($1);
 846                 }
 847         }
 848         close $log;
 849
 850         Git::SVN::Log::set_local_timezone();
 851
 852         $result .= "Last Changed Author: $lc_author\n";
 853         $result .= "Last Changed Rev: $lc_rev\n";
 854         $result .= "Last Changed Date: " .
 855                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 856
 857         if ($file_type ne "dir") {
 858                 my $text_last_updated_date =
 859                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 860                 $result .=
 861                     "Text Last Updated: " .
 862                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
 863                     "\n";
 864                 my $checksum;
 865                 if ($diff_status eq "D") {
 866                         my ($fh, $ctx) =
 867                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
 868                         if ($file_type eq "link") {
 869                                 my $file_name = <$fh>;
 870                                 $checksum = md5sum("link $file_name");
 871                         } else {
 872                                 $checksum = md5sum($fh);
 873                         }
 874                         command_close_pipe($fh, $ctx);
 875                 } elsif ($file_type eq "link") {
 876                         my $file_name =
 877                             command(qw(cat-file blob), "HEAD:$path");
 878                         $checksum =
 879                             md5sum("link " . $file_name);
 880                 } else {
 881                         open FILE, "<", $path or die $!;
 882                         $checksum = md5sum(\*FILE);
 883                         close FILE or die $!;
 884                 }
 885                 $result .= "Checksum: " . $checksum . "\n";
 886         }
 887
 888         print $result, "\n";
 889 }
 890
 891 ########################### utility functions #########################
 892
 893 sub rebase_cmd {
 894         my @cmd = qw/rebase/;
 895         push @cmd, '-v' if $_verbose;
 896         push @cmd, qw/--merge/ if $_merge;
 897         push @cmd, "--strategy=$_strategy" if $_strategy;
 898         @cmd;
 899 }
 900
 901 sub post_fetch_checkout {
 902         return if $_no_checkout;
 903         my $gs = $Git::SVN::_head or return;
 904         return if verify_ref('refs/heads/master^0');
 905
 906         my $valid_head = verify_ref('HEAD^0');
 907         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 908         return if ($valid_head || !verify_ref('HEAD^0'));
 909
 910         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 911         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 912         return if -f $index;
 913
 914         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
 915         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 916         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 917         print STDERR "Checked out HEAD:\n  ",
 918                      $gs->full_url, " r", $gs->last_rev, "\n";
 919 }
 920
 921 sub complete_svn_url {
 922         my ($url, $path) = @_;
 923         $path =~ s#/+$##;
 924         if ($path !~ m#^[a-z\+]+://#) {
 925                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 926                         fatal("E: '$path' is not a complete URL ",
 927                               "and a separate URL is not specified");
 928                 }
 929                 return ($url, $path);
 930         }
 931         return ($path, '');
 932 }
 933
 934 sub complete_url_ls_init {
 935         my ($ra, $repo_path, $switch, $pfx) = @_;
 936         unless ($repo_path) {
 937                 print STDERR "W: $switch not specified\n";
 938                 return;
 939         }
 940         $repo_path =~ s#/+$##;
 941         if ($repo_path =~ m#^[a-z\+]+://#) {
 942                 $ra = Git::SVN::Ra->new($repo_path);
 943                 $repo_path = '';
 944         } else {
 945                 $repo_path =~ s#^/+##;
 946                 unless ($ra) {
 947                         fatal("E: '$repo_path' is not a complete URL ",
 948                               "and a separate URL is not specified");
 949                 }
 950         }
 951         my $url = $ra->{url};
 952         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 953         my $k = "svn-remote.$gs->{repo_id}.url";
 954         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 955         if ($orig_url && ($orig_url ne $gs->{url})) {
 956                 die "$k already set: $orig_url\n",
 957                     "wanted to set to: $gs->{url}\n";
 958         }
 959         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 960         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 961         $remote_path =~ s#/+#/#g;
 962         $remote_path =~ s#^/##g;
 963         my ($n) = ($switch =~ /^--(\w+)/);
 964         if (length $pfx && $pfx !~ m#/$#) {
 965                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 966         }
 967         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 968                                 "$remote_path:refs/remotes/$pfx*");
 969 }
 970
 971 sub verify_ref {
 972         my ($ref) = @_;
 973         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 974                                { STDERR => 0 }); };
 975 }
 976
 977 sub get_tree_from_treeish {
 978         my ($treeish) = @_;
 979         # $treeish can be a symbolic ref, too:
 980         my $type = command_oneline(qw/cat-file -t/, $treeish);
 981         my $expected;
 982         while ($type eq 'tag') {
 983                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 984         }
 985         if ($type eq 'commit') {
 986                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 987                                                     $treeish))[0];
 988                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 989                 die "Unable to get tree from $treeish\n" unless $expected;
 990         } elsif ($type eq 'tree') {
 991                 $expected = $treeish;
 992         } else {
 993                 die "$treeish is a $type, expected tree, tag or commit\n";
 994         }
 995         return $expected;
 996 }
 997
 998 sub get_commit_entry {
 999         my ($treeish) = shift;
1000         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1001         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1002         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1003         open my $log_fh, '>', $commit_editmsg or croak $!;
1004
1005         my $type = command_oneline(qw/cat-file -t/, $treeish);
1006         if ($type eq 'commit' || $type eq 'tag') {
1007                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1008                                                          $type, $treeish);
1009                 my $in_msg = 0;
1010                 while (<$msg_fh>) {
1011                         if (!$in_msg) {
1012                                 $in_msg = 1 if (/^\s*$/);
1013                         } elsif (/^git-svn-id: /) {
1014                                 # skip this for now, we regenerate the
1015                                 # correct one on re-fetch anyways
1016                                 # TODO: set *:merge properties or like...
1017                         } else {
1018                                 print $log_fh $_ or croak $!;
1019                         }
1020                 }
1021                 command_close_pipe($msg_fh, $ctx);
1022         }
1023         close $log_fh or croak $!;
1024
1025         if ($_edit || ($type eq 'tree')) {
1026                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1027                 # TODO: strip out spaces, comments, like git-commit.sh
1028                 system($editor, $commit_editmsg);
1029         }
1030         rename $commit_editmsg, $commit_msg or croak $!;
1031         open $log_fh, '<', $commit_msg or croak $!;
1032         { local $/; chomp($log_entry{log} = <$log_fh>); }
1033         close $log_fh or croak $!;
1034         unlink $commit_msg;
1035         \%log_entry;
1036 }
1037
1038 sub s_to_file {
1039         my ($str, $file, $mode) = @_;
1040         open my $fd,'>',$file or croak $!;
1041         print $fd $str,"\n" or croak $!;
1042         close $fd or croak $!;
1043         chmod ($mode &~ umask, $file) if (defined $mode);
1044 }
1045
1046 sub file_to_s {
1047         my $file = shift;
1048         open my $fd,'<',$file or croak "$!: file: $file\n";
1049         local $/;
1050         my $ret = <$fd>;
1051         close $fd or croak $!;
1052         $ret =~ s/\s*$//s;
1053         return $ret;
1054 }
1055
1056 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1057 sub load_authors {
1058         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1059         my $log = $cmd eq 'log';
1060         while (<$authors>) {
1061                 chomp;
1062                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1063                 my ($user, $name, $email) = ($1, $2, $3);
1064                 if ($log) {
1065                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1066                 } else {
1067                         $users{$user} = [$name, $email];
1068                 }
1069         }
1070         close $authors or croak $!;
1071 }
1072
1073 # convert GetOpt::Long specs for use by git-config
1074 sub read_repo_config {
1075         return unless -d $ENV{GIT_DIR};
1076         my $opts = shift;
1077         my @config_only;
1078         foreach my $o (keys %$opts) {
1079                 # if we have mixedCase and a long option-only, then
1080                 # it's a config-only variable that we don't need for
1081                 # the command-line.
1082                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1083                 my $v = $opts->{$o};
1084                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1085                 $key =~ s/-//g;
1086                 my $arg = 'git-config';
1087                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1088                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1089                 if (ref $v eq 'ARRAY') {
1090                         chomp(my @tmp = `$arg --get-all svn.$key`);
1091                         @$v = @tmp if @tmp;
1092                 } else {
1093                         chomp(my $tmp = `$arg --get svn.$key`);
1094                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1095                                 $$v = $tmp;
1096                         }
1097                 }
1098         }
1099         delete @$opts{@config_only} if @config_only;
1100 }
1101
1102 sub extract_metadata {
1103         my $id = shift or return (undef, undef, undef);
1104         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1105                                                         \s([a-f\d\-]+)$/x);
1106         if (!defined $rev || !$uuid || !$url) {
1107                 # some of the original repositories I made had
1108                 # identifiers like this:
1109                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1110         }
1111         return ($url, $rev, $uuid);
1112 }
1113
1114 sub cmt_metadata {
1115         return extract_metadata((grep(/^git-svn-id: /,
1116                 command(qw/cat-file commit/, shift)))[-1]);
1117 }
1118
1119 sub working_head_info {
1120         my ($head, $refs) = @_;
1121         my @args = ('log', '--no-color', '--first-parent');
1122         my ($fh, $ctx) = command_output_pipe(@args, $head);
1123         my $hash;
1124         my %max;
1125         while (<$fh>) {
1126                 if ( m{^commit ($::sha1)$} ) {
1127                         unshift @$refs, $hash if $hash and $refs;
1128                         $hash = $1;
1129                         next;
1130                 }
1131                 next unless s{^\s*(git-svn-id:)}{$1};
1132                 my ($url, $rev, $uuid) = extract_metadata($_);
1133                 if (defined $url && defined $rev) {
1134                         next if $max{$url} and $max{$url} < $rev;
1135                         if (my $gs = Git::SVN->find_by_url($url)) {
1136                                 my $c = $gs->rev_map_get($rev);
1137                                 if ($c && $c eq $hash) {
1138                                         close $fh; # break the pipe
1139                                         return ($url, $rev, $uuid, $gs);
1140                                 } else {
1141                                         $max{$url} ||= $gs->rev_map_max;
1142                                 }
1143                         }
1144                 }
1145         }
1146         command_close_pipe($fh, $ctx);
1147         (undef, undef, undef, undef);
1148 }
1149
1150 sub read_commit_parents {
1151         my ($parents, $c) = @_;
1152         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1153         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1154         @{$parents->{$c}} = split(/ /, $p);
1155 }
1156
1157 sub linearize_history {
1158         my ($gs, $refs) = @_;
1159         my %parents;
1160         foreach my $c (@$refs) {
1161                 read_commit_parents(\%parents, $c);
1162         }
1163
1164         my @linear_refs;
1165         my %skip = ();
1166         my $last_svn_commit = $gs->last_commit;
1167         foreach my $c (reverse @$refs) {
1168                 next if $c eq $last_svn_commit;
1169                 last if $skip{$c};
1170
1171                 unshift @linear_refs, $c;
1172                 $skip{$c} = 1;
1173
1174                 # we only want the first parent to diff against for linear
1175                 # history, we save the rest to inject when we finalize the
1176                 # svn commit
1177                 my $fp_a = verify_ref("$c~1");
1178                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1179                 if (!$fp_a || !$fp_b) {
1180                         die "Commit $c\n",
1181                             "has no parent commit, and therefore ",
1182                             "nothing to diff against.\n",
1183                             "You should be working from a repository ",
1184                             "originally created by git-svn\n";
1185                 }
1186                 if ($fp_a ne $fp_b) {
1187                         die "$c~1 = $fp_a, however parsing commit $c ",
1188                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1189                 }
1190
1191                 foreach my $p (@{$parents{$c}}) {
1192                         $skip{$p} = 1;
1193                 }
1194         }
1195         (\@linear_refs, \%parents);
1196 }
1197
1198 sub find_file_type_and_diff_status {
1199         my ($path) = @_;
1200         return ('dir', '') if $path eq '.';
1201
1202         my $diff_output =
1203             command_oneline(qw(diff --cached --name-status --), $path) || "";
1204         my $diff_status = (split(' ', $diff_output))[0] || "";
1205
1206         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1207
1208         return (undef, undef) if !$diff_status && !$ls_tree;
1209
1210         if ($diff_status eq "A") {
1211                 return ("link", $diff_status) if -l $path;
1212                 return ("dir", $diff_status) if -d $path;
1213                 return ("file", $diff_status);
1214         }
1215
1216         my $mode = (split(' ', $ls_tree))[0] || "";
1217
1218         return ("link", $diff_status) if $mode eq "120000";
1219         return ("dir", $diff_status) if $mode eq "040000";
1220         return ("file", $diff_status);
1221 }
1222
1223 sub md5sum {
1224         my $arg = shift;
1225         my $ref = ref $arg;
1226         my $md5 = Digest::MD5->new();
1227         if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1228                 $md5->addfile($arg) or croak $!;
1229         } elsif ($ref eq 'SCALAR') {
1230                 $md5->add($$arg) or croak $!;
1231         } elsif (!$ref) {
1232                 $md5->add($arg) or croak $!;
1233         } else {
1234                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1235         }
1236         return $md5->hexdigest();
1237 }
1238
1239 package Git::SVN;
1240 use strict;
1241 use warnings;
1242 use Fcntl qw/:DEFAULT :seek/;
1243 use constant rev_map_fmt => 'NH40';
1244 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1245             $_repack $_repack_flags $_use_svm_props $_head
1246             $_use_svnsync_props $no_reuse_existing $_minimize_url
1247             $_use_log_author/;
1248 use Carp qw/croak/;
1249 use File::Path qw/mkpath/;
1250 use File::Copy qw/copy/;
1251 use IPC::Open3;
1252
1253 my ($_gc_nr, $_gc_period);
1254
1255 # properties that we do not log:
1256 my %SKIP_PROP;
1257 BEGIN {
1258         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1259                                         svn:special svn:executable
1260                                         svn:entry:committed-rev
1261                                         svn:entry:last-author
1262                                         svn:entry:uuid
1263                                         svn:entry:committed-date/;
1264
1265         # some options are read globally, but can be overridden locally
1266         # per [svn-remote "..."] section.  Command-line options will *NOT*
1267         # override options set in an [svn-remote "..."] section
1268         no strict 'refs';
1269         for my $option (qw/follow_parent no_metadata use_svm_props
1270                            use_svnsync_props/) {
1271                 my $key = $option;
1272                 $key =~ tr/_//d;
1273                 my $prop = "-$option";
1274                 *$option = sub {
1275                         my ($self) = @_;
1276                         return $self->{$prop} if exists $self->{$prop};
1277                         my $k = "svn-remote.$self->{repo_id}.$key";
1278                         eval { command_oneline(qw/config --get/, $k) };
1279                         if ($@) {
1280                                 $self->{$prop} = ${"Git::SVN::_$option"};
1281                         } else {
1282                                 my $v = command_oneline(qw/config --bool/,$k);
1283                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1284                         }
1285                         return $self->{$prop};
1286                 }
1287         }
1288 }
1289
1290 my (%LOCKFILES, %INDEX_FILES);
1291 END {
1292         unlink keys %LOCKFILES if %LOCKFILES;
1293         unlink keys %INDEX_FILES if %INDEX_FILES;
1294 }
1295
1296 sub resolve_local_globs {
1297         my ($url, $fetch, $glob_spec) = @_;
1298         return unless defined $glob_spec;
1299         my $ref = $glob_spec->{ref};
1300         my $path = $glob_spec->{path};
1301         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1302                 next unless m#^refs/remotes/$ref->{regex}$#;
1303                 my $p = $1;
1304                 my $pathname = desanitize_refname($path->full_path($p));
1305                 my $refname = desanitize_refname($ref->full_path($p));
1306                 if (my $existing = $fetch->{$pathname}) {
1307                         if ($existing ne $refname) {
1308                                 die "Refspec conflict:\n",
1309                                     "existing: refs/remotes/$existing\n",
1310                                     " globbed: refs/remotes/$refname\n";
1311                         }
1312                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1313                         $u =~ s!^\Q$url\E(/|$)!! or die
1314                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1315                         if ($pathname ne $u) {
1316                                 warn "W: Refspec glob conflict ",
1317                                      "(ref: refs/remotes/$refname):\n",
1318                                      "expected path: $pathname\n",
1319                                      "    real path: $u\n",
1320                                      "Continuing ahead with $u\n";
1321                                 next;
1322                         }
1323                 } else {
1324                         $fetch->{$pathname} = $refname;
1325                 }
1326         }
1327 }
1328
1329 sub parse_revision_argument {
1330         my ($base, $head) = @_;
1331         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1332                 return ($base, $head);
1333         }
1334         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1335         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1336         return ($head, $head) if ($::_revision eq 'HEAD');
1337         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1338         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1339         die "revision argument: $::_revision not understood by git-svn\n";
1340 }
1341
1342 sub fetch_all {
1343         my ($repo_id, $remotes) = @_;
1344         if (ref $repo_id) {
1345                 my $gs = $repo_id;
1346                 $repo_id = undef;
1347                 $repo_id = $gs->{repo_id};
1348         }
1349         $remotes ||= read_all_remotes();
1350         my $remote = $remotes->{$repo_id} or
1351                      die "[svn-remote \"$repo_id\"] unknown\n";
1352         my $fetch = $remote->{fetch};
1353         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1354         my (@gs, @globs);
1355         my $ra = Git::SVN::Ra->new($url);
1356         my $uuid = $ra->get_uuid;
1357         my $head = $ra->get_latest_revnum;
1358         my $base = defined $fetch ? $head : 0;
1359
1360         # read the max revs for wildcard expansion (branches/*, tags/*)
1361         foreach my $t (qw/branches tags/) {
1362                 defined $remote->{$t} or next;
1363                 push @globs, $remote->{$t};
1364                 my $max_rev = eval { tmp_config(qw/--int --get/,
1365                                          "svn-remote.$repo_id.${t}-maxRev") };
1366                 if (defined $max_rev && ($max_rev < $base)) {
1367                         $base = $max_rev;
1368                 } elsif (!defined $max_rev) {
1369                         $base = 0;
1370                 }
1371         }
1372
1373         if ($fetch) {
1374                 foreach my $p (sort keys %$fetch) {
1375                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1376                         my $lr = $gs->rev_map_max;
1377                         if (defined $lr) {
1378                                 $base = $lr if ($lr < $base);
1379                         }
1380                         push @gs, $gs;
1381                 }
1382         }
1383
1384         ($base, $head) = parse_revision_argument($base, $head);
1385         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1386 }
1387
1388 sub read_all_remotes {
1389         my $r = {};
1390         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1391                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1392                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1393                         $local_ref =~ s{^/}{};
1394                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1395                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1396                         $r->{$1}->{url} = $2;
1397                 } elsif (m!^(.+)\.(branches|tags)=
1398                            (.*):refs/remotes/(.+)\s*$/!x) {
1399                         my ($p, $g) = ($3, $4);
1400                         my $rs = $r->{$1}->{$2} = {
1401                                           t => $2,
1402                                           remote => $1,
1403                                           path => Git::SVN::GlobSpec->new($p),
1404                                           ref => Git::SVN::GlobSpec->new($g) };
1405                         if (length($rs->{ref}->{right}) != 0) {
1406                                 die "The '*' glob character must be the last ",
1407                                     "character of '$g'\n";
1408                         }
1409                 }
1410         }
1411         $r;
1412 }
1413
1414 sub init_vars {
1415         $_gc_nr = $_gc_period = 1000;
1416         if (defined $_repack || defined $_repack_flags) {
1417                warn "Repack options are obsolete; they have no effect.\n";
1418         }
1419 }
1420
1421 sub verify_remotes_sanity {
1422         return unless -d $ENV{GIT_DIR};
1423         my %seen;
1424         foreach (command(qw/config -l/)) {
1425                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1426                         if ($seen{$1}) {
1427                                 die "Remote ref refs/remote/$1 is tracked by",
1428                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1429                                     "Please resolve this ambiguity in ",
1430                                     "your git configuration file before ",
1431                                     "continuing\n";
1432                         }
1433                         $seen{$1} = $_;
1434                 }
1435         }
1436 }
1437
1438 # we allow more chars than remotes2config.sh...
1439 sub sanitize_remote_name {
1440         my ($name) = @_;
1441         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1442         $name;
1443 }
1444
1445 sub find_existing_remote {
1446         my ($url, $remotes) = @_;
1447         return undef if $no_reuse_existing;
1448         my $existing;
1449         foreach my $repo_id (keys %$remotes) {
1450                 my $u = $remotes->{$repo_id}->{url} or next;
1451                 next if $u ne $url;
1452                 $existing = $repo_id;
1453                 last;
1454         }
1455         $existing;
1456 }
1457
1458 sub init_remote_config {
1459         my ($self, $url, $no_write) = @_;
1460         $url =~ s!/+$!!; # strip trailing slash
1461         my $r = read_all_remotes();
1462         my $existing = find_existing_remote($url, $r);
1463         if ($existing) {
1464                 unless ($no_write) {
1465                         print STDERR "Using existing ",
1466                                      "[svn-remote \"$existing\"]\n";
1467                 }
1468                 $self->{repo_id} = $existing;
1469         } elsif ($_minimize_url) {
1470                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1471                 $existing = find_existing_remote($min_url, $r);
1472                 if ($existing) {
1473                         unless ($no_write) {
1474                                 print STDERR "Using existing ",
1475                                              "[svn-remote \"$existing\"]\n";
1476                         }
1477                         $self->{repo_id} = $existing;
1478                 }
1479                 if ($min_url ne $url) {
1480                         unless ($no_write) {
1481                                 print STDERR "Using higher level of URL: ",
1482                                              "$url => $min_url\n";
1483                         }
1484                         my $old_path = $self->{path};
1485                         $self->{path} = $url;
1486                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1487                         if (length $old_path) {
1488                                 $self->{path} .= "/$old_path";
1489                         }
1490                         $url = $min_url;
1491                 }
1492         }
1493         my $orig_url;
1494         if (!$existing) {
1495                 # verify that we aren't overwriting anything:
1496                 $orig_url = eval {
1497                         command_oneline('config', '--get',
1498                                         "svn-remote.$self->{repo_id}.url")
1499                 };
1500                 if ($orig_url && ($orig_url ne $url)) {
1501                         die "svn-remote.$self->{repo_id}.url already set: ",
1502                             "$orig_url\nwanted to set to: $url\n";
1503                 }
1504         }
1505         my ($xrepo_id, $xpath) = find_ref($self->refname);
1506         if (defined $xpath) {
1507                 die "svn-remote.$xrepo_id.fetch already set to track ",
1508                     "$xpath:refs/remotes/", $self->refname, "\n";
1509         }
1510         unless ($no_write) {
1511                 command_noisy('config',
1512                               "svn-remote.$self->{repo_id}.url", $url);
1513                 $self->{path} =~ s{^/}{};
1514                 command_noisy('config', '--add',
1515                               "svn-remote.$self->{repo_id}.fetch",
1516                               "$self->{path}:".$self->refname);
1517         }
1518         $self->{url} = $url;
1519 }
1520
1521 sub find_by_url { # repos_root and, path are optional
1522         my ($class, $full_url, $repos_root, $path) = @_;
1523
1524         return undef unless defined $full_url;
1525         remove_username($full_url);
1526         remove_username($repos_root) if defined $repos_root;
1527         my $remotes = read_all_remotes();
1528         if (defined $full_url && defined $repos_root && !defined $path) {
1529                 $path = $full_url;
1530                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1531         }
1532         foreach my $repo_id (keys %$remotes) {
1533                 my $u = $remotes->{$repo_id}->{url} or next;
1534                 remove_username($u);
1535                 next if defined $repos_root && $repos_root ne $u;
1536
1537                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1538                 foreach (qw/branches tags/) {
1539                         resolve_local_globs($u, $fetch,
1540                                             $remotes->{$repo_id}->{$_});
1541                 }
1542                 my $p = $path;
1543                 unless (defined $p) {
1544                         $p = $full_url;
1545                         $p =~ s#^\Q$u\E(?:/|$)## or next;
1546                 }
1547                 foreach my $f (keys %$fetch) {
1548                         next if $f ne $p;
1549                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1550                 }
1551         }
1552         undef;
1553 }
1554
1555 sub init {
1556         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1557         my $self = _new($class, $repo_id, $ref_id, $path);
1558         if (defined $url) {
1559                 $self->init_remote_config($url, $no_write);
1560         }
1561         $self;
1562 }
1563
1564 sub find_ref {
1565         my ($ref_id) = @_;
1566         foreach (command(qw/config -l/)) {
1567                 next unless m!^svn-remote\.(.+)\.fetch=
1568                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1569                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1570                 if ($ref eq $ref_id) {
1571                         $path = '' if ($path =~ m#^\./?#);
1572                         return ($repo_id, $path);
1573                 }
1574         }
1575         (undef, undef, undef);
1576 }
1577
1578 sub new {
1579         my ($class, $ref_id, $repo_id, $path) = @_;
1580         if (defined $ref_id && !defined $repo_id && !defined $path) {
1581                 ($repo_id, $path) = find_ref($ref_id);
1582                 if (!defined $repo_id) {
1583                         die "Could not find a \"svn-remote.*.fetch\" key ",
1584                             "in the repository configuration matching: ",
1585                             "refs/remotes/$ref_id\n";
1586                 }
1587         }
1588         my $self = _new($class, $repo_id, $ref_id, $path);
1589         if (!defined $self->{path} || !length $self->{path}) {
1590                 my $fetch = command_oneline('config', '--get',
1591                                             "svn-remote.$repo_id.fetch",
1592                                             ":refs/remotes/$ref_id\$") or
1593                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1594                          "\":refs/remotes/$ref_id\$\" in config\n";
1595                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1596         }
1597         $self->{url} = command_oneline('config', '--get',
1598                                        "svn-remote.$repo_id.url") or
1599                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1600         $self->rebuild;
1601         $self;
1602 }
1603
1604 sub refname {
1605         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1606
1607         # It cannot end with a slash /, we'll throw up on this because
1608         # SVN can't have directories with a slash in their name, either:
1609         if ($refname =~ m{/$}) {
1610                 die "ref: '$refname' ends with a trailing slash, this is ",
1611                     "not permitted by git nor Subversion\n";
1612         }
1613
1614         # It cannot have ASCII control character space, tilde ~, caret ^,
1615         # colon :, question-mark ?, asterisk *, space, or open bracket [
1616         # anywhere.
1617         #
1618         # Additionally, % must be escaped because it is used for escaping
1619         # and we want our escaped refname to be reversible
1620         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1621
1622         # no slash-separated component can begin with a dot .
1623         # /.* becomes /%2E*
1624         $refname =~ s{/\.}{/%2E}g;
1625
1626         # It cannot have two consecutive dots .. anywhere
1627         # .. becomes %2E%2E
1628         $refname =~ s{\.\.}{%2E%2E}g;
1629
1630         return $refname;
1631 }
1632
1633 sub desanitize_refname {
1634         my ($refname) = @_;
1635         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1636         return $refname;
1637 }
1638
1639 sub svm_uuid {
1640         my ($self) = @_;
1641         return $self->{svm}->{uuid} if $self->svm;
1642         $self->ra;
1643         unless ($self->{svm}) {
1644                 die "SVM UUID not cached, and reading remotely failed\n";
1645         }
1646         $self->{svm}->{uuid};
1647 }
1648
1649 sub svm {
1650         my ($self) = @_;
1651         return $self->{svm} if $self->{svm};
1652         my $svm;
1653         # see if we have it in our config, first:
1654         eval {
1655                 my $section = "svn-remote.$self->{repo_id}";
1656                 $svm = {
1657                   source => tmp_config('--get', "$section.svm-source"),
1658                   uuid => tmp_config('--get', "$section.svm-uuid"),
1659                   replace => tmp_config('--get', "$section.svm-replace"),
1660                 }
1661         };
1662         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1663                 $self->{svm} = $svm;
1664         }
1665         $self->{svm};
1666 }
1667
1668 sub _set_svm_vars {
1669         my ($self, $ra) = @_;
1670         return $ra if $self->svm;
1671
1672         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1673                     "(svm:source, svm:uuid) ",
1674                     "from the following URLs:\n" );
1675         sub read_svm_props {
1676                 my ($self, $ra, $path, $r) = @_;
1677                 my $props = ($ra->get_dir($path, $r))[2];
1678                 my $src = $props->{'svm:source'};
1679                 my $uuid = $props->{'svm:uuid'};
1680                 return undef if (!$src || !$uuid);
1681
1682                 chomp($src, $uuid);
1683
1684                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1685                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1686
1687                 # the '!' is used to mark the repos_root!/relative/path
1688                 $src =~ s{/?!/?}{/};
1689                 $src =~ s{/+$}{}; # no trailing slashes please
1690                 # username is of no interest
1691                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1692
1693                 my $replace = $ra->{url};
1694                 $replace .= "/$path" if length $path;
1695
1696                 my $section = "svn-remote.$self->{repo_id}";
1697                 tmp_config("$section.svm-source", $src);
1698                 tmp_config("$section.svm-replace", $replace);
1699                 tmp_config("$section.svm-uuid", $uuid);
1700                 $self->{svm} = {
1701                         source => $src,
1702                         uuid => $uuid,
1703                         replace => $replace
1704                 };
1705         }
1706
1707         my $r = $ra->get_latest_revnum;
1708         my $path = $self->{path};
1709         my %tried;
1710         while (length $path) {
1711                 unless ($tried{"$self->{url}/$path"}) {
1712                         return $ra if $self->read_svm_props($ra, $path, $r);
1713                         $tried{"$self->{url}/$path"} = 1;
1714                 }
1715                 $path =~ s#/?[^/]+$##;
1716         }
1717         die "Path: '$path' should be ''\n" if $path ne '';
1718         return $ra if $self->read_svm_props($ra, $path, $r);
1719         $tried{"$self->{url}/$path"} = 1;
1720
1721         if ($ra->{repos_root} eq $self->{url}) {
1722                 die @err, (map { "  $_\n" } keys %tried), "\n";
1723         }
1724
1725         # nope, make sure we're connected to the repository root:
1726         my $ok;
1727         my @tried_b;
1728         $path = $ra->{svn_path};
1729         $ra = Git::SVN::Ra->new($ra->{repos_root});
1730         while (length $path) {
1731                 unless ($tried{"$ra->{url}/$path"}) {
1732                         $ok = $self->read_svm_props($ra, $path, $r);
1733                         last if $ok;
1734                         $tried{"$ra->{url}/$path"} = 1;
1735                 }
1736                 $path =~ s#/?[^/]+$##;
1737         }
1738         die "Path: '$path' should be ''\n" if $path ne '';
1739         $ok ||= $self->read_svm_props($ra, $path, $r);
1740         $tried{"$ra->{url}/$path"} = 1;
1741         if (!$ok) {
1742                 die @err, (map { "  $_\n" } keys %tried), "\n";
1743         }
1744         Git::SVN::Ra->new($self->{url});
1745 }
1746
1747 sub svnsync {
1748         my ($self) = @_;
1749         return $self->{svnsync} if $self->{svnsync};
1750
1751         if ($self->no_metadata) {
1752                 die "Can't have both 'noMetadata' and ",
1753                     "'useSvnsyncProps' options set!\n";
1754         }
1755         if ($self->rewrite_root) {
1756                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1757                     "options set!\n";
1758         }
1759
1760         my $svnsync;
1761         # see if we have it in our config, first:
1762         eval {
1763                 my $section = "svn-remote.$self->{repo_id}";
1764
1765                 my $url = tmp_config('--get', "$section.svnsync-url");
1766                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1767                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1768
1769                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1770                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1771                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1772
1773                 $svnsync = { url => $url, uuid => $uuid }
1774         };
1775         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1776                 return $self->{svnsync} = $svnsync;
1777         }
1778
1779         my $err = "useSvnsyncProps set, but failed to read " .
1780                   "svnsync property: svn:sync-from-";
1781         my $rp = $self->ra->rev_proplist(0);
1782
1783         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1784         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1785                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1786
1787         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1788         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1789                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1790
1791         my $section = "svn-remote.$self->{repo_id}";
1792         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1793         tmp_config('--add', "$section.svnsync-url", $url);
1794         return $self->{svnsync} = { url => $url, uuid => $uuid };
1795 }
1796
1797 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1798 # remote lookup (useful for 'git svn log').
1799 sub ra_uuid {
1800         my ($self) = @_;
1801         unless ($self->{ra_uuid}) {
1802                 my $key = "svn-remote.$self->{repo_id}.uuid";
1803                 my $uuid = eval { tmp_config('--get', $key) };
1804                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1805                         $self->{ra_uuid} = $uuid;
1806                 } else {
1807                         die "ra_uuid called without URL\n" unless $self->{url};
1808                         $self->{ra_uuid} = $self->ra->get_uuid;
1809                         tmp_config('--add', $key, $self->{ra_uuid});
1810                 }
1811         }
1812         $self->{ra_uuid};
1813 }
1814
1815 sub _set_repos_root {
1816         my ($self, $repos_root) = @_;
1817         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1818         $repos_root ||= $self->ra->{repos_root};
1819         tmp_config($k, $repos_root);
1820         $repos_root;
1821 }
1822
1823 sub repos_root {
1824         my ($self) = @_;
1825         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1826         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1827 }
1828
1829 sub ra {
1830         my ($self) = shift;
1831         my $ra = Git::SVN::Ra->new($self->{url});
1832         $self->_set_repos_root($ra->{repos_root});
1833         if ($self->use_svm_props && !$self->{svm}) {
1834                 if ($self->no_metadata) {
1835                         die "Can't have both 'noMetadata' and ",
1836                             "'useSvmProps' options set!\n";
1837                 } elsif ($self->use_svnsync_props) {
1838                         die "Can't have both 'useSvnsyncProps' and ",
1839                             "'useSvmProps' options set!\n";
1840                 }
1841                 $ra = $self->_set_svm_vars($ra);
1842                 $self->{-want_revprops} = 1;
1843         }
1844         $ra;
1845 }
1846
1847 sub rel_path {
1848         my ($self) = @_;
1849         my $repos_root = $self->ra->{repos_root};
1850         return $self->{path} if ($self->{url} eq $repos_root);
1851         my $url = $self->{url} .
1852                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1853         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1854         $url;
1855 }
1856
1857 # prop_walk(PATH, REV, SUB)
1858 # -------------------------
1859 # Recursively traverse PATH at revision REV and invoke SUB for each
1860 # directory that contains a SVN property.  SUB will be invoked as
1861 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
1862 # Git::SVN, `path' the path to the directory where the properties
1863 # `props' were found.  The `path' will be relative to point of checkout,
1864 # that is, if url://repo/trunk is the current Git branch, and that
1865 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1866 # as `path' (note the trailing `/').
1867 sub prop_walk {
1868         my ($self, $path, $rev, $sub) = @_;
1869
1870         $path =~ s#^/##;
1871         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1872         $path =~ s#^/*#/#g;
1873         my $p = $path;
1874         # Strip the irrelevant part of the path.
1875         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1876         # Ensure the path is terminated by a `/'.
1877         $p =~ s#/*$#/#;
1878
1879         # The properties contain all the internal SVN stuff nobody
1880         # (usually) cares about.
1881         my $interesting_props = 0;
1882         foreach (keys %{$props}) {
1883                 # If it doesn't start with `svn:', it must be a
1884                 # user-defined property.
1885                 ++$interesting_props and next if $_ !~ /^svn:/;
1886                 # FIXME: Fragile, if SVN adds new public properties,
1887                 # this needs to be updated.
1888                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1889                                                  |eol-style|mime-type
1890                                                  |externals|needs-lock)$/x;
1891         }
1892         &$sub($self, $p, $props) if $interesting_props;
1893
1894         foreach (sort keys %$dirent) {
1895                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1896                 $self->prop_walk($path . '/' . $_, $rev, $sub);
1897         }
1898 }
1899
1900 sub last_rev { ($_[0]->last_rev_commit)[0] }
1901 sub last_commit { ($_[0]->last_rev_commit)[1] }
1902
1903 # returns the newest SVN revision number and newest commit SHA1
1904 sub last_rev_commit {
1905         my ($self) = @_;
1906         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1907                 return ($self->{last_rev}, $self->{last_commit});
1908         }
1909         my $c = ::verify_ref($self->refname.'^0');
1910         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1911                 my $rev = (::cmt_metadata($c))[1];
1912                 if (defined $rev) {
1913                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1914                         return ($rev, $c);
1915                 }
1916         }
1917         my $map_path = $self->map_path;
1918         unless (-e $map_path) {
1919                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1920                 return (undef, undef);
1921         }
1922         my ($rev, $commit) = $self->rev_map_max(1);
1923         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1924         return ($rev, $commit);
1925 }
1926
1927 sub get_fetch_range {
1928         my ($self, $min, $max) = @_;
1929         $max ||= $self->ra->get_latest_revnum;
1930         $min ||= $self->rev_map_max;
1931         (++$min, $max);
1932 }
1933
1934 sub tmp_config {
1935         my (@args) = @_;
1936         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1937         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1938         if (! -f $config && -f $old_def_config) {
1939                 rename $old_def_config, $config or
1940                        die "Failed rename $old_def_config => $config: $!\n";
1941         }
1942         my $old_config = $ENV{GIT_CONFIG};
1943         $ENV{GIT_CONFIG} = $config;
1944         $@ = undef;
1945         my @ret = eval {
1946                 unless (-f $config) {
1947                         mkfile($config);
1948                         open my $fh, '>', $config or
1949                             die "Can't open $config: $!\n";
1950                         print $fh "; This file is used internally by ",
1951                                   "git-svn\n" or die
1952                                   "Couldn't write to $config: $!\n";
1953                         print $fh "; You should not have to edit it\n" or
1954                               die "Couldn't write to $config: $!\n";
1955                         close $fh or die "Couldn't close $config: $!\n";
1956                 }
1957                 command('config', @args);
1958         };
1959         my $err = $@;
1960         if (defined $old_config) {
1961                 $ENV{GIT_CONFIG} = $old_config;
1962         } else {
1963                 delete $ENV{GIT_CONFIG};
1964         }
1965         die $err if $err;
1966         wantarray ? @ret : $ret[0];
1967 }
1968
1969 sub tmp_index_do {
1970         my ($self, $sub) = @_;
1971         my $old_index = $ENV{GIT_INDEX_FILE};
1972         $ENV{GIT_INDEX_FILE} = $self->{index};
1973         $@ = undef;
1974         my @ret = eval {
1975                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1976                 mkpath([$dir]) unless -d $dir;
1977                 &$sub;
1978         };
1979         my $err = $@;
1980         if (defined $old_index) {
1981                 $ENV{GIT_INDEX_FILE} = $old_index;
1982         } else {
1983                 delete $ENV{GIT_INDEX_FILE};
1984         }
1985         die $err if $err;
1986         wantarray ? @ret : $ret[0];
1987 }
1988
1989 sub assert_index_clean {
1990         my ($self, $treeish) = @_;
1991
1992         $self->tmp_index_do(sub {
1993                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1994                 my $x = command_oneline('write-tree');
1995                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1996                            /^tree ($::sha1)/mo);
1997                 return if $y eq $x;
1998
1999                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2000                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2001                 command_noisy('read-tree', $treeish);
2002                 $x = command_oneline('write-tree');
2003                 if ($y ne $x) {
2004                         ::fatal "trees ($treeish) $y != $x\n",
2005                                 "Something is seriously wrong...";
2006                 }
2007         });
2008 }
2009
2010 sub get_commit_parents {
2011         my ($self, $log_entry) = @_;
2012         my (%seen, @ret, @tmp);
2013         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2014         if (my $ip = $self->{inject_parents}) {
2015                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2016                         push @tmp, $commit;
2017                 }
2018         }
2019         if (my $cur = ::verify_ref($self->refname.'^0')) {
2020                 push @tmp, $cur;
2021         }
2022         if (my $ipd = $self->{inject_parents_dcommit}) {
2023                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2024                         push @tmp, @$commit;
2025                 }
2026         }
2027         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2028         while (my $p = shift @tmp) {
2029                 next if $seen{$p};
2030                 $seen{$p} = 1;
2031                 push @ret, $p;
2032                 # MAXPARENT is defined to 16 in commit-tree.c:
2033                 last if @ret >= 16;
2034         }
2035         if (@tmp) {
2036                 die "r$log_entry->{revision}: No room for parents:\n\t",
2037                     join("\n\t", @tmp), "\n";
2038         }
2039         @ret;
2040 }
2041
2042 sub rewrite_root {
2043         my ($self) = @_;
2044         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2045         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2046         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2047         if ($rwr) {
2048                 $rwr =~ s#/+$##;
2049                 if ($rwr !~ m#^[a-z\+]+://#) {
2050                         die "$rwr is not a valid URL (key: $k)\n";
2051                 }
2052         }
2053         $self->{-rewrite_root} = $rwr;
2054 }
2055
2056 sub metadata_url {
2057         my ($self) = @_;
2058         ($self->rewrite_root || $self->{url}) .
2059            (length $self->{path} ? '/' . $self->{path} : '');
2060 }
2061
2062 sub full_url {
2063         my ($self) = @_;
2064         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2065 }
2066
2067
2068 sub set_commit_header_env {
2069         my ($log_entry) = @_;
2070         my %env;
2071         foreach my $ned (qw/NAME EMAIL DATE/) {
2072                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2073                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2074                 }
2075         }
2076
2077         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2078         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2079         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2080
2081         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2082                                                 ? $log_entry->{commit_name}
2083                                                 : $log_entry->{name};
2084         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2085                                                 ? $log_entry->{commit_email}
2086                                                 : $log_entry->{email};
2087         \%env;
2088 }
2089
2090 sub restore_commit_header_env {
2091         my ($env) = @_;
2092         foreach my $ned (qw/NAME EMAIL DATE/) {
2093                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2094                         my $k = "GIT_${ac}_${ned}";
2095                         if (defined $env->{$k}) {
2096                                 $ENV{$k} = $env->{$k};
2097                         } else {
2098                                 delete $ENV{$k};
2099                         }
2100                 }
2101         }
2102 }
2103
2104 sub gc {
2105         command_noisy('gc', '--auto');
2106 };
2107
2108 sub do_git_commit {
2109         my ($self, $log_entry) = @_;
2110         my $lr = $self->last_rev;
2111         if (defined $lr && $lr >= $log_entry->{revision}) {
2112                 die "Last fetched revision of ", $self->refname,
2113                     " was r$lr, but we are about to fetch: ",
2114                     "r$log_entry->{revision}!\n";
2115         }
2116         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2117                 croak "$log_entry->{revision} = $c already exists! ",
2118                       "Why are we refetching it?\n";
2119         }
2120         my $old_env = set_commit_header_env($log_entry);
2121         my $tree = $log_entry->{tree};
2122         if (!defined $tree) {
2123                 $tree = $self->tmp_index_do(sub {
2124                                             command_oneline('write-tree') });
2125         }
2126         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2127
2128         my @exec = ('git-commit-tree', $tree);
2129         foreach ($self->get_commit_parents($log_entry)) {
2130                 push @exec, '-p', $_;
2131         }
2132         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2133                                                                    or croak $!;
2134         print $msg_fh $log_entry->{log} or croak $!;
2135         restore_commit_header_env($old_env);
2136         unless ($self->no_metadata) {
2137                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2138                               or croak $!;
2139         }
2140         $msg_fh->flush == 0 or croak $!;
2141         close $msg_fh or croak $!;
2142         chomp(my $commit = do { local $/; <$out_fh> });
2143         close $out_fh or croak $!;
2144         waitpid $pid, 0;
2145         croak $? if $?;
2146         if ($commit !~ /^$::sha1$/o) {
2147                 die "Failed to commit, invalid sha1: $commit\n";
2148         }
2149
2150         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2151
2152         $self->{last_rev} = $log_entry->{revision};
2153         $self->{last_commit} = $commit;
2154         print "r$log_entry->{revision}";
2155         if (defined $log_entry->{svm_revision}) {
2156                  print " (\@$log_entry->{svm_revision})";
2157                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2158                                    0, $self->svm_uuid);
2159         }
2160         print " = $commit ($self->{ref_id})\n";
2161         if (--$_gc_nr == 0) {
2162                 $_gc_nr = $_gc_period;
2163                 gc();
2164         }
2165         return $commit;
2166 }
2167
2168 sub match_paths {
2169         my ($self, $paths, $r) = @_;
2170         return 1 if $self->{path} eq '';
2171         if (my $path = $paths->{"/$self->{path}"}) {
2172                 return ($path->{action} eq 'D') ? 0 : 1;
2173         }
2174         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2175         if (grep /$self->{path_regex}/, keys %$paths) {
2176                 return 1;
2177         }
2178         my $c = '';
2179         foreach (split m#/#, $self->{path}) {
2180                 $c .= "/$_";
2181                 next unless ($paths->{$c} &&
2182                              ($paths->{$c}->{action} =~ /^[AR]$/));
2183                 if ($self->ra->check_path($self->{path}, $r) ==
2184                     $SVN::Node::dir) {
2185                         return 1;
2186                 }
2187         }
2188         return 0;
2189 }
2190
2191 sub find_parent_branch {
2192         my ($self, $paths, $rev) = @_;
2193         return undef unless $self->follow_parent;
2194         unless (defined $paths) {
2195                 my $err_handler = $SVN::Error::handler;
2196                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2197                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2198                                    $paths =
2199                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
2200                 $SVN::Error::handler = $err_handler;
2201         }
2202         return undef unless defined $paths;
2203
2204         # look for a parent from another branch:
2205         my @b_path_components = split m#/#, $self->rel_path;
2206         my @a_path_components;
2207         my $i;
2208         while (@b_path_components) {
2209                 $i = $paths->{'/'.join('/', @b_path_components)};
2210                 last if $i && defined $i->{copyfrom_path};
2211                 unshift(@a_path_components, pop(@b_path_components));
2212         }
2213         return undef unless defined $i && defined $i->{copyfrom_path};
2214         my $branch_from = $i->{copyfrom_path};
2215         if (@a_path_components) {
2216                 print STDERR "branch_from: $branch_from => ";
2217                 $branch_from .= '/'.join('/', @a_path_components);
2218                 print STDERR $branch_from, "\n";
2219         }
2220         my $r = $i->{copyfrom_rev};
2221         my $repos_root = $self->ra->{repos_root};
2222         my $url = $self->ra->{url};
2223         my $new_url = $repos_root . $branch_from;
2224         print STDERR  "Found possible branch point: ",
2225                       "$new_url => ", $self->full_url, ", $r\n";
2226         $branch_from =~ s#^/##;
2227         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2228         unless ($gs) {
2229                 my $ref_id = $self->{ref_id};
2230                 $ref_id =~ s/\@\d+$//;
2231                 $ref_id .= "\@$r";
2232                 # just grow a tail if we're not unique enough :x
2233                 $ref_id .= '-' while find_ref($ref_id);
2234                 print STDERR "Initializing parent: $ref_id\n";
2235                 my ($u, $p) = ($new_url, '');
2236                 if ($u =~ s#^\Q$url\E(/|$)##) {
2237                         $p = $u;
2238                         $u = $url;
2239                 }
2240                 $gs = Git::SVN->init($u, $p, $self->{repo_id}, $ref_id, 1);
2241         }
2242         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2243         if (!defined $r0 || !defined $parent) {
2244                 my ($base, $head) = parse_revision_argument(0, $r);
2245                 if ($base <= $r) {
2246                         $gs->fetch($base, $r);
2247                 }
2248                 ($r0, $parent) = $gs->last_rev_commit;
2249         }
2250         if (defined $r0 && defined $parent) {
2251                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2252                 my $ed;
2253                 if ($self->ra->can_do_switch) {
2254                         $self->assert_index_clean($parent);
2255                         print STDERR "Following parent with do_switch\n";
2256                         # do_switch works with svn/trunk >= r22312, but that
2257                         # is not included with SVN 1.4.3 (the latest version
2258                         # at the moment), so we can't rely on it
2259                         $self->{last_commit} = $parent;
2260                         $ed = SVN::Git::Fetcher->new($self);
2261                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2262                                               $self->full_url, $ed)
2263                           or die "SVN connection failed somewhere...\n";
2264                 } elsif ($self->ra->trees_match($new_url, $r0,
2265                                                 $self->full_url, $rev)) {
2266                         print STDERR "Trees match:\n",
2267                                      "  $new_url\@$r0\n",
2268                                      "  ${\$self->full_url}\@$rev\n",
2269                                      "Following parent with no changes\n";
2270                         $self->tmp_index_do(sub {
2271                             command_noisy('read-tree', $parent);
2272                         });
2273                         $self->{last_commit} = $parent;
2274                 } else {
2275                         print STDERR "Following parent with do_update\n";
2276                         $ed = SVN::Git::Fetcher->new($self);
2277                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2278                           or die "SVN connection failed somewhere...\n";
2279                 }
2280                 print STDERR "Successfully followed parent\n";
2281                 return $self->make_log_entry($rev, [$parent], $ed);
2282         }
2283         return undef;
2284 }
2285
2286 sub do_fetch {
2287         my ($self, $paths, $rev) = @_;
2288         my $ed;
2289         my ($last_rev, @parents);
2290         if (my $lc = $self->last_commit) {
2291                 # we can have a branch that was deleted, then re-added
2292                 # under the same name but copied from another path, in
2293                 # which case we'll have multiple parents (we don't
2294                 # want to break the original ref, nor lose copypath info):
2295                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2296                         push @{$log_entry->{parents}}, $lc;
2297                         return $log_entry;
2298                 }
2299                 $ed = SVN::Git::Fetcher->new($self);
2300                 $last_rev = $self->{last_rev};
2301                 $ed->{c} = $lc;
2302                 @parents = ($lc);
2303         } else {
2304                 $last_rev = $rev;
2305                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2306                         return $log_entry;
2307                 }
2308                 $ed = SVN::Git::Fetcher->new($self);
2309         }
2310         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2311                 die "SVN connection failed somewhere...\n";
2312         }
2313         $self->make_log_entry($rev, \@parents, $ed);
2314 }
2315
2316 sub get_untracked {
2317         my ($self, $ed) = @_;
2318         my @out;
2319         my $h = $ed->{empty};
2320         foreach (sort keys %$h) {
2321                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2322                 push @out, "  $act: " . uri_encode($_);
2323                 warn "W: $act: $_\n";
2324         }
2325         foreach my $t (qw/dir_prop file_prop/) {
2326                 $h = $ed->{$t} or next;
2327                 foreach my $path (sort keys %$h) {
2328                         my $ppath = $path eq '' ? '.' : $path;
2329                         foreach my $prop (sort keys %{$h->{$path}}) {
2330                                 next if $SKIP_PROP{$prop};
2331                                 my $v = $h->{$path}->{$prop};
2332                                 my $t_ppath_prop = "$t: " .
2333                                                     uri_encode($ppath) . ' ' .
2334                                                     uri_encode($prop);
2335                                 if (defined $v) {
2336                                         push @out, "  +$t_ppath_prop " .
2337                                                    uri_encode($v);
2338                                 } else {
2339                                         push @out, "  -$t_ppath_prop";
2340                                 }
2341                         }
2342                 }
2343         }
2344         foreach my $t (qw/absent_file absent_directory/) {
2345                 $h = $ed->{$t} or next;
2346                 foreach my $parent (sort keys %$h) {
2347                         foreach my $path (sort @{$h->{$parent}}) {
2348                                 push @out, "  $t: " .
2349                                            uri_encode("$parent/$path");
2350                                 warn "W: $t: $parent/$path ",
2351                                      "Insufficient permissions?\n";
2352                         }
2353                 }
2354         }
2355         \@out;
2356 }
2357
2358 sub parse_svn_date {
2359         my $date = shift || return '+0000 1970-01-01 00:00:00';
2360         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2361                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2362                                          croak "Unable to parse date: $date\n";
2363         "+0000 $Y-$m-$d $H:$M:$S";
2364 }
2365
2366 sub check_author {
2367         my ($author) = @_;
2368         if (!defined $author || length $author == 0) {
2369                 $author = '(no author)';
2370         }
2371         if (defined $::_authors && ! defined $::users{$author}) {
2372                 die "Author: $author not defined in $::_authors file\n";
2373         }
2374         $author;
2375 }
2376
2377 sub make_log_entry {
2378         my ($self, $rev, $parents, $ed) = @_;
2379         my $untracked = $self->get_untracked($ed);
2380
2381         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2382         print $un "r$rev\n" or croak $!;
2383         print $un $_, "\n" foreach @$untracked;
2384         my %log_entry = ( parents => $parents || [], revision => $rev,
2385                           log => '');
2386
2387         my $headrev;
2388         my $logged = delete $self->{logged_rev_props};
2389         if (!$logged || $self->{-want_revprops}) {
2390                 my $rp = $self->ra->rev_proplist($rev);
2391                 foreach (sort keys %$rp) {
2392                         my $v = $rp->{$_};
2393                         if (/^svn:(author|date|log)$/) {
2394                                 $log_entry{$1} = $v;
2395                         } elsif ($_ eq 'svm:headrev') {
2396                                 $headrev = $v;
2397                         } else {
2398                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2399                                           uri_encode($v), "\n";
2400                         }
2401                 }
2402         } else {
2403                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2404         }
2405         close $un or croak $!;
2406
2407         $log_entry{date} = parse_svn_date($log_entry{date});
2408         $log_entry{log} .= "\n";
2409         my $author = $log_entry{author} = check_author($log_entry{author});
2410         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2411                                                        : ($author, undef);
2412
2413         my ($commit_name, $commit_email) = ($name, $email);
2414         if ($_use_log_author) {
2415                 my $name_field;
2416                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2417                         $name_field = $1;
2418                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2419                         $name_field = $1;
2420                 }
2421                 if (!defined $name_field) {
2422                         #
2423                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2424                         ($name, $email) = ($1, $2);
2425                 } elsif ($name_field =~ /(.*)@/) {
2426                         ($name, $email) = ($1, $name_field);
2427                 } else {
2428                         ($name, $email) = ($name_field, 'unknown');
2429                 }
2430         }
2431         if (defined $headrev && $self->use_svm_props) {
2432                 if ($self->rewrite_root) {
2433                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2434                             "options set!\n";
2435                 }
2436                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2437                 # we don't want "SVM: initializing mirror for junk" ...
2438                 return undef if $r == 0;
2439                 my $svm = $self->svm;
2440                 if ($uuid ne $svm->{uuid}) {
2441                         die "UUID mismatch on SVM path:\n",
2442                             "expected: $svm->{uuid}\n",
2443                             "     got: $uuid\n";
2444                 }
2445                 my $full_url = $self->full_url;
2446                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2447                              die "Failed to replace '$svm->{replace}' with ",
2448                                  "'$svm->{source}' in $full_url\n";
2449                 # throw away username for storing in records
2450                 remove_username($full_url);
2451                 $log_entry{metadata} = "$full_url\@$r $uuid";
2452                 $log_entry{svm_revision} = $r;
2453                 $email ||= "$author\@$uuid";
2454                 $commit_email ||= "$author\@$uuid";
2455         } elsif ($self->use_svnsync_props) {
2456                 my $full_url = $self->svnsync->{url};
2457                 $full_url .= "/$self->{path}" if length $self->{path};
2458                 remove_username($full_url);
2459                 my $uuid = $self->svnsync->{uuid};
2460                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2461                 $email ||= "$author\@$uuid";
2462                 $commit_email ||= "$author\@$uuid";
2463         } else {
2464                 my $url = $self->metadata_url;
2465                 remove_username($url);
2466                 $log_entry{metadata} = "$url\@$rev " .
2467                                        $self->ra->get_uuid;
2468                 $email ||= "$author\@" . $self->ra->get_uuid;
2469                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2470         }
2471         $log_entry{name} = $name;
2472         $log_entry{email} = $email;
2473         $log_entry{commit_name} = $commit_name;
2474         $log_entry{commit_email} = $commit_email;
2475         \%log_entry;
2476 }
2477
2478 sub fetch {
2479         my ($self, $min_rev, $max_rev, @parents) = @_;
2480         my ($last_rev, $last_commit) = $self->last_rev_commit;
2481         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2482         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2483 }
2484
2485 sub set_tree_cb {
2486         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2487         $self->{inject_parents} = { $rev => $tree };
2488         $self->fetch(undef, undef);
2489 }
2490
2491 sub set_tree {
2492         my ($self, $tree) = (shift, shift);
2493         my $log_entry = ::get_commit_entry($tree);
2494         unless ($self->{last_rev}) {
2495                 fatal("Must have an existing revision to commit");
2496         }
2497         my %ed_opts = ( r => $self->{last_rev},
2498                         log => $log_entry->{log},
2499                         ra => $self->ra,
2500                         tree_a => $self->{last_commit},
2501                         tree_b => $tree,
2502                         editor_cb => sub {
2503                                $self->set_tree_cb($log_entry, $tree, @_) },
2504                         svn_path => $self->{path} );
2505         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2506                 print "No changes\nr$self->{last_rev} = $tree\n";
2507         }
2508 }
2509
2510 sub rebuild_from_rev_db {
2511         my ($self, $path) = @_;
2512         my $r = -1;
2513         open my $fh, '<', $path or croak "open: $!";
2514         while (<$fh>) {
2515                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2516                 chomp($_);
2517                 ++$r;
2518                 next if $_ eq ('0' x 40);
2519                 $self->rev_map_set($r, $_);
2520                 print "r$r = $_\n";
2521         }
2522         close $fh or croak "close: $!";
2523         unlink $path or croak "unlink: $!";
2524 }
2525
2526 sub rebuild {
2527         my ($self) = @_;
2528         my $map_path = $self->map_path;
2529         return if (-e $map_path && ! -z $map_path);
2530         return unless ::verify_ref($self->refname.'^0');
2531         if ($self->use_svm_props || $self->no_metadata) {
2532                 my $rev_db = $self->rev_db_path;
2533                 $self->rebuild_from_rev_db($rev_db);
2534                 if ($self->use_svm_props) {
2535                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2536                         $self->rebuild_from_rev_db($svm_rev_db);
2537                 }
2538                 $self->unlink_rev_db_symlink;
2539                 return;
2540         }
2541         print "Rebuilding $map_path ...\n";
2542         my ($log, $ctx) =
2543             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2544                                 $self->refname, '--');
2545         my $full_url = $self->full_url;
2546         remove_username($full_url);
2547         my $svn_uuid = $self->ra_uuid;
2548         my $c;
2549         while (<$log>) {
2550                 if ( m{^commit ($::sha1)$} ) {
2551                         $c = $1;
2552                         next;
2553                 }
2554                 next unless s{^\s*(git-svn-id:)}{$1};
2555                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2556                 remove_username($url);
2557
2558                 # ignore merges (from set-tree)
2559                 next if (!defined $rev || !$uuid);
2560
2561                 # if we merged or otherwise started elsewhere, this is
2562                 # how we break out of it
2563                 if (($uuid ne $svn_uuid) ||
2564                     ($full_url && $url && ($url ne $full_url))) {
2565                         next;
2566                 }
2567
2568                 $self->rev_map_set($rev, $c);
2569                 print "r$rev = $c\n";
2570         }
2571         command_close_pipe($log, $ctx);
2572         print "Done rebuilding $map_path\n";
2573         my $rev_db_path = $self->rev_db_path;
2574         if (-f $self->rev_db_path) {
2575                 unlink $self->rev_db_path or croak "unlink: $!";
2576         }
2577         $self->unlink_rev_db_symlink;
2578 }
2579
2580 # rev_map:
2581 # Tie::File seems to be prone to offset errors if revisions get sparse,
2582 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2583 # one of my favorite modules is out :<  Next up would be one of the DBM
2584 # modules, but I'm not sure which is most portable...
2585 #
2586 # This is the replacement for the rev_db format, which was too big
2587 # and inefficient for large repositories with a lot of sparse history
2588 # (mainly tags)
2589 #
2590 # The format is this:
2591 #   - 24 bytes for every record,
2592 #     * 4 bytes for the integer representing an SVN revision number
2593 #     * 20 bytes representing the sha1 of a git commit
2594 #   - No empty padding records like the old format
2595 #     (except the last record, which can be overwritten)
2596 #   - new records are written append-only since SVN revision numbers
2597 #     increase monotonically
2598 #   - lookups on SVN revision number are done via a binary search
2599 #   - Piping the file to xxd -c24 is a good way of dumping it for
2600 #     viewing or editing (piped back through xxd -r), should the need
2601 #     ever arise.
2602 #   - The last record can be padding revision with an all-zero sha1
2603 #     This is used to optimize fetch performance when using multiple
2604 #     "fetch" directives in .git/config
2605 #
2606 # These files are disposable unless noMetadata or useSvmProps is set
2607
2608 sub _rev_map_set {
2609         my ($fh, $rev, $commit) = @_;
2610
2611         my $size = (stat($fh))[7];
2612         ($size % 24) == 0 or croak "inconsistent size: $size";
2613
2614         my $wr_offset = 0;
2615         if ($size > 0) {
2616                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2617                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2618                 $read == 24 or croak "read only $read bytes (!= 24)";
2619                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2620                 if ($last_commit eq ('0' x40)) {
2621                         if ($size >= 48) {
2622                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2623                                 $read = sysread($fh, $buf, 24) or
2624                                     croak "read: $!";
2625                                 $read == 24 or
2626                                     croak "read only $read bytes (!= 24)";
2627                                 ($last_rev, $last_commit) =
2628                                     unpack(rev_map_fmt, $buf);
2629                                 if ($last_commit eq ('0' x40)) {
2630                                         croak "inconsistent .rev_map\n";
2631                                 }
2632                         }
2633                         if ($last_rev >= $rev) {
2634                                 croak "last_rev is higher!: $last_rev >= $rev";
2635                         }
2636                         $wr_offset = -24;
2637                 }
2638         }
2639         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2640         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2641           croak "write: $!";
2642 }
2643
2644 sub mkfile {
2645         my ($path) = @_;
2646         unless (-e $path) {
2647                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2648                 mkpath([$dir]) unless -d $dir;
2649                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2650                 close $fh or die "Couldn't close (create) $path: $!\n";
2651         }
2652 }
2653
2654 sub rev_map_set {
2655         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2656         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2657         my $db = $self->map_path($uuid);
2658         my $db_lock = "$db.lock";
2659         my $sig;
2660         if ($update_ref) {
2661                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2662                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2663         }
2664         mkfile($db);
2665
2666         $LOCKFILES{$db_lock} = 1;
2667         my $sync;
2668         # both of these options make our .rev_db file very, very important
2669         # and we can't afford to lose it because rebuild() won't work
2670         if ($self->use_svm_props || $self->no_metadata) {
2671                 $sync = 1;
2672                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2673                                            "Failed to copy: ",
2674                                            "$db => $db_lock ($!)\n";
2675         } else {
2676                 rename $db, $db_lock or die "rev_map_set(@_): ",
2677                                             "Failed to rename: ",
2678                                             "$db => $db_lock ($!)\n";
2679         }
2680
2681         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2682              or croak "Couldn't open $db_lock: $!\n";
2683         _rev_map_set($fh, $rev, $commit);
2684         if ($sync) {
2685                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2686                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2687         }
2688         close $fh or croak $!;
2689         if ($update_ref) {
2690                 $_head = $self;
2691                 command_noisy('update-ref', '-m', "r$rev",
2692                               $self->refname, $commit);
2693         }
2694         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2695                                     "$db_lock => $db ($!)\n";
2696         delete $LOCKFILES{$db_lock};
2697         if ($update_ref) {
2698                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2699                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2700                 kill $sig, $$ if defined $sig;
2701         }
2702 }
2703
2704 # If want_commit, this will return an array of (rev, commit) where
2705 # commit _must_ be a valid commit in the archive.
2706 # Otherwise, it'll return the max revision (whether or not the
2707 # commit is valid or just a 0x40 placeholder).
2708 sub rev_map_max {
2709         my ($self, $want_commit) = @_;
2710         $self->rebuild;
2711         my $map_path = $self->map_path;
2712         stat $map_path or return $want_commit ? (0, undef) : 0;
2713         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2714         my $size = (stat($fh))[7];
2715         ($size % 24) == 0 or croak "inconsistent size: $size";
2716
2717         if ($size == 0) {
2718                 close $fh or croak "close: $!";
2719                 return $want_commit ? (0, undef) : 0;
2720         }
2721
2722         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2723         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2724         my ($r, $c) = unpack(rev_map_fmt, $buf);
2725         if ($want_commit && $c eq ('0' x40)) {
2726                 if ($size < 48) {
2727                         return $want_commit ? (0, undef) : 0;
2728                 }
2729                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2730                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2731                 ($r, $c) = unpack(rev_map_fmt, $buf);
2732                 if ($c eq ('0'x40)) {
2733                         croak "Penultimate record is all-zeroes in $map_path";
2734                 }
2735         }
2736         close $fh or croak "close: $!";
2737         $want_commit ? ($r, $c) : $r;
2738 }
2739
2740 sub rev_map_get {
2741         my ($self, $rev, $uuid) = @_;
2742         my $map_path = $self->map_path($uuid);
2743         return undef unless -e $map_path;
2744
2745         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2746         my $size = (stat($fh))[7];
2747         ($size % 24) == 0 or croak "inconsistent size: $size";
2748
2749         if ($size == 0) {
2750                 close $fh or croak "close: $fh";
2751                 return undef;
2752         }
2753
2754         my ($l, $u) = (0, $size - 24);
2755         my ($r, $c, $buf);
2756
2757         while ($l <= $u) {
2758                 my $i = int(($l/24 + $u/24) / 2) * 24;
2759                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2760                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2761                 my ($r, $c) = unpack('NH40', $buf);
2762
2763                 if ($r < $rev) {
2764                         $l = $i + 24;
2765                 } elsif ($r > $rev) {
2766                         $u = $i - 24;
2767                 } else { # $r == $rev
2768                         close($fh) or croak "close: $!";
2769                         return $c eq ('0' x 40) ? undef : $c;
2770                 }
2771         }
2772         close($fh) or croak "close: $!";
2773         undef;
2774 }
2775
2776 # Finds the first svn revision that exists on (if $eq_ok is true) or
2777 # before $rev for the current branch.  It will not search any lower
2778 # than $min_rev.  Returns the git commit hash and svn revision number
2779 # if found, else (undef, undef).
2780 sub find_rev_before {
2781         my ($self, $rev, $eq_ok, $min_rev) = @_;
2782         --$rev unless $eq_ok;
2783         $min_rev ||= 1;
2784         while ($rev >= $min_rev) {
2785                 if (my $c = $self->rev_map_get($rev)) {
2786                         return ($rev, $c);
2787                 }
2788                 --$rev;
2789         }
2790         return (undef, undef);
2791 }
2792
2793 # Finds the first svn revision that exists on (if $eq_ok is true) or
2794 # after $rev for the current branch.  It will not search any higher
2795 # than $max_rev.  Returns the git commit hash and svn revision number
2796 # if found, else (undef, undef).
2797 sub find_rev_after {
2798         my ($self, $rev, $eq_ok, $max_rev) = @_;
2799         ++$rev unless $eq_ok;
2800         $max_rev ||= $self->rev_map_max;
2801         while ($rev <= $max_rev) {
2802                 if (my $c = $self->rev_map_get($rev)) {
2803                         return ($rev, $c);
2804                 }
2805                 ++$rev;
2806         }
2807         return (undef, undef);
2808 }
2809
2810 sub _new {
2811         my ($class, $repo_id, $ref_id, $path) = @_;
2812         unless (defined $repo_id && length $repo_id) {
2813                 $repo_id = $Git::SVN::default_repo_id;
2814         }
2815         unless (defined $ref_id && length $ref_id) {
2816                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2817         }
2818         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2819         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2820         $_[3] = $path = '' unless (defined $path);
2821         mkpath(["$ENV{GIT_DIR}/svn"]);
2822         bless {
2823                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2824                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2825                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2826 }
2827
2828 # for read-only access of old .rev_db formats
2829 sub unlink_rev_db_symlink {
2830         my ($self) = @_;
2831         my $link = $self->rev_db_path;
2832         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2833         if (-l $link) {
2834                 unlink $link or croak "unlink: $link failed!";
2835         }
2836 }
2837
2838 sub rev_db_path {
2839         my ($self, $uuid) = @_;
2840         my $db_path = $self->map_path($uuid);
2841         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2842             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2843         $db_path;
2844 }
2845
2846 # the new replacement for .rev_db
2847 sub map_path {
2848         my ($self, $uuid) = @_;
2849         $uuid ||= $self->ra_uuid;
2850         "$self->{map_root}.$uuid";
2851 }
2852
2853 sub uri_encode {
2854         my ($f) = @_;
2855         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2856         $f
2857 }
2858
2859 sub remove_username {
2860         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2861 }
2862
2863 package Git::SVN::Prompt;
2864 use strict;
2865 use warnings;
2866 require SVN::Core;
2867 use vars qw/$_no_auth_cache $_username/;
2868
2869 sub simple {
2870         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2871         $may_save = undef if $_no_auth_cache;
2872         $default_username = $_username if defined $_username;
2873         if (defined $default_username && length $default_username) {
2874                 if (defined $realm && length $realm) {
2875                         print STDERR "Authentication realm: $realm\n";
2876                         STDERR->flush;
2877                 }
2878                 $cred->username($default_username);
2879         } else {
2880                 username($cred, $realm, $may_save, $pool);
2881         }
2882         $cred->password(_read_password("Password for '" .
2883                                        $cred->username . "': ", $realm));
2884         $cred->may_save($may_save);
2885         $SVN::_Core::SVN_NO_ERROR;
2886 }
2887
2888 sub ssl_server_trust {
2889         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2890         $may_save = undef if $_no_auth_cache;
2891         print STDERR "Error validating server certificate for '$realm':\n";
2892         {
2893                 no warnings 'once';
2894                 # All variables SVN::Auth::SSL::* are used only once,
2895                 # so we're shutting up Perl warnings about this.
2896                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2897                         print STDERR " - The certificate is not issued ",
2898                             "by a trusted authority. Use the\n",
2899                             "   fingerprint to validate ",
2900                             "the certificate manually!\n";
2901                 }
2902                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2903                         print STDERR " - The certificate hostname ",
2904                             "does not match.\n";
2905                 }
2906                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2907                         print STDERR " - The certificate is not yet valid.\n";
2908                 }
2909                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2910                         print STDERR " - The certificate has expired.\n";
2911                 }
2912                 if ($failures & $SVN::Auth::SSL::OTHER) {
2913                         print STDERR " - The certificate has ",
2914                             "an unknown error.\n";
2915                 }
2916         } # no warnings 'once'
2917         printf STDERR
2918                 "Certificate information:\n".
2919                 " - Hostname: %s\n".
2920                 " - Valid: from %s until %s\n".
2921                 " - Issuer: %s\n".
2922                 " - Fingerprint: %s\n",
2923                 map $cert_info->$_, qw(hostname valid_from valid_until
2924                                        issuer_dname fingerprint);
2925         my $choice;
2926 prompt:
2927         print STDERR $may_save ?
2928               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2929               "(R)eject or accept (t)emporarily? ";
2930         STDERR->flush;
2931         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2932         if ($choice =~ /^t$/i) {
2933                 $cred->may_save(undef);
2934         } elsif ($choice =~ /^r$/i) {
2935                 return -1;
2936         } elsif ($may_save && $choice =~ /^p$/i) {
2937                 $cred->may_save($may_save);
2938         } else {
2939                 goto prompt;
2940         }
2941         $cred->accepted_failures($failures);
2942         $SVN::_Core::SVN_NO_ERROR;
2943 }
2944
2945 sub ssl_client_cert {
2946         my ($cred, $realm, $may_save, $pool) = @_;
2947         $may_save = undef if $_no_auth_cache;
2948         print STDERR "Client certificate filename: ";
2949         STDERR->flush;
2950         chomp(my $filename = <STDIN>);
2951         $cred->cert_file($filename);
2952         $cred->may_save($may_save);
2953         $SVN::_Core::SVN_NO_ERROR;
2954 }
2955
2956 sub ssl_client_cert_pw {
2957         my ($cred, $realm, $may_save, $pool) = @_;
2958         $may_save = undef if $_no_auth_cache;
2959         $cred->password(_read_password("Password: ", $realm));
2960         $cred->may_save($may_save);
2961         $SVN::_Core::SVN_NO_ERROR;
2962 }
2963
2964 sub username {
2965         my ($cred, $realm, $may_save, $pool) = @_;
2966         $may_save = undef if $_no_auth_cache;
2967         if (defined $realm && length $realm) {
2968                 print STDERR "Authentication realm: $realm\n";
2969         }
2970         my $username;
2971         if (defined $_username) {
2972                 $username = $_username;
2973         } else {
2974                 print STDERR "Username: ";
2975                 STDERR->flush;
2976                 chomp($username = <STDIN>);
2977         }
2978         $cred->username($username);
2979         $cred->may_save($may_save);
2980         $SVN::_Core::SVN_NO_ERROR;
2981 }
2982
2983 sub _read_password {
2984         my ($prompt, $realm) = @_;
2985         print STDERR $prompt;
2986         STDERR->flush;
2987         require Term::ReadKey;
2988         Term::ReadKey::ReadMode('noecho');
2989         my $password = '';
2990         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2991                 last if $key =~ /[\012\015]/; # \n\r
2992                 $password .= $key;
2993         }
2994         Term::ReadKey::ReadMode('restore');
2995         print STDERR "\n";
2996         STDERR->flush;
2997         $password;
2998 }
2999
3000 package SVN::Git::Fetcher;
3001 use vars qw/@ISA/;
3002 use strict;
3003 use warnings;
3004 use Carp qw/croak/;
3005 use IO::File qw//;
3006
3007 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3008 sub new {
3009         my ($class, $git_svn) = @_;
3010         my $self = SVN::Delta::Editor->new;
3011         bless $self, $class;
3012         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3013         $self->{empty} = {};
3014         $self->{dir_prop} = {};
3015         $self->{file_prop} = {};
3016         $self->{absent_dir} = {};
3017         $self->{absent_file} = {};
3018         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3019         $self;
3020 }
3021
3022 sub set_path_strip {
3023         my ($self, $path) = @_;
3024         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3025 }
3026
3027 sub open_root {
3028         { path => '' };
3029 }
3030
3031 sub open_directory {
3032         my ($self, $path, $pb, $rev) = @_;
3033         { path => $path };
3034 }
3035
3036 sub git_path {
3037         my ($self, $path) = @_;
3038         if ($self->{path_strip}) {
3039                 $path =~ s!$self->{path_strip}!! or
3040                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3041         }
3042         $path;
3043 }
3044
3045 sub delete_entry {
3046         my ($self, $path, $rev, $pb) = @_;
3047
3048         my $gpath = $self->git_path($path);
3049         return undef if ($gpath eq '');
3050
3051         # remove entire directories.
3052         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3053                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3054                                                      -r --name-only -z/,
3055                                                      $self->{c}, '--', $gpath);
3056                 local $/ = "\0";
3057                 while (<$ls>) {
3058                         chomp;
3059                         $self->{gii}->remove($_);
3060                         print "\tD\t$_\n" unless $::_q;
3061                 }
3062                 print "\tD\t$gpath/\n" unless $::_q;
3063                 command_close_pipe($ls, $ctx);
3064                 $self->{empty}->{$path} = 0
3065         } else {
3066                 $self->{gii}->remove($gpath);
3067                 print "\tD\t$gpath\n" unless $::_q;
3068         }
3069         undef;
3070 }
3071
3072 sub open_file {
3073         my ($self, $path, $pb, $rev) = @_;
3074         my $gpath = $self->git_path($path);
3075         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3076                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3077         unless (defined $mode && defined $blob) {
3078                 die "$path was not found in commit $self->{c} (r$rev)\n";
3079         }
3080         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3081           pool => SVN::Pool->new, action => 'M' };
3082 }
3083
3084 sub add_file {
3085         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3086         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3087         delete $self->{empty}->{$dir};
3088         { path => $path, mode_a => 100644, mode_b => 100644,
3089           pool => SVN::Pool->new, action => 'A' };
3090 }
3091
3092 sub add_directory {
3093         my ($self, $path, $cp_path, $cp_rev) = @_;
3094         my $gpath = $self->git_path($path);
3095         if ($gpath eq '') {
3096                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3097                                                      -r --name-only -z/,
3098                                                      $self->{c});
3099                 local $/ = "\0";
3100                 while (<$ls>) {
3101                         chomp;
3102                         $self->{gii}->remove($_);
3103                         print "\tD\t$_\n" unless $::_q;
3104                 }
3105                 command_close_pipe($ls, $ctx);
3106                 $self->{empty}->{$path} = 0;
3107         }
3108         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3109         delete $self->{empty}->{$dir};
3110         $self->{empty}->{$path} = 1;
3111         { path => $path };
3112 }
3113
3114 sub change_dir_prop {
3115         my ($self, $db, $prop, $value) = @_;
3116         $self->{dir_prop}->{$db->{path}} ||= {};
3117         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3118         undef;
3119 }
3120
3121 sub absent_directory {
3122         my ($self, $path, $pb) = @_;
3123         $self->{absent_dir}->{$pb->{path}} ||= [];
3124         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3125         undef;
3126 }
3127
3128 sub absent_file {
3129         my ($self, $path, $pb) = @_;
3130         $self->{absent_file}->{$pb->{path}} ||= [];
3131         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3132         undef;
3133 }
3134
3135 sub change_file_prop {
3136         my ($self, $fb, $prop, $value) = @_;
3137         if ($prop eq 'svn:executable') {
3138                 if ($fb->{mode_b} != 120000) {
3139                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3140                 }
3141         } elsif ($prop eq 'svn:special') {
3142                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3143         } else {
3144                 $self->{file_prop}->{$fb->{path}} ||= {};
3145                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3146         }
3147         undef;
3148 }
3149
3150 sub apply_textdelta {
3151         my ($self, $fb, $exp) = @_;
3152         my $fh = IO::File->new_tmpfile;
3153         $fh->autoflush(1);
3154         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3155         # (but $base does not,) so dup() it for reading in close_file
3156         open my $dup, '<&', $fh or croak $!;
3157         my $base = IO::File->new_tmpfile;
3158         $base->autoflush(1);
3159         if ($fb->{blob}) {
3160                 defined (my $pid = fork) or croak $!;
3161                 if (!$pid) {
3162                         open STDOUT, '>&', $base or croak $!;
3163                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3164                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3165                 }
3166                 waitpid $pid, 0;
3167                 croak $? if $?;
3168
3169                 if (defined $exp) {
3170                         seek $base, 0, 0 or croak $!;
3171                         my $got = ::md5sum($base);
3172                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3173                             "expected: $exp\n",
3174                             "     got: $got\n" if ($got ne $exp);
3175                 }
3176         }
3177         seek $base, 0, 0 or croak $!;
3178         $fb->{fh} = $dup;
3179         $fb->{base} = $base;
3180         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3181 }
3182
3183 sub close_file {
3184         my ($self, $fb, $exp) = @_;
3185         my $hash;
3186         my $path = $self->git_path($fb->{path});
3187         if (my $fh = $fb->{fh}) {
3188                 if (defined $exp) {
3189                         seek($fh, 0, 0) or croak $!;
3190                         my $got = ::md5sum($fh);
3191                         if ($got ne $exp) {
3192                                 die "Checksum mismatch: $path\n",
3193                                     "expected: $exp\n    got: $got\n";
3194                         }
3195                 }
3196                 sysseek($fh, 0, 0) or croak $!;
3197                 if ($fb->{mode_b} == 120000) {
3198                         eval {
3199                                 sysread($fh, my $buf, 5) == 5 or croak $!;
3200                                 $buf eq 'link ' or die "$path has mode 120000",
3201                                                        " but is not a link";
3202                         };
3203                         if ($@) {
3204                                 warn "$@\n";
3205                                 sysseek($fh, 0, 0) or croak $!;
3206                         }
3207                 }
3208                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3209                 if (!$pid) {
3210                         open STDIN, '<&', $fh or croak $!;
3211                         exec qw/git-hash-object -w --stdin/ or croak $!;
3212                 }
3213                 chomp($hash = do { local $/; <$out> });
3214                 close $out or croak $!;
3215                 close $fh or croak $!;
3216                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3217                 close $fb->{base} or croak $!;
3218         } else {
3219                 $hash = $fb->{blob} or die "no blob information\n";
3220         }
3221         $fb->{pool}->clear;
3222         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3223         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3224         undef;
3225 }
3226
3227 sub abort_edit {
3228         my $self = shift;
3229         $self->{nr} = $self->{gii}->{nr};
3230         delete $self->{gii};
3231         $self->SUPER::abort_edit(@_);
3232 }
3233
3234 sub close_edit {
3235         my $self = shift;
3236         $self->{git_commit_ok} = 1;
3237         $self->{nr} = $self->{gii}->{nr};
3238         delete $self->{gii};
3239         $self->SUPER::close_edit(@_);
3240 }
3241
3242 package SVN::Git::Editor;
3243 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3244 use strict;
3245 use warnings;
3246 use Carp qw/croak/;
3247 use IO::File;
3248
3249 sub new {
3250         my ($class, $opts) = @_;
3251         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3252                 die "$_ required!\n" unless (defined $opts->{$_});
3253         }
3254
3255         my $pool = SVN::Pool->new;
3256         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3257         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3258                                      $opts->{r}, $mods);
3259
3260         # $opts->{ra} functions should not be used after this:
3261         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3262                                                 $opts->{editor_cb}, $pool);
3263         my $self = SVN::Delta::Editor->new(@ce, $pool);
3264         bless $self, $class;
3265         foreach (qw/svn_path r tree_a tree_b/) {
3266                 $self->{$_} = $opts->{$_};
3267         }
3268         $self->{url} = $opts->{ra}->{url};
3269         $self->{mods} = $mods;
3270         $self->{types} = $types;
3271         $self->{pool} = $pool;
3272         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3273         $self->{rm} = { };
3274         $self->{path_prefix} = length $self->{svn_path} ?
3275                                "$self->{svn_path}/" : '';
3276         return $self;
3277 }
3278
3279 sub generate_diff {
3280         my ($tree_a, $tree_b) = @_;
3281         my @diff_tree = qw(diff-tree -z -r);
3282         if ($_cp_similarity) {
3283                 push @diff_tree, "-C$_cp_similarity";
3284         } else {
3285                 push @diff_tree, '-C';
3286         }
3287         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3288         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3289         push @diff_tree, $tree_a, $tree_b;
3290         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3291         local $/ = "\0";
3292         my $state = 'meta';
3293         my @mods;
3294         while (<$diff_fh>) {
3295                 chomp $_; # this gets rid of the trailing "\0"
3296                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3297                                         $::sha1\s($::sha1)\s
3298                                         ([MTCRAD])\d*$/xo) {
3299                         push @mods, {   mode_a => $1, mode_b => $2,
3300                                         sha1_b => $3, chg => $4 };
3301                         if ($4 =~ /^(?:C|R)$/) {
3302                                 $state = 'file_a';
3303                         } else {
3304                                 $state = 'file_b';
3305                         }
3306                 } elsif ($state eq 'file_a') {
3307                         my $x = $mods[$#mods] or croak "Empty array\n";
3308                         if ($x->{chg} !~ /^(?:C|R)$/) {
3309                                 croak "Error parsing $_, $x->{chg}\n";
3310                         }
3311                         $x->{file_a} = $_;
3312                         $state = 'file_b';
3313                 } elsif ($state eq 'file_b') {
3314                         my $x = $mods[$#mods] or croak "Empty array\n";
3315                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3316                                 croak "Error parsing $_, $x->{chg}\n";
3317                         }
3318                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3319                                 croak "Error parsing $_, $x->{chg}\n";
3320                         }
3321                         $x->{file_b} = $_;
3322                         $state = 'meta';
3323                 } else {
3324                         croak "Error parsing $_\n";
3325                 }
3326         }
3327         command_close_pipe($diff_fh, $ctx);
3328         \@mods;
3329 }
3330
3331 sub check_diff_paths {
3332         my ($ra, $pfx, $rev, $mods) = @_;
3333         my %types;
3334         $pfx .= '/' if length $pfx;
3335
3336         sub type_diff_paths {
3337                 my ($ra, $types, $path, $rev) = @_;
3338                 my @p = split m#/+#, $path;
3339                 my $c = shift @p;
3340                 unless (defined $types->{$c}) {
3341                         $types->{$c} = $ra->check_path($c, $rev);
3342                 }
3343                 while (@p) {
3344                         $c .= '/' . shift @p;
3345                         next if defined $types->{$c};
3346                         $types->{$c} = $ra->check_path($c, $rev);
3347                 }
3348         }
3349
3350         foreach my $m (@$mods) {
3351                 foreach my $f (qw/file_a file_b/) {
3352                         next unless defined $m->{$f};
3353                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3354                         if (length $pfx.$dir && ! defined $types{$dir}) {
3355                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3356                         }
3357                 }
3358         }
3359         \%types;
3360 }
3361
3362 sub split_path {
3363         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3364 }
3365
3366 sub repo_path {
3367         my ($self, $path) = @_;
3368         $self->{path_prefix}.(defined $path ? $path : '');
3369 }
3370
3371 sub url_path {
3372         my ($self, $path) = @_;
3373         if ($self->{url} =~ m#^https?://#) {
3374                 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3375         }
3376         $self->{url} . '/' . $self->repo_path($path);
3377 }
3378
3379 sub rmdirs {
3380         my ($self) = @_;
3381         my $rm = $self->{rm};
3382         delete $rm->{''}; # we never delete the url we're tracking
3383         return unless %$rm;
3384
3385         foreach (keys %$rm) {
3386                 my @d = split m#/#, $_;
3387                 my $c = shift @d;
3388                 $rm->{$c} = 1;
3389                 while (@d) {
3390                         $c .= '/' . shift @d;
3391                         $rm->{$c} = 1;
3392                 }
3393         }
3394         delete $rm->{$self->{svn_path}};
3395         delete $rm->{''}; # we never delete the url we're tracking
3396         return unless %$rm;
3397
3398         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3399                                              $self->{tree_b});
3400         local $/ = "\0";
3401         while (<$fh>) {
3402                 chomp;
3403                 my @dn = split m#/#, $_;
3404                 while (pop @dn) {
3405                         delete $rm->{join '/', @dn};
3406                 }
3407                 unless (%$rm) {
3408                         close $fh;
3409                         return;
3410                 }
3411         }
3412         command_close_pipe($fh, $ctx);
3413
3414         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3415         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3416                 $self->close_directory($bat->{$d}, $p);
3417                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3418                 print "\tD+\t$d/\n" unless $::_q;
3419                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3420                 delete $bat->{$d};
3421         }
3422 }
3423
3424 sub open_or_add_dir {
3425         my ($self, $full_path, $baton) = @_;
3426         my $t = $self->{types}->{$full_path};
3427         if (!defined $t) {
3428                 die "$full_path not known in r$self->{r} or we have a bug!\n";
3429         }
3430         {
3431                 no warnings 'once';
3432                 # SVN::Node::none and SVN::Node::file are used only once,
3433                 # so we're shutting up Perl's warnings about them.
3434                 if ($t == $SVN::Node::none) {
3435                         return $self->add_directory($full_path, $baton,
3436                             undef, -1, $self->{pool});
3437                 } elsif ($t == $SVN::Node::dir) {
3438                         return $self->open_directory($full_path, $baton,
3439                             $self->{r}, $self->{pool});
3440                 } # no warnings 'once'
3441                 print STDERR "$full_path already exists in repository at ",
3442                     "r$self->{r} and it is not a directory (",
3443                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3444         } # no warnings 'once'
3445         exit 1;
3446 }
3447
3448 sub ensure_path {
3449         my ($self, $path) = @_;
3450         my $bat = $self->{bat};
3451         my $repo_path = $self->repo_path($path);
3452         return $bat->{''} unless (length $repo_path);
3453         my @p = split m#/+#, $repo_path;
3454         my $c = shift @p;
3455         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3456         while (@p) {
3457                 my $c0 = $c;
3458                 $c .= '/' . shift @p;
3459                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3460         }
3461         return $bat->{$c};
3462 }
3463
3464 sub A {
3465         my ($self, $m) = @_;
3466         my ($dir, $file) = split_path($m->{file_b});
3467         my $pbat = $self->ensure_path($dir);
3468         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3469                                         undef, -1);
3470         print "\tA\t$m->{file_b}\n" unless $::_q;
3471         $self->chg_file($fbat, $m);
3472         $self->close_file($fbat,undef,$self->{pool});
3473 }
3474
3475 sub C {
3476         my ($self, $m) = @_;
3477         my ($dir, $file) = split_path($m->{file_b});
3478         my $pbat = $self->ensure_path($dir);
3479         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3480                                 $self->url_path($m->{file_a}), $self->{r});
3481         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3482         $self->chg_file($fbat, $m);
3483         $self->close_file($fbat,undef,$self->{pool});
3484 }
3485
3486 sub delete_entry {
3487         my ($self, $path, $pbat) = @_;
3488         my $rpath = $self->repo_path($path);
3489         my ($dir, $file) = split_path($rpath);
3490         $self->{rm}->{$dir} = 1;
3491         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3492 }
3493
3494 sub R {
3495         my ($self, $m) = @_;
3496         my ($dir, $file) = split_path($m->{file_b});
3497         my $pbat = $self->ensure_path($dir);
3498         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3499                                 $self->url_path($m->{file_a}), $self->{r});
3500         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3501         $self->chg_file($fbat, $m);
3502         $self->close_file($fbat,undef,$self->{pool});
3503
3504         ($dir, $file) = split_path($m->{file_a});
3505         $pbat = $self->ensure_path($dir);
3506         $self->delete_entry($m->{file_a}, $pbat);
3507 }
3508
3509 sub M {
3510         my ($self, $m) = @_;
3511         my ($dir, $file) = split_path($m->{file_b});
3512         my $pbat = $self->ensure_path($dir);
3513         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3514                                 $pbat,$self->{r},$self->{pool});
3515         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3516         $self->chg_file($fbat, $m);
3517         $self->close_file($fbat,undef,$self->{pool});
3518 }
3519
3520 sub T { shift->M(@_) }
3521
3522 sub change_file_prop {
3523         my ($self, $fbat, $pname, $pval) = @_;
3524         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3525 }
3526
3527 sub chg_file {
3528         my ($self, $fbat, $m) = @_;
3529         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3530                 $self->change_file_prop($fbat,'svn:executable','*');
3531         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3532                 $self->change_file_prop($fbat,'svn:executable',undef);
3533         }
3534         my $fh = IO::File->new_tmpfile or croak $!;
3535         if ($m->{mode_b} =~ /^120/) {
3536                 print $fh 'link ' or croak $!;
3537                 $self->change_file_prop($fbat,'svn:special','*');
3538         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3539                 $self->change_file_prop($fbat,'svn:special',undef);
3540         }
3541         defined(my $pid = fork) or croak $!;
3542         if (!$pid) {
3543                 open STDOUT, '>&', $fh or croak $!;
3544                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3545         }
3546         waitpid $pid, 0;
3547         croak $? if $?;
3548         $fh->flush == 0 or croak $!;
3549         seek $fh, 0, 0 or croak $!;
3550
3551         my $exp = ::md5sum($fh);
3552         seek $fh, 0, 0 or croak $!;
3553
3554         my $pool = SVN::Pool->new;
3555         my $atd = $self->apply_textdelta($fbat, undef, $pool);
3556         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3557         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3558         $pool->clear;
3559
3560         close $fh or croak $!;
3561 }
3562
3563 sub D {
3564         my ($self, $m) = @_;
3565         my ($dir, $file) = split_path($m->{file_b});
3566         my $pbat = $self->ensure_path($dir);
3567         print "\tD\t$m->{file_b}\n" unless $::_q;
3568         $self->delete_entry($m->{file_b}, $pbat);
3569 }
3570
3571 sub close_edit {
3572         my ($self) = @_;
3573         my ($p,$bat) = ($self->{pool}, $self->{bat});
3574         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3575                 next if $_ eq '';
3576                 $self->close_directory($bat->{$_}, $p);
3577         }
3578         $self->close_directory($bat->{''}, $p);
3579         $self->SUPER::close_edit($p);
3580         $p->clear;
3581 }
3582
3583 sub abort_edit {
3584         my ($self) = @_;
3585         $self->SUPER::abort_edit($self->{pool});
3586 }
3587
3588 sub DESTROY {
3589         my $self = shift;
3590         $self->SUPER::DESTROY(@_);
3591         $self->{pool}->clear;
3592 }
3593
3594 # this drives the editor
3595 sub apply_diff {
3596         my ($self) = @_;
3597         my $mods = $self->{mods};
3598         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3599         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3600                 my $f = $m->{chg};
3601                 if (defined $o{$f}) {
3602                         $self->$f($m);
3603                 } else {
3604                         fatal("Invalid change type: $f");
3605                 }
3606         }
3607         $self->rmdirs if $_rmdir;
3608         if (@$mods == 0) {
3609                 $self->abort_edit;
3610         } else {
3611                 $self->close_edit;
3612         }
3613         return scalar @$mods;
3614 }
3615
3616 package Git::SVN::Ra;
3617 use vars qw/@ISA $config_dir $_log_window_size/;
3618 use strict;
3619 use warnings;
3620 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3621
3622 BEGIN {
3623         # enforce temporary pool usage for some simple functions
3624         no strict 'refs';
3625         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3626                 my $SUPER = "SUPER::$f";
3627                 *$f = sub {
3628                         my $self = shift;
3629                         my $pool = SVN::Pool->new;
3630                         my @ret = $self->$SUPER(@_,$pool);
3631                         $pool->clear;
3632                         wantarray ? @ret : $ret[0];
3633                 };
3634         }
3635 }
3636
3637 sub _auth_providers () {
3638         [
3639           SVN::Client::get_simple_provider(),
3640           SVN::Client::get_ssl_server_trust_file_provider(),
3641           SVN::Client::get_simple_prompt_provider(
3642             \&Git::SVN::Prompt::simple, 2),
3643           SVN::Client::get_ssl_client_cert_file_provider(),
3644           SVN::Client::get_ssl_client_cert_prompt_provider(
3645             \&Git::SVN::Prompt::ssl_client_cert, 2),
3646           SVN::Client::get_ssl_client_cert_pw_file_provider(),
3647           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3648             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3649           SVN::Client::get_username_provider(),
3650           SVN::Client::get_ssl_server_trust_prompt_provider(
3651             \&Git::SVN::Prompt::ssl_server_trust),
3652           SVN::Client::get_username_prompt_provider(
3653             \&Git::SVN::Prompt::username, 2)
3654         ]
3655 }
3656
3657 sub escape_uri_only {
3658         my ($uri) = @_;
3659         my @tmp;
3660         foreach (split m{/}, $uri) {
3661                 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3662                 push @tmp, $_;
3663         }
3664         join('/', @tmp);
3665 }
3666
3667 sub escape_url {
3668         my ($url) = @_;
3669         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3670                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3671                 $url = "$scheme://$domain$uri";
3672         }
3673         $url;
3674 }
3675
3676 sub new {
3677         my ($class, $url) = @_;
3678         $url =~ s!/+$!!;
3679         return $RA if ($RA && $RA->{url} eq $url);
3680
3681         SVN::_Core::svn_config_ensure($config_dir, undef);
3682         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3683         my $config = SVN::Core::config_get_config($config_dir);
3684         $RA = undef;
3685         my $dont_store_passwords = 1;
3686         my $conf_t = ${$config}{'config'};
3687         {
3688                 no warnings 'once';
3689                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3690                 # produces warnings that variables are used only once.
3691                 # I had not found the better way to shut them up, so
3692                 # the warnings of type 'once' are disabled in this block.
3693                 if (SVN::_Core::svn_config_get_bool($conf_t,
3694                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3695                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3696                     1) == 0) {
3697                         SVN::_Core::svn_auth_set_parameter($baton,
3698                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3699                             bless (\$dont_store_passwords, "_p_void"));
3700                 }
3701                 if (SVN::_Core::svn_config_get_bool($conf_t,
3702                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3703                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3704                     1) == 0) {
3705                         $Git::SVN::Prompt::_no_auth_cache = 1;
3706                 }
3707         } # no warnings 'once'
3708         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3709                               config => $config,
3710                               pool => SVN::Pool->new,
3711                               auth_provider_callbacks => $callbacks);
3712         $self->{url} = $url;
3713         $self->{svn_path} = $url;
3714         $self->{repos_root} = $self->get_repos_root;
3715         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3716         $self->{cache} = { check_path => { r => 0, data => {} },
3717                            get_dir => { r => 0, data => {} } };
3718         $RA = bless $self, $class;
3719 }
3720
3721 sub check_path {
3722         my ($self, $path, $r) = @_;
3723         my $cache = $self->{cache}->{check_path};
3724         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3725                 return $cache->{data}->{$path};
3726         }
3727         my $pool = SVN::Pool->new;
3728         my $t = $self->SUPER::check_path($path, $r, $pool);
3729         $pool->clear;
3730         if ($r != $cache->{r}) {
3731                 %{$cache->{data}} = ();
3732                 $cache->{r} = $r;
3733         }
3734         $cache->{data}->{$path} = $t;
3735 }
3736
3737 sub get_dir {
3738         my ($self, $dir, $r) = @_;
3739         my $cache = $self->{cache}->{get_dir};
3740         if ($r == $cache->{r}) {
3741                 if (my $x = $cache->{data}->{$dir}) {
3742                         return wantarray ? @$x : $x->[0];
3743                 }
3744         }
3745         my $pool = SVN::Pool->new;
3746         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3747         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3748         $pool->clear;
3749         if ($r != $cache->{r}) {
3750                 %{$cache->{data}} = ();
3751                 $cache->{r} = $r;
3752         }
3753         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3754         wantarray ? (\%dirents, $r, $props) : \%dirents;
3755 }
3756
3757 sub DESTROY {
3758         # do not call the real DESTROY since we store ourselves in $RA
3759 }
3760
3761 sub get_log {
3762         my ($self, @args) = @_;
3763         my $pool = SVN::Pool->new;
3764         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3765         my $ret = $self->SUPER::get_log(@args, $pool);
3766         $pool->clear;
3767         $ret;
3768 }
3769
3770 sub trees_match {
3771         my ($self, $url1, $rev1, $url2, $rev2) = @_;
3772         my $ctx = SVN::Client->new(auth => _auth_providers);
3773         my $out = IO::File->new_tmpfile;
3774
3775         # older SVN (1.1.x) doesn't take $pool as the last parameter for
3776         # $ctx->diff(), so we'll create a default one
3777         my $pool = SVN::Pool->new_default_sub;
3778
3779         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3780         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3781         $out->flush;
3782         my $ret = (($out->stat)[7] == 0);
3783         close $out or croak $!;
3784
3785         $ret;
3786 }
3787
3788 sub get_commit_editor {
3789         my ($self, $log, $cb, $pool) = @_;
3790         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3791         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3792 }
3793
3794 sub gs_do_update {
3795         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3796         my $new = ($rev_a == $rev_b);
3797         my $path = $gs->{path};
3798
3799         if ($new && -e $gs->{index}) {
3800                 unlink $gs->{index} or die
3801                   "Couldn't unlink index: $gs->{index}: $!\n";
3802         }
3803         my $pool = SVN::Pool->new;
3804         $editor->set_path_strip($path);
3805         my (@pc) = split m#/#, $path;
3806         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3807                                         1, $editor, $pool);
3808         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3809
3810         # Since we can't rely on svn_ra_reparent being available, we'll
3811         # just have to do some magic with set_path to make it so
3812         # we only want a partial path.
3813         my $sp = '';
3814         my $final = join('/', @pc);
3815         while (@pc) {
3816                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3817                 $sp .= '/' if length $sp;
3818                 $sp .= shift @pc;
3819         }
3820         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3821
3822         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3823
3824         $reporter->finish_report($pool);
3825         $pool->clear;
3826         $editor->{git_commit_ok};
3827 }
3828
3829 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3830 # svn_ra_reparent didn't work before 1.4)
3831 sub gs_do_switch {
3832         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3833         my $path = $gs->{path};
3834         my $pool = SVN::Pool->new;
3835
3836         my $full_url = $self->{url};
3837         my $old_url = $full_url;
3838         $full_url .= '/' . escape_uri_only($path) if length $path;
3839         my ($ra, $reparented);
3840         if ($old_url ne $full_url) {
3841                 if ($old_url !~ m#^svn(\+ssh)?://#) {
3842                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3843                                                   $pool);
3844                         $self->{url} = $full_url;
3845                         $reparented = 1;
3846                 } else {
3847                         $_[0] = undef;
3848                         $self = undef;
3849                         $RA = undef;
3850                         $ra = Git::SVN::Ra->new($full_url);
3851                         $ra_invalid = 1;
3852                 }
3853         }
3854         $ra ||= $self;
3855         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3856         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3857         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3858         $reporter->finish_report($pool);
3859
3860         if ($reparented) {
3861                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3862                 $self->{url} = $old_url;
3863         }
3864
3865         $pool->clear;
3866         $editor->{git_commit_ok};
3867 }
3868
3869 sub longest_common_path {
3870         my ($gsv, $globs) = @_;
3871         my %common;
3872         my $common_max = scalar @$gsv;
3873
3874         foreach my $gs (@$gsv) {
3875                 my @tmp = split m#/#, $gs->{path};
3876                 my $p = '';
3877                 foreach (@tmp) {
3878                         $p .= length($p) ? "/$_" : $_;
3879                         $common{$p} ||= 0;
3880                         $common{$p}++;
3881                 }
3882         }
3883         $globs ||= [];
3884         $common_max += scalar @$globs;
3885         foreach my $glob (@$globs) {
3886                 my @tmp = split m#/#, $glob->{path}->{left};
3887                 my $p = '';
3888                 foreach (@tmp) {
3889                         $p .= length($p) ? "/$_" : $_;
3890                         $common{$p} ||= 0;
3891                         $common{$p}++;
3892                 }
3893         }
3894
3895         my $longest_path = '';
3896         foreach (sort {length $b <=> length $a} keys %common) {
3897                 if ($common{$_} == $common_max) {
3898                         $longest_path = $_;
3899                         last;
3900                 }
3901         }
3902         $longest_path;
3903 }
3904
3905 sub gs_fetch_loop_common {
3906         my ($self, $base, $head, $gsv, $globs) = @_;
3907         return if ($base > $head);
3908         my $inc = $_log_window_size;
3909         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3910         my $longest_path = longest_common_path($gsv, $globs);
3911         my $ra_url = $self->{url};
3912         while (1) {
3913                 my %revs;
3914                 my $err;
3915                 my $err_handler = $SVN::Error::handler;
3916                 $SVN::Error::handler = sub {
3917                         ($err) = @_;
3918                         skip_unknown_revs($err);
3919                 };
3920                 sub _cb {
3921                         my ($paths, $r, $author, $date, $log) = @_;
3922                         [ dup_changed_paths($paths),
3923                           { author => $author, date => $date, log => $log } ];
3924                 }
3925                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3926                                sub { $revs{$_[1]} = _cb(@_) });
3927                 if ($err && $max >= $head) {
3928                         print STDERR "Path '$longest_path' ",
3929                                      "was probably deleted:\n",
3930                                      $err->expanded_message,
3931                                      "\nWill attempt to follow ",
3932                                      "revisions r$min .. r$max ",
3933                                      "committed before the deletion\n";
3934                         my $hi = $max;
3935                         while (--$hi >= $min) {
3936                                 my $ok;
3937                                 $self->get_log([$longest_path], $min, $hi,
3938                                                0, 1, 1, sub {
3939                                                $ok ||= $_[1];
3940                                                $revs{$_[1]} = _cb(@_) });
3941                                 if ($ok) {
3942                                         print STDERR "r$min .. r$ok OK\n";
3943                                         last;
3944                                 }
3945                         }
3946                 }
3947                 $SVN::Error::handler = $err_handler;
3948
3949                 my %exists = map { $_->{path} => $_ } @$gsv;
3950                 foreach my $r (sort {$a <=> $b} keys %revs) {
3951                         my ($paths, $logged) = @{$revs{$r}};
3952
3953                         foreach my $gs ($self->match_globs(\%exists, $paths,
3954                                                            $globs, $r)) {
3955                                 if ($gs->rev_map_max >= $r) {
3956                                         next;
3957                                 }
3958                                 next unless $gs->match_paths($paths, $r);
3959                                 $gs->{logged_rev_props} = $logged;
3960                                 if (my $last_commit = $gs->last_commit) {
3961                                         $gs->assert_index_clean($last_commit);
3962                                 }
3963                                 my $log_entry = $gs->do_fetch($paths, $r);
3964                                 if ($log_entry) {
3965                                         $gs->do_git_commit($log_entry);
3966                                 }
3967                                 $INDEX_FILES{$gs->{index}} = 1;
3968                         }
3969                         foreach my $g (@$globs) {
3970                                 my $k = "svn-remote.$g->{remote}." .
3971                                         "$g->{t}-maxRev";
3972                                 Git::SVN::tmp_config($k, $r);
3973                         }
3974                         if ($ra_invalid) {
3975                                 $_[0] = undef;
3976                                 $self = undef;
3977                                 $RA = undef;
3978                                 $self = Git::SVN::Ra->new($ra_url);
3979                                 $ra_invalid = undef;
3980                         }
3981                 }
3982                 # pre-fill the .rev_db since it'll eventually get filled in
3983                 # with '0' x40 if something new gets committed
3984                 foreach my $gs (@$gsv) {
3985                         next if $gs->rev_map_max >= $max;
3986                         next if defined $gs->rev_map_get($max);
3987                         $gs->rev_map_set($max, 0 x40);
3988                 }
3989                 foreach my $g (@$globs) {
3990                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3991                         Git::SVN::tmp_config($k, $max);
3992                 }
3993                 last if $max >= $head;
3994                 $min = $max + 1;
3995                 $max += $inc;
3996                 $max = $head if ($max > $head);
3997         }
3998         Git::SVN::gc();
3999 }
4000
4001 sub match_globs {
4002         my ($self, $exists, $paths, $globs, $r) = @_;
4003
4004         sub get_dir_check {
4005                 my ($self, $exists, $g, $r) = @_;
4006                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4007                 return unless scalar @x == 3;
4008                 my $dirents = $x[0];
4009                 foreach my $de (keys %$dirents) {
4010                         next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4011                         my $p = $g->{path}->full_path($de);
4012                         next if $exists->{$p};
4013                         next if (length $g->{path}->{right} &&
4014                                  ($self->check_path($p, $r) !=
4015                                   $SVN::Node::dir));
4016                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4017                                          $g->{ref}->full_path($de), 1);
4018                 }
4019         }
4020         foreach my $g (@$globs) {
4021                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4022                         if ($path->{action} =~ /^[AR]$/) {
4023                                 get_dir_check($self, $exists, $g, $r);
4024                         }
4025                 }
4026                 foreach (keys %$paths) {
4027                         if (/$g->{path}->{left_regex}/ &&
4028                             !/$g->{path}->{regex}/) {
4029                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4030                                 get_dir_check($self, $exists, $g, $r);
4031                         }
4032                         next unless /$g->{path}->{regex}/;
4033                         my $p = $1;
4034                         my $pathname = $g->{path}->full_path($p);
4035                         next if $exists->{$pathname};
4036                         next if ($self->check_path($pathname, $r) !=
4037                                  $SVN::Node::dir);
4038                         $exists->{$pathname} = Git::SVN->init(
4039                                               $self->{url}, $pathname, undef,
4040                                               $g->{ref}->full_path($p), 1);
4041                 }
4042                 my $c = '';
4043                 foreach (split m#/#, $g->{path}->{left}) {
4044                         $c .= "/$_";
4045                         next unless ($paths->{$c} &&
4046                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4047                         get_dir_check($self, $exists, $g, $r);
4048                 }
4049         }
4050         values %$exists;
4051 }
4052
4053 sub minimize_url {
4054         my ($self) = @_;
4055         return $self->{url} if ($self->{url} eq $self->{repos_root});
4056         my $url = $self->{repos_root};
4057         my @components = split(m!/!, $self->{svn_path});
4058         my $c = '';
4059         do {
4060                 $url .= "/$c" if length $c;
4061                 eval { (ref $self)->new($url)->get_latest_revnum };
4062         } while ($@ && ($c = shift @components));
4063         $url;
4064 }
4065
4066 sub can_do_switch {
4067         my $self = shift;
4068         unless (defined $can_do_switch) {
4069                 my $pool = SVN::Pool->new;
4070                 my $rep = eval {
4071                         $self->do_switch(1, '', 0, $self->{url},
4072                                          SVN::Delta::Editor->new, $pool);
4073                 };
4074                 if ($@) {
4075                         $can_do_switch = 0;
4076                 } else {
4077                         $rep->abort_report($pool);
4078                         $can_do_switch = 1;
4079                 }
4080                 $pool->clear;
4081         }
4082         $can_do_switch;
4083 }
4084
4085 sub skip_unknown_revs {
4086         my ($err) = @_;
4087         my $errno = $err->apr_err();
4088         # Maybe the branch we're tracking didn't
4089         # exist when the repo started, so it's
4090         # not an error if it doesn't, just continue
4091         #
4092         # Wonderfully consistent library, eh?
4093         # 160013 - svn:// and file://
4094         # 175002 - http(s)://
4095         # 175007 - http(s):// (this repo required authorization, too...)
4096         #   More codes may be discovered later...
4097         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4098                 my $err_key = $err->expanded_message;
4099                 # revision numbers change every time, filter them out
4100                 $err_key =~ s/\d+/\0/g;
4101                 $err_key = "$errno\0$err_key";
4102                 unless ($ignored_err{$err_key}) {
4103                         warn "W: Ignoring error from SVN, path probably ",
4104                              "does not exist: ($errno): ",
4105                              $err->expanded_message,"\n";
4106                         warn "W: Do not be alarmed at the above message ",
4107                              "git-svn is just searching aggressively for ",
4108                              "old history.\n",
4109                              "This may take a while on large repositories\n";
4110                         $ignored_err{$err_key} = 1;
4111                 }
4112                 return;
4113         }
4114         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4115 }
4116
4117 # svn_log_changed_path_t objects passed to get_log are likely to be
4118 # overwritten even if only the refs are copied to an external variable,
4119 # so we should dup the structures in their entirety.  Using an externally
4120 # passed pool (instead of our temporary and quickly cleared pool in
4121 # Git::SVN::Ra) does not help matters at all...
4122 sub dup_changed_paths {
4123         my ($paths) = @_;
4124         return undef unless $paths;
4125         my %ret;
4126         foreach my $p (keys %$paths) {
4127                 my $i = $paths->{$p};
4128                 my %s = map { $_ => $i->$_ }
4129                               qw/copyfrom_path copyfrom_rev action/;
4130                 $ret{$p} = \%s;
4131         }
4132         \%ret;
4133 }
4134
4135 package Git::SVN::Log;
4136 use strict;
4137 use warnings;
4138 use POSIX qw/strftime/;
4139 use constant commit_log_separator => ('-' x 72) . "\n";
4140 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4141             %rusers $show_commit $incremental/;
4142 my $l_fmt;
4143
4144 sub cmt_showable {
4145         my ($c) = @_;
4146         return 1 if defined $c->{r};
4147
4148         # big commit message got truncated by the 16k pretty buffer in rev-list
4149         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4150                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4151                 @{$c->{l}} = ();
4152                 my @log = command(qw/cat-file commit/, $c->{c});
4153
4154                 # shift off the headers
4155                 shift @log while ($log[0] ne '');
4156                 shift @log;
4157
4158                 # TODO: make $c->{l} not have a trailing newline in the future
4159                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4160
4161                 (undef, $c->{r}, undef) = ::extract_metadata(
4162                                 (grep(/^git-svn-id: /, @log))[-1]);
4163         }
4164         return defined $c->{r};
4165 }
4166
4167 sub log_use_color {
4168         return $color || Git->repository->get_colorbool('color.diff');
4169 }
4170
4171 sub git_svn_log_cmd {
4172         my ($r_min, $r_max, @args) = @_;
4173         my $head = 'HEAD';
4174         my (@files, @log_opts);
4175         foreach my $x (@args) {
4176                 if ($x eq '--' || @files) {
4177                         push @files, $x;
4178                 } else {
4179                         if (::verify_ref("$x^0")) {
4180                                 $head = $x;
4181                         } else {
4182                                 push @log_opts, $x;
4183                         }
4184                 }
4185         }
4186
4187         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4188         $gs ||= Git::SVN->_new;
4189         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4190                    $gs->refname);
4191         push @cmd, '-r' unless $non_recursive;
4192         push @cmd, qw/--raw --name-status/ if $verbose;
4193         push @cmd, '--color' if log_use_color();
4194         push @cmd, @log_opts;
4195         if (defined $r_max && $r_max == $r_min) {
4196                 push @cmd, '--max-count=1';
4197                 if (my $c = $gs->rev_map_get($r_max)) {
4198                         push @cmd, $c;
4199                 }
4200         } elsif (defined $r_max) {
4201                 if ($r_max < $r_min) {
4202                         ($r_min, $r_max) = ($r_max, $r_min);
4203                 }
4204                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4205                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4206                 # If there are no commits in the range, both $c_max and $c_min
4207                 # will be undefined.  If there is at least 1 commit in the
4208                 # range, both will be defined.
4209                 return () if !defined $c_min || !defined $c_max;
4210                 if ($c_min eq $c_max) {
4211                         push @cmd, '--max-count=1', $c_min;
4212                 } else {
4213                         push @cmd, '--boundary', "$c_min..$c_max";
4214                 }
4215         }
4216         return (@cmd, @files);
4217 }
4218
4219 # adapted from pager.c
4220 sub config_pager {
4221         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4222         if (!defined $pager) {
4223                 $pager = 'less';
4224         } elsif (length $pager == 0 || $pager eq 'cat') {
4225                 $pager = undef;
4226         }
4227         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4228 }
4229
4230 sub run_pager {
4231         return unless -t *STDOUT && defined $pager;
4232         pipe my $rfd, my $wfd or return;
4233         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4234         if (!$pid) {
4235                 open STDOUT, '>&', $wfd or
4236                                      ::fatal "Can't redirect to stdout: $!";
4237                 return;
4238         }
4239         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4240         $ENV{LESS} ||= 'FRSX';
4241         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4242 }
4243
4244 sub format_svn_date {
4245         return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4246 }
4247
4248 sub parse_git_date {
4249         my ($t, $tz) = @_;
4250         # Date::Parse isn't in the standard Perl distro :(
4251         if ($tz =~ s/^\+//) {
4252                 $t += tz_to_s_offset($tz);
4253         } elsif ($tz =~ s/^\-//) {
4254                 $t -= tz_to_s_offset($tz);
4255         }
4256         return $t;
4257 }
4258
4259 sub set_local_timezone {
4260         if (defined $TZ) {
4261                 $ENV{TZ} = $TZ;
4262         } else {
4263                 delete $ENV{TZ};
4264         }
4265 }
4266
4267 sub tz_to_s_offset {
4268         my ($tz) = @_;
4269         $tz =~ s/(\d\d)$//;
4270         return ($1 * 60) + ($tz * 3600);
4271 }
4272
4273 sub get_author_info {
4274         my ($dest, $author, $t, $tz) = @_;
4275         $author =~ s/(?:^\s*|\s*$)//g;
4276         $dest->{a_raw} = $author;
4277         my $au;
4278         if ($::_authors) {
4279                 $au = $rusers{$author} || undef;
4280         }
4281         if (!$au) {
4282                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4283         }
4284         $dest->{t} = $t;
4285         $dest->{tz} = $tz;
4286         $dest->{a} = $au;
4287         $dest->{t_utc} = parse_git_date($t, $tz);
4288 }
4289
4290 sub process_commit {
4291         my ($c, $r_min, $r_max, $defer) = @_;
4292         if (defined $r_min && defined $r_max) {
4293                 if ($r_min == $c->{r} && $r_min == $r_max) {
4294                         show_commit($c);
4295                         return 0;
4296                 }
4297                 return 1 if $r_min == $r_max;
4298                 if ($r_min < $r_max) {
4299                         # we need to reverse the print order
4300                         return 0 if (defined $limit && --$limit < 0);
4301                         push @$defer, $c;
4302                         return 1;
4303                 }
4304                 if ($r_min != $r_max) {
4305                         return 1 if ($r_min < $c->{r});
4306                         return 1 if ($r_max > $c->{r});
4307                 }
4308         }
4309         return 0 if (defined $limit && --$limit < 0);
4310         show_commit($c);
4311         return 1;
4312 }
4313
4314 sub show_commit {
4315         my $c = shift;
4316         if ($oneline) {
4317                 my $x = "\n";
4318                 if (my $l = $c->{l}) {
4319                         while ($l->[0] =~ /^\s*$/) { shift @$l }
4320                         $x = $l->[0];
4321                 }
4322                 $l_fmt ||= 'A' . length($c->{r});
4323                 print 'r',pack($l_fmt, $c->{r}),' | ';
4324                 print "$c->{c} | " if $show_commit;
4325                 print $x;
4326         } else {
4327                 show_commit_normal($c);
4328         }
4329 }
4330
4331 sub show_commit_changed_paths {
4332         my ($c) = @_;
4333         return unless $c->{changed};
4334         print "Changed paths:\n", @{$c->{changed}};
4335 }
4336
4337 sub show_commit_normal {
4338         my ($c) = @_;
4339         print commit_log_separator, "r$c->{r} | ";
4340         print "$c->{c} | " if $show_commit;
4341         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4342         my $nr_line = 0;
4343
4344         if (my $l = $c->{l}) {
4345                 while ($l->[$#$l] eq "\n" && $#$l > 0
4346                                           && $l->[($#$l - 1)] eq "\n") {
4347                         pop @$l;
4348                 }
4349                 $nr_line = scalar @$l;
4350                 if (!$nr_line) {
4351                         print "1 line\n\n\n";
4352                 } else {
4353                         if ($nr_line == 1) {
4354                                 $nr_line = '1 line';
4355                         } else {
4356                                 $nr_line .= ' lines';
4357                         }
4358                         print $nr_line, "\n";
4359                         show_commit_changed_paths($c);
4360                         print "\n";
4361                         print $_ foreach @$l;
4362                 }
4363         } else {
4364                 print "1 line\n";
4365                 show_commit_changed_paths($c);
4366                 print "\n";
4367
4368         }
4369         foreach my $x (qw/raw stat diff/) {
4370                 if ($c->{$x}) {
4371                         print "\n";
4372                         print $_ foreach @{$c->{$x}}
4373                 }
4374         }
4375 }
4376
4377 sub cmd_show_log {
4378         my (@args) = @_;
4379         my ($r_min, $r_max);
4380         my $r_last = -1; # prevent dupes
4381         set_local_timezone();
4382         if (defined $::_revision) {
4383                 if ($::_revision =~ /^(\d+):(\d+)$/) {
4384                         ($r_min, $r_max) = ($1, $2);
4385                 } elsif ($::_revision =~ /^\d+$/) {
4386                         $r_min = $r_max = $::_revision;
4387                 } else {
4388                         ::fatal "-r$::_revision is not supported, use ",
4389                                 "standard 'git log' arguments instead";
4390                 }
4391         }
4392
4393         config_pager();
4394         @args = git_svn_log_cmd($r_min, $r_max, @args);
4395         if (!@args) {
4396                 print commit_log_separator unless $incremental || $oneline;
4397                 return;
4398         }
4399         my $log = command_output_pipe(@args);
4400         run_pager();
4401         my (@k, $c, $d, $stat);
4402         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4403         while (<$log>) {
4404                 if (/^${esc_color}commit -?($::sha1_short)/o) {
4405                         my $cmt = $1;
4406                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4407                                 $r_last = $c->{r};
4408                                 process_commit($c, $r_min, $r_max, \@k) or
4409                                                                 goto out;
4410                         }
4411                         $d = undef;
4412                         $c = { c => $cmt };
4413                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4414                         get_author_info($c, $1, $2, $3);
4415                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4416                         # ignore
4417                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4418                         push @{$c->{raw}}, $_;
4419                 } elsif (/^${esc_color}[ACRMDT]\t/) {
4420                         # we could add $SVN->{svn_path} here, but that requires
4421                         # remote access at the moment (repo_path_split)...
4422                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4423                         push @{$c->{changed}}, $_;
4424                 } elsif (/^${esc_color}diff /o) {
4425                         $d = 1;
4426                         push @{$c->{diff}}, $_;
4427                 } elsif ($d) {
4428                         push @{$c->{diff}}, $_;
4429                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4430                           $esc_color*[\+\-]*$esc_color$/x) {
4431                         $stat = 1;
4432                         push @{$c->{stat}}, $_;
4433                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4434                         push @{$c->{stat}}, $_;
4435                         $stat = undef;
4436                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4437                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4438                 } elsif (s/^${esc_color}    //o) {
4439                         push @{$c->{l}}, $_;
4440                 }
4441         }
4442         if ($c && defined $c->{r} && $c->{r} != $r_last) {
4443                 $r_last = $c->{r};
4444                 process_commit($c, $r_min, $r_max, \@k);
4445         }
4446         if (@k) {
4447                 ($r_min, $r_max) = ($r_max, $r_min);
4448                 process_commit($_, $r_min, $r_max) foreach reverse @k;
4449         }
4450 out:
4451         close $log;
4452         print commit_log_separator unless $incremental || $oneline;
4453 }
4454
4455 sub cmd_blame {
4456         my $path = shift;
4457
4458         config_pager();
4459         run_pager();
4460
4461         my ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4462         while (my $line = <$fh>) {
4463                 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4464                         my (undef, $rev, undef) = ::cmt_metadata($1);
4465                         $rev = sprintf('%-10s', $rev);
4466                         $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4467                 }
4468                 print $line;
4469         }
4470         command_close_pipe($fh, $ctx);
4471 }
4472
4473 package Git::SVN::Migration;
4474 # these version numbers do NOT correspond to actual version numbers
4475 # of git nor git-svn.  They are just relative.
4476 #
4477 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4478 #
4479 # v1 layout: .git/$id/info/url, refs/remotes/$id
4480 #
4481 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4482 #
4483 # v3 layout: .git/svn/$id, refs/remotes/$id
4484 #            - info/url may remain for backwards compatibility
4485 #            - this is what we migrate up to this layout automatically,
4486 #            - this will be used by git svn init on single branches
4487 # v3.1 layout (auto migrated):
4488 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4489 #              for backwards compatibility
4490 #
4491 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4492 #            - this is only created for newly multi-init-ed
4493 #              repositories.  Similar in spirit to the
4494 #              --use-separate-remotes option in git-clone (now default)
4495 #            - we do not automatically migrate to this (following
4496 #              the example set by core git)
4497 #
4498 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4499 #            - newer, more-efficient format that uses 24-bytes per record
4500 #              with no filler space.
4501 #            - use xxd -c24 < .rev_map.$UUID to view and debug
4502 #            - This is a one-way migration, repositories updated to the
4503 #              new format will not be able to use old git-svn without
4504 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
4505 #              possible if noMetadata or useSvmProps are set; but should
4506 #              be no problem for users that use the (sensible) defaults.
4507 use strict;
4508 use warnings;
4509 use Carp qw/croak/;
4510 use File::Path qw/mkpath/;
4511 use File::Basename qw/dirname basename/;
4512 use vars qw/$_minimize/;
4513
4514 sub migrate_from_v0 {
4515         my $git_dir = $ENV{GIT_DIR};
4516         return undef unless -d $git_dir;
4517         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4518         my $migrated = 0;
4519         while (<$fh>) {
4520                 chomp;
4521                 my ($id, $orig_ref) = ($_, $_);
4522                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4523                 next unless -f "$git_dir/$id/info/url";
4524                 my $new_ref = "refs/remotes/$id";
4525                 if (::verify_ref("$new_ref^0")) {
4526                         print STDERR "W: $orig_ref is probably an old ",
4527                                      "branch used by an ancient version of ",
4528                                      "git-svn.\n",
4529                                      "However, $new_ref also exists.\n",
4530                                      "We will not be able ",
4531                                      "to use this branch until this ",
4532                                      "ambiguity is resolved.\n";
4533                         next;
4534                 }
4535                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4536                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4537                 command_noisy('update-ref', $new_ref, $orig_ref);
4538                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4539                 $migrated++;
4540         }
4541         command_close_pipe($fh, $ctx);
4542         print STDERR "Done migrating from v0 layout...\n" if $migrated;
4543         $migrated;
4544 }
4545
4546 sub migrate_from_v1 {
4547         my $git_dir = $ENV{GIT_DIR};
4548         my $migrated = 0;
4549         return $migrated unless -d $git_dir;
4550         my $svn_dir = "$git_dir/svn";
4551
4552         # just in case somebody used 'svn' as their $id at some point...
4553         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4554
4555         print STDERR "Migrating from a git-svn v1 layout...\n";
4556         mkpath([$svn_dir]);
4557         print STDERR "Data from a previous version of git-svn exists, but\n\t",
4558                      "$svn_dir\n\t(required for this version ",
4559                      "($::VERSION) of git-svn) does not. exist\n";
4560         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4561         while (<$fh>) {
4562                 my $x = $_;
4563                 next unless $x =~ s#^refs/remotes/##;
4564                 chomp $x;
4565                 next unless -f "$git_dir/$x/info/url";
4566                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4567                 next unless $u;
4568                 my $dn = dirname("$git_dir/svn/$x");
4569                 mkpath([$dn]) unless -d $dn;
4570                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4571                         mkpath(["$git_dir/svn/svn"]);
4572                         print STDERR " - $git_dir/$x/info => ",
4573                                         "$git_dir/svn/$x/info\n";
4574                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4575                                croak "$!: $x";
4576                         # don't worry too much about these, they probably
4577                         # don't exist with repos this old (save for index,
4578                         # and we can easily regenerate that)
4579                         foreach my $f (qw/unhandled.log index .rev_db/) {
4580                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4581                         }
4582                 } else {
4583                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4584                         rename "$git_dir/$x", "$git_dir/svn/$x" or
4585                                croak "$!: $x";
4586                 }
4587                 $migrated++;
4588         }
4589         command_close_pipe($fh, $ctx);
4590         print STDERR "Done migrating from a git-svn v1 layout\n";
4591         $migrated;
4592 }
4593
4594 sub read_old_urls {
4595         my ($l_map, $pfx, $path) = @_;
4596         my @dir;
4597         foreach (<$path/*>) {
4598                 if (-r "$_/info/url") {
4599                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4600                         my $ref_id = $pfx . basename $_;
4601                         my $url = ::file_to_s("$_/info/url");
4602                         $l_map->{$ref_id} = $url;
4603                 } elsif (-d $_) {
4604                         push @dir, $_;
4605                 }
4606         }
4607         foreach (@dir) {
4608                 my $x = $_;
4609                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4610                 read_old_urls($l_map, $x, $_);
4611         }
4612 }
4613
4614 sub migrate_from_v2 {
4615         my @cfg = command(qw/config -l/);
4616         return if grep /^svn-remote\..+\.url=/, @cfg;
4617         my %l_map;
4618         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4619         my $migrated = 0;
4620
4621         foreach my $ref_id (sort keys %l_map) {
4622                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4623                 if ($@) {
4624                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4625                 }
4626                 $migrated++;
4627         }
4628         $migrated;
4629 }
4630
4631 sub minimize_connections {
4632         my $r = Git::SVN::read_all_remotes();
4633         my $new_urls = {};
4634         my $root_repos = {};
4635         foreach my $repo_id (keys %$r) {
4636                 my $url = $r->{$repo_id}->{url} or next;
4637                 my $fetch = $r->{$repo_id}->{fetch} or next;
4638                 my $ra = Git::SVN::Ra->new($url);
4639
4640                 # skip existing cases where we already connect to the root
4641                 if (($ra->{url} eq $ra->{repos_root}) ||
4642                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4643                      $repo_id)) {
4644                         $root_repos->{$ra->{url}} = $repo_id;
4645                         next;
4646                 }
4647
4648                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4649                 my $root_path = $ra->{url};
4650                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4651                 foreach my $path (keys %$fetch) {
4652                         my $ref_id = $fetch->{$path};
4653                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4654
4655                         # make sure we can read when connecting to
4656                         # a higher level of a repository
4657                         my ($last_rev, undef) = $gs->last_rev_commit;
4658                         if (!defined $last_rev) {
4659                                 $last_rev = eval {
4660                                         $root_ra->get_latest_revnum;
4661                                 };
4662                                 next if $@;
4663                         }
4664                         my $new = $root_path;
4665                         $new .= length $path ? "/$path" : '';
4666                         eval {
4667                                 $root_ra->get_log([$new], $last_rev, $last_rev,
4668                                                   0, 0, 1, sub { });
4669                         };
4670                         next if $@;
4671                         $new_urls->{$ra->{repos_root}}->{$new} =
4672                                 { ref_id => $ref_id,
4673                                   old_repo_id => $repo_id,
4674                                   old_path => $path };
4675                 }
4676         }
4677
4678         my @emptied;
4679         foreach my $url (keys %$new_urls) {
4680                 # see if we can re-use an existing [svn-remote "repo_id"]
4681                 # instead of creating a(n ugly) new section:
4682                 my $repo_id = $root_repos->{$url} ||
4683                               Git::SVN::sanitize_remote_name($url);
4684
4685                 my $fetch = $new_urls->{$url};
4686                 foreach my $path (keys %$fetch) {
4687                         my $x = $fetch->{$path};
4688                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4689                         my $pfx = "svn-remote.$x->{old_repo_id}";
4690
4691                         my $old_fetch = quotemeta("$x->{old_path}:".
4692                                                   "refs/remotes/$x->{ref_id}");
4693                         command_noisy(qw/config --unset/,
4694                                       "$pfx.fetch", '^'. $old_fetch . '$');
4695                         delete $r->{$x->{old_repo_id}}->
4696                                {fetch}->{$x->{old_path}};
4697                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4698                                 command_noisy(qw/config --unset/,
4699                                               "$pfx.url");
4700                                 push @emptied, $x->{old_repo_id}
4701                         }
4702                 }
4703         }
4704         if (@emptied) {
4705                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4706                            "$ENV{GIT_DIR}/config";
4707                 print STDERR <<EOF;
4708 The following [svn-remote] sections in your config file ($file) are empty
4709 and can be safely removed:
4710 EOF
4711                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4712         }
4713 }
4714
4715 sub migration_check {
4716         migrate_from_v0();
4717         migrate_from_v1();
4718         migrate_from_v2();
4719         minimize_connections() if $_minimize;
4720 }
4721
4722 package Git::IndexInfo;
4723 use strict;
4724 use warnings;
4725 use Git qw/command_input_pipe command_close_pipe/;
4726
4727 sub new {
4728         my ($class) = @_;
4729         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4730         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4731 }
4732
4733 sub remove {
4734         my ($self, $path) = @_;
4735         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4736                 return ++$self->{nr};
4737         }
4738         undef;
4739 }
4740
4741 sub update {
4742         my ($self, $mode, $hash, $path) = @_;
4743         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4744                 return ++$self->{nr};
4745         }
4746         undef;
4747 }
4748
4749 sub DESTROY {
4750         my ($self) = @_;
4751         command_close_pipe($self->{gui}, $self->{ctx});
4752 }
4753
4754 package Git::SVN::GlobSpec;
4755 use strict;
4756 use warnings;
4757
4758 sub new {
4759         my ($class, $glob) = @_;
4760         my $re = $glob;
4761         $re =~ s!/+$!!g; # no need for trailing slashes
4762         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4763         my ($left, $right) = ($1, $2);
4764         if ($nr > 1) {
4765                 die "Only one '*' wildcard expansion ",
4766                     "is supported (got $nr): '$glob'\n";
4767         } elsif ($nr == 0) {
4768                 die "One '*' is needed for glob: '$glob'\n";
4769         }
4770         $re = quotemeta($left) . $re . quotemeta($right);
4771         if (length $left && !($left =~ s!/+$!!g)) {
4772                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4773         }
4774         if (length $right && !($right =~ s!^/+!!g)) {
4775                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4776         }
4777         my $left_re = qr/^\/\Q$left\E(\/|$)/;
4778         bless { left => $left, right => $right, left_regex => $left_re,
4779                 regex => qr/$re/, glob => $glob }, $class;
4780 }
4781
4782 sub full_path {
4783         my ($self, $path) = @_;
4784         return (length $self->{left} ? "$self->{left}/" : '') .
4785                $path . (length $self->{right} ? "/$self->{right}" : '');
4786 }
4787
4788 __END__
4789
4790 Data structures:
4791
4792
4793 $remotes = { # returned by read_all_remotes()
4794         'svn' => {
4795                 # svn-remote.svn.url=https://svn.musicpd.org
4796                 url => 'https://svn.musicpd.org',
4797                 # svn-remote.svn.fetch=mpd/trunk:trunk
4798                 fetch => {
4799                         'mpd/trunk' => 'trunk',
4800                 },
4801                 # svn-remote.svn.tags=mpd/tags/*:tags/*
4802                 tags => {
4803                         path => {
4804                                 left => 'mpd/tags',
4805                                 right => '',
4806                                 regex => qr!mpd/tags/([^/]+)$!,
4807                                 glob => 'tags/*',
4808                         },
4809                         ref => {
4810                                 left => 'tags',
4811                                 right => '',
4812                                 regex => qr!tags/([^/]+)$!,
4813                                 glob => 'tags/*',
4814                         },
4815                 }
4816         }
4817 };
4818
4819 $log_entry hashref as returned by libsvn_log_entry()
4820 {
4821         log => 'whitespace-formatted log entry
4822 ',                                              # trailing newline is preserved
4823         revision => '8',                        # integer
4824         date => '2004-02-24T17:01:44.108345Z',  # commit date
4825         author => 'committer name'
4826 };
4827
4828
4829 # this is generated by generate_diff();
4830 @mods = array of diff-index line hashes, each element represents one line
4831         of diff-index output
4832
4833 diff-index line ($m hash)
4834 {
4835         mode_a => first column of diff-index output, no leading ':',
4836         mode_b => second column of diff-index output,
4837         sha1_b => sha1sum of the final blob,
4838         chg => change type [MCRADT],
4839         file_a => original file name of a file (iff chg is 'C' or 'R')
4840         file_b => new/current file name of a file (any chg)
4841 }
4842 ;
4843
4844 # retval of read_url_paths{,_all}();
4845 $l_map = {
4846         # repository root url
4847         'https://svn.musicpd.org' => {
4848                 # repository path               # GIT_SVN_ID
4849                 'mpd/trunk'             =>      'trunk',
4850                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
4851         },
4852 }
4853
4854 Notes:
4855         I don't trust the each() function on unless I created %hash myself
4856         because the internal iterator may not have started at base.