git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22
  23 $Git::SVN::Log::TZ = $ENV{TZ};
  24 $ENV{TZ} = 'UTC';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use Digest::MD5;
  39 use IO::File qw//;
  40 use File::Basename qw/dirname basename/;
  41 use File::Path qw/mkpath/;
  42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  43 use IPC::Open3;
  44 use Git;
  45
  46 BEGIN {
  47         # import functions from Git into our packages, en masse
  48         no strict 'refs';
  49         foreach (qw/command command_oneline command_noisy command_output_pipe
  50                     command_input_pipe command_close_pipe/) {
  51                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  52                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  53                         __PACKAGE__) {
  54                         *{"${package}::$_"} = \&{"Git::$_"};
  55                 }
  56         }
  57 }
  58
  59 my ($SVN);
  60
  61 $sha1 = qr/[a-f\d]{40}/;
  62 $sha1_short = qr/[a-f\d]{4,40}/;
  63 my ($_stdin, $_help, $_edit,
  64         $_message, $_file,
  65         $_template, $_shared,
  66         $_version, $_fetch_all, $_no_rebase,
  67         $_merge, $_strategy, $_dry_run, $_local,
  68         $_prefix, $_no_checkout, $_url, $_verbose);
  69 $Git::SVN::_follow_parent = 1;
  70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  71                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  72                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  74                 'authors-file|A=s' => \$_authors,
  75                 'repack:i' => \$Git::SVN::_repack,
  76                 'noMetadata' => \$Git::SVN::_no_metadata,
  77                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  78                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  79                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  80                 'no-checkout' => \$_no_checkout,
  81                 'quiet|q' => \$_q,
  82                 'repack-flags|repack-args|repack-opts=s' =>
  83                    \$Git::SVN::_repack_flags,
  84                 'use-log-author' => \$Git::SVN::_use_log_author,
  85                 %remote_opts );
  86
  87 my ($_trunk, $_tags, $_branches, $_stdlayout);
  88 my %icv;
  89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  90                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  91                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  92                   'stdlayout|s' => \$_stdlayout,
  93                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  94                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  95                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  96                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  97                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  98                   %remote_opts );
  99 my %cmt_opts = ( 'edit|e' => \$_edit,
 100                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 101                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 102                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 103                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 104 );
 105
 106 my %cmd = (
 107         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 108                         { 'revision|r=s' => \$_revision,
 109                           'fetch-all|all' => \$_fetch_all,
 110                            %fc_opts } ],
 111         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 112                         { 'revision|r=s' => \$_revision,
 113                            %fc_opts, %init_opts } ],
 114         init => [ \&cmd_init, "Initialize a repo for tracking" .
 115                           " (requires URL argument)",
 116                           \%init_opts ],
 117         'multi-init' => [ \&cmd_multi_init,
 118                           "Deprecated alias for ".
 119                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 120                           \%init_opts ],
 121         dcommit => [ \&cmd_dcommit,
 122                      'Commit several diffs to merge with upstream',
 123                         { 'merge|m|M' => \$_merge,
 124                           'strategy|s=s' => \$_strategy,
 125                           'verbose|v' => \$_verbose,
 126                           'dry-run|n' => \$_dry_run,
 127                           'fetch-all|all' => \$_fetch_all,
 128                           'no-rebase' => \$_no_rebase,
 129                         %cmt_opts, %fc_opts } ],
 130         'set-tree' => [ \&cmd_set_tree,
 131                         "Set an SVN repository to a git tree-ish",
 132                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 133         'create-ignore' => [ \&cmd_create_ignore,
 134                              'Create a .gitignore per svn:ignore',
 135                              { 'revision|r=i' => \$_revision
 136                              } ],
 137         'propget' => [ \&cmd_propget,
 138                        'Print the value of a property on a file or directory',
 139                        { 'revision|r=i' => \$_revision } ],
 140         'proplist' => [ \&cmd_proplist,
 141                        'List all properties of a file or directory',
 142                        { 'revision|r=i' => \$_revision } ],
 143         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 144                         { 'revision|r=i' => \$_revision
 145                         } ],
 146         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 147                         { 'revision|r=i' => \$_revision
 148                         } ],
 149         'multi-fetch' => [ \&cmd_multi_fetch,
 150                            "Deprecated alias for $0 fetch --all",
 151                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 152         'migrate' => [ sub { },
 153                        # no-op, we automatically run this anyways,
 154                        'Migrate configuration/metadata/layout from
 155                         previous versions of git-svn',
 156                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 157                          %remote_opts } ],
 158         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 159                         { 'limit=i' => \$Git::SVN::Log::limit,
 160                           'revision|r=s' => \$_revision,
 161                           'verbose|v' => \$Git::SVN::Log::verbose,
 162                           'incremental' => \$Git::SVN::Log::incremental,
 163                           'oneline' => \$Git::SVN::Log::oneline,
 164                           'show-commit' => \$Git::SVN::Log::show_commit,
 165                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 166                           'authors-file|A=s' => \$_authors,
 167                           'color' => \$Git::SVN::Log::color,
 168                           'pager=s' => \$Git::SVN::Log::pager
 169                         } ],
 170         'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
 171                         {} ],
 172         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 173                         { 'merge|m|M' => \$_merge,
 174                           'verbose|v' => \$_verbose,
 175                           'strategy|s=s' => \$_strategy,
 176                           'local|l' => \$_local,
 177                           'fetch-all|all' => \$_fetch_all,
 178                           %fc_opts } ],
 179         'commit-diff' => [ \&cmd_commit_diff,
 180                            'Commit a diff between two trees',
 181                         { 'message|m=s' => \$_message,
 182                           'file|F=s' => \$_file,
 183                           'revision|r=s' => \$_revision,
 184                         %cmt_opts } ],
 185         'info' => [ \&cmd_info,
 186                     "Show info about the latest SVN revision
 187                      on the current branch",
 188                     { 'url' => \$_url, } ],
 189 );
 190
 191 my $cmd;
 192 for (my $i = 0; $i < @ARGV; $i++) {
 193         if (defined $cmd{$ARGV[$i]}) {
 194                 $cmd = $ARGV[$i];
 195                 splice @ARGV, $i, 1;
 196                 last;
 197         }
 198 };
 199
 200 # make sure we're always running
 201 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
 202         unless (-d $ENV{GIT_DIR}) {
 203                 if ($git_dir_user_set) {
 204                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 205                             "but it is not a directory\n";
 206                 }
 207                 my $git_dir = delete $ENV{GIT_DIR};
 208                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 209                 unless (length $cdup) {
 210                         die "Already at toplevel, but $git_dir ",
 211                             "not found '$cdup'\n";
 212                 }
 213                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 214                 unless (-d $git_dir) {
 215                         die "$git_dir still not found after going to ",
 216                             "'$cdup'\n";
 217                 }
 218                 $ENV{GIT_DIR} = $git_dir;
 219         }
 220 }
 221
 222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 223
 224 read_repo_config(\%opts);
 225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 227                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 228                     'id|i=s' => \$Git::SVN::default_ref_id,
 229                     'svn-remote|remote|R=s' => sub {
 230                        $Git::SVN::no_reuse_existing = 1;
 231                        $Git::SVN::default_repo_id = $_[1] });
 232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 233
 234 usage(0) if $_help;
 235 version() if $_version;
 236 usage(1) unless defined $cmd;
 237 load_authors() if $_authors;
 238
 239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 240         Git::SVN::Migration::migration_check();
 241 }
 242 Git::SVN::init_vars();
 243 eval {
 244         Git::SVN::verify_remotes_sanity();
 245         $cmd{$cmd}->[0]->(@ARGV);
 246 };
 247 fatal $@ if $@;
 248 post_fetch_checkout();
 249 exit 0;
 250
 251 ####################### primary functions ######################
 252 sub usage {
 253         my $exit = shift || 0;
 254         my $fd = $exit ? \*STDERR : \*STDOUT;
 255         print $fd <<"";
 256 git-svn - bidirectional operations between a single Subversion tree and git
 257 Usage: $0 <command> [options] [arguments]\n
 258
 259         print $fd "Available commands:\n" unless $cmd;
 260
 261         foreach (sort keys %cmd) {
 262                 next if $cmd && $cmd ne $_;
 263                 next if /^multi-/; # don't show deprecated commands
 264                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 265                 foreach (sort keys %{$cmd{$_}->[2]}) {
 266                         # mixed-case options are for .git/config only
 267                         next if /[A-Z]/ && /^[a-z]+$/i;
 268                         # prints out arguments as they should be passed:
 269                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 270                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 271                                                         "--$_" : "-$_" }
 272                                                 split /\|/,$_)," $x\n";
 273                 }
 274         }
 275         print $fd <<"";
 276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 278 one git repository and want to keep them separate.  See git-svn(1) for more
 279 information.
 280
 281         exit $exit;
 282 }
 283
 284 sub version {
 285         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 286         exit 0;
 287 }
 288
 289 sub do_git_init_db {
 290         unless (-d $ENV{GIT_DIR}) {
 291                 my @init_db = ('init');
 292                 push @init_db, "--template=$_template" if defined $_template;
 293                 if (defined $_shared) {
 294                         if ($_shared =~ /[a-z]/) {
 295                                 push @init_db, "--shared=$_shared";
 296                         } else {
 297                                 push @init_db, "--shared";
 298                         }
 299                 }
 300                 command_noisy(@init_db);
 301         }
 302         my $set;
 303         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 304         foreach my $i (keys %icv) {
 305                 die "'$set' and '$i' cannot both be set\n" if $set;
 306                 next unless defined $icv{$i};
 307                 command_noisy('config', "$pfx.$i", $icv{$i});
 308                 $set = $i;
 309         }
 310 }
 311
 312 sub init_subdir {
 313         my $repo_path = shift or return;
 314         mkpath([$repo_path]) unless -d $repo_path;
 315         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 316         $ENV{GIT_DIR} = '.git';
 317 }
 318
 319 sub cmd_clone {
 320         my ($url, $path) = @_;
 321         if (!defined $path &&
 322             (defined $_trunk || defined $_branches || defined $_tags ||
 323              defined $_stdlayout) &&
 324             $url !~ m#^[a-z\+]+://#) {
 325                 $path = $url;
 326         }
 327         $path = basename($url) if !defined $path || !length $path;
 328         cmd_init($url, $path);
 329         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 330 }
 331
 332 sub cmd_init {
 333         if (defined $_stdlayout) {
 334                 $_trunk = 'trunk' if (!defined $_trunk);
 335                 $_tags = 'tags' if (!defined $_tags);
 336                 $_branches = 'branches' if (!defined $_branches);
 337         }
 338         if (defined $_trunk || defined $_branches || defined $_tags) {
 339                 return cmd_multi_init(@_);
 340         }
 341         my $url = shift or die "SVN repository location required ",
 342                                "as a command-line argument\n";
 343         init_subdir(@_);
 344         do_git_init_db();
 345
 346         Git::SVN->init($url);
 347 }
 348
 349 sub cmd_fetch {
 350         if (grep /^\d+=./, @_) {
 351                 die "'<rev>=<commit>' fetch arguments are ",
 352                     "no longer supported.\n";
 353         }
 354         my ($remote) = @_;
 355         if (@_ > 1) {
 356                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 357         }
 358         $remote ||= $Git::SVN::default_repo_id;
 359         if ($_fetch_all) {
 360                 cmd_multi_fetch();
 361         } else {
 362                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 363         }
 364 }
 365
 366 sub cmd_set_tree {
 367         my (@commits) = @_;
 368         if ($_stdin || !@commits) {
 369                 print "Reading from stdin...\n";
 370                 @commits = ();
 371                 while (<STDIN>) {
 372                         if (/\b($sha1_short)\b/o) {
 373                                 unshift @commits, $1;
 374                         }
 375                 }
 376         }
 377         my @revs;
 378         foreach my $c (@commits) {
 379                 my @tmp = command('rev-parse',$c);
 380                 if (scalar @tmp == 1) {
 381                         push @revs, $tmp[0];
 382                 } elsif (scalar @tmp > 1) {
 383                         push @revs, reverse(command('rev-list',@tmp));
 384                 } else {
 385                         fatal "Failed to rev-parse $c";
 386                 }
 387         }
 388         my $gs = Git::SVN->new;
 389         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 390         $gs->fetch;
 391         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 392                 fatal "There are new revisions that were fetched ",
 393                       "and need to be merged (or acknowledged) ",
 394                       "before committing.\nlast rev: $r_last\n",
 395                       " current: $gs->{last_rev}";
 396         }
 397         $gs->set_tree($_) foreach @revs;
 398         print "Done committing ",scalar @revs," revisions to SVN\n";
 399         unlink $gs->{index};
 400 }
 401
 402 sub cmd_dcommit {
 403         my $head = shift;
 404         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 405                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 406                 . "or stash them with `git stash'.\n";
 407         $head ||= 'HEAD';
 408         my @refs;
 409         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 410         print "Committing to $url ...\n";
 411         unless ($gs) {
 412                 die "Unable to determine upstream SVN information from ",
 413                     "$head history\n";
 414         }
 415         my $last_rev;
 416         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 417         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 418                 warn "Attempting to commit more than one change while ",
 419                      "--no-rebase is enabled.\n",
 420                      "If these changes depend on each other, re-running ",
 421                      "without --no-rebase will be required."
 422         }
 423         while (1) {
 424                 my $d = shift @$linear_refs or last;
 425                 unless (defined $last_rev) {
 426                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 427                         unless (defined $last_rev) {
 428                                 fatal "Unable to extract revision information ",
 429                                       "from commit $d~1";
 430                         }
 431                 }
 432                 if ($_dry_run) {
 433                         print "diff-tree $d~1 $d\n";
 434                 } else {
 435                         my $cmt_rev;
 436                         my %ed_opts = ( r => $last_rev,
 437                                         log => get_commit_entry($d)->{log},
 438                                         ra => Git::SVN::Ra->new($gs->full_url),
 439                                         config => SVN::Core::config_get_config(
 440                                                 $Git::SVN::Ra::config_dir
 441                                         ),
 442                                         tree_a => "$d~1",
 443                                         tree_b => $d,
 444                                         editor_cb => sub {
 445                                                print "Committed r$_[0]\n";
 446                                                $cmt_rev = $_[0];
 447                                         },
 448                                         svn_path => '');
 449                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 450                                 print "No changes\n$d~1 == $d\n";
 451                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 452                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 453                                                                $parents->{$d};
 454                         }
 455                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 456                         next if $_no_rebase;
 457
 458                         # we always want to rebase against the current HEAD,
 459                         # not any head that was passed to us
 460                         my @diff = command('diff-tree', $d,
 461                                            $gs->refname, '--');
 462                         my @finish;
 463                         if (@diff) {
 464                                 @finish = rebase_cmd();
 465                                 print STDERR "W: $d and ", $gs->refname,
 466                                              " differ, using @finish:\n",
 467                                              join("\n", @diff), "\n";
 468                         } else {
 469                                 print "No changes between current HEAD and ",
 470                                       $gs->refname,
 471                                       "\nResetting to the latest ",
 472                                       $gs->refname, "\n";
 473                                 @finish = qw/reset --mixed/;
 474                         }
 475                         command_noisy(@finish, $gs->refname);
 476                         if (@diff) {
 477                                 @refs = ();
 478                                 my ($url_, $rev_, $uuid_, $gs_) =
 479                                               working_head_info($head, \@refs);
 480                                 my ($linear_refs_, $parents_) =
 481                                               linearize_history($gs_, \@refs);
 482                                 if (scalar(@$linear_refs) !=
 483                                     scalar(@$linear_refs_)) {
 484                                         fatal "# of revisions changed ",
 485                                           "\nbefore:\n",
 486                                           join("\n", @$linear_refs),
 487                                           "\n\nafter:\n",
 488                                           join("\n", @$linear_refs_), "\n",
 489                                           'If you are attempting to commit ',
 490                                           "merges, try running:\n\t",
 491                                           'git rebase --interactive',
 492                                           '--preserve-merges ',
 493                                           $gs->refname,
 494                                           "\nBefore dcommitting";
 495                                 }
 496                                 if ($url_ ne $url) {
 497                                         fatal "URL mismatch after rebase: ",
 498                                               "$url_ != $url";
 499                                 }
 500                                 if ($uuid_ ne $uuid) {
 501                                         fatal "uuid mismatch after rebase: ",
 502                                               "$uuid_ != $uuid";
 503                                 }
 504                                 # remap parents
 505                                 my (%p, @l, $i);
 506                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 507                                         my $new = $linear_refs_->[$i] or next;
 508                                         $p{$new} =
 509                                                 $parents->{$linear_refs->[$i]};
 510                                         push @l, $new;
 511                                 }
 512                                 $parents = \%p;
 513                                 $linear_refs = \@l;
 514                         }
 515                         $last_rev = $cmt_rev;
 516                 }
 517         }
 518         unlink $gs->{index};
 519 }
 520
 521 sub cmd_find_rev {
 522         my $revision_or_hash = shift;
 523         my $result;
 524         if ($revision_or_hash =~ /^r\d+$/) {
 525                 my $head = shift;
 526                 $head ||= 'HEAD';
 527                 my @refs;
 528                 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
 529                 unless ($gs) {
 530                         die "Unable to determine upstream SVN information from ",
 531                             "$head history\n";
 532                 }
 533                 my $desired_revision = substr($revision_or_hash, 1);
 534                 $result = $gs->rev_map_get($desired_revision);
 535         } else {
 536                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 537                 $result = $rev;
 538         }
 539         print "$result\n" if $result;
 540 }
 541
 542 sub cmd_rebase {
 543         command_noisy(qw/update-index --refresh/);
 544         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 545         unless ($gs) {
 546                 die "Unable to determine upstream SVN information from ",
 547                     "working tree history\n";
 548         }
 549         if (command(qw/diff-index HEAD --/)) {
 550                 print STDERR "Cannot rebase with uncommited changes:\n";
 551                 command_noisy('status');
 552                 exit 1;
 553         }
 554         unless ($_local) {
 555                 # rebase will checkout for us, so no need to do it explicitly
 556                 $_no_checkout = 'true';
 557                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 558         }
 559         command_noisy(rebase_cmd(), $gs->refname);
 560 }
 561
 562 sub cmd_show_ignore {
 563         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 564         $gs ||= Git::SVN->new;
 565         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 566         $gs->prop_walk($gs->{path}, $r, sub {
 567                 my ($gs, $path, $props) = @_;
 568                 print STDOUT "\n# $path\n";
 569                 my $s = $props->{'svn:ignore'} or return;
 570                 $s =~ s/[\r\n]+/\n/g;
 571                 chomp $s;
 572                 $s =~ s#^#$path#gm;
 573                 print STDOUT "$s\n";
 574         });
 575 }
 576
 577 sub cmd_show_externals {
 578         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 579         $gs ||= Git::SVN->new;
 580         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 581         $gs->prop_walk($gs->{path}, $r, sub {
 582                 my ($gs, $path, $props) = @_;
 583                 print STDOUT "\n# $path\n";
 584                 my $s = $props->{'svn:externals'} or return;
 585                 $s =~ s/[\r\n]+/\n/g;
 586                 chomp $s;
 587                 $s =~ s#^#$path#gm;
 588                 print STDOUT "$s\n";
 589         });
 590 }
 591
 592 sub cmd_create_ignore {
 593         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 594         $gs ||= Git::SVN->new;
 595         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 596         $gs->prop_walk($gs->{path}, $r, sub {
 597                 my ($gs, $path, $props) = @_;
 598                 # $path is of the form /path/to/dir/
 599                 my $ignore = '.' . $path . '.gitignore';
 600                 my $s = $props->{'svn:ignore'} or return;
 601                 open(GITIGNORE, '>', $ignore)
 602                   or fatal("Failed to open `$ignore' for writing: $!");
 603                 $s =~ s/[\r\n]+/\n/g;
 604                 chomp $s;
 605                 # Prefix all patterns so that the ignore doesn't apply
 606                 # to sub-directories.
 607                 $s =~ s#^#/#gm;
 608                 print GITIGNORE "$s\n";
 609                 close(GITIGNORE)
 610                   or fatal("Failed to close `$ignore': $!");
 611                 command_noisy('add', $ignore);
 612         });
 613 }
 614
 615 sub canonicalize_path {
 616         my ($path) = @_;
 617         my $dot_slash_added = 0;
 618         if (substr($path, 0, 1) ne "/") {
 619                 $path = "./" . $path;
 620                 $dot_slash_added = 1;
 621         }
 622         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 623         # good reason), so let's do this manually.
 624         $path =~ s#/+#/#g;
 625         $path =~ s#/\.(?:/|$)#/#g;
 626         $path =~ s#/[^/]+/\.\.##g;
 627         $path =~ s#/$##g;
 628         $path =~ s#^\./## if $dot_slash_added;
 629         return $path;
 630 }
 631
 632 # get_svnprops(PATH)
 633 # ------------------
 634 # Helper for cmd_propget and cmd_proplist below.
 635 sub get_svnprops {
 636         my $path = shift;
 637         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 638         $gs ||= Git::SVN->new;
 639
 640         # prefix THE PATH by the sub-directory from which the user
 641         # invoked us.
 642         $path = $cmd_dir_prefix . $path;
 643         fatal("No such file or directory: $path") unless -e $path;
 644         my $is_dir = -d $path ? 1 : 0;
 645         $path = $gs->{path} . '/' . $path;
 646
 647         # canonicalize the path (otherwise libsvn will abort or fail to
 648         # find the file)
 649         $path = canonicalize_path($path);
 650
 651         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 652         my $props;
 653         if ($is_dir) {
 654                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 655         }
 656         else {
 657                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 658         }
 659         return $props;
 660 }
 661
 662 # cmd_propget (PROP, PATH)
 663 # ------------------------
 664 # Print the SVN property PROP for PATH.
 665 sub cmd_propget {
 666         my ($prop, $path) = @_;
 667         $path = '.' if not defined $path;
 668         usage(1) if not defined $prop;
 669         my $props = get_svnprops($path);
 670         if (not defined $props->{$prop}) {
 671                 fatal("`$path' does not have a `$prop' SVN property.");
 672         }
 673         print $props->{$prop} . "\n";
 674 }
 675
 676 # cmd_proplist (PATH)
 677 # -------------------
 678 # Print the list of SVN properties for PATH.
 679 sub cmd_proplist {
 680         my $path = shift;
 681         $path = '.' if not defined $path;
 682         my $props = get_svnprops($path);
 683         print "Properties on '$path':\n";
 684         foreach (sort keys %{$props}) {
 685                 print "  $_\n";
 686         }
 687 }
 688
 689 sub cmd_multi_init {
 690         my $url = shift;
 691         unless (defined $_trunk || defined $_branches || defined $_tags) {
 692                 usage(1);
 693         }
 694
 695         # there are currently some bugs that prevent multi-init/multi-fetch
 696         # setups from working well without this.
 697         $Git::SVN::_minimize_url = 1;
 698
 699         $_prefix = '' unless defined $_prefix;
 700         if (defined $url) {
 701                 $url =~ s#/+$##;
 702                 init_subdir(@_);
 703         }
 704         do_git_init_db();
 705         if (defined $_trunk) {
 706                 my $trunk_ref = $_prefix . 'trunk';
 707                 # try both old-style and new-style lookups:
 708                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 709                 unless ($gs_trunk) {
 710                         my ($trunk_url, $trunk_path) =
 711                                               complete_svn_url($url, $_trunk);
 712                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 713                                                    undef, $trunk_ref);
 714                 }
 715         }
 716         return unless defined $_branches || defined $_tags;
 717         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 718         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 719         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 720 }
 721
 722 sub cmd_multi_fetch {
 723         my $remotes = Git::SVN::read_all_remotes();
 724         foreach my $repo_id (sort keys %$remotes) {
 725                 if ($remotes->{$repo_id}->{url}) {
 726                         Git::SVN::fetch_all($repo_id, $remotes);
 727                 }
 728         }
 729 }
 730
 731 # this command is special because it requires no metadata
 732 sub cmd_commit_diff {
 733         my ($ta, $tb, $url) = @_;
 734         my $usage = "Usage: $0 commit-diff -r<revision> ".
 735                     "<tree-ish> <tree-ish> [<URL>]";
 736         fatal($usage) if (!defined $ta || !defined $tb);
 737         my $svn_path;
 738         if (!defined $url) {
 739                 my $gs = eval { Git::SVN->new };
 740                 if (!$gs) {
 741                         fatal("Needed URL or usable git-svn --id in ",
 742                               "the command-line\n", $usage);
 743                 }
 744                 $url = $gs->{url};
 745                 $svn_path = $gs->{path};
 746         }
 747         unless (defined $_revision) {
 748                 fatal("-r|--revision is a required argument\n", $usage);
 749         }
 750         if (defined $_message && defined $_file) {
 751                 fatal("Both --message/-m and --file/-F specified ",
 752                       "for the commit message.\n",
 753                       "I have no idea what you mean");
 754         }
 755         if (defined $_file) {
 756                 $_message = file_to_s($_file);
 757         } else {
 758                 $_message ||= get_commit_entry($tb)->{log};
 759         }
 760         my $ra ||= Git::SVN::Ra->new($url);
 761         $svn_path ||= $ra->{svn_path};
 762         my $r = $_revision;
 763         if ($r eq 'HEAD') {
 764                 $r = $ra->get_latest_revnum;
 765         } elsif ($r !~ /^\d+$/) {
 766                 die "revision argument: $r not understood by git-svn\n";
 767         }
 768         my %ed_opts = ( r => $r,
 769                         log => $_message,
 770                         ra => $ra,
 771                         tree_a => $ta,
 772                         tree_b => $tb,
 773                         editor_cb => sub { print "Committed r$_[0]\n" },
 774                         svn_path => $svn_path );
 775         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 776                 print "No changes\n$ta == $tb\n";
 777         }
 778 }
 779
 780 sub cmd_info {
 781         my $path = canonicalize_path(shift or ".");
 782         unless (scalar(@_) == 0) {
 783                 die "Too many arguments specified\n";
 784         }
 785
 786         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
 787
 788         if (!$file_type && !$diff_status) {
 789                 print STDERR "$path:  (Not a versioned resource)\n\n";
 790                 return;
 791         }
 792
 793         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 794         unless ($gs) {
 795                 die "Unable to determine upstream SVN information from ",
 796                     "working tree history\n";
 797         }
 798         my $full_url = $url . ($path eq "." ? "" : "/$path");
 799
 800         if ($_url) {
 801                 print $full_url, "\n";
 802                 return;
 803         }
 804
 805         my $result = "Path: $path\n";
 806         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
 807         $result .= "URL: " . $full_url . "\n";
 808
 809         eval {
 810                 my $repos_root = $gs->repos_root;
 811                 Git::SVN::remove_username($repos_root);
 812                 $result .= "Repository Root: $repos_root\n";
 813         };
 814         if ($@) {
 815                 $result .= "Repository Root: (offline)\n";
 816         }
 817         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
 818         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
 819
 820         $result .= "Node Kind: " .
 821                    ($file_type eq "dir" ? "directory" : "file") . "\n";
 822
 823         my $schedule = $diff_status eq "A"
 824                        ? "add"
 825                        : ($diff_status eq "D" ? "delete" : "normal");
 826         $result .= "Schedule: $schedule\n";
 827
 828         if ($diff_status eq "A") {
 829                 print $result, "\n";
 830                 return;
 831         }
 832
 833         my ($lc_author, $lc_rev, $lc_date_utc);
 834         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
 835         my $log = command_output_pipe(@args);
 836         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
 837         while (<$log>) {
 838                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
 839                         $lc_author = $1;
 840                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
 841                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
 842                         (undef, $lc_rev, undef) = ::extract_metadata($1);
 843                 }
 844         }
 845         close $log;
 846
 847         Git::SVN::Log::set_local_timezone();
 848
 849         $result .= "Last Changed Author: $lc_author\n";
 850         $result .= "Last Changed Rev: $lc_rev\n";
 851         $result .= "Last Changed Date: " .
 852                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
 853
 854         if ($file_type ne "dir") {
 855                 my $text_last_updated_date =
 856                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
 857                 $result .=
 858                     "Text Last Updated: " .
 859                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
 860                     "\n";
 861                 my $checksum;
 862                 if ($diff_status eq "D") {
 863                         my ($fh, $ctx) =
 864                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
 865                         if ($file_type eq "link") {
 866                                 my $file_name = <$fh>;
 867                                 $checksum = md5sum("link $file_name");
 868                         } else {
 869                                 $checksum = md5sum($fh);
 870                         }
 871                         command_close_pipe($fh, $ctx);
 872                 } elsif ($file_type eq "link") {
 873                         my $file_name =
 874                             command(qw(cat-file blob), "HEAD:$path");
 875                         $checksum =
 876                             md5sum("link " . $file_name);
 877                 } else {
 878                         open FILE, "<", $path or die $!;
 879                         $checksum = md5sum(\*FILE);
 880                         close FILE or die $!;
 881                 }
 882                 $result .= "Checksum: " . $checksum . "\n";
 883         }
 884
 885         print $result, "\n";
 886 }
 887
 888 ########################### utility functions #########################
 889
 890 sub rebase_cmd {
 891         my @cmd = qw/rebase/;
 892         push @cmd, '-v' if $_verbose;
 893         push @cmd, qw/--merge/ if $_merge;
 894         push @cmd, "--strategy=$_strategy" if $_strategy;
 895         @cmd;
 896 }
 897
 898 sub post_fetch_checkout {
 899         return if $_no_checkout;
 900         my $gs = $Git::SVN::_head or return;
 901         return if verify_ref('refs/heads/master^0');
 902
 903         my $valid_head = verify_ref('HEAD^0');
 904         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 905         return if ($valid_head || !verify_ref('HEAD^0'));
 906
 907         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 908         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 909         return if -f $index;
 910
 911         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
 912         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 913         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 914         print STDERR "Checked out HEAD:\n  ",
 915                      $gs->full_url, " r", $gs->last_rev, "\n";
 916 }
 917
 918 sub complete_svn_url {
 919         my ($url, $path) = @_;
 920         $path =~ s#/+$##;
 921         if ($path !~ m#^[a-z\+]+://#) {
 922                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 923                         fatal("E: '$path' is not a complete URL ",
 924                               "and a separate URL is not specified");
 925                 }
 926                 return ($url, $path);
 927         }
 928         return ($path, '');
 929 }
 930
 931 sub complete_url_ls_init {
 932         my ($ra, $repo_path, $switch, $pfx) = @_;
 933         unless ($repo_path) {
 934                 print STDERR "W: $switch not specified\n";
 935                 return;
 936         }
 937         $repo_path =~ s#/+$##;
 938         if ($repo_path =~ m#^[a-z\+]+://#) {
 939                 $ra = Git::SVN::Ra->new($repo_path);
 940                 $repo_path = '';
 941         } else {
 942                 $repo_path =~ s#^/+##;
 943                 unless ($ra) {
 944                         fatal("E: '$repo_path' is not a complete URL ",
 945                               "and a separate URL is not specified");
 946                 }
 947         }
 948         my $url = $ra->{url};
 949         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 950         my $k = "svn-remote.$gs->{repo_id}.url";
 951         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 952         if ($orig_url && ($orig_url ne $gs->{url})) {
 953                 die "$k already set: $orig_url\n",
 954                     "wanted to set to: $gs->{url}\n";
 955         }
 956         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 957         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 958         $remote_path =~ s#/+#/#g;
 959         $remote_path =~ s#^/##g;
 960         my ($n) = ($switch =~ /^--(\w+)/);
 961         if (length $pfx && $pfx !~ m#/$#) {
 962                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 963         }
 964         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 965                                 "$remote_path:refs/remotes/$pfx*");
 966 }
 967
 968 sub verify_ref {
 969         my ($ref) = @_;
 970         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 971                                { STDERR => 0 }); };
 972 }
 973
 974 sub get_tree_from_treeish {
 975         my ($treeish) = @_;
 976         # $treeish can be a symbolic ref, too:
 977         my $type = command_oneline(qw/cat-file -t/, $treeish);
 978         my $expected;
 979         while ($type eq 'tag') {
 980                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 981         }
 982         if ($type eq 'commit') {
 983                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 984                                                     $treeish))[0];
 985                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 986                 die "Unable to get tree from $treeish\n" unless $expected;
 987         } elsif ($type eq 'tree') {
 988                 $expected = $treeish;
 989         } else {
 990                 die "$treeish is a $type, expected tree, tag or commit\n";
 991         }
 992         return $expected;
 993 }
 994
 995 sub get_commit_entry {
 996         my ($treeish) = shift;
 997         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 998         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 999         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000         open my $log_fh, '>', $commit_editmsg or croak $!;
1001
1002         my $type = command_oneline(qw/cat-file -t/, $treeish);
1003         if ($type eq 'commit' || $type eq 'tag') {
1004                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005                                                          $type, $treeish);
1006                 my $in_msg = 0;
1007                 while (<$msg_fh>) {
1008                         if (!$in_msg) {
1009                                 $in_msg = 1 if (/^\s*$/);
1010                         } elsif (/^git-svn-id: /) {
1011                                 # skip this for now, we regenerate the
1012                                 # correct one on re-fetch anyways
1013                                 # TODO: set *:merge properties or like...
1014                         } else {
1015                                 print $log_fh $_ or croak $!;
1016                         }
1017                 }
1018                 command_close_pipe($msg_fh, $ctx);
1019         }
1020         close $log_fh or croak $!;
1021
1022         if ($_edit || ($type eq 'tree')) {
1023                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024                 # TODO: strip out spaces, comments, like git-commit.sh
1025                 system($editor, $commit_editmsg);
1026         }
1027         rename $commit_editmsg, $commit_msg or croak $!;
1028         open $log_fh, '<', $commit_msg or croak $!;
1029         { local $/; chomp($log_entry{log} = <$log_fh>); }
1030         close $log_fh or croak $!;
1031         unlink $commit_msg;
1032         \%log_entry;
1033 }
1034
1035 sub s_to_file {
1036         my ($str, $file, $mode) = @_;
1037         open my $fd,'>',$file or croak $!;
1038         print $fd $str,"\n" or croak $!;
1039         close $fd or croak $!;
1040         chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1042
1043 sub file_to_s {
1044         my $file = shift;
1045         open my $fd,'<',$file or croak "$!: file: $file\n";
1046         local $/;
1047         my $ret = <$fd>;
1048         close $fd or croak $!;
1049         $ret =~ s/\s*$//s;
1050         return $ret;
1051 }
1052
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056         my $log = $cmd eq 'log';
1057         while (<$authors>) {
1058                 chomp;
1059                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060                 my ($user, $name, $email) = ($1, $2, $3);
1061                 if ($log) {
1062                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063                 } else {
1064                         $users{$user} = [$name, $email];
1065                 }
1066         }
1067         close $authors or croak $!;
1068 }
1069
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072         return unless -d $ENV{GIT_DIR};
1073         my $opts = shift;
1074         my @config_only;
1075         foreach my $o (keys %$opts) {
1076                 # if we have mixedCase and a long option-only, then
1077                 # it's a config-only variable that we don't need for
1078                 # the command-line.
1079                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080                 my $v = $opts->{$o};
1081                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082                 $key =~ s/-//g;
1083                 my $arg = 'git-config';
1084                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086                 if (ref $v eq 'ARRAY') {
1087                         chomp(my @tmp = `$arg --get-all svn.$key`);
1088                         @$v = @tmp if @tmp;
1089                 } else {
1090                         chomp(my $tmp = `$arg --get svn.$key`);
1091                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092                                 $$v = $tmp;
1093                         }
1094                 }
1095         }
1096         delete @$opts{@config_only} if @config_only;
1097 }
1098
1099 sub extract_metadata {
1100         my $id = shift or return (undef, undef, undef);
1101         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102                                                         \s([a-f\d\-]+)$/x);
1103         if (!defined $rev || !$uuid || !$url) {
1104                 # some of the original repositories I made had
1105                 # identifiers like this:
1106                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107         }
1108         return ($url, $rev, $uuid);
1109 }
1110
1111 sub cmt_metadata {
1112         return extract_metadata((grep(/^git-svn-id: /,
1113                 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1115
1116 sub working_head_info {
1117         my ($head, $refs) = @_;
1118         my @args = ('log', '--no-color', '--first-parent');
1119         my ($fh, $ctx) = command_output_pipe(@args, $head);
1120         my $hash;
1121         my %max;
1122         while (<$fh>) {
1123                 if ( m{^commit ($::sha1)$} ) {
1124                         unshift @$refs, $hash if $hash and $refs;
1125                         $hash = $1;
1126                         next;
1127                 }
1128                 next unless s{^\s*(git-svn-id:)}{$1};
1129                 my ($url, $rev, $uuid) = extract_metadata($_);
1130                 if (defined $url && defined $rev) {
1131                         next if $max{$url} and $max{$url} < $rev;
1132                         if (my $gs = Git::SVN->find_by_url($url)) {
1133                                 my $c = $gs->rev_map_get($rev);
1134                                 if ($c && $c eq $hash) {
1135                                         close $fh; # break the pipe
1136                                         return ($url, $rev, $uuid, $gs);
1137                                 } else {
1138                                         $max{$url} ||= $gs->rev_map_max;
1139                                 }
1140                         }
1141                 }
1142         }
1143         command_close_pipe($fh, $ctx);
1144         (undef, undef, undef, undef);
1145 }
1146
1147 sub read_commit_parents {
1148         my ($parents, $c) = @_;
1149         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151         @{$parents->{$c}} = split(/ /, $p);
1152 }
1153
1154 sub linearize_history {
1155         my ($gs, $refs) = @_;
1156         my %parents;
1157         foreach my $c (@$refs) {
1158                 read_commit_parents(\%parents, $c);
1159         }
1160
1161         my @linear_refs;
1162         my %skip = ();
1163         my $last_svn_commit = $gs->last_commit;
1164         foreach my $c (reverse @$refs) {
1165                 next if $c eq $last_svn_commit;
1166                 last if $skip{$c};
1167
1168                 unshift @linear_refs, $c;
1169                 $skip{$c} = 1;
1170
1171                 # we only want the first parent to diff against for linear
1172                 # history, we save the rest to inject when we finalize the
1173                 # svn commit
1174                 my $fp_a = verify_ref("$c~1");
1175                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176                 if (!$fp_a || !$fp_b) {
1177                         die "Commit $c\n",
1178                             "has no parent commit, and therefore ",
1179                             "nothing to diff against.\n",
1180                             "You should be working from a repository ",
1181                             "originally created by git-svn\n";
1182                 }
1183                 if ($fp_a ne $fp_b) {
1184                         die "$c~1 = $fp_a, however parsing commit $c ",
1185                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186                 }
1187
1188                 foreach my $p (@{$parents{$c}}) {
1189                         $skip{$p} = 1;
1190                 }
1191         }
1192         (\@linear_refs, \%parents);
1193 }
1194
1195 sub find_file_type_and_diff_status {
1196         my ($path) = @_;
1197         return ('dir', '') if $path eq '.';
1198
1199         my $diff_output =
1200             command_oneline(qw(diff --cached --name-status --), $path) || "";
1201         my $diff_status = (split(' ', $diff_output))[0] || "";
1202
1203         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1204
1205         return (undef, undef) if !$diff_status && !$ls_tree;
1206
1207         if ($diff_status eq "A") {
1208                 return ("link", $diff_status) if -l $path;
1209                 return ("dir", $diff_status) if -d $path;
1210                 return ("file", $diff_status);
1211         }
1212
1213         my $mode = (split(' ', $ls_tree))[0] || "";
1214
1215         return ("link", $diff_status) if $mode eq "120000";
1216         return ("dir", $diff_status) if $mode eq "040000";
1217         return ("file", $diff_status);
1218 }
1219
1220 sub md5sum {
1221         my $arg = shift;
1222         my $ref = ref $arg;
1223         my $md5 = Digest::MD5->new();
1224         if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225                 $md5->addfile($arg) or croak $!;
1226         } elsif ($ref eq 'SCALAR') {
1227                 $md5->add($$arg) or croak $!;
1228         } elsif (!$ref) {
1229                 $md5->add($arg) or croak $!;
1230         } else {
1231                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232         }
1233         return $md5->hexdigest();
1234 }
1235
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242             $_repack $_repack_flags $_use_svm_props $_head
1243             $_use_svnsync_props $no_reuse_existing $_minimize_url
1244             $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1249
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255                                         svn:special svn:executable
1256                                         svn:entry:committed-rev
1257                                         svn:entry:last-author
1258                                         svn:entry:uuid
1259                                         svn:entry:committed-date/;
1260
1261         # some options are read globally, but can be overridden locally
1262         # per [svn-remote "..."] section.  Command-line options will *NOT*
1263         # override options set in an [svn-remote "..."] section
1264         no strict 'refs';
1265         for my $option (qw/follow_parent no_metadata use_svm_props
1266                            use_svnsync_props/) {
1267                 my $key = $option;
1268                 $key =~ tr/_//d;
1269                 my $prop = "-$option";
1270                 *$option = sub {
1271                         my ($self) = @_;
1272                         return $self->{$prop} if exists $self->{$prop};
1273                         my $k = "svn-remote.$self->{repo_id}.$key";
1274                         eval { command_oneline(qw/config --get/, $k) };
1275                         if ($@) {
1276                                 $self->{$prop} = ${"Git::SVN::_$option"};
1277                         } else {
1278                                 my $v = command_oneline(qw/config --bool/,$k);
1279                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280                         }
1281                         return $self->{$prop};
1282                 }
1283         }
1284 }
1285
1286 my %LOCKFILES;
1287 END { unlink keys %LOCKFILES if %LOCKFILES }
1288
1289 sub resolve_local_globs {
1290         my ($url, $fetch, $glob_spec) = @_;
1291         return unless defined $glob_spec;
1292         my $ref = $glob_spec->{ref};
1293         my $path = $glob_spec->{path};
1294         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1295                 next unless m#^refs/remotes/$ref->{regex}$#;
1296                 my $p = $1;
1297                 my $pathname = desanitize_refname($path->full_path($p));
1298                 my $refname = desanitize_refname($ref->full_path($p));
1299                 if (my $existing = $fetch->{$pathname}) {
1300                         if ($existing ne $refname) {
1301                                 die "Refspec conflict:\n",
1302                                     "existing: refs/remotes/$existing\n",
1303                                     " globbed: refs/remotes/$refname\n";
1304                         }
1305                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1306                         $u =~ s!^\Q$url\E(/|$)!! or die
1307                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1308                         if ($pathname ne $u) {
1309                                 warn "W: Refspec glob conflict ",
1310                                      "(ref: refs/remotes/$refname):\n",
1311                                      "expected path: $pathname\n",
1312                                      "    real path: $u\n",
1313                                      "Continuing ahead with $u\n";
1314                                 next;
1315                         }
1316                 } else {
1317                         $fetch->{$pathname} = $refname;
1318                 }
1319         }
1320 }
1321
1322 sub parse_revision_argument {
1323         my ($base, $head) = @_;
1324         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1325                 return ($base, $head);
1326         }
1327         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1328         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1329         return ($head, $head) if ($::_revision eq 'HEAD');
1330         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1331         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1332         die "revision argument: $::_revision not understood by git-svn\n";
1333 }
1334
1335 sub fetch_all {
1336         my ($repo_id, $remotes) = @_;
1337         if (ref $repo_id) {
1338                 my $gs = $repo_id;
1339                 $repo_id = undef;
1340                 $repo_id = $gs->{repo_id};
1341         }
1342         $remotes ||= read_all_remotes();
1343         my $remote = $remotes->{$repo_id} or
1344                      die "[svn-remote \"$repo_id\"] unknown\n";
1345         my $fetch = $remote->{fetch};
1346         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1347         my (@gs, @globs);
1348         my $ra = Git::SVN::Ra->new($url);
1349         my $uuid = $ra->get_uuid;
1350         my $head = $ra->get_latest_revnum;
1351         my $base = defined $fetch ? $head : 0;
1352
1353         # read the max revs for wildcard expansion (branches/*, tags/*)
1354         foreach my $t (qw/branches tags/) {
1355                 defined $remote->{$t} or next;
1356                 push @globs, $remote->{$t};
1357                 my $max_rev = eval { tmp_config(qw/--int --get/,
1358                                          "svn-remote.$repo_id.${t}-maxRev") };
1359                 if (defined $max_rev && ($max_rev < $base)) {
1360                         $base = $max_rev;
1361                 } elsif (!defined $max_rev) {
1362                         $base = 0;
1363                 }
1364         }
1365
1366         if ($fetch) {
1367                 foreach my $p (sort keys %$fetch) {
1368                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1369                         my $lr = $gs->rev_map_max;
1370                         if (defined $lr) {
1371                                 $base = $lr if ($lr < $base);
1372                         }
1373                         push @gs, $gs;
1374                 }
1375         }
1376
1377         ($base, $head) = parse_revision_argument($base, $head);
1378         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1379         unlink $_->{index} foreach @gs;
1380 }
1381
1382 sub read_all_remotes {
1383         my $r = {};
1384         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1385                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1386                         my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1387                         $local_ref =~ s{^/}{};
1388                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1389                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1390                         $r->{$1}->{url} = $2;
1391                 } elsif (m!^(.+)\.(branches|tags)=
1392                            (.*):refs/remotes/(.+)\s*$/!x) {
1393                         my ($p, $g) = ($3, $4);
1394                         my $rs = $r->{$1}->{$2} = {
1395                                           t => $2,
1396                                           remote => $1,
1397                                           path => Git::SVN::GlobSpec->new($p),
1398                                           ref => Git::SVN::GlobSpec->new($g) };
1399                         if (length($rs->{ref}->{right}) != 0) {
1400                                 die "The '*' glob character must be the last ",
1401                                     "character of '$g'\n";
1402                         }
1403                 }
1404         }
1405         $r;
1406 }
1407
1408 sub init_vars {
1409         if (defined $_repack) {
1410                 $_repack = 1000 if ($_repack <= 0);
1411                 $_repack_nr = $_repack;
1412                 $_repack_flags ||= '-d';
1413         }
1414 }
1415
1416 sub verify_remotes_sanity {
1417         return unless -d $ENV{GIT_DIR};
1418         my %seen;
1419         foreach (command(qw/config -l/)) {
1420                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1421                         if ($seen{$1}) {
1422                                 die "Remote ref refs/remote/$1 is tracked by",
1423                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1424                                     "Please resolve this ambiguity in ",
1425                                     "your git configuration file before ",
1426                                     "continuing\n";
1427                         }
1428                         $seen{$1} = $_;
1429                 }
1430         }
1431 }
1432
1433 # we allow more chars than remotes2config.sh...
1434 sub sanitize_remote_name {
1435         my ($name) = @_;
1436         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1437         $name;
1438 }
1439
1440 sub find_existing_remote {
1441         my ($url, $remotes) = @_;
1442         return undef if $no_reuse_existing;
1443         my $existing;
1444         foreach my $repo_id (keys %$remotes) {
1445                 my $u = $remotes->{$repo_id}->{url} or next;
1446                 next if $u ne $url;
1447                 $existing = $repo_id;
1448                 last;
1449         }
1450         $existing;
1451 }
1452
1453 sub init_remote_config {
1454         my ($self, $url, $no_write) = @_;
1455         $url =~ s!/+$!!; # strip trailing slash
1456         my $r = read_all_remotes();
1457         my $existing = find_existing_remote($url, $r);
1458         if ($existing) {
1459                 unless ($no_write) {
1460                         print STDERR "Using existing ",
1461                                      "[svn-remote \"$existing\"]\n";
1462                 }
1463                 $self->{repo_id} = $existing;
1464         } elsif ($_minimize_url) {
1465                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1466                 $existing = find_existing_remote($min_url, $r);
1467                 if ($existing) {
1468                         unless ($no_write) {
1469                                 print STDERR "Using existing ",
1470                                              "[svn-remote \"$existing\"]\n";
1471                         }
1472                         $self->{repo_id} = $existing;
1473                 }
1474                 if ($min_url ne $url) {
1475                         unless ($no_write) {
1476                                 print STDERR "Using higher level of URL: ",
1477                                              "$url => $min_url\n";
1478                         }
1479                         my $old_path = $self->{path};
1480                         $self->{path} = $url;
1481                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1482                         if (length $old_path) {
1483                                 $self->{path} .= "/$old_path";
1484                         }
1485                         $url = $min_url;
1486                 }
1487         }
1488         my $orig_url;
1489         if (!$existing) {
1490                 # verify that we aren't overwriting anything:
1491                 $orig_url = eval {
1492                         command_oneline('config', '--get',
1493                                         "svn-remote.$self->{repo_id}.url")
1494                 };
1495                 if ($orig_url && ($orig_url ne $url)) {
1496                         die "svn-remote.$self->{repo_id}.url already set: ",
1497                             "$orig_url\nwanted to set to: $url\n";
1498                 }
1499         }
1500         my ($xrepo_id, $xpath) = find_ref($self->refname);
1501         if (defined $xpath) {
1502                 die "svn-remote.$xrepo_id.fetch already set to track ",
1503                     "$xpath:refs/remotes/", $self->refname, "\n";
1504         }
1505         unless ($no_write) {
1506                 command_noisy('config',
1507                               "svn-remote.$self->{repo_id}.url", $url);
1508                 $self->{path} =~ s{^/}{};
1509                 command_noisy('config', '--add',
1510                               "svn-remote.$self->{repo_id}.fetch",
1511                               "$self->{path}:".$self->refname);
1512         }
1513         $self->{url} = $url;
1514 }
1515
1516 sub find_by_url { # repos_root and, path are optional
1517         my ($class, $full_url, $repos_root, $path) = @_;
1518
1519         return undef unless defined $full_url;
1520         remove_username($full_url);
1521         remove_username($repos_root) if defined $repos_root;
1522         my $remotes = read_all_remotes();
1523         if (defined $full_url && defined $repos_root && !defined $path) {
1524                 $path = $full_url;
1525                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1526         }
1527         foreach my $repo_id (keys %$remotes) {
1528                 my $u = $remotes->{$repo_id}->{url} or next;
1529                 remove_username($u);
1530                 next if defined $repos_root && $repos_root ne $u;
1531
1532                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1533                 foreach (qw/branches tags/) {
1534                         resolve_local_globs($u, $fetch,
1535                                             $remotes->{$repo_id}->{$_});
1536                 }
1537                 my $p = $path;
1538                 unless (defined $p) {
1539                         $p = $full_url;
1540                         $p =~ s#^\Q$u\E(?:/|$)## or next;
1541                 }
1542                 foreach my $f (keys %$fetch) {
1543                         next if $f ne $p;
1544                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1545                 }
1546         }
1547         undef;
1548 }
1549
1550 sub init {
1551         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1552         my $self = _new($class, $repo_id, $ref_id, $path);
1553         if (defined $url) {
1554                 $self->init_remote_config($url, $no_write);
1555         }
1556         $self;
1557 }
1558
1559 sub find_ref {
1560         my ($ref_id) = @_;
1561         foreach (command(qw/config -l/)) {
1562                 next unless m!^svn-remote\.(.+)\.fetch=
1563                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1564                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1565                 if ($ref eq $ref_id) {
1566                         $path = '' if ($path =~ m#^\./?#);
1567                         return ($repo_id, $path);
1568                 }
1569         }
1570         (undef, undef, undef);
1571 }
1572
1573 sub new {
1574         my ($class, $ref_id, $repo_id, $path) = @_;
1575         if (defined $ref_id && !defined $repo_id && !defined $path) {
1576                 ($repo_id, $path) = find_ref($ref_id);
1577                 if (!defined $repo_id) {
1578                         die "Could not find a \"svn-remote.*.fetch\" key ",
1579                             "in the repository configuration matching: ",
1580                             "refs/remotes/$ref_id\n";
1581                 }
1582         }
1583         my $self = _new($class, $repo_id, $ref_id, $path);
1584         if (!defined $self->{path} || !length $self->{path}) {
1585                 my $fetch = command_oneline('config', '--get',
1586                                             "svn-remote.$repo_id.fetch",
1587                                             ":refs/remotes/$ref_id\$") or
1588                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1589                          "\":refs/remotes/$ref_id\$\" in config\n";
1590                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1591         }
1592         $self->{url} = command_oneline('config', '--get',
1593                                        "svn-remote.$repo_id.url") or
1594                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1595         $self->rebuild;
1596         $self;
1597 }
1598
1599 sub refname {
1600         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1601
1602         # It cannot end with a slash /, we'll throw up on this because
1603         # SVN can't have directories with a slash in their name, either:
1604         if ($refname =~ m{/$}) {
1605                 die "ref: '$refname' ends with a trailing slash, this is ",
1606                     "not permitted by git nor Subversion\n";
1607         }
1608
1609         # It cannot have ASCII control character space, tilde ~, caret ^,
1610         # colon :, question-mark ?, asterisk *, space, or open bracket [
1611         # anywhere.
1612         #
1613         # Additionally, % must be escaped because it is used for escaping
1614         # and we want our escaped refname to be reversible
1615         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1616
1617         # no slash-separated component can begin with a dot .
1618         # /.* becomes /%2E*
1619         $refname =~ s{/\.}{/%2E}g;
1620
1621         # It cannot have two consecutive dots .. anywhere
1622         # .. becomes %2E%2E
1623         $refname =~ s{\.\.}{%2E%2E}g;
1624
1625         return $refname;
1626 }
1627
1628 sub desanitize_refname {
1629         my ($refname) = @_;
1630         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1631         return $refname;
1632 }
1633
1634 sub svm_uuid {
1635         my ($self) = @_;
1636         return $self->{svm}->{uuid} if $self->svm;
1637         $self->ra;
1638         unless ($self->{svm}) {
1639                 die "SVM UUID not cached, and reading remotely failed\n";
1640         }
1641         $self->{svm}->{uuid};
1642 }
1643
1644 sub svm {
1645         my ($self) = @_;
1646         return $self->{svm} if $self->{svm};
1647         my $svm;
1648         # see if we have it in our config, first:
1649         eval {
1650                 my $section = "svn-remote.$self->{repo_id}";
1651                 $svm = {
1652                   source => tmp_config('--get', "$section.svm-source"),
1653                   uuid => tmp_config('--get', "$section.svm-uuid"),
1654                   replace => tmp_config('--get', "$section.svm-replace"),
1655                 }
1656         };
1657         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1658                 $self->{svm} = $svm;
1659         }
1660         $self->{svm};
1661 }
1662
1663 sub _set_svm_vars {
1664         my ($self, $ra) = @_;
1665         return $ra if $self->svm;
1666
1667         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1668                     "(svm:source, svm:uuid) ",
1669                     "from the following URLs:\n" );
1670         sub read_svm_props {
1671                 my ($self, $ra, $path, $r) = @_;
1672                 my $props = ($ra->get_dir($path, $r))[2];
1673                 my $src = $props->{'svm:source'};
1674                 my $uuid = $props->{'svm:uuid'};
1675                 return undef if (!$src || !$uuid);
1676
1677                 chomp($src, $uuid);
1678
1679                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1680                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1681
1682                 # the '!' is used to mark the repos_root!/relative/path
1683                 $src =~ s{/?!/?}{/};
1684                 $src =~ s{/+$}{}; # no trailing slashes please
1685                 # username is of no interest
1686                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1687
1688                 my $replace = $ra->{url};
1689                 $replace .= "/$path" if length $path;
1690
1691                 my $section = "svn-remote.$self->{repo_id}";
1692                 tmp_config("$section.svm-source", $src);
1693                 tmp_config("$section.svm-replace", $replace);
1694                 tmp_config("$section.svm-uuid", $uuid);
1695                 $self->{svm} = {
1696                         source => $src,
1697                         uuid => $uuid,
1698                         replace => $replace
1699                 };
1700         }
1701
1702         my $r = $ra->get_latest_revnum;
1703         my $path = $self->{path};
1704         my %tried;
1705         while (length $path) {
1706                 unless ($tried{"$self->{url}/$path"}) {
1707                         return $ra if $self->read_svm_props($ra, $path, $r);
1708                         $tried{"$self->{url}/$path"} = 1;
1709                 }
1710                 $path =~ s#/?[^/]+$##;
1711         }
1712         die "Path: '$path' should be ''\n" if $path ne '';
1713         return $ra if $self->read_svm_props($ra, $path, $r);
1714         $tried{"$self->{url}/$path"} = 1;
1715
1716         if ($ra->{repos_root} eq $self->{url}) {
1717                 die @err, (map { "  $_\n" } keys %tried), "\n";
1718         }
1719
1720         # nope, make sure we're connected to the repository root:
1721         my $ok;
1722         my @tried_b;
1723         $path = $ra->{svn_path};
1724         $ra = Git::SVN::Ra->new($ra->{repos_root});
1725         while (length $path) {
1726                 unless ($tried{"$ra->{url}/$path"}) {
1727                         $ok = $self->read_svm_props($ra, $path, $r);
1728                         last if $ok;
1729                         $tried{"$ra->{url}/$path"} = 1;
1730                 }
1731                 $path =~ s#/?[^/]+$##;
1732         }
1733         die "Path: '$path' should be ''\n" if $path ne '';
1734         $ok ||= $self->read_svm_props($ra, $path, $r);
1735         $tried{"$ra->{url}/$path"} = 1;
1736         if (!$ok) {
1737                 die @err, (map { "  $_\n" } keys %tried), "\n";
1738         }
1739         Git::SVN::Ra->new($self->{url});
1740 }
1741
1742 sub svnsync {
1743         my ($self) = @_;
1744         return $self->{svnsync} if $self->{svnsync};
1745
1746         if ($self->no_metadata) {
1747                 die "Can't have both 'noMetadata' and ",
1748                     "'useSvnsyncProps' options set!\n";
1749         }
1750         if ($self->rewrite_root) {
1751                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1752                     "options set!\n";
1753         }
1754
1755         my $svnsync;
1756         # see if we have it in our config, first:
1757         eval {
1758                 my $section = "svn-remote.$self->{repo_id}";
1759                 $svnsync = {
1760                   url => tmp_config('--get', "$section.svnsync-url"),
1761                   uuid => tmp_config('--get', "$section.svnsync-uuid"),
1762                 }
1763         };
1764         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1765                 return $self->{svnsync} = $svnsync;
1766         }
1767
1768         my $err = "useSvnsyncProps set, but failed to read " .
1769                   "svnsync property: svn:sync-from-";
1770         my $rp = $self->ra->rev_proplist(0);
1771
1772         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1773         $url =~ m{^[a-z\+]+://} or
1774                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1775
1776         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1777         $uuid =~ m{^[0-9a-f\-]{30,}$} or
1778                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1779
1780         my $section = "svn-remote.$self->{repo_id}";
1781         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1782         tmp_config('--add', "$section.svnsync-url", $url);
1783         return $self->{svnsync} = { url => $url, uuid => $uuid };
1784 }
1785
1786 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1787 # remote lookup (useful for 'git svn log').
1788 sub ra_uuid {
1789         my ($self) = @_;
1790         unless ($self->{ra_uuid}) {
1791                 my $key = "svn-remote.$self->{repo_id}.uuid";
1792                 my $uuid = eval { tmp_config('--get', $key) };
1793                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1794                         $self->{ra_uuid} = $uuid;
1795                 } else {
1796                         die "ra_uuid called without URL\n" unless $self->{url};
1797                         $self->{ra_uuid} = $self->ra->get_uuid;
1798                         tmp_config('--add', $key, $self->{ra_uuid});
1799                 }
1800         }
1801         $self->{ra_uuid};
1802 }
1803
1804 sub _set_repos_root {
1805         my ($self, $repos_root) = @_;
1806         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1807         $repos_root ||= $self->ra->{repos_root};
1808         tmp_config($k, $repos_root);
1809         $repos_root;
1810 }
1811
1812 sub repos_root {
1813         my ($self) = @_;
1814         my $k = "svn-remote.$self->{repo_id}.reposRoot";
1815         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1816 }
1817
1818 sub ra {
1819         my ($self) = shift;
1820         my $ra = Git::SVN::Ra->new($self->{url});
1821         $self->_set_repos_root($ra->{repos_root});
1822         if ($self->use_svm_props && !$self->{svm}) {
1823                 if ($self->no_metadata) {
1824                         die "Can't have both 'noMetadata' and ",
1825                             "'useSvmProps' options set!\n";
1826                 } elsif ($self->use_svnsync_props) {
1827                         die "Can't have both 'useSvnsyncProps' and ",
1828                             "'useSvmProps' options set!\n";
1829                 }
1830                 $ra = $self->_set_svm_vars($ra);
1831                 $self->{-want_revprops} = 1;
1832         }
1833         $ra;
1834 }
1835
1836 sub rel_path {
1837         my ($self) = @_;
1838         my $repos_root = $self->ra->{repos_root};
1839         return $self->{path} if ($self->{url} eq $repos_root);
1840         my $url = $self->{url} .
1841                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1842         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1843         $url;
1844 }
1845
1846 # prop_walk(PATH, REV, SUB)
1847 # -------------------------
1848 # Recursively traverse PATH at revision REV and invoke SUB for each
1849 # directory that contains a SVN property.  SUB will be invoked as
1850 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
1851 # Git::SVN, `path' the path to the directory where the properties
1852 # `props' were found.  The `path' will be relative to point of checkout,
1853 # that is, if url://repo/trunk is the current Git branch, and that
1854 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1855 # as `path' (note the trailing `/').
1856 sub prop_walk {
1857         my ($self, $path, $rev, $sub) = @_;
1858
1859         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1860         $path =~ s#^/*#/#g;
1861         my $p = $path;
1862         # Strip the irrelevant part of the path.
1863         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1864         # Ensure the path is terminated by a `/'.
1865         $p =~ s#/*$#/#;
1866
1867         # The properties contain all the internal SVN stuff nobody
1868         # (usually) cares about.
1869         my $interesting_props = 0;
1870         foreach (keys %{$props}) {
1871                 # If it doesn't start with `svn:', it must be a
1872                 # user-defined property.
1873                 ++$interesting_props and next if $_ !~ /^svn:/;
1874                 # FIXME: Fragile, if SVN adds new public properties,
1875                 # this needs to be updated.
1876                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1877                                                  |eol-style|mime-type
1878                                                  |externals|needs-lock)$/x;
1879         }
1880         &$sub($self, $p, $props) if $interesting_props;
1881
1882         foreach (sort keys %$dirent) {
1883                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1884                 $self->prop_walk($path . '/' . $_, $rev, $sub);
1885         }
1886 }
1887
1888 sub last_rev { ($_[0]->last_rev_commit)[0] }
1889 sub last_commit { ($_[0]->last_rev_commit)[1] }
1890
1891 # returns the newest SVN revision number and newest commit SHA1
1892 sub last_rev_commit {
1893         my ($self) = @_;
1894         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1895                 return ($self->{last_rev}, $self->{last_commit});
1896         }
1897         my $c = ::verify_ref($self->refname.'^0');
1898         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1899                 my $rev = (::cmt_metadata($c))[1];
1900                 if (defined $rev) {
1901                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1902                         return ($rev, $c);
1903                 }
1904         }
1905         my $map_path = $self->map_path;
1906         unless (-e $map_path) {
1907                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1908                 return (undef, undef);
1909         }
1910         my ($rev, $commit) = $self->rev_map_max(1);
1911         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1912         return ($rev, $commit);
1913 }
1914
1915 sub get_fetch_range {
1916         my ($self, $min, $max) = @_;
1917         $max ||= $self->ra->get_latest_revnum;
1918         $min ||= $self->rev_map_max;
1919         (++$min, $max);
1920 }
1921
1922 sub tmp_config {
1923         my (@args) = @_;
1924         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1925         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1926         if (! -f $config && -f $old_def_config) {
1927                 rename $old_def_config, $config or
1928                        die "Failed rename $old_def_config => $config: $!\n";
1929         }
1930         my $old_config = $ENV{GIT_CONFIG};
1931         $ENV{GIT_CONFIG} = $config;
1932         $@ = undef;
1933         my @ret = eval {
1934                 unless (-f $config) {
1935                         mkfile($config);
1936                         open my $fh, '>', $config or
1937                             die "Can't open $config: $!\n";
1938                         print $fh "; This file is used internally by ",
1939                                   "git-svn\n" or die
1940                                   "Couldn't write to $config: $!\n";
1941                         print $fh "; You should not have to edit it\n" or
1942                               die "Couldn't write to $config: $!\n";
1943                         close $fh or die "Couldn't close $config: $!\n";
1944                 }
1945                 command('config', @args);
1946         };
1947         my $err = $@;
1948         if (defined $old_config) {
1949                 $ENV{GIT_CONFIG} = $old_config;
1950         } else {
1951                 delete $ENV{GIT_CONFIG};
1952         }
1953         die $err if $err;
1954         wantarray ? @ret : $ret[0];
1955 }
1956
1957 sub tmp_index_do {
1958         my ($self, $sub) = @_;
1959         my $old_index = $ENV{GIT_INDEX_FILE};
1960         $ENV{GIT_INDEX_FILE} = $self->{index};
1961         $@ = undef;
1962         my @ret = eval {
1963                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1964                 mkpath([$dir]) unless -d $dir;
1965                 &$sub;
1966         };
1967         my $err = $@;
1968         if (defined $old_index) {
1969                 $ENV{GIT_INDEX_FILE} = $old_index;
1970         } else {
1971                 delete $ENV{GIT_INDEX_FILE};
1972         }
1973         die $err if $err;
1974         wantarray ? @ret : $ret[0];
1975 }
1976
1977 sub assert_index_clean {
1978         my ($self, $treeish) = @_;
1979
1980         $self->tmp_index_do(sub {
1981                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1982                 my $x = command_oneline('write-tree');
1983                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1984                            /^tree ($::sha1)/mo);
1985                 return if $y eq $x;
1986
1987                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1988                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1989                 command_noisy('read-tree', $treeish);
1990                 $x = command_oneline('write-tree');
1991                 if ($y ne $x) {
1992                         ::fatal "trees ($treeish) $y != $x\n",
1993                                 "Something is seriously wrong...";
1994                 }
1995         });
1996 }
1997
1998 sub get_commit_parents {
1999         my ($self, $log_entry) = @_;
2000         my (%seen, @ret, @tmp);
2001         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2002         if (my $ip = $self->{inject_parents}) {
2003                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2004                         push @tmp, $commit;
2005                 }
2006         }
2007         if (my $cur = ::verify_ref($self->refname.'^0')) {
2008                 push @tmp, $cur;
2009         }
2010         if (my $ipd = $self->{inject_parents_dcommit}) {
2011                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2012                         push @tmp, @$commit;
2013                 }
2014         }
2015         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2016         while (my $p = shift @tmp) {
2017                 next if $seen{$p};
2018                 $seen{$p} = 1;
2019                 push @ret, $p;
2020                 # MAXPARENT is defined to 16 in commit-tree.c:
2021                 last if @ret >= 16;
2022         }
2023         if (@tmp) {
2024                 die "r$log_entry->{revision}: No room for parents:\n\t",
2025                     join("\n\t", @tmp), "\n";
2026         }
2027         @ret;
2028 }
2029
2030 sub rewrite_root {
2031         my ($self) = @_;
2032         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2033         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2034         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2035         if ($rwr) {
2036                 $rwr =~ s#/+$##;
2037                 if ($rwr !~ m#^[a-z\+]+://#) {
2038                         die "$rwr is not a valid URL (key: $k)\n";
2039                 }
2040         }
2041         $self->{-rewrite_root} = $rwr;
2042 }
2043
2044 sub metadata_url {
2045         my ($self) = @_;
2046         ($self->rewrite_root || $self->{url}) .
2047            (length $self->{path} ? '/' . $self->{path} : '');
2048 }
2049
2050 sub full_url {
2051         my ($self) = @_;
2052         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2053 }
2054
2055
2056 sub set_commit_header_env {
2057         my ($log_entry) = @_;
2058         my %env;
2059         foreach my $ned (qw/NAME EMAIL DATE/) {
2060                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2061                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2062                 }
2063         }
2064
2065         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2066         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2067         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2068
2069         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2070                                                 ? $log_entry->{commit_name}
2071                                                 : $log_entry->{name};
2072         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2073                                                 ? $log_entry->{commit_email}
2074                                                 : $log_entry->{email};
2075         \%env;
2076 }
2077
2078 sub restore_commit_header_env {
2079         my ($env) = @_;
2080         foreach my $ned (qw/NAME EMAIL DATE/) {
2081                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2082                         my $k = "GIT_${ac}_${ned}";
2083                         if (defined $env->{$k}) {
2084                                 $ENV{$k} = $env->{$k};
2085                         } else {
2086                                 delete $ENV{$k};
2087                         }
2088                 }
2089         }
2090 }
2091
2092 sub do_git_commit {
2093         my ($self, $log_entry) = @_;
2094         my $lr = $self->last_rev;
2095         if (defined $lr && $lr >= $log_entry->{revision}) {
2096                 die "Last fetched revision of ", $self->refname,
2097                     " was r$lr, but we are about to fetch: ",
2098                     "r$log_entry->{revision}!\n";
2099         }
2100         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2101                 croak "$log_entry->{revision} = $c already exists! ",
2102                       "Why are we refetching it?\n";
2103         }
2104         my $old_env = set_commit_header_env($log_entry);
2105         my $tree = $log_entry->{tree};
2106         if (!defined $tree) {
2107                 $tree = $self->tmp_index_do(sub {
2108                                             command_oneline('write-tree') });
2109         }
2110         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2111
2112         my @exec = ('git-commit-tree', $tree);
2113         foreach ($self->get_commit_parents($log_entry)) {
2114                 push @exec, '-p', $_;
2115         }
2116         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2117                                                                    or croak $!;
2118         print $msg_fh $log_entry->{log} or croak $!;
2119         restore_commit_header_env($old_env);
2120         unless ($self->no_metadata) {
2121                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2122                               or croak $!;
2123         }
2124         $msg_fh->flush == 0 or croak $!;
2125         close $msg_fh or croak $!;
2126         chomp(my $commit = do { local $/; <$out_fh> });
2127         close $out_fh or croak $!;
2128         waitpid $pid, 0;
2129         croak $? if $?;
2130         if ($commit !~ /^$::sha1$/o) {
2131                 die "Failed to commit, invalid sha1: $commit\n";
2132         }
2133
2134         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2135
2136         $self->{last_rev} = $log_entry->{revision};
2137         $self->{last_commit} = $commit;
2138         print "r$log_entry->{revision}";
2139         if (defined $log_entry->{svm_revision}) {
2140                  print " (\@$log_entry->{svm_revision})";
2141                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2142                                    0, $self->svm_uuid);
2143         }
2144         print " = $commit ($self->{ref_id})\n";
2145         if (defined $_repack && (--$_repack_nr == 0)) {
2146                 $_repack_nr = $_repack;
2147                 # repack doesn't use any arguments with spaces in them, does it?
2148                 print "Running git repack $_repack_flags ...\n";
2149                 command_noisy('repack', split(/\s+/, $_repack_flags));
2150                 print "Done repacking\n";
2151         }
2152         return $commit;
2153 }
2154
2155 sub match_paths {
2156         my ($self, $paths, $r) = @_;
2157         return 1 if $self->{path} eq '';
2158         if (my $path = $paths->{"/$self->{path}"}) {
2159                 return ($path->{action} eq 'D') ? 0 : 1;
2160         }
2161         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2162         if (grep /$self->{path_regex}/, keys %$paths) {
2163                 return 1;
2164         }
2165         my $c = '';
2166         foreach (split m#/#, $self->{path}) {
2167                 $c .= "/$_";
2168                 next unless ($paths->{$c} &&
2169                              ($paths->{$c}->{action} =~ /^[AR]$/));
2170                 if ($self->ra->check_path($self->{path}, $r) ==
2171                     $SVN::Node::dir) {
2172                         return 1;
2173                 }
2174         }
2175         return 0;
2176 }
2177
2178 sub find_parent_branch {
2179         my ($self, $paths, $rev) = @_;
2180         return undef unless $self->follow_parent;
2181         unless (defined $paths) {
2182                 my $err_handler = $SVN::Error::handler;
2183                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2184                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2185                                    $paths =
2186                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
2187                 $SVN::Error::handler = $err_handler;
2188         }
2189         return undef unless defined $paths;
2190
2191         # look for a parent from another branch:
2192         my @b_path_components = split m#/#, $self->rel_path;
2193         my @a_path_components;
2194         my $i;
2195         while (@b_path_components) {
2196                 $i = $paths->{'/'.join('/', @b_path_components)};
2197                 last if $i && defined $i->{copyfrom_path};
2198                 unshift(@a_path_components, pop(@b_path_components));
2199         }
2200         return undef unless defined $i && defined $i->{copyfrom_path};
2201         my $branch_from = $i->{copyfrom_path};
2202         if (@a_path_components) {
2203                 print STDERR "branch_from: $branch_from => ";
2204                 $branch_from .= '/'.join('/', @a_path_components);
2205                 print STDERR $branch_from, "\n";
2206         }
2207         my $r = $i->{copyfrom_rev};
2208         my $repos_root = $self->ra->{repos_root};
2209         my $url = $self->ra->{url};
2210         my $new_url = $repos_root . $branch_from;
2211         print STDERR  "Found possible branch point: ",
2212                       "$new_url => ", $self->full_url, ", $r\n";
2213         $branch_from =~ s#^/##;
2214         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2215         unless ($gs) {
2216                 my $ref_id = $self->{ref_id};
2217                 $ref_id =~ s/\@\d+$//;
2218                 $ref_id .= "\@$r";
2219                 # just grow a tail if we're not unique enough :x
2220                 $ref_id .= '-' while find_ref($ref_id);
2221                 print STDERR "Initializing parent: $ref_id\n";
2222                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2223         }
2224         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2225         if (!defined $r0 || !defined $parent) {
2226                 my ($base, $head) = parse_revision_argument(0, $r);
2227                 if ($base <= $r) {
2228                         $gs->fetch($base, $r);
2229                 }
2230                 ($r0, $parent) = $gs->last_rev_commit;
2231         }
2232         if (defined $r0 && defined $parent) {
2233                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2234                 my $ed;
2235                 if ($self->ra->can_do_switch) {
2236                         $self->assert_index_clean($parent);
2237                         print STDERR "Following parent with do_switch\n";
2238                         # do_switch works with svn/trunk >= r22312, but that
2239                         # is not included with SVN 1.4.3 (the latest version
2240                         # at the moment), so we can't rely on it
2241                         $self->{last_commit} = $parent;
2242                         $ed = SVN::Git::Fetcher->new($self);
2243                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2244                                               $self->full_url, $ed)
2245                           or die "SVN connection failed somewhere...\n";
2246                 } elsif ($self->ra->trees_match($new_url, $r0,
2247                                                 $self->full_url, $rev)) {
2248                         print STDERR "Trees match:\n",
2249                                      "  $new_url\@$r0\n",
2250                                      "  ${\$self->full_url}\@$rev\n",
2251                                      "Following parent with no changes\n";
2252                         $self->tmp_index_do(sub {
2253                             command_noisy('read-tree', $parent);
2254                         });
2255                         $self->{last_commit} = $parent;
2256                 } else {
2257                         print STDERR "Following parent with do_update\n";
2258                         $ed = SVN::Git::Fetcher->new($self);
2259                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2260                           or die "SVN connection failed somewhere...\n";
2261                 }
2262                 print STDERR "Successfully followed parent\n";
2263                 return $self->make_log_entry($rev, [$parent], $ed);
2264         }
2265         return undef;
2266 }
2267
2268 sub do_fetch {
2269         my ($self, $paths, $rev) = @_;
2270         my $ed;
2271         my ($last_rev, @parents);
2272         if (my $lc = $self->last_commit) {
2273                 # we can have a branch that was deleted, then re-added
2274                 # under the same name but copied from another path, in
2275                 # which case we'll have multiple parents (we don't
2276                 # want to break the original ref, nor lose copypath info):
2277                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2278                         push @{$log_entry->{parents}}, $lc;
2279                         return $log_entry;
2280                 }
2281                 $ed = SVN::Git::Fetcher->new($self);
2282                 $last_rev = $self->{last_rev};
2283                 $ed->{c} = $lc;
2284                 @parents = ($lc);
2285         } else {
2286                 $last_rev = $rev;
2287                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2288                         return $log_entry;
2289                 }
2290                 $ed = SVN::Git::Fetcher->new($self);
2291         }
2292         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2293                 die "SVN connection failed somewhere...\n";
2294         }
2295         $self->make_log_entry($rev, \@parents, $ed);
2296 }
2297
2298 sub get_untracked {
2299         my ($self, $ed) = @_;
2300         my @out;
2301         my $h = $ed->{empty};
2302         foreach (sort keys %$h) {
2303                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2304                 push @out, "  $act: " . uri_encode($_);
2305                 warn "W: $act: $_\n";
2306         }
2307         foreach my $t (qw/dir_prop file_prop/) {
2308                 $h = $ed->{$t} or next;
2309                 foreach my $path (sort keys %$h) {
2310                         my $ppath = $path eq '' ? '.' : $path;
2311                         foreach my $prop (sort keys %{$h->{$path}}) {
2312                                 next if $SKIP_PROP{$prop};
2313                                 my $v = $h->{$path}->{$prop};
2314                                 my $t_ppath_prop = "$t: " .
2315                                                     uri_encode($ppath) . ' ' .
2316                                                     uri_encode($prop);
2317                                 if (defined $v) {
2318                                         push @out, "  +$t_ppath_prop " .
2319                                                    uri_encode($v);
2320                                 } else {
2321                                         push @out, "  -$t_ppath_prop";
2322                                 }
2323                         }
2324                 }
2325         }
2326         foreach my $t (qw/absent_file absent_directory/) {
2327                 $h = $ed->{$t} or next;
2328                 foreach my $parent (sort keys %$h) {
2329                         foreach my $path (sort @{$h->{$parent}}) {
2330                                 push @out, "  $t: " .
2331                                            uri_encode("$parent/$path");
2332                                 warn "W: $t: $parent/$path ",
2333                                      "Insufficient permissions?\n";
2334                         }
2335                 }
2336         }
2337         \@out;
2338 }
2339
2340 sub parse_svn_date {
2341         my $date = shift || return '+0000 1970-01-01 00:00:00';
2342         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2343                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2344                                          croak "Unable to parse date: $date\n";
2345         "+0000 $Y-$m-$d $H:$M:$S";
2346 }
2347
2348 sub check_author {
2349         my ($author) = @_;
2350         if (!defined $author || length $author == 0) {
2351                 $author = '(no author)';
2352         }
2353         if (defined $::_authors && ! defined $::users{$author}) {
2354                 die "Author: $author not defined in $::_authors file\n";
2355         }
2356         $author;
2357 }
2358
2359 sub make_log_entry {
2360         my ($self, $rev, $parents, $ed) = @_;
2361         my $untracked = $self->get_untracked($ed);
2362
2363         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2364         print $un "r$rev\n" or croak $!;
2365         print $un $_, "\n" foreach @$untracked;
2366         my %log_entry = ( parents => $parents || [], revision => $rev,
2367                           log => '');
2368
2369         my $headrev;
2370         my $logged = delete $self->{logged_rev_props};
2371         if (!$logged || $self->{-want_revprops}) {
2372                 my $rp = $self->ra->rev_proplist($rev);
2373                 foreach (sort keys %$rp) {
2374                         my $v = $rp->{$_};
2375                         if (/^svn:(author|date|log)$/) {
2376                                 $log_entry{$1} = $v;
2377                         } elsif ($_ eq 'svm:headrev') {
2378                                 $headrev = $v;
2379                         } else {
2380                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2381                                           uri_encode($v), "\n";
2382                         }
2383                 }
2384         } else {
2385                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2386         }
2387         close $un or croak $!;
2388
2389         $log_entry{date} = parse_svn_date($log_entry{date});
2390         $log_entry{log} .= "\n";
2391         my $author = $log_entry{author} = check_author($log_entry{author});
2392         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2393                                                        : ($author, undef);
2394
2395         my ($commit_name, $commit_email) = ($name, $email);
2396         if ($_use_log_author) {
2397                 my $name_field;
2398                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2399                         $name_field = $1;
2400                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2401                         $name_field = $1;
2402                 }
2403                 if (!defined $name_field) {
2404                         #
2405                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2406                         ($name, $email) = ($1, $2);
2407                 } elsif ($name_field =~ /(.*)@/) {
2408                         ($name, $email) = ($1, $name_field);
2409                 } else {
2410                         ($name, $email) = ($name_field, 'unknown');
2411                 }
2412         }
2413         if (defined $headrev && $self->use_svm_props) {
2414                 if ($self->rewrite_root) {
2415                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2416                             "options set!\n";
2417                 }
2418                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2419                 # we don't want "SVM: initializing mirror for junk" ...
2420                 return undef if $r == 0;
2421                 my $svm = $self->svm;
2422                 if ($uuid ne $svm->{uuid}) {
2423                         die "UUID mismatch on SVM path:\n",
2424                             "expected: $svm->{uuid}\n",
2425                             "     got: $uuid\n";
2426                 }
2427                 my $full_url = $self->full_url;
2428                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2429                              die "Failed to replace '$svm->{replace}' with ",
2430                                  "'$svm->{source}' in $full_url\n";
2431                 # throw away username for storing in records
2432                 remove_username($full_url);
2433                 $log_entry{metadata} = "$full_url\@$r $uuid";
2434                 $log_entry{svm_revision} = $r;
2435                 $email ||= "$author\@$uuid";
2436                 $commit_email ||= "$author\@$uuid";
2437         } elsif ($self->use_svnsync_props) {
2438                 my $full_url = $self->svnsync->{url};
2439                 $full_url .= "/$self->{path}" if length $self->{path};
2440                 remove_username($full_url);
2441                 my $uuid = $self->svnsync->{uuid};
2442                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2443                 $email ||= "$author\@$uuid";
2444                 $commit_email ||= "$author\@$uuid";
2445         } else {
2446                 my $url = $self->metadata_url;
2447                 remove_username($url);
2448                 $log_entry{metadata} = "$url\@$rev " .
2449                                        $self->ra->get_uuid;
2450                 $email ||= "$author\@" . $self->ra->get_uuid;
2451                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2452         }
2453         $log_entry{name} = $name;
2454         $log_entry{email} = $email;
2455         $log_entry{commit_name} = $commit_name;
2456         $log_entry{commit_email} = $commit_email;
2457         \%log_entry;
2458 }
2459
2460 sub fetch {
2461         my ($self, $min_rev, $max_rev, @parents) = @_;
2462         my ($last_rev, $last_commit) = $self->last_rev_commit;
2463         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2464         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2465 }
2466
2467 sub set_tree_cb {
2468         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2469         $self->{inject_parents} = { $rev => $tree };
2470         $self->fetch(undef, undef);
2471 }
2472
2473 sub set_tree {
2474         my ($self, $tree) = (shift, shift);
2475         my $log_entry = ::get_commit_entry($tree);
2476         unless ($self->{last_rev}) {
2477                 fatal("Must have an existing revision to commit");
2478         }
2479         my %ed_opts = ( r => $self->{last_rev},
2480                         log => $log_entry->{log},
2481                         ra => $self->ra,
2482                         tree_a => $self->{last_commit},
2483                         tree_b => $tree,
2484                         editor_cb => sub {
2485                                $self->set_tree_cb($log_entry, $tree, @_) },
2486                         svn_path => $self->{path} );
2487         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2488                 print "No changes\nr$self->{last_rev} = $tree\n";
2489         }
2490 }
2491
2492 sub rebuild_from_rev_db {
2493         my ($self, $path) = @_;
2494         my $r = -1;
2495         open my $fh, '<', $path or croak "open: $!";
2496         while (<$fh>) {
2497                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2498                 chomp($_);
2499                 ++$r;
2500                 next if $_ eq ('0' x 40);
2501                 $self->rev_map_set($r, $_);
2502                 print "r$r = $_\n";
2503         }
2504         close $fh or croak "close: $!";
2505         unlink $path or croak "unlink: $!";
2506 }
2507
2508 sub rebuild {
2509         my ($self) = @_;
2510         my $map_path = $self->map_path;
2511         return if (-e $map_path && ! -z $map_path);
2512         return unless ::verify_ref($self->refname.'^0');
2513         if ($self->use_svm_props || $self->no_metadata) {
2514                 my $rev_db = $self->rev_db_path;
2515                 $self->rebuild_from_rev_db($rev_db);
2516                 if ($self->use_svm_props) {
2517                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2518                         $self->rebuild_from_rev_db($svm_rev_db);
2519                 }
2520                 $self->unlink_rev_db_symlink;
2521                 return;
2522         }
2523         print "Rebuilding $map_path ...\n";
2524         my ($log, $ctx) =
2525             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2526                                 $self->refname, '--');
2527         my $full_url = $self->full_url;
2528         remove_username($full_url);
2529         my $svn_uuid = $self->ra_uuid;
2530         my $c;
2531         while (<$log>) {
2532                 if ( m{^commit ($::sha1)$} ) {
2533                         $c = $1;
2534                         next;
2535                 }
2536                 next unless s{^\s*(git-svn-id:)}{$1};
2537                 my ($url, $rev, $uuid) = ::extract_metadata($_);
2538                 remove_username($url);
2539
2540                 # ignore merges (from set-tree)
2541                 next if (!defined $rev || !$uuid);
2542
2543                 # if we merged or otherwise started elsewhere, this is
2544                 # how we break out of it
2545                 if (($uuid ne $svn_uuid) ||
2546                     ($full_url && $url && ($url ne $full_url))) {
2547                         next;
2548                 }
2549
2550                 $self->rev_map_set($rev, $c);
2551                 print "r$rev = $c\n";
2552         }
2553         command_close_pipe($log, $ctx);
2554         print "Done rebuilding $map_path\n";
2555         my $rev_db_path = $self->rev_db_path;
2556         if (-f $self->rev_db_path) {
2557                 unlink $self->rev_db_path or croak "unlink: $!";
2558         }
2559         $self->unlink_rev_db_symlink;
2560 }
2561
2562 # rev_map:
2563 # Tie::File seems to be prone to offset errors if revisions get sparse,
2564 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
2565 # one of my favorite modules is out :<  Next up would be one of the DBM
2566 # modules, but I'm not sure which is most portable...
2567 #
2568 # This is the replacement for the rev_db format, which was too big
2569 # and inefficient for large repositories with a lot of sparse history
2570 # (mainly tags)
2571 #
2572 # The format is this:
2573 #   - 24 bytes for every record,
2574 #     * 4 bytes for the integer representing an SVN revision number
2575 #     * 20 bytes representing the sha1 of a git commit
2576 #   - No empty padding records like the old format
2577 #     (except the last record, which can be overwritten)
2578 #   - new records are written append-only since SVN revision numbers
2579 #     increase monotonically
2580 #   - lookups on SVN revision number are done via a binary search
2581 #   - Piping the file to xxd -c24 is a good way of dumping it for
2582 #     viewing or editing (piped back through xxd -r), should the need
2583 #     ever arise.
2584 #   - The last record can be padding revision with an all-zero sha1
2585 #     This is used to optimize fetch performance when using multiple
2586 #     "fetch" directives in .git/config
2587 #
2588 # These files are disposable unless noMetadata or useSvmProps is set
2589
2590 sub _rev_map_set {
2591         my ($fh, $rev, $commit) = @_;
2592
2593         my $size = (stat($fh))[7];
2594         ($size % 24) == 0 or croak "inconsistent size: $size";
2595
2596         my $wr_offset = 0;
2597         if ($size > 0) {
2598                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2599                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2600                 $read == 24 or croak "read only $read bytes (!= 24)";
2601                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2602                 if ($last_commit eq ('0' x40)) {
2603                         if ($size >= 48) {
2604                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2605                                 $read = sysread($fh, $buf, 24) or
2606                                     croak "read: $!";
2607                                 $read == 24 or
2608                                     croak "read only $read bytes (!= 24)";
2609                                 ($last_rev, $last_commit) =
2610                                     unpack(rev_map_fmt, $buf);
2611                                 if ($last_commit eq ('0' x40)) {
2612                                         croak "inconsistent .rev_map\n";
2613                                 }
2614                         }
2615                         if ($last_rev >= $rev) {
2616                                 croak "last_rev is higher!: $last_rev >= $rev";
2617                         }
2618                         $wr_offset = -24;
2619                 }
2620         }
2621         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2622         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2623           croak "write: $!";
2624 }
2625
2626 sub mkfile {
2627         my ($path) = @_;
2628         unless (-e $path) {
2629                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2630                 mkpath([$dir]) unless -d $dir;
2631                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2632                 close $fh or die "Couldn't close (create) $path: $!\n";
2633         }
2634 }
2635
2636 sub rev_map_set {
2637         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2638         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2639         my $db = $self->map_path($uuid);
2640         my $db_lock = "$db.lock";
2641         my $sig;
2642         if ($update_ref) {
2643                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2644                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2645         }
2646         mkfile($db);
2647
2648         $LOCKFILES{$db_lock} = 1;
2649         my $sync;
2650         # both of these options make our .rev_db file very, very important
2651         # and we can't afford to lose it because rebuild() won't work
2652         if ($self->use_svm_props || $self->no_metadata) {
2653                 $sync = 1;
2654                 copy($db, $db_lock) or die "rev_map_set(@_): ",
2655                                            "Failed to copy: ",
2656                                            "$db => $db_lock ($!)\n";
2657         } else {
2658                 rename $db, $db_lock or die "rev_map_set(@_): ",
2659                                             "Failed to rename: ",
2660                                             "$db => $db_lock ($!)\n";
2661         }
2662
2663         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2664              or croak "Couldn't open $db_lock: $!\n";
2665         _rev_map_set($fh, $rev, $commit);
2666         if ($sync) {
2667                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2668                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2669         }
2670         close $fh or croak $!;
2671         if ($update_ref) {
2672                 $_head = $self;
2673                 command_noisy('update-ref', '-m', "r$rev",
2674                               $self->refname, $commit);
2675         }
2676         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2677                                     "$db_lock => $db ($!)\n";
2678         delete $LOCKFILES{$db_lock};
2679         if ($update_ref) {
2680                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2681                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2682                 kill $sig, $$ if defined $sig;
2683         }
2684 }
2685
2686 # If want_commit, this will return an array of (rev, commit) where
2687 # commit _must_ be a valid commit in the archive.
2688 # Otherwise, it'll return the max revision (whether or not the
2689 # commit is valid or just a 0x40 placeholder).
2690 sub rev_map_max {
2691         my ($self, $want_commit) = @_;
2692         $self->rebuild;
2693         my $map_path = $self->map_path;
2694         stat $map_path or return $want_commit ? (0, undef) : 0;
2695         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2696         my $size = (stat($fh))[7];
2697         ($size % 24) == 0 or croak "inconsistent size: $size";
2698
2699         if ($size == 0) {
2700                 close $fh or croak "close: $!";
2701                 return $want_commit ? (0, undef) : 0;
2702         }
2703
2704         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2705         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2706         my ($r, $c) = unpack(rev_map_fmt, $buf);
2707         if ($want_commit && $c eq ('0' x40)) {
2708                 if ($size < 48) {
2709                         return $want_commit ? (0, undef) : 0;
2710                 }
2711                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2712                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2713                 ($r, $c) = unpack(rev_map_fmt, $buf);
2714                 if ($c eq ('0'x40)) {
2715                         croak "Penultimate record is all-zeroes in $map_path";
2716                 }
2717         }
2718         close $fh or croak "close: $!";
2719         $want_commit ? ($r, $c) : $r;
2720 }
2721
2722 sub rev_map_get {
2723         my ($self, $rev, $uuid) = @_;
2724         my $map_path = $self->map_path($uuid);
2725         return undef unless -e $map_path;
2726
2727         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2728         my $size = (stat($fh))[7];
2729         ($size % 24) == 0 or croak "inconsistent size: $size";
2730
2731         if ($size == 0) {
2732                 close $fh or croak "close: $fh";
2733                 return undef;
2734         }
2735
2736         my ($l, $u) = (0, $size - 24);
2737         my ($r, $c, $buf);
2738
2739         while ($l <= $u) {
2740                 my $i = int(($l/24 + $u/24) / 2) * 24;
2741                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2742                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2743                 my ($r, $c) = unpack('NH40', $buf);
2744
2745                 if ($r < $rev) {
2746                         $l = $i + 24;
2747                 } elsif ($r > $rev) {
2748                         $u = $i - 24;
2749                 } else { # $r == $rev
2750                         close($fh) or croak "close: $!";
2751                         return $c eq ('0' x 40) ? undef : $c;
2752                 }
2753         }
2754         close($fh) or croak "close: $!";
2755         undef;
2756 }
2757
2758 # Finds the first svn revision that exists on (if $eq_ok is true) or
2759 # before $rev for the current branch.  It will not search any lower
2760 # than $min_rev.  Returns the git commit hash and svn revision number
2761 # if found, else (undef, undef).
2762 sub find_rev_before {
2763         my ($self, $rev, $eq_ok, $min_rev) = @_;
2764         --$rev unless $eq_ok;
2765         $min_rev ||= 1;
2766         while ($rev >= $min_rev) {
2767                 if (my $c = $self->rev_map_get($rev)) {
2768                         return ($rev, $c);
2769                 }
2770                 --$rev;
2771         }
2772         return (undef, undef);
2773 }
2774
2775 # Finds the first svn revision that exists on (if $eq_ok is true) or
2776 # after $rev for the current branch.  It will not search any higher
2777 # than $max_rev.  Returns the git commit hash and svn revision number
2778 # if found, else (undef, undef).
2779 sub find_rev_after {
2780         my ($self, $rev, $eq_ok, $max_rev) = @_;
2781         ++$rev unless $eq_ok;
2782         $max_rev ||= $self->rev_map_max;
2783         while ($rev <= $max_rev) {
2784                 if (my $c = $self->rev_map_get($rev)) {
2785                         return ($rev, $c);
2786                 }
2787                 ++$rev;
2788         }
2789         return (undef, undef);
2790 }
2791
2792 sub _new {
2793         my ($class, $repo_id, $ref_id, $path) = @_;
2794         unless (defined $repo_id && length $repo_id) {
2795                 $repo_id = $Git::SVN::default_repo_id;
2796         }
2797         unless (defined $ref_id && length $ref_id) {
2798                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2799         }
2800         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2801         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2802         $_[3] = $path = '' unless (defined $path);
2803         mkpath(["$ENV{GIT_DIR}/svn"]);
2804         bless {
2805                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2806                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2807                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2808 }
2809
2810 # for read-only access of old .rev_db formats
2811 sub unlink_rev_db_symlink {
2812         my ($self) = @_;
2813         my $link = $self->rev_db_path;
2814         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2815         if (-l $link) {
2816                 unlink $link or croak "unlink: $link failed!";
2817         }
2818 }
2819
2820 sub rev_db_path {
2821         my ($self, $uuid) = @_;
2822         my $db_path = $self->map_path($uuid);
2823         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2824             or croak "map_path: $db_path does not contain '/.rev_map.' !";
2825         $db_path;
2826 }
2827
2828 # the new replacement for .rev_db
2829 sub map_path {
2830         my ($self, $uuid) = @_;
2831         $uuid ||= $self->ra_uuid;
2832         "$self->{map_root}.$uuid";
2833 }
2834
2835 sub uri_encode {
2836         my ($f) = @_;
2837         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2838         $f
2839 }
2840
2841 sub remove_username {
2842         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2843 }
2844
2845 package Git::SVN::Prompt;
2846 use strict;
2847 use warnings;
2848 require SVN::Core;
2849 use vars qw/$_no_auth_cache $_username/;
2850
2851 sub simple {
2852         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2853         $may_save = undef if $_no_auth_cache;
2854         $default_username = $_username if defined $_username;
2855         if (defined $default_username && length $default_username) {
2856                 if (defined $realm && length $realm) {
2857                         print STDERR "Authentication realm: $realm\n";
2858                         STDERR->flush;
2859                 }
2860                 $cred->username($default_username);
2861         } else {
2862                 username($cred, $realm, $may_save, $pool);
2863         }
2864         $cred->password(_read_password("Password for '" .
2865                                        $cred->username . "': ", $realm));
2866         $cred->may_save($may_save);
2867         $SVN::_Core::SVN_NO_ERROR;
2868 }
2869
2870 sub ssl_server_trust {
2871         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2872         $may_save = undef if $_no_auth_cache;
2873         print STDERR "Error validating server certificate for '$realm':\n";
2874         {
2875                 no warnings 'once';
2876                 # All variables SVN::Auth::SSL::* are used only once,
2877                 # so we're shutting up Perl warnings about this.
2878                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2879                         print STDERR " - The certificate is not issued ",
2880                             "by a trusted authority. Use the\n",
2881                             "   fingerprint to validate ",
2882                             "the certificate manually!\n";
2883                 }
2884                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2885                         print STDERR " - The certificate hostname ",
2886                             "does not match.\n";
2887                 }
2888                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2889                         print STDERR " - The certificate is not yet valid.\n";
2890                 }
2891                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2892                         print STDERR " - The certificate has expired.\n";
2893                 }
2894                 if ($failures & $SVN::Auth::SSL::OTHER) {
2895                         print STDERR " - The certificate has ",
2896                             "an unknown error.\n";
2897                 }
2898         } # no warnings 'once'
2899         printf STDERR
2900                 "Certificate information:\n".
2901                 " - Hostname: %s\n".
2902                 " - Valid: from %s until %s\n".
2903                 " - Issuer: %s\n".
2904                 " - Fingerprint: %s\n",
2905                 map $cert_info->$_, qw(hostname valid_from valid_until
2906                                        issuer_dname fingerprint);
2907         my $choice;
2908 prompt:
2909         print STDERR $may_save ?
2910               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2911               "(R)eject or accept (t)emporarily? ";
2912         STDERR->flush;
2913         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2914         if ($choice =~ /^t$/i) {
2915                 $cred->may_save(undef);
2916         } elsif ($choice =~ /^r$/i) {
2917                 return -1;
2918         } elsif ($may_save && $choice =~ /^p$/i) {
2919                 $cred->may_save($may_save);
2920         } else {
2921                 goto prompt;
2922         }
2923         $cred->accepted_failures($failures);
2924         $SVN::_Core::SVN_NO_ERROR;
2925 }
2926
2927 sub ssl_client_cert {
2928         my ($cred, $realm, $may_save, $pool) = @_;
2929         $may_save = undef if $_no_auth_cache;
2930         print STDERR "Client certificate filename: ";
2931         STDERR->flush;
2932         chomp(my $filename = <STDIN>);
2933         $cred->cert_file($filename);
2934         $cred->may_save($may_save);
2935         $SVN::_Core::SVN_NO_ERROR;
2936 }
2937
2938 sub ssl_client_cert_pw {
2939         my ($cred, $realm, $may_save, $pool) = @_;
2940         $may_save = undef if $_no_auth_cache;
2941         $cred->password(_read_password("Password: ", $realm));
2942         $cred->may_save($may_save);
2943         $SVN::_Core::SVN_NO_ERROR;
2944 }
2945
2946 sub username {
2947         my ($cred, $realm, $may_save, $pool) = @_;
2948         $may_save = undef if $_no_auth_cache;
2949         if (defined $realm && length $realm) {
2950                 print STDERR "Authentication realm: $realm\n";
2951         }
2952         my $username;
2953         if (defined $_username) {
2954                 $username = $_username;
2955         } else {
2956                 print STDERR "Username: ";
2957                 STDERR->flush;
2958                 chomp($username = <STDIN>);
2959         }
2960         $cred->username($username);
2961         $cred->may_save($may_save);
2962         $SVN::_Core::SVN_NO_ERROR;
2963 }
2964
2965 sub _read_password {
2966         my ($prompt, $realm) = @_;
2967         print STDERR $prompt;
2968         STDERR->flush;
2969         require Term::ReadKey;
2970         Term::ReadKey::ReadMode('noecho');
2971         my $password = '';
2972         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2973                 last if $key =~ /[\012\015]/; # \n\r
2974                 $password .= $key;
2975         }
2976         Term::ReadKey::ReadMode('restore');
2977         print STDERR "\n";
2978         STDERR->flush;
2979         $password;
2980 }
2981
2982 package SVN::Git::Fetcher;
2983 use vars qw/@ISA/;
2984 use strict;
2985 use warnings;
2986 use Carp qw/croak/;
2987 use IO::File qw//;
2988
2989 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2990 sub new {
2991         my ($class, $git_svn) = @_;
2992         my $self = SVN::Delta::Editor->new;
2993         bless $self, $class;
2994         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2995         $self->{empty} = {};
2996         $self->{dir_prop} = {};
2997         $self->{file_prop} = {};
2998         $self->{absent_dir} = {};
2999         $self->{absent_file} = {};
3000         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3001         $self;
3002 }
3003
3004 sub set_path_strip {
3005         my ($self, $path) = @_;
3006         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3007 }
3008
3009 sub open_root {
3010         { path => '' };
3011 }
3012
3013 sub open_directory {
3014         my ($self, $path, $pb, $rev) = @_;
3015         { path => $path };
3016 }
3017
3018 sub git_path {
3019         my ($self, $path) = @_;
3020         if ($self->{path_strip}) {
3021                 $path =~ s!$self->{path_strip}!! or
3022                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3023         }
3024         $path;
3025 }
3026
3027 sub delete_entry {
3028         my ($self, $path, $rev, $pb) = @_;
3029
3030         my $gpath = $self->git_path($path);
3031         return undef if ($gpath eq '');
3032
3033         # remove entire directories.
3034         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3035                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3036                                                      -r --name-only -z/,
3037                                                      $self->{c}, '--', $gpath);
3038                 local $/ = "\0";
3039                 while (<$ls>) {
3040                         chomp;
3041                         $self->{gii}->remove($_);
3042                         print "\tD\t$_\n" unless $::_q;
3043                 }
3044                 print "\tD\t$gpath/\n" unless $::_q;
3045                 command_close_pipe($ls, $ctx);
3046                 $self->{empty}->{$path} = 0
3047         } else {
3048                 $self->{gii}->remove($gpath);
3049                 print "\tD\t$gpath\n" unless $::_q;
3050         }
3051         undef;
3052 }
3053
3054 sub open_file {
3055         my ($self, $path, $pb, $rev) = @_;
3056         my $gpath = $self->git_path($path);
3057         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3058                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3059         unless (defined $mode && defined $blob) {
3060                 die "$path was not found in commit $self->{c} (r$rev)\n";
3061         }
3062         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3063           pool => SVN::Pool->new, action => 'M' };
3064 }
3065
3066 sub add_file {
3067         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3068         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3069         delete $self->{empty}->{$dir};
3070         { path => $path, mode_a => 100644, mode_b => 100644,
3071           pool => SVN::Pool->new, action => 'A' };
3072 }
3073
3074 sub add_directory {
3075         my ($self, $path, $cp_path, $cp_rev) = @_;
3076         my $gpath = $self->git_path($path);
3077         if ($gpath eq '') {
3078                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3079                                                      -r --name-only -z/,
3080                                                      $self->{c});
3081                 local $/ = "\0";
3082                 while (<$ls>) {
3083                         chomp;
3084                         $self->{gii}->remove($_);
3085                         print "\tD\t$_\n" unless $::_q;
3086                 }
3087                 command_close_pipe($ls, $ctx);
3088                 $self->{empty}->{$path} = 0;
3089         }
3090         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3091         delete $self->{empty}->{$dir};
3092         $self->{empty}->{$path} = 1;
3093         { path => $path };
3094 }
3095
3096 sub change_dir_prop {
3097         my ($self, $db, $prop, $value) = @_;
3098         $self->{dir_prop}->{$db->{path}} ||= {};
3099         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3100         undef;
3101 }
3102
3103 sub absent_directory {
3104         my ($self, $path, $pb) = @_;
3105         $self->{absent_dir}->{$pb->{path}} ||= [];
3106         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3107         undef;
3108 }
3109
3110 sub absent_file {
3111         my ($self, $path, $pb) = @_;
3112         $self->{absent_file}->{$pb->{path}} ||= [];
3113         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3114         undef;
3115 }
3116
3117 sub change_file_prop {
3118         my ($self, $fb, $prop, $value) = @_;
3119         if ($prop eq 'svn:executable') {
3120                 if ($fb->{mode_b} != 120000) {
3121                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3122                 }
3123         } elsif ($prop eq 'svn:special') {
3124                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3125         } else {
3126                 $self->{file_prop}->{$fb->{path}} ||= {};
3127                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3128         }
3129         undef;
3130 }
3131
3132 sub apply_textdelta {
3133         my ($self, $fb, $exp) = @_;
3134         my $fh = IO::File->new_tmpfile;
3135         $fh->autoflush(1);
3136         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3137         # (but $base does not,) so dup() it for reading in close_file
3138         open my $dup, '<&', $fh or croak $!;
3139         my $base = IO::File->new_tmpfile;
3140         $base->autoflush(1);
3141         if ($fb->{blob}) {
3142                 defined (my $pid = fork) or croak $!;
3143                 if (!$pid) {
3144                         open STDOUT, '>&', $base or croak $!;
3145                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3146                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3147                 }
3148                 waitpid $pid, 0;
3149                 croak $? if $?;
3150
3151                 if (defined $exp) {
3152                         seek $base, 0, 0 or croak $!;
3153                         my $got = ::md5sum($base);
3154                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3155                             "expected: $exp\n",
3156                             "     got: $got\n" if ($got ne $exp);
3157                 }
3158         }
3159         seek $base, 0, 0 or croak $!;
3160         $fb->{fh} = $dup;
3161         $fb->{base} = $base;
3162         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3163 }
3164
3165 sub close_file {
3166         my ($self, $fb, $exp) = @_;
3167         my $hash;
3168         my $path = $self->git_path($fb->{path});
3169         if (my $fh = $fb->{fh}) {
3170                 if (defined $exp) {
3171                         seek($fh, 0, 0) or croak $!;
3172                         my $got = ::md5sum($fh);
3173                         if ($got ne $exp) {
3174                                 die "Checksum mismatch: $path\n",
3175                                     "expected: $exp\n    got: $got\n";
3176                         }
3177                 }
3178                 sysseek($fh, 0, 0) or croak $!;
3179                 if ($fb->{mode_b} == 120000) {
3180                         sysread($fh, my $buf, 5) == 5 or croak $!;
3181                         $buf eq 'link ' or die "$path has mode 120000",
3182                                                "but is not a link\n";
3183                 }
3184                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3185                 if (!$pid) {
3186                         open STDIN, '<&', $fh or croak $!;
3187                         exec qw/git-hash-object -w --stdin/ or croak $!;
3188                 }
3189                 chomp($hash = do { local $/; <$out> });
3190                 close $out or croak $!;
3191                 close $fh or croak $!;
3192                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3193                 close $fb->{base} or croak $!;
3194         } else {
3195                 $hash = $fb->{blob} or die "no blob information\n";
3196         }
3197         $fb->{pool}->clear;
3198         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3199         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3200         undef;
3201 }
3202
3203 sub abort_edit {
3204         my $self = shift;
3205         $self->{nr} = $self->{gii}->{nr};
3206         delete $self->{gii};
3207         $self->SUPER::abort_edit(@_);
3208 }
3209
3210 sub close_edit {
3211         my $self = shift;
3212         $self->{git_commit_ok} = 1;
3213         $self->{nr} = $self->{gii}->{nr};
3214         delete $self->{gii};
3215         $self->SUPER::close_edit(@_);
3216 }
3217
3218 package SVN::Git::Editor;
3219 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3220 use strict;
3221 use warnings;
3222 use Carp qw/croak/;
3223 use IO::File;
3224
3225 sub new {
3226         my ($class, $opts) = @_;
3227         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3228                 die "$_ required!\n" unless (defined $opts->{$_});
3229         }
3230
3231         my $pool = SVN::Pool->new;
3232         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3233         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3234                                      $opts->{r}, $mods);
3235
3236         # $opts->{ra} functions should not be used after this:
3237         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3238                                                 $opts->{editor_cb}, $pool);
3239         my $self = SVN::Delta::Editor->new(@ce, $pool);
3240         bless $self, $class;
3241         foreach (qw/svn_path r tree_a tree_b/) {
3242                 $self->{$_} = $opts->{$_};
3243         }
3244         $self->{url} = $opts->{ra}->{url};
3245         $self->{mods} = $mods;
3246         $self->{types} = $types;
3247         $self->{pool} = $pool;
3248         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3249         $self->{rm} = { };
3250         $self->{path_prefix} = length $self->{svn_path} ?
3251                                "$self->{svn_path}/" : '';
3252         return $self;
3253 }
3254
3255 sub generate_diff {
3256         my ($tree_a, $tree_b) = @_;
3257         my @diff_tree = qw(diff-tree -z -r);
3258         if ($_cp_similarity) {
3259                 push @diff_tree, "-C$_cp_similarity";
3260         } else {
3261                 push @diff_tree, '-C';
3262         }
3263         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3264         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3265         push @diff_tree, $tree_a, $tree_b;
3266         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3267         local $/ = "\0";
3268         my $state = 'meta';
3269         my @mods;
3270         while (<$diff_fh>) {
3271                 chomp $_; # this gets rid of the trailing "\0"
3272                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3273                                         $::sha1\s($::sha1)\s
3274                                         ([MTCRAD])\d*$/xo) {
3275                         push @mods, {   mode_a => $1, mode_b => $2,
3276                                         sha1_b => $3, chg => $4 };
3277                         if ($4 =~ /^(?:C|R)$/) {
3278                                 $state = 'file_a';
3279                         } else {
3280                                 $state = 'file_b';
3281                         }
3282                 } elsif ($state eq 'file_a') {
3283                         my $x = $mods[$#mods] or croak "Empty array\n";
3284                         if ($x->{chg} !~ /^(?:C|R)$/) {
3285                                 croak "Error parsing $_, $x->{chg}\n";
3286                         }
3287                         $x->{file_a} = $_;
3288                         $state = 'file_b';
3289                 } elsif ($state eq 'file_b') {
3290                         my $x = $mods[$#mods] or croak "Empty array\n";
3291                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3292                                 croak "Error parsing $_, $x->{chg}\n";
3293                         }
3294                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3295                                 croak "Error parsing $_, $x->{chg}\n";
3296                         }
3297                         $x->{file_b} = $_;
3298                         $state = 'meta';
3299                 } else {
3300                         croak "Error parsing $_\n";
3301                 }
3302         }
3303         command_close_pipe($diff_fh, $ctx);
3304         \@mods;
3305 }
3306
3307 sub check_diff_paths {
3308         my ($ra, $pfx, $rev, $mods) = @_;
3309         my %types;
3310         $pfx .= '/' if length $pfx;
3311
3312         sub type_diff_paths {
3313                 my ($ra, $types, $path, $rev) = @_;
3314                 my @p = split m#/+#, $path;
3315                 my $c = shift @p;
3316                 unless (defined $types->{$c}) {
3317                         $types->{$c} = $ra->check_path($c, $rev);
3318                 }
3319                 while (@p) {
3320                         $c .= '/' . shift @p;
3321                         next if defined $types->{$c};
3322                         $types->{$c} = $ra->check_path($c, $rev);
3323                 }
3324         }
3325
3326         foreach my $m (@$mods) {
3327                 foreach my $f (qw/file_a file_b/) {
3328                         next unless defined $m->{$f};
3329                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3330                         if (length $pfx.$dir && ! defined $types{$dir}) {
3331                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3332                         }
3333                 }
3334         }
3335         \%types;
3336 }
3337
3338 sub split_path {
3339         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3340 }
3341
3342 sub repo_path {
3343         my ($self, $path) = @_;
3344         $self->{path_prefix}.(defined $path ? $path : '');
3345 }
3346
3347 sub url_path {
3348         my ($self, $path) = @_;
3349         if ($self->{url} =~ m#^https?://#) {
3350                 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3351         }
3352         $self->{url} . '/' . $self->repo_path($path);
3353 }
3354
3355 sub rmdirs {
3356         my ($self) = @_;
3357         my $rm = $self->{rm};
3358         delete $rm->{''}; # we never delete the url we're tracking
3359         return unless %$rm;
3360
3361         foreach (keys %$rm) {
3362                 my @d = split m#/#, $_;
3363                 my $c = shift @d;
3364                 $rm->{$c} = 1;
3365                 while (@d) {
3366                         $c .= '/' . shift @d;
3367                         $rm->{$c} = 1;
3368                 }
3369         }
3370         delete $rm->{$self->{svn_path}};
3371         delete $rm->{''}; # we never delete the url we're tracking
3372         return unless %$rm;
3373
3374         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3375                                              $self->{tree_b});
3376         local $/ = "\0";
3377         while (<$fh>) {
3378                 chomp;
3379                 my @dn = split m#/#, $_;
3380                 while (pop @dn) {
3381                         delete $rm->{join '/', @dn};
3382                 }
3383                 unless (%$rm) {
3384                         close $fh;
3385                         return;
3386                 }
3387         }
3388         command_close_pipe($fh, $ctx);
3389
3390         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3391         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3392                 $self->close_directory($bat->{$d}, $p);
3393                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3394                 print "\tD+\t$d/\n" unless $::_q;
3395                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3396                 delete $bat->{$d};
3397         }
3398 }
3399
3400 sub open_or_add_dir {
3401         my ($self, $full_path, $baton) = @_;
3402         my $t = $self->{types}->{$full_path};
3403         if (!defined $t) {
3404                 die "$full_path not known in r$self->{r} or we have a bug!\n";
3405         }
3406         {
3407                 no warnings 'once';
3408                 # SVN::Node::none and SVN::Node::file are used only once,
3409                 # so we're shutting up Perl's warnings about them.
3410                 if ($t == $SVN::Node::none) {
3411                         return $self->add_directory($full_path, $baton,
3412                             undef, -1, $self->{pool});
3413                 } elsif ($t == $SVN::Node::dir) {
3414                         return $self->open_directory($full_path, $baton,
3415                             $self->{r}, $self->{pool});
3416                 } # no warnings 'once'
3417                 print STDERR "$full_path already exists in repository at ",
3418                     "r$self->{r} and it is not a directory (",
3419                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3420         } # no warnings 'once'
3421         exit 1;
3422 }
3423
3424 sub ensure_path {
3425         my ($self, $path) = @_;
3426         my $bat = $self->{bat};
3427         my $repo_path = $self->repo_path($path);
3428         return $bat->{''} unless (length $repo_path);
3429         my @p = split m#/+#, $repo_path;
3430         my $c = shift @p;
3431         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3432         while (@p) {
3433                 my $c0 = $c;
3434                 $c .= '/' . shift @p;
3435                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3436         }
3437         return $bat->{$c};
3438 }
3439
3440 sub A {
3441         my ($self, $m) = @_;
3442         my ($dir, $file) = split_path($m->{file_b});
3443         my $pbat = $self->ensure_path($dir);
3444         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3445                                         undef, -1);
3446         print "\tA\t$m->{file_b}\n" unless $::_q;
3447         $self->chg_file($fbat, $m);
3448         $self->close_file($fbat,undef,$self->{pool});
3449 }
3450
3451 sub C {
3452         my ($self, $m) = @_;
3453         my ($dir, $file) = split_path($m->{file_b});
3454         my $pbat = $self->ensure_path($dir);
3455         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3456                                 $self->url_path($m->{file_a}), $self->{r});
3457         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3458         $self->chg_file($fbat, $m);
3459         $self->close_file($fbat,undef,$self->{pool});
3460 }
3461
3462 sub delete_entry {
3463         my ($self, $path, $pbat) = @_;
3464         my $rpath = $self->repo_path($path);
3465         my ($dir, $file) = split_path($rpath);
3466         $self->{rm}->{$dir} = 1;
3467         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3468 }
3469
3470 sub R {
3471         my ($self, $m) = @_;
3472         my ($dir, $file) = split_path($m->{file_b});
3473         my $pbat = $self->ensure_path($dir);
3474         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3475                                 $self->url_path($m->{file_a}), $self->{r});
3476         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3477         $self->chg_file($fbat, $m);
3478         $self->close_file($fbat,undef,$self->{pool});
3479
3480         ($dir, $file) = split_path($m->{file_a});
3481         $pbat = $self->ensure_path($dir);
3482         $self->delete_entry($m->{file_a}, $pbat);
3483 }
3484
3485 sub M {
3486         my ($self, $m) = @_;
3487         my ($dir, $file) = split_path($m->{file_b});
3488         my $pbat = $self->ensure_path($dir);
3489         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3490                                 $pbat,$self->{r},$self->{pool});
3491         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3492         $self->chg_file($fbat, $m);
3493         $self->close_file($fbat,undef,$self->{pool});
3494 }
3495
3496 sub T { shift->M(@_) }
3497
3498 sub change_file_prop {
3499         my ($self, $fbat, $pname, $pval) = @_;
3500         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3501 }
3502
3503 sub chg_file {
3504         my ($self, $fbat, $m) = @_;
3505         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3506                 $self->change_file_prop($fbat,'svn:executable','*');
3507         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3508                 $self->change_file_prop($fbat,'svn:executable',undef);
3509         }
3510         my $fh = IO::File->new_tmpfile or croak $!;
3511         if ($m->{mode_b} =~ /^120/) {
3512                 print $fh 'link ' or croak $!;
3513                 $self->change_file_prop($fbat,'svn:special','*');
3514         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3515                 $self->change_file_prop($fbat,'svn:special',undef);
3516         }
3517         defined(my $pid = fork) or croak $!;
3518         if (!$pid) {
3519                 open STDOUT, '>&', $fh or croak $!;
3520                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3521         }
3522         waitpid $pid, 0;
3523         croak $? if $?;
3524         $fh->flush == 0 or croak $!;
3525         seek $fh, 0, 0 or croak $!;
3526
3527         my $exp = ::md5sum($fh);
3528         seek $fh, 0, 0 or croak $!;
3529
3530         my $pool = SVN::Pool->new;
3531         my $atd = $self->apply_textdelta($fbat, undef, $pool);
3532         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3533         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3534         $pool->clear;
3535
3536         close $fh or croak $!;
3537 }
3538
3539 sub D {
3540         my ($self, $m) = @_;
3541         my ($dir, $file) = split_path($m->{file_b});
3542         my $pbat = $self->ensure_path($dir);
3543         print "\tD\t$m->{file_b}\n" unless $::_q;
3544         $self->delete_entry($m->{file_b}, $pbat);
3545 }
3546
3547 sub close_edit {
3548         my ($self) = @_;
3549         my ($p,$bat) = ($self->{pool}, $self->{bat});
3550         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3551                 next if $_ eq '';
3552                 $self->close_directory($bat->{$_}, $p);
3553         }
3554         $self->close_directory($bat->{''}, $p);
3555         $self->SUPER::close_edit($p);
3556         $p->clear;
3557 }
3558
3559 sub abort_edit {
3560         my ($self) = @_;
3561         $self->SUPER::abort_edit($self->{pool});
3562 }
3563
3564 sub DESTROY {
3565         my $self = shift;
3566         $self->SUPER::DESTROY(@_);
3567         $self->{pool}->clear;
3568 }
3569
3570 # this drives the editor
3571 sub apply_diff {
3572         my ($self) = @_;
3573         my $mods = $self->{mods};
3574         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3575         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3576                 my $f = $m->{chg};
3577                 if (defined $o{$f}) {
3578                         $self->$f($m);
3579                 } else {
3580                         fatal("Invalid change type: $f");
3581                 }
3582         }
3583         $self->rmdirs if $_rmdir;
3584         if (@$mods == 0) {
3585                 $self->abort_edit;
3586         } else {
3587                 $self->close_edit;
3588         }
3589         return scalar @$mods;
3590 }
3591
3592 package Git::SVN::Ra;
3593 use vars qw/@ISA $config_dir $_log_window_size/;
3594 use strict;
3595 use warnings;
3596 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3597
3598 BEGIN {
3599         # enforce temporary pool usage for some simple functions
3600         no strict 'refs';
3601         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3602                 my $SUPER = "SUPER::$f";
3603                 *$f = sub {
3604                         my $self = shift;
3605                         my $pool = SVN::Pool->new;
3606                         my @ret = $self->$SUPER(@_,$pool);
3607                         $pool->clear;
3608                         wantarray ? @ret : $ret[0];
3609                 };
3610         }
3611 }
3612
3613 sub _auth_providers () {
3614         [
3615           SVN::Client::get_simple_provider(),
3616           SVN::Client::get_ssl_server_trust_file_provider(),
3617           SVN::Client::get_simple_prompt_provider(
3618             \&Git::SVN::Prompt::simple, 2),
3619           SVN::Client::get_ssl_client_cert_file_provider(),
3620           SVN::Client::get_ssl_client_cert_prompt_provider(
3621             \&Git::SVN::Prompt::ssl_client_cert, 2),
3622           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3623             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3624           SVN::Client::get_username_provider(),
3625           SVN::Client::get_ssl_server_trust_prompt_provider(
3626             \&Git::SVN::Prompt::ssl_server_trust),
3627           SVN::Client::get_username_prompt_provider(
3628             \&Git::SVN::Prompt::username, 2)
3629         ]
3630 }
3631
3632 sub escape_uri_only {
3633         my ($uri) = @_;
3634         my @tmp;
3635         foreach (split m{/}, $uri) {
3636                 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3637                 push @tmp, $_;
3638         }
3639         join('/', @tmp);
3640 }
3641
3642 sub escape_url {
3643         my ($url) = @_;
3644         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3645                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3646                 $url = "$scheme://$domain$uri";
3647         }
3648         $url;
3649 }
3650
3651 sub new {
3652         my ($class, $url) = @_;
3653         $url =~ s!/+$!!;
3654         return $RA if ($RA && $RA->{url} eq $url);
3655
3656         SVN::_Core::svn_config_ensure($config_dir, undef);
3657         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3658         my $config = SVN::Core::config_get_config($config_dir);
3659         $RA = undef;
3660         my $dont_store_passwords = 1;
3661         my $conf_t = ${$config}{'config'};
3662         {
3663                 no warnings 'once';
3664                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3665                 # produces warnings that variables are used only once.
3666                 # I had not found the better way to shut them up, so
3667                 # the warnings of type 'once' are disabled in this block.
3668                 if (SVN::_Core::svn_config_get_bool($conf_t,
3669                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3670                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3671                     1) == 0) {
3672                         SVN::_Core::svn_auth_set_parameter($baton,
3673                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3674                             bless (\$dont_store_passwords, "_p_void"));
3675                 }
3676                 if (SVN::_Core::svn_config_get_bool($conf_t,
3677                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3678                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3679                     1) == 0) {
3680                         $Git::SVN::Prompt::_no_auth_cache = 1;
3681                 }
3682         } # no warnings 'once'
3683         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3684                               config => $config,
3685                               pool => SVN::Pool->new,
3686                               auth_provider_callbacks => $callbacks);
3687         $self->{url} = $url;
3688         $self->{svn_path} = $url;
3689         $self->{repos_root} = $self->get_repos_root;
3690         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3691         $self->{cache} = { check_path => { r => 0, data => {} },
3692                            get_dir => { r => 0, data => {} } };
3693         $RA = bless $self, $class;
3694 }
3695
3696 sub check_path {
3697         my ($self, $path, $r) = @_;
3698         my $cache = $self->{cache}->{check_path};
3699         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3700                 return $cache->{data}->{$path};
3701         }
3702         my $pool = SVN::Pool->new;
3703         my $t = $self->SUPER::check_path($path, $r, $pool);
3704         $pool->clear;
3705         if ($r != $cache->{r}) {
3706                 %{$cache->{data}} = ();
3707                 $cache->{r} = $r;
3708         }
3709         $cache->{data}->{$path} = $t;
3710 }
3711
3712 sub get_dir {
3713         my ($self, $dir, $r) = @_;
3714         my $cache = $self->{cache}->{get_dir};
3715         if ($r == $cache->{r}) {
3716                 if (my $x = $cache->{data}->{$dir}) {
3717                         return wantarray ? @$x : $x->[0];
3718                 }
3719         }
3720         my $pool = SVN::Pool->new;
3721         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3722         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3723         $pool->clear;
3724         if ($r != $cache->{r}) {
3725                 %{$cache->{data}} = ();
3726                 $cache->{r} = $r;
3727         }
3728         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3729         wantarray ? (\%dirents, $r, $props) : \%dirents;
3730 }
3731
3732 sub DESTROY {
3733         # do not call the real DESTROY since we store ourselves in $RA
3734 }
3735
3736 sub get_log {
3737         my ($self, @args) = @_;
3738         my $pool = SVN::Pool->new;
3739         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3740         my $ret = $self->SUPER::get_log(@args, $pool);
3741         $pool->clear;
3742         $ret;
3743 }
3744
3745 sub trees_match {
3746         my ($self, $url1, $rev1, $url2, $rev2) = @_;
3747         my $ctx = SVN::Client->new(auth => _auth_providers);
3748         my $out = IO::File->new_tmpfile;
3749
3750         # older SVN (1.1.x) doesn't take $pool as the last parameter for
3751         # $ctx->diff(), so we'll create a default one
3752         my $pool = SVN::Pool->new_default_sub;
3753
3754         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3755         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3756         $out->flush;
3757         my $ret = (($out->stat)[7] == 0);
3758         close $out or croak $!;
3759
3760         $ret;
3761 }
3762
3763 sub get_commit_editor {
3764         my ($self, $log, $cb, $pool) = @_;
3765         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3766         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3767 }
3768
3769 sub gs_do_update {
3770         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3771         my $new = ($rev_a == $rev_b);
3772         my $path = $gs->{path};
3773
3774         if ($new && -e $gs->{index}) {
3775                 unlink $gs->{index} or die
3776                   "Couldn't unlink index: $gs->{index}: $!\n";
3777         }
3778         my $pool = SVN::Pool->new;
3779         $editor->set_path_strip($path);
3780         my (@pc) = split m#/#, $path;
3781         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3782                                         1, $editor, $pool);
3783         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3784
3785         # Since we can't rely on svn_ra_reparent being available, we'll
3786         # just have to do some magic with set_path to make it so
3787         # we only want a partial path.
3788         my $sp = '';
3789         my $final = join('/', @pc);
3790         while (@pc) {
3791                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3792                 $sp .= '/' if length $sp;
3793                 $sp .= shift @pc;
3794         }
3795         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3796
3797         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3798
3799         $reporter->finish_report($pool);
3800         $pool->clear;
3801         $editor->{git_commit_ok};
3802 }
3803
3804 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3805 # svn_ra_reparent didn't work before 1.4)
3806 sub gs_do_switch {
3807         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3808         my $path = $gs->{path};
3809         my $pool = SVN::Pool->new;
3810
3811         my $full_url = $self->{url};
3812         my $old_url = $full_url;
3813         $full_url .= '/' . escape_uri_only($path) if length $path;
3814         my ($ra, $reparented);
3815         if ($old_url ne $full_url) {
3816                 if ($old_url !~ m#^svn(\+ssh)?://#) {
3817                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3818                                                   $pool);
3819                         $self->{url} = $full_url;
3820                         $reparented = 1;
3821                 } else {
3822                         $_[0] = undef;
3823                         $self = undef;
3824                         $RA = undef;
3825                         $ra = Git::SVN::Ra->new($full_url);
3826                         $ra_invalid = 1;
3827                 }
3828         }
3829         $ra ||= $self;
3830         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3831         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3832         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3833         $reporter->finish_report($pool);
3834
3835         if ($reparented) {
3836                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3837                 $self->{url} = $old_url;
3838         }
3839
3840         $pool->clear;
3841         $editor->{git_commit_ok};
3842 }
3843
3844 sub longest_common_path {
3845         my ($gsv, $globs) = @_;
3846         my %common;
3847         my $common_max = scalar @$gsv;
3848
3849         foreach my $gs (@$gsv) {
3850                 my @tmp = split m#/#, $gs->{path};
3851                 my $p = '';
3852                 foreach (@tmp) {
3853                         $p .= length($p) ? "/$_" : $_;
3854                         $common{$p} ||= 0;
3855                         $common{$p}++;
3856                 }
3857         }
3858         $globs ||= [];
3859         $common_max += scalar @$globs;
3860         foreach my $glob (@$globs) {
3861                 my @tmp = split m#/#, $glob->{path}->{left};
3862                 my $p = '';
3863                 foreach (@tmp) {
3864                         $p .= length($p) ? "/$_" : $_;
3865                         $common{$p} ||= 0;
3866                         $common{$p}++;
3867                 }
3868         }
3869
3870         my $longest_path = '';
3871         foreach (sort {length $b <=> length $a} keys %common) {
3872                 if ($common{$_} == $common_max) {
3873                         $longest_path = $_;
3874                         last;
3875                 }
3876         }
3877         $longest_path;
3878 }
3879
3880 sub gs_fetch_loop_common {
3881         my ($self, $base, $head, $gsv, $globs) = @_;
3882         return if ($base > $head);
3883         my $inc = $_log_window_size;
3884         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3885         my $longest_path = longest_common_path($gsv, $globs);
3886         my $ra_url = $self->{url};
3887         while (1) {
3888                 my %revs;
3889                 my $err;
3890                 my $err_handler = $SVN::Error::handler;
3891                 $SVN::Error::handler = sub {
3892                         ($err) = @_;
3893                         skip_unknown_revs($err);
3894                 };
3895                 sub _cb {
3896                         my ($paths, $r, $author, $date, $log) = @_;
3897                         [ dup_changed_paths($paths),
3898                           { author => $author, date => $date, log => $log } ];
3899                 }
3900                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3901                                sub { $revs{$_[1]} = _cb(@_) });
3902                 if ($err && $max >= $head) {
3903                         print STDERR "Path '$longest_path' ",
3904                                      "was probably deleted:\n",
3905                                      $err->expanded_message,
3906                                      "\nWill attempt to follow ",
3907                                      "revisions r$min .. r$max ",
3908                                      "committed before the deletion\n";
3909                         my $hi = $max;
3910                         while (--$hi >= $min) {
3911                                 my $ok;
3912                                 $self->get_log([$longest_path], $min, $hi,
3913                                                0, 1, 1, sub {
3914                                                $ok ||= $_[1];
3915                                                $revs{$_[1]} = _cb(@_) });
3916                                 if ($ok) {
3917                                         print STDERR "r$min .. r$ok OK\n";
3918                                         last;
3919                                 }
3920                         }
3921                 }
3922                 $SVN::Error::handler = $err_handler;
3923
3924                 my %exists = map { $_->{path} => $_ } @$gsv;
3925                 foreach my $r (sort {$a <=> $b} keys %revs) {
3926                         my ($paths, $logged) = @{$revs{$r}};
3927
3928                         foreach my $gs ($self->match_globs(\%exists, $paths,
3929                                                            $globs, $r)) {
3930                                 if ($gs->rev_map_max >= $r) {
3931                                         next;
3932                                 }
3933                                 next unless $gs->match_paths($paths, $r);
3934                                 $gs->{logged_rev_props} = $logged;
3935                                 if (my $last_commit = $gs->last_commit) {
3936                                         $gs->assert_index_clean($last_commit);
3937                                 }
3938                                 my $log_entry = $gs->do_fetch($paths, $r);
3939                                 if ($log_entry) {
3940                                         $gs->do_git_commit($log_entry);
3941                                 }
3942                         }
3943                         foreach my $g (@$globs) {
3944                                 my $k = "svn-remote.$g->{remote}." .
3945                                         "$g->{t}-maxRev";
3946                                 Git::SVN::tmp_config($k, $r);
3947                         }
3948                         if ($ra_invalid) {
3949                                 $_[0] = undef;
3950                                 $self = undef;
3951                                 $RA = undef;
3952                                 $self = Git::SVN::Ra->new($ra_url);
3953                                 $ra_invalid = undef;
3954                         }
3955                 }
3956                 # pre-fill the .rev_db since it'll eventually get filled in
3957                 # with '0' x40 if something new gets committed
3958                 foreach my $gs (@$gsv) {
3959                         next if $gs->rev_map_max >= $max;
3960                         next if defined $gs->rev_map_get($max);
3961                         $gs->rev_map_set($max, 0 x40);
3962                 }
3963                 foreach my $g (@$globs) {
3964                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3965                         Git::SVN::tmp_config($k, $max);
3966                 }
3967                 last if $max >= $head;
3968                 $min = $max + 1;
3969                 $max += $inc;
3970                 $max = $head if ($max > $head);
3971         }
3972 }
3973
3974 sub match_globs {
3975         my ($self, $exists, $paths, $globs, $r) = @_;
3976
3977         sub get_dir_check {
3978                 my ($self, $exists, $g, $r) = @_;
3979                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3980                 return unless scalar @x == 3;
3981                 my $dirents = $x[0];
3982                 foreach my $de (keys %$dirents) {
3983                         next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3984                         my $p = $g->{path}->full_path($de);
3985                         next if $exists->{$p};
3986                         next if (length $g->{path}->{right} &&
3987                                  ($self->check_path($p, $r) !=
3988                                   $SVN::Node::dir));
3989                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3990                                          $g->{ref}->full_path($de), 1);
3991                 }
3992         }
3993         foreach my $g (@$globs) {
3994                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3995                         if ($path->{action} =~ /^[AR]$/) {
3996                                 get_dir_check($self, $exists, $g, $r);
3997                         }
3998                 }
3999                 foreach (keys %$paths) {
4000                         if (/$g->{path}->{left_regex}/ &&
4001                             !/$g->{path}->{regex}/) {
4002                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4003                                 get_dir_check($self, $exists, $g, $r);
4004                         }
4005                         next unless /$g->{path}->{regex}/;
4006                         my $p = $1;
4007                         my $pathname = $g->{path}->full_path($p);
4008                         next if $exists->{$pathname};
4009                         next if ($self->check_path($pathname, $r) !=
4010                                  $SVN::Node::dir);
4011                         $exists->{$pathname} = Git::SVN->init(
4012                                               $self->{url}, $pathname, undef,
4013                                               $g->{ref}->full_path($p), 1);
4014                 }
4015                 my $c = '';
4016                 foreach (split m#/#, $g->{path}->{left}) {
4017                         $c .= "/$_";
4018                         next unless ($paths->{$c} &&
4019                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4020                         get_dir_check($self, $exists, $g, $r);
4021                 }
4022         }
4023         values %$exists;
4024 }
4025
4026 sub minimize_url {
4027         my ($self) = @_;
4028         return $self->{url} if ($self->{url} eq $self->{repos_root});
4029         my $url = $self->{repos_root};
4030         my @components = split(m!/!, $self->{svn_path});
4031         my $c = '';
4032         do {
4033                 $url .= "/$c" if length $c;
4034                 eval { (ref $self)->new($url)->get_latest_revnum };
4035         } while ($@ && ($c = shift @components));
4036         $url;
4037 }
4038
4039 sub can_do_switch {
4040         my $self = shift;
4041         unless (defined $can_do_switch) {
4042                 my $pool = SVN::Pool->new;
4043                 my $rep = eval {
4044                         $self->do_switch(1, '', 0, $self->{url},
4045                                          SVN::Delta::Editor->new, $pool);
4046                 };
4047                 if ($@) {
4048                         $can_do_switch = 0;
4049                 } else {
4050                         $rep->abort_report($pool);
4051                         $can_do_switch = 1;
4052                 }
4053                 $pool->clear;
4054         }
4055         $can_do_switch;
4056 }
4057
4058 sub skip_unknown_revs {
4059         my ($err) = @_;
4060         my $errno = $err->apr_err();
4061         # Maybe the branch we're tracking didn't
4062         # exist when the repo started, so it's
4063         # not an error if it doesn't, just continue
4064         #
4065         # Wonderfully consistent library, eh?
4066         # 160013 - svn:// and file://
4067         # 175002 - http(s)://
4068         # 175007 - http(s):// (this repo required authorization, too...)
4069         #   More codes may be discovered later...
4070         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4071                 my $err_key = $err->expanded_message;
4072                 # revision numbers change every time, filter them out
4073                 $err_key =~ s/\d+/\0/g;
4074                 $err_key = "$errno\0$err_key";
4075                 unless ($ignored_err{$err_key}) {
4076                         warn "W: Ignoring error from SVN, path probably ",
4077                              "does not exist: ($errno): ",
4078                              $err->expanded_message,"\n";
4079                         $ignored_err{$err_key} = 1;
4080                 }
4081                 return;
4082         }
4083         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4084 }
4085
4086 # svn_log_changed_path_t objects passed to get_log are likely to be
4087 # overwritten even if only the refs are copied to an external variable,
4088 # so we should dup the structures in their entirety.  Using an externally
4089 # passed pool (instead of our temporary and quickly cleared pool in
4090 # Git::SVN::Ra) does not help matters at all...
4091 sub dup_changed_paths {
4092         my ($paths) = @_;
4093         return undef unless $paths;
4094         my %ret;
4095         foreach my $p (keys %$paths) {
4096                 my $i = $paths->{$p};
4097                 my %s = map { $_ => $i->$_ }
4098                               qw/copyfrom_path copyfrom_rev action/;
4099                 $ret{$p} = \%s;
4100         }
4101         \%ret;
4102 }
4103
4104 package Git::SVN::Log;
4105 use strict;
4106 use warnings;
4107 use POSIX qw/strftime/;
4108 use constant commit_log_separator => ('-' x 72) . "\n";
4109 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4110             %rusers $show_commit $incremental/;
4111 my $l_fmt;
4112
4113 sub cmt_showable {
4114         my ($c) = @_;
4115         return 1 if defined $c->{r};
4116
4117         # big commit message got truncated by the 16k pretty buffer in rev-list
4118         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4119                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4120                 @{$c->{l}} = ();
4121                 my @log = command(qw/cat-file commit/, $c->{c});
4122
4123                 # shift off the headers
4124                 shift @log while ($log[0] ne '');
4125                 shift @log;
4126
4127                 # TODO: make $c->{l} not have a trailing newline in the future
4128                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4129
4130                 (undef, $c->{r}, undef) = ::extract_metadata(
4131                                 (grep(/^git-svn-id: /, @log))[-1]);
4132         }
4133         return defined $c->{r};
4134 }
4135
4136 sub log_use_color {
4137         return $color || Git->repository->get_colorbool('color.diff');
4138 }
4139
4140 sub git_svn_log_cmd {
4141         my ($r_min, $r_max, @args) = @_;
4142         my $head = 'HEAD';
4143         my (@files, @log_opts);
4144         foreach my $x (@args) {
4145                 if ($x eq '--' || @files) {
4146                         push @files, $x;
4147                 } else {
4148                         if (::verify_ref("$x^0")) {
4149                                 $head = $x;
4150                         } else {
4151                                 push @log_opts, $x;
4152                         }
4153                 }
4154         }
4155
4156         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4157         $gs ||= Git::SVN->_new;
4158         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4159                    $gs->refname);
4160         push @cmd, '-r' unless $non_recursive;
4161         push @cmd, qw/--raw --name-status/ if $verbose;
4162         push @cmd, '--color' if log_use_color();
4163         push @cmd, @log_opts;
4164         if (defined $r_max && $r_max == $r_min) {
4165                 push @cmd, '--max-count=1';
4166                 if (my $c = $gs->rev_map_get($r_max)) {
4167                         push @cmd, $c;
4168                 }
4169         } elsif (defined $r_max) {
4170                 if ($r_max < $r_min) {
4171                         ($r_min, $r_max) = ($r_max, $r_min);
4172                 }
4173                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4174                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4175                 # If there are no commits in the range, both $c_max and $c_min
4176                 # will be undefined.  If there is at least 1 commit in the
4177                 # range, both will be defined.
4178                 return () if !defined $c_min || !defined $c_max;
4179                 if ($c_min eq $c_max) {
4180                         push @cmd, '--max-count=1', $c_min;
4181                 } else {
4182                         push @cmd, '--boundary', "$c_min..$c_max";
4183                 }
4184         }
4185         return (@cmd, @files);
4186 }
4187
4188 # adapted from pager.c
4189 sub config_pager {
4190         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4191         if (!defined $pager) {
4192                 $pager = 'less';
4193         } elsif (length $pager == 0 || $pager eq 'cat') {
4194                 $pager = undef;
4195         }
4196         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4197 }
4198
4199 sub run_pager {
4200         return unless -t *STDOUT && defined $pager;
4201         pipe my $rfd, my $wfd or return;
4202         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4203         if (!$pid) {
4204                 open STDOUT, '>&', $wfd or
4205                                      ::fatal "Can't redirect to stdout: $!";
4206                 return;
4207         }
4208         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4209         $ENV{LESS} ||= 'FRSX';
4210         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4211 }
4212
4213 sub format_svn_date {
4214         return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4215 }
4216
4217 sub parse_git_date {
4218         my ($t, $tz) = @_;
4219         # Date::Parse isn't in the standard Perl distro :(
4220         if ($tz =~ s/^\+//) {
4221                 $t += tz_to_s_offset($tz);
4222         } elsif ($tz =~ s/^\-//) {
4223                 $t -= tz_to_s_offset($tz);
4224         }
4225         return $t;
4226 }
4227
4228 sub set_local_timezone {
4229         if (defined $TZ) {
4230                 $ENV{TZ} = $TZ;
4231         } else {
4232                 delete $ENV{TZ};
4233         }
4234 }
4235
4236 sub tz_to_s_offset {
4237         my ($tz) = @_;
4238         $tz =~ s/(\d\d)$//;
4239         return ($1 * 60) + ($tz * 3600);
4240 }
4241
4242 sub get_author_info {
4243         my ($dest, $author, $t, $tz) = @_;
4244         $author =~ s/(?:^\s*|\s*$)//g;
4245         $dest->{a_raw} = $author;
4246         my $au;
4247         if ($::_authors) {
4248                 $au = $rusers{$author} || undef;
4249         }
4250         if (!$au) {
4251                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4252         }
4253         $dest->{t} = $t;
4254         $dest->{tz} = $tz;
4255         $dest->{a} = $au;
4256         $dest->{t_utc} = parse_git_date($t, $tz);
4257 }
4258
4259 sub process_commit {
4260         my ($c, $r_min, $r_max, $defer) = @_;
4261         if (defined $r_min && defined $r_max) {
4262                 if ($r_min == $c->{r} && $r_min == $r_max) {
4263                         show_commit($c);
4264                         return 0;
4265                 }
4266                 return 1 if $r_min == $r_max;
4267                 if ($r_min < $r_max) {
4268                         # we need to reverse the print order
4269                         return 0 if (defined $limit && --$limit < 0);
4270                         push @$defer, $c;
4271                         return 1;
4272                 }
4273                 if ($r_min != $r_max) {
4274                         return 1 if ($r_min < $c->{r});
4275                         return 1 if ($r_max > $c->{r});
4276                 }
4277         }
4278         return 0 if (defined $limit && --$limit < 0);
4279         show_commit($c);
4280         return 1;
4281 }
4282
4283 sub show_commit {
4284         my $c = shift;
4285         if ($oneline) {
4286                 my $x = "\n";
4287                 if (my $l = $c->{l}) {
4288                         while ($l->[0] =~ /^\s*$/) { shift @$l }
4289                         $x = $l->[0];
4290                 }
4291                 $l_fmt ||= 'A' . length($c->{r});
4292                 print 'r',pack($l_fmt, $c->{r}),' | ';
4293                 print "$c->{c} | " if $show_commit;
4294                 print $x;
4295         } else {
4296                 show_commit_normal($c);
4297         }
4298 }
4299
4300 sub show_commit_changed_paths {
4301         my ($c) = @_;
4302         return unless $c->{changed};
4303         print "Changed paths:\n", @{$c->{changed}};
4304 }
4305
4306 sub show_commit_normal {
4307         my ($c) = @_;
4308         print commit_log_separator, "r$c->{r} | ";
4309         print "$c->{c} | " if $show_commit;
4310         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4311         my $nr_line = 0;
4312
4313         if (my $l = $c->{l}) {
4314                 while ($l->[$#$l] eq "\n" && $#$l > 0
4315                                           && $l->[($#$l - 1)] eq "\n") {
4316                         pop @$l;
4317                 }
4318                 $nr_line = scalar @$l;
4319                 if (!$nr_line) {
4320                         print "1 line\n\n\n";
4321                 } else {
4322                         if ($nr_line == 1) {
4323                                 $nr_line = '1 line';
4324                         } else {
4325                                 $nr_line .= ' lines';
4326                         }
4327                         print $nr_line, "\n";
4328                         show_commit_changed_paths($c);
4329                         print "\n";
4330                         print $_ foreach @$l;
4331                 }
4332         } else {
4333                 print "1 line\n";
4334                 show_commit_changed_paths($c);
4335                 print "\n";
4336
4337         }
4338         foreach my $x (qw/raw stat diff/) {
4339                 if ($c->{$x}) {
4340                         print "\n";
4341                         print $_ foreach @{$c->{$x}}
4342                 }
4343         }
4344 }
4345
4346 sub cmd_show_log {
4347         my (@args) = @_;
4348         my ($r_min, $r_max);
4349         my $r_last = -1; # prevent dupes
4350         set_local_timezone();
4351         if (defined $::_revision) {
4352                 if ($::_revision =~ /^(\d+):(\d+)$/) {
4353                         ($r_min, $r_max) = ($1, $2);
4354                 } elsif ($::_revision =~ /^\d+$/) {
4355                         $r_min = $r_max = $::_revision;
4356                 } else {
4357                         ::fatal "-r$::_revision is not supported, use ",
4358                                 "standard 'git log' arguments instead";
4359                 }
4360         }
4361
4362         config_pager();
4363         @args = git_svn_log_cmd($r_min, $r_max, @args);
4364         if (!@args) {
4365                 print commit_log_separator unless $incremental || $oneline;
4366                 return;
4367         }
4368         my $log = command_output_pipe(@args);
4369         run_pager();
4370         my (@k, $c, $d, $stat);
4371         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4372         while (<$log>) {
4373                 if (/^${esc_color}commit -?($::sha1_short)/o) {
4374                         my $cmt = $1;
4375                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4376                                 $r_last = $c->{r};
4377                                 process_commit($c, $r_min, $r_max, \@k) or
4378                                                                 goto out;
4379                         }
4380                         $d = undef;
4381                         $c = { c => $cmt };
4382                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4383                         get_author_info($c, $1, $2, $3);
4384                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4385                         # ignore
4386                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4387                         push @{$c->{raw}}, $_;
4388                 } elsif (/^${esc_color}[ACRMDT]\t/) {
4389                         # we could add $SVN->{svn_path} here, but that requires
4390                         # remote access at the moment (repo_path_split)...
4391                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
4392                         push @{$c->{changed}}, $_;
4393                 } elsif (/^${esc_color}diff /o) {
4394                         $d = 1;
4395                         push @{$c->{diff}}, $_;
4396                 } elsif ($d) {
4397                         push @{$c->{diff}}, $_;
4398                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4399                           $esc_color*[\+\-]*$esc_color$/x) {
4400                         $stat = 1;
4401                         push @{$c->{stat}}, $_;
4402                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4403                         push @{$c->{stat}}, $_;
4404                         $stat = undef;
4405                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
4406                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4407                 } elsif (s/^${esc_color}    //o) {
4408                         push @{$c->{l}}, $_;
4409                 }
4410         }
4411         if ($c && defined $c->{r} && $c->{r} != $r_last) {
4412                 $r_last = $c->{r};
4413                 process_commit($c, $r_min, $r_max, \@k);
4414         }
4415         if (@k) {
4416                 ($r_min, $r_max) = ($r_max, $r_min);
4417                 process_commit($_, $r_min, $r_max) foreach reverse @k;
4418         }
4419 out:
4420         close $log;
4421         print commit_log_separator unless $incremental || $oneline;
4422 }
4423
4424 package Git::SVN::Migration;
4425 # these version numbers do NOT correspond to actual version numbers
4426 # of git nor git-svn.  They are just relative.
4427 #
4428 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4429 #
4430 # v1 layout: .git/$id/info/url, refs/remotes/$id
4431 #
4432 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4433 #
4434 # v3 layout: .git/svn/$id, refs/remotes/$id
4435 #            - info/url may remain for backwards compatibility
4436 #            - this is what we migrate up to this layout automatically,
4437 #            - this will be used by git svn init on single branches
4438 # v3.1 layout (auto migrated):
4439 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4440 #              for backwards compatibility
4441 #
4442 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4443 #            - this is only created for newly multi-init-ed
4444 #              repositories.  Similar in spirit to the
4445 #              --use-separate-remotes option in git-clone (now default)
4446 #            - we do not automatically migrate to this (following
4447 #              the example set by core git)
4448 #
4449 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4450 #            - newer, more-efficient format that uses 24-bytes per record
4451 #              with no filler space.
4452 #            - use xxd -c24 < .rev_map.$UUID to view and debug
4453 #            - This is a one-way migration, repositories updated to the
4454 #              new format will not be able to use old git-svn without
4455 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
4456 #              possible if noMetadata or useSvmProps are set; but should
4457 #              be no problem for users that use the (sensible) defaults.
4458 use strict;
4459 use warnings;
4460 use Carp qw/croak/;
4461 use File::Path qw/mkpath/;
4462 use File::Basename qw/dirname basename/;
4463 use vars qw/$_minimize/;
4464
4465 sub migrate_from_v0 {
4466         my $git_dir = $ENV{GIT_DIR};
4467         return undef unless -d $git_dir;
4468         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4469         my $migrated = 0;
4470         while (<$fh>) {
4471                 chomp;
4472                 my ($id, $orig_ref) = ($_, $_);
4473                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4474                 next unless -f "$git_dir/$id/info/url";
4475                 my $new_ref = "refs/remotes/$id";
4476                 if (::verify_ref("$new_ref^0")) {
4477                         print STDERR "W: $orig_ref is probably an old ",
4478                                      "branch used by an ancient version of ",
4479                                      "git-svn.\n",
4480                                      "However, $new_ref also exists.\n",
4481                                      "We will not be able ",
4482                                      "to use this branch until this ",
4483                                      "ambiguity is resolved.\n";
4484                         next;
4485                 }
4486                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4487                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4488                 command_noisy('update-ref', $new_ref, $orig_ref);
4489                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4490                 $migrated++;
4491         }
4492         command_close_pipe($fh, $ctx);
4493         print STDERR "Done migrating from v0 layout...\n" if $migrated;
4494         $migrated;
4495 }
4496
4497 sub migrate_from_v1 {
4498         my $git_dir = $ENV{GIT_DIR};
4499         my $migrated = 0;
4500         return $migrated unless -d $git_dir;
4501         my $svn_dir = "$git_dir/svn";
4502
4503         # just in case somebody used 'svn' as their $id at some point...
4504         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4505
4506         print STDERR "Migrating from a git-svn v1 layout...\n";
4507         mkpath([$svn_dir]);
4508         print STDERR "Data from a previous version of git-svn exists, but\n\t",
4509                      "$svn_dir\n\t(required for this version ",
4510                      "($::VERSION) of git-svn) does not. exist\n";
4511         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4512         while (<$fh>) {
4513                 my $x = $_;
4514                 next unless $x =~ s#^refs/remotes/##;
4515                 chomp $x;
4516                 next unless -f "$git_dir/$x/info/url";
4517                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4518                 next unless $u;
4519                 my $dn = dirname("$git_dir/svn/$x");
4520                 mkpath([$dn]) unless -d $dn;
4521                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4522                         mkpath(["$git_dir/svn/svn"]);
4523                         print STDERR " - $git_dir/$x/info => ",
4524                                         "$git_dir/svn/$x/info\n";
4525                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4526                                croak "$!: $x";
4527                         # don't worry too much about these, they probably
4528                         # don't exist with repos this old (save for index,
4529                         # and we can easily regenerate that)
4530                         foreach my $f (qw/unhandled.log index .rev_db/) {
4531                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4532                         }
4533                 } else {
4534                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4535                         rename "$git_dir/$x", "$git_dir/svn/$x" or
4536                                croak "$!: $x";
4537                 }
4538                 $migrated++;
4539         }
4540         command_close_pipe($fh, $ctx);
4541         print STDERR "Done migrating from a git-svn v1 layout\n";
4542         $migrated;
4543 }
4544
4545 sub read_old_urls {
4546         my ($l_map, $pfx, $path) = @_;
4547         my @dir;
4548         foreach (<$path/*>) {
4549                 if (-r "$_/info/url") {
4550                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4551                         my $ref_id = $pfx . basename $_;
4552                         my $url = ::file_to_s("$_/info/url");
4553                         $l_map->{$ref_id} = $url;
4554                 } elsif (-d $_) {
4555                         push @dir, $_;
4556                 }
4557         }
4558         foreach (@dir) {
4559                 my $x = $_;
4560                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4561                 read_old_urls($l_map, $x, $_);
4562         }
4563 }
4564
4565 sub migrate_from_v2 {
4566         my @cfg = command(qw/config -l/);
4567         return if grep /^svn-remote\..+\.url=/, @cfg;
4568         my %l_map;
4569         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4570         my $migrated = 0;
4571
4572         foreach my $ref_id (sort keys %l_map) {
4573                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4574                 if ($@) {
4575                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4576                 }
4577                 $migrated++;
4578         }
4579         $migrated;
4580 }
4581
4582 sub minimize_connections {
4583         my $r = Git::SVN::read_all_remotes();
4584         my $new_urls = {};
4585         my $root_repos = {};
4586         foreach my $repo_id (keys %$r) {
4587                 my $url = $r->{$repo_id}->{url} or next;
4588                 my $fetch = $r->{$repo_id}->{fetch} or next;
4589                 my $ra = Git::SVN::Ra->new($url);
4590
4591                 # skip existing cases where we already connect to the root
4592                 if (($ra->{url} eq $ra->{repos_root}) ||
4593                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4594                      $repo_id)) {
4595                         $root_repos->{$ra->{url}} = $repo_id;
4596                         next;
4597                 }
4598
4599                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4600                 my $root_path = $ra->{url};
4601                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4602                 foreach my $path (keys %$fetch) {
4603                         my $ref_id = $fetch->{$path};
4604                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4605
4606                         # make sure we can read when connecting to
4607                         # a higher level of a repository
4608                         my ($last_rev, undef) = $gs->last_rev_commit;
4609                         if (!defined $last_rev) {
4610                                 $last_rev = eval {
4611                                         $root_ra->get_latest_revnum;
4612                                 };
4613                                 next if $@;
4614                         }
4615                         my $new = $root_path;
4616                         $new .= length $path ? "/$path" : '';
4617                         eval {
4618                                 $root_ra->get_log([$new], $last_rev, $last_rev,
4619                                                   0, 0, 1, sub { });
4620                         };
4621                         next if $@;
4622                         $new_urls->{$ra->{repos_root}}->{$new} =
4623                                 { ref_id => $ref_id,
4624                                   old_repo_id => $repo_id,
4625                                   old_path => $path };
4626                 }
4627         }
4628
4629         my @emptied;
4630         foreach my $url (keys %$new_urls) {
4631                 # see if we can re-use an existing [svn-remote "repo_id"]
4632                 # instead of creating a(n ugly) new section:
4633                 my $repo_id = $root_repos->{$url} ||
4634                               Git::SVN::sanitize_remote_name($url);
4635
4636                 my $fetch = $new_urls->{$url};
4637                 foreach my $path (keys %$fetch) {
4638                         my $x = $fetch->{$path};
4639                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4640                         my $pfx = "svn-remote.$x->{old_repo_id}";
4641
4642                         my $old_fetch = quotemeta("$x->{old_path}:".
4643                                                   "refs/remotes/$x->{ref_id}");
4644                         command_noisy(qw/config --unset/,
4645                                       "$pfx.fetch", '^'. $old_fetch . '$');
4646                         delete $r->{$x->{old_repo_id}}->
4647                                {fetch}->{$x->{old_path}};
4648                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4649                                 command_noisy(qw/config --unset/,
4650                                               "$pfx.url");
4651                                 push @emptied, $x->{old_repo_id}
4652                         }
4653                 }
4654         }
4655         if (@emptied) {
4656                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4657                            "$ENV{GIT_DIR}/config";
4658                 print STDERR <<EOF;
4659 The following [svn-remote] sections in your config file ($file) are empty
4660 and can be safely removed:
4661 EOF
4662                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4663         }
4664 }
4665
4666 sub migration_check {
4667         migrate_from_v0();
4668         migrate_from_v1();
4669         migrate_from_v2();
4670         minimize_connections() if $_minimize;
4671 }
4672
4673 package Git::IndexInfo;
4674 use strict;
4675 use warnings;
4676 use Git qw/command_input_pipe command_close_pipe/;
4677
4678 sub new {
4679         my ($class) = @_;
4680         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4681         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4682 }
4683
4684 sub remove {
4685         my ($self, $path) = @_;
4686         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4687                 return ++$self->{nr};
4688         }
4689         undef;
4690 }
4691
4692 sub update {
4693         my ($self, $mode, $hash, $path) = @_;
4694         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4695                 return ++$self->{nr};
4696         }
4697         undef;
4698 }
4699
4700 sub DESTROY {
4701         my ($self) = @_;
4702         command_close_pipe($self->{gui}, $self->{ctx});
4703 }
4704
4705 package Git::SVN::GlobSpec;
4706 use strict;
4707 use warnings;
4708
4709 sub new {
4710         my ($class, $glob) = @_;
4711         my $re = $glob;
4712         $re =~ s!/+$!!g; # no need for trailing slashes
4713         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4714         my ($left, $right) = ($1, $2);
4715         if ($nr > 1) {
4716                 die "Only one '*' wildcard expansion ",
4717                     "is supported (got $nr): '$glob'\n";
4718         } elsif ($nr == 0) {
4719                 die "One '*' is needed for glob: '$glob'\n";
4720         }
4721         $re = quotemeta($left) . $re . quotemeta($right);
4722         if (length $left && !($left =~ s!/+$!!g)) {
4723                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4724         }
4725         if (length $right && !($right =~ s!^/+!!g)) {
4726                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4727         }
4728         my $left_re = qr/^\/\Q$left\E(\/|$)/;
4729         bless { left => $left, right => $right, left_regex => $left_re,
4730                 regex => qr/$re/, glob => $glob }, $class;
4731 }
4732
4733 sub full_path {
4734         my ($self, $path) = @_;
4735         return (length $self->{left} ? "$self->{left}/" : '') .
4736                $path . (length $self->{right} ? "/$self->{right}" : '');
4737 }
4738
4739 __END__
4740
4741 Data structures:
4742
4743
4744 $remotes = { # returned by read_all_remotes()
4745         'svn' => {
4746                 # svn-remote.svn.url=https://svn.musicpd.org
4747                 url => 'https://svn.musicpd.org',
4748                 # svn-remote.svn.fetch=mpd/trunk:trunk
4749                 fetch => {
4750                         'mpd/trunk' => 'trunk',
4751                 },
4752                 # svn-remote.svn.tags=mpd/tags/*:tags/*
4753                 tags => {
4754                         path => {
4755                                 left => 'mpd/tags',
4756                                 right => '',
4757                                 regex => qr!mpd/tags/([^/]+)$!,
4758                                 glob => 'tags/*',
4759                         },
4760                         ref => {
4761                                 left => 'tags',
4762                                 right => '',
4763                                 regex => qr!tags/([^/]+)$!,
4764                                 glob => 'tags/*',
4765                         },
4766                 }
4767         }
4768 };
4769
4770 $log_entry hashref as returned by libsvn_log_entry()
4771 {
4772         log => 'whitespace-formatted log entry
4773 ',                                              # trailing newline is preserved
4774         revision => '8',                        # integer
4775         date => '2004-02-24T17:01:44.108345Z',  # commit date
4776         author => 'committer name'
4777 };
4778
4779
4780 # this is generated by generate_diff();
4781 @mods = array of diff-index line hashes, each element represents one line
4782         of diff-index output
4783
4784 diff-index line ($m hash)
4785 {
4786         mode_a => first column of diff-index output, no leading ':',
4787         mode_b => second column of diff-index output,
4788         sha1_b => sha1sum of the final blob,
4789         chg => change type [MCRADT],
4790         file_a => original file name of a file (iff chg is 'C' or 'R')
4791         file_b => new/current file name of a file (any chg)
4792 }
4793 ;
4794
4795 # retval of read_url_paths{,_all}();
4796 $l_map = {
4797         # repository root url
4798         'https://svn.musicpd.org' => {
4799                 # repository path               # GIT_SVN_ID
4800                 'mpd/trunk'             =>      'trunk',
4801                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
4802         },
4803 }
4804
4805 Notes:
4806         I don't trust the each() function on unless I created %hash myself
4807         because the internal iterator may not have started at base.