git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --[no-]to               <str>  * Email To:
  51     --[no-]cc               <str>  * Email Cc:
  52     --[no-]bcc              <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  68     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  69
  70   Automating:
  71     --identity              <str>  * Use the sendemail.<id> options.
  72     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  73     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  74     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  75     --[no-]suppress-from           * Send to self. Default off.
  76     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  77     --[no-]thread                  * Use In-Reply-To: field. Default on.
  78
  79   Administering:
  80     --confirm               <str>  * Confirm recipients before sending;
  81                                      auto, cc, compose, always, or never.
  82     --quiet                        * Output one line of info per email.
  83     --dry-run                      * Don't actually send the emails.
  84     --[no-]validate                * Perform patch sanity checks. Default on.
  85     --[no-]format-patch            * understand any non optional arguments as
  86                                      `git format-patch` ones.
  87
  88 EOT
  89         exit(1);
  90 }
  91
  92 # most mail servers generate the Date: header, but not all...
  93 sub format_2822_time {
  94         my ($time) = @_;
  95         my @localtm = localtime($time);
  96         my @gmttm = gmtime($time);
  97         my $localmin = $localtm[1] + $localtm[2] * 60;
  98         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  99         if ($localtm[0] != $gmttm[0]) {
 100                 die "local zone differs from GMT by a non-minute interval\n";
 101         }
 102         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 103                 $localmin += 1440;
 104         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 105                 $localmin -= 1440;
 106         } elsif ($gmttm[6] != $localtm[6]) {
 107                 die "local time offset greater than or equal to 24 hours\n";
 108         }
 109         my $offset = $localmin - $gmtmin;
 110         my $offhour = $offset / 60;
 111         my $offmin = abs($offset % 60);
 112         if (abs($offhour) >= 24) {
 113                 die ("local time offset greater than or equal to 24 hours\n");
 114         }
 115
 116         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 117                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 118                        $localtm[3],
 119                        qw(Jan Feb Mar Apr May Jun
 120                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 121                        $localtm[5]+1900,
 122                        $localtm[2],
 123                        $localtm[1],
 124                        $localtm[0],
 125                        ($offset >= 0) ? '+' : '-',
 126                        abs($offhour),
 127                        $offmin,
 128                        );
 129 }
 130
 131 my $have_email_valid = eval { require Email::Valid; 1 };
 132 my $have_mail_address = eval { require Mail::Address; 1 };
 133 my $smtp;
 134 my $auth;
 135 my $mail_domain_default = "localhost.localdomain";
 136 my $mail_domain;
 137
 138 sub unique_email_list(@);
 139 sub cleanup_compose_files();
 140
 141 # Variables we fill in automatically, or via prompting:
 142 my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 143         $initial_reply_to,$initial_subject,@files,
 144         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 145
 146 my $envelope_sender;
 147
 148 # Example reply to:
 149 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 150
 151 my $repo = eval { Git->repository() };
 152 my @repo = $repo ? ($repo) : ();
 153 my $term = eval {
 154         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 155                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 156                 : new Term::ReadLine 'git-send-email';
 157 };
 158 if ($@) {
 159         $term = new FakeTerm "$@: going non-interactive";
 160 }
 161
 162 # Behavior modification variables
 163 my ($quiet, $dry_run) = (0, 0);
 164 my $format_patch;
 165 my $compose_filename;
 166
 167 # Handle interactive edition of files.
 168 my $multiedit;
 169 my $editor = Git::command_oneline('var', 'GIT_EDITOR');
 170
 171 sub do_edit {
 172         if (defined($multiedit) && !$multiedit) {
 173                 map {
 174                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 175                         if (($? & 127) || ($? >> 8)) {
 176                                 die("the editor exited uncleanly, aborting everything");
 177                         }
 178                 } @_;
 179         } else {
 180                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 181                 if (($? & 127) || ($? >> 8)) {
 182                         die("the editor exited uncleanly, aborting everything");
 183                 }
 184         }
 185 }
 186
 187 # Variables with corresponding config settings
 188 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 189 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 190 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 191 my ($validate, $confirm);
 192 my (@suppress_cc);
 193
 194 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 195
 196 my $not_set_by_user = "true but not set by the user";
 197
 198 my %config_bool_settings = (
 199     "thread" => [\$thread, 1],
 200     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 201     "suppressfrom" => [\$suppress_from, undef],
 202     "signedoffbycc" => [\$signed_off_by_cc, undef],
 203     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 204     "validate" => [\$validate, 1],
 205 );
 206
 207 my %config_settings = (
 208     "smtpserver" => \$smtp_server,
 209     "smtpserverport" => \$smtp_server_port,
 210     "smtpuser" => \$smtp_authuser,
 211     "smtppass" => \$smtp_authpass,
 212     "to" => \@to,
 213     "cc" => \@initial_cc,
 214     "cccmd" => \$cc_cmd,
 215     "aliasfiletype" => \$aliasfiletype,
 216     "bcc" => \@bcclist,
 217     "aliasesfile" => \@alias_files,
 218     "suppresscc" => \@suppress_cc,
 219     "envelopesender" => \$envelope_sender,
 220     "multiedit" => \$multiedit,
 221     "confirm"   => \$confirm,
 222     "from" => \$sender,
 223 );
 224
 225 # Help users prepare for 1.7.0
 226 sub chain_reply_to {
 227         if (defined $chain_reply_to &&
 228             $chain_reply_to eq $not_set_by_user) {
 229                 print STDERR
 230                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 231                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 232                     "you want to keep --chain-reply-to as your default.\n";
 233                 $chain_reply_to = 0;
 234         }
 235         return $chain_reply_to;
 236 }
 237
 238 # Handle Uncouth Termination
 239 sub signal_handler {
 240
 241         # Make text normal
 242         print color("reset"), "\n";
 243
 244         # SMTP password masked
 245         system "stty echo";
 246
 247         # tmp files from --compose
 248         if (defined $compose_filename) {
 249                 if (-e $compose_filename) {
 250                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 251                 }
 252                 if (-e ($compose_filename . ".final")) {
 253                         print "'$compose_filename.final' contains the composed email.\n"
 254                 }
 255         }
 256
 257         exit;
 258 };
 259
 260 $SIG{TERM} = \&signal_handler;
 261 $SIG{INT}  = \&signal_handler;
 262
 263 # Begin by accumulating all the variables (defined above), that we will end up
 264 # needing, first, from the command line:
 265
 266 my $rc = GetOptions("sender|from=s" => \$sender,
 267                     "in-reply-to=s" => \$initial_reply_to,
 268                     "subject=s" => \$initial_subject,
 269                     "to=s" => \@to,
 270                     "no-to" => \$no_to,
 271                     "cc=s" => \@initial_cc,
 272                     "no-cc" => \$no_cc,
 273                     "bcc=s" => \@bcclist,
 274                     "no-bcc" => \$no_bcc,
 275                     "chain-reply-to!" => \$chain_reply_to,
 276                     "smtp-server=s" => \$smtp_server,
 277                     "smtp-server-port=s" => \$smtp_server_port,
 278                     "smtp-user=s" => \$smtp_authuser,
 279                     "smtp-pass:s" => \$smtp_authpass,
 280                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 281                     "smtp-encryption=s" => \$smtp_encryption,
 282                     "smtp-debug:i" => \$debug_net_smtp,
 283                     "smtp-domain:s" => \$mail_domain,
 284                     "identity=s" => \$identity,
 285                     "annotate" => \$annotate,
 286                     "compose" => \$compose,
 287                     "quiet" => \$quiet,
 288                     "cc-cmd=s" => \$cc_cmd,
 289                     "suppress-from!" => \$suppress_from,
 290                     "suppress-cc=s" => \@suppress_cc,
 291                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 292                     "confirm=s" => \$confirm,
 293                     "dry-run" => \$dry_run,
 294                     "envelope-sender=s" => \$envelope_sender,
 295                     "thread!" => \$thread,
 296                     "validate!" => \$validate,
 297                     "format-patch!" => \$format_patch,
 298          );
 299
 300 unless ($rc) {
 301     usage();
 302 }
 303
 304 die "Cannot run git format-patch from outside a repository\n"
 305         if $format_patch and not $repo;
 306
 307 # Now, let's fill any that aren't set in with defaults:
 308
 309 sub read_config {
 310         my ($prefix) = @_;
 311
 312         foreach my $setting (keys %config_bool_settings) {
 313                 my $target = $config_bool_settings{$setting}->[0];
 314                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 315         }
 316
 317         foreach my $setting (keys %config_settings) {
 318                 my $target = $config_settings{$setting};
 319                 next if $setting eq "to" and defined $no_to;
 320                 next if $setting eq "cc" and defined $no_cc;
 321                 next if $setting eq "bcc" and defined $no_bcc;
 322                 if (ref($target) eq "ARRAY") {
 323                         unless (@$target) {
 324                                 my @values = Git::config(@repo, "$prefix.$setting");
 325                                 @$target = @values if (@values && defined $values[0]);
 326                         }
 327                 }
 328                 else {
 329                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 330                 }
 331         }
 332
 333         if (!defined $smtp_encryption) {
 334                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 335                 if (defined $enc) {
 336                         $smtp_encryption = $enc;
 337                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 338                         $smtp_encryption = 'ssl';
 339                 }
 340         }
 341 }
 342
 343 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 344 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 345 read_config("sendemail.$identity") if (defined $identity);
 346 read_config("sendemail");
 347
 348 # fall back on builtin bool defaults
 349 foreach my $setting (values %config_bool_settings) {
 350         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 351 }
 352
 353 # 'default' encryption is none -- this only prevents a warning
 354 $smtp_encryption = '' unless (defined $smtp_encryption);
 355
 356 # Set CC suppressions
 357 my(%suppress_cc);
 358 if (@suppress_cc) {
 359         foreach my $entry (@suppress_cc) {
 360                 die "Unknown --suppress-cc field: '$entry'\n"
 361                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 362                 $suppress_cc{$entry} = 1;
 363         }
 364 }
 365
 366 if ($suppress_cc{'all'}) {
 367         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 368                 $suppress_cc{$entry} = 1;
 369         }
 370         delete $suppress_cc{'all'};
 371 }
 372
 373 # If explicit old-style ones are specified, they trump --suppress-cc.
 374 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 375 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 376
 377 if ($suppress_cc{'body'}) {
 378         foreach my $entry (qw (sob bodycc)) {
 379                 $suppress_cc{$entry} = 1;
 380         }
 381         delete $suppress_cc{'body'};
 382 }
 383
 384 # Set confirm's default value
 385 my $confirm_unconfigured = !defined $confirm;
 386 if ($confirm_unconfigured) {
 387         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 388 };
 389 die "Unknown --confirm setting: '$confirm'\n"
 390         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 391
 392 # Debugging, print out the suppressions.
 393 if (0) {
 394         print "suppressions:\n";
 395         foreach my $entry (keys %suppress_cc) {
 396                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 397         }
 398 }
 399
 400 my ($repoauthor, $repocommitter);
 401 ($repoauthor) = Git::ident_person(@repo, 'author');
 402 ($repocommitter) = Git::ident_person(@repo, 'committer');
 403
 404 # Verify the user input
 405
 406 foreach my $entry (@to) {
 407         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 408 }
 409
 410 foreach my $entry (@initial_cc) {
 411         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 412 }
 413
 414 foreach my $entry (@bcclist) {
 415         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 416 }
 417
 418 sub parse_address_line {
 419         if ($have_mail_address) {
 420                 return map { $_->format } Mail::Address->parse($_[0]);
 421         } else {
 422                 return split_addrs($_[0]);
 423         }
 424 }
 425
 426 sub split_addrs {
 427         return quotewords('\s*,\s*', 1, @_);
 428 }
 429
 430 my %aliases;
 431 my %parse_alias = (
 432         # multiline formats can be supported in the future
 433         mutt => sub { my $fh = shift; while (<$fh>) {
 434                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 435                         my ($alias, $addr) = ($1, $2);
 436                         $addr =~ s/#.*$//; # mutt allows # comments
 437                          # commas delimit multiple addresses
 438                         $aliases{$alias} = [ split_addrs($addr) ];
 439                 }}},
 440         mailrc => sub { my $fh = shift; while (<$fh>) {
 441                 if (/^alias\s+(\S+)\s+(.*)$/) {
 442                         # spaces delimit multiple addresses
 443                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 444                 }}},
 445         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 446                 for (my $x = ''; defined($x); $x = $_) {
 447                         chomp $x;
 448                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 449                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 450                         $aliases{$1} = [ split_addrs($2) ];
 451                 }},
 452         elm => sub  { my $fh = shift;
 453                       while (<$fh>) {
 454                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 455                               my ($alias, $addr) = ($1, $2);
 456                                $aliases{$alias} = [ split_addrs($addr) ];
 457                           }
 458                       } },
 459
 460         gnus => sub { my $fh = shift; while (<$fh>) {
 461                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 462                         $aliases{$1} = [ $2 ];
 463                 }}}
 464 );
 465
 466 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 467         foreach my $file (@alias_files) {
 468                 open my $fh, '<', $file or die "opening $file: $!\n";
 469                 $parse_alias{$aliasfiletype}->($fh);
 470                 close $fh;
 471         }
 472 }
 473
 474 ($sender) = expand_aliases($sender) if defined $sender;
 475
 476 # returns 1 if the conflict must be solved using it as a format-patch argument
 477 sub check_file_rev_conflict($) {
 478         return unless $repo;
 479         my $f = shift;
 480         try {
 481                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 482                 if (defined($format_patch)) {
 483                         return $format_patch;
 484                 }
 485                 die(<<EOF);
 486 File '$f' exists but it could also be the range of commits
 487 to produce patches for.  Please disambiguate by...
 488
 489     * Saying "./$f" if you mean a file; or
 490     * Giving --format-patch option if you mean a range.
 491 EOF
 492         } catch Git::Error::Command with {
 493                 return 0;
 494         }
 495 }
 496
 497 # Now that all the defaults are set, process the rest of the command line
 498 # arguments and collect up the files that need to be processed.
 499 my @rev_list_opts;
 500 while (defined(my $f = shift @ARGV)) {
 501         if ($f eq "--") {
 502                 push @rev_list_opts, "--", @ARGV;
 503                 @ARGV = ();
 504         } elsif (-d $f and !check_file_rev_conflict($f)) {
 505                 opendir(DH,$f)
 506                         or die "Failed to opendir $f: $!";
 507
 508                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 509                                 sort readdir(DH);
 510                 closedir(DH);
 511         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 512                 push @files, $f;
 513         } else {
 514                 push @rev_list_opts, $f;
 515         }
 516 }
 517
 518 if (@rev_list_opts) {
 519         die "Cannot run git format-patch from outside a repository\n"
 520                 unless $repo;
 521         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 522 }
 523
 524 if ($validate) {
 525         foreach my $f (@files) {
 526                 unless (-p $f) {
 527                         my $error = validate_patch($f);
 528                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 529                 }
 530         }
 531 }
 532
 533 if (@files) {
 534         unless ($quiet) {
 535                 print $_,"\n" for (@files);
 536         }
 537 } else {
 538         print STDERR "\nNo patch files specified!\n\n";
 539         usage();
 540 }
 541
 542 sub get_patch_subject($) {
 543         my $fn = shift;
 544         open (my $fh, '<', $fn);
 545         while (my $line = <$fh>) {
 546                 next unless ($line =~ /^Subject: (.*)$/);
 547                 close $fh;
 548                 return "GIT: $1\n";
 549         }
 550         close $fh;
 551         die "No subject line in $fn ?";
 552 }
 553
 554 if ($compose) {
 555         # Note that this does not need to be secure, but we will make a small
 556         # effort to have it be unique
 557         $compose_filename = ($repo ?
 558                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 559                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 560         open(C,">",$compose_filename)
 561                 or die "Failed to open for writing $compose_filename: $!";
 562
 563
 564         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 565         my $tpl_subject = $initial_subject || '';
 566         my $tpl_reply_to = $initial_reply_to || '';
 567
 568         print C <<EOT;
 569 From $tpl_sender # This line is ignored.
 570 GIT: Lines beginning in "GIT:" will be removed.
 571 GIT: Consider including an overall diffstat or table of contents
 572 GIT: for the patch you are writing.
 573 GIT:
 574 GIT: Clear the body content if you don't wish to send a summary.
 575 From: $tpl_sender
 576 Subject: $tpl_subject
 577 In-Reply-To: $tpl_reply_to
 578
 579 EOT
 580         for my $f (@files) {
 581                 print C get_patch_subject($f);
 582         }
 583         close(C);
 584
 585         if ($annotate) {
 586                 do_edit($compose_filename, @files);
 587         } else {
 588                 do_edit($compose_filename);
 589         }
 590
 591         open(C2,">",$compose_filename . ".final")
 592                 or die "Failed to open $compose_filename.final : " . $!;
 593
 594         open(C,"<",$compose_filename)
 595                 or die "Failed to open $compose_filename : " . $!;
 596
 597         my $need_8bit_cte = file_has_nonascii($compose_filename);
 598         my $in_body = 0;
 599         my $summary_empty = 1;
 600         while(<C>) {
 601                 next if m/^GIT:/;
 602                 if ($in_body) {
 603                         $summary_empty = 0 unless (/^\n$/);
 604                 } elsif (/^\n$/) {
 605                         $in_body = 1;
 606                         if ($need_8bit_cte) {
 607                                 print C2 "MIME-Version: 1.0\n",
 608                                          "Content-Type: text/plain; ",
 609                                            "charset=UTF-8\n",
 610                                          "Content-Transfer-Encoding: 8bit\n";
 611                         }
 612                 } elsif (/^MIME-Version:/i) {
 613                         $need_8bit_cte = 0;
 614                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 615                         $initial_subject = $1;
 616                         my $subject = $initial_subject;
 617                         $_ = "Subject: " .
 618                                 ($subject =~ /[^[:ascii:]]/ ?
 619                                  quote_rfc2047($subject) :
 620                                  $subject) .
 621                                 "\n";
 622                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 623                         $initial_reply_to = $1;
 624                         next;
 625                 } elsif (/^From:\s*(.+)\s*$/i) {
 626                         $sender = $1;
 627                         next;
 628                 } elsif (/^(?:To|Cc|Bcc):/i) {
 629                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 630                         next;
 631                 }
 632                 print C2 $_;
 633         }
 634         close(C);
 635         close(C2);
 636
 637         if ($summary_empty) {
 638                 print "Summary email is empty, skipping it\n";
 639                 $compose = -1;
 640         }
 641 } elsif ($annotate) {
 642         do_edit(@files);
 643 }
 644
 645 sub ask {
 646         my ($prompt, %arg) = @_;
 647         my $valid_re = $arg{valid_re};
 648         my $default = $arg{default};
 649         my $resp;
 650         my $i = 0;
 651         return defined $default ? $default : undef
 652                 unless defined $term->IN and defined fileno($term->IN) and
 653                        defined $term->OUT and defined fileno($term->OUT);
 654         while ($i++ < 10) {
 655                 $resp = $term->readline($prompt);
 656                 if (!defined $resp) { # EOF
 657                         print "\n";
 658                         return defined $default ? $default : undef;
 659                 }
 660                 if ($resp eq '' and defined $default) {
 661                         return $default;
 662                 }
 663                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 664                         return $resp;
 665                 }
 666         }
 667         return undef;
 668 }
 669
 670 my $prompting = 0;
 671 if (!defined $sender) {
 672         $sender = $repoauthor || $repocommitter || '';
 673         $sender = ask("Who should the emails appear to be from? [$sender] ",
 674                       default => $sender);
 675         print "Emails will be sent from: ", $sender, "\n";
 676         $prompting++;
 677 }
 678
 679 if (!@to) {
 680         my $to = ask("Who should the emails be sent to? ");
 681         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 682         $prompting++;
 683 }
 684
 685 sub expand_aliases {
 686         return map { expand_one_alias($_) } @_;
 687 }
 688
 689 my %EXPANDED_ALIASES;
 690 sub expand_one_alias {
 691         my $alias = shift;
 692         if ($EXPANDED_ALIASES{$alias}) {
 693                 die "fatal: alias '$alias' expands to itself\n";
 694         }
 695         local $EXPANDED_ALIASES{$alias} = 1;
 696         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 697 }
 698
 699 @to = expand_aliases(@to);
 700 @to = (map { sanitize_address($_) } @to);
 701 @initial_cc = expand_aliases(@initial_cc);
 702 @bcclist = expand_aliases(@bcclist);
 703
 704 if ($thread && !defined $initial_reply_to && $prompting) {
 705         $initial_reply_to = ask(
 706                 "Message-ID to be used as In-Reply-To for the first email? ");
 707 }
 708 if (defined $initial_reply_to) {
 709         $initial_reply_to =~ s/^\s*<?//;
 710         $initial_reply_to =~ s/>?\s*$//;
 711         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 712 }
 713
 714 if (!defined $smtp_server) {
 715         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 716                 if (-x $_) {
 717                         $smtp_server = $_;
 718                         last;
 719                 }
 720         }
 721         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 722 }
 723
 724 if ($compose && $compose > 0) {
 725         @files = ($compose_filename . ".final", @files);
 726 }
 727
 728 # Variables we set as part of the loop over files
 729 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 730         $needs_confirm, $message_num, $ask_default);
 731
 732 sub extract_valid_address {
 733         my $address = shift;
 734         my $local_part_regexp = '[^<>"\s@]+';
 735         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 736
 737         # check for a local address:
 738         return $address if ($address =~ /^($local_part_regexp)$/);
 739
 740         $address =~ s/^\s*<(.*)>\s*$/$1/;
 741         if ($have_email_valid) {
 742                 return scalar Email::Valid->address($address);
 743         } else {
 744                 # less robust/correct than the monster regexp in Email::Valid,
 745                 # but still does a 99% job, and one less dependency
 746                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 747                 return $1;
 748         }
 749 }
 750
 751 # Usually don't need to change anything below here.
 752
 753 # we make a "fake" message id by taking the current number
 754 # of seconds since the beginning of Unix time and tacking on
 755 # a random number to the end, in case we are called quicker than
 756 # 1 second since the last time we were called.
 757
 758 # We'll setup a template for the message id, using the "from" address:
 759
 760 my ($message_id_stamp, $message_id_serial);
 761 sub make_message_id
 762 {
 763         my $uniq;
 764         if (!defined $message_id_stamp) {
 765                 $message_id_stamp = sprintf("%s-%s", time, $$);
 766                 $message_id_serial = 0;
 767         }
 768         $message_id_serial++;
 769         $uniq = "$message_id_stamp-$message_id_serial";
 770
 771         my $du_part;
 772         for ($sender, $repocommitter, $repoauthor) {
 773                 $du_part = extract_valid_address(sanitize_address($_));
 774                 last if (defined $du_part and $du_part ne '');
 775         }
 776         if (not defined $du_part or $du_part eq '') {
 777                 use Sys::Hostname qw();
 778                 $du_part = 'user@' . Sys::Hostname::hostname();
 779         }
 780         my $message_id_template = "<%s-git-send-email-%s>";
 781         $message_id = sprintf($message_id_template, $uniq, $du_part);
 782         #print "new message id = $message_id\n"; # Was useful for debugging
 783 }
 784
 785
 786
 787 $time = time - scalar $#files;
 788
 789 sub unquote_rfc2047 {
 790         local ($_) = @_;
 791         my $encoding;
 792         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 793                 $encoding = $1;
 794                 s/_/ /g;
 795                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 796         }
 797         return wantarray ? ($_, $encoding) : $_;
 798 }
 799
 800 sub quote_rfc2047 {
 801         local $_ = shift;
 802         my $encoding = shift || 'UTF-8';
 803         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 804         s/(.*)/=\?$encoding\?q\?$1\?=/;
 805         return $_;
 806 }
 807
 808 sub is_rfc2047_quoted {
 809         my $s = shift;
 810         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 811         my $encoded_text = '[!->@-~]+';
 812         length($s) <= 75 &&
 813         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 814 }
 815
 816 # use the simplest quoting being able to handle the recipient
 817 sub sanitize_address
 818 {
 819         my ($recipient) = @_;
 820         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 821
 822         if (not $recipient_name) {
 823                 return "$recipient";
 824         }
 825
 826         # if recipient_name is already quoted, do nothing
 827         if (is_rfc2047_quoted($recipient_name)) {
 828                 return $recipient;
 829         }
 830
 831         # rfc2047 is needed if a non-ascii char is included
 832         if ($recipient_name =~ /[^[:ascii:]]/) {
 833                 $recipient_name =~ s/^"(.*)"$/$1/;
 834                 $recipient_name = quote_rfc2047($recipient_name);
 835         }
 836
 837         # double quotes are needed if specials or CTLs are included
 838         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 839                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 840                 $recipient_name = "\"$recipient_name\"";
 841         }
 842
 843         return "$recipient_name $recipient_addr";
 844
 845 }
 846
 847 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 848 #
 849 # Tightly configured MTAa require that a caller sends a real DNS
 850 # domain name that corresponds the IP address in the HELO/EHLO
 851 # handshake. This is used to verify the connection and prevent
 852 # spammers from trying to hide their identity. If the DNS and IP don't
 853 # match, the receiveing MTA may deny the connection.
 854 #
 855 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 856 #
 857 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 858 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 859 #
 860 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 861 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 862
 863 sub maildomain_net
 864 {
 865         my $maildomain;
 866
 867         if (eval { require Net::Domain; 1 }) {
 868                 my $domain = Net::Domain::domainname();
 869                 $maildomain = $domain
 870                         unless $^O eq 'darwin' && $domain =~ /\.local$/;
 871         }
 872
 873         return $maildomain;
 874 }
 875
 876 sub maildomain_mta
 877 {
 878         my $maildomain;
 879
 880         if (eval { require Net::SMTP; 1 }) {
 881                 for my $host (qw(mailhost localhost)) {
 882                         my $smtp = Net::SMTP->new($host);
 883                         if (defined $smtp) {
 884                                 my $domain = $smtp->domain;
 885                                 $smtp->quit;
 886
 887                                 $maildomain = $domain
 888                                         unless $^O eq 'darwin' && $domain =~ /\.local$/;
 889
 890                                 last if $maildomain;
 891                         }
 892                 }
 893         }
 894
 895         return $maildomain;
 896 }
 897
 898 sub maildomain
 899 {
 900         return maildomain_net() || maildomain_mta() || $mail_domain_default;
 901 }
 902
 903 # Returns 1 if the message was sent, and 0 otherwise.
 904 # In actuality, the whole program dies when there
 905 # is an error sending a message.
 906
 907 sub send_message
 908 {
 909         my @recipients = unique_email_list(@to);
 910         @cc = (grep { my $cc = extract_valid_address($_);
 911                       not grep { $cc eq $_ } @recipients
 912                     }
 913                map { sanitize_address($_) }
 914                @cc);
 915         my $to = join (",\n\t", @recipients);
 916         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 917         @recipients = (map { extract_valid_address($_) } @recipients);
 918         my $date = format_2822_time($time++);
 919         my $gitversion = '@@GIT_VERSION@@';
 920         if ($gitversion =~ m/..GIT_VERSION../) {
 921             $gitversion = Git::version();
 922         }
 923
 924         my $cc = join(",\n\t", unique_email_list(@cc));
 925         my $ccline = "";
 926         if ($cc ne '') {
 927                 $ccline = "\nCc: $cc";
 928         }
 929         my $sanitized_sender = sanitize_address($sender);
 930         make_message_id() unless defined($message_id);
 931
 932         my $header = "From: $sanitized_sender
 933 To: $to${ccline}
 934 Subject: $subject
 935 Date: $date
 936 Message-Id: $message_id
 937 X-Mailer: git-send-email $gitversion
 938 ";
 939         if ($reply_to) {
 940
 941                 $header .= "In-Reply-To: $reply_to\n";
 942                 $header .= "References: $references\n";
 943         }
 944         if (@xh) {
 945                 $header .= join("\n", @xh) . "\n";
 946         }
 947
 948         my @sendmail_parameters = ('-i', @recipients);
 949         my $raw_from = $sanitized_sender;
 950         if (defined $envelope_sender && $envelope_sender ne "auto") {
 951                 $raw_from = $envelope_sender;
 952         }
 953         $raw_from = extract_valid_address($raw_from);
 954         unshift (@sendmail_parameters,
 955                         '-f', $raw_from) if(defined $envelope_sender);
 956
 957         if ($needs_confirm && !$dry_run) {
 958                 print "\n$header\n";
 959                 if ($needs_confirm eq "inform") {
 960                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 961                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 962                         print "    The Cc list above has been expanded by additional\n";
 963                         print "    addresses found in the patch commit message. By default\n";
 964                         print "    send-email prompts before sending whenever this occurs.\n";
 965                         print "    This behavior is controlled by the sendemail.confirm\n";
 966                         print "    configuration setting.\n";
 967                         print "\n";
 968                         print "    For additional information, run 'git send-email --help'.\n";
 969                         print "    To retain the current behavior, but squelch this message,\n";
 970                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 971                 }
 972                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 973                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 974                          default => $ask_default);
 975                 die "Send this email reply required" unless defined $_;
 976                 if (/^n/i) {
 977                         return 0;
 978                 } elsif (/^q/i) {
 979                         cleanup_compose_files();
 980                         exit(0);
 981                 } elsif (/^a/i) {
 982                         $confirm = 'never';
 983                 }
 984         }
 985
 986         if ($dry_run) {
 987                 # We don't want to send the email.
 988         } elsif ($smtp_server =~ m#^/#) {
 989                 my $pid = open my $sm, '|-';
 990                 defined $pid or die $!;
 991                 if (!$pid) {
 992                         exec($smtp_server, @sendmail_parameters) or die $!;
 993                 }
 994                 print $sm "$header\n$message";
 995                 close $sm or die $?;
 996         } else {
 997
 998                 if (!defined $smtp_server) {
 999                         die "The required SMTP server is not properly defined."
1000                 }
1001
1002                 if ($smtp_encryption eq 'ssl') {
1003                         $smtp_server_port ||= 465; # ssmtp
1004                         require Net::SMTP::SSL;
1005                         $mail_domain ||= maildomain();
1006                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1007                                                       Hello => $mail_domain,
1008                                                       Port => $smtp_server_port);
1009                 }
1010                 else {
1011                         require Net::SMTP;
1012                         $mail_domain ||= maildomain();
1013                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1014                                                  ? "$smtp_server:$smtp_server_port"
1015                                                  : $smtp_server,
1016                                                  Hello => $mail_domain,
1017                                                  Debug => $debug_net_smtp);
1018                         if ($smtp_encryption eq 'tls' && $smtp) {
1019                                 require Net::SMTP::SSL;
1020                                 $smtp->command('STARTTLS');
1021                                 $smtp->response();
1022                                 if ($smtp->code == 220) {
1023                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1024                                                 or die "STARTTLS failed! ".$smtp->message;
1025                                         $smtp_encryption = '';
1026                                         # Send EHLO again to receive fresh
1027                                         # supported commands
1028                                         $smtp->hello();
1029                                 } else {
1030                                         die "Server does not support STARTTLS! ".$smtp->message;
1031                                 }
1032                         }
1033                 }
1034
1035                 if (!$smtp) {
1036                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1037                             "VALUES: server=$smtp_server ",
1038                             "encryption=$smtp_encryption ",
1039                             "maildomain=$mail_domain",
1040                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1041                 }
1042
1043                 if (defined $smtp_authuser) {
1044
1045                         if (!defined $smtp_authpass) {
1046
1047                                 system "stty -echo";
1048
1049                                 do {
1050                                         print "Password: ";
1051                                         $_ = <STDIN>;
1052                                         print "\n";
1053                                 } while (!defined $_);
1054
1055                                 chomp($smtp_authpass = $_);
1056
1057                                 system "stty echo";
1058                         }
1059
1060                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1061                 }
1062
1063                 $smtp->mail( $raw_from ) or die $smtp->message;
1064                 $smtp->to( @recipients ) or die $smtp->message;
1065                 $smtp->data or die $smtp->message;
1066                 $smtp->datasend("$header\n$message") or die $smtp->message;
1067                 $smtp->dataend() or die $smtp->message;
1068                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1069         }
1070         if ($quiet) {
1071                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1072         } else {
1073                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1074                 if ($smtp_server !~ m#^/#) {
1075                         print "Server: $smtp_server\n";
1076                         print "MAIL FROM:<$raw_from>\n";
1077                         foreach my $entry (@recipients) {
1078                             print "RCPT TO:<$entry>\n";
1079                         }
1080                 } else {
1081                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1082                 }
1083                 print $header, "\n";
1084                 if ($smtp) {
1085                         print "Result: ", $smtp->code, ' ',
1086                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1087                 } else {
1088                         print "Result: OK\n";
1089                 }
1090         }
1091
1092         return 1;
1093 }
1094
1095 $reply_to = $initial_reply_to;
1096 $references = $initial_reply_to || '';
1097 $subject = $initial_subject;
1098 $message_num = 0;
1099
1100 foreach my $t (@files) {
1101         open(F,"<",$t) or die "can't open file $t";
1102
1103         my $author = undef;
1104         my $author_encoding;
1105         my $has_content_type;
1106         my $body_encoding;
1107         @cc = ();
1108         @xh = ();
1109         my $input_format = undef;
1110         my @header = ();
1111         $message = "";
1112         $message_num++;
1113         # First unfold multiline header fields
1114         while(<F>) {
1115                 last if /^\s*$/;
1116                 if (/^\s+\S/ and @header) {
1117                         chomp($header[$#header]);
1118                         s/^\s+/ /;
1119                         $header[$#header] .= $_;
1120             } else {
1121                         push(@header, $_);
1122                 }
1123         }
1124         # Now parse the header
1125         foreach(@header) {
1126                 if (/^From /) {
1127                         $input_format = 'mbox';
1128                         next;
1129                 }
1130                 chomp;
1131                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1132                         $input_format = 'mbox';
1133                 }
1134
1135                 if (defined $input_format && $input_format eq 'mbox') {
1136                         if (/^Subject:\s+(.*)$/) {
1137                                 $subject = $1;
1138                         }
1139                         elsif (/^From:\s+(.*)$/) {
1140                                 ($author, $author_encoding) = unquote_rfc2047($1);
1141                                 next if $suppress_cc{'author'};
1142                                 next if $suppress_cc{'self'} and $author eq $sender;
1143                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1144                                         $1, $_) unless $quiet;
1145                                 push @cc, $1;
1146                         }
1147                         elsif (/^Cc:\s+(.*)$/) {
1148                                 foreach my $addr (parse_address_line($1)) {
1149                                         if (unquote_rfc2047($addr) eq $sender) {
1150                                                 next if ($suppress_cc{'self'});
1151                                         } else {
1152                                                 next if ($suppress_cc{'cc'});
1153                                         }
1154                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1155                                                 $addr, $_) unless $quiet;
1156                                         push @cc, $addr;
1157                                 }
1158                         }
1159                         elsif (/^Content-type:/i) {
1160                                 $has_content_type = 1;
1161                                 if (/charset="?([^ "]+)/) {
1162                                         $body_encoding = $1;
1163                                 }
1164                                 push @xh, $_;
1165                         }
1166                         elsif (/^Message-Id: (.*)/i) {
1167                                 $message_id = $1;
1168                         }
1169                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1170                                 push @xh, $_;
1171                         }
1172
1173                 } else {
1174                         # In the traditional
1175                         # "send lots of email" format,
1176                         # line 1 = cc
1177                         # line 2 = subject
1178                         # So let's support that, too.
1179                         $input_format = 'lots';
1180                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1181                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1182                                         $_, $_) unless $quiet;
1183                                 push @cc, $_;
1184                         } elsif (!defined $subject) {
1185                                 $subject = $_;
1186                         }
1187                 }
1188         }
1189         # Now parse the message body
1190         while(<F>) {
1191                 $message .=  $_;
1192                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1193                         chomp;
1194                         my ($what, $c) = ($1, $2);
1195                         chomp $c;
1196                         if ($c eq $sender) {
1197                                 next if ($suppress_cc{'self'});
1198                         } else {
1199                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1200                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1201                         }
1202                         push @cc, $c;
1203                         printf("(body) Adding cc: %s from line '%s'\n",
1204                                 $c, $_) unless $quiet;
1205                 }
1206         }
1207         close F;
1208
1209         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1210                 open(F, "$cc_cmd \Q$t\E |")
1211                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1212                 while(<F>) {
1213                         my $c = $_;
1214                         $c =~ s/^\s*//g;
1215                         $c =~ s/\n$//g;
1216                         next if ($c eq $sender and $suppress_from);
1217                         push @cc, $c;
1218                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1219                                 $c, $cc_cmd) unless $quiet;
1220                 }
1221                 close F
1222                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1223         }
1224
1225         if (defined $author and $author ne $sender) {
1226                 $message = "From: $author\n\n$message";
1227                 if (defined $author_encoding) {
1228                         if ($has_content_type) {
1229                                 if ($body_encoding eq $author_encoding) {
1230                                         # ok, we already have the right encoding
1231                                 }
1232                                 else {
1233                                         # uh oh, we should re-encode
1234                                 }
1235                         }
1236                         else {
1237                                 push @xh,
1238                                   'MIME-Version: 1.0',
1239                                   "Content-Type: text/plain; charset=$author_encoding",
1240                                   'Content-Transfer-Encoding: 8bit';
1241                         }
1242                 }
1243         }
1244
1245         $needs_confirm = (
1246                 $confirm eq "always" or
1247                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1248                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1249         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1250
1251         @cc = (@initial_cc, @cc);
1252
1253         my $message_was_sent = send_message();
1254
1255         # set up for the next message
1256         if ($thread && $message_was_sent &&
1257                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1258                 $reply_to = $message_id;
1259                 if (length $references > 0) {
1260                         $references .= "\n $message_id";
1261                 } else {
1262                         $references = "$message_id";
1263                 }
1264         }
1265         $message_id = undef;
1266 }
1267
1268 cleanup_compose_files();
1269
1270 sub cleanup_compose_files() {
1271         unlink($compose_filename, $compose_filename . ".final") if $compose;
1272 }
1273
1274 $smtp->quit if $smtp;
1275
1276 sub unique_email_list(@) {
1277         my %seen;
1278         my @emails;
1279
1280         foreach my $entry (@_) {
1281                 if (my $clean = extract_valid_address($entry)) {
1282                         $seen{$clean} ||= 0;
1283                         next if $seen{$clean}++;
1284                         push @emails, $entry;
1285                 } else {
1286                         print STDERR "W: unable to extract a valid address",
1287                                         " from: $entry\n";
1288                 }
1289         }
1290         return @emails;
1291 }
1292
1293 sub validate_patch {
1294         my $fn = shift;
1295         open(my $fh, '<', $fn)
1296                 or die "unable to open $fn: $!\n";
1297         while (my $line = <$fh>) {
1298                 if (length($line) > 998) {
1299                         return "$.: patch contains a line longer than 998 characters";
1300                 }
1301         }
1302         return undef;
1303 }
1304
1305 sub file_has_nonascii {
1306         my $fn = shift;
1307         open(my $fh, '<', $fn)
1308                 or die "unable to open $fn: $!\n";
1309         while (my $line = <$fh>) {
1310                 return 1 if $line =~ /[^[:ascii:]]/;
1311         }
1312         return 0;
1313 }