git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision $_repository
   8                 $_q $_authors $_authors_prog %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 # From which subdir have we been invoked?
  13 my $cmd_dir_prefix = eval {
  14         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  15 } || '';
  16
  17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  18 $ENV{GIT_DIR} ||= '.git';
  19 $Git::SVN::default_repo_id = 'svn';
  20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  21 $Git::SVN::Ra::_log_window_size = 100;
  22 $Git::SVN::_minimize_url = 'unset';
  23
  24 $Git::SVN::Log::TZ = $ENV{TZ};
  25 $ENV{TZ} = 'UTC';
  26 $| = 1; # unbuffer STDOUT
  27
  28 sub fatal (@) { print STDERR "@_\n"; exit 1 }
  29 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  30 require SVN::Ra;
  31 require SVN::Delta;
  32 if ($SVN::Core::VERSION lt '1.1.0') {
  33         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  34 }
  35 my $can_compress = eval { require Compress::Zlib; 1};
  36 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  37 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  38 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  39 use Carp qw/croak/;
  40 use Digest::MD5;
  41 use IO::File qw//;
  42 use File::Basename qw/dirname basename/;
  43 use File::Path qw/mkpath/;
  44 use File::Spec;
  45 use File::Find;
  46 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  47 use IPC::Open3;
  48 use Git;
  49
  50 BEGIN {
  51         # import functions from Git into our packages, en masse
  52         no strict 'refs';
  53         foreach (qw/command command_oneline command_noisy command_output_pipe
  54                     command_input_pipe command_close_pipe
  55                     command_bidi_pipe command_close_bidi_pipe/) {
  56                 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
  57                         Git::SVN::Migration Git::SVN::Log Git::SVN),
  58                         __PACKAGE__) {
  59                         *{"${package}::$_"} = \&{"Git::$_"};
  60                 }
  61         }
  62 }
  63
  64 my ($SVN);
  65
  66 $sha1 = qr/[a-f\d]{40}/;
  67 $sha1_short = qr/[a-f\d]{4,40}/;
  68 my ($_stdin, $_help, $_edit,
  69         $_message, $_file, $_branch_dest,
  70         $_template, $_shared,
  71         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
  72         $_merge, $_strategy, $_dry_run, $_local,
  73         $_prefix, $_no_checkout, $_url, $_verbose,
  74         $_git_format, $_commit_url, $_tag);
  75 $Git::SVN::_follow_parent = 1;
  76 $_q ||= 0;
  77 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  78                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  79                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
  80                     'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
  81 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  82                 'authors-file|A=s' => \$_authors,
  83                 'authors-prog=s' => \$_authors_prog,
  84                 'repack:i' => \$Git::SVN::_repack,
  85                 'noMetadata' => \$Git::SVN::_no_metadata,
  86                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  87                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  88                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  89                 'no-checkout' => \$_no_checkout,
  90                 'quiet|q+' => \$_q,
  91                 'repack-flags|repack-args|repack-opts=s' =>
  92                    \$Git::SVN::_repack_flags,
  93                 'use-log-author' => \$Git::SVN::_use_log_author,
  94                 'add-author-from' => \$Git::SVN::_add_author_from,
  95                 'localtime' => \$Git::SVN::_localtime,
  96                 %remote_opts );
  97
  98 my ($_trunk, @_tags, @_branches, $_stdlayout);
  99 my %icv;
 100 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 101                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 102                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 103                   'stdlayout|s' => \$_stdlayout,
 104                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 105                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 106                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 107                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 108                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 109                   %remote_opts );
 110 my %cmt_opts = ( 'edit|e' => \$_edit,
 111                 'rmdir' => \$SVN::Git::Editor::_rmdir,
 112                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
 113                 'l=i' => \$SVN::Git::Editor::_rename_limit,
 114                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
 115 );
 116
 117 my %cmd = (
 118         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 119                         { 'revision|r=s' => \$_revision,
 120                           'fetch-all|all' => \$_fetch_all,
 121                           'parent|p' => \$_fetch_parent,
 122                            %fc_opts } ],
 123         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 124                         { 'revision|r=s' => \$_revision,
 125                            %fc_opts, %init_opts } ],
 126         init => [ \&cmd_init, "Initialize a repo for tracking" .
 127                           " (requires URL argument)",
 128                           \%init_opts ],
 129         'multi-init' => [ \&cmd_multi_init,
 130                           "Deprecated alias for ".
 131                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 132                           \%init_opts ],
 133         dcommit => [ \&cmd_dcommit,
 134                      'Commit several diffs to merge with upstream',
 135                         { 'merge|m|M' => \$_merge,
 136                           'strategy|s=s' => \$_strategy,
 137                           'verbose|v' => \$_verbose,
 138                           'dry-run|n' => \$_dry_run,
 139                           'fetch-all|all' => \$_fetch_all,
 140                           'commit-url=s' => \$_commit_url,
 141                           'revision|r=i' => \$_revision,
 142                           'no-rebase' => \$_no_rebase,
 143                         %cmt_opts, %fc_opts } ],
 144         branch => [ \&cmd_branch,
 145                     'Create a branch in the SVN repository',
 146                     { 'message|m=s' => \$_message,
 147                       'destination|d=s' => \$_branch_dest,
 148                       'dry-run|n' => \$_dry_run,
 149                       'tag|t' => \$_tag } ],
 150         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 151                  'Create a tag in the SVN repository',
 152                  { 'message|m=s' => \$_message,
 153                    'destination|d=s' => \$_branch_dest,
 154                    'dry-run|n' => \$_dry_run } ],
 155         'set-tree' => [ \&cmd_set_tree,
 156                         "Set an SVN repository to a git tree-ish",
 157                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 158         'create-ignore' => [ \&cmd_create_ignore,
 159                              'Create a .gitignore per svn:ignore',
 160                              { 'revision|r=i' => \$_revision
 161                              } ],
 162         'propget' => [ \&cmd_propget,
 163                        'Print the value of a property on a file or directory',
 164                        { 'revision|r=i' => \$_revision } ],
 165         'proplist' => [ \&cmd_proplist,
 166                        'List all properties of a file or directory',
 167                        { 'revision|r=i' => \$_revision } ],
 168         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 169                         { 'revision|r=i' => \$_revision
 170                         } ],
 171         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 172                         { 'revision|r=i' => \$_revision
 173                         } ],
 174         'multi-fetch' => [ \&cmd_multi_fetch,
 175                            "Deprecated alias for $0 fetch --all",
 176                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 177         'migrate' => [ sub { },
 178                        # no-op, we automatically run this anyways,
 179                        'Migrate configuration/metadata/layout from
 180                         previous versions of git-svn',
 181                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 182                          %remote_opts } ],
 183         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 184                         { 'limit=i' => \$Git::SVN::Log::limit,
 185                           'revision|r=s' => \$_revision,
 186                           'verbose|v' => \$Git::SVN::Log::verbose,
 187                           'incremental' => \$Git::SVN::Log::incremental,
 188                           'oneline' => \$Git::SVN::Log::oneline,
 189                           'show-commit' => \$Git::SVN::Log::show_commit,
 190                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 191                           'authors-file|A=s' => \$_authors,
 192                           'color' => \$Git::SVN::Log::color,
 193                           'pager=s' => \$Git::SVN::Log::pager
 194                         } ],
 195         'find-rev' => [ \&cmd_find_rev,
 196                         "Translate between SVN revision numbers and tree-ish",
 197                         {} ],
 198         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 199                         { 'merge|m|M' => \$_merge,
 200                           'verbose|v' => \$_verbose,
 201                           'strategy|s=s' => \$_strategy,
 202                           'local|l' => \$_local,
 203                           'fetch-all|all' => \$_fetch_all,
 204                           'dry-run|n' => \$_dry_run,
 205                           %fc_opts } ],
 206         'commit-diff' => [ \&cmd_commit_diff,
 207                            'Commit a diff between two trees',
 208                         { 'message|m=s' => \$_message,
 209                           'file|F=s' => \$_file,
 210                           'revision|r=s' => \$_revision,
 211                         %cmt_opts } ],
 212         'info' => [ \&cmd_info,
 213                     "Show info about the latest SVN revision
 214                      on the current branch",
 215                     { 'url' => \$_url, } ],
 216         'blame' => [ \&Git::SVN::Log::cmd_blame,
 217                     "Show what revision and author last modified each line of a file",
 218                     { 'git-format' => \$_git_format } ],
 219         'reset' => [ \&cmd_reset,
 220                      "Undo fetches back to the specified SVN revision",
 221                      { 'revision|r=s' => \$_revision,
 222                        'parent|p' => \$_fetch_parent } ],
 223         'gc' => [ \&cmd_gc,
 224                   "Compress unhandled.log files in .git/svn and remove " .
 225                   "index files in .git/svn",
 226                 {} ],
 227 );
 228
 229 my $cmd;
 230 for (my $i = 0; $i < @ARGV; $i++) {
 231         if (defined $cmd{$ARGV[$i]}) {
 232                 $cmd = $ARGV[$i];
 233                 splice @ARGV, $i, 1;
 234                 last;
 235         } elsif ($ARGV[$i] eq 'help') {
 236                 $cmd = $ARGV[$i+1];
 237                 usage(0);
 238         }
 239 };
 240
 241 # make sure we're always running at the top-level working directory
 242 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 243         unless (-d $ENV{GIT_DIR}) {
 244                 if ($git_dir_user_set) {
 245                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 246                             "but it is not a directory\n";
 247                 }
 248                 my $git_dir = delete $ENV{GIT_DIR};
 249                 my $cdup = undef;
 250                 git_cmd_try {
 251                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 252                         $git_dir = '.' unless ($cdup);
 253                         chomp $cdup if ($cdup);
 254                         $cdup = "." unless ($cdup && length $cdup);
 255                 } "Already at toplevel, but $git_dir not found\n";
 256                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 257                 unless (-d $git_dir) {
 258                         die "$git_dir still not found after going to ",
 259                             "'$cdup'\n";
 260                 }
 261                 $ENV{GIT_DIR} = $git_dir;
 262         }
 263         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 264 }
 265
 266 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 267
 268 read_repo_config(\%opts);
 269 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 270         Getopt::Long::Configure('pass_through');
 271 }
 272 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 273                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 274                     'id|i=s' => \$Git::SVN::default_ref_id,
 275                     'svn-remote|remote|R=s' => sub {
 276                        $Git::SVN::no_reuse_existing = 1;
 277                        $Git::SVN::default_repo_id = $_[1] });
 278 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 279
 280 usage(0) if $_help;
 281 version() if $_version;
 282 usage(1) unless defined $cmd;
 283 load_authors() if $_authors;
 284 if (defined $_authors_prog) {
 285         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 286 }
 287
 288 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 289         Git::SVN::Migration::migration_check();
 290 }
 291 Git::SVN::init_vars();
 292 eval {
 293         Git::SVN::verify_remotes_sanity();
 294         $cmd{$cmd}->[0]->(@ARGV);
 295 };
 296 fatal $@ if $@;
 297 post_fetch_checkout();
 298 exit 0;
 299
 300 ####################### primary functions ######################
 301 sub usage {
 302         my $exit = shift || 0;
 303         my $fd = $exit ? \*STDERR : \*STDOUT;
 304         print $fd <<"";
 305 git-svn - bidirectional operations between a single Subversion tree and git
 306 Usage: git svn <command> [options] [arguments]\n
 307
 308         print $fd "Available commands:\n" unless $cmd;
 309
 310         foreach (sort keys %cmd) {
 311                 next if $cmd && $cmd ne $_;
 312                 next if /^multi-/; # don't show deprecated commands
 313                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 314                 foreach (sort keys %{$cmd{$_}->[2]}) {
 315                         # mixed-case options are for .git/config only
 316                         next if /[A-Z]/ && /^[a-z]+$/i;
 317                         # prints out arguments as they should be passed:
 318                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 319                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 320                                                         "--$_" : "-$_" }
 321                                                 split /\|/,$_)," $x\n";
 322                 }
 323         }
 324         print $fd <<"";
 325 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 326 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 327 one git repository and want to keep them separate.  See git-svn(1) for more
 328 information.
 329
 330         exit $exit;
 331 }
 332
 333 sub version {
 334         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 335         exit 0;
 336 }
 337
 338 sub do_git_init_db {
 339         unless (-d $ENV{GIT_DIR}) {
 340                 my @init_db = ('init');
 341                 push @init_db, "--template=$_template" if defined $_template;
 342                 if (defined $_shared) {
 343                         if ($_shared =~ /[a-z]/) {
 344                                 push @init_db, "--shared=$_shared";
 345                         } else {
 346                                 push @init_db, "--shared";
 347                         }
 348                 }
 349                 command_noisy(@init_db);
 350                 $_repository = Git->repository(Repository => ".git");
 351         }
 352         command_noisy('config', 'core.autocrlf', 'false');
 353         my $set;
 354         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 355         foreach my $i (keys %icv) {
 356                 die "'$set' and '$i' cannot both be set\n" if $set;
 357                 next unless defined $icv{$i};
 358                 command_noisy('config', "$pfx.$i", $icv{$i});
 359                 $set = $i;
 360         }
 361         my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
 362         command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
 363                 if defined $$ignore_regex;
 364 }
 365
 366 sub init_subdir {
 367         my $repo_path = shift or return;
 368         mkpath([$repo_path]) unless -d $repo_path;
 369         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 370         $ENV{GIT_DIR} = '.git';
 371         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 372 }
 373
 374 sub cmd_clone {
 375         my ($url, $path) = @_;
 376         if (!defined $path &&
 377             (defined $_trunk || @_branches || @_tags ||
 378              defined $_stdlayout) &&
 379             $url !~ m#^[a-z\+]+://#) {
 380                 $path = $url;
 381         }
 382         $path = basename($url) if !defined $path || !length $path;
 383         cmd_init($url, $path);
 384         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 385         command_oneline('config', 'svn.authorsfile', $_authors) if $_authors;
 386 }
 387
 388 sub cmd_init {
 389         if (defined $_stdlayout) {
 390                 $_trunk = 'trunk' if (!defined $_trunk);
 391                 @_tags = 'tags' if (! @_tags);
 392                 @_branches = 'branches' if (! @_branches);
 393         }
 394         if (defined $_trunk || @_branches || @_tags) {
 395                 return cmd_multi_init(@_);
 396         }
 397         my $url = shift or die "SVN repository location required ",
 398                                "as a command-line argument\n";
 399         $url = canonicalize_url($url);
 400         init_subdir(@_);
 401         do_git_init_db();
 402
 403         if ($Git::SVN::_minimize_url eq 'unset') {
 404                 $Git::SVN::_minimize_url = 0;
 405         }
 406
 407         Git::SVN->init($url);
 408 }
 409
 410 sub cmd_fetch {
 411         if (grep /^\d+=./, @_) {
 412                 die "'<rev>=<commit>' fetch arguments are ",
 413                     "no longer supported.\n";
 414         }
 415         my ($remote) = @_;
 416         if (@_ > 1) {
 417                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 418         }
 419         if ($_fetch_parent) {
 420                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 421                 unless ($gs) {
 422                         die "Unable to determine upstream SVN information from ",
 423                             "working tree history\n";
 424                 }
 425                 # just fetch, don't checkout.
 426                 $_no_checkout = 'true';
 427                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 428         } elsif ($_fetch_all) {
 429                 cmd_multi_fetch();
 430         } else {
 431                 $remote ||= $Git::SVN::default_repo_id;
 432                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 433         }
 434 }
 435
 436 sub cmd_set_tree {
 437         my (@commits) = @_;
 438         if ($_stdin || !@commits) {
 439                 print "Reading from stdin...\n";
 440                 @commits = ();
 441                 while (<STDIN>) {
 442                         if (/\b($sha1_short)\b/o) {
 443                                 unshift @commits, $1;
 444                         }
 445                 }
 446         }
 447         my @revs;
 448         foreach my $c (@commits) {
 449                 my @tmp = command('rev-parse',$c);
 450                 if (scalar @tmp == 1) {
 451                         push @revs, $tmp[0];
 452                 } elsif (scalar @tmp > 1) {
 453                         push @revs, reverse(command('rev-list',@tmp));
 454                 } else {
 455                         fatal "Failed to rev-parse $c";
 456                 }
 457         }
 458         my $gs = Git::SVN->new;
 459         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 460         $gs->fetch;
 461         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 462                 fatal "There are new revisions that were fetched ",
 463                       "and need to be merged (or acknowledged) ",
 464                       "before committing.\nlast rev: $r_last\n",
 465                       " current: $gs->{last_rev}";
 466         }
 467         $gs->set_tree($_) foreach @revs;
 468         print "Done committing ",scalar @revs," revisions to SVN\n";
 469         unlink $gs->{index};
 470 }
 471
 472 sub cmd_dcommit {
 473         my $head = shift;
 474         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 475                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 476                 . "or stash them with `git stash'.\n";
 477         $head ||= 'HEAD';
 478
 479         my $old_head;
 480         if ($head ne 'HEAD') {
 481                 $old_head = eval {
 482                         command_oneline([qw/symbolic-ref -q HEAD/])
 483                 };
 484                 if ($old_head) {
 485                         $old_head =~ s{^refs/heads/}{};
 486                 } else {
 487                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 488                 }
 489                 command(['checkout', $head], STDERR => 0);
 490         }
 491
 492         my @refs;
 493         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 494         unless ($gs) {
 495                 die "Unable to determine upstream SVN information from ",
 496                     "$head history.\nPerhaps the repository is empty.";
 497         }
 498
 499         if (defined $_commit_url) {
 500                 $url = $_commit_url;
 501         } else {
 502                 $url = eval { command_oneline('config', '--get',
 503                               "svn-remote.$gs->{repo_id}.commiturl") };
 504                 if (!$url) {
 505                         $url = $gs->full_url
 506                 }
 507         }
 508
 509         my $last_rev = $_revision if defined $_revision;
 510         if ($url) {
 511                 print "Committing to $url ...\n";
 512         }
 513         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 514         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 515                 warn "Attempting to commit more than one change while ",
 516                      "--no-rebase is enabled.\n",
 517                      "If these changes depend on each other, re-running ",
 518                      "without --no-rebase may be required."
 519         }
 520         my $expect_url = $url;
 521         Git::SVN::remove_username($expect_url);
 522         while (1) {
 523                 my $d = shift @$linear_refs or last;
 524                 unless (defined $last_rev) {
 525                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 526                         unless (defined $last_rev) {
 527                                 fatal "Unable to extract revision information ",
 528                                       "from commit $d~1";
 529                         }
 530                 }
 531                 if ($_dry_run) {
 532                         print "diff-tree $d~1 $d\n";
 533                 } else {
 534                         my $cmt_rev;
 535                         my %ed_opts = ( r => $last_rev,
 536                                         log => get_commit_entry($d)->{log},
 537                                         ra => Git::SVN::Ra->new($url),
 538                                         config => SVN::Core::config_get_config(
 539                                                 $Git::SVN::Ra::config_dir
 540                                         ),
 541                                         tree_a => "$d~1",
 542                                         tree_b => $d,
 543                                         editor_cb => sub {
 544                                                print "Committed r$_[0]\n";
 545                                                $cmt_rev = $_[0];
 546                                         },
 547                                         svn_path => '');
 548                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 549                                 print "No changes\n$d~1 == $d\n";
 550                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 551                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 552                                                                $parents->{$d};
 553                         }
 554                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 555                         $last_rev = $cmt_rev;
 556                         next if $_no_rebase;
 557
 558                         # we always want to rebase against the current HEAD,
 559                         # not any head that was passed to us
 560                         my @diff = command('diff-tree', $d,
 561                                            $gs->refname, '--');
 562                         my @finish;
 563                         if (@diff) {
 564                                 @finish = rebase_cmd();
 565                                 print STDERR "W: $d and ", $gs->refname,
 566                                              " differ, using @finish:\n",
 567                                              join("\n", @diff), "\n";
 568                         } else {
 569                                 print "No changes between current HEAD and ",
 570                                       $gs->refname,
 571                                       "\nResetting to the latest ",
 572                                       $gs->refname, "\n";
 573                                 @finish = qw/reset --mixed/;
 574                         }
 575                         command_noisy(@finish, $gs->refname);
 576                         if (@diff) {
 577                                 @refs = ();
 578                                 my ($url_, $rev_, $uuid_, $gs_) =
 579                                               working_head_info('HEAD', \@refs);
 580                                 my ($linear_refs_, $parents_) =
 581                                               linearize_history($gs_, \@refs);
 582                                 if (scalar(@$linear_refs) !=
 583                                     scalar(@$linear_refs_)) {
 584                                         fatal "# of revisions changed ",
 585                                           "\nbefore:\n",
 586                                           join("\n", @$linear_refs),
 587                                           "\n\nafter:\n",
 588                                           join("\n", @$linear_refs_), "\n",
 589                                           'If you are attempting to commit ',
 590                                           "merges, try running:\n\t",
 591                                           'git rebase --interactive',
 592                                           '--preserve-merges ',
 593                                           $gs->refname,
 594                                           "\nBefore dcommitting";
 595                                 }
 596                                 if ($url_ ne $expect_url) {
 597                                         fatal "URL mismatch after rebase: ",
 598                                               "$url_ != $expect_url";
 599                                 }
 600                                 if ($uuid_ ne $uuid) {
 601                                         fatal "uuid mismatch after rebase: ",
 602                                               "$uuid_ != $uuid";
 603                                 }
 604                                 # remap parents
 605                                 my (%p, @l, $i);
 606                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
 607                                         my $new = $linear_refs_->[$i] or next;
 608                                         $p{$new} =
 609                                                 $parents->{$linear_refs->[$i]};
 610                                         push @l, $new;
 611                                 }
 612                                 $parents = \%p;
 613                                 $linear_refs = \@l;
 614                         }
 615                 }
 616         }
 617
 618         if ($old_head) {
 619                 my $new_head = command_oneline(qw/rev-parse HEAD/);
 620                 my $new_is_symbolic = eval {
 621                         command_oneline(qw/symbolic-ref -q HEAD/);
 622                 };
 623                 if ($new_is_symbolic) {
 624                         print "dcommitted the branch ", $head, "\n";
 625                 } else {
 626                         print "dcommitted on a detached HEAD because you gave ",
 627                               "a revision argument.\n",
 628                               "The rewritten commit is: ", $new_head, "\n";
 629                 }
 630                 command(['checkout', $old_head], STDERR => 0);
 631         }
 632
 633         unlink $gs->{index};
 634 }
 635
 636 sub cmd_branch {
 637         my ($branch_name, $head) = @_;
 638
 639         unless (defined $branch_name && length $branch_name) {
 640                 die(($_tag ? "tag" : "branch") . " name required\n");
 641         }
 642         $head ||= 'HEAD';
 643
 644         my ($src, $rev, undef, $gs) = working_head_info($head);
 645
 646         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
 647         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
 648         my $glob;
 649         if ($#{$allglobs} == 0) {
 650                 $glob = $allglobs->[0];
 651         } else {
 652                 unless(defined $_branch_dest) {
 653                         die "Multiple ",
 654                             $_tag ? "tag" : "branch",
 655                             " paths defined for Subversion repository.\n",
 656                             "You must specify where you want to create the ",
 657                             $_tag ? "tag" : "branch",
 658                             " with the --destination argument.\n";
 659                 }
 660                 foreach my $g (@{$allglobs}) {
 661                         # SVN::Git::Editor could probably be moved to Git.pm..
 662                         my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
 663                         if ($_branch_dest =~ /$re/) {
 664                                 $glob = $g;
 665                                 last;
 666                         }
 667                 }
 668                 unless (defined $glob) {
 669                         die "Unknown ",
 670                             $_tag ? "tag" : "branch",
 671                             " destination $_branch_dest\n";
 672                 }
 673         }
 674         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
 675         my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
 676
 677         my $ctx = SVN::Client->new(
 678                 auth    => Git::SVN::Ra::_auth_providers(),
 679                 log_msg => sub {
 680                         ${ $_[0] } = defined $_message
 681                                 ? $_message
 682                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
 683                                 . $branch_name;
 684                 },
 685         );
 686
 687         eval {
 688                 $ctx->ls($dst, 'HEAD', 0);
 689         } and die "branch ${branch_name} already exists\n";
 690
 691         print "Copying ${src} at r${rev} to ${dst}...\n";
 692         $ctx->copy($src, $rev, $dst)
 693                 unless $_dry_run;
 694
 695         $gs->fetch_all;
 696 }
 697
 698 sub cmd_find_rev {
 699         my $revision_or_hash = shift or die "SVN or git revision required ",
 700                                             "as a command-line argument\n";
 701         my $result;
 702         if ($revision_or_hash =~ /^r\d+$/) {
 703                 my $head = shift;
 704                 $head ||= 'HEAD';
 705                 my @refs;
 706                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
 707                 unless ($gs) {
 708                         die "Unable to determine upstream SVN information from ",
 709                             "$head history\n";
 710                 }
 711                 my $desired_revision = substr($revision_or_hash, 1);
 712                 $result = $gs->rev_map_get($desired_revision, $uuid);
 713         } else {
 714                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 715                 $result = $rev;
 716         }
 717         print "$result\n" if $result;
 718 }
 719
 720 sub cmd_rebase {
 721         command_noisy(qw/update-index --refresh/);
 722         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 723         unless ($gs) {
 724                 die "Unable to determine upstream SVN information from ",
 725                     "working tree history\n";
 726         }
 727         if ($_dry_run) {
 728                 print "Remote Branch: " . $gs->refname . "\n";
 729                 print "SVN URL: " . $url . "\n";
 730                 return;
 731         }
 732         if (command(qw/diff-index HEAD --/)) {
 733                 print STDERR "Cannot rebase with uncommited changes:\n";
 734                 command_noisy('status');
 735                 exit 1;
 736         }
 737         unless ($_local) {
 738                 # rebase will checkout for us, so no need to do it explicitly
 739                 $_no_checkout = 'true';
 740                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 741         }
 742         command_noisy(rebase_cmd(), $gs->refname);
 743 }
 744
 745 sub cmd_show_ignore {
 746         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 747         $gs ||= Git::SVN->new;
 748         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 749         $gs->prop_walk($gs->{path}, $r, sub {
 750                 my ($gs, $path, $props) = @_;
 751                 print STDOUT "\n# $path\n";
 752                 my $s = $props->{'svn:ignore'} or return;
 753                 $s =~ s/[\r\n]+/\n/g;
 754                 chomp $s;
 755                 $s =~ s#^#$path#gm;
 756                 print STDOUT "$s\n";
 757         });
 758 }
 759
 760 sub cmd_show_externals {
 761         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 762         $gs ||= Git::SVN->new;
 763         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 764         $gs->prop_walk($gs->{path}, $r, sub {
 765                 my ($gs, $path, $props) = @_;
 766                 print STDOUT "\n# $path\n";
 767                 my $s = $props->{'svn:externals'} or return;
 768                 $s =~ s/[\r\n]+/\n/g;
 769                 chomp $s;
 770                 $s =~ s#^#$path#gm;
 771                 print STDOUT "$s\n";
 772         });
 773 }
 774
 775 sub cmd_create_ignore {
 776         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 777         $gs ||= Git::SVN->new;
 778         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 779         $gs->prop_walk($gs->{path}, $r, sub {
 780                 my ($gs, $path, $props) = @_;
 781                 # $path is of the form /path/to/dir/
 782                 $path = '.' . $path;
 783                 # SVN can have attributes on empty directories,
 784                 # which git won't track
 785                 mkpath([$path]) unless -d $path;
 786                 my $ignore = $path . '.gitignore';
 787                 my $s = $props->{'svn:ignore'} or return;
 788                 open(GITIGNORE, '>', $ignore)
 789                   or fatal("Failed to open `$ignore' for writing: $!");
 790                 $s =~ s/[\r\n]+/\n/g;
 791                 chomp $s;
 792                 # Prefix all patterns so that the ignore doesn't apply
 793                 # to sub-directories.
 794                 $s =~ s#^#/#gm;
 795                 print GITIGNORE "$s\n";
 796                 close(GITIGNORE)
 797                   or fatal("Failed to close `$ignore': $!");
 798                 command_noisy('add', '-f', $ignore);
 799         });
 800 }
 801
 802 sub canonicalize_path {
 803         my ($path) = @_;
 804         my $dot_slash_added = 0;
 805         if (substr($path, 0, 1) ne "/") {
 806                 $path = "./" . $path;
 807                 $dot_slash_added = 1;
 808         }
 809         # File::Spec->canonpath doesn't collapse x/../y into y (for a
 810         # good reason), so let's do this manually.
 811         $path =~ s#/+#/#g;
 812         $path =~ s#/\.(?:/|$)#/#g;
 813         $path =~ s#/[^/]+/\.\.##g;
 814         $path =~ s#/$##g;
 815         $path =~ s#^\./## if $dot_slash_added;
 816         $path =~ s#^/##;
 817         $path =~ s#^\.$##;
 818         return $path;
 819 }
 820
 821 sub canonicalize_url {
 822         my ($url) = @_;
 823         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
 824         return $url;
 825 }
 826
 827 # get_svnprops(PATH)
 828 # ------------------
 829 # Helper for cmd_propget and cmd_proplist below.
 830 sub get_svnprops {
 831         my $path = shift;
 832         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 833         $gs ||= Git::SVN->new;
 834
 835         # prefix THE PATH by the sub-directory from which the user
 836         # invoked us.
 837         $path = $cmd_dir_prefix . $path;
 838         fatal("No such file or directory: $path") unless -e $path;
 839         my $is_dir = -d $path ? 1 : 0;
 840         $path = $gs->{path} . '/' . $path;
 841
 842         # canonicalize the path (otherwise libsvn will abort or fail to
 843         # find the file)
 844         $path = canonicalize_path($path);
 845
 846         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 847         my $props;
 848         if ($is_dir) {
 849                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
 850         }
 851         else {
 852                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
 853         }
 854         return $props;
 855 }
 856
 857 # cmd_propget (PROP, PATH)
 858 # ------------------------
 859 # Print the SVN property PROP for PATH.
 860 sub cmd_propget {
 861         my ($prop, $path) = @_;
 862         $path = '.' if not defined $path;
 863         usage(1) if not defined $prop;
 864         my $props = get_svnprops($path);
 865         if (not defined $props->{$prop}) {
 866                 fatal("`$path' does not have a `$prop' SVN property.");
 867         }
 868         print $props->{$prop} . "\n";
 869 }
 870
 871 # cmd_proplist (PATH)
 872 # -------------------
 873 # Print the list of SVN properties for PATH.
 874 sub cmd_proplist {
 875         my $path = shift;
 876         $path = '.' if not defined $path;
 877         my $props = get_svnprops($path);
 878         print "Properties on '$path':\n";
 879         foreach (sort keys %{$props}) {
 880                 print "  $_\n";
 881         }
 882 }
 883
 884 sub cmd_multi_init {
 885         my $url = shift;
 886         unless (defined $_trunk || @_branches || @_tags) {
 887                 usage(1);
 888         }
 889
 890         $_prefix = '' unless defined $_prefix;
 891         if (defined $url) {
 892                 $url = canonicalize_url($url);
 893                 init_subdir(@_);
 894         }
 895         do_git_init_db();
 896         if (defined $_trunk) {
 897                 my $trunk_ref = $_prefix . 'trunk';
 898                 # try both old-style and new-style lookups:
 899                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 900                 unless ($gs_trunk) {
 901                         my ($trunk_url, $trunk_path) =
 902                                               complete_svn_url($url, $_trunk);
 903                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 904                                                    undef, $trunk_ref);
 905                 }
 906         }
 907         return unless @_branches || @_tags;
 908         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 909         foreach my $path (@_branches) {
 910                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
 911         }
 912         foreach my $path (@_tags) {
 913                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
 914         }
 915 }
 916
 917 sub cmd_multi_fetch {
 918         my $remotes = Git::SVN::read_all_remotes();
 919         foreach my $repo_id (sort keys %$remotes) {
 920                 if ($remotes->{$repo_id}->{url}) {
 921                         Git::SVN::fetch_all($repo_id, $remotes);
 922                 }
 923         }
 924 }
 925
 926 # this command is special because it requires no metadata
 927 sub cmd_commit_diff {
 928         my ($ta, $tb, $url) = @_;
 929         my $usage = "Usage: $0 commit-diff -r<revision> ".
 930                     "<tree-ish> <tree-ish> [<URL>]";
 931         fatal($usage) if (!defined $ta || !defined $tb);
 932         my $svn_path = '';
 933         if (!defined $url) {
 934                 my $gs = eval { Git::SVN->new };
 935                 if (!$gs) {
 936                         fatal("Needed URL or usable git-svn --id in ",
 937                               "the command-line\n", $usage);
 938                 }
 939                 $url = $gs->{url};
 940                 $svn_path = $gs->{path};
 941         }
 942         unless (defined $_revision) {
 943                 fatal("-r|--revision is a required argument\n", $usage);
 944         }
 945         if (defined $_message && defined $_file) {
 946                 fatal("Both --message/-m and --file/-F specified ",
 947                       "for the commit message.\n",
 948                       "I have no idea what you mean");
 949         }
 950         if (defined $_file) {
 951                 $_message = file_to_s($_file);
 952         } else {
 953                 $_message ||= get_commit_entry($tb)->{log};
 954         }
 955         my $ra ||= Git::SVN::Ra->new($url);
 956         my $r = $_revision;
 957         if ($r eq 'HEAD') {
 958                 $r = $ra->get_latest_revnum;
 959         } elsif ($r !~ /^\d+$/) {
 960                 die "revision argument: $r not understood by git-svn\n";
 961         }
 962         my %ed_opts = ( r => $r,
 963                         log => $_message,
 964                         ra => $ra,
 965                         tree_a => $ta,
 966                         tree_b => $tb,
 967                         editor_cb => sub { print "Committed r$_[0]\n" },
 968                         svn_path => $svn_path );
 969         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 970                 print "No changes\n$ta == $tb\n";
 971         }
 972 }
 973
 974 sub escape_uri_only {
 975         my ($uri) = @_;
 976         my @tmp;
 977         foreach (split m{/}, $uri) {
 978                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
 979                 push @tmp, $_;
 980         }
 981         join('/', @tmp);
 982 }
 983
 984 sub escape_url {
 985         my ($url) = @_;
 986         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
 987                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
 988                 $url = "$scheme://$domain$uri";
 989         }
 990         $url;
 991 }
 992
 993 sub cmd_info {
 994         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
 995         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
 996         if (exists $_[1]) {
 997                 die "Too many arguments specified\n";
 998         }
 999
1000         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1001
1002         if (!$file_type && !$diff_status) {
1003                 print STDERR "svn: '$path' is not under version control\n";
1004                 exit 1;
1005         }
1006
1007         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1008         unless ($gs) {
1009                 die "Unable to determine upstream SVN information from ",
1010                     "working tree history\n";
1011         }
1012
1013         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1014         $path = "." if $path eq "";
1015
1016         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1017
1018         if ($_url) {
1019                 print escape_url($full_url), "\n";
1020                 return;
1021         }
1022
1023         my $result = "Path: $path\n";
1024         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1025         $result .= "URL: " . escape_url($full_url) . "\n";
1026
1027         eval {
1028                 my $repos_root = $gs->repos_root;
1029                 Git::SVN::remove_username($repos_root);
1030                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1031         };
1032         if ($@) {
1033                 $result .= "Repository Root: (offline)\n";
1034         }
1035         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1036                 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1037         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1038
1039         $result .= "Node Kind: " .
1040                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1041
1042         my $schedule = $diff_status eq "A"
1043                        ? "add"
1044                        : ($diff_status eq "D" ? "delete" : "normal");
1045         $result .= "Schedule: $schedule\n";
1046
1047         if ($diff_status eq "A") {
1048                 print $result, "\n";
1049                 return;
1050         }
1051
1052         my ($lc_author, $lc_rev, $lc_date_utc);
1053         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1054         my $log = command_output_pipe(@args);
1055         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1056         while (<$log>) {
1057                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1058                         $lc_author = $1;
1059                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1060                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1061                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1062                 }
1063         }
1064         close $log;
1065
1066         Git::SVN::Log::set_local_timezone();
1067
1068         $result .= "Last Changed Author: $lc_author\n";
1069         $result .= "Last Changed Rev: $lc_rev\n";
1070         $result .= "Last Changed Date: " .
1071                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1072
1073         if ($file_type ne "dir") {
1074                 my $text_last_updated_date =
1075                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1076                 $result .=
1077                     "Text Last Updated: " .
1078                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1079                     "\n";
1080                 my $checksum;
1081                 if ($diff_status eq "D") {
1082                         my ($fh, $ctx) =
1083                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1084                         if ($file_type eq "link") {
1085                                 my $file_name = <$fh>;
1086                                 $checksum = md5sum("link $file_name");
1087                         } else {
1088                                 $checksum = md5sum($fh);
1089                         }
1090                         command_close_pipe($fh, $ctx);
1091                 } elsif ($file_type eq "link") {
1092                         my $file_name =
1093                             command(qw(cat-file blob), "HEAD:$path");
1094                         $checksum =
1095                             md5sum("link " . $file_name);
1096                 } else {
1097                         open FILE, "<", $path or die $!;
1098                         $checksum = md5sum(\*FILE);
1099                         close FILE or die $!;
1100                 }
1101                 $result .= "Checksum: " . $checksum . "\n";
1102         }
1103
1104         print $result, "\n";
1105 }
1106
1107 sub cmd_reset {
1108         my $target = shift || $_revision or die "SVN revision required\n";
1109         $target = $1 if $target =~ /^r(\d+)$/;
1110         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1111         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1112         unless ($gs) {
1113                 die "Unable to determine upstream SVN information from ".
1114                     "history\n";
1115         }
1116         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1117         $gs->rev_map_set($r, $c, 'reset', $uuid);
1118         print "r$r = $c ($gs->{ref_id})\n";
1119 }
1120
1121 sub cmd_gc {
1122         if (!$can_compress) {
1123                 warn "Compress::Zlib could not be found; unhandled.log " .
1124                      "files will not be compressed.\n";
1125         }
1126         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1127 }
1128
1129 ########################### utility functions #########################
1130
1131 sub rebase_cmd {
1132         my @cmd = qw/rebase/;
1133         push @cmd, '-v' if $_verbose;
1134         push @cmd, qw/--merge/ if $_merge;
1135         push @cmd, "--strategy=$_strategy" if $_strategy;
1136         @cmd;
1137 }
1138
1139 sub post_fetch_checkout {
1140         return if $_no_checkout;
1141         my $gs = $Git::SVN::_head or return;
1142         return if verify_ref('refs/heads/master^0');
1143
1144         my $valid_head = verify_ref('HEAD^0');
1145         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1146         return if ($valid_head || !verify_ref('HEAD^0'));
1147
1148         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1149         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1150         return if -f $index;
1151
1152         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1153         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1154         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1155         print STDERR "Checked out HEAD:\n  ",
1156                      $gs->full_url, " r", $gs->last_rev, "\n";
1157 }
1158
1159 sub complete_svn_url {
1160         my ($url, $path) = @_;
1161         $path =~ s#/+$##;
1162         if ($path !~ m#^[a-z\+]+://#) {
1163                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1164                         fatal("E: '$path' is not a complete URL ",
1165                               "and a separate URL is not specified");
1166                 }
1167                 return ($url, $path);
1168         }
1169         return ($path, '');
1170 }
1171
1172 sub complete_url_ls_init {
1173         my ($ra, $repo_path, $switch, $pfx) = @_;
1174         unless ($repo_path) {
1175                 print STDERR "W: $switch not specified\n";
1176                 return;
1177         }
1178         $repo_path =~ s#/+$##;
1179         if ($repo_path =~ m#^[a-z\+]+://#) {
1180                 $ra = Git::SVN::Ra->new($repo_path);
1181                 $repo_path = '';
1182         } else {
1183                 $repo_path =~ s#^/+##;
1184                 unless ($ra) {
1185                         fatal("E: '$repo_path' is not a complete URL ",
1186                               "and a separate URL is not specified");
1187                 }
1188         }
1189         my $url = $ra->{url};
1190         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1191         my $k = "svn-remote.$gs->{repo_id}.url";
1192         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1193         if ($orig_url && ($orig_url ne $gs->{url})) {
1194                 die "$k already set: $orig_url\n",
1195                     "wanted to set to: $gs->{url}\n";
1196         }
1197         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1198         my $remote_path = "$gs->{path}/$repo_path";
1199         $remote_path =~ s#/+#/#g;
1200         $remote_path =~ s#^/##g;
1201         $remote_path .= "/*" if $remote_path !~ /\*/;
1202         my ($n) = ($switch =~ /^--(\w+)/);
1203         if (length $pfx && $pfx !~ m#/$#) {
1204                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1205         }
1206         command_noisy('config',
1207                       '--add',
1208                       "svn-remote.$gs->{repo_id}.$n",
1209                       "$remote_path:refs/remotes/$pfx*" .
1210                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1211 }
1212
1213 sub verify_ref {
1214         my ($ref) = @_;
1215         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1216                                { STDERR => 0 }); };
1217 }
1218
1219 sub get_tree_from_treeish {
1220         my ($treeish) = @_;
1221         # $treeish can be a symbolic ref, too:
1222         my $type = command_oneline(qw/cat-file -t/, $treeish);
1223         my $expected;
1224         while ($type eq 'tag') {
1225                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1226         }
1227         if ($type eq 'commit') {
1228                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1229                                                     $treeish))[0];
1230                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1231                 die "Unable to get tree from $treeish\n" unless $expected;
1232         } elsif ($type eq 'tree') {
1233                 $expected = $treeish;
1234         } else {
1235                 die "$treeish is a $type, expected tree, tag or commit\n";
1236         }
1237         return $expected;
1238 }
1239
1240 sub get_commit_entry {
1241         my ($treeish) = shift;
1242         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1243         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1244         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1245         open my $log_fh, '>', $commit_editmsg or croak $!;
1246
1247         my $type = command_oneline(qw/cat-file -t/, $treeish);
1248         if ($type eq 'commit' || $type eq 'tag') {
1249                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1250                                                          $type, $treeish);
1251                 my $in_msg = 0;
1252                 my $author;
1253                 my $saw_from = 0;
1254                 my $msgbuf = "";
1255                 while (<$msg_fh>) {
1256                         if (!$in_msg) {
1257                                 $in_msg = 1 if (/^\s*$/);
1258                                 $author = $1 if (/^author (.*>)/);
1259                         } elsif (/^git-svn-id: /) {
1260                                 # skip this for now, we regenerate the
1261                                 # correct one on re-fetch anyways
1262                                 # TODO: set *:merge properties or like...
1263                         } else {
1264                                 if (/^From:/ || /^Signed-off-by:/) {
1265                                         $saw_from = 1;
1266                                 }
1267                                 $msgbuf .= $_;
1268                         }
1269                 }
1270                 $msgbuf =~ s/\s+$//s;
1271                 if ($Git::SVN::_add_author_from && defined($author)
1272                     && !$saw_from) {
1273                         $msgbuf .= "\n\nFrom: $author";
1274                 }
1275                 print $log_fh $msgbuf or croak $!;
1276                 command_close_pipe($msg_fh, $ctx);
1277         }
1278         close $log_fh or croak $!;
1279
1280         if ($_edit || ($type eq 'tree')) {
1281                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1282                 # TODO: strip out spaces, comments, like git-commit.sh
1283                 system($editor, $commit_editmsg);
1284         }
1285         rename $commit_editmsg, $commit_msg or croak $!;
1286         {
1287                 require Encode;
1288                 # SVN requires messages to be UTF-8 when entering the repo
1289                 local $/;
1290                 open $log_fh, '<', $commit_msg or croak $!;
1291                 binmode $log_fh;
1292                 chomp($log_entry{log} = <$log_fh>);
1293
1294                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1295                 my $msg = $log_entry{log};
1296
1297                 eval { $msg = Encode::decode($enc, $msg, 1) };
1298                 if ($@) {
1299                         die "Could not decode as $enc:\n", $msg,
1300                             "\nPerhaps you need to set i18n.commitencoding\n";
1301                 }
1302
1303                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1304                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1305
1306                 $log_entry{log} = $msg;
1307
1308                 close $log_fh or croak $!;
1309         }
1310         unlink $commit_msg;
1311         \%log_entry;
1312 }
1313
1314 sub s_to_file {
1315         my ($str, $file, $mode) = @_;
1316         open my $fd,'>',$file or croak $!;
1317         print $fd $str,"\n" or croak $!;
1318         close $fd or croak $!;
1319         chmod ($mode &~ umask, $file) if (defined $mode);
1320 }
1321
1322 sub file_to_s {
1323         my $file = shift;
1324         open my $fd,'<',$file or croak "$!: file: $file\n";
1325         local $/;
1326         my $ret = <$fd>;
1327         close $fd or croak $!;
1328         $ret =~ s/\s*$//s;
1329         return $ret;
1330 }
1331
1332 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1333 sub load_authors {
1334         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1335         my $log = $cmd eq 'log';
1336         while (<$authors>) {
1337                 chomp;
1338                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1339                 my ($user, $name, $email) = ($1, $2, $3);
1340                 if ($log) {
1341                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1342                 } else {
1343                         $users{$user} = [$name, $email];
1344                 }
1345         }
1346         close $authors or croak $!;
1347 }
1348
1349 # convert GetOpt::Long specs for use by git-config
1350 sub read_repo_config {
1351         return unless -d $ENV{GIT_DIR};
1352         my $opts = shift;
1353         my @config_only;
1354         foreach my $o (keys %$opts) {
1355                 # if we have mixedCase and a long option-only, then
1356                 # it's a config-only variable that we don't need for
1357                 # the command-line.
1358                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1359                 my $v = $opts->{$o};
1360                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1361                 $key =~ s/-//g;
1362                 my $arg = 'git config';
1363                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1364                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1365                 if (ref $v eq 'ARRAY') {
1366                         chomp(my @tmp = `$arg --get-all svn.$key`);
1367                         @$v = @tmp if @tmp;
1368                 } else {
1369                         chomp(my $tmp = `$arg --get svn.$key`);
1370                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1371                                 $$v = $tmp;
1372                         }
1373                 }
1374         }
1375         delete @$opts{@config_only} if @config_only;
1376 }
1377
1378 sub extract_metadata {
1379         my $id = shift or return (undef, undef, undef);
1380         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1381                                                         \s([a-f\d\-]+)$/ix);
1382         if (!defined $rev || !$uuid || !$url) {
1383                 # some of the original repositories I made had
1384                 # identifiers like this:
1385                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1386         }
1387         return ($url, $rev, $uuid);
1388 }
1389
1390 sub cmt_metadata {
1391         return extract_metadata((grep(/^git-svn-id: /,
1392                 command(qw/cat-file commit/, shift)))[-1]);
1393 }
1394
1395 sub cmt_sha2rev_batch {
1396         my %s2r;
1397         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1398         my $list = shift;
1399
1400         foreach my $sha (@{$list}) {
1401                 my $first = 1;
1402                 my $size = 0;
1403                 print $out $sha, "\n";
1404
1405                 while (my $line = <$in>) {
1406                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1407                                 last;
1408                         } elsif ($first &&
1409                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1410                                 $first = 0;
1411                                 $size = $1;
1412                                 next;
1413                         } elsif ($line =~ /^(git-svn-id: )/) {
1414                                 my (undef, $rev, undef) =
1415                                                       extract_metadata($line);
1416                                 $s2r{$sha} = $rev;
1417                         }
1418
1419                         $size -= length($line);
1420                         last if ($size == 0);
1421                 }
1422         }
1423
1424         command_close_bidi_pipe($pid, $in, $out, $ctx);
1425
1426         return \%s2r;
1427 }
1428
1429 sub working_head_info {
1430         my ($head, $refs) = @_;
1431         my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1432         my ($fh, $ctx) = command_output_pipe(@args, $head);
1433         my $hash;
1434         my %max;
1435         while (<$fh>) {
1436                 if ( m{^commit ($::sha1)$} ) {
1437                         unshift @$refs, $hash if $hash and $refs;
1438                         $hash = $1;
1439                         next;
1440                 }
1441                 next unless s{^\s*(git-svn-id:)}{$1};
1442                 my ($url, $rev, $uuid) = extract_metadata($_);
1443                 if (defined $url && defined $rev) {
1444                         next if $max{$url} and $max{$url} < $rev;
1445                         if (my $gs = Git::SVN->find_by_url($url)) {
1446                                 my $c = $gs->rev_map_get($rev, $uuid);
1447                                 if ($c && $c eq $hash) {
1448                                         close $fh; # break the pipe
1449                                         return ($url, $rev, $uuid, $gs);
1450                                 } else {
1451                                         $max{$url} ||= $gs->rev_map_max;
1452                                 }
1453                         }
1454                 }
1455         }
1456         command_close_pipe($fh, $ctx);
1457         (undef, undef, undef, undef);
1458 }
1459
1460 sub read_commit_parents {
1461         my ($parents, $c) = @_;
1462         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1463         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1464         @{$parents->{$c}} = split(/ /, $p);
1465 }
1466
1467 sub linearize_history {
1468         my ($gs, $refs) = @_;
1469         my %parents;
1470         foreach my $c (@$refs) {
1471                 read_commit_parents(\%parents, $c);
1472         }
1473
1474         my @linear_refs;
1475         my %skip = ();
1476         my $last_svn_commit = $gs->last_commit;
1477         foreach my $c (reverse @$refs) {
1478                 next if $c eq $last_svn_commit;
1479                 last if $skip{$c};
1480
1481                 unshift @linear_refs, $c;
1482                 $skip{$c} = 1;
1483
1484                 # we only want the first parent to diff against for linear
1485                 # history, we save the rest to inject when we finalize the
1486                 # svn commit
1487                 my $fp_a = verify_ref("$c~1");
1488                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1489                 if (!$fp_a || !$fp_b) {
1490                         die "Commit $c\n",
1491                             "has no parent commit, and therefore ",
1492                             "nothing to diff against.\n",
1493                             "You should be working from a repository ",
1494                             "originally created by git-svn\n";
1495                 }
1496                 if ($fp_a ne $fp_b) {
1497                         die "$c~1 = $fp_a, however parsing commit $c ",
1498                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1499                 }
1500
1501                 foreach my $p (@{$parents{$c}}) {
1502                         $skip{$p} = 1;
1503                 }
1504         }
1505         (\@linear_refs, \%parents);
1506 }
1507
1508 sub find_file_type_and_diff_status {
1509         my ($path) = @_;
1510         return ('dir', '') if $path eq '';
1511
1512         my $diff_output =
1513             command_oneline(qw(diff --cached --name-status --), $path) || "";
1514         my $diff_status = (split(' ', $diff_output))[0] || "";
1515
1516         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1517
1518         return (undef, undef) if !$diff_status && !$ls_tree;
1519
1520         if ($diff_status eq "A") {
1521                 return ("link", $diff_status) if -l $path;
1522                 return ("dir", $diff_status) if -d $path;
1523                 return ("file", $diff_status);
1524         }
1525
1526         my $mode = (split(' ', $ls_tree))[0] || "";
1527
1528         return ("link", $diff_status) if $mode eq "120000";
1529         return ("dir", $diff_status) if $mode eq "040000";
1530         return ("file", $diff_status);
1531 }
1532
1533 sub md5sum {
1534         my $arg = shift;
1535         my $ref = ref $arg;
1536         my $md5 = Digest::MD5->new();
1537         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1538                 $md5->addfile($arg) or croak $!;
1539         } elsif ($ref eq 'SCALAR') {
1540                 $md5->add($$arg) or croak $!;
1541         } elsif (!$ref) {
1542                 $md5->add($arg) or croak $!;
1543         } else {
1544                 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1545         }
1546         return $md5->hexdigest();
1547 }
1548
1549 sub gc_directory {
1550         if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1551                 my $out_filename = $_ . ".gz";
1552                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1553                 binmode $in_fh;
1554                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1555                                 die "Unable to open $out_filename: $!\n";
1556
1557                 my $res;
1558                 while ($res = sysread($in_fh, my $str, 1024)) {
1559                         $gz->gzwrite($str) or
1560                                 die "Unable to write: ".$gz->gzerror()."!\n";
1561                 }
1562                 unlink $_ or die "unlink $File::Find::name: $!\n";
1563         } elsif (-f $_ && basename($_) eq "index") {
1564                 unlink $_ or die "unlink $_: $!\n";
1565         }
1566 }
1567
1568 package Git::SVN;
1569 use strict;
1570 use warnings;
1571 use Fcntl qw/:DEFAULT :seek/;
1572 use constant rev_map_fmt => 'NH40';
1573 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1574             $_repack $_repack_flags $_use_svm_props $_head
1575             $_use_svnsync_props $no_reuse_existing $_minimize_url
1576             $_use_log_author $_add_author_from $_localtime/;
1577 use Carp qw/croak/;
1578 use File::Path qw/mkpath/;
1579 use File::Copy qw/copy/;
1580 use IPC::Open3;
1581
1582 my ($_gc_nr, $_gc_period);
1583
1584 # properties that we do not log:
1585 my %SKIP_PROP;
1586 BEGIN {
1587         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1588                                         svn:special svn:executable
1589                                         svn:entry:committed-rev
1590                                         svn:entry:last-author
1591                                         svn:entry:uuid
1592                                         svn:entry:committed-date/;
1593
1594         # some options are read globally, but can be overridden locally
1595         # per [svn-remote "..."] section.  Command-line options will *NOT*
1596         # override options set in an [svn-remote "..."] section
1597         no strict 'refs';
1598         for my $option (qw/follow_parent no_metadata use_svm_props
1599                            use_svnsync_props/) {
1600                 my $key = $option;
1601                 $key =~ tr/_//d;
1602                 my $prop = "-$option";
1603                 *$option = sub {
1604                         my ($self) = @_;
1605                         return $self->{$prop} if exists $self->{$prop};
1606                         my $k = "svn-remote.$self->{repo_id}.$key";
1607                         eval { command_oneline(qw/config --get/, $k) };
1608                         if ($@) {
1609                                 $self->{$prop} = ${"Git::SVN::_$option"};
1610                         } else {
1611                                 my $v = command_oneline(qw/config --bool/,$k);
1612                                 $self->{$prop} = $v eq 'false' ? 0 : 1;
1613                         }
1614                         return $self->{$prop};
1615                 }
1616         }
1617 }
1618
1619
1620 my (%LOCKFILES, %INDEX_FILES);
1621 END {
1622         unlink keys %LOCKFILES if %LOCKFILES;
1623         unlink keys %INDEX_FILES if %INDEX_FILES;
1624 }
1625
1626 sub resolve_local_globs {
1627         my ($url, $fetch, $glob_spec) = @_;
1628         return unless defined $glob_spec;
1629         my $ref = $glob_spec->{ref};
1630         my $path = $glob_spec->{path};
1631         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1632                 next unless m#^refs/remotes/$ref->{regex}$#;
1633                 my $p = $1;
1634                 my $pathname = desanitize_refname($path->full_path($p));
1635                 my $refname = desanitize_refname($ref->full_path($p));
1636                 if (my $existing = $fetch->{$pathname}) {
1637                         if ($existing ne $refname) {
1638                                 die "Refspec conflict:\n",
1639                                     "existing: refs/remotes/$existing\n",
1640                                     " globbed: refs/remotes/$refname\n";
1641                         }
1642                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1643                         $u =~ s!^\Q$url\E(/|$)!! or die
1644                           "refs/remotes/$refname: '$url' not found in '$u'\n";
1645                         if ($pathname ne $u) {
1646                                 warn "W: Refspec glob conflict ",
1647                                      "(ref: refs/remotes/$refname):\n",
1648                                      "expected path: $pathname\n",
1649                                      "    real path: $u\n",
1650                                      "Continuing ahead with $u\n";
1651                                 next;
1652                         }
1653                 } else {
1654                         $fetch->{$pathname} = $refname;
1655                 }
1656         }
1657 }
1658
1659 sub parse_revision_argument {
1660         my ($base, $head) = @_;
1661         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1662                 return ($base, $head);
1663         }
1664         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1665         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1666         return ($head, $head) if ($::_revision eq 'HEAD');
1667         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1668         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1669         die "revision argument: $::_revision not understood by git-svn\n";
1670 }
1671
1672 sub fetch_all {
1673         my ($repo_id, $remotes) = @_;
1674         if (ref $repo_id) {
1675                 my $gs = $repo_id;
1676                 $repo_id = undef;
1677                 $repo_id = $gs->{repo_id};
1678         }
1679         $remotes ||= read_all_remotes();
1680         my $remote = $remotes->{$repo_id} or
1681                      die "[svn-remote \"$repo_id\"] unknown\n";
1682         my $fetch = $remote->{fetch};
1683         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1684         my (@gs, @globs);
1685         my $ra = Git::SVN::Ra->new($url);
1686         my $uuid = $ra->get_uuid;
1687         my $head = $ra->get_latest_revnum;
1688         $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1689         my $base = defined $fetch ? $head : 0;
1690
1691         # read the max revs for wildcard expansion (branches/*, tags/*)
1692         foreach my $t (qw/branches tags/) {
1693                 defined $remote->{$t} or next;
1694                 push @globs, @{$remote->{$t}};
1695
1696                 my $max_rev = eval { tmp_config(qw/--int --get/,
1697                                          "svn-remote.$repo_id.${t}-maxRev") };
1698                 if (defined $max_rev && ($max_rev < $base)) {
1699                         $base = $max_rev;
1700                 } elsif (!defined $max_rev) {
1701                         $base = 0;
1702                 }
1703         }
1704
1705         if ($fetch) {
1706                 foreach my $p (sort keys %$fetch) {
1707                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1708                         my $lr = $gs->rev_map_max;
1709                         if (defined $lr) {
1710                                 $base = $lr if ($lr < $base);
1711                         }
1712                         push @gs, $gs;
1713                 }
1714         }
1715
1716         ($base, $head) = parse_revision_argument($base, $head);
1717         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1718 }
1719
1720 sub read_all_remotes {
1721         my $r = {};
1722         my $use_svm_props = eval { command_oneline(qw/config --bool
1723             svn.useSvmProps/) };
1724         $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1725         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1726                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*(.+)\s*$!) {
1727                         my ($remote, $local_ref, $_remote_ref) = ($1, $2, $3);
1728                         die("svn-remote.$remote: remote ref '$_remote_ref' "
1729                             . "must start with 'refs/remotes/'\n")
1730                                 unless $_remote_ref =~ m{^refs/remotes/(.+)};
1731                         my $remote_ref = $1;
1732                         $local_ref =~ s{^/}{};
1733                         $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1734                         $r->{$remote}->{svm} = {} if $use_svm_props;
1735                 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1736                         $r->{$1}->{svm} = {};
1737                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1738                         $r->{$1}->{url} = $2;
1739                 } elsif (m!^(.+)\.(branches|tags)=
1740                            (.*):refs/remotes/(.+)\s*$/!x) {
1741                         my ($p, $g) = ($3, $4);
1742                         my $rs = {
1743                             t => $2,
1744                             remote => $1,
1745                             path => Git::SVN::GlobSpec->new($p),
1746                             ref => Git::SVN::GlobSpec->new($g) };
1747                         if (length($rs->{ref}->{right}) != 0) {
1748                                 die "The '*' glob character must be the last ",
1749                                     "character of '$g'\n";
1750                         }
1751                         push @{ $r->{$1}->{$2} }, $rs;
1752                 }
1753         }
1754
1755         map {
1756                 if (defined $r->{$_}->{svm}) {
1757                         my $svm;
1758                         eval {
1759                                 my $section = "svn-remote.$_";
1760                                 $svm = {
1761                                         source => tmp_config('--get',
1762                                             "$section.svm-source"),
1763                                         replace => tmp_config('--get',
1764                                             "$section.svm-replace"),
1765                                 }
1766                         };
1767                         $r->{$_}->{svm} = $svm;
1768                 }
1769         } keys %$r;
1770
1771         $r;
1772 }
1773
1774 sub init_vars {
1775         $_gc_nr = $_gc_period = 1000;
1776         if (defined $_repack || defined $_repack_flags) {
1777                warn "Repack options are obsolete; they have no effect.\n";
1778         }
1779 }
1780
1781 sub verify_remotes_sanity {
1782         return unless -d $ENV{GIT_DIR};
1783         my %seen;
1784         foreach (command(qw/config -l/)) {
1785                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1786                         if ($seen{$1}) {
1787                                 die "Remote ref refs/remote/$1 is tracked by",
1788                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1789                                     "Please resolve this ambiguity in ",
1790                                     "your git configuration file before ",
1791                                     "continuing\n";
1792                         }
1793                         $seen{$1} = $_;
1794                 }
1795         }
1796 }
1797
1798 sub find_existing_remote {
1799         my ($url, $remotes) = @_;
1800         return undef if $no_reuse_existing;
1801         my $existing;
1802         foreach my $repo_id (keys %$remotes) {
1803                 my $u = $remotes->{$repo_id}->{url} or next;
1804                 next if $u ne $url;
1805                 $existing = $repo_id;
1806                 last;
1807         }
1808         $existing;
1809 }
1810
1811 sub init_remote_config {
1812         my ($self, $url, $no_write) = @_;
1813         $url =~ s!/+$!!; # strip trailing slash
1814         my $r = read_all_remotes();
1815         my $existing = find_existing_remote($url, $r);
1816         if ($existing) {
1817                 unless ($no_write) {
1818                         print STDERR "Using existing ",
1819                                      "[svn-remote \"$existing\"]\n";
1820                 }
1821                 $self->{repo_id} = $existing;
1822         } elsif ($_minimize_url) {
1823                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1824                 $existing = find_existing_remote($min_url, $r);
1825                 if ($existing) {
1826                         unless ($no_write) {
1827                                 print STDERR "Using existing ",
1828                                              "[svn-remote \"$existing\"]\n";
1829                         }
1830                         $self->{repo_id} = $existing;
1831                 }
1832                 if ($min_url ne $url) {
1833                         unless ($no_write) {
1834                                 print STDERR "Using higher level of URL: ",
1835                                              "$url => $min_url\n";
1836                         }
1837                         my $old_path = $self->{path};
1838                         $self->{path} = $url;
1839                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1840                         if (length $old_path) {
1841                                 $self->{path} .= "/$old_path";
1842                         }
1843                         $url = $min_url;
1844                 }
1845         }
1846         my $orig_url;
1847         if (!$existing) {
1848                 # verify that we aren't overwriting anything:
1849                 $orig_url = eval {
1850                         command_oneline('config', '--get',
1851                                         "svn-remote.$self->{repo_id}.url")
1852                 };
1853                 if ($orig_url && ($orig_url ne $url)) {
1854                         die "svn-remote.$self->{repo_id}.url already set: ",
1855                             "$orig_url\nwanted to set to: $url\n";
1856                 }
1857         }
1858         my ($xrepo_id, $xpath) = find_ref($self->refname);
1859         if (defined $xpath) {
1860                 die "svn-remote.$xrepo_id.fetch already set to track ",
1861                     "$xpath:refs/remotes/", $self->refname, "\n";
1862         }
1863         unless ($no_write) {
1864                 command_noisy('config',
1865                               "svn-remote.$self->{repo_id}.url", $url);
1866                 $self->{path} =~ s{^/}{};
1867                 command_noisy('config', '--add',
1868                               "svn-remote.$self->{repo_id}.fetch",
1869                               "$self->{path}:".$self->refname);
1870         }
1871         $self->{url} = $url;
1872 }
1873
1874 sub find_by_url { # repos_root and, path are optional
1875         my ($class, $full_url, $repos_root, $path) = @_;
1876
1877         return undef unless defined $full_url;
1878         remove_username($full_url);
1879         remove_username($repos_root) if defined $repos_root;
1880         my $remotes = read_all_remotes();
1881         if (defined $full_url && defined $repos_root && !defined $path) {
1882                 $path = $full_url;
1883                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1884         }
1885         foreach my $repo_id (keys %$remotes) {
1886                 my $u = $remotes->{$repo_id}->{url} or next;
1887                 remove_username($u);
1888                 next if defined $repos_root && $repos_root ne $u;
1889
1890                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1891                 foreach my $t (qw/branches tags/) {
1892                         foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1893                                 resolve_local_globs($u, $fetch, $globspec);
1894                         }
1895                 }
1896                 my $p = $path;
1897                 my $rwr = rewrite_root({repo_id => $repo_id});
1898                 my $svm = $remotes->{$repo_id}->{svm}
1899                         if defined $remotes->{$repo_id}->{svm};
1900                 unless (defined $p) {
1901                         $p = $full_url;
1902                         my $z = $u;
1903                         my $prefix = '';
1904                         if ($rwr) {
1905                                 $z = $rwr;
1906                                 remove_username($z);
1907                         } elsif (defined $svm) {
1908                                 $z = $svm->{source};
1909                                 $prefix = $svm->{replace};
1910                                 $prefix =~ s#^\Q$u\E(?:/|$)##;
1911                                 $prefix =~ s#/$##;
1912                         }
1913                         $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1914                 }
1915                 foreach my $f (keys %$fetch) {
1916                         next if $f ne $p;
1917                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1918                 }
1919         }
1920         undef;
1921 }
1922
1923 sub init {
1924         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1925         my $self = _new($class, $repo_id, $ref_id, $path);
1926         if (defined $url) {
1927                 $self->init_remote_config($url, $no_write);
1928         }
1929         $self;
1930 }
1931
1932 sub find_ref {
1933         my ($ref_id) = @_;
1934         foreach (command(qw/config -l/)) {
1935                 next unless m!^svn-remote\.(.+)\.fetch=
1936                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1937                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1938                 if ($ref eq $ref_id) {
1939                         $path = '' if ($path =~ m#^\./?#);
1940                         return ($repo_id, $path);
1941                 }
1942         }
1943         (undef, undef, undef);
1944 }
1945
1946 sub new {
1947         my ($class, $ref_id, $repo_id, $path) = @_;
1948         if (defined $ref_id && !defined $repo_id && !defined $path) {
1949                 ($repo_id, $path) = find_ref($ref_id);
1950                 if (!defined $repo_id) {
1951                         die "Could not find a \"svn-remote.*.fetch\" key ",
1952                             "in the repository configuration matching: ",
1953                             "refs/remotes/$ref_id\n";
1954                 }
1955         }
1956         my $self = _new($class, $repo_id, $ref_id, $path);
1957         if (!defined $self->{path} || !length $self->{path}) {
1958                 my $fetch = command_oneline('config', '--get',
1959                                             "svn-remote.$repo_id.fetch",
1960                                             ":refs/remotes/$ref_id\$") or
1961                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1962                          "\":refs/remotes/$ref_id\$\" in config\n";
1963                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1964         }
1965         $self->{url} = command_oneline('config', '--get',
1966                                        "svn-remote.$repo_id.url") or
1967                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1968         $self->rebuild;
1969         $self;
1970 }
1971
1972 sub refname {
1973         my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1974
1975         # It cannot end with a slash /, we'll throw up on this because
1976         # SVN can't have directories with a slash in their name, either:
1977         if ($refname =~ m{/$}) {
1978                 die "ref: '$refname' ends with a trailing slash, this is ",
1979                     "not permitted by git nor Subversion\n";
1980         }
1981
1982         # It cannot have ASCII control character space, tilde ~, caret ^,
1983         # colon :, question-mark ?, asterisk *, space, or open bracket [
1984         # anywhere.
1985         #
1986         # Additionally, % must be escaped because it is used for escaping
1987         # and we want our escaped refname to be reversible
1988         $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1989
1990         # no slash-separated component can begin with a dot .
1991         # /.* becomes /%2E*
1992         $refname =~ s{/\.}{/%2E}g;
1993
1994         # It cannot have two consecutive dots .. anywhere
1995         # .. becomes %2E%2E
1996         $refname =~ s{\.\.}{%2E%2E}g;
1997
1998         return $refname;
1999 }
2000
2001 sub desanitize_refname {
2002         my ($refname) = @_;
2003         $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2004         return $refname;
2005 }
2006
2007 sub svm_uuid {
2008         my ($self) = @_;
2009         return $self->{svm}->{uuid} if $self->svm;
2010         $self->ra;
2011         unless ($self->{svm}) {
2012                 die "SVM UUID not cached, and reading remotely failed\n";
2013         }
2014         $self->{svm}->{uuid};
2015 }
2016
2017 sub svm {
2018         my ($self) = @_;
2019         return $self->{svm} if $self->{svm};
2020         my $svm;
2021         # see if we have it in our config, first:
2022         eval {
2023                 my $section = "svn-remote.$self->{repo_id}";
2024                 $svm = {
2025                   source => tmp_config('--get', "$section.svm-source"),
2026                   uuid => tmp_config('--get', "$section.svm-uuid"),
2027                   replace => tmp_config('--get', "$section.svm-replace"),
2028                 }
2029         };
2030         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2031                 $self->{svm} = $svm;
2032         }
2033         $self->{svm};
2034 }
2035
2036 sub _set_svm_vars {
2037         my ($self, $ra) = @_;
2038         return $ra if $self->svm;
2039
2040         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2041                     "(svm:source, svm:uuid) ",
2042                     "from the following URLs:\n" );
2043         sub read_svm_props {
2044                 my ($self, $ra, $path, $r) = @_;
2045                 my $props = ($ra->get_dir($path, $r))[2];
2046                 my $src = $props->{'svm:source'};
2047                 my $uuid = $props->{'svm:uuid'};
2048                 return undef if (!$src || !$uuid);
2049
2050                 chomp($src, $uuid);
2051
2052                 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2053                     or die "doesn't look right - svm:uuid is '$uuid'\n";
2054
2055                 # the '!' is used to mark the repos_root!/relative/path
2056                 $src =~ s{/?!/?}{/};
2057                 $src =~ s{/+$}{}; # no trailing slashes please
2058                 # username is of no interest
2059                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2060
2061                 my $replace = $ra->{url};
2062                 $replace .= "/$path" if length $path;
2063
2064                 my $section = "svn-remote.$self->{repo_id}";
2065                 tmp_config("$section.svm-source", $src);
2066                 tmp_config("$section.svm-replace", $replace);
2067                 tmp_config("$section.svm-uuid", $uuid);
2068                 $self->{svm} = {
2069                         source => $src,
2070                         uuid => $uuid,
2071                         replace => $replace
2072                 };
2073         }
2074
2075         my $r = $ra->get_latest_revnum;
2076         my $path = $self->{path};
2077         my %tried;
2078         while (length $path) {
2079                 unless ($tried{"$self->{url}/$path"}) {
2080                         return $ra if $self->read_svm_props($ra, $path, $r);
2081                         $tried{"$self->{url}/$path"} = 1;
2082                 }
2083                 $path =~ s#/?[^/]+$##;
2084         }
2085         die "Path: '$path' should be ''\n" if $path ne '';
2086         return $ra if $self->read_svm_props($ra, $path, $r);
2087         $tried{"$self->{url}/$path"} = 1;
2088
2089         if ($ra->{repos_root} eq $self->{url}) {
2090                 die @err, (map { "  $_\n" } keys %tried), "\n";
2091         }
2092
2093         # nope, make sure we're connected to the repository root:
2094         my $ok;
2095         my @tried_b;
2096         $path = $ra->{svn_path};
2097         $ra = Git::SVN::Ra->new($ra->{repos_root});
2098         while (length $path) {
2099                 unless ($tried{"$ra->{url}/$path"}) {
2100                         $ok = $self->read_svm_props($ra, $path, $r);
2101                         last if $ok;
2102                         $tried{"$ra->{url}/$path"} = 1;
2103                 }
2104                 $path =~ s#/?[^/]+$##;
2105         }
2106         die "Path: '$path' should be ''\n" if $path ne '';
2107         $ok ||= $self->read_svm_props($ra, $path, $r);
2108         $tried{"$ra->{url}/$path"} = 1;
2109         if (!$ok) {
2110                 die @err, (map { "  $_\n" } keys %tried), "\n";
2111         }
2112         Git::SVN::Ra->new($self->{url});
2113 }
2114
2115 sub svnsync {
2116         my ($self) = @_;
2117         return $self->{svnsync} if $self->{svnsync};
2118
2119         if ($self->no_metadata) {
2120                 die "Can't have both 'noMetadata' and ",
2121                     "'useSvnsyncProps' options set!\n";
2122         }
2123         if ($self->rewrite_root) {
2124                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2125                     "options set!\n";
2126         }
2127
2128         my $svnsync;
2129         # see if we have it in our config, first:
2130         eval {
2131                 my $section = "svn-remote.$self->{repo_id}";
2132
2133                 my $url = tmp_config('--get', "$section.svnsync-url");
2134                 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2135                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2136
2137                 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2138                 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2139                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2140
2141                 $svnsync = { url => $url, uuid => $uuid }
2142         };
2143         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2144                 return $self->{svnsync} = $svnsync;
2145         }
2146
2147         my $err = "useSvnsyncProps set, but failed to read " .
2148                   "svnsync property: svn:sync-from-";
2149         my $rp = $self->ra->rev_proplist(0);
2150
2151         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2152         ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2153                    die "doesn't look right - svn:sync-from-url is '$url'\n";
2154
2155         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2156         ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2157                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2158
2159         my $section = "svn-remote.$self->{repo_id}";
2160         tmp_config('--add', "$section.svnsync-uuid", $uuid);
2161         tmp_config('--add', "$section.svnsync-url", $url);
2162         return $self->{svnsync} = { url => $url, uuid => $uuid };
2163 }
2164
2165 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2166 # remote lookup (useful for 'git svn log').
2167 sub ra_uuid {
2168         my ($self) = @_;
2169         unless ($self->{ra_uuid}) {
2170                 my $key = "svn-remote.$self->{repo_id}.uuid";
2171                 my $uuid = eval { tmp_config('--get', $key) };
2172                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2173                         $self->{ra_uuid} = $uuid;
2174                 } else {
2175                         die "ra_uuid called without URL\n" unless $self->{url};
2176                         $self->{ra_uuid} = $self->ra->get_uuid;
2177                         tmp_config('--add', $key, $self->{ra_uuid});
2178                 }
2179         }
2180         $self->{ra_uuid};
2181 }
2182
2183 sub _set_repos_root {
2184         my ($self, $repos_root) = @_;
2185         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2186         $repos_root ||= $self->ra->{repos_root};
2187         tmp_config($k, $repos_root);
2188         $repos_root;
2189 }
2190
2191 sub repos_root {
2192         my ($self) = @_;
2193         my $k = "svn-remote.$self->{repo_id}.reposRoot";
2194         eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2195 }
2196
2197 sub ra {
2198         my ($self) = shift;
2199         my $ra = Git::SVN::Ra->new($self->{url});
2200         $self->_set_repos_root($ra->{repos_root});
2201         if ($self->use_svm_props && !$self->{svm}) {
2202                 if ($self->no_metadata) {
2203                         die "Can't have both 'noMetadata' and ",
2204                             "'useSvmProps' options set!\n";
2205                 } elsif ($self->use_svnsync_props) {
2206                         die "Can't have both 'useSvnsyncProps' and ",
2207                             "'useSvmProps' options set!\n";
2208                 }
2209                 $ra = $self->_set_svm_vars($ra);
2210                 $self->{-want_revprops} = 1;
2211         }
2212         $ra;
2213 }
2214
2215 # prop_walk(PATH, REV, SUB)
2216 # -------------------------
2217 # Recursively traverse PATH at revision REV and invoke SUB for each
2218 # directory that contains a SVN property.  SUB will be invoked as
2219 # follows:  &SUB(gs, path, props);  where `gs' is this instance of
2220 # Git::SVN, `path' the path to the directory where the properties
2221 # `props' were found.  The `path' will be relative to point of checkout,
2222 # that is, if url://repo/trunk is the current Git branch, and that
2223 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2224 # as `path' (note the trailing `/').
2225 sub prop_walk {
2226         my ($self, $path, $rev, $sub) = @_;
2227
2228         $path =~ s#^/##;
2229         my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2230         $path =~ s#^/*#/#g;
2231         my $p = $path;
2232         # Strip the irrelevant part of the path.
2233         $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2234         # Ensure the path is terminated by a `/'.
2235         $p =~ s#/*$#/#;
2236
2237         # The properties contain all the internal SVN stuff nobody
2238         # (usually) cares about.
2239         my $interesting_props = 0;
2240         foreach (keys %{$props}) {
2241                 # If it doesn't start with `svn:', it must be a
2242                 # user-defined property.
2243                 ++$interesting_props and next if $_ !~ /^svn:/;
2244                 # FIXME: Fragile, if SVN adds new public properties,
2245                 # this needs to be updated.
2246                 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2247                                                  |eol-style|mime-type
2248                                                  |externals|needs-lock)$/x;
2249         }
2250         &$sub($self, $p, $props) if $interesting_props;
2251
2252         foreach (sort keys %$dirent) {
2253                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2254                 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2255         }
2256 }
2257
2258 sub last_rev { ($_[0]->last_rev_commit)[0] }
2259 sub last_commit { ($_[0]->last_rev_commit)[1] }
2260
2261 # returns the newest SVN revision number and newest commit SHA1
2262 sub last_rev_commit {
2263         my ($self) = @_;
2264         if (defined $self->{last_rev} && defined $self->{last_commit}) {
2265                 return ($self->{last_rev}, $self->{last_commit});
2266         }
2267         my $c = ::verify_ref($self->refname.'^0');
2268         if ($c && !$self->use_svm_props && !$self->no_metadata) {
2269                 my $rev = (::cmt_metadata($c))[1];
2270                 if (defined $rev) {
2271                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2272                         return ($rev, $c);
2273                 }
2274         }
2275         my $map_path = $self->map_path;
2276         unless (-e $map_path) {
2277                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2278                 return (undef, undef);
2279         }
2280         my ($rev, $commit) = $self->rev_map_max(1);
2281         ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2282         return ($rev, $commit);
2283 }
2284
2285 sub get_fetch_range {
2286         my ($self, $min, $max) = @_;
2287         $max ||= $self->ra->get_latest_revnum;
2288         $min ||= $self->rev_map_max;
2289         (++$min, $max);
2290 }
2291
2292 sub tmp_config {
2293         my (@args) = @_;
2294         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2295         my $config = "$ENV{GIT_DIR}/svn/.metadata";
2296         if (! -f $config && -f $old_def_config) {
2297                 rename $old_def_config, $config or
2298                        die "Failed rename $old_def_config => $config: $!\n";
2299         }
2300         my $old_config = $ENV{GIT_CONFIG};
2301         $ENV{GIT_CONFIG} = $config;
2302         $@ = undef;
2303         my @ret = eval {
2304                 unless (-f $config) {
2305                         mkfile($config);
2306                         open my $fh, '>', $config or
2307                             die "Can't open $config: $!\n";
2308                         print $fh "; This file is used internally by ",
2309                                   "git-svn\n" or die
2310                                   "Couldn't write to $config: $!\n";
2311                         print $fh "; You should not have to edit it\n" or
2312                               die "Couldn't write to $config: $!\n";
2313                         close $fh or die "Couldn't close $config: $!\n";
2314                 }
2315                 command('config', @args);
2316         };
2317         my $err = $@;
2318         if (defined $old_config) {
2319                 $ENV{GIT_CONFIG} = $old_config;
2320         } else {
2321                 delete $ENV{GIT_CONFIG};
2322         }
2323         die $err if $err;
2324         wantarray ? @ret : $ret[0];
2325 }
2326
2327 sub tmp_index_do {
2328         my ($self, $sub) = @_;
2329         my $old_index = $ENV{GIT_INDEX_FILE};
2330         $ENV{GIT_INDEX_FILE} = $self->{index};
2331         $@ = undef;
2332         my @ret = eval {
2333                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2334                 mkpath([$dir]) unless -d $dir;
2335                 &$sub;
2336         };
2337         my $err = $@;
2338         if (defined $old_index) {
2339                 $ENV{GIT_INDEX_FILE} = $old_index;
2340         } else {
2341                 delete $ENV{GIT_INDEX_FILE};
2342         }
2343         die $err if $err;
2344         wantarray ? @ret : $ret[0];
2345 }
2346
2347 sub assert_index_clean {
2348         my ($self, $treeish) = @_;
2349
2350         $self->tmp_index_do(sub {
2351                 command_noisy('read-tree', $treeish) unless -e $self->{index};
2352                 my $x = command_oneline('write-tree');
2353                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2354                            /^tree ($::sha1)/mo);
2355                 return if $y eq $x;
2356
2357                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2358                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2359                 command_noisy('read-tree', $treeish);
2360                 $x = command_oneline('write-tree');
2361                 if ($y ne $x) {
2362                         ::fatal "trees ($treeish) $y != $x\n",
2363                                 "Something is seriously wrong...";
2364                 }
2365         });
2366 }
2367
2368 sub get_commit_parents {
2369         my ($self, $log_entry) = @_;
2370         my (%seen, @ret, @tmp);
2371         # legacy support for 'set-tree'; this is only used by set_tree_cb:
2372         if (my $ip = $self->{inject_parents}) {
2373                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2374                         push @tmp, $commit;
2375                 }
2376         }
2377         if (my $cur = ::verify_ref($self->refname.'^0')) {
2378                 push @tmp, $cur;
2379         }
2380         if (my $ipd = $self->{inject_parents_dcommit}) {
2381                 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2382                         push @tmp, @$commit;
2383                 }
2384         }
2385         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2386         while (my $p = shift @tmp) {
2387                 next if $seen{$p};
2388                 $seen{$p} = 1;
2389                 push @ret, $p;
2390                 # MAXPARENT is defined to 16 in commit-tree.c:
2391                 last if @ret >= 16;
2392         }
2393         if (@tmp) {
2394                 die "r$log_entry->{revision}: No room for parents:\n\t",
2395                     join("\n\t", @tmp), "\n";
2396         }
2397         @ret;
2398 }
2399
2400 sub rewrite_root {
2401         my ($self) = @_;
2402         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2403         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2404         my $rwr = eval { command_oneline(qw/config --get/, $k) };
2405         if ($rwr) {
2406                 $rwr =~ s#/+$##;
2407                 if ($rwr !~ m#^[a-z\+]+://#) {
2408                         die "$rwr is not a valid URL (key: $k)\n";
2409                 }
2410         }
2411         $self->{-rewrite_root} = $rwr;
2412 }
2413
2414 sub metadata_url {
2415         my ($self) = @_;
2416         ($self->rewrite_root || $self->{url}) .
2417            (length $self->{path} ? '/' . $self->{path} : '');
2418 }
2419
2420 sub full_url {
2421         my ($self) = @_;
2422         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2423 }
2424
2425
2426 sub set_commit_header_env {
2427         my ($log_entry) = @_;
2428         my %env;
2429         foreach my $ned (qw/NAME EMAIL DATE/) {
2430                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2431                         $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2432                 }
2433         }
2434
2435         $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2436         $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2437         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2438
2439         $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2440                                                 ? $log_entry->{commit_name}
2441                                                 : $log_entry->{name};
2442         $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2443                                                 ? $log_entry->{commit_email}
2444                                                 : $log_entry->{email};
2445         \%env;
2446 }
2447
2448 sub restore_commit_header_env {
2449         my ($env) = @_;
2450         foreach my $ned (qw/NAME EMAIL DATE/) {
2451                 foreach my $ac (qw/AUTHOR COMMITTER/) {
2452                         my $k = "GIT_${ac}_${ned}";
2453                         if (defined $env->{$k}) {
2454                                 $ENV{$k} = $env->{$k};
2455                         } else {
2456                                 delete $ENV{$k};
2457                         }
2458                 }
2459         }
2460 }
2461
2462 sub gc {
2463         command_noisy('gc', '--auto');
2464 };
2465
2466 sub do_git_commit {
2467         my ($self, $log_entry) = @_;
2468         my $lr = $self->last_rev;
2469         if (defined $lr && $lr >= $log_entry->{revision}) {
2470                 die "Last fetched revision of ", $self->refname,
2471                     " was r$lr, but we are about to fetch: ",
2472                     "r$log_entry->{revision}!\n";
2473         }
2474         if (my $c = $self->rev_map_get($log_entry->{revision})) {
2475                 croak "$log_entry->{revision} = $c already exists! ",
2476                       "Why are we refetching it?\n";
2477         }
2478         my $old_env = set_commit_header_env($log_entry);
2479         my $tree = $log_entry->{tree};
2480         if (!defined $tree) {
2481                 $tree = $self->tmp_index_do(sub {
2482                                             command_oneline('write-tree') });
2483         }
2484         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2485
2486         my @exec = ('git', 'commit-tree', $tree);
2487         foreach ($self->get_commit_parents($log_entry)) {
2488                 push @exec, '-p', $_;
2489         }
2490         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2491                                                                    or croak $!;
2492         binmode $msg_fh;
2493
2494         # we always get UTF-8 from SVN, but we may want our commits in
2495         # a different encoding.
2496         if (my $enc = Git::config('i18n.commitencoding')) {
2497                 require Encode;
2498                 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2499         }
2500         print $msg_fh $log_entry->{log} or croak $!;
2501         restore_commit_header_env($old_env);
2502         unless ($self->no_metadata) {
2503                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2504                               or croak $!;
2505         }
2506         $msg_fh->flush == 0 or croak $!;
2507         close $msg_fh or croak $!;
2508         chomp(my $commit = do { local $/; <$out_fh> });
2509         close $out_fh or croak $!;
2510         waitpid $pid, 0;
2511         croak $? if $?;
2512         if ($commit !~ /^$::sha1$/o) {
2513                 die "Failed to commit, invalid sha1: $commit\n";
2514         }
2515
2516         $self->rev_map_set($log_entry->{revision}, $commit, 1);
2517
2518         $self->{last_rev} = $log_entry->{revision};
2519         $self->{last_commit} = $commit;
2520         print "r$log_entry->{revision}" unless $::_q > 1;
2521         if (defined $log_entry->{svm_revision}) {
2522                  print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2523                  $self->rev_map_set($log_entry->{svm_revision}, $commit,
2524                                    0, $self->svm_uuid);
2525         }
2526         print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2527         if (--$_gc_nr == 0) {
2528                 $_gc_nr = $_gc_period;
2529                 gc();
2530         }
2531         return $commit;
2532 }
2533
2534 sub match_paths {
2535         my ($self, $paths, $r) = @_;
2536         return 1 if $self->{path} eq '';
2537         if (my $path = $paths->{"/$self->{path}"}) {
2538                 return ($path->{action} eq 'D') ? 0 : 1;
2539         }
2540         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2541         if (grep /$self->{path_regex}/, keys %$paths) {
2542                 return 1;
2543         }
2544         my $c = '';
2545         foreach (split m#/#, $self->{path}) {
2546                 $c .= "/$_";
2547                 next unless ($paths->{$c} &&
2548                              ($paths->{$c}->{action} =~ /^[AR]$/));
2549                 if ($self->ra->check_path($self->{path}, $r) ==
2550                     $SVN::Node::dir) {
2551                         return 1;
2552                 }
2553         }
2554         return 0;
2555 }
2556
2557 sub find_parent_branch {
2558         my ($self, $paths, $rev) = @_;
2559         return undef unless $self->follow_parent;
2560         unless (defined $paths) {
2561                 my $err_handler = $SVN::Error::handler;
2562                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2563                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2564                                    sub { $paths = $_[0] });
2565                 $SVN::Error::handler = $err_handler;
2566         }
2567         return undef unless defined $paths;
2568
2569         # look for a parent from another branch:
2570         my @b_path_components = split m#/#, $self->{path};
2571         my @a_path_components;
2572         my $i;
2573         while (@b_path_components) {
2574                 $i = $paths->{'/'.join('/', @b_path_components)};
2575                 last if $i && defined $i->{copyfrom_path};
2576                 unshift(@a_path_components, pop(@b_path_components));
2577         }
2578         return undef unless defined $i && defined $i->{copyfrom_path};
2579         my $branch_from = $i->{copyfrom_path};
2580         if (@a_path_components) {
2581                 print STDERR "branch_from: $branch_from => ";
2582                 $branch_from .= '/'.join('/', @a_path_components);
2583                 print STDERR $branch_from, "\n";
2584         }
2585         my $r = $i->{copyfrom_rev};
2586         my $repos_root = $self->ra->{repos_root};
2587         my $url = $self->ra->{url};
2588         my $new_url = $url . $branch_from;
2589         print STDERR  "Found possible branch point: ",
2590                       "$new_url => ", $self->full_url, ", $r\n";
2591         $branch_from =~ s#^/##;
2592         my $gs = $self->other_gs($new_url, $url,
2593                                  $branch_from, $r, $self->{ref_id});
2594         my ($r0, $parent) = $gs->find_rev_before($r, 1);
2595         {
2596                 my ($base, $head);
2597                 if (!defined $r0 || !defined $parent) {
2598                         ($base, $head) = parse_revision_argument(0, $r);
2599                 } else {
2600                         if ($r0 < $r) {
2601                                 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2602                                         0, 1, sub { $base = $_[1] - 1 });
2603                         }
2604                 }
2605                 if (defined $base && $base <= $r) {
2606                         $gs->fetch($base, $r);
2607                 }
2608                 ($r0, $parent) = $gs->find_rev_before($r, 1);
2609         }
2610         if (defined $r0 && defined $parent) {
2611                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2612                 my $ed;
2613                 if ($self->ra->can_do_switch) {
2614                         $self->assert_index_clean($parent);
2615                         print STDERR "Following parent with do_switch\n";
2616                         # do_switch works with svn/trunk >= r22312, but that
2617                         # is not included with SVN 1.4.3 (the latest version
2618                         # at the moment), so we can't rely on it
2619                         $self->{last_rev} = $r0;
2620                         $self->{last_commit} = $parent;
2621                         $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2622                         $gs->ra->gs_do_switch($r0, $rev, $gs,
2623                                               $self->full_url, $ed)
2624                           or die "SVN connection failed somewhere...\n";
2625                 } elsif ($self->ra->trees_match($new_url, $r0,
2626                                                 $self->full_url, $rev)) {
2627                         print STDERR "Trees match:\n",
2628                                      "  $new_url\@$r0\n",
2629                                      "  ${\$self->full_url}\@$rev\n",
2630                                      "Following parent with no changes\n";
2631                         $self->tmp_index_do(sub {
2632                             command_noisy('read-tree', $parent);
2633                         });
2634                         $self->{last_commit} = $parent;
2635                 } else {
2636                         print STDERR "Following parent with do_update\n";
2637                         $ed = SVN::Git::Fetcher->new($self);
2638                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
2639                           or die "SVN connection failed somewhere...\n";
2640                 }
2641                 print STDERR "Successfully followed parent\n";
2642                 return $self->make_log_entry($rev, [$parent], $ed);
2643         }
2644         return undef;
2645 }
2646
2647 sub do_fetch {
2648         my ($self, $paths, $rev) = @_;
2649         my $ed;
2650         my ($last_rev, @parents);
2651         if (my $lc = $self->last_commit) {
2652                 # we can have a branch that was deleted, then re-added
2653                 # under the same name but copied from another path, in
2654                 # which case we'll have multiple parents (we don't
2655                 # want to break the original ref, nor lose copypath info):
2656                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2657                         push @{$log_entry->{parents}}, $lc;
2658                         return $log_entry;
2659                 }
2660                 $ed = SVN::Git::Fetcher->new($self);
2661                 $last_rev = $self->{last_rev};
2662                 $ed->{c} = $lc;
2663                 @parents = ($lc);
2664         } else {
2665                 $last_rev = $rev;
2666                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2667                         return $log_entry;
2668                 }
2669                 $ed = SVN::Git::Fetcher->new($self);
2670         }
2671         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2672                 die "SVN connection failed somewhere...\n";
2673         }
2674         $self->make_log_entry($rev, \@parents, $ed);
2675 }
2676
2677 sub get_untracked {
2678         my ($self, $ed) = @_;
2679         my @out;
2680         my $h = $ed->{empty};
2681         foreach (sort keys %$h) {
2682                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2683                 push @out, "  $act: " . uri_encode($_);
2684                 warn "W: $act: $_\n";
2685         }
2686         foreach my $t (qw/dir_prop file_prop/) {
2687                 $h = $ed->{$t} or next;
2688                 foreach my $path (sort keys %$h) {
2689                         my $ppath = $path eq '' ? '.' : $path;
2690                         foreach my $prop (sort keys %{$h->{$path}}) {
2691                                 next if $SKIP_PROP{$prop};
2692                                 my $v = $h->{$path}->{$prop};
2693                                 my $t_ppath_prop = "$t: " .
2694                                                     uri_encode($ppath) . ' ' .
2695                                                     uri_encode($prop);
2696                                 if (defined $v) {
2697                                         push @out, "  +$t_ppath_prop " .
2698                                                    uri_encode($v);
2699                                 } else {
2700                                         push @out, "  -$t_ppath_prop";
2701                                 }
2702                         }
2703                 }
2704         }
2705         foreach my $t (qw/absent_file absent_directory/) {
2706                 $h = $ed->{$t} or next;
2707                 foreach my $parent (sort keys %$h) {
2708                         foreach my $path (sort @{$h->{$parent}}) {
2709                                 push @out, "  $t: " .
2710                                            uri_encode("$parent/$path");
2711                                 warn "W: $t: $parent/$path ",
2712                                      "Insufficient permissions?\n";
2713                         }
2714                 }
2715         }
2716         \@out;
2717 }
2718
2719 # parse_svn_date(DATE)
2720 # --------------------
2721 # Given a date (in UTC) from Subversion, return a string in the format
2722 # "<TZ Offset> <local date/time>" that Git will use.
2723 #
2724 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2725 # is true we'll convert it to the local timezone instead.
2726 sub parse_svn_date {
2727         my $date = shift || return '+0000 1970-01-01 00:00:00';
2728         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2729                                             (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2730                                          croak "Unable to parse date: $date\n";
2731         my $parsed_date;    # Set next.
2732
2733         if ($Git::SVN::_localtime) {
2734                 # Translate the Subversion datetime to an epoch time.
2735                 # Begin by switching ourselves to $date's timezone, UTC.
2736                 my $old_env_TZ = $ENV{TZ};
2737                 $ENV{TZ} = 'UTC';
2738
2739                 my $epoch_in_UTC =
2740                     POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2741
2742                 # Determine our local timezone (including DST) at the
2743                 # time of $epoch_in_UTC.  $Git::SVN::Log::TZ stored the
2744                 # value of TZ, if any, at the time we were run.
2745                 if (defined $Git::SVN::Log::TZ) {
2746                         $ENV{TZ} = $Git::SVN::Log::TZ;
2747                 } else {
2748                         delete $ENV{TZ};
2749                 }
2750
2751                 my $our_TZ =
2752                     POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2753
2754                 # This converts $epoch_in_UTC into our local timezone.
2755                 my ($sec, $min, $hour, $mday, $mon, $year,
2756                     $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2757
2758                 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2759                                        $our_TZ, $year + 1900, $mon + 1,
2760                                        $mday, $hour, $min, $sec);
2761
2762                 # Reset us to the timezone in effect when we entered
2763                 # this routine.
2764                 if (defined $old_env_TZ) {
2765                         $ENV{TZ} = $old_env_TZ;
2766                 } else {
2767                         delete $ENV{TZ};
2768                 }
2769         } else {
2770                 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2771         }
2772
2773         return $parsed_date;
2774 }
2775
2776 sub other_gs {
2777         my ($self, $new_url, $url,
2778             $branch_from, $r, $old_ref_id) = @_;
2779         my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2780         unless ($gs) {
2781                 my $ref_id = $old_ref_id;
2782                 $ref_id =~ s/\@\d+$//;
2783                 $ref_id .= "\@$r";
2784                 # just grow a tail if we're not unique enough :x
2785                 $ref_id .= '-' while find_ref($ref_id);
2786                 print STDERR "Initializing parent: $ref_id\n";
2787                 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2788                 if ($u =~ s#^\Q$url\E(/|$)##) {
2789                         $p = $u;
2790                         $u = $url;
2791                         $repo_id = $self->{repo_id};
2792                 }
2793                 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2794         }
2795         $gs
2796 }
2797
2798 sub call_authors_prog {
2799         my ($orig_author) = @_;
2800         my $author = `$::_authors_prog $orig_author`;
2801         if ($? != 0) {
2802                 die "$::_authors_prog failed with exit code $?\n"
2803         }
2804         if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2805                 my ($name, $email) = ($1, $2);
2806                 $email = undef if length $2 == 0;
2807                 return [$name, $email];
2808         } else {
2809                 die "Author: $orig_author: $::_authors_prog returned "
2810                         . "invalid author format: $author\n";
2811         }
2812 }
2813
2814 sub check_author {
2815         my ($author) = @_;
2816         if (!defined $author || length $author == 0) {
2817                 $author = '(no author)';
2818         }
2819         if (!defined $::users{$author}) {
2820                 if (defined $::_authors_prog) {
2821                         $::users{$author} = call_authors_prog($author);
2822                 } elsif (defined $::_authors) {
2823                         die "Author: $author not defined in $::_authors file\n";
2824                 }
2825         }
2826         $author;
2827 }
2828
2829 sub make_log_entry {
2830         my ($self, $rev, $parents, $ed) = @_;
2831         my $untracked = $self->get_untracked($ed);
2832
2833         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2834         print $un "r$rev\n" or croak $!;
2835         print $un $_, "\n" foreach @$untracked;
2836         my %log_entry = ( parents => $parents || [], revision => $rev,
2837                           log => '');
2838
2839         my $headrev;
2840         my $logged = delete $self->{logged_rev_props};
2841         if (!$logged || $self->{-want_revprops}) {
2842                 my $rp = $self->ra->rev_proplist($rev);
2843                 foreach (sort keys %$rp) {
2844                         my $v = $rp->{$_};
2845                         if (/^svn:(author|date|log)$/) {
2846                                 $log_entry{$1} = $v;
2847                         } elsif ($_ eq 'svm:headrev') {
2848                                 $headrev = $v;
2849                         } else {
2850                                 print $un "  rev_prop: ", uri_encode($_), ' ',
2851                                           uri_encode($v), "\n";
2852                         }
2853                 }
2854         } else {
2855                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2856         }
2857         close $un or croak $!;
2858
2859         $log_entry{date} = parse_svn_date($log_entry{date});
2860         $log_entry{log} .= "\n";
2861         my $author = $log_entry{author} = check_author($log_entry{author});
2862         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2863                                                        : ($author, undef);
2864
2865         my ($commit_name, $commit_email) = ($name, $email);
2866         if ($_use_log_author) {
2867                 my $name_field;
2868                 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2869                         $name_field = $1;
2870                 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2871                         $name_field = $1;
2872                 }
2873                 if (!defined $name_field) {
2874                         if (!defined $email) {
2875                                 $email = $name;
2876                         }
2877                 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2878                         ($name, $email) = ($1, $2);
2879                 } elsif ($name_field =~ /(.*)@/) {
2880                         ($name, $email) = ($1, $name_field);
2881                 } else {
2882                         ($name, $email) = ($name_field, $name_field);
2883                 }
2884         }
2885         if (defined $headrev && $self->use_svm_props) {
2886                 if ($self->rewrite_root) {
2887                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2888                             "options set!\n";
2889                 }
2890                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2891                 # we don't want "SVM: initializing mirror for junk" ...
2892                 return undef if $r == 0;
2893                 my $svm = $self->svm;
2894                 if ($uuid ne $svm->{uuid}) {
2895                         die "UUID mismatch on SVM path:\n",
2896                             "expected: $svm->{uuid}\n",
2897                             "     got: $uuid\n";
2898                 }
2899                 my $full_url = $self->full_url;
2900                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2901                              die "Failed to replace '$svm->{replace}' with ",
2902                                  "'$svm->{source}' in $full_url\n";
2903                 # throw away username for storing in records
2904                 remove_username($full_url);
2905                 $log_entry{metadata} = "$full_url\@$r $uuid";
2906                 $log_entry{svm_revision} = $r;
2907                 $email ||= "$author\@$uuid";
2908                 $commit_email ||= "$author\@$uuid";
2909         } elsif ($self->use_svnsync_props) {
2910                 my $full_url = $self->svnsync->{url};
2911                 $full_url .= "/$self->{path}" if length $self->{path};
2912                 remove_username($full_url);
2913                 my $uuid = $self->svnsync->{uuid};
2914                 $log_entry{metadata} = "$full_url\@$rev $uuid";
2915                 $email ||= "$author\@$uuid";
2916                 $commit_email ||= "$author\@$uuid";
2917         } else {
2918                 my $url = $self->metadata_url;
2919                 remove_username($url);
2920                 $log_entry{metadata} = "$url\@$rev " .
2921                                        $self->ra->get_uuid;
2922                 $email ||= "$author\@" . $self->ra->get_uuid;
2923                 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2924         }
2925         $log_entry{name} = $name;
2926         $log_entry{email} = $email;
2927         $log_entry{commit_name} = $commit_name;
2928         $log_entry{commit_email} = $commit_email;
2929         \%log_entry;
2930 }
2931
2932 sub fetch {
2933         my ($self, $min_rev, $max_rev, @parents) = @_;
2934         my ($last_rev, $last_commit) = $self->last_rev_commit;
2935         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2936         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2937 }
2938
2939 sub set_tree_cb {
2940         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2941         $self->{inject_parents} = { $rev => $tree };
2942         $self->fetch(undef, undef);
2943 }
2944
2945 sub set_tree {
2946         my ($self, $tree) = (shift, shift);
2947         my $log_entry = ::get_commit_entry($tree);
2948         unless ($self->{last_rev}) {
2949                 ::fatal("Must have an existing revision to commit");
2950         }
2951         my %ed_opts = ( r => $self->{last_rev},
2952                         log => $log_entry->{log},
2953                         ra => $self->ra,
2954                         tree_a => $self->{last_commit},
2955                         tree_b => $tree,
2956                         editor_cb => sub {
2957                                $self->set_tree_cb($log_entry, $tree, @_) },
2958                         svn_path => $self->{path} );
2959         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2960                 print "No changes\nr$self->{last_rev} = $tree\n";
2961         }
2962 }
2963
2964 sub rebuild_from_rev_db {
2965         my ($self, $path) = @_;
2966         my $r = -1;
2967         open my $fh, '<', $path or croak "open: $!";
2968         binmode $fh or croak "binmode: $!";
2969         while (<$fh>) {
2970                 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2971                 chomp($_);
2972                 ++$r;
2973                 next if $_ eq ('0' x 40);
2974                 $self->rev_map_set($r, $_);
2975                 print "r$r = $_\n";
2976         }
2977         close $fh or croak "close: $!";
2978         unlink $path or croak "unlink: $!";
2979 }
2980
2981 sub rebuild {
2982         my ($self) = @_;
2983         my $map_path = $self->map_path;
2984         my $partial = (-e $map_path && ! -z $map_path);
2985         return unless ::verify_ref($self->refname.'^0');
2986         if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
2987                 my $rev_db = $self->rev_db_path;
2988                 $self->rebuild_from_rev_db($rev_db);
2989                 if ($self->use_svm_props) {
2990                         my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2991                         $self->rebuild_from_rev_db($svm_rev_db);
2992                 }
2993                 $self->unlink_rev_db_symlink;
2994                 return;
2995         }
2996         print "Rebuilding $map_path ...\n" if (!$partial);
2997         my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
2998                 (undef, undef));
2999         my ($log, $ctx) =
3000             command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3001                                 ($head ? "$head.." : "") . $self->refname,
3002                                 '--');
3003         my $metadata_url = $self->metadata_url;
3004         remove_username($metadata_url);
3005         my $svn_uuid = $self->ra_uuid;
3006         my $c;
3007         while (<$log>) {
3008                 if ( m{^commit ($::sha1)$} ) {
3009                         $c = $1;
3010                         next;
3011                 }
3012                 next unless s{^\s*(git-svn-id:)}{$1};
3013                 my ($url, $rev, $uuid) = ::extract_metadata($_);
3014                 remove_username($url);
3015
3016                 # ignore merges (from set-tree)
3017                 next if (!defined $rev || !$uuid);
3018
3019                 # if we merged or otherwise started elsewhere, this is
3020                 # how we break out of it
3021                 if (($uuid ne $svn_uuid) ||
3022                     ($metadata_url && $url && ($url ne $metadata_url))) {
3023                         next;
3024                 }
3025                 if ($partial && $head) {
3026                         print "Partial-rebuilding $map_path ...\n";
3027                         print "Currently at $base_rev = $head\n";
3028                         $head = undef;
3029                 }
3030
3031                 $self->rev_map_set($rev, $c);
3032                 print "r$rev = $c\n";
3033         }
3034         command_close_pipe($log, $ctx);
3035         print "Done rebuilding $map_path\n" if (!$partial || !$head);
3036         my $rev_db_path = $self->rev_db_path;
3037         if (-f $self->rev_db_path) {
3038                 unlink $self->rev_db_path or croak "unlink: $!";
3039         }
3040         $self->unlink_rev_db_symlink;
3041 }
3042
3043 # rev_map:
3044 # Tie::File seems to be prone to offset errors if revisions get sparse,
3045 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
3046 # one of my favorite modules is out :<  Next up would be one of the DBM
3047 # modules, but I'm not sure which is most portable...
3048 #
3049 # This is the replacement for the rev_db format, which was too big
3050 # and inefficient for large repositories with a lot of sparse history
3051 # (mainly tags)
3052 #
3053 # The format is this:
3054 #   - 24 bytes for every record,
3055 #     * 4 bytes for the integer representing an SVN revision number
3056 #     * 20 bytes representing the sha1 of a git commit
3057 #   - No empty padding records like the old format
3058 #     (except the last record, which can be overwritten)
3059 #   - new records are written append-only since SVN revision numbers
3060 #     increase monotonically
3061 #   - lookups on SVN revision number are done via a binary search
3062 #   - Piping the file to xxd -c24 is a good way of dumping it for
3063 #     viewing or editing (piped back through xxd -r), should the need
3064 #     ever arise.
3065 #   - The last record can be padding revision with an all-zero sha1
3066 #     This is used to optimize fetch performance when using multiple
3067 #     "fetch" directives in .git/config
3068 #
3069 # These files are disposable unless noMetadata or useSvmProps is set
3070
3071 sub _rev_map_set {
3072         my ($fh, $rev, $commit) = @_;
3073
3074         binmode $fh or croak "binmode: $!";
3075         my $size = (stat($fh))[7];
3076         ($size % 24) == 0 or croak "inconsistent size: $size";
3077
3078         my $wr_offset = 0;
3079         if ($size > 0) {
3080                 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3081                 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3082                 $read == 24 or croak "read only $read bytes (!= 24)";
3083                 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3084                 if ($last_commit eq ('0' x40)) {
3085                         if ($size >= 48) {
3086                                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3087                                 $read = sysread($fh, $buf, 24) or
3088                                     croak "read: $!";
3089                                 $read == 24 or
3090                                     croak "read only $read bytes (!= 24)";
3091                                 ($last_rev, $last_commit) =
3092                                     unpack(rev_map_fmt, $buf);
3093                                 if ($last_commit eq ('0' x40)) {
3094                                         croak "inconsistent .rev_map\n";
3095                                 }
3096                         }
3097                         if ($last_rev >= $rev) {
3098                                 croak "last_rev is higher!: $last_rev >= $rev";
3099                         }
3100                         $wr_offset = -24;
3101                 }
3102         }
3103         sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3104         syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3105           croak "write: $!";
3106 }
3107
3108 sub _rev_map_reset {
3109         my ($fh, $rev, $commit) = @_;
3110         my $c = _rev_map_get($fh, $rev);
3111         $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3112         my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3113         truncate $fh, $offset or croak "truncate: $!";
3114 }
3115
3116 sub mkfile {
3117         my ($path) = @_;
3118         unless (-e $path) {
3119                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3120                 mkpath([$dir]) unless -d $dir;
3121                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3122                 close $fh or die "Couldn't close (create) $path: $!\n";
3123         }
3124 }
3125
3126 sub rev_map_set {
3127         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3128         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3129         my $db = $self->map_path($uuid);
3130         my $db_lock = "$db.lock";
3131         my $sig;
3132         $update_ref ||= 0;
3133         if ($update_ref) {
3134                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3135                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3136         }
3137         mkfile($db);
3138
3139         $LOCKFILES{$db_lock} = 1;
3140         my $sync;
3141         # both of these options make our .rev_db file very, very important
3142         # and we can't afford to lose it because rebuild() won't work
3143         if ($self->use_svm_props || $self->no_metadata) {
3144                 $sync = 1;
3145                 copy($db, $db_lock) or die "rev_map_set(@_): ",
3146                                            "Failed to copy: ",
3147                                            "$db => $db_lock ($!)\n";
3148         } else {
3149                 rename $db, $db_lock or die "rev_map_set(@_): ",
3150                                             "Failed to rename: ",
3151                                             "$db => $db_lock ($!)\n";
3152         }
3153
3154         sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3155              or croak "Couldn't open $db_lock: $!\n";
3156         $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3157                                  _rev_map_set($fh, $rev, $commit);
3158         if ($sync) {
3159                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3160                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3161         }
3162         close $fh or croak $!;
3163         if ($update_ref) {
3164                 $_head = $self;
3165                 my $note = "";
3166                 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3167                 command_noisy('update-ref', '-m', "r$rev$note",
3168                               $self->refname, $commit);
3169         }
3170         rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3171                                     "$db_lock => $db ($!)\n";
3172         delete $LOCKFILES{$db_lock};
3173         if ($update_ref) {
3174                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3175                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3176                 kill $sig, $$ if defined $sig;
3177         }
3178 }
3179
3180 # If want_commit, this will return an array of (rev, commit) where
3181 # commit _must_ be a valid commit in the archive.
3182 # Otherwise, it'll return the max revision (whether or not the
3183 # commit is valid or just a 0x40 placeholder).
3184 sub rev_map_max {
3185         my ($self, $want_commit) = @_;
3186         $self->rebuild;
3187         my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3188         $want_commit ? ($r, $c) : $r;
3189 }
3190
3191 sub rev_map_max_norebuild {
3192         my ($self, $want_commit) = @_;
3193         my $map_path = $self->map_path;
3194         stat $map_path or return $want_commit ? (0, undef) : 0;
3195         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3196         binmode $fh or croak "binmode: $!";
3197         my $size = (stat($fh))[7];
3198         ($size % 24) == 0 or croak "inconsistent size: $size";
3199
3200         if ($size == 0) {
3201                 close $fh or croak "close: $!";
3202                 return $want_commit ? (0, undef) : 0;
3203         }
3204
3205         sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3206         sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3207         my ($r, $c) = unpack(rev_map_fmt, $buf);
3208         if ($want_commit && $c eq ('0' x40)) {
3209                 if ($size < 48) {
3210                         return $want_commit ? (0, undef) : 0;
3211                 }
3212                 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3213                 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3214                 ($r, $c) = unpack(rev_map_fmt, $buf);
3215                 if ($c eq ('0'x40)) {
3216                         croak "Penultimate record is all-zeroes in $map_path";
3217                 }
3218         }
3219         close $fh or croak "close: $!";
3220         $want_commit ? ($r, $c) : $r;
3221 }
3222
3223 sub rev_map_get {
3224         my ($self, $rev, $uuid) = @_;
3225         my $map_path = $self->map_path($uuid);
3226         return undef unless -e $map_path;
3227
3228         sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3229         my $c = _rev_map_get($fh, $rev);
3230         close($fh) or croak "close: $!";
3231         $c
3232 }
3233
3234 sub _rev_map_get {
3235         my ($fh, $rev) = @_;
3236
3237         binmode $fh or croak "binmode: $!";
3238         my $size = (stat($fh))[7];
3239         ($size % 24) == 0 or croak "inconsistent size: $size";
3240
3241         if ($size == 0) {
3242                 return undef;
3243         }
3244
3245         my ($l, $u) = (0, $size - 24);
3246         my ($r, $c, $buf);
3247
3248         while ($l <= $u) {
3249                 my $i = int(($l/24 + $u/24) / 2) * 24;
3250                 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3251                 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3252                 my ($r, $c) = unpack('NH40', $buf);
3253
3254                 if ($r < $rev) {
3255                         $l = $i + 24;
3256                 } elsif ($r > $rev) {
3257                         $u = $i - 24;
3258                 } else { # $r == $rev
3259                         return $c eq ('0' x 40) ? undef : $c;
3260                 }
3261         }
3262         undef;
3263 }
3264
3265 # Finds the first svn revision that exists on (if $eq_ok is true) or
3266 # before $rev for the current branch.  It will not search any lower
3267 # than $min_rev.  Returns the git commit hash and svn revision number
3268 # if found, else (undef, undef).
3269 sub find_rev_before {
3270         my ($self, $rev, $eq_ok, $min_rev) = @_;
3271         --$rev unless $eq_ok;
3272         $min_rev ||= 1;
3273         my $max_rev = $self->rev_map_max;
3274         $rev = $max_rev if ($rev > $max_rev);
3275         while ($rev >= $min_rev) {
3276                 if (my $c = $self->rev_map_get($rev)) {
3277                         return ($rev, $c);
3278                 }
3279                 --$rev;
3280         }
3281         return (undef, undef);
3282 }
3283
3284 # Finds the first svn revision that exists on (if $eq_ok is true) or
3285 # after $rev for the current branch.  It will not search any higher
3286 # than $max_rev.  Returns the git commit hash and svn revision number
3287 # if found, else (undef, undef).
3288 sub find_rev_after {
3289         my ($self, $rev, $eq_ok, $max_rev) = @_;
3290         ++$rev unless $eq_ok;
3291         $max_rev ||= $self->rev_map_max;
3292         while ($rev <= $max_rev) {
3293                 if (my $c = $self->rev_map_get($rev)) {
3294                         return ($rev, $c);
3295                 }
3296                 ++$rev;
3297         }
3298         return (undef, undef);
3299 }
3300
3301 sub _new {
3302         my ($class, $repo_id, $ref_id, $path) = @_;
3303         unless (defined $repo_id && length $repo_id) {
3304                 $repo_id = $Git::SVN::default_repo_id;
3305         }
3306         unless (defined $ref_id && length $ref_id) {
3307                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
3308         }
3309         $_[1] = $repo_id;
3310         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3311         $_[3] = $path = '' unless (defined $path);
3312         mkpath(["$ENV{GIT_DIR}/svn"]);
3313         bless {
3314                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3315                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3316                 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3317 }
3318
3319 # for read-only access of old .rev_db formats
3320 sub unlink_rev_db_symlink {
3321         my ($self) = @_;
3322         my $link = $self->rev_db_path;
3323         $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3324         if (-l $link) {
3325                 unlink $link or croak "unlink: $link failed!";
3326         }
3327 }
3328
3329 sub rev_db_path {
3330         my ($self, $uuid) = @_;
3331         my $db_path = $self->map_path($uuid);
3332         $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3333             or croak "map_path: $db_path does not contain '/.rev_map.' !";
3334         $db_path;
3335 }
3336
3337 # the new replacement for .rev_db
3338 sub map_path {
3339         my ($self, $uuid) = @_;
3340         $uuid ||= $self->ra_uuid;
3341         "$self->{map_root}.$uuid";
3342 }
3343
3344 sub uri_encode {
3345         my ($f) = @_;
3346         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3347         $f
3348 }
3349
3350 sub remove_username {
3351         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3352 }
3353
3354 package Git::SVN::Prompt;
3355 use strict;
3356 use warnings;
3357 require SVN::Core;
3358 use vars qw/$_no_auth_cache $_username/;
3359
3360 sub simple {
3361         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3362         $may_save = undef if $_no_auth_cache;
3363         $default_username = $_username if defined $_username;
3364         if (defined $default_username && length $default_username) {
3365                 if (defined $realm && length $realm) {
3366                         print STDERR "Authentication realm: $realm\n";
3367                         STDERR->flush;
3368                 }
3369                 $cred->username($default_username);
3370         } else {
3371                 username($cred, $realm, $may_save, $pool);
3372         }
3373         $cred->password(_read_password("Password for '" .
3374                                        $cred->username . "': ", $realm));
3375         $cred->may_save($may_save);
3376         $SVN::_Core::SVN_NO_ERROR;
3377 }
3378
3379 sub ssl_server_trust {
3380         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3381         $may_save = undef if $_no_auth_cache;
3382         print STDERR "Error validating server certificate for '$realm':\n";
3383         {
3384                 no warnings 'once';
3385                 # All variables SVN::Auth::SSL::* are used only once,
3386                 # so we're shutting up Perl warnings about this.
3387                 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3388                         print STDERR " - The certificate is not issued ",
3389                             "by a trusted authority. Use the\n",
3390                             "   fingerprint to validate ",
3391                             "the certificate manually!\n";
3392                 }
3393                 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3394                         print STDERR " - The certificate hostname ",
3395                             "does not match.\n";
3396                 }
3397                 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3398                         print STDERR " - The certificate is not yet valid.\n";
3399                 }
3400                 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3401                         print STDERR " - The certificate has expired.\n";
3402                 }
3403                 if ($failures & $SVN::Auth::SSL::OTHER) {
3404                         print STDERR " - The certificate has ",
3405                             "an unknown error.\n";
3406                 }
3407         } # no warnings 'once'
3408         printf STDERR
3409                 "Certificate information:\n".
3410                 " - Hostname: %s\n".
3411                 " - Valid: from %s until %s\n".
3412                 " - Issuer: %s\n".
3413                 " - Fingerprint: %s\n",
3414                 map $cert_info->$_, qw(hostname valid_from valid_until
3415                                        issuer_dname fingerprint);
3416         my $choice;
3417 prompt:
3418         print STDERR $may_save ?
3419               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3420               "(R)eject or accept (t)emporarily? ";
3421         STDERR->flush;
3422         $choice = lc(substr(<STDIN> || 'R', 0, 1));
3423         if ($choice =~ /^t$/i) {
3424                 $cred->may_save(undef);
3425         } elsif ($choice =~ /^r$/i) {
3426                 return -1;
3427         } elsif ($may_save && $choice =~ /^p$/i) {
3428                 $cred->may_save($may_save);
3429         } else {
3430                 goto prompt;
3431         }
3432         $cred->accepted_failures($failures);
3433         $SVN::_Core::SVN_NO_ERROR;
3434 }
3435
3436 sub ssl_client_cert {
3437         my ($cred, $realm, $may_save, $pool) = @_;
3438         $may_save = undef if $_no_auth_cache;
3439         print STDERR "Client certificate filename: ";
3440         STDERR->flush;
3441         chomp(my $filename = <STDIN>);
3442         $cred->cert_file($filename);
3443         $cred->may_save($may_save);
3444         $SVN::_Core::SVN_NO_ERROR;
3445 }
3446
3447 sub ssl_client_cert_pw {
3448         my ($cred, $realm, $may_save, $pool) = @_;
3449         $may_save = undef if $_no_auth_cache;
3450         $cred->password(_read_password("Password: ", $realm));
3451         $cred->may_save($may_save);
3452         $SVN::_Core::SVN_NO_ERROR;
3453 }
3454
3455 sub username {
3456         my ($cred, $realm, $may_save, $pool) = @_;
3457         $may_save = undef if $_no_auth_cache;
3458         if (defined $realm && length $realm) {
3459                 print STDERR "Authentication realm: $realm\n";
3460         }
3461         my $username;
3462         if (defined $_username) {
3463                 $username = $_username;
3464         } else {
3465                 print STDERR "Username: ";
3466                 STDERR->flush;
3467                 chomp($username = <STDIN>);
3468         }
3469         $cred->username($username);
3470         $cred->may_save($may_save);
3471         $SVN::_Core::SVN_NO_ERROR;
3472 }
3473
3474 sub _read_password {
3475         my ($prompt, $realm) = @_;
3476         print STDERR $prompt;
3477         STDERR->flush;
3478         require Term::ReadKey;
3479         Term::ReadKey::ReadMode('noecho');
3480         my $password = '';
3481         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3482                 last if $key =~ /[\012\015]/; # \n\r
3483                 $password .= $key;
3484         }
3485         Term::ReadKey::ReadMode('restore');
3486         print STDERR "\n";
3487         STDERR->flush;
3488         $password;
3489 }
3490
3491 package SVN::Git::Fetcher;
3492 use vars qw/@ISA/;
3493 use strict;
3494 use warnings;
3495 use Carp qw/croak/;
3496 use File::Temp qw/tempfile/;
3497 use IO::File qw//;
3498 use vars qw/$_ignore_regex/;
3499
3500 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3501 sub new {
3502         my ($class, $git_svn, $switch_path) = @_;
3503         my $self = SVN::Delta::Editor->new;
3504         bless $self, $class;
3505         if (exists $git_svn->{last_commit}) {
3506                 $self->{c} = $git_svn->{last_commit};
3507                 $self->{empty_symlinks} =
3508                                   _mark_empty_symlinks($git_svn, $switch_path);
3509         }
3510         $self->{ignore_regex} = eval { command_oneline('config', '--get',
3511                              "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3512         $self->{empty} = {};
3513         $self->{dir_prop} = {};
3514         $self->{file_prop} = {};
3515         $self->{absent_dir} = {};
3516         $self->{absent_file} = {};
3517         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3518         $self;
3519 }
3520
3521 # this uses the Ra object, so it must be called before do_{switch,update},
3522 # not inside them (when the Git::SVN::Fetcher object is passed) to
3523 # do_{switch,update}
3524 sub _mark_empty_symlinks {
3525         my ($git_svn, $switch_path) = @_;
3526         my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3527         return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3528
3529         my %ret;
3530         my ($rev, $cmt) = $git_svn->last_rev_commit;
3531         return {} unless ($rev && $cmt);
3532
3533         # allow the warning to be printed for each revision we fetch to
3534         # ensure the user sees it.  The user can also disable the workaround
3535         # on the repository even while git svn is running and the next
3536         # revision fetched will skip this expensive function.
3537         my $printed_warning;
3538         chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3539         my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3540         local $/ = "\0";
3541         my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3542         $pfx .= '/' if length($pfx);
3543         while (<$ls>) {
3544                 chomp;
3545                 s/\A100644 blob $empty_blob\t//o or next;
3546                 unless ($printed_warning) {
3547                         print STDERR "Scanning for empty symlinks, ",
3548                                      "this may take a while if you have ",
3549                                      "many empty files\n",
3550                                      "You may disable this with `",
3551                                      "git config svn.brokenSymlinkWorkaround ",
3552                                      "false'.\n",
3553                                      "This may be done in a different ",
3554                                      "terminal without restarting ",
3555                                      "git svn\n";
3556                         $printed_warning = 1;
3557                 }
3558                 my $path = $_;
3559                 my (undef, $props) =
3560                                $git_svn->ra->get_file($pfx.$path, $rev, undef);
3561                 if ($props->{'svn:special'}) {
3562                         $ret{$path} = 1;
3563                 }
3564         }
3565         command_close_pipe($ls, $ctx);
3566         \%ret;
3567 }
3568
3569 # returns true if a given path is inside a ".git" directory
3570 sub in_dot_git {
3571         $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3572 }
3573
3574 # return value: 0 -- don't ignore, 1 -- ignore
3575 sub is_path_ignored {
3576         my ($self, $path) = @_;
3577         return 1 if in_dot_git($path);
3578         return 1 if defined($self->{ignore_regex}) &&
3579                     $path =~ m!$self->{ignore_regex}!;
3580         return 0 unless defined($_ignore_regex);
3581         return 1 if $path =~ m!$_ignore_regex!o;
3582         return 0;
3583 }
3584
3585 sub set_path_strip {
3586         my ($self, $path) = @_;
3587         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3588 }
3589
3590 sub open_root {
3591         { path => '' };
3592 }
3593
3594 sub open_directory {
3595         my ($self, $path, $pb, $rev) = @_;
3596         { path => $path };
3597 }
3598
3599 sub git_path {
3600         my ($self, $path) = @_;
3601         if ($self->{path_strip}) {
3602                 $path =~ s!$self->{path_strip}!! or
3603                   die "Failed to strip path '$path' ($self->{path_strip})\n";
3604         }
3605         $path;
3606 }
3607
3608 sub delete_entry {
3609         my ($self, $path, $rev, $pb) = @_;
3610         return undef if $self->is_path_ignored($path);
3611
3612         my $gpath = $self->git_path($path);
3613         return undef if ($gpath eq '');
3614
3615         # remove entire directories.
3616         my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3617                          =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3618         if ($tree) {
3619                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3620                                                      -r --name-only -z/,
3621                                                      $tree);
3622                 local $/ = "\0";
3623                 while (<$ls>) {
3624                         chomp;
3625                         my $rmpath = "$gpath/$_";
3626                         $self->{gii}->remove($rmpath);
3627                         print "\tD\t$rmpath\n" unless $::_q;
3628                 }
3629                 print "\tD\t$gpath/\n" unless $::_q;
3630                 command_close_pipe($ls, $ctx);
3631                 $self->{empty}->{$path} = 0
3632         } else {
3633                 $self->{gii}->remove($gpath);
3634                 print "\tD\t$gpath\n" unless $::_q;
3635         }
3636         undef;
3637 }
3638
3639 sub open_file {
3640         my ($self, $path, $pb, $rev) = @_;
3641         my ($mode, $blob);
3642
3643         goto out if $self->is_path_ignored($path);
3644
3645         my $gpath = $self->git_path($path);
3646         ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3647                              =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3648         unless (defined $mode && defined $blob) {
3649                 die "$path was not found in commit $self->{c} (r$rev)\n";
3650         }
3651         if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3652                 $mode = '120000';
3653         }
3654 out:
3655         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3656           pool => SVN::Pool->new, action => 'M' };
3657 }
3658
3659 sub add_file {
3660         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3661         my $mode;
3662
3663         if (!$self->is_path_ignored($path)) {
3664                 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3665                 delete $self->{empty}->{$dir};
3666                 $mode = '100644';
3667         }
3668         { path => $path, mode_a => $mode, mode_b => $mode,
3669           pool => SVN::Pool->new, action => 'A' };
3670 }
3671
3672 sub add_directory {
3673         my ($self, $path, $cp_path, $cp_rev) = @_;
3674         goto out if $self->is_path_ignored($path);
3675         my $gpath = $self->git_path($path);
3676         if ($gpath eq '') {
3677                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3678                                                      -r --name-only -z/,
3679                                                      $self->{c});
3680                 local $/ = "\0";
3681                 while (<$ls>) {
3682                         chomp;
3683                         $self->{gii}->remove($_);
3684                         print "\tD\t$_\n" unless $::_q;
3685                 }
3686                 command_close_pipe($ls, $ctx);
3687                 $self->{empty}->{$path} = 0;
3688         }
3689         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3690         delete $self->{empty}->{$dir};
3691         $self->{empty}->{$path} = 1;
3692 out:
3693         { path => $path };
3694 }
3695
3696 sub change_dir_prop {
3697         my ($self, $db, $prop, $value) = @_;
3698         return undef if $self->is_path_ignored($db->{path});
3699         $self->{dir_prop}->{$db->{path}} ||= {};
3700         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3701         undef;
3702 }
3703
3704 sub absent_directory {
3705         my ($self, $path, $pb) = @_;
3706         return undef if $self->is_path_ignored($path);
3707         $self->{absent_dir}->{$pb->{path}} ||= [];
3708         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3709         undef;
3710 }
3711
3712 sub absent_file {
3713         my ($self, $path, $pb) = @_;
3714         return undef if $self->is_path_ignored($path);
3715         $self->{absent_file}->{$pb->{path}} ||= [];
3716         push @{$self->{absent_file}->{$pb->{path}}}, $path;
3717         undef;
3718 }
3719
3720 sub change_file_prop {
3721         my ($self, $fb, $prop, $value) = @_;
3722         return undef if $self->is_path_ignored($fb->{path});
3723         if ($prop eq 'svn:executable') {
3724                 if ($fb->{mode_b} != 120000) {
3725                         $fb->{mode_b} = defined $value ? 100755 : 100644;
3726                 }
3727         } elsif ($prop eq 'svn:special') {
3728                 $fb->{mode_b} = defined $value ? 120000 : 100644;
3729         } else {
3730                 $self->{file_prop}->{$fb->{path}} ||= {};
3731                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3732         }
3733         undef;
3734 }
3735
3736 sub apply_textdelta {
3737         my ($self, $fb, $exp) = @_;
3738         return undef if $self->is_path_ignored($fb->{path});
3739         my $fh = $::_repository->temp_acquire('svn_delta');
3740         # $fh gets auto-closed() by SVN::TxDelta::apply(),
3741         # (but $base does not,) so dup() it for reading in close_file
3742         open my $dup, '<&', $fh or croak $!;
3743         my $base = $::_repository->temp_acquire('git_blob');
3744
3745         if ($fb->{blob}) {
3746                 my ($base_is_link, $size);
3747
3748                 if ($fb->{mode_a} eq '120000' &&
3749                     ! $self->{empty_symlinks}->{$fb->{path}}) {
3750                         print $base 'link ' or die "print $!\n";
3751                         $base_is_link = 1;
3752                 }
3753         retry:
3754                 $size = $::_repository->cat_blob($fb->{blob}, $base);
3755                 die "Failed to read object $fb->{blob}" if ($size < 0);
3756
3757                 if (defined $exp) {
3758                         seek $base, 0, 0 or croak $!;
3759                         my $got = ::md5sum($base);
3760                         if ($got ne $exp) {
3761                                 my $err = "Checksum mismatch: ".
3762                                        "$fb->{path} $fb->{blob}\n" .
3763                                        "expected: $exp\n" .
3764                                        "     got: $got\n";
3765                                 if ($base_is_link) {
3766                                         warn $err,
3767                                              "Retrying... (possibly ",
3768                                              "a bad symlink from SVN)\n";
3769                                         $::_repository->temp_reset($base);
3770                                         $base_is_link = 0;
3771                                         goto retry;
3772                                 }
3773                                 die $err;
3774                         }
3775                 }
3776         }
3777         seek $base, 0, 0 or croak $!;
3778         $fb->{fh} = $fh;
3779         $fb->{base} = $base;
3780         [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3781 }
3782
3783 sub close_file {
3784         my ($self, $fb, $exp) = @_;
3785         return undef if $self->is_path_ignored($fb->{path});
3786
3787         my $hash;
3788         my $path = $self->git_path($fb->{path});
3789         if (my $fh = $fb->{fh}) {
3790                 if (defined $exp) {
3791                         seek($fh, 0, 0) or croak $!;
3792                         my $got = ::md5sum($fh);
3793                         if ($got ne $exp) {
3794                                 die "Checksum mismatch: $path\n",
3795                                     "expected: $exp\n    got: $got\n";
3796                         }
3797                 }
3798                 if ($fb->{mode_b} == 120000) {
3799                         sysseek($fh, 0, 0) or croak $!;
3800                         my $rd = sysread($fh, my $buf, 5);
3801
3802                         if (!defined $rd) {
3803                                 croak "sysread: $!\n";
3804                         } elsif ($rd == 0) {
3805                                 warn "$path has mode 120000",
3806                                      " but it points to nothing\n",
3807                                      "converting to an empty file with mode",
3808                                      " 100644\n";
3809                                 $fb->{mode_b} = '100644';
3810                         } elsif ($buf ne 'link ') {
3811                                 warn "$path has mode 120000",
3812                                      " but is not a link\n";
3813                         } else {
3814                                 my $tmp_fh = $::_repository->temp_acquire(
3815                                         'svn_hash');
3816                                 my $res;
3817                                 while ($res = sysread($fh, my $str, 1024)) {
3818                                         my $out = syswrite($tmp_fh, $str, $res);
3819                                         defined($out) && $out == $res
3820                                                 or croak("write ",
3821                                                         Git::temp_path($tmp_fh),
3822                                                         ": $!\n");
3823                                 }
3824                                 defined $res or croak $!;
3825
3826                                 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3827                                 Git::temp_release($tmp_fh, 1);
3828                         }
3829                 }
3830
3831                 $hash = $::_repository->hash_and_insert_object(
3832                                 Git::temp_path($fh));
3833                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3834
3835                 Git::temp_release($fb->{base}, 1);
3836                 Git::temp_release($fh, 1);
3837         } else {
3838                 $hash = $fb->{blob} or die "no blob information\n";
3839         }
3840         $fb->{pool}->clear;
3841         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3842         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3843         undef;
3844 }
3845
3846 sub abort_edit {
3847         my $self = shift;
3848         $self->{nr} = $self->{gii}->{nr};
3849         delete $self->{gii};
3850         $self->SUPER::abort_edit(@_);
3851 }
3852
3853 sub close_edit {
3854         my $self = shift;
3855         $self->{git_commit_ok} = 1;
3856         $self->{nr} = $self->{gii}->{nr};
3857         delete $self->{gii};
3858         $self->SUPER::close_edit(@_);
3859 }
3860
3861 package SVN::Git::Editor;
3862 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3863 use strict;
3864 use warnings;
3865 use Carp qw/croak/;
3866 use IO::File;
3867
3868 sub new {
3869         my ($class, $opts) = @_;
3870         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3871                 die "$_ required!\n" unless (defined $opts->{$_});
3872         }
3873
3874         my $pool = SVN::Pool->new;
3875         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3876         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3877                                      $opts->{r}, $mods);
3878
3879         # $opts->{ra} functions should not be used after this:
3880         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
3881                                                 $opts->{editor_cb}, $pool);
3882         my $self = SVN::Delta::Editor->new(@ce, $pool);
3883         bless $self, $class;
3884         foreach (qw/svn_path r tree_a tree_b/) {
3885                 $self->{$_} = $opts->{$_};
3886         }
3887         $self->{url} = $opts->{ra}->{url};
3888         $self->{mods} = $mods;
3889         $self->{types} = $types;
3890         $self->{pool} = $pool;
3891         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3892         $self->{rm} = { };
3893         $self->{path_prefix} = length $self->{svn_path} ?
3894                                "$self->{svn_path}/" : '';
3895         $self->{config} = $opts->{config};
3896         return $self;
3897 }
3898
3899 sub generate_diff {
3900         my ($tree_a, $tree_b) = @_;
3901         my @diff_tree = qw(diff-tree -z -r);
3902         if ($_cp_similarity) {
3903                 push @diff_tree, "-C$_cp_similarity";
3904         } else {
3905                 push @diff_tree, '-C';
3906         }
3907         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3908         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3909         push @diff_tree, $tree_a, $tree_b;
3910         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3911         local $/ = "\0";
3912         my $state = 'meta';
3913         my @mods;
3914         while (<$diff_fh>) {
3915                 chomp $_; # this gets rid of the trailing "\0"
3916                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3917                                         ($::sha1)\s($::sha1)\s
3918                                         ([MTCRAD])\d*$/xo) {
3919                         push @mods, {   mode_a => $1, mode_b => $2,
3920                                         sha1_a => $3, sha1_b => $4,
3921                                         chg => $5 };
3922                         if ($5 =~ /^(?:C|R)$/) {
3923                                 $state = 'file_a';
3924                         } else {
3925                                 $state = 'file_b';
3926                         }
3927                 } elsif ($state eq 'file_a') {
3928                         my $x = $mods[$#mods] or croak "Empty array\n";
3929                         if ($x->{chg} !~ /^(?:C|R)$/) {
3930                                 croak "Error parsing $_, $x->{chg}\n";
3931                         }
3932                         $x->{file_a} = $_;
3933                         $state = 'file_b';
3934                 } elsif ($state eq 'file_b') {
3935                         my $x = $mods[$#mods] or croak "Empty array\n";
3936                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3937                                 croak "Error parsing $_, $x->{chg}\n";
3938                         }
3939                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3940                                 croak "Error parsing $_, $x->{chg}\n";
3941                         }
3942                         $x->{file_b} = $_;
3943                         $state = 'meta';
3944                 } else {
3945                         croak "Error parsing $_\n";
3946                 }
3947         }
3948         command_close_pipe($diff_fh, $ctx);
3949         \@mods;
3950 }
3951
3952 sub check_diff_paths {
3953         my ($ra, $pfx, $rev, $mods) = @_;
3954         my %types;
3955         $pfx .= '/' if length $pfx;
3956
3957         sub type_diff_paths {
3958                 my ($ra, $types, $path, $rev) = @_;
3959                 my @p = split m#/+#, $path;
3960                 my $c = shift @p;
3961                 unless (defined $types->{$c}) {
3962                         $types->{$c} = $ra->check_path($c, $rev);
3963                 }
3964                 while (@p) {
3965                         $c .= '/' . shift @p;
3966                         next if defined $types->{$c};
3967                         $types->{$c} = $ra->check_path($c, $rev);
3968                 }
3969         }
3970
3971         foreach my $m (@$mods) {
3972                 foreach my $f (qw/file_a file_b/) {
3973                         next unless defined $m->{$f};
3974                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3975                         if (length $pfx.$dir && ! defined $types{$dir}) {
3976                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3977                         }
3978                 }
3979         }
3980         \%types;
3981 }
3982
3983 sub split_path {
3984         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3985 }
3986
3987 sub repo_path {
3988         my ($self, $path) = @_;
3989         $self->{path_prefix}.(defined $path ? $path : '');
3990 }
3991
3992 sub url_path {
3993         my ($self, $path) = @_;
3994         if ($self->{url} =~ m#^https?://#) {
3995                 $path =~ s/([^~a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3996         }
3997         $self->{url} . '/' . $self->repo_path($path);
3998 }
3999
4000 sub rmdirs {
4001         my ($self) = @_;
4002         my $rm = $self->{rm};
4003         delete $rm->{''}; # we never delete the url we're tracking
4004         return unless %$rm;
4005
4006         foreach (keys %$rm) {
4007                 my @d = split m#/#, $_;
4008                 my $c = shift @d;
4009                 $rm->{$c} = 1;
4010                 while (@d) {
4011                         $c .= '/' . shift @d;
4012                         $rm->{$c} = 1;
4013                 }
4014         }
4015         delete $rm->{$self->{svn_path}};
4016         delete $rm->{''}; # we never delete the url we're tracking
4017         return unless %$rm;
4018
4019         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4020                                              $self->{tree_b});
4021         local $/ = "\0";
4022         while (<$fh>) {
4023                 chomp;
4024                 my @dn = split m#/#, $_;
4025                 while (pop @dn) {
4026                         delete $rm->{join '/', @dn};
4027                 }
4028                 unless (%$rm) {
4029                         close $fh;
4030                         return;
4031                 }
4032         }
4033         command_close_pipe($fh, $ctx);
4034
4035         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4036         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4037                 $self->close_directory($bat->{$d}, $p);
4038                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4039                 print "\tD+\t$d/\n" unless $::_q;
4040                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4041                 delete $bat->{$d};
4042         }
4043 }
4044
4045 sub open_or_add_dir {
4046         my ($self, $full_path, $baton) = @_;
4047         my $t = $self->{types}->{$full_path};
4048         if (!defined $t) {
4049                 die "$full_path not known in r$self->{r} or we have a bug!\n";
4050         }
4051         {
4052                 no warnings 'once';
4053                 # SVN::Node::none and SVN::Node::file are used only once,
4054                 # so we're shutting up Perl's warnings about them.
4055                 if ($t == $SVN::Node::none) {
4056                         return $self->add_directory($full_path, $baton,
4057                             undef, -1, $self->{pool});
4058                 } elsif ($t == $SVN::Node::dir) {
4059                         return $self->open_directory($full_path, $baton,
4060                             $self->{r}, $self->{pool});
4061                 } # no warnings 'once'
4062                 print STDERR "$full_path already exists in repository at ",
4063                     "r$self->{r} and it is not a directory (",
4064                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4065         } # no warnings 'once'
4066         exit 1;
4067 }
4068
4069 sub ensure_path {
4070         my ($self, $path) = @_;
4071         my $bat = $self->{bat};
4072         my $repo_path = $self->repo_path($path);
4073         return $bat->{''} unless (length $repo_path);
4074         my @p = split m#/+#, $repo_path;
4075         my $c = shift @p;
4076         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4077         while (@p) {
4078                 my $c0 = $c;
4079                 $c .= '/' . shift @p;
4080                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4081         }
4082         return $bat->{$c};
4083 }
4084
4085 # Subroutine to convert a globbing pattern to a regular expression.
4086 # From perl cookbook.
4087 sub glob2pat {
4088         my $globstr = shift;
4089         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4090         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4091         return '^' . $globstr . '$';
4092 }
4093
4094 sub check_autoprop {
4095         my ($self, $pattern, $properties, $file, $fbat) = @_;
4096         # Convert the globbing pattern to a regular expression.
4097         my $regex = glob2pat($pattern);
4098         # Check if the pattern matches the file name.
4099         if($file =~ m/($regex)/) {
4100                 # Parse the list of properties to set.
4101                 my @props = split(/;/, $properties);
4102                 foreach my $prop (@props) {
4103                         # Parse 'name=value' syntax and set the property.
4104                         if ($prop =~ /([^=]+)=(.*)/) {
4105                                 my ($n,$v) = ($1,$2);
4106                                 for ($n, $v) {
4107                                         s/^\s+//; s/\s+$//;
4108                                 }
4109                                 $self->change_file_prop($fbat, $n, $v);
4110                         }
4111                 }
4112         }
4113 }
4114
4115 sub apply_autoprops {
4116         my ($self, $file, $fbat) = @_;
4117         my $conf_t = ${$self->{config}}{'config'};
4118         no warnings 'once';
4119         # Check [miscellany]/enable-auto-props in svn configuration.
4120         if (SVN::_Core::svn_config_get_bool(
4121                 $conf_t,
4122                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4123                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4124                 0)) {
4125                 # Auto-props are enabled.  Enumerate them to look for matches.
4126                 my $callback = sub {
4127                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
4128                 };
4129                 SVN::_Core::svn_config_enumerate(
4130                         $conf_t,
4131                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4132                         $callback);
4133         }
4134 }
4135
4136 sub A {
4137         my ($self, $m) = @_;
4138         my ($dir, $file) = split_path($m->{file_b});
4139         my $pbat = $self->ensure_path($dir);
4140         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4141                                         undef, -1);
4142         print "\tA\t$m->{file_b}\n" unless $::_q;
4143         $self->apply_autoprops($file, $fbat);
4144         $self->chg_file($fbat, $m);
4145         $self->close_file($fbat,undef,$self->{pool});
4146 }
4147
4148 sub C {
4149         my ($self, $m) = @_;
4150         my ($dir, $file) = split_path($m->{file_b});
4151         my $pbat = $self->ensure_path($dir);
4152         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4153                                 $self->url_path($m->{file_a}), $self->{r});
4154         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4155         $self->chg_file($fbat, $m);
4156         $self->close_file($fbat,undef,$self->{pool});
4157 }
4158
4159 sub delete_entry {
4160         my ($self, $path, $pbat) = @_;
4161         my $rpath = $self->repo_path($path);
4162         my ($dir, $file) = split_path($rpath);
4163         $self->{rm}->{$dir} = 1;
4164         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4165 }
4166
4167 sub R {
4168         my ($self, $m) = @_;
4169         my ($dir, $file) = split_path($m->{file_b});
4170         my $pbat = $self->ensure_path($dir);
4171         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4172                                 $self->url_path($m->{file_a}), $self->{r});
4173         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4174         $self->apply_autoprops($file, $fbat);
4175         $self->chg_file($fbat, $m);
4176         $self->close_file($fbat,undef,$self->{pool});
4177
4178         ($dir, $file) = split_path($m->{file_a});
4179         $pbat = $self->ensure_path($dir);
4180         $self->delete_entry($m->{file_a}, $pbat);
4181 }
4182
4183 sub M {
4184         my ($self, $m) = @_;
4185         my ($dir, $file) = split_path($m->{file_b});
4186         my $pbat = $self->ensure_path($dir);
4187         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4188                                 $pbat,$self->{r},$self->{pool});
4189         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4190         $self->chg_file($fbat, $m);
4191         $self->close_file($fbat,undef,$self->{pool});
4192 }
4193
4194 sub T { shift->M(@_) }
4195
4196 sub change_file_prop {
4197         my ($self, $fbat, $pname, $pval) = @_;
4198         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4199 }
4200
4201 sub _chg_file_get_blob ($$$$) {
4202         my ($self, $fbat, $m, $which) = @_;
4203         my $fh = $::_repository->temp_acquire("git_blob_$which");
4204         if ($m->{"mode_$which"} =~ /^120/) {
4205                 print $fh 'link ' or croak $!;
4206                 $self->change_file_prop($fbat,'svn:special','*');
4207         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4208                 $self->change_file_prop($fbat,'svn:special',undef);
4209         }
4210         my $blob = $m->{"sha1_$which"};
4211         return ($fh,) if ($blob =~ /^0{40}$/);
4212         my $size = $::_repository->cat_blob($blob, $fh);
4213         croak "Failed to read object $blob" if ($size < 0);
4214         $fh->flush == 0 or croak $!;
4215         seek $fh, 0, 0 or croak $!;
4216
4217         my $exp = ::md5sum($fh);
4218         seek $fh, 0, 0 or croak $!;
4219         return ($fh, $exp);
4220 }
4221
4222 sub chg_file {
4223         my ($self, $fbat, $m) = @_;
4224         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4225                 $self->change_file_prop($fbat,'svn:executable','*');
4226         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4227                 $self->change_file_prop($fbat,'svn:executable',undef);
4228         }
4229         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4230         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4231         my $pool = SVN::Pool->new;
4232         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4233         if (-s $fh_a) {
4234                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4235                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4236                 if (defined $res) {
4237                         die "Unexpected result from send_txstream: $res\n",
4238                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4239                 }
4240         } else {
4241                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4242                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4243                     if ($got ne $exp_b);
4244         }
4245         Git::temp_release($fh_b, 1);
4246         Git::temp_release($fh_a, 1);
4247         $pool->clear;
4248 }
4249
4250 sub D {
4251         my ($self, $m) = @_;
4252         my ($dir, $file) = split_path($m->{file_b});
4253         my $pbat = $self->ensure_path($dir);
4254         print "\tD\t$m->{file_b}\n" unless $::_q;
4255         $self->delete_entry($m->{file_b}, $pbat);
4256 }
4257
4258 sub close_edit {
4259         my ($self) = @_;
4260         my ($p,$bat) = ($self->{pool}, $self->{bat});
4261         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4262                 next if $_ eq '';
4263                 $self->close_directory($bat->{$_}, $p);
4264         }
4265         $self->close_directory($bat->{''}, $p);
4266         $self->SUPER::close_edit($p);
4267         $p->clear;
4268 }
4269
4270 sub abort_edit {
4271         my ($self) = @_;
4272         $self->SUPER::abort_edit($self->{pool});
4273 }
4274
4275 sub DESTROY {
4276         my $self = shift;
4277         $self->SUPER::DESTROY(@_);
4278         $self->{pool}->clear;
4279 }
4280
4281 # this drives the editor
4282 sub apply_diff {
4283         my ($self) = @_;
4284         my $mods = $self->{mods};
4285         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4286         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4287                 my $f = $m->{chg};
4288                 if (defined $o{$f}) {
4289                         $self->$f($m);
4290                 } else {
4291                         fatal("Invalid change type: $f");
4292                 }
4293         }
4294         $self->rmdirs if $_rmdir;
4295         if (@$mods == 0) {
4296                 $self->abort_edit;
4297         } else {
4298                 $self->close_edit;
4299         }
4300         return scalar @$mods;
4301 }
4302
4303 package Git::SVN::Ra;
4304 use vars qw/@ISA $config_dir $_log_window_size/;
4305 use strict;
4306 use warnings;
4307 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4308
4309 BEGIN {
4310         # enforce temporary pool usage for some simple functions
4311         no strict 'refs';
4312         for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4313                       get_file/) {
4314                 my $SUPER = "SUPER::$f";
4315                 *$f = sub {
4316                         my $self = shift;
4317                         my $pool = SVN::Pool->new;
4318                         my @ret = $self->$SUPER(@_,$pool);
4319                         $pool->clear;
4320                         wantarray ? @ret : $ret[0];
4321                 };
4322         }
4323 }
4324
4325 sub _auth_providers () {
4326         [
4327           SVN::Client::get_simple_provider(),
4328           SVN::Client::get_ssl_server_trust_file_provider(),
4329           SVN::Client::get_simple_prompt_provider(
4330             \&Git::SVN::Prompt::simple, 2),
4331           SVN::Client::get_ssl_client_cert_file_provider(),
4332           SVN::Client::get_ssl_client_cert_prompt_provider(
4333             \&Git::SVN::Prompt::ssl_client_cert, 2),
4334           SVN::Client::get_ssl_client_cert_pw_file_provider(),
4335           SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4336             \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4337           SVN::Client::get_username_provider(),
4338           SVN::Client::get_ssl_server_trust_prompt_provider(
4339             \&Git::SVN::Prompt::ssl_server_trust),
4340           SVN::Client::get_username_prompt_provider(
4341             \&Git::SVN::Prompt::username, 2)
4342         ]
4343 }
4344
4345 sub escape_uri_only {
4346         my ($uri) = @_;
4347         my @tmp;
4348         foreach (split m{/}, $uri) {
4349                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4350                 push @tmp, $_;
4351         }
4352         join('/', @tmp);
4353 }
4354
4355 sub escape_url {
4356         my ($url) = @_;
4357         if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4358                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4359                 $url = "$scheme://$domain$uri";
4360         }
4361         $url;
4362 }
4363
4364 sub new {
4365         my ($class, $url) = @_;
4366         $url =~ s!/+$!!;
4367         return $RA if ($RA && $RA->{url} eq $url);
4368
4369         SVN::_Core::svn_config_ensure($config_dir, undef);
4370         my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4371         my $config = SVN::Core::config_get_config($config_dir);
4372         $RA = undef;
4373         my $dont_store_passwords = 1;
4374         my $conf_t = ${$config}{'config'};
4375         {
4376                 no warnings 'once';
4377                 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4378                 # produces warnings that variables are used only once.
4379                 # I had not found the better way to shut them up, so
4380                 # the warnings of type 'once' are disabled in this block.
4381                 if (SVN::_Core::svn_config_get_bool($conf_t,
4382                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4383                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4384                     1) == 0) {
4385                         SVN::_Core::svn_auth_set_parameter($baton,
4386                             $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4387                             bless (\$dont_store_passwords, "_p_void"));
4388                 }
4389                 if (SVN::_Core::svn_config_get_bool($conf_t,
4390                     $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4391                     $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4392                     1) == 0) {
4393                         $Git::SVN::Prompt::_no_auth_cache = 1;
4394                 }
4395         } # no warnings 'once'
4396         my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4397                               config => $config,
4398                               pool => SVN::Pool->new,
4399                               auth_provider_callbacks => $callbacks);
4400         $self->{url} = $url;
4401         $self->{svn_path} = $url;
4402         $self->{repos_root} = $self->get_repos_root;
4403         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4404         $self->{cache} = { check_path => { r => 0, data => {} },
4405                            get_dir => { r => 0, data => {} } };
4406         $RA = bless $self, $class;
4407 }
4408
4409 sub check_path {
4410         my ($self, $path, $r) = @_;
4411         my $cache = $self->{cache}->{check_path};
4412         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4413                 return $cache->{data}->{$path};
4414         }
4415         my $pool = SVN::Pool->new;
4416         my $t = $self->SUPER::check_path($path, $r, $pool);
4417         $pool->clear;
4418         if ($r != $cache->{r}) {
4419                 %{$cache->{data}} = ();
4420                 $cache->{r} = $r;
4421         }
4422         $cache->{data}->{$path} = $t;
4423 }
4424
4425 sub get_dir {
4426         my ($self, $dir, $r) = @_;
4427         my $cache = $self->{cache}->{get_dir};
4428         if ($r == $cache->{r}) {
4429                 if (my $x = $cache->{data}->{$dir}) {
4430                         return wantarray ? @$x : $x->[0];
4431                 }
4432         }
4433         my $pool = SVN::Pool->new;
4434         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4435         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4436         $pool->clear;
4437         if ($r != $cache->{r}) {
4438                 %{$cache->{data}} = ();
4439                 $cache->{r} = $r;
4440         }
4441         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4442         wantarray ? (\%dirents, $r, $props) : \%dirents;
4443 }
4444
4445 sub DESTROY {
4446         # do not call the real DESTROY since we store ourselves in $RA
4447 }
4448
4449 # get_log(paths, start, end, limit,
4450 #         discover_changed_paths, strict_node_history, receiver)
4451 sub get_log {
4452         my ($self, @args) = @_;
4453         my $pool = SVN::Pool->new;
4454
4455         # svn_log_changed_path_t objects passed to get_log are likely to be
4456         # overwritten even if only the refs are copied to an external variable,
4457         # so we should dup the structures in their entirety.  Using an
4458         # externally passed pool (instead of our temporary and quickly cleared
4459         # pool in Git::SVN::Ra) does not help matters at all...
4460         my $receiver = pop @args;
4461         my $prefix = "/".$self->{svn_path};
4462         $prefix =~ s#/+($)##;
4463         my $prefix_regex = qr#^\Q$prefix\E#;
4464         push(@args, sub {
4465                 my ($paths) = $_[0];
4466                 return &$receiver(@_) unless $paths;
4467                 $_[0] = ();
4468                 foreach my $p (keys %$paths) {
4469                         my $i = $paths->{$p};
4470                         # Make path relative to our url, not repos_root
4471                         $p =~ s/$prefix_regex//;
4472                         my %s = map { $_ => $i->$_; }
4473                                 qw/copyfrom_path copyfrom_rev action/;
4474                         if ($s{'copyfrom_path'}) {
4475                                 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4476                         }
4477                         $_[0]{$p} = \%s;
4478                 }
4479                 &$receiver(@_);
4480         });
4481
4482
4483         # the limit parameter was not supported in SVN 1.1.x, so we
4484         # drop it.  Therefore, the receiver callback passed to it
4485         # is made aware of this limitation by being wrapped if
4486         # the limit passed to is being wrapped.
4487         if ($SVN::Core::VERSION le '1.2.0') {
4488                 my $limit = splice(@args, 3, 1);
4489                 if ($limit > 0) {
4490                         my $receiver = pop @args;
4491                         push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4492                 }
4493         }
4494         my $ret = $self->SUPER::get_log(@args, $pool);
4495         $pool->clear;
4496         $ret;
4497 }
4498
4499 sub trees_match {
4500         my ($self, $url1, $rev1, $url2, $rev2) = @_;
4501         my $ctx = SVN::Client->new(auth => _auth_providers);
4502         my $out = IO::File->new_tmpfile;
4503
4504         # older SVN (1.1.x) doesn't take $pool as the last parameter for
4505         # $ctx->diff(), so we'll create a default one
4506         my $pool = SVN::Pool->new_default_sub;
4507
4508         $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4509         $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4510         $out->flush;
4511         my $ret = (($out->stat)[7] == 0);
4512         close $out or croak $!;
4513
4514         $ret;
4515 }
4516
4517 sub get_commit_editor {
4518         my ($self, $log, $cb, $pool) = @_;
4519         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4520         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4521 }
4522
4523 sub gs_do_update {
4524         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4525         my $new = ($rev_a == $rev_b);
4526         my $path = $gs->{path};
4527
4528         if ($new && -e $gs->{index}) {
4529                 unlink $gs->{index} or die
4530                   "Couldn't unlink index: $gs->{index}: $!\n";
4531         }
4532         my $pool = SVN::Pool->new;
4533         $editor->set_path_strip($path);
4534         my (@pc) = split m#/#, $path;
4535         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4536                                         1, $editor, $pool);
4537         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4538
4539         # Since we can't rely on svn_ra_reparent being available, we'll
4540         # just have to do some magic with set_path to make it so
4541         # we only want a partial path.
4542         my $sp = '';
4543         my $final = join('/', @pc);
4544         while (@pc) {
4545                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4546                 $sp .= '/' if length $sp;
4547                 $sp .= shift @pc;
4548         }
4549         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4550
4551         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4552
4553         $reporter->finish_report($pool);
4554         $pool->clear;
4555         $editor->{git_commit_ok};
4556 }
4557
4558 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4559 # svn_ra_reparent didn't work before 1.4)
4560 sub gs_do_switch {
4561         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4562         my $path = $gs->{path};
4563         my $pool = SVN::Pool->new;
4564
4565         my $full_url = $self->{url};
4566         my $old_url = $full_url;
4567         $full_url .= '/' . $path if length $path;
4568         my ($ra, $reparented);
4569
4570         if ($old_url =~ m#^svn(\+ssh)?://# ||
4571             ($full_url =~ m#^https?://# &&
4572              escape_url($full_url) ne $full_url)) {
4573                 $_[0] = undef;
4574                 $self = undef;
4575                 $RA = undef;
4576                 $ra = Git::SVN::Ra->new($full_url);
4577                 $ra_invalid = 1;
4578         } elsif ($old_url ne $full_url) {
4579                 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4580                 $self->{url} = $full_url;
4581                 $reparented = 1;
4582         }
4583
4584         $ra ||= $self;
4585         $url_b = escape_url($url_b);
4586         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4587         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4588         $reporter->set_path('', $rev_a, 0, @lock, $pool);
4589         $reporter->finish_report($pool);
4590
4591         if ($reparented) {
4592                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4593                 $self->{url} = $old_url;
4594         }
4595
4596         $pool->clear;
4597         $editor->{git_commit_ok};
4598 }
4599
4600 sub longest_common_path {
4601         my ($gsv, $globs) = @_;
4602         my %common;
4603         my $common_max = scalar @$gsv;
4604
4605         foreach my $gs (@$gsv) {
4606                 my @tmp = split m#/#, $gs->{path};
4607                 my $p = '';
4608                 foreach (@tmp) {
4609                         $p .= length($p) ? "/$_" : $_;
4610                         $common{$p} ||= 0;
4611                         $common{$p}++;
4612                 }
4613         }
4614         $globs ||= [];
4615         $common_max += scalar @$globs;
4616         foreach my $glob (@$globs) {
4617                 my @tmp = split m#/#, $glob->{path}->{left};
4618                 my $p = '';
4619                 foreach (@tmp) {
4620                         $p .= length($p) ? "/$_" : $_;
4621                         $common{$p} ||= 0;
4622                         $common{$p}++;
4623                 }
4624         }
4625
4626         my $longest_path = '';
4627         foreach (sort {length $b <=> length $a} keys %common) {
4628                 if ($common{$_} == $common_max) {
4629                         $longest_path = $_;
4630                         last;
4631                 }
4632         }
4633         $longest_path;
4634 }
4635
4636 sub gs_fetch_loop_common {
4637         my ($self, $base, $head, $gsv, $globs) = @_;
4638         return if ($base > $head);
4639         my $inc = $_log_window_size;
4640         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4641         my $longest_path = longest_common_path($gsv, $globs);
4642         my $ra_url = $self->{url};
4643         my $find_trailing_edge;
4644         while (1) {
4645                 my %revs;
4646                 my $err;
4647                 my $err_handler = $SVN::Error::handler;
4648                 $SVN::Error::handler = sub {
4649                         ($err) = @_;
4650                         skip_unknown_revs($err);
4651                 };
4652                 sub _cb {
4653                         my ($paths, $r, $author, $date, $log) = @_;
4654                         [ $paths,
4655                           { author => $author, date => $date, log => $log } ];
4656                 }
4657                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4658                                sub { $revs{$_[1]} = _cb(@_) });
4659                 if ($err) {
4660                         print "Checked through r$max\r";
4661                 } else {
4662                         $find_trailing_edge = 1;
4663                 }
4664                 if ($err and $find_trailing_edge) {
4665                         print STDERR "Path '$longest_path' ",
4666                                      "was probably deleted:\n",
4667                                      $err->expanded_message,
4668                                      "\nWill attempt to follow ",
4669                                      "revisions r$min .. r$max ",
4670                                      "committed before the deletion\n";
4671                         my $hi = $max;
4672                         while (--$hi >= $min) {
4673                                 my $ok;
4674                                 $self->get_log([$longest_path], $min, $hi,
4675                                                0, 1, 1, sub {
4676                                                $ok = $_[1];
4677                                                $revs{$_[1]} = _cb(@_) });
4678                                 if ($ok) {
4679                                         print STDERR "r$min .. r$ok OK\n";
4680                                         last;
4681                                 }
4682                         }
4683                         $find_trailing_edge = 0;
4684                 }
4685                 $SVN::Error::handler = $err_handler;
4686
4687                 my %exists = map { $_->{path} => $_ } @$gsv;
4688                 foreach my $r (sort {$a <=> $b} keys %revs) {
4689                         my ($paths, $logged) = @{$revs{$r}};
4690
4691                         foreach my $gs ($self->match_globs(\%exists, $paths,
4692                                                            $globs, $r)) {
4693                                 if ($gs->rev_map_max >= $r) {
4694                                         next;
4695                                 }
4696                                 next unless $gs->match_paths($paths, $r);
4697                                 $gs->{logged_rev_props} = $logged;
4698                                 if (my $last_commit = $gs->last_commit) {
4699                                         $gs->assert_index_clean($last_commit);
4700                                 }
4701                                 my $log_entry = $gs->do_fetch($paths, $r);
4702                                 if ($log_entry) {
4703                                         $gs->do_git_commit($log_entry);
4704                                 }
4705                                 $INDEX_FILES{$gs->{index}} = 1;
4706                         }
4707                         foreach my $g (@$globs) {
4708                                 my $k = "svn-remote.$g->{remote}." .
4709                                         "$g->{t}-maxRev";
4710                                 Git::SVN::tmp_config($k, $r);
4711                         }
4712                         if ($ra_invalid) {
4713                                 $_[0] = undef;
4714                                 $self = undef;
4715                                 $RA = undef;
4716                                 $self = Git::SVN::Ra->new($ra_url);
4717                                 $ra_invalid = undef;
4718                         }
4719                 }
4720                 # pre-fill the .rev_db since it'll eventually get filled in
4721                 # with '0' x40 if something new gets committed
4722                 foreach my $gs (@$gsv) {
4723                         next if $gs->rev_map_max >= $max;
4724                         next if defined $gs->rev_map_get($max);
4725                         $gs->rev_map_set($max, 0 x40);
4726                 }
4727                 foreach my $g (@$globs) {
4728                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4729                         Git::SVN::tmp_config($k, $max);
4730                 }
4731                 last if $max >= $head;
4732                 $min = $max + 1;
4733                 $max += $inc;
4734                 $max = $head if ($max > $head);
4735         }
4736         Git::SVN::gc();
4737 }
4738
4739 sub get_dir_globbed {
4740         my ($self, $left, $depth, $r) = @_;
4741
4742         my @x = eval { $self->get_dir($left, $r) };
4743         return unless scalar @x == 3;
4744         my $dirents = $x[0];
4745         my @finalents;
4746         foreach my $de (keys %$dirents) {
4747                 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4748                 if ($depth > 1) {
4749                         my @args = ("$left/$de", $depth - 1, $r);
4750                         foreach my $dir ($self->get_dir_globbed(@args)) {
4751                                 push @finalents, "$de/$dir";
4752                         }
4753                 } else {
4754                         push @finalents, $de;
4755                 }
4756         }
4757         @finalents;
4758 }
4759
4760 sub match_globs {
4761         my ($self, $exists, $paths, $globs, $r) = @_;
4762
4763         sub get_dir_check {
4764                 my ($self, $exists, $g, $r) = @_;
4765
4766                 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4767                                                   $g->{path}->{depth},
4768                                                   $r);
4769
4770                 foreach my $de (@dirs) {
4771                         my $p = $g->{path}->full_path($de);
4772                         next if $exists->{$p};
4773                         next if (length $g->{path}->{right} &&
4774                                  ($self->check_path($p, $r) !=
4775                                   $SVN::Node::dir));
4776                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4777                                          $g->{ref}->full_path($de), 1);
4778                 }
4779         }
4780         foreach my $g (@$globs) {
4781                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4782                         if ($path->{action} =~ /^[AR]$/) {
4783                                 get_dir_check($self, $exists, $g, $r);
4784                         }
4785                 }
4786                 foreach (keys %$paths) {
4787                         if (/$g->{path}->{left_regex}/ &&
4788                             !/$g->{path}->{regex}/) {
4789                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
4790                                 get_dir_check($self, $exists, $g, $r);
4791                         }
4792                         next unless /$g->{path}->{regex}/;
4793                         my $p = $1;
4794                         my $pathname = $g->{path}->full_path($p);
4795                         next if $exists->{$pathname};
4796                         next if ($self->check_path($pathname, $r) !=
4797                                  $SVN::Node::dir);
4798                         $exists->{$pathname} = Git::SVN->init(
4799                                               $self->{url}, $pathname, undef,
4800                                               $g->{ref}->full_path($p), 1);
4801                 }
4802                 my $c = '';
4803                 foreach (split m#/#, $g->{path}->{left}) {
4804                         $c .= "/$_";
4805                         next unless ($paths->{$c} &&
4806                                      ($paths->{$c}->{action} =~ /^[AR]$/));
4807                         get_dir_check($self, $exists, $g, $r);
4808                 }
4809         }
4810         values %$exists;
4811 }
4812
4813 sub minimize_url {
4814         my ($self) = @_;
4815         return $self->{url} if ($self->{url} eq $self->{repos_root});
4816         my $url = $self->{repos_root};
4817         my @components = split(m!/!, $self->{svn_path});
4818         my $c = '';
4819         do {
4820                 $url .= "/$c" if length $c;
4821                 eval { (ref $self)->new($url)->get_latest_revnum };
4822         } while ($@ && ($c = shift @components));
4823         $url;
4824 }
4825
4826 sub can_do_switch {
4827         my $self = shift;
4828         unless (defined $can_do_switch) {
4829                 my $pool = SVN::Pool->new;
4830                 my $rep = eval {
4831                         $self->do_switch(1, '', 0, $self->{url},
4832                                          SVN::Delta::Editor->new, $pool);
4833                 };
4834                 if ($@) {
4835                         $can_do_switch = 0;
4836                 } else {
4837                         $rep->abort_report($pool);
4838                         $can_do_switch = 1;
4839                 }
4840                 $pool->clear;
4841         }
4842         $can_do_switch;
4843 }
4844
4845 sub skip_unknown_revs {
4846         my ($err) = @_;
4847         my $errno = $err->apr_err();
4848         # Maybe the branch we're tracking didn't
4849         # exist when the repo started, so it's
4850         # not an error if it doesn't, just continue
4851         #
4852         # Wonderfully consistent library, eh?
4853         # 160013 - svn:// and file://
4854         # 175002 - http(s)://
4855         # 175007 - http(s):// (this repo required authorization, too...)
4856         #   More codes may be discovered later...
4857         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4858                 my $err_key = $err->expanded_message;
4859                 # revision numbers change every time, filter them out
4860                 $err_key =~ s/\d+/\0/g;
4861                 $err_key = "$errno\0$err_key";
4862                 unless ($ignored_err{$err_key}) {
4863                         warn "W: Ignoring error from SVN, path probably ",
4864                              "does not exist: ($errno): ",
4865                              $err->expanded_message,"\n";
4866                         warn "W: Do not be alarmed at the above message ",
4867                              "git-svn is just searching aggressively for ",
4868                              "old history.\n",
4869                              "This may take a while on large repositories\n";
4870                         $ignored_err{$err_key} = 1;
4871                 }
4872                 return;
4873         }
4874         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4875 }
4876
4877 package Git::SVN::Log;
4878 use strict;
4879 use warnings;
4880 use POSIX qw/strftime/;
4881 use Time::Local;
4882 use constant commit_log_separator => ('-' x 72) . "\n";
4883 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4884             %rusers $show_commit $incremental/;
4885 my $l_fmt;
4886
4887 sub cmt_showable {
4888         my ($c) = @_;
4889         return 1 if defined $c->{r};
4890
4891         # big commit message got truncated by the 16k pretty buffer in rev-list
4892         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4893                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4894                 @{$c->{l}} = ();
4895                 my @log = command(qw/cat-file commit/, $c->{c});
4896
4897                 # shift off the headers
4898                 shift @log while ($log[0] ne '');
4899                 shift @log;
4900
4901                 # TODO: make $c->{l} not have a trailing newline in the future
4902                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4903
4904                 (undef, $c->{r}, undef) = ::extract_metadata(
4905                                 (grep(/^git-svn-id: /, @log))[-1]);
4906         }
4907         return defined $c->{r};
4908 }
4909
4910 sub log_use_color {
4911         return $color || Git->repository->get_colorbool('color.diff');
4912 }
4913
4914 sub git_svn_log_cmd {
4915         my ($r_min, $r_max, @args) = @_;
4916         my $head = 'HEAD';
4917         my (@files, @log_opts);
4918         foreach my $x (@args) {
4919                 if ($x eq '--' || @files) {
4920                         push @files, $x;
4921                 } else {
4922                         if (::verify_ref("$x^0")) {
4923                                 $head = $x;
4924                         } else {
4925                                 push @log_opts, $x;
4926                         }
4927                 }
4928         }
4929
4930         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4931         $gs ||= Git::SVN->_new;
4932         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4933                    $gs->refname);
4934         push @cmd, '-r' unless $non_recursive;
4935         push @cmd, qw/--raw --name-status/ if $verbose;
4936         push @cmd, '--color' if log_use_color();
4937         push @cmd, @log_opts;
4938         if (defined $r_max && $r_max == $r_min) {
4939                 push @cmd, '--max-count=1';
4940                 if (my $c = $gs->rev_map_get($r_max)) {
4941                         push @cmd, $c;
4942                 }
4943         } elsif (defined $r_max) {
4944                 if ($r_max < $r_min) {
4945                         ($r_min, $r_max) = ($r_max, $r_min);
4946                 }
4947                 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4948                 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4949                 # If there are no commits in the range, both $c_max and $c_min
4950                 # will be undefined.  If there is at least 1 commit in the
4951                 # range, both will be defined.
4952                 return () if !defined $c_min || !defined $c_max;
4953                 if ($c_min eq $c_max) {
4954                         push @cmd, '--max-count=1', $c_min;
4955                 } else {
4956                         push @cmd, '--boundary', "$c_min..$c_max";
4957                 }
4958         }
4959         return (@cmd, @files);
4960 }
4961
4962 # adapted from pager.c
4963 sub config_pager {
4964         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4965         if (!defined $pager) {
4966                 $pager = 'less';
4967         } elsif (length $pager == 0 || $pager eq 'cat') {
4968                 $pager = undef;
4969         }
4970         $ENV{GIT_PAGER_IN_USE} = defined($pager);
4971 }
4972
4973 sub run_pager {
4974         return unless -t *STDOUT && defined $pager;
4975         pipe my ($rfd, $wfd) or return;
4976         defined(my $pid = fork) or ::fatal "Can't fork: $!";
4977         if (!$pid) {
4978                 open STDOUT, '>&', $wfd or
4979                                      ::fatal "Can't redirect to stdout: $!";
4980                 return;
4981         }
4982         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4983         $ENV{LESS} ||= 'FRSX';
4984         exec $pager or ::fatal "Can't run pager: $! ($pager)";
4985 }
4986
4987 sub format_svn_date {
4988         # some systmes don't handle or mishandle %z, so be creative.
4989         my $t = shift || time;
4990         my $gm = timelocal(gmtime($t));
4991         my $sign = qw( + + - )[ $t <=> $gm ];
4992         my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
4993         return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
4994 }
4995
4996 sub parse_git_date {
4997         my ($t, $tz) = @_;
4998         # Date::Parse isn't in the standard Perl distro :(
4999         if ($tz =~ s/^\+//) {
5000                 $t += tz_to_s_offset($tz);
5001         } elsif ($tz =~ s/^\-//) {
5002                 $t -= tz_to_s_offset($tz);
5003         }
5004         return $t;
5005 }
5006
5007 sub set_local_timezone {
5008         if (defined $TZ) {
5009                 $ENV{TZ} = $TZ;
5010         } else {
5011                 delete $ENV{TZ};
5012         }
5013 }
5014
5015 sub tz_to_s_offset {
5016         my ($tz) = @_;
5017         $tz =~ s/(\d\d)$//;
5018         return ($1 * 60) + ($tz * 3600);
5019 }
5020
5021 sub get_author_info {
5022         my ($dest, $author, $t, $tz) = @_;
5023         $author =~ s/(?:^\s*|\s*$)//g;
5024         $dest->{a_raw} = $author;
5025         my $au;
5026         if ($::_authors) {
5027                 $au = $rusers{$author} || undef;
5028         }
5029         if (!$au) {
5030                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5031         }
5032         $dest->{t} = $t;
5033         $dest->{tz} = $tz;
5034         $dest->{a} = $au;
5035         $dest->{t_utc} = parse_git_date($t, $tz);
5036 }
5037
5038 sub process_commit {
5039         my ($c, $r_min, $r_max, $defer) = @_;
5040         if (defined $r_min && defined $r_max) {
5041                 if ($r_min == $c->{r} && $r_min == $r_max) {
5042                         show_commit($c);
5043                         return 0;
5044                 }
5045                 return 1 if $r_min == $r_max;
5046                 if ($r_min < $r_max) {
5047                         # we need to reverse the print order
5048                         return 0 if (defined $limit && --$limit < 0);
5049                         push @$defer, $c;
5050                         return 1;
5051                 }
5052                 if ($r_min != $r_max) {
5053                         return 1 if ($r_min < $c->{r});
5054                         return 1 if ($r_max > $c->{r});
5055                 }
5056         }
5057         return 0 if (defined $limit && --$limit < 0);
5058         show_commit($c);
5059         return 1;
5060 }
5061
5062 sub show_commit {
5063         my $c = shift;
5064         if ($oneline) {
5065                 my $x = "\n";
5066                 if (my $l = $c->{l}) {
5067                         while ($l->[0] =~ /^\s*$/) { shift @$l }
5068                         $x = $l->[0];
5069                 }
5070                 $l_fmt ||= 'A' . length($c->{r});
5071                 print 'r',pack($l_fmt, $c->{r}),' | ';
5072                 print "$c->{c} | " if $show_commit;
5073                 print $x;
5074         } else {
5075                 show_commit_normal($c);
5076         }
5077 }
5078
5079 sub show_commit_changed_paths {
5080         my ($c) = @_;
5081         return unless $c->{changed};
5082         print "Changed paths:\n", @{$c->{changed}};
5083 }
5084
5085 sub show_commit_normal {
5086         my ($c) = @_;
5087         print commit_log_separator, "r$c->{r} | ";
5088         print "$c->{c} | " if $show_commit;
5089         print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5090         my $nr_line = 0;
5091
5092         if (my $l = $c->{l}) {
5093                 while ($l->[$#$l] eq "\n" && $#$l > 0
5094                                           && $l->[($#$l - 1)] eq "\n") {
5095                         pop @$l;
5096                 }
5097                 $nr_line = scalar @$l;
5098                 if (!$nr_line) {
5099                         print "1 line\n\n\n";
5100                 } else {
5101                         if ($nr_line == 1) {
5102                                 $nr_line = '1 line';
5103                         } else {
5104                                 $nr_line .= ' lines';
5105                         }
5106                         print $nr_line, "\n";
5107                         show_commit_changed_paths($c);
5108                         print "\n";
5109                         print $_ foreach @$l;
5110                 }
5111         } else {
5112                 print "1 line\n";
5113                 show_commit_changed_paths($c);
5114                 print "\n";
5115
5116         }
5117         foreach my $x (qw/raw stat diff/) {
5118                 if ($c->{$x}) {
5119                         print "\n";
5120                         print $_ foreach @{$c->{$x}}
5121                 }
5122         }
5123 }
5124
5125 sub cmd_show_log {
5126         my (@args) = @_;
5127         my ($r_min, $r_max);
5128         my $r_last = -1; # prevent dupes
5129         set_local_timezone();
5130         if (defined $::_revision) {
5131                 if ($::_revision =~ /^(\d+):(\d+)$/) {
5132                         ($r_min, $r_max) = ($1, $2);
5133                 } elsif ($::_revision =~ /^\d+$/) {
5134                         $r_min = $r_max = $::_revision;
5135                 } else {
5136                         ::fatal "-r$::_revision is not supported, use ",
5137                                 "standard 'git log' arguments instead";
5138                 }
5139         }
5140
5141         config_pager();
5142         @args = git_svn_log_cmd($r_min, $r_max, @args);
5143         if (!@args) {
5144                 print commit_log_separator unless $incremental || $oneline;
5145                 return;
5146         }
5147         my $log = command_output_pipe(@args);
5148         run_pager();
5149         my (@k, $c, $d, $stat);
5150         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5151         while (<$log>) {
5152                 if (/^${esc_color}commit -?($::sha1_short)/o) {
5153                         my $cmt = $1;
5154                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5155                                 $r_last = $c->{r};
5156                                 process_commit($c, $r_min, $r_max, \@k) or
5157                                                                 goto out;
5158                         }
5159                         $d = undef;
5160                         $c = { c => $cmt };
5161                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5162                         get_author_info($c, $1, $2, $3);
5163                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5164                         # ignore
5165                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5166                         push @{$c->{raw}}, $_;
5167                 } elsif (/^${esc_color}[ACRMDT]\t/) {
5168                         # we could add $SVN->{svn_path} here, but that requires
5169                         # remote access at the moment (repo_path_split)...
5170                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
5171                         push @{$c->{changed}}, $_;
5172                 } elsif (/^${esc_color}diff /o) {
5173                         $d = 1;
5174                         push @{$c->{diff}}, $_;
5175                 } elsif ($d) {
5176                         push @{$c->{diff}}, $_;
5177                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5178                           $esc_color*[\+\-]*$esc_color$/x) {
5179                         $stat = 1;
5180                         push @{$c->{stat}}, $_;
5181                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5182                         push @{$c->{stat}}, $_;
5183                         $stat = undef;
5184                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
5185                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5186                 } elsif (s/^${esc_color}    //o) {
5187                         push @{$c->{l}}, $_;
5188                 }
5189         }
5190         if ($c && defined $c->{r} && $c->{r} != $r_last) {
5191                 $r_last = $c->{r};
5192                 process_commit($c, $r_min, $r_max, \@k);
5193         }
5194         if (@k) {
5195                 ($r_min, $r_max) = ($r_max, $r_min);
5196                 process_commit($_, $r_min, $r_max) foreach reverse @k;
5197         }
5198 out:
5199         close $log;
5200         print commit_log_separator unless $incremental || $oneline;
5201 }
5202
5203 sub cmd_blame {
5204         my $path = pop;
5205
5206         config_pager();
5207         run_pager();
5208
5209         my ($fh, $ctx, $rev);
5210
5211         if ($_git_format) {
5212                 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5213                 while (my $line = <$fh>) {
5214                         if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5215                                 # Uncommitted edits show up as a rev ID of
5216                                 # all zeros, which we can't look up with
5217                                 # cmt_metadata
5218                                 if ($1 !~ /^0+$/) {
5219                                         (undef, $rev, undef) =
5220                                                 ::cmt_metadata($1);
5221                                         $rev = '0' if (!$rev);
5222                                 } else {
5223                                         $rev = '0';
5224                                 }
5225                                 $rev = sprintf('%-10s', $rev);
5226                                 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5227                         }
5228                         print $line;
5229                 }
5230         } else {
5231                 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5232                                                   '--', $path);
5233                 my ($sha1);
5234                 my %authors;
5235                 my @buffer;
5236                 my %dsha; #distinct sha keys
5237
5238                 while (my $line = <$fh>) {
5239                         push @buffer, $line;
5240                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5241                                 $dsha{$1} = 1;
5242                         }
5243                 }
5244
5245                 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5246
5247                 foreach my $line (@buffer) {
5248                         if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5249                                 $rev = $s2r->{$1};
5250                                 $rev = '0' if (!$rev)
5251                         }
5252                         elsif ($line =~ /^author (.*)/) {
5253                                 $authors{$rev} = $1;
5254                                 $authors{$rev} =~ s/\s/_/g;
5255                         }
5256                         elsif ($line =~ /^\t(.*)$/) {
5257                                 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5258                         }
5259                 }
5260         }
5261         command_close_pipe($fh, $ctx);
5262 }
5263
5264 package Git::SVN::Migration;
5265 # these version numbers do NOT correspond to actual version numbers
5266 # of git nor git-svn.  They are just relative.
5267 #
5268 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5269 #
5270 # v1 layout: .git/$id/info/url, refs/remotes/$id
5271 #
5272 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5273 #
5274 # v3 layout: .git/svn/$id, refs/remotes/$id
5275 #            - info/url may remain for backwards compatibility
5276 #            - this is what we migrate up to this layout automatically,
5277 #            - this will be used by git svn init on single branches
5278 # v3.1 layout (auto migrated):
5279 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5280 #              for backwards compatibility
5281 #
5282 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5283 #            - this is only created for newly multi-init-ed
5284 #              repositories.  Similar in spirit to the
5285 #              --use-separate-remotes option in git-clone (now default)
5286 #            - we do not automatically migrate to this (following
5287 #              the example set by core git)
5288 #
5289 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5290 #            - newer, more-efficient format that uses 24-bytes per record
5291 #              with no filler space.
5292 #            - use xxd -c24 < .rev_map.$UUID to view and debug
5293 #            - This is a one-way migration, repositories updated to the
5294 #              new format will not be able to use old git-svn without
5295 #              rebuilding the .rev_db.  Rebuilding the rev_db is not
5296 #              possible if noMetadata or useSvmProps are set; but should
5297 #              be no problem for users that use the (sensible) defaults.
5298 use strict;
5299 use warnings;
5300 use Carp qw/croak/;
5301 use File::Path qw/mkpath/;
5302 use File::Basename qw/dirname basename/;
5303 use vars qw/$_minimize/;
5304
5305 sub migrate_from_v0 {
5306         my $git_dir = $ENV{GIT_DIR};
5307         return undef unless -d $git_dir;
5308         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5309         my $migrated = 0;
5310         while (<$fh>) {
5311                 chomp;
5312                 my ($id, $orig_ref) = ($_, $_);
5313                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5314                 next unless -f "$git_dir/$id/info/url";
5315                 my $new_ref = "refs/remotes/$id";
5316                 if (::verify_ref("$new_ref^0")) {
5317                         print STDERR "W: $orig_ref is probably an old ",
5318                                      "branch used by an ancient version of ",
5319                                      "git-svn.\n",
5320                                      "However, $new_ref also exists.\n",
5321                                      "We will not be able ",
5322                                      "to use this branch until this ",
5323                                      "ambiguity is resolved.\n";
5324                         next;
5325                 }
5326                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5327                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5328                 command_noisy('update-ref', $new_ref, $orig_ref);
5329                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5330                 $migrated++;
5331         }
5332         command_close_pipe($fh, $ctx);
5333         print STDERR "Done migrating from v0 layout...\n" if $migrated;
5334         $migrated;
5335 }
5336
5337 sub migrate_from_v1 {
5338         my $git_dir = $ENV{GIT_DIR};
5339         my $migrated = 0;
5340         return $migrated unless -d $git_dir;
5341         my $svn_dir = "$git_dir/svn";
5342
5343         # just in case somebody used 'svn' as their $id at some point...
5344         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5345
5346         print STDERR "Migrating from a git-svn v1 layout...\n";
5347         mkpath([$svn_dir]);
5348         print STDERR "Data from a previous version of git-svn exists, but\n\t",
5349                      "$svn_dir\n\t(required for this version ",
5350                      "($::VERSION) of git-svn) does not exist.\n";
5351         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5352         while (<$fh>) {
5353                 my $x = $_;
5354                 next unless $x =~ s#^refs/remotes/##;
5355                 chomp $x;
5356                 next unless -f "$git_dir/$x/info/url";
5357                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5358                 next unless $u;
5359                 my $dn = dirname("$git_dir/svn/$x");
5360                 mkpath([$dn]) unless -d $dn;
5361                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5362                         mkpath(["$git_dir/svn/svn"]);
5363                         print STDERR " - $git_dir/$x/info => ",
5364                                         "$git_dir/svn/$x/info\n";
5365                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5366                                croak "$!: $x";
5367                         # don't worry too much about these, they probably
5368                         # don't exist with repos this old (save for index,
5369                         # and we can easily regenerate that)
5370                         foreach my $f (qw/unhandled.log index .rev_db/) {
5371                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5372                         }
5373                 } else {
5374                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5375                         rename "$git_dir/$x", "$git_dir/svn/$x" or
5376                                croak "$!: $x";
5377                 }
5378                 $migrated++;
5379         }
5380         command_close_pipe($fh, $ctx);
5381         print STDERR "Done migrating from a git-svn v1 layout\n";
5382         $migrated;
5383 }
5384
5385 sub read_old_urls {
5386         my ($l_map, $pfx, $path) = @_;
5387         my @dir;
5388         foreach (<$path/*>) {
5389                 if (-r "$_/info/url") {
5390                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5391                         my $ref_id = $pfx . basename $_;
5392                         my $url = ::file_to_s("$_/info/url");
5393                         $l_map->{$ref_id} = $url;
5394                 } elsif (-d $_) {
5395                         push @dir, $_;
5396                 }
5397         }
5398         foreach (@dir) {
5399                 my $x = $_;
5400                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5401                 read_old_urls($l_map, $x, $_);
5402         }
5403 }
5404
5405 sub migrate_from_v2 {
5406         my @cfg = command(qw/config -l/);
5407         return if grep /^svn-remote\..+\.url=/, @cfg;
5408         my %l_map;
5409         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5410         my $migrated = 0;
5411
5412         foreach my $ref_id (sort keys %l_map) {
5413                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5414                 if ($@) {
5415                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5416                 }
5417                 $migrated++;
5418         }
5419         $migrated;
5420 }
5421
5422 sub minimize_connections {
5423         my $r = Git::SVN::read_all_remotes();
5424         my $new_urls = {};
5425         my $root_repos = {};
5426         foreach my $repo_id (keys %$r) {
5427                 my $url = $r->{$repo_id}->{url} or next;
5428                 my $fetch = $r->{$repo_id}->{fetch} or next;
5429                 my $ra = Git::SVN::Ra->new($url);
5430
5431                 # skip existing cases where we already connect to the root
5432                 if (($ra->{url} eq $ra->{repos_root}) ||
5433                     ($ra->{repos_root} eq $repo_id)) {
5434                         $root_repos->{$ra->{url}} = $repo_id;
5435                         next;
5436                 }
5437
5438                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5439                 my $root_path = $ra->{url};
5440                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5441                 foreach my $path (keys %$fetch) {
5442                         my $ref_id = $fetch->{$path};
5443                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5444
5445                         # make sure we can read when connecting to
5446                         # a higher level of a repository
5447                         my ($last_rev, undef) = $gs->last_rev_commit;
5448                         if (!defined $last_rev) {
5449                                 $last_rev = eval {
5450                                         $root_ra->get_latest_revnum;
5451                                 };
5452                                 next if $@;
5453                         }
5454                         my $new = $root_path;
5455                         $new .= length $path ? "/$path" : '';
5456                         eval {
5457                                 $root_ra->get_log([$new], $last_rev, $last_rev,
5458                                                   0, 0, 1, sub { });
5459                         };
5460                         next if $@;
5461                         $new_urls->{$ra->{repos_root}}->{$new} =
5462                                 { ref_id => $ref_id,
5463                                   old_repo_id => $repo_id,
5464                                   old_path => $path };
5465                 }
5466         }
5467
5468         my @emptied;
5469         foreach my $url (keys %$new_urls) {
5470                 # see if we can re-use an existing [svn-remote "repo_id"]
5471                 # instead of creating a(n ugly) new section:
5472                 my $repo_id = $root_repos->{$url} || $url;
5473
5474                 my $fetch = $new_urls->{$url};
5475                 foreach my $path (keys %$fetch) {
5476                         my $x = $fetch->{$path};
5477                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5478                         my $pfx = "svn-remote.$x->{old_repo_id}";
5479
5480                         my $old_fetch = quotemeta("$x->{old_path}:".
5481                                                   "refs/remotes/$x->{ref_id}");
5482                         command_noisy(qw/config --unset/,
5483                                       "$pfx.fetch", '^'. $old_fetch . '$');
5484                         delete $r->{$x->{old_repo_id}}->
5485                                {fetch}->{$x->{old_path}};
5486                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5487                                 command_noisy(qw/config --unset/,
5488                                               "$pfx.url");
5489                                 push @emptied, $x->{old_repo_id}
5490                         }
5491                 }
5492         }
5493         if (@emptied) {
5494                 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5495                 print STDERR <<EOF;
5496 The following [svn-remote] sections in your config file ($file) are empty
5497 and can be safely removed:
5498 EOF
5499                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5500         }
5501 }
5502
5503 sub migration_check {
5504         migrate_from_v0();
5505         migrate_from_v1();
5506         migrate_from_v2();
5507         minimize_connections() if $_minimize;
5508 }
5509
5510 package Git::IndexInfo;
5511 use strict;
5512 use warnings;
5513 use Git qw/command_input_pipe command_close_pipe/;
5514
5515 sub new {
5516         my ($class) = @_;
5517         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5518         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5519 }
5520
5521 sub remove {
5522         my ($self, $path) = @_;
5523         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5524                 return ++$self->{nr};
5525         }
5526         undef;
5527 }
5528
5529 sub update {
5530         my ($self, $mode, $hash, $path) = @_;
5531         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5532                 return ++$self->{nr};
5533         }
5534         undef;
5535 }
5536
5537 sub DESTROY {
5538         my ($self) = @_;
5539         command_close_pipe($self->{gui}, $self->{ctx});
5540 }
5541
5542 package Git::SVN::GlobSpec;
5543 use strict;
5544 use warnings;
5545
5546 sub new {
5547         my ($class, $glob) = @_;
5548         my $re = $glob;
5549         $re =~ s!/+$!!g; # no need for trailing slashes
5550         $re =~ m!^([^*]*)(\*(?:/\*)*)([^*]*)$!;
5551         my $temp = $re;
5552         my ($left, $right) = ($1, $3);
5553         $re = $2;
5554         my $depth = $re =~ tr/*/*/;
5555         if ($depth != $temp =~ tr/*/*/) {
5556                 die "Only one set of wildcard directories " .
5557                         "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5558         }
5559         if ($depth == 0) {
5560                 die "One '*' is needed for glob: '$glob'\n";
5561         }
5562         $re =~ s!\*!\[^/\]*!g;
5563         $re = quotemeta($left) . "($re)" . quotemeta($right);
5564         if (length $left && !($left =~ s!/+$!!g)) {
5565                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5566         }
5567         if (length $right && !($right =~ s!^/+!!g)) {
5568                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5569         }
5570         my $left_re = qr/^\/\Q$left\E(\/|$)/;
5571         bless { left => $left, right => $right, left_regex => $left_re,
5572                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5573 }
5574
5575 sub full_path {
5576         my ($self, $path) = @_;
5577         return (length $self->{left} ? "$self->{left}/" : '') .
5578                $path . (length $self->{right} ? "/$self->{right}" : '');
5579 }
5580
5581 __END__
5582
5583 Data structures:
5584
5585
5586 $remotes = { # returned by read_all_remotes()
5587         'svn' => {
5588                 # svn-remote.svn.url=https://svn.musicpd.org
5589                 url => 'https://svn.musicpd.org',
5590                 # svn-remote.svn.fetch=mpd/trunk:trunk
5591                 fetch => {
5592                         'mpd/trunk' => 'trunk',
5593                 },
5594                 # svn-remote.svn.tags=mpd/tags/*:tags/*
5595                 tags => {
5596                         path => {
5597                                 left => 'mpd/tags',
5598                                 right => '',
5599                                 regex => qr!mpd/tags/([^/]+)$!,
5600                                 glob => 'tags/*',
5601                         },
5602                         ref => {
5603                                 left => 'tags',
5604                                 right => '',
5605                                 regex => qr!tags/([^/]+)$!,
5606                                 glob => 'tags/*',
5607                         },
5608                 }
5609         }
5610 };
5611
5612 $log_entry hashref as returned by libsvn_log_entry()
5613 {
5614         log => 'whitespace-formatted log entry
5615 ',                                              # trailing newline is preserved
5616         revision => '8',                        # integer
5617         date => '2004-02-24T17:01:44.108345Z',  # commit date
5618         author => 'committer name'
5619 };
5620
5621
5622 # this is generated by generate_diff();
5623 @mods = array of diff-index line hashes, each element represents one line
5624         of diff-index output
5625
5626 diff-index line ($m hash)
5627 {
5628         mode_a => first column of diff-index output, no leading ':',
5629         mode_b => second column of diff-index output,
5630         sha1_b => sha1sum of the final blob,
5631         chg => change type [MCRADT],
5632         file_a => original file name of a file (iff chg is 'C' or 'R')
5633         file_b => new/current file name of a file (any chg)
5634 }
5635 ;
5636
5637 # retval of read_url_paths{,_all}();
5638 $l_map = {
5639         # repository root url
5640         'https://svn.musicpd.org' => {
5641                 # repository path               # GIT_SVN_ID
5642                 'mpd/trunk'             =>      'trunk',
5643                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
5644         },
5645 }
5646
5647 Notes:
5648         I don't trust the each() function on unless I created %hash myself
5649         because the internal iterator may not have started at base.