git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --[no-]to               <str>  * Email To:
  51     --[no-]cc               <str>  * Email Cc:
  52     --[no-]bcc              <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  68     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  69
  70   Automating:
  71     --identity              <str>  * Use the sendemail.<id> options.
  72     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  73     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  74     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  75     --[no-]suppress-from           * Send to self. Default off.
  76     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  77     --[no-]thread                  * Use In-Reply-To: field. Default on.
  78
  79   Administering:
  80     --confirm               <str>  * Confirm recipients before sending;
  81                                      auto, cc, compose, always, or never.
  82     --quiet                        * Output one line of info per email.
  83     --dry-run                      * Don't actually send the emails.
  84     --[no-]validate                * Perform patch sanity checks. Default on.
  85     --[no-]format-patch            * understand any non optional arguments as
  86                                      `git format-patch` ones.
  87
  88 EOT
  89         exit(1);
  90 }
  91
  92 # most mail servers generate the Date: header, but not all...
  93 sub format_2822_time {
  94         my ($time) = @_;
  95         my @localtm = localtime($time);
  96         my @gmttm = gmtime($time);
  97         my $localmin = $localtm[1] + $localtm[2] * 60;
  98         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  99         if ($localtm[0] != $gmttm[0]) {
 100                 die "local zone differs from GMT by a non-minute interval\n";
 101         }
 102         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 103                 $localmin += 1440;
 104         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 105                 $localmin -= 1440;
 106         } elsif ($gmttm[6] != $localtm[6]) {
 107                 die "local time offset greater than or equal to 24 hours\n";
 108         }
 109         my $offset = $localmin - $gmtmin;
 110         my $offhour = $offset / 60;
 111         my $offmin = abs($offset % 60);
 112         if (abs($offhour) >= 24) {
 113                 die ("local time offset greater than or equal to 24 hours\n");
 114         }
 115
 116         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 117                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 118                        $localtm[3],
 119                        qw(Jan Feb Mar Apr May Jun
 120                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 121                        $localtm[5]+1900,
 122                        $localtm[2],
 123                        $localtm[1],
 124                        $localtm[0],
 125                        ($offset >= 0) ? '+' : '-',
 126                        abs($offhour),
 127                        $offmin,
 128                        );
 129 }
 130
 131 my $have_email_valid = eval { require Email::Valid; 1 };
 132 my $have_mail_address = eval { require Mail::Address; 1 };
 133 my $smtp;
 134 my $auth;
 135 my $mail_domain_default = "localhost.localdomain";
 136 my $mail_domain;
 137
 138 sub unique_email_list(@);
 139 sub cleanup_compose_files();
 140
 141 # Variables we fill in automatically, or via prompting:
 142 my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 143         $initial_reply_to,$initial_subject,@files,
 144         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 145
 146 my $envelope_sender;
 147
 148 # Example reply to:
 149 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 150
 151 my $repo = eval { Git->repository() };
 152 my @repo = $repo ? ($repo) : ();
 153 my $term = eval {
 154         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 155                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 156                 : new Term::ReadLine 'git-send-email';
 157 };
 158 if ($@) {
 159         $term = new FakeTerm "$@: going non-interactive";
 160 }
 161
 162 # Behavior modification variables
 163 my ($quiet, $dry_run) = (0, 0);
 164 my $format_patch;
 165 my $compose_filename;
 166
 167 # Handle interactive edition of files.
 168 my $multiedit;
 169 my $editor;
 170
 171 sub do_edit {
 172         if (!defined($editor)) {
 173                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 174         }
 175         if (defined($multiedit) && !$multiedit) {
 176                 map {
 177                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 178                         if (($? & 127) || ($? >> 8)) {
 179                                 die("the editor exited uncleanly, aborting everything");
 180                         }
 181                 } @_;
 182         } else {
 183                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 184                 if (($? & 127) || ($? >> 8)) {
 185                         die("the editor exited uncleanly, aborting everything");
 186                 }
 187         }
 188 }
 189
 190 # Variables with corresponding config settings
 191 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 192 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 193 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 194 my ($validate, $confirm);
 195 my (@suppress_cc);
 196
 197 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 198
 199 my $not_set_by_user = "true but not set by the user";
 200
 201 my %config_bool_settings = (
 202     "thread" => [\$thread, 1],
 203     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 204     "suppressfrom" => [\$suppress_from, undef],
 205     "signedoffbycc" => [\$signed_off_by_cc, undef],
 206     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 207     "validate" => [\$validate, 1],
 208 );
 209
 210 my %config_settings = (
 211     "smtpserver" => \$smtp_server,
 212     "smtpserverport" => \$smtp_server_port,
 213     "smtpuser" => \$smtp_authuser,
 214     "smtppass" => \$smtp_authpass,
 215     "to" => \@to,
 216     "cc" => \@initial_cc,
 217     "cccmd" => \$cc_cmd,
 218     "aliasfiletype" => \$aliasfiletype,
 219     "bcc" => \@bcclist,
 220     "aliasesfile" => \@alias_files,
 221     "suppresscc" => \@suppress_cc,
 222     "envelopesender" => \$envelope_sender,
 223     "multiedit" => \$multiedit,
 224     "confirm"   => \$confirm,
 225     "from" => \$sender,
 226 );
 227
 228 # Help users prepare for 1.7.0
 229 sub chain_reply_to {
 230         if (defined $chain_reply_to &&
 231             $chain_reply_to eq $not_set_by_user) {
 232                 print STDERR
 233                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 234                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 235                     "you want to keep --chain-reply-to as your default.\n";
 236                 $chain_reply_to = 0;
 237         }
 238         return $chain_reply_to;
 239 }
 240
 241 # Handle Uncouth Termination
 242 sub signal_handler {
 243
 244         # Make text normal
 245         print color("reset"), "\n";
 246
 247         # SMTP password masked
 248         system "stty echo";
 249
 250         # tmp files from --compose
 251         if (defined $compose_filename) {
 252                 if (-e $compose_filename) {
 253                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 254                 }
 255                 if (-e ($compose_filename . ".final")) {
 256                         print "'$compose_filename.final' contains the composed email.\n"
 257                 }
 258         }
 259
 260         exit;
 261 };
 262
 263 $SIG{TERM} = \&signal_handler;
 264 $SIG{INT}  = \&signal_handler;
 265
 266 # Begin by accumulating all the variables (defined above), that we will end up
 267 # needing, first, from the command line:
 268
 269 my $rc = GetOptions("sender|from=s" => \$sender,
 270                     "in-reply-to=s" => \$initial_reply_to,
 271                     "subject=s" => \$initial_subject,
 272                     "to=s" => \@to,
 273                     "no-to" => \$no_to,
 274                     "cc=s" => \@initial_cc,
 275                     "no-cc" => \$no_cc,
 276                     "bcc=s" => \@bcclist,
 277                     "no-bcc" => \$no_bcc,
 278                     "chain-reply-to!" => \$chain_reply_to,
 279                     "smtp-server=s" => \$smtp_server,
 280                     "smtp-server-port=s" => \$smtp_server_port,
 281                     "smtp-user=s" => \$smtp_authuser,
 282                     "smtp-pass:s" => \$smtp_authpass,
 283                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 284                     "smtp-encryption=s" => \$smtp_encryption,
 285                     "smtp-debug:i" => \$debug_net_smtp,
 286                     "smtp-domain:s" => \$mail_domain,
 287                     "identity=s" => \$identity,
 288                     "annotate" => \$annotate,
 289                     "compose" => \$compose,
 290                     "quiet" => \$quiet,
 291                     "cc-cmd=s" => \$cc_cmd,
 292                     "suppress-from!" => \$suppress_from,
 293                     "suppress-cc=s" => \@suppress_cc,
 294                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 295                     "confirm=s" => \$confirm,
 296                     "dry-run" => \$dry_run,
 297                     "envelope-sender=s" => \$envelope_sender,
 298                     "thread!" => \$thread,
 299                     "validate!" => \$validate,
 300                     "format-patch!" => \$format_patch,
 301          );
 302
 303 unless ($rc) {
 304     usage();
 305 }
 306
 307 die "Cannot run git format-patch from outside a repository\n"
 308         if $format_patch and not $repo;
 309
 310 # Now, let's fill any that aren't set in with defaults:
 311
 312 sub read_config {
 313         my ($prefix) = @_;
 314
 315         foreach my $setting (keys %config_bool_settings) {
 316                 my $target = $config_bool_settings{$setting}->[0];
 317                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 318         }
 319
 320         foreach my $setting (keys %config_settings) {
 321                 my $target = $config_settings{$setting};
 322                 next if $setting eq "to" and defined $no_to;
 323                 next if $setting eq "cc" and defined $no_cc;
 324                 next if $setting eq "bcc" and defined $no_bcc;
 325                 if (ref($target) eq "ARRAY") {
 326                         unless (@$target) {
 327                                 my @values = Git::config(@repo, "$prefix.$setting");
 328                                 @$target = @values if (@values && defined $values[0]);
 329                         }
 330                 }
 331                 else {
 332                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 333                 }
 334         }
 335
 336         if (!defined $smtp_encryption) {
 337                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 338                 if (defined $enc) {
 339                         $smtp_encryption = $enc;
 340                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 341                         $smtp_encryption = 'ssl';
 342                 }
 343         }
 344 }
 345
 346 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 347 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 348 read_config("sendemail.$identity") if (defined $identity);
 349 read_config("sendemail");
 350
 351 # fall back on builtin bool defaults
 352 foreach my $setting (values %config_bool_settings) {
 353         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 354 }
 355
 356 # 'default' encryption is none -- this only prevents a warning
 357 $smtp_encryption = '' unless (defined $smtp_encryption);
 358
 359 # Set CC suppressions
 360 my(%suppress_cc);
 361 if (@suppress_cc) {
 362         foreach my $entry (@suppress_cc) {
 363                 die "Unknown --suppress-cc field: '$entry'\n"
 364                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 365                 $suppress_cc{$entry} = 1;
 366         }
 367 }
 368
 369 if ($suppress_cc{'all'}) {
 370         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 371                 $suppress_cc{$entry} = 1;
 372         }
 373         delete $suppress_cc{'all'};
 374 }
 375
 376 # If explicit old-style ones are specified, they trump --suppress-cc.
 377 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 378 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 379
 380 if ($suppress_cc{'body'}) {
 381         foreach my $entry (qw (sob bodycc)) {
 382                 $suppress_cc{$entry} = 1;
 383         }
 384         delete $suppress_cc{'body'};
 385 }
 386
 387 # Set confirm's default value
 388 my $confirm_unconfigured = !defined $confirm;
 389 if ($confirm_unconfigured) {
 390         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 391 };
 392 die "Unknown --confirm setting: '$confirm'\n"
 393         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 394
 395 # Debugging, print out the suppressions.
 396 if (0) {
 397         print "suppressions:\n";
 398         foreach my $entry (keys %suppress_cc) {
 399                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 400         }
 401 }
 402
 403 my ($repoauthor, $repocommitter);
 404 ($repoauthor) = Git::ident_person(@repo, 'author');
 405 ($repocommitter) = Git::ident_person(@repo, 'committer');
 406
 407 # Verify the user input
 408
 409 foreach my $entry (@to) {
 410         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 411 }
 412
 413 foreach my $entry (@initial_cc) {
 414         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 415 }
 416
 417 foreach my $entry (@bcclist) {
 418         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 419 }
 420
 421 sub parse_address_line {
 422         if ($have_mail_address) {
 423                 return map { $_->format } Mail::Address->parse($_[0]);
 424         } else {
 425                 return split_addrs($_[0]);
 426         }
 427 }
 428
 429 sub split_addrs {
 430         return quotewords('\s*,\s*', 1, @_);
 431 }
 432
 433 my %aliases;
 434 my %parse_alias = (
 435         # multiline formats can be supported in the future
 436         mutt => sub { my $fh = shift; while (<$fh>) {
 437                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 438                         my ($alias, $addr) = ($1, $2);
 439                         $addr =~ s/#.*$//; # mutt allows # comments
 440                          # commas delimit multiple addresses
 441                         $aliases{$alias} = [ split_addrs($addr) ];
 442                 }}},
 443         mailrc => sub { my $fh = shift; while (<$fh>) {
 444                 if (/^alias\s+(\S+)\s+(.*)$/) {
 445                         # spaces delimit multiple addresses
 446                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 447                 }}},
 448         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 449                 for (my $x = ''; defined($x); $x = $_) {
 450                         chomp $x;
 451                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 452                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 453                         $aliases{$1} = [ split_addrs($2) ];
 454                 }},
 455         elm => sub  { my $fh = shift;
 456                       while (<$fh>) {
 457                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 458                               my ($alias, $addr) = ($1, $2);
 459                                $aliases{$alias} = [ split_addrs($addr) ];
 460                           }
 461                       } },
 462
 463         gnus => sub { my $fh = shift; while (<$fh>) {
 464                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 465                         $aliases{$1} = [ $2 ];
 466                 }}}
 467 );
 468
 469 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 470         foreach my $file (@alias_files) {
 471                 open my $fh, '<', $file or die "opening $file: $!\n";
 472                 $parse_alias{$aliasfiletype}->($fh);
 473                 close $fh;
 474         }
 475 }
 476
 477 ($sender) = expand_aliases($sender) if defined $sender;
 478
 479 # returns 1 if the conflict must be solved using it as a format-patch argument
 480 sub check_file_rev_conflict($) {
 481         return unless $repo;
 482         my $f = shift;
 483         try {
 484                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 485                 if (defined($format_patch)) {
 486                         return $format_patch;
 487                 }
 488                 die(<<EOF);
 489 File '$f' exists but it could also be the range of commits
 490 to produce patches for.  Please disambiguate by...
 491
 492     * Saying "./$f" if you mean a file; or
 493     * Giving --format-patch option if you mean a range.
 494 EOF
 495         } catch Git::Error::Command with {
 496                 return 0;
 497         }
 498 }
 499
 500 # Now that all the defaults are set, process the rest of the command line
 501 # arguments and collect up the files that need to be processed.
 502 my @rev_list_opts;
 503 while (defined(my $f = shift @ARGV)) {
 504         if ($f eq "--") {
 505                 push @rev_list_opts, "--", @ARGV;
 506                 @ARGV = ();
 507         } elsif (-d $f and !check_file_rev_conflict($f)) {
 508                 opendir(DH,$f)
 509                         or die "Failed to opendir $f: $!";
 510
 511                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 512                                 sort readdir(DH);
 513                 closedir(DH);
 514         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 515                 push @files, $f;
 516         } else {
 517                 push @rev_list_opts, $f;
 518         }
 519 }
 520
 521 if (@rev_list_opts) {
 522         die "Cannot run git format-patch from outside a repository\n"
 523                 unless $repo;
 524         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 525 }
 526
 527 if ($validate) {
 528         foreach my $f (@files) {
 529                 unless (-p $f) {
 530                         my $error = validate_patch($f);
 531                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 532                 }
 533         }
 534 }
 535
 536 if (@files) {
 537         unless ($quiet) {
 538                 print $_,"\n" for (@files);
 539         }
 540 } else {
 541         print STDERR "\nNo patch files specified!\n\n";
 542         usage();
 543 }
 544
 545 sub get_patch_subject($) {
 546         my $fn = shift;
 547         open (my $fh, '<', $fn);
 548         while (my $line = <$fh>) {
 549                 next unless ($line =~ /^Subject: (.*)$/);
 550                 close $fh;
 551                 return "GIT: $1\n";
 552         }
 553         close $fh;
 554         die "No subject line in $fn ?";
 555 }
 556
 557 if ($compose) {
 558         # Note that this does not need to be secure, but we will make a small
 559         # effort to have it be unique
 560         $compose_filename = ($repo ?
 561                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 562                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 563         open(C,">",$compose_filename)
 564                 or die "Failed to open for writing $compose_filename: $!";
 565
 566
 567         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 568         my $tpl_subject = $initial_subject || '';
 569         my $tpl_reply_to = $initial_reply_to || '';
 570
 571         print C <<EOT;
 572 From $tpl_sender # This line is ignored.
 573 GIT: Lines beginning in "GIT:" will be removed.
 574 GIT: Consider including an overall diffstat or table of contents
 575 GIT: for the patch you are writing.
 576 GIT:
 577 GIT: Clear the body content if you don't wish to send a summary.
 578 From: $tpl_sender
 579 Subject: $tpl_subject
 580 In-Reply-To: $tpl_reply_to
 581
 582 EOT
 583         for my $f (@files) {
 584                 print C get_patch_subject($f);
 585         }
 586         close(C);
 587
 588         if ($annotate) {
 589                 do_edit($compose_filename, @files);
 590         } else {
 591                 do_edit($compose_filename);
 592         }
 593
 594         open(C2,">",$compose_filename . ".final")
 595                 or die "Failed to open $compose_filename.final : " . $!;
 596
 597         open(C,"<",$compose_filename)
 598                 or die "Failed to open $compose_filename : " . $!;
 599
 600         my $need_8bit_cte = file_has_nonascii($compose_filename);
 601         my $in_body = 0;
 602         my $summary_empty = 1;
 603         while(<C>) {
 604                 next if m/^GIT:/;
 605                 if ($in_body) {
 606                         $summary_empty = 0 unless (/^\n$/);
 607                 } elsif (/^\n$/) {
 608                         $in_body = 1;
 609                         if ($need_8bit_cte) {
 610                                 print C2 "MIME-Version: 1.0\n",
 611                                          "Content-Type: text/plain; ",
 612                                            "charset=UTF-8\n",
 613                                          "Content-Transfer-Encoding: 8bit\n";
 614                         }
 615                 } elsif (/^MIME-Version:/i) {
 616                         $need_8bit_cte = 0;
 617                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 618                         $initial_subject = $1;
 619                         my $subject = $initial_subject;
 620                         $_ = "Subject: " .
 621                                 ($subject =~ /[^[:ascii:]]/ ?
 622                                  quote_rfc2047($subject) :
 623                                  $subject) .
 624                                 "\n";
 625                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 626                         $initial_reply_to = $1;
 627                         next;
 628                 } elsif (/^From:\s*(.+)\s*$/i) {
 629                         $sender = $1;
 630                         next;
 631                 } elsif (/^(?:To|Cc|Bcc):/i) {
 632                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 633                         next;
 634                 }
 635                 print C2 $_;
 636         }
 637         close(C);
 638         close(C2);
 639
 640         if ($summary_empty) {
 641                 print "Summary email is empty, skipping it\n";
 642                 $compose = -1;
 643         }
 644 } elsif ($annotate) {
 645         do_edit(@files);
 646 }
 647
 648 sub ask {
 649         my ($prompt, %arg) = @_;
 650         my $valid_re = $arg{valid_re};
 651         my $default = $arg{default};
 652         my $resp;
 653         my $i = 0;
 654         return defined $default ? $default : undef
 655                 unless defined $term->IN and defined fileno($term->IN) and
 656                        defined $term->OUT and defined fileno($term->OUT);
 657         while ($i++ < 10) {
 658                 $resp = $term->readline($prompt);
 659                 if (!defined $resp) { # EOF
 660                         print "\n";
 661                         return defined $default ? $default : undef;
 662                 }
 663                 if ($resp eq '' and defined $default) {
 664                         return $default;
 665                 }
 666                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 667                         return $resp;
 668                 }
 669         }
 670         return undef;
 671 }
 672
 673 my $prompting = 0;
 674 if (!defined $sender) {
 675         $sender = $repoauthor || $repocommitter || '';
 676         $sender = ask("Who should the emails appear to be from? [$sender] ",
 677                       default => $sender);
 678         print "Emails will be sent from: ", $sender, "\n";
 679         $prompting++;
 680 }
 681
 682 if (!@to) {
 683         my $to = ask("Who should the emails be sent to? ");
 684         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 685         $prompting++;
 686 }
 687
 688 sub expand_aliases {
 689         return map { expand_one_alias($_) } @_;
 690 }
 691
 692 my %EXPANDED_ALIASES;
 693 sub expand_one_alias {
 694         my $alias = shift;
 695         if ($EXPANDED_ALIASES{$alias}) {
 696                 die "fatal: alias '$alias' expands to itself\n";
 697         }
 698         local $EXPANDED_ALIASES{$alias} = 1;
 699         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 700 }
 701
 702 @to = expand_aliases(@to);
 703 @to = (map { sanitize_address($_) } @to);
 704 @initial_cc = expand_aliases(@initial_cc);
 705 @bcclist = expand_aliases(@bcclist);
 706
 707 if ($thread && !defined $initial_reply_to && $prompting) {
 708         $initial_reply_to = ask(
 709                 "Message-ID to be used as In-Reply-To for the first email? ");
 710 }
 711 if (defined $initial_reply_to) {
 712         $initial_reply_to =~ s/^\s*<?//;
 713         $initial_reply_to =~ s/>?\s*$//;
 714         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 715 }
 716
 717 if (!defined $smtp_server) {
 718         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 719                 if (-x $_) {
 720                         $smtp_server = $_;
 721                         last;
 722                 }
 723         }
 724         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 725 }
 726
 727 if ($compose && $compose > 0) {
 728         @files = ($compose_filename . ".final", @files);
 729 }
 730
 731 # Variables we set as part of the loop over files
 732 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 733         $needs_confirm, $message_num, $ask_default);
 734
 735 sub extract_valid_address {
 736         my $address = shift;
 737         my $local_part_regexp = '[^<>"\s@]+';
 738         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 739
 740         # check for a local address:
 741         return $address if ($address =~ /^($local_part_regexp)$/);
 742
 743         $address =~ s/^\s*<(.*)>\s*$/$1/;
 744         if ($have_email_valid) {
 745                 return scalar Email::Valid->address($address);
 746         } else {
 747                 # less robust/correct than the monster regexp in Email::Valid,
 748                 # but still does a 99% job, and one less dependency
 749                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 750                 return $1;
 751         }
 752 }
 753
 754 # Usually don't need to change anything below here.
 755
 756 # we make a "fake" message id by taking the current number
 757 # of seconds since the beginning of Unix time and tacking on
 758 # a random number to the end, in case we are called quicker than
 759 # 1 second since the last time we were called.
 760
 761 # We'll setup a template for the message id, using the "from" address:
 762
 763 my ($message_id_stamp, $message_id_serial);
 764 sub make_message_id
 765 {
 766         my $uniq;
 767         if (!defined $message_id_stamp) {
 768                 $message_id_stamp = sprintf("%s-%s", time, $$);
 769                 $message_id_serial = 0;
 770         }
 771         $message_id_serial++;
 772         $uniq = "$message_id_stamp-$message_id_serial";
 773
 774         my $du_part;
 775         for ($sender, $repocommitter, $repoauthor) {
 776                 $du_part = extract_valid_address(sanitize_address($_));
 777                 last if (defined $du_part and $du_part ne '');
 778         }
 779         if (not defined $du_part or $du_part eq '') {
 780                 use Sys::Hostname qw();
 781                 $du_part = 'user@' . Sys::Hostname::hostname();
 782         }
 783         my $message_id_template = "<%s-git-send-email-%s>";
 784         $message_id = sprintf($message_id_template, $uniq, $du_part);
 785         #print "new message id = $message_id\n"; # Was useful for debugging
 786 }
 787
 788
 789
 790 $time = time - scalar $#files;
 791
 792 sub unquote_rfc2047 {
 793         local ($_) = @_;
 794         my $encoding;
 795         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 796                 $encoding = $1;
 797                 s/_/ /g;
 798                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 799         }
 800         return wantarray ? ($_, $encoding) : $_;
 801 }
 802
 803 sub quote_rfc2047 {
 804         local $_ = shift;
 805         my $encoding = shift || 'UTF-8';
 806         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 807         s/(.*)/=\?$encoding\?q\?$1\?=/;
 808         return $_;
 809 }
 810
 811 sub is_rfc2047_quoted {
 812         my $s = shift;
 813         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 814         my $encoded_text = '[!->@-~]+';
 815         length($s) <= 75 &&
 816         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 817 }
 818
 819 # use the simplest quoting being able to handle the recipient
 820 sub sanitize_address
 821 {
 822         my ($recipient) = @_;
 823         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 824
 825         if (not $recipient_name) {
 826                 return "$recipient";
 827         }
 828
 829         # if recipient_name is already quoted, do nothing
 830         if (is_rfc2047_quoted($recipient_name)) {
 831                 return $recipient;
 832         }
 833
 834         # rfc2047 is needed if a non-ascii char is included
 835         if ($recipient_name =~ /[^[:ascii:]]/) {
 836                 $recipient_name =~ s/^"(.*)"$/$1/;
 837                 $recipient_name = quote_rfc2047($recipient_name);
 838         }
 839
 840         # double quotes are needed if specials or CTLs are included
 841         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 842                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 843                 $recipient_name = "\"$recipient_name\"";
 844         }
 845
 846         return "$recipient_name $recipient_addr";
 847
 848 }
 849
 850 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 851 #
 852 # Tightly configured MTAa require that a caller sends a real DNS
 853 # domain name that corresponds the IP address in the HELO/EHLO
 854 # handshake. This is used to verify the connection and prevent
 855 # spammers from trying to hide their identity. If the DNS and IP don't
 856 # match, the receiveing MTA may deny the connection.
 857 #
 858 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 859 #
 860 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 861 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 862 #
 863 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 864 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 865
 866 sub maildomain_net
 867 {
 868         my $maildomain;
 869
 870         if (eval { require Net::Domain; 1 }) {
 871                 my $domain = Net::Domain::domainname();
 872                 $maildomain = $domain
 873                         unless $^O eq 'darwin' && $domain =~ /\.local$/;
 874         }
 875
 876         return $maildomain;
 877 }
 878
 879 sub maildomain_mta
 880 {
 881         my $maildomain;
 882
 883         if (eval { require Net::SMTP; 1 }) {
 884                 for my $host (qw(mailhost localhost)) {
 885                         my $smtp = Net::SMTP->new($host);
 886                         if (defined $smtp) {
 887                                 my $domain = $smtp->domain;
 888                                 $smtp->quit;
 889
 890                                 $maildomain = $domain
 891                                         unless $^O eq 'darwin' && $domain =~ /\.local$/;
 892
 893                                 last if $maildomain;
 894                         }
 895                 }
 896         }
 897
 898         return $maildomain;
 899 }
 900
 901 sub maildomain
 902 {
 903         return maildomain_net() || maildomain_mta() || $mail_domain_default;
 904 }
 905
 906 # Returns 1 if the message was sent, and 0 otherwise.
 907 # In actuality, the whole program dies when there
 908 # is an error sending a message.
 909
 910 sub send_message
 911 {
 912         my @recipients = unique_email_list(@to);
 913         @cc = (grep { my $cc = extract_valid_address($_);
 914                       not grep { $cc eq $_ } @recipients
 915                     }
 916                map { sanitize_address($_) }
 917                @cc);
 918         my $to = join (",\n\t", @recipients);
 919         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 920         @recipients = (map { extract_valid_address($_) } @recipients);
 921         my $date = format_2822_time($time++);
 922         my $gitversion = '@@GIT_VERSION@@';
 923         if ($gitversion =~ m/..GIT_VERSION../) {
 924             $gitversion = Git::version();
 925         }
 926
 927         my $cc = join(",\n\t", unique_email_list(@cc));
 928         my $ccline = "";
 929         if ($cc ne '') {
 930                 $ccline = "\nCc: $cc";
 931         }
 932         my $sanitized_sender = sanitize_address($sender);
 933         make_message_id() unless defined($message_id);
 934
 935         my $header = "From: $sanitized_sender
 936 To: $to${ccline}
 937 Subject: $subject
 938 Date: $date
 939 Message-Id: $message_id
 940 X-Mailer: git-send-email $gitversion
 941 ";
 942         if ($reply_to) {
 943
 944                 $header .= "In-Reply-To: $reply_to\n";
 945                 $header .= "References: $references\n";
 946         }
 947         if (@xh) {
 948                 $header .= join("\n", @xh) . "\n";
 949         }
 950
 951         my @sendmail_parameters = ('-i', @recipients);
 952         my $raw_from = $sanitized_sender;
 953         if (defined $envelope_sender && $envelope_sender ne "auto") {
 954                 $raw_from = $envelope_sender;
 955         }
 956         $raw_from = extract_valid_address($raw_from);
 957         unshift (@sendmail_parameters,
 958                         '-f', $raw_from) if(defined $envelope_sender);
 959
 960         if ($needs_confirm && !$dry_run) {
 961                 print "\n$header\n";
 962                 if ($needs_confirm eq "inform") {
 963                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 964                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 965                         print "    The Cc list above has been expanded by additional\n";
 966                         print "    addresses found in the patch commit message. By default\n";
 967                         print "    send-email prompts before sending whenever this occurs.\n";
 968                         print "    This behavior is controlled by the sendemail.confirm\n";
 969                         print "    configuration setting.\n";
 970                         print "\n";
 971                         print "    For additional information, run 'git send-email --help'.\n";
 972                         print "    To retain the current behavior, but squelch this message,\n";
 973                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 974                 }
 975                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 976                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 977                          default => $ask_default);
 978                 die "Send this email reply required" unless defined $_;
 979                 if (/^n/i) {
 980                         return 0;
 981                 } elsif (/^q/i) {
 982                         cleanup_compose_files();
 983                         exit(0);
 984                 } elsif (/^a/i) {
 985                         $confirm = 'never';
 986                 }
 987         }
 988
 989         if ($dry_run) {
 990                 # We don't want to send the email.
 991         } elsif ($smtp_server =~ m#^/#) {
 992                 my $pid = open my $sm, '|-';
 993                 defined $pid or die $!;
 994                 if (!$pid) {
 995                         exec($smtp_server, @sendmail_parameters) or die $!;
 996                 }
 997                 print $sm "$header\n$message";
 998                 close $sm or die $?;
 999         } else {
1000
1001                 if (!defined $smtp_server) {
1002                         die "The required SMTP server is not properly defined."
1003                 }
1004
1005                 if ($smtp_encryption eq 'ssl') {
1006                         $smtp_server_port ||= 465; # ssmtp
1007                         require Net::SMTP::SSL;
1008                         $mail_domain ||= maildomain();
1009                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1010                                                       Hello => $mail_domain,
1011                                                       Port => $smtp_server_port);
1012                 }
1013                 else {
1014                         require Net::SMTP;
1015                         $mail_domain ||= maildomain();
1016                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1017                                                  ? "$smtp_server:$smtp_server_port"
1018                                                  : $smtp_server,
1019                                                  Hello => $mail_domain,
1020                                                  Debug => $debug_net_smtp);
1021                         if ($smtp_encryption eq 'tls' && $smtp) {
1022                                 require Net::SMTP::SSL;
1023                                 $smtp->command('STARTTLS');
1024                                 $smtp->response();
1025                                 if ($smtp->code == 220) {
1026                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1027                                                 or die "STARTTLS failed! ".$smtp->message;
1028                                         $smtp_encryption = '';
1029                                         # Send EHLO again to receive fresh
1030                                         # supported commands
1031                                         $smtp->hello();
1032                                 } else {
1033                                         die "Server does not support STARTTLS! ".$smtp->message;
1034                                 }
1035                         }
1036                 }
1037
1038                 if (!$smtp) {
1039                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1040                             "VALUES: server=$smtp_server ",
1041                             "encryption=$smtp_encryption ",
1042                             "maildomain=$mail_domain",
1043                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1044                 }
1045
1046                 if (defined $smtp_authuser) {
1047
1048                         if (!defined $smtp_authpass) {
1049
1050                                 system "stty -echo";
1051
1052                                 do {
1053                                         print "Password: ";
1054                                         $_ = <STDIN>;
1055                                         print "\n";
1056                                 } while (!defined $_);
1057
1058                                 chomp($smtp_authpass = $_);
1059
1060                                 system "stty echo";
1061                         }
1062
1063                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1064                 }
1065
1066                 $smtp->mail( $raw_from ) or die $smtp->message;
1067                 $smtp->to( @recipients ) or die $smtp->message;
1068                 $smtp->data or die $smtp->message;
1069                 $smtp->datasend("$header\n$message") or die $smtp->message;
1070                 $smtp->dataend() or die $smtp->message;
1071                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1072         }
1073         if ($quiet) {
1074                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1075         } else {
1076                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1077                 if ($smtp_server !~ m#^/#) {
1078                         print "Server: $smtp_server\n";
1079                         print "MAIL FROM:<$raw_from>\n";
1080                         foreach my $entry (@recipients) {
1081                             print "RCPT TO:<$entry>\n";
1082                         }
1083                 } else {
1084                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1085                 }
1086                 print $header, "\n";
1087                 if ($smtp) {
1088                         print "Result: ", $smtp->code, ' ',
1089                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1090                 } else {
1091                         print "Result: OK\n";
1092                 }
1093         }
1094
1095         return 1;
1096 }
1097
1098 $reply_to = $initial_reply_to;
1099 $references = $initial_reply_to || '';
1100 $subject = $initial_subject;
1101 $message_num = 0;
1102
1103 foreach my $t (@files) {
1104         open(F,"<",$t) or die "can't open file $t";
1105
1106         my $author = undef;
1107         my $author_encoding;
1108         my $has_content_type;
1109         my $body_encoding;
1110         @cc = ();
1111         @xh = ();
1112         my $input_format = undef;
1113         my @header = ();
1114         $message = "";
1115         $message_num++;
1116         # First unfold multiline header fields
1117         while(<F>) {
1118                 last if /^\s*$/;
1119                 if (/^\s+\S/ and @header) {
1120                         chomp($header[$#header]);
1121                         s/^\s+/ /;
1122                         $header[$#header] .= $_;
1123             } else {
1124                         push(@header, $_);
1125                 }
1126         }
1127         # Now parse the header
1128         foreach(@header) {
1129                 if (/^From /) {
1130                         $input_format = 'mbox';
1131                         next;
1132                 }
1133                 chomp;
1134                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1135                         $input_format = 'mbox';
1136                 }
1137
1138                 if (defined $input_format && $input_format eq 'mbox') {
1139                         if (/^Subject:\s+(.*)$/) {
1140                                 $subject = $1;
1141                         }
1142                         elsif (/^From:\s+(.*)$/) {
1143                                 ($author, $author_encoding) = unquote_rfc2047($1);
1144                                 next if $suppress_cc{'author'};
1145                                 next if $suppress_cc{'self'} and $author eq $sender;
1146                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1147                                         $1, $_) unless $quiet;
1148                                 push @cc, $1;
1149                         }
1150                         elsif (/^Cc:\s+(.*)$/) {
1151                                 foreach my $addr (parse_address_line($1)) {
1152                                         if (unquote_rfc2047($addr) eq $sender) {
1153                                                 next if ($suppress_cc{'self'});
1154                                         } else {
1155                                                 next if ($suppress_cc{'cc'});
1156                                         }
1157                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1158                                                 $addr, $_) unless $quiet;
1159                                         push @cc, $addr;
1160                                 }
1161                         }
1162                         elsif (/^Content-type:/i) {
1163                                 $has_content_type = 1;
1164                                 if (/charset="?([^ "]+)/) {
1165                                         $body_encoding = $1;
1166                                 }
1167                                 push @xh, $_;
1168                         }
1169                         elsif (/^Message-Id: (.*)/i) {
1170                                 $message_id = $1;
1171                         }
1172                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1173                                 push @xh, $_;
1174                         }
1175
1176                 } else {
1177                         # In the traditional
1178                         # "send lots of email" format,
1179                         # line 1 = cc
1180                         # line 2 = subject
1181                         # So let's support that, too.
1182                         $input_format = 'lots';
1183                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1184                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1185                                         $_, $_) unless $quiet;
1186                                 push @cc, $_;
1187                         } elsif (!defined $subject) {
1188                                 $subject = $_;
1189                         }
1190                 }
1191         }
1192         # Now parse the message body
1193         while(<F>) {
1194                 $message .=  $_;
1195                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1196                         chomp;
1197                         my ($what, $c) = ($1, $2);
1198                         chomp $c;
1199                         if ($c eq $sender) {
1200                                 next if ($suppress_cc{'self'});
1201                         } else {
1202                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1203                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1204                         }
1205                         push @cc, $c;
1206                         printf("(body) Adding cc: %s from line '%s'\n",
1207                                 $c, $_) unless $quiet;
1208                 }
1209         }
1210         close F;
1211
1212         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1213                 open(F, "$cc_cmd \Q$t\E |")
1214                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1215                 while(<F>) {
1216                         my $c = $_;
1217                         $c =~ s/^\s*//g;
1218                         $c =~ s/\n$//g;
1219                         next if ($c eq $sender and $suppress_from);
1220                         push @cc, $c;
1221                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1222                                 $c, $cc_cmd) unless $quiet;
1223                 }
1224                 close F
1225                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1226         }
1227
1228         if (defined $author and $author ne $sender) {
1229                 $message = "From: $author\n\n$message";
1230                 if (defined $author_encoding) {
1231                         if ($has_content_type) {
1232                                 if ($body_encoding eq $author_encoding) {
1233                                         # ok, we already have the right encoding
1234                                 }
1235                                 else {
1236                                         # uh oh, we should re-encode
1237                                 }
1238                         }
1239                         else {
1240                                 push @xh,
1241                                   'MIME-Version: 1.0',
1242                                   "Content-Type: text/plain; charset=$author_encoding",
1243                                   'Content-Transfer-Encoding: 8bit';
1244                         }
1245                 }
1246         }
1247
1248         $needs_confirm = (
1249                 $confirm eq "always" or
1250                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1251                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1252         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1253
1254         @cc = (@initial_cc, @cc);
1255
1256         my $message_was_sent = send_message();
1257
1258         # set up for the next message
1259         if ($thread && $message_was_sent &&
1260                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1261                 $reply_to = $message_id;
1262                 if (length $references > 0) {
1263                         $references .= "\n $message_id";
1264                 } else {
1265                         $references = "$message_id";
1266                 }
1267         }
1268         $message_id = undef;
1269 }
1270
1271 cleanup_compose_files();
1272
1273 sub cleanup_compose_files() {
1274         unlink($compose_filename, $compose_filename . ".final") if $compose;
1275 }
1276
1277 $smtp->quit if $smtp;
1278
1279 sub unique_email_list(@) {
1280         my %seen;
1281         my @emails;
1282
1283         foreach my $entry (@_) {
1284                 if (my $clean = extract_valid_address($entry)) {
1285                         $seen{$clean} ||= 0;
1286                         next if $seen{$clean}++;
1287                         push @emails, $entry;
1288                 } else {
1289                         print STDERR "W: unable to extract a valid address",
1290                                         " from: $entry\n";
1291                 }
1292         }
1293         return @emails;
1294 }
1295
1296 sub validate_patch {
1297         my $fn = shift;
1298         open(my $fh, '<', $fn)
1299                 or die "unable to open $fn: $!\n";
1300         while (my $line = <$fh>) {
1301                 if (length($line) > 998) {
1302                         return "$.: patch contains a line longer than 998 characters";
1303                 }
1304         }
1305         return undef;
1306 }
1307
1308 sub file_has_nonascii {
1309         my $fn = shift;
1310         open(my $fh, '<', $fn)
1311                 or die "unable to open $fn: $!\n";
1312         while (my $line = <$fh>) {
1313                 return 1 if $line =~ /[^[:ascii:]]/;
1314         }
1315         return 0;
1316 }