hw/mbl_pkg.vhd

   1 ---------------------------------------------------------------------------------
   2 --
   3 --  Package:      mbl_Pkg
   4 --  Filename:     mbl_Pkg.vhd
   5 --  Description:  Package for the TUD MB-Lite implementation
   6 --
   7 --  Author:       Huib Lincklaen Arriens
   8 --                Delft University of Technology
   9 --                Faculty EEMCS, Department ME&CE, Circuits and Systems
  10 --  Date:         September, 2010
  11 --
  12 --  Modified:     September, 2013: Removed FSL, core customization (Meloun)
  13 --                     June, 2011: ALU_ACTION_Type extended to incorporate
  14 --                                 MUL and BS instructions (Huib)
  15 --                                 Adapted to work with separate fsl_M-
  16 --                                 and fsl_S selectors and automatic
  17 --                                 tumbl<_jtag><_fsl>.vhd generation (Huib)
  18 --                     July, 2011: function ef_nbits added (Huib)
  19 --  Remarks:
  20 --
  21 --------------------------------------------------------------------------------
  22
  23 LIBRARY IEEE;
  24 USE IEEE.std_logic_1164.all;
  25 USE IEEE.std_logic_unsigned.all;
  26 USE IEEE.numeric_std.all;
  27
  28 --------------------------------------------------------------------------------
  29 PACKAGE mbl_pkg IS
  30 --------------------------------------------------------------------------------
  31
  32         CONSTANT  C_8_ZEROS : STD_LOGIC_VECTOR ( 7 DOWNTO 0) :=       X"00";
  33         CONSTANT C_16_ZEROS : STD_LOGIC_VECTOR (15 DOWNTO 0) :=     X"0000";
  34         CONSTANT C_24_ZEROS : STD_LOGIC_VECTOR (23 DOWNTO 0) :=   X"000000";
  35         CONSTANT C_32_ZEROS : STD_LOGIC_VECTOR (31 DOWNTO 0) := X"00000000";
  36
  37         CONSTANT C_16_ONES  : STD_LOGIC_VECTOR (15 DOWNTO 0) :=     X"FFFF";
  38         CONSTANT C_24_ONES  : STD_LOGIC_VECTOR (23 DOWNTO 0) :=   X"FFFFFF";
  39
  40
  41 ----------------------------------------------------------------------------------------------
  42 -- TYPE DEFINITIONS
  43 ----------------------------------------------------------------------------------------------
  44
  45         TYPE ALU_ACTION_Type    IS (A_NOP, A_ADD, A_CMP, A_CMPU, A_OR, A_AND, A_XOR,
  46                                     A_SHIFT, A_SEXT8, A_SEXT16, A_MFS, A_MTS, A_MUL,
  47                                     A_BSLL, A_BSRL, A_BSRA, A_CLZ);
  48         TYPE ALU_IN1_Type       IS (ALU_IN_REGA, ALU_IN_NOT_REGA, ALU_IN_PC, ALU_IN_ZERO);
  49         TYPE ALU_IN2_Type       IS (ALU_IN_REGB, ALU_IN_NOT_REGB, ALU_IN_IMM, ALU_IN_NOT_IMM);
  50         TYPE ALU_CIN_Type       IS (CIN_ZERO, CIN_ONE, FROM_MSR, FROM_IN1);
  51         TYPE MSR_ACTION_Type    IS (UPDATE_CARRY, KEEP_CARRY);
  52         TYPE BRANCH_ACTION_Type IS (NO_BR, BR, BRL);
  53         TYPE IT_ACTION_Type     IS (NO_IT, IT, ITT, ITE);
  54         TYPE WRB_ACTION_Type    IS (NO_WRB, WRB_EX, WRB_MEM);
  55         TYPE MEM_ACTION_Type    IS (NO_MEM, WR_MEM, RD_MEM);
  56         TYPE TRANSFER_SIZE_Type IS (WORD, HALFWORD, BYTE);
  57         TYPE SAVE_REG_Type      IS (NO_SAVE, SAVE_RA, SAVE_RB);
  58         TYPE COND_Type          IS (COND_ALL, COND_EQ, COND_NE, COND_LT, COND_LE, COND_GT, COND_GE);
  59         --
  60         TYPE IF2ID_Type IS RECORD
  61                 program_counter : STD_LOGIC_VECTOR (31 DOWNTO 0);
  62         END RECORD;
  63
  64         TYPE ID2EX_Type IS RECORD
  65                 program_counter  : STD_LOGIC_VECTOR (31 DOWNTO 0);
  66                 rdix_rA          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  67                 rdix_rB          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  68                 curr_rD          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  69                 alu_Action       : ALU_ACTION_Type;
  70                 alu_Op1          : ALU_IN1_Type;
  71                 alu_Op2          : ALU_IN2_Type;
  72                 alu_Cin          : ALU_CIN_Type;
  73                 IMM16            : STD_LOGIC_VECTOR (15 DOWNTO 0);
  74                 IMM_Lock         : STD_LOGIC;
  75                 msr_Action       : MSR_ACTION_Type;
  76                 branch_Action    : BRANCH_ACTION_Type;
  77                 it_Action        : IT_ACTION_Type;
  78                 mem_Action       : MEM_ACTION_Type;         -- rd_mem implies writeback
  79                 transfer_Size    : TRANSFER_SIZE_Type;
  80                 wrb_Action       : WRB_ACTION_Type;
  81                 condition        : COND_Type;
  82                 halt             : STD_LOGIC;
  83         END RECORD;
  84
  85         TYPE ID2GPRF_Type IS RECORD
  86                 rdix_rA : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  87                 rdix_rB : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  88                 rdix_rD : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  89         END RECORD;
  90
  91         TYPE INT_CTRL_Type IS RECORD
  92                 setup_int  : STD_LOGIC;
  93                 rti_target : STD_LOGIC_VECTOR (31 DOWNTO 0);
  94                 int_busy   : STD_LOGIC;
  95         END RECORD;
  96
  97         TYPE ID2CTRL_Type IS RECORD
  98                 delayBit : STD_LOGIC;
  99                 int_busy : STD_LOGIC;
 100         END RECORD;
 101
 102         TYPE GPRF2EX_Type IS RECORD
 103                 data_rA : STD_LOGIC_VECTOR (31 DOWNTO 0);
 104                 data_rB : STD_LOGIC_VECTOR (31 DOWNTO 0);
 105                 data_rD : STD_LOGIC_VECTOR (31 DOWNTO 0);
 106         END RECORD;
 107
 108         TYPE IMM_LOCK_Type IS RECORD
 109                 locked   : STD_LOGIC;
 110                 IMM_hi16 : STD_LOGIC_VECTOR (15 DOWNTO 0);
 111         END RECORD;
 112
 113         TYPE MSR_Type IS RECORD
 114                 IE  : STD_LOGIC;        -- MSR[VHDL b1] = [MicroBlaze b30]
 115                 C   : STD_LOGIC;        -- MSR[VHDL b2 and b31] = [MicroBlaze b29 and b0]
 116         END RECORD;
 117
 118         TYPE EX2IF_Type IS RECORD
 119                 take_branch   : STD_LOGIC;
 120                 branch_target : STD_LOGIC_VECTOR (31 DOWNTO 0);
 121         END RECORD;
 122
 123         TYPE EX2CTRL_Type IS RECORD
 124                 flush_first       : STD_LOGIC;
 125                 flush_second      : STD_LOGIC;
 126                 ignore_state      : STD_LOGIC;
 127         END RECORD;
 128
 129         TYPE HALT_Type IS RECORD
 130                 halt          : STD_LOGIC;
 131                 halt_code     : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 132         END RECORD;
 133
 134         TYPE EX2MEM_Type IS RECORD
 135                 mem_Action      : MEM_ACTION_Type;                  -- RD_MEM implies writeback
 136                 wrb_Action      : WRB_ACTION_Type;
 137                 exeq_result     : STD_LOGIC_VECTOR (31 DOWNTO 0);
 138                 data_rD         : STD_LOGIC_VECTOR (31 DOWNTO 0);
 139                 byte_Enable     : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 140                 wrix_rD         : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 141         END RECORD;
 142
 143         TYPE WRB_Type IS RECORD
 144                 wrb_Action : WRB_ACTION_Type;
 145                 wrix_rD    : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 146                 data_rD    : STD_LOGIC_VECTOR (31 DOWNTO 0);
 147         END RECORD;
 148
 149         TYPE HAZARD_WRB_Type IS RECORD
 150                 hazard  : STD_LOGIC;
 151                 save_rX : SAVE_REG_Type;
 152                 data_rX : STD_LOGIC_VECTOR (31 DOWNTO 0);
 153                 data_rD : STD_LOGIC_VECTOR (31 DOWNTO 0);
 154         END RECORD;
 155
 156         TYPE MEM_REG_Type IS RECORD
 157                 wrb_Action  : WRB_ACTION_Type;
 158                 exeq_result : STD_LOGIC_VECTOR (31 DOWNTO 0);
 159                 byte_Enable : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 160                 wrix_rD     : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 161         END RECORD;
 162
 163         TYPE MEM2CTRL_Type IS RECORD
 164                 bus_taken   : STD_LOGIC;
 165                 bus_wait    : STD_LOGIC;
 166                 int         : STD_LOGIC;
 167         END RECORD;
 168
 169         TYPE CORE2DMEMB_Type IS RECORD
 170                 rd    : STD_LOGIC;
 171                 addr  : STD_LOGIC_VECTOR (14 DOWNTO 0); -- 64 kB space is more than enough
 172                 bls   : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 173                 data  : STD_LOGIC_VECTOR (31 DOWNTO 0);
 174         END RECORD;
 175
 176         TYPE DMEMB2CORE_Type IS RECORD
 177                 bus_taken   : STD_LOGIC;
 178                 bus_wait    : STD_LOGIC;
 179                 data  : STD_LOGIC_VECTOR (31 DOWNTO 0);
 180                 int   : STD_LOGIC;
 181         END RECORD;
 182
 183         TYPE MEMORY_MAP_Type IS ARRAY(NATURAL RANGE <>) OF STD_LOGIC_VECTOR (31 DOWNTO 0);
 184         -- NOTE: Use the named association format  xxxx := ( 0 => X"A0010000" );
 185         --       in case the array has to contain only one element !!
 186
 187 ----------------------------------------------------------------------------------------------
 188 -- COMPONENTS
 189 ----------------------------------------------------------------------------------------------
 190
 191         COMPONENT fetch IS
 192         PORT
 193         (
 194                 prog_cntr_i :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 195                 inc_pc_i    :  IN STD_LOGIC;
 196                 EX2IF_i     :  IN EX2IF_Type;
 197                 IF2ID_o     : OUT IF2ID_Type
 198         );
 199         END COMPONENT;
 200
 201         COMPONENT decode IS
 202         GENERIC
 203         (
 204                 USE_HW_MUL_g : BOOLEAN := TRUE;
 205                 USE_BARREL_g : BOOLEAN := TRUE;
 206                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 207         );
 208         PORT
 209         (
 210                 IF2ID_i     :  IN IF2ID_Type;
 211                 imem_data_i :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 212                 --
 213                 ID2GPRF_o   : OUT ID2GPRF_Type;
 214                 ID2EX_o     : OUT ID2EX_Type;
 215                 --
 216                 INT_CTRL_i  :  IN INT_CTRL_Type;
 217                 ID2CTRL_o   : OUT ID2CTRL_Type
 218         );
 219         END COMPONENT;
 220
 221         COMPONENT exeq IS
 222         GENERIC
 223         (
 224                 USE_HW_MUL_g : BOOLEAN := FALSE;
 225                 USE_BARREL_g : BOOLEAN := FALSE;
 226                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 227         );
 228         PORT
 229         (
 230                 IF2ID_i      :  IN IF2ID_Type;
 231                 --
 232                 ID2EX_i      :  IN ID2EX_Type;
 233                 delayBit_i   :  IN STD_LOGIC;
 234                 GPRF2EX_i    :  IN GPRF2EX_Type;
 235                 EX2IF_o      : OUT EX2IF_Type;
 236                 EX2CTRL_o    : OUT EX2CTRL_Type;
 237                 HALT_o       : OUT HALT_Type;
 238                 --
 239                 EX_WRB_i     :  IN WRB_Type;
 240                 EX_WRB_o     : OUT WRB_Type;
 241                 MEM_WRB_i    :  IN WRB_Type;
 242                 --
 243                 HAZARD_WRB_i :  IN HAZARD_WRB_Type;
 244                 HAZARD_WRB_o : OUT HAZARD_WRB_Type;
 245                 --
 246                 IMM_LOCK_i   :  IN IMM_LOCK_Type;
 247                 IMM_LOCK_o   : OUT IMM_LOCK_Type;
 248                 --
 249                 MSR_i        :  IN MSR_Type;
 250                 MSR_o        : OUT MSR_Type;
 251                 --
 252                 EX2MEM_o     : OUT EX2MEM_Type
 253         );
 254         END COMPONENT;
 255
 256         COMPONENT mem IS
 257         PORT
 258         (
 259                 EX2MEM_i    :  IN EX2MEM_Type;
 260                 --
 261                 DMEMB_i     :  IN DMEMB2CORE_Type;
 262                 DMEMB_o     : OUT CORE2DMEMB_Type;
 263                 --
 264                 MEM_REG_i   :  IN MEM_REG_Type;
 265                 MEM_REG_o   : OUT MEM_REG_Type;
 266                 --
 267                 MEM_WRB_o   : OUT WRB_Type;
 268                 MEM2CTRL_o  : OUT MEM2CTRL_Type
 269         );
 270         END COMPONENT;
 271
 272         COMPONENT core_ctrl IS
 273         GENERIC
 274         (
 275                 IMEM_ABITS_g         : positive := 9;
 276                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 277         );
 278         PORT
 279         (
 280                 clk_i           :  IN STD_LOGIC;
 281                 rst_i           :  IN STD_LOGIC;
 282                 halt_i          :  IN STD_LOGIC;
 283                 int_i           :  IN STD_LOGIC;
 284                 trace_i         :  IN STD_LOGIC;
 285                 trace_kick_i    :  IN STD_LOGIC;
 286                 core_clken_o    : OUT STD_LOGIC;
 287                 -- specific fetch i/o
 288                 imem_addr_o     : OUT STD_LOGIC_VECTOR ((IMEM_ABITS_g-1) DOWNTO 0);
 289                 imem_clken_o    : OUT STD_LOGIC;
 290                 pc_ctrl_o       : OUT STD_LOGIC;
 291                 -- fetch to decode pipeline registers
 292                 IF2ID_REG_i     :  IN IF2ID_Type;
 293                 IF2ID_REG_o     : OUT IF2ID_Type;
 294                 -- decode to exeq pipeline registers
 295                 ID2EX_REG_i     :  IN ID2EX_Type;
 296                 ID2EX_REG_o     : OUT ID2EX_Type;
 297                 delay_bit_o     : OUT STD_LOGIC;
 298                 -- GPRF control
 299                 gprf_clken_o    : OUT STD_LOGIC;
 300                 -- exeq to fetch feedback registers
 301                 EX2IF_REG_i     :  IN EX2IF_Type;
 302                 EX2IF_REG_o     : OUT EX2IF_Type;
 303                 EX2CTRL_REG_i   :  IN EX2CTRL_Type;
 304                 -- exeq to core (halting)
 305                 exeq_halt_i     :  IN STD_LOGIC;
 306                 -- exeq to mem pipeline registers
 307                 EX2MEM_REG_i    :  IN EX2MEM_Type;
 308                 EX2MEM_REG_o    : OUT EX2MEM_Type;
 309                 -- mem pipeline register
 310                 MEM_REG_i       :  IN MEM_REG_Type;
 311                 MEM_REG_o       : OUT MEM_REG_Type;
 312                 -- decode control i/o
 313                 ID2CTRL_i       :  IN ID2CTRL_Type;
 314                 INT_CTRL_o      : OUT INT_CTRL_Type;
 315                 -- exeq control i/o
 316                 EX_WRB_i        :  IN WRB_Type;
 317                 EX_WRB_o        : OUT WRB_Type;
 318                 -- data hazard i/o
 319                 HAZARD_WRB_i    :  IN HAZARD_WRB_Type;
 320                 HAZARD_WRB_o    : OUT HAZARD_WRB_Type;
 321                 -- for handling the 'IMM' instruction
 322                 IMM_LOCK_i      :  IN IMM_LOCK_Type;
 323                 IMM_LOCK_o      : OUT IMM_LOCK_Type;
 324                 -- for handling the Machine Status Register
 325                 MSR_i           :  IN MSR_Type;
 326                 MSR_o           : OUT MSR_Type;
 327                 -- miscellaneous
 328                 MEM2CTRL_i      :  IN MEM2CTRL_Type
 329         );
 330         END COMPONENT;
 331
 332 ----------------------------------------------------------------------------------------------
 333 -- FUNCTION, PROCEDURE DECLARATIONS
 334 ----------------------------------------------------------------------------------------------
 335
 336         PROCEDURE ep_add32 (    a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 337                                                                                                 ci   :  IN STD_LOGIC;
 338                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0);
 339                                                                                         VARIABLE co : OUT STD_LOGIC );
 340
 341         PROCEDURE ep_add32nc (  a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 342                                                                                                         ci   :  IN STD_LOGIC;
 343                                                                                                 VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0));
 344
 345         PROCEDURE leading_zeroes32( m : IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 346                                     n : IN UNSIGNED;
 347                                VARIABLE r : OUT STD_LOGIC_VECTOR (31 DOWNTO 0) );
 348
 349         FUNCTION ef_nbits ( value : NATURAL ) RETURN POSITIVE;
 350
 351 END PACKAGE mbl_pkg;
 352
 353 ----------------------------------------------------------
 354 PACKAGE BODY mbl_pkg IS
 355 ----------------------------------------------------------
 356
 357         PROCEDURE ep_add32 (    a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 358                                                                                                 ci   :  IN STD_LOGIC;
 359                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0);
 360                                                                                         VARIABLE co : OUT STD_LOGIC ) IS
 361
 362                 CONSTANT NBITS_LO_c : POSITIVE := 17;
 363                 CONSTANT NBITS_HI_c : POSITIVE := 32 -NBITS_LO_c;
 364                 VARIABLE tmp_lo_v   : STD_LOGIC_VECTOR (NBITS_LO_c +1 DOWNTO 0);
 365                 VARIABLE tmp_hi0_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 366                 VARIABLE tmp_hi1_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 367         BEGIN
 368                 tmp_lo_v  := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(NBITS_LO_c -1 DOWNTO  0) & '1' ) +
 369                                                                                                                                                 UNSIGNED( '0' & b(NBITS_LO_c -1 DOWNTO  0) & ci  ));
 370                 tmp_hi0_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 371                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '0'));
 372                 tmp_hi1_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 373                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '1'));
 374                 IF (tmp_lo_v(NBITS_LO_c +1) = '0') THEN
 375                         s  := tmp_hi0_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 376                         co := tmp_hi0_v(NBITS_HI_c +1);
 377                 ELSE
 378                         s  := tmp_hi1_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 379                         co := tmp_hi1_v(NBITS_HI_c +1);
 380                 END IF;
 381         END PROCEDURE;
 382
 383     PROCEDURE ep_add32nc (      a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 384                                                                                                                 ci   :  IN STD_LOGIC;
 385                                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0) ) IS
 386
 387                 CONSTANT NBITS_LO_c : POSITIVE := 17;
 388                 CONSTANT NBITS_HI_c : POSITIVE := 32 -NBITS_LO_c;
 389                 VARIABLE tmp_lo_v   : STD_LOGIC_VECTOR (NBITS_LO_c +1 DOWNTO 0);
 390                 VARIABLE tmp_hi0_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 391                 VARIABLE tmp_hi1_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 392         BEGIN
 393                 tmp_lo_v  := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(NBITS_LO_c -1 DOWNTO  0) & '1' ) +
 394                                                                                                                                                 UNSIGNED( '0' & b(NBITS_LO_c -1 DOWNTO  0) & ci  ));
 395                 tmp_hi0_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 396                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '0'));
 397                 tmp_hi1_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 398                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '1'));
 399                 IF (tmp_lo_v(NBITS_LO_c +1) = '0') THEN
 400                         s  := tmp_hi0_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 401                 ELSE
 402                         s  := tmp_hi1_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 403                 END IF;
 404         END PROCEDURE;
 405
 406         PROCEDURE leading_zeroes32( m : IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 407                                     n : IN UNSIGNED;
 408                                VARIABLE r : OUT STD_LOGIC_VECTOR (31 DOWNTO 0) ) IS
 409         BEGIN
 410                 -- It would be easier if it could be generated, but it's a sequence
 411                 IF ( m(31) = '1' ) THEN
 412                   r := STD_LOGIC_VECTOR ( n );
 413                 ELSE
 414                   leading_zeroes32 ( m (30 DOWNTO 0) & '1', UNSIGNED (n + 1), r);
 415                 END IF;
 416
 417         END PROCEDURE leading_zeroes32;
 418
 419         FUNCTION ef_nbits ( value : NATURAL ) RETURN POSITIVE IS
 420                 VARIABLE temp_v : POSITIVE;
 421         BEGIN
 422                 temp_v := 1;
 423                 FOR i IN 1 TO INTEGER'HIGH LOOP
 424                         temp_v := 2*temp_v;
 425                         IF (temp_v > value) THEN
 426                                 RETURN i;
 427                         END IF;
 428                 END LOOP;
 429                 RETURN 32;
 430         END FUNCTION;
 431
 432 END PACKAGE BODY mbl_pkg;