configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libbacktrace \
 156                 target-libgloss \
 157                 target-newlib \
 158                 target-libgomp \
 159                 target-libatomic \
 160                 target-libitm \
 161                 target-libstdc++-v3 \
 162                 target-libmudflap \
 163                 target-libssp \
 164                 target-libquadmath \
 165                 target-libgfortran \
 166                 target-boehm-gc \
 167                 ${libgcj} \
 168                 target-libobjc \
 169                 target-libada \
 170                 target-libgo"
 171
 172 # these tools are built using the target libraries, and are intended to
 173 # run only in the target environment
 174 #
 175 # note: any program that *uses* libraries that are in the "target_libraries"
 176 # list belongs in this list.
 177 #
 178 target_tools="target-rda"
 179
 180 ################################################################################
 181
 182 ## All tools belong in one of the four categories, and are assigned above
 183 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 184 ## is important because configure will choke if they ever get through.
 185 ## ${configdirs} is directories we build using the host tools.
 186 ## ${target_configdirs} is directories we build using the target tools.
 187 configdirs=`echo ${host_libs} ${host_tools}`
 188 target_configdirs=`echo ${target_libraries} ${target_tools}`
 189 build_configdirs=`echo ${build_libs} ${build_tools}`
 190
 191 m4_divert_text([PARSE_ARGS],
 192 [case $srcdir in
 193   *" "*)
 194 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 195     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 196 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 197     ;;
 198 esac
 199 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 200 ])
 201
 202 ################################################################################
 203
 204 srcname="gnu development package"
 205
 206 # This gets set non-empty for some net releases of packages.
 207 appdirs=""
 208
 209 # Define is_cross_compiler to save on calls to 'test'.
 210 is_cross_compiler=
 211 if test x"${host}" = x"${target}" ; then
 212   is_cross_compiler=no
 213 else
 214   is_cross_compiler=yes
 215 fi
 216
 217 # Find the build and target subdir names.
 218 GCC_TOPLEV_SUBDIRS
 219 # Be sure to cover against remnants of an in-tree build.
 220 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 221   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 222 Use a pristine source tree when building in a separate tree])
 223 fi
 224
 225 # Skipdirs are removed silently.
 226 skipdirs=
 227 # Noconfigdirs are removed loudly.
 228 noconfigdirs=""
 229
 230 use_gnu_ld=
 231 # Make sure we don't let GNU ld be added if we didn't want it.
 232 if test x$with_gnu_ld = xno ; then
 233   use_gnu_ld=no
 234   noconfigdirs="$noconfigdirs ld gold"
 235 fi
 236
 237 use_gnu_as=
 238 # Make sure we don't let GNU as be added if we didn't want it.
 239 if test x$with_gnu_as = xno ; then
 240   use_gnu_as=no
 241   noconfigdirs="$noconfigdirs gas"
 242 fi
 243
 244 use_included_zlib=
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 # Handle --enable-gold, --enable-ld.
 288 # --disable-gold [--enable-ld]
 289 #     Build only ld.  Default option.
 290 # --enable-gold [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 292 #     as "ld.bfd" and "ld".
 293 # --enable-gold=default [--enable-ld]
 294 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 295 #     install ld as "ld.bfd".
 296 # --enable-gold[=default] --disable-ld
 297 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 298 # --enable-gold --enable-ld=default
 299 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 300 #     and ld.bfd).
 301 #     In other words, ld is default
 302 # --enable-gold=default --enable-ld=default
 303 #     Error.
 304
 305 default_ld=
 306 AC_ARG_ENABLE(gold,
 307 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 308                 [build gold @<:@ARG={default,yes,no}@:>@])],
 309 ENABLE_GOLD=$enableval,
 310 ENABLE_GOLD=no)
 311 case "${ENABLE_GOLD}" in
 312   yes|default)
 313     # Check for ELF target.
 314     is_elf=no
 315     case "${target}" in
 316       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 317       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 318       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 319       | *-*-solaris2* | *-*-nto*)
 320         case "${target}" in
 321           *-*-linux*aout* | *-*-linux*oldld*)
 322             ;;
 323           *)
 324             is_elf=yes
 325             ;;
 326         esac
 327     esac
 328
 329     if test "$is_elf" = "yes"; then
 330       # Check for target supported by gold.
 331       case "${target}" in
 332         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*)
 333           configdirs="$configdirs gold"
 334           if test x${ENABLE_GOLD} = xdefault; then
 335             default_ld=gold
 336           fi
 337           ENABLE_GOLD=yes
 338           ;;
 339       esac
 340     fi
 341     ;;
 342   no)
 343     ;;
 344   *)
 345     AC_MSG_ERROR([invalid --enable-gold argument])
 346     ;;
 347 esac
 348
 349 AC_ARG_ENABLE(ld,
 350 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 351                 [build ld @<:@ARG={default,yes,no}@:>@])],
 352 ENABLE_LD=$enableval,
 353 ENABLE_LD=yes)
 354
 355 case "${ENABLE_LD}" in
 356   default)
 357     if test x${default_ld} != x; then
 358       AC_MSG_ERROR([either gold or ld can be the default ld])
 359     fi
 360     ;;
 361   yes)
 362     ;;
 363   no)
 364     if test x${ENABLE_GOLD} != xyes; then
 365       AC_MSG_WARN([neither ld nor gold are enabled])
 366     fi
 367     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 368     ;;
 369   *)
 370     AC_MSG_ERROR([invalid --enable-ld argument])
 371     ;;
 372 esac
 373
 374 # Configure extra directories which are host specific
 375
 376 case "${host}" in
 377   *-cygwin*)
 378     configdirs="$configdirs libtermcap" ;;
 379 esac
 380
 381 # A target can indicate whether a language isn't supported for some reason.
 382 # Only spaces may be used in this macro; not newlines or tabs.
 383 unsupported_languages=
 384
 385 # Remove more programs from consideration, based on the host or
 386 # target this usually means that a port of the program doesn't
 387 # exist yet.
 388
 389 case "${host}" in
 390   i[[3456789]]86-*-msdosdjgpp*)
 391     noconfigdirs="$noconfigdirs tcl tk itcl"
 392     ;;
 393 esac
 394
 395
 396 AC_ARG_ENABLE(libquadmath,
 397 AS_HELP_STRING([--disable-libquadmath],
 398   [do not build libquadmath directory]),
 399 ENABLE_LIBQUADMATH=$enableval,
 400 ENABLE_LIBQUADMATH=yes)
 401 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 402   noconfigdirs="$noconfigdirs target-libquadmath"
 403 fi
 404
 405
 406 AC_ARG_ENABLE(libquadmath-support,
 407 AS_HELP_STRING([--disable-libquadmath-support],
 408   [disable libquadmath support for Fortran]),
 409 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 410 ENABLE_LIBQUADMATH_SUPPORT=yes)
 411 enable_libquadmath_support=
 412 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 413   enable_libquadmath_support=no
 414 fi
 415
 416
 417 AC_ARG_ENABLE(libada,
 418 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 419 ENABLE_LIBADA=$enableval,
 420 ENABLE_LIBADA=yes)
 421 if test "${ENABLE_LIBADA}" != "yes" ; then
 422   noconfigdirs="$noconfigdirs gnattools"
 423 fi
 424
 425 AC_ARG_ENABLE(libssp,
 426 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 427 ENABLE_LIBSSP=$enableval,
 428 ENABLE_LIBSSP=yes)
 429
 430 # Save it here so that, even in case of --enable-libgcj, if the Java
 431 # front-end isn't enabled, we still get libgcj disabled.
 432 libgcj_saved=$libgcj
 433 case $enable_libgcj in
 434 yes)
 435   # If we reset it here, it won't get added to noconfigdirs in the
 436   # target-specific build rules, so it will be forcibly enabled
 437   # (unless the Java language itself isn't enabled).
 438   libgcj=
 439   ;;
 440 no)
 441   # Make sure we get it printed in the list of not supported target libs.
 442   # Don't disable libffi, though, other languages use it.
 443   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 444   # Clear libgcj_saved so that even if java is enabled libffi won't be
 445   # built.
 446   libgcj_saved=
 447   ;;
 448 esac
 449
 450 AC_ARG_ENABLE(static-libjava,
 451 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 452                 [build static libjava @<:@default=no@:>@])],
 453 ENABLE_STATIC_LIBJAVA=$enableval,
 454 ENABLE_STATIC_LIBJAVA=no)
 455 enable_static_libjava=
 456 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 457   enable_static_libjava=yes
 458 fi
 459
 460 if test x$enable_static_libjava != xyes ; then
 461   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 462 fi
 463 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 464
 465 # Disable libmudflap on some systems.
 466 if test x$enable_libmudflap = x ; then
 467     case "${target}" in
 468     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 469         # Enable libmudflap by default in GNU and friends.
 470         ;;
 471     *-*-freebsd*)
 472         # Enable libmudflap by default in FreeBSD.
 473         ;;
 474     *)
 475         # Disable it by default everywhere else.
 476         noconfigdirs="$noconfigdirs target-libmudflap"
 477         ;;
 478     esac
 479 fi
 480
 481 # Disable libgomp on non POSIX hosted systems.
 482 if test x$enable_libgomp = x ; then
 483     # Enable libgomp by default on hosted POSIX systems.
 484     case "${target}" in
 485     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 486         ;;
 487     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 488         ;;
 489     *-*-solaris2* | *-*-hpux11*)
 490         ;;
 491     *-*-darwin* | *-*-aix*)
 492         ;;
 493     *)
 494         noconfigdirs="$noconfigdirs target-libgomp"
 495         ;;
 496     esac
 497 fi
 498
 499 # Disable libatomic on unsupported systems.
 500 if test -d ${srcdir}/libatomic; then
 501     if test x$enable_libatomic = x; then
 502         AC_MSG_CHECKING([for libatomic support])
 503         if (srcdir=${srcdir}/libatomic; \
 504                 . ${srcdir}/configure.tgt; \
 505                 test -n "$UNSUPPORTED")
 506         then
 507             AC_MSG_RESULT([no])
 508             noconfigdirs="$noconfigdirs target-libatomic"
 509         else
 510             AC_MSG_RESULT([yes])
 511         fi
 512     fi
 513 fi
 514
 515 # Disable libitm on unsupported systems.
 516 if test -d ${srcdir}/libitm; then
 517     if test x$enable_libitm = x; then
 518         AC_MSG_CHECKING([for libitm support])
 519         if (srcdir=${srcdir}/libitm; \
 520                 . ${srcdir}/configure.tgt; \
 521                 test -n "$UNSUPPORTED")
 522         then
 523             AC_MSG_RESULT([no])
 524             noconfigdirs="$noconfigdirs target-libitm"
 525         else
 526             AC_MSG_RESULT([yes])
 527         fi
 528     fi
 529 fi
 530
 531 # Disable libquadmath for some systems.
 532 case "${target}" in
 533   # libquadmath is unused on AIX and libquadmath build process use of
 534   # LD_LIBRARY_PATH can break AIX bootstrap.
 535   powerpc-*-aix* | rs6000-*-aix*)
 536     noconfigdirs="$noconfigdirs target-libquadmath"
 537     ;;
 538 esac
 539
 540 # Disable libssp for some systems.
 541 case "${target}" in
 542   avr-*-*)
 543     # No hosted I/O support.
 544     noconfigdirs="$noconfigdirs target-libssp"
 545     ;;
 546   powerpc-*-aix* | rs6000-*-aix*)
 547     noconfigdirs="$noconfigdirs target-libssp"
 548     ;;
 549   rl78-*-*)
 550     # libssp uses a misaligned load to trigger a fault, but the RL78
 551     # doesn't fault for those - instead, it gives a build-time error
 552     # for explicit misaligned loads.
 553     noconfigdirs="$noconfigdirs target-libssp"
 554     ;;
 555 esac
 556
 557 # Disable libquadmath for some systems.
 558 case "${target}" in
 559   avr-*-*)
 560     noconfigdirs="$noconfigdirs target-libquadmath"
 561     ;;
 562 esac
 563
 564 # Disable libstdc++-v3 for some systems.
 565 case "${target}" in
 566   *-*-vxworks*)
 567     # VxWorks uses the Dinkumware C++ library.
 568     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 569     ;;
 570   arm*-wince-pe*)
 571     # the C++ libraries don't build on top of CE's C libraries
 572     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 573     ;;
 574   avr-*-*)
 575     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 576     ;;
 577 esac
 578
 579 # Disable Fortran for some systems.
 580 case "${target}" in
 581   mmix-*-*)
 582     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 583     unsupported_languages="$unsupported_languages fortran"
 584     ;;
 585 esac
 586
 587 # Disable Java if libffi is not supported.
 588 case "${target}" in
 589   alpha*-*-*)
 590     ;;
 591   arm*-*-*)
 592     ;;
 593   cris-*-*)
 594     ;;
 595   frv-*-*)
 596     ;;
 597   hppa*-*-linux*)
 598     ;;
 599   hppa*-*-hpux*)
 600     ;;
 601   i?86-*-*)
 602     ;;
 603   ia64*-*-*)
 604     ;;
 605   m32r*-*-*)
 606     ;;
 607   m68k-*-*)
 608     ;;
 609   mips*-*-rtems*)
 610     ;;
 611   mips*-*-linux*)
 612     ;;
 613   powerpc*-*-linux*)
 614     ;;
 615   powerpc-*-darwin*)
 616     ;;
 617   powerpc-*-aix* | rs6000-*-aix*)
 618     ;;
 619   powerpc-*-freebsd*)
 620     ;;
 621   powerpc64-*-freebsd*)
 622     ;;
 623   powerpc*-*-rtems*)
 624     ;;
 625   s390-*-* | s390x-*-*)
 626     ;;
 627   sh-*-* | sh[[34]]*-*-*)
 628     ;;
 629   sh64-*-* | sh5*-*-*)
 630     ;;
 631   sparc*-*-*)
 632     ;;
 633   x86_64-*-*)
 634     ;;
 635   *-*-*)
 636     unsupported_languages="$unsupported_languages java"
 637     ;;
 638 esac
 639
 640 # Disable Java, libgcj or related libraries for some systems.
 641 case "${target}" in
 642   powerpc-*-darwin*)
 643     ;;
 644   i[[3456789]]86-*-darwin*)
 645     ;;
 646   x86_64-*-darwin[[912]]*)
 647     ;;
 648   *-*-darwin*)
 649     noconfigdirs="$noconfigdirs ${libgcj}"
 650     ;;
 651   *-*-netware*)
 652     noconfigdirs="$noconfigdirs ${libgcj}"
 653     ;;
 654   *-*-rtems*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   *-*-tpf*)
 658     noconfigdirs="$noconfigdirs ${libgcj}"
 659     ;;
 660   *-*-uclinux*)
 661     noconfigdirs="$noconfigdirs ${libgcj}"
 662     ;;
 663   *-*-vxworks*)
 664     noconfigdirs="$noconfigdirs ${libgcj}"
 665     ;;
 666   alpha*-*-*vms*)
 667     noconfigdirs="$noconfigdirs ${libgcj}"
 668     ;;
 669   arm-wince-pe)
 670     noconfigdirs="$noconfigdirs ${libgcj}"
 671     ;;
 672   arm*-*-symbianelf*)
 673     noconfigdirs="$noconfigdirs ${libgcj}"
 674     ;;
 675   bfin-*-*)
 676     noconfigdirs="$noconfigdirs target-boehm-gc"
 677     ;;
 678   cris-*-* | crisv32-*-*)
 679     unsupported_languages="$unsupported_languages java"
 680     case "${target}" in
 681       *-*-linux*)
 682         ;;
 683       *) # See PR46792 regarding target-libffi.
 684         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 685     esac
 686     ;;
 687   hppa*64*-*-linux*)
 688     # In this case, it's because the hppa64-linux target is for
 689     # the kernel only at this point and has no libc, and thus no
 690     # headers, crt*.o, etc., all of which are needed by these.
 691     unsupported_languages="$unsupported_languages java"
 692     ;;
 693   hppa*64*-*-hpux*)
 694     noconfigdirs="$noconfigdirs ${libgcj}"
 695     ;;
 696   hppa*-hp-hpux11*)
 697     ;;
 698   hppa*-*-hpux*)
 699     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 700     # build on HP-UX 10.20.
 701     noconfigdirs="$noconfigdirs ${libgcj}"
 702     ;;
 703   ia64*-*-*vms*)
 704     noconfigdirs="$noconfigdirs ${libgcj}"
 705     ;;
 706   i[[3456789]]86-w64-mingw*)
 707     noconfigdirs="$noconfigdirs ${libgcj}"
 708     ;;
 709   i[[3456789]]86-*-mingw*)
 710     noconfigdirs="$noconfigdirs ${libgcj}"
 711     ;;
 712   x86_64-*-mingw*)
 713     noconfigdirs="$noconfigdirs ${libgcj}"
 714     ;;
 715   mmix-*-*)
 716     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 717     ;;
 718   powerpc-*-aix*)
 719     # copied from rs6000-*-* entry
 720     noconfigdirs="$noconfigdirs ${libgcj}"
 721     ;;
 722   rs6000-*-aix*)
 723     noconfigdirs="$noconfigdirs ${libgcj}"
 724     ;;
 725   *-*-lynxos*)
 726     noconfigdirs="$noconfigdirs ${libgcj}"
 727     ;;
 728 esac
 729
 730 # Default libgloss CPU subdirectory.
 731 libgloss_dir="$target_cpu"
 732
 733 case "${target}" in
 734   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 735     libgloss_dir=wince
 736     ;;
 737   arm*-*-*)
 738     libgloss_dir=arm
 739     ;;
 740   cris-*-* | crisv32-*-*)
 741     libgloss_dir=cris
 742     ;;
 743   hppa*-*-*)
 744     libgloss_dir=pa
 745     ;;
 746   i[[3456789]]86-*-*)
 747     libgloss_dir=i386
 748     ;;
 749   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 750     libgloss_dir=m68hc11
 751     ;;
 752   m68*-*-* | fido-*-*)
 753     libgloss_dir=m68k
 754     ;;
 755   mips*-*-*)
 756     libgloss_dir=mips
 757     ;;
 758   powerpc*-*-*)
 759     libgloss_dir=rs6000
 760     ;;
 761   sparc*-*-*)
 762     libgloss_dir=sparc
 763     ;;
 764 esac
 765
 766 # Disable newlib and libgloss for various target OSes.
 767 case "${target}" in
 768   alpha*-dec-osf*)
 769     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 770     ;;
 771   i[[3456789]]86-*-linux*)
 772     # This section makes it possible to build newlib natively on linux.
 773     # If we are using a cross compiler then don't configure newlib.
 774     if test x${is_cross_compiler} != xno ; then
 775       noconfigdirs="$noconfigdirs target-newlib"
 776     fi
 777     noconfigdirs="$noconfigdirs target-libgloss"
 778     # If we are not using a cross compiler, do configure newlib.
 779     # Note however, that newlib will only be configured in this situation
 780     # if the --with-newlib option has been given, because otherwise
 781     # 'target-newlib' will appear in skipdirs.
 782     ;;
 783   i[[3456789]]86-*-rdos*)
 784     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 785     ;;
 786   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 787     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 788     ;;
 789   sparc-*-sunos4*)
 790     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 791     ;;
 792   *-*-aix*)
 793     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 794     ;;
 795   *-*-beos*)
 796     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 797     ;;
 798   *-*-chorusos)
 799     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 800     ;;
 801   *-*-dragonfly*)
 802     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 803     ;;
 804   *-*-freebsd*)
 805     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 806     ;;
 807   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 808     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 809     ;;
 810   *-*-lynxos*)
 811     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 812     ;;
 813   *-*-mingw*)
 814     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 815     ;;
 816   *-*-netbsd*)
 817     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 818     ;;
 819   *-*-netware*)
 820     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 821     ;;
 822   *-*-tpf*)
 823     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 824     ;;
 825   *-*-uclinux*)
 826     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 827     ;;
 828   *-*-vxworks*)
 829     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 830     ;;
 831 esac
 832
 833 case "${target}" in
 834   *-*-chorusos)
 835     ;;
 836   powerpc-*-darwin*)
 837     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 838     noconfigdirs="$noconfigdirs sim target-rda"
 839     ;;
 840   i[[3456789]]86-*-darwin*)
 841     noconfigdirs="$noconfigdirs ld gprof"
 842     noconfigdirs="$noconfigdirs sim target-rda"
 843     ;;
 844   x86_64-*-darwin[[912]]*)
 845     noconfigdirs="$noconfigdirs ld gas gprof"
 846     noconfigdirs="$noconfigdirs sim target-rda"
 847     ;;
 848   *-*-darwin*)
 849     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 850     noconfigdirs="$noconfigdirs sim target-rda"
 851     ;;
 852   *-*-dragonfly*)
 853     ;;
 854   *-*-freebsd*)
 855     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 856         && test -f /usr/local/include/gmp.h; then
 857       with_gmp=/usr/local
 858     fi
 859     ;;
 860   *-*-kaos*)
 861     # Remove unsupported stuff on all kaOS configurations.
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     ;;
 864   *-*-netbsd*)
 865     ;;
 866   *-*-netware*)
 867     ;;
 868   *-*-rtems*)
 869     noconfigdirs="$noconfigdirs target-libgloss"
 870     ;;
 871     # The tpf target doesn't support gdb yet.
 872   *-*-tpf*)
 873     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 874     ;;
 875   *-*-uclinux*)
 876     noconfigdirs="$noconfigdirs target-rda"
 877     ;;
 878   *-*-vxworks*)
 879     ;;
 880   alpha*-dec-osf*)
 881     # ld works, but does not support shared libraries.
 882     # gas doesn't generate exception information.
 883     noconfigdirs="$noconfigdirs gas ld"
 884     ;;
 885   alpha*-*-*vms*)
 886     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 887     ;;
 888   alpha*-*-*)
 889     # newlib is not 64 bit ready
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 893     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 894     ;;
 895   arc-*-*)
 896     noconfigdirs="$noconfigdirs target-libgloss"
 897     ;;
 898   arm-*-pe*)
 899     noconfigdirs="$noconfigdirs target-libgloss"
 900     ;;
 901   arm-*-riscix*)
 902     noconfigdirs="$noconfigdirs ld target-libgloss"
 903     ;;
 904   avr-*-rtems*)
 905     ;;
 906   avr-*-*)
 907     if test x${with_avrlibc} != xno; then
 908       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     fi
 910     ;;
 911   c4x-*-* | tic4x-*-*)
 912     noconfigdirs="$noconfigdirs target-libgloss"
 913     ;;
 914   tic54x-*-*)
 915     noconfigdirs="$noconfigdirs target-libgloss gdb"
 916     ;;
 917   d10v-*-*)
 918     noconfigdirs="$noconfigdirs target-libgloss"
 919     ;;
 920   d30v-*-*)
 921     noconfigdirs="$noconfigdirs gdb"
 922     ;;
 923   fr30-*-elf*)
 924     noconfigdirs="$noconfigdirs gdb"
 925     ;;
 926   moxie-*-*)
 927     noconfigdirs="$noconfigdirs gprof"
 928     ;;
 929   h8300*-*-*)
 930     noconfigdirs="$noconfigdirs target-libgloss"
 931     ;;
 932   h8500-*-*)
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     ;;
 935   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 936     ;;
 937   hppa*64*-*-linux*)
 938     ;;
 939   hppa*-*-linux*)
 940     ;;
 941   hppa*-*-*elf* | \
 942   hppa*-*-lites* | \
 943   hppa*-*-openbsd* | \
 944   hppa*64*-*-*)
 945     ;;
 946   hppa*-hp-hpux11*)
 947     noconfigdirs="$noconfigdirs ld"
 948     ;;
 949   hppa*-*-pro*)
 950     ;;
 951   hppa*-*-*)
 952     noconfigdirs="$noconfigdirs ld"
 953     ;;
 954   i960-*-*)
 955     noconfigdirs="$noconfigdirs gdb"
 956     ;;
 957   ia64*-*-elf*)
 958     # No gdb support yet.
 959     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 960     ;;
 961   ia64*-**-hpux*)
 962     # No ld support yet.
 963     noconfigdirs="$noconfigdirs libgui itcl ld"
 964     ;;
 965   ia64*-*-*vms*)
 966     # No ld support yet.
 967     noconfigdirs="$noconfigdirs libgui itcl ld"
 968     ;;
 969   i[[3456789]]86-w64-mingw*)
 970     ;;
 971   i[[3456789]]86-*-mingw*)
 972     target_configdirs="$target_configdirs target-winsup"
 973     ;;
 974   *-*-cygwin*)
 975     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     # always build newlib if winsup directory is present.
 978     if test -d "$srcdir/winsup/cygwin"; then
 979       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 980     elif test -d "$srcdir/newlib"; then
 981       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 982     fi
 983     ;;
 984   i[[3456789]]86-*-pe)
 985     noconfigdirs="$noconfigdirs target-libgloss"
 986     ;;
 987   i[[3456789]]86-*-sco3.2v5*)
 988     # The linker does not yet know about weak symbols in COFF,
 989     # and is not configured to handle mixed ELF and COFF.
 990     noconfigdirs="$noconfigdirs ld target-libgloss"
 991     ;;
 992   i[[3456789]]86-*-sco*)
 993     noconfigdirs="$noconfigdirs gprof target-libgloss"
 994     ;;
 995   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 996     noconfigdirs="$noconfigdirs target-libgloss"
 997     ;;
 998   i[[3456789]]86-*-sysv4*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   i[[3456789]]86-*-beos*)
1002     noconfigdirs="$noconfigdirs gdb"
1003     ;;
1004   i[[3456789]]86-*-rdos*)
1005     noconfigdirs="$noconfigdirs gdb"
1006     ;;
1007   mmix-*-*)
1008     noconfigdirs="$noconfigdirs gdb"
1009     ;;
1010   mt-*-*)
1011     noconfigdirs="$noconfigdirs sim"
1012     ;;
1013   powerpc-*-aix*)
1014     # copied from rs6000-*-* entry
1015     noconfigdirs="$noconfigdirs gprof"
1016     ;;
1017   powerpc*-*-winnt* | powerpc*-*-pe*)
1018     target_configdirs="$target_configdirs target-winsup"
1019     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1020     # always build newlib.
1021     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1022     ;;
1023     # This is temporary until we can link against shared libraries
1024   powerpcle-*-solaris*)
1025     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1026     ;;
1027   powerpc-*-beos*)
1028     noconfigdirs="$noconfigdirs gdb"
1029     ;;
1030   rs6000-*-lynxos*)
1031     noconfigdirs="$noconfigdirs gprof"
1032     ;;
1033   rs6000-*-aix*)
1034     noconfigdirs="$noconfigdirs gprof"
1035     ;;
1036   rs6000-*-*)
1037     noconfigdirs="$noconfigdirs gprof"
1038     ;;
1039   m68k-apollo-*)
1040     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1041     ;;
1042   microblaze*)
1043     noconfigdirs="$noconfigdirs gprof"
1044     ;;
1045   mips*-sde-elf* | mips*-mti-elf*)
1046     if test x$with_newlib = xyes; then
1047       noconfigdirs="$noconfigdirs gprof"
1048     fi
1049     ;;
1050   mips*-*-irix5*)
1051     noconfigdirs="$noconfigdirs gprof target-libgloss"
1052     ;;
1053   mips*-*-irix6*)
1054     noconfigdirs="$noconfigdirs gprof target-libgloss"
1055     ;;
1056   mips*-*-bsd*)
1057     noconfigdirs="$noconfigdirs gprof target-libgloss"
1058     ;;
1059   mips*-*-linux*)
1060     ;;
1061   mips*-*-*)
1062     noconfigdirs="$noconfigdirs gprof"
1063     ;;
1064   sh-*-* | sh64-*-*)
1065     case "${target}" in
1066       sh*-*-elf)
1067          ;;
1068       *)
1069          noconfigdirs="$noconfigdirs target-libgloss" ;;
1070     esac
1071     ;;
1072   sparc-*-sunos4*)
1073     if test x${is_cross_compiler} = xno ; then
1074            use_gnu_ld=no
1075     fi
1076     ;;
1077   tic6x-*-*)
1078     noconfigdirs="$noconfigdirs sim"
1079     ;;
1080   tilepro-*-* | tilegx-*-*)
1081     noconfigdirs="$noconfigdirs sim"
1082     ;;
1083   v810-*-*)
1084     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1085     ;;
1086   vax-*-*)
1087     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1088     ;;
1089 esac
1090
1091 # If we aren't building newlib, then don't build libgloss, since libgloss
1092 # depends upon some newlib header files.
1093 case "${noconfigdirs}" in
1094   *target-libgloss*) ;;
1095   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1096 esac
1097
1098 # Work in distributions that contain no compiler tools, like Autoconf.
1099 host_makefile_frag=/dev/null
1100 if test -d ${srcdir}/config ; then
1101 case "${host}" in
1102   i[[3456789]]86-*-msdosdjgpp*)
1103     host_makefile_frag="config/mh-djgpp"
1104     ;;
1105   *-cygwin*)
1106     ACX_CHECK_CYGWIN_CAT_WORKS
1107     host_makefile_frag="config/mh-cygwin"
1108     ;;
1109   *-mingw*)
1110     host_makefile_frag="config/mh-mingw"
1111     ;;
1112   hppa*-hp-hpux10*)
1113     host_makefile_frag="config/mh-pa-hpux10"
1114     ;;
1115   hppa*-hp-hpux*)
1116     host_makefile_frag="config/mh-pa"
1117     ;;
1118   hppa*-*)
1119     host_makefile_frag="config/mh-pa"
1120     ;;
1121   *-*-darwin*)
1122     host_makefile_frag="config/mh-darwin"
1123     ;;
1124   powerpc-*-aix*)
1125     host_makefile_frag="config/mh-ppc-aix"
1126     ;;
1127   rs6000-*-aix*)
1128     host_makefile_frag="config/mh-ppc-aix"
1129     ;;
1130 esac
1131 fi
1132
1133 if test "${build}" != "${host}" ; then
1134   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1135   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1136   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1137   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1138   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1139   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1140   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1141   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1142   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1143   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1144   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1145   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1146   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1147 else
1148   AR_FOR_BUILD="\$(AR)"
1149   AS_FOR_BUILD="\$(AS)"
1150   CC_FOR_BUILD="\$(CC)"
1151   CXX_FOR_BUILD="\$(CXX)"
1152   GCJ_FOR_BUILD="\$(GCJ)"
1153   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1154   GOC_FOR_BUILD="\$(GOC)"
1155   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1156   LD_FOR_BUILD="\$(LD)"
1157   NM_FOR_BUILD="\$(NM)"
1158   RANLIB_FOR_BUILD="\$(RANLIB)"
1159   WINDRES_FOR_BUILD="\$(WINDRES)"
1160   WINDMC_FOR_BUILD="\$(WINDMC)"
1161 fi
1162
1163 AC_PROG_CC
1164 AC_PROG_CXX
1165
1166 # We must set the default linker to the linker used by gcc for the correct
1167 # operation of libtool.  If LD is not defined and we are using gcc, try to
1168 # set the LD default to the ld used by gcc.
1169 if test -z "$LD"; then
1170   if test "$GCC" = yes; then
1171     case $build in
1172     *-*-mingw*)
1173       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1174     *)
1175       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1176     esac
1177     case $gcc_prog_ld in
1178     # Accept absolute paths.
1179     [[\\/]* | [A-Za-z]:[\\/]*)]
1180       LD="$gcc_prog_ld" ;;
1181     esac
1182   fi
1183 fi
1184
1185 # Check whether -static-libstdc++ -static-libgcc is supported.
1186 have_static_libs=no
1187 if test "$GCC" = yes; then
1188   saved_LDFLAGS="$LDFLAGS"
1189
1190   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1191   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1192   AC_LANG_PUSH(C++)
1193   AC_LINK_IFELSE([int main() {}],
1194     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1195     [AC_MSG_RESULT([no])])
1196   AC_LANG_POP(C++)
1197
1198   LDFLAGS="$saved_LDFLAGS"
1199 fi
1200
1201 ACX_PROG_GNAT
1202 ACX_PROG_CMP_IGNORE_INITIAL
1203
1204 AC_ARG_ENABLE([bootstrap],
1205 [AS_HELP_STRING([--enable-bootstrap],
1206                 [enable bootstrapping @<:@yes if native build@:>@])],,
1207 enable_bootstrap=default)
1208
1209 # Issue errors and warnings for invalid/strange bootstrap combinations.
1210 if test -r $srcdir/gcc/configure; then
1211   have_compiler=yes
1212 else
1213   have_compiler=no
1214 fi
1215
1216 case "$have_compiler:$host:$target:$enable_bootstrap" in
1217   *:*:*:no) ;;
1218
1219   # Default behavior.  Enable bootstrap if we have a compiler
1220   # and we are in a native configuration.
1221   yes:$build:$build:default)
1222     enable_bootstrap=yes ;;
1223
1224   *:*:*:default)
1225     enable_bootstrap=no ;;
1226
1227   # We have a compiler and we are in a native configuration, bootstrap is ok
1228   yes:$build:$build:yes)
1229     ;;
1230
1231   # Other configurations, but we have a compiler.  Assume the user knows
1232   # what he's doing.
1233   yes:*:*:yes)
1234     AC_MSG_WARN([trying to bootstrap a cross compiler])
1235     ;;
1236
1237   # No compiler: if they passed --enable-bootstrap explicitly, fail
1238   no:*:*:yes)
1239     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1240
1241   # Fail if wrong command line
1242   *)
1243     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1244     ;;
1245 esac
1246
1247 # Used for setting $lt_cv_objdir
1248 _LT_CHECK_OBJDIR
1249
1250 # Check for GMP, MPFR and MPC
1251 gmplibs="-lmpc -lmpfr -lgmp"
1252 gmpinc=
1253 have_gmp=no
1254
1255 # Specify a location for mpc
1256 # check for this first so it ends up on the link line before mpfr.
1257 AC_ARG_WITH(mpc,
1258 [AS_HELP_STRING([--with-mpc=PATH],
1259                 [specify prefix directory for installed MPC package.
1260                  Equivalent to --with-mpc-include=PATH/include
1261                  plus --with-mpc-lib=PATH/lib])])
1262 AC_ARG_WITH(mpc-include,
1263 [AS_HELP_STRING([--with-mpc-include=PATH],
1264                 [specify directory for installed MPC include files])])
1265 AC_ARG_WITH(mpc-lib,
1266 [AS_HELP_STRING([--with-mpc-lib=PATH],
1267                 [specify directory for the installed MPC library])])
1268
1269 if test "x$with_mpc" != x; then
1270   gmplibs="-L$with_mpc/lib $gmplibs"
1271   gmpinc="-I$with_mpc/include $gmpinc"
1272 fi
1273 if test "x$with_mpc_include" != x; then
1274   gmpinc="-I$with_mpc_include $gmpinc"
1275 fi
1276 if test "x$with_mpc_lib" != x; then
1277   gmplibs="-L$with_mpc_lib $gmplibs"
1278 fi
1279 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1280   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1281   gmpinc='-I$$s/mpc/src '"$gmpinc"
1282   # Do not test the mpc version.  Assume that it is sufficient, since
1283   # it is in the source tree, and the library has not been built yet
1284   # but it would be included on the link line in the version check below
1285   # hence making the test fail.
1286   have_gmp=yes
1287 fi
1288
1289 # Specify a location for mpfr
1290 # check for this first so it ends up on the link line before gmp.
1291 AC_ARG_WITH(mpfr-dir,
1292 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1293 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1294 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1295
1296 AC_ARG_WITH(mpfr,
1297 [AS_HELP_STRING([--with-mpfr=PATH],
1298                 [specify prefix directory for installed MPFR package.
1299                  Equivalent to --with-mpfr-include=PATH/include
1300                  plus --with-mpfr-lib=PATH/lib])])
1301 AC_ARG_WITH(mpfr-include,
1302 [AS_HELP_STRING([--with-mpfr-include=PATH],
1303                 [specify directory for installed MPFR include files])])
1304 AC_ARG_WITH(mpfr-lib,
1305 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1306                 [specify directory for the installed MPFR library])])
1307
1308 if test "x$with_mpfr" != x; then
1309   gmplibs="-L$with_mpfr/lib $gmplibs"
1310   gmpinc="-I$with_mpfr/include $gmpinc"
1311 fi
1312 if test "x$with_mpfr_include" != x; then
1313   gmpinc="-I$with_mpfr_include $gmpinc"
1314 fi
1315 if test "x$with_mpfr_lib" != x; then
1316   gmplibs="-L$with_mpfr_lib $gmplibs"
1317 fi
1318 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1319   # MPFR v3.1.0 moved the sources into a src sub-directory.
1320   if test -d ${srcdir}/mpfr/src; then
1321     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1322     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1323     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1324   else
1325     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1326     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1327     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1328   fi
1329   # Do not test the mpfr version.  Assume that it is sufficient, since
1330   # it is in the source tree, and the library has not been built yet
1331   # but it would be included on the link line in the version check below
1332   # hence making the test fail.
1333   have_gmp=yes
1334 fi
1335
1336 # Specify a location for gmp
1337 AC_ARG_WITH(gmp-dir,
1338 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1339 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1340 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1341
1342 AC_ARG_WITH(gmp,
1343 [AS_HELP_STRING([--with-gmp=PATH],
1344                 [specify prefix directory for the installed GMP package.
1345                  Equivalent to --with-gmp-include=PATH/include
1346                  plus --with-gmp-lib=PATH/lib])])
1347 AC_ARG_WITH(gmp-include,
1348 [AS_HELP_STRING([--with-gmp-include=PATH],
1349                 [specify directory for installed GMP include files])])
1350 AC_ARG_WITH(gmp-lib,
1351 [AS_HELP_STRING([--with-gmp-lib=PATH],
1352                 [specify directory for the installed GMP library])])
1353
1354
1355 if test "x$with_gmp" != x; then
1356   gmplibs="-L$with_gmp/lib $gmplibs"
1357   gmpinc="-I$with_gmp/include $gmpinc"
1358 fi
1359 if test "x$with_gmp_include" != x; then
1360   gmpinc="-I$with_gmp_include $gmpinc"
1361 fi
1362 if test "x$with_gmp_lib" != x; then
1363   gmplibs="-L$with_gmp_lib $gmplibs"
1364 fi
1365 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1366   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1367   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1368   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1369   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1370   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1371   # Do not test the gmp version.  Assume that it is sufficient, since
1372   # it is in the source tree, and the library has not been built yet
1373   # but it would be included on the link line in the version check below
1374   # hence making the test fail.
1375   have_gmp=yes
1376 fi
1377
1378 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1379   have_gmp=yes
1380   saved_CFLAGS="$CFLAGS"
1381   CFLAGS="$CFLAGS $gmpinc"
1382   # Check for the recommended and required versions of GMP.
1383   AC_MSG_CHECKING([for the correct version of gmp.h])
1384   AC_TRY_COMPILE([#include "gmp.h"],[
1385   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1386   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1387   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1388   choke me
1389   #endif
1390   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1391   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1392   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1393   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1394   choke me
1395   #endif
1396   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1397    [AC_MSG_RESULT([no]); have_gmp=no])
1398
1399   # If we have GMP, check the MPFR version.
1400   if test x"$have_gmp" = xyes; then
1401     # Check for the recommended and required versions of MPFR.
1402     AC_MSG_CHECKING([for the correct version of mpfr.h])
1403     AC_TRY_COMPILE([#include <gmp.h>
1404     #include <mpfr.h>],[
1405     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1406     choke me
1407     #endif
1408     ], [AC_TRY_COMPILE([#include <gmp.h>
1409     #include <mpfr.h>],[
1410     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1411     choke me
1412     #endif
1413     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1414      [AC_MSG_RESULT([no]); have_gmp=no])
1415   fi
1416
1417   # Check for the MPC header version.
1418   if test x"$have_gmp" = xyes ; then
1419     # Check for the recommended and required versions of MPC.
1420     AC_MSG_CHECKING([for the correct version of mpc.h])
1421     AC_TRY_COMPILE([#include <mpc.h>],[
1422     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1423     choke me
1424     #endif
1425     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1426     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1427     choke me
1428     #endif
1429     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1430      [AC_MSG_RESULT([no]); have_gmp=no])
1431   fi
1432
1433   # Now check the MPFR library.
1434   if test x"$have_gmp" = xyes; then
1435     saved_LIBS="$LIBS"
1436     LIBS="$LIBS $gmplibs"
1437     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1438     AC_TRY_LINK([#include <mpc.h>],[
1439     mpfr_t n;
1440     mpfr_t x;
1441     mpc_t c;
1442     int t;
1443     mpfr_init (n);
1444     mpfr_init (x);
1445     mpfr_atan2 (n, n, x, GMP_RNDN);
1446     mpfr_erfc (n, x, GMP_RNDN);
1447     mpfr_subnormalize (x, t, GMP_RNDN);
1448     mpfr_clear(n);
1449     mpfr_clear(x);
1450     mpc_init2 (c, 53);
1451     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1452     mpc_cosh (c, c, MPC_RNDNN);
1453     mpc_pow (c, c, c, MPC_RNDNN);
1454     mpc_acosh (c, c, MPC_RNDNN);
1455     mpc_clear (c);
1456     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1457     LIBS="$saved_LIBS"
1458   fi
1459
1460   CFLAGS="$saved_CFLAGS"
1461
1462 # The library versions listed in the error message below should match
1463 # the HARD-minimums enforced above.
1464   if test x$have_gmp != xyes; then
1465     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1466 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1467 their locations.  Source code for these libraries can be found at
1468 their respective hosting sites as well as at
1469 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1470 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1471 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1472 make sure that you have installed both the libraries and the header
1473 files.  They may be located in separate packages.])
1474   fi
1475 fi
1476
1477 # Flags needed for both GMP, MPFR and/or MPC.
1478 AC_SUBST(gmplibs)
1479 AC_SUBST(gmpinc)
1480 AC_SUBST(extra_mpfr_configure_flags)
1481 AC_SUBST(extra_mpc_gmp_configure_flags)
1482 AC_SUBST(extra_mpc_mpfr_configure_flags)
1483 AC_SUBST(extra_isl_gmp_configure_flags)
1484
1485 # Allow host libstdc++ to be specified for static linking with PPL.
1486 AC_ARG_WITH(host-libstdcxx,
1487 [AS_HELP_STRING([--with-host-libstdcxx=L],
1488                 [use linker arguments L to link with libstdc++
1489                  when linking with PPL])])
1490
1491 case $with_host_libstdcxx in
1492   no|yes)
1493     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1494     ;;
1495 esac
1496
1497 # Libraries to use for stage1 or when not bootstrapping.
1498 AC_ARG_WITH(stage1-libs,
1499 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1500 [if test "$withval" = "no" -o "$withval" = "yes"; then
1501    stage1_libs=
1502  else
1503    stage1_libs=$withval
1504  fi],
1505 [stage1_libs=$with_host_libstdcxx])
1506 AC_SUBST(stage1_libs)
1507
1508 # Linker flags to use for stage1 or when not bootstrapping.
1509 AC_ARG_WITH(stage1-ldflags,
1510 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1511 [if test "$withval" = "no" -o "$withval" = "yes"; then
1512    stage1_ldflags=
1513  else
1514    stage1_ldflags=$withval
1515  fi],
1516 [stage1_ldflags=
1517  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1518  # if supported.  But if the user explicitly specified the libraries to use,
1519  # trust that they are doing what they want.
1520  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1521    stage1_ldflags="-static-libstdc++ -static-libgcc"
1522  fi])
1523 AC_SUBST(stage1_ldflags)
1524
1525 # Libraries to use for stage2 and later builds.  This defaults to the
1526 # argument passed to --with-host-libstdcxx.
1527 AC_ARG_WITH(boot-libs,
1528 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1529 [if test "$withval" = "no" -o "$withval" = "yes"; then
1530    poststage1_libs=
1531  else
1532    poststage1_libs=$withval
1533  fi],
1534 [poststage1_libs=$with_host_libstdcxx])
1535 AC_SUBST(poststage1_libs)
1536
1537 # Linker flags to use for stage2 and later builds.
1538 AC_ARG_WITH(boot-ldflags,
1539 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1540                 [linker flags for stage2 and later])],
1541 [if test "$withval" = "no" -o "$withval" = "yes"; then
1542    poststage1_ldflags=
1543  else
1544    poststage1_ldflags=$withval
1545  fi],
1546 [poststage1_ldflags=
1547  # In stages 2 and 3, default to linking libstdc++ and libgcc
1548  # statically.  But if the user explicitly specified the libraries to
1549  # use, trust that they are doing what they want.
1550  if test "$poststage1_libs" = ""; then
1551    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1552  fi])
1553 AC_SUBST(poststage1_ldflags)
1554
1555 # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL.
1556 # Basic setup is inlined here, actual checks are in config/cloog.m4 and
1557 # config/isl.m4
1558
1559 AC_ARG_WITH(cloog,
1560   [AS_HELP_STRING(
1561     [--with-cloog=PATH],
1562     [Specify prefix directory for the installed CLooG-ISL package.
1563      Equivalent to --with-cloog-include=PATH/include
1564      plus --with-cloog-lib=PATH/lib])])
1565 AC_ARG_WITH(isl,
1566   [AS_HELP_STRING(
1567    [--with-isl=PATH],
1568    [Specify prefix directory for the installed ISL package.
1569     Equivalent to --with-isl-include=PATH/include
1570     plus --with-isl-lib=PATH/lib])])
1571
1572 # Treat either --without-cloog or --without-isl as a request to disable
1573 # GRAPHITE support and skip all following checks.
1574 if test "x$with_isl" != "xno" &&
1575    test "x$with_cloog" != "xno"; then
1576   # Check for ISL
1577   dnl Provide configure switches and initialize islinc & isllibs
1578   dnl with user input.
1579   ISL_INIT_FLAGS
1580   dnl The minimal version of ISL required for Graphite.
1581   ISL_CHECK_VERSION(0,10)
1582   dnl Only execute fail-action, if ISL has been requested.
1583   ISL_IF_FAILED([
1584     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1585
1586   if test "x$gcc_cv_isl" != "xno"; then
1587     # Check for CLOOG
1588     dnl Provide configure switches and initialize clooginc & clooglibs
1589     dnl with user input.
1590     CLOOG_INIT_FLAGS
1591     dnl The minimal version of CLooG required for Graphite.
1592     dnl
1593     dnl If we use CLooG-Legacy, the provided version information is
1594     dnl ignored.
1595     CLOOG_CHECK_VERSION(0,17,0)
1596
1597     dnl Only execute fail-action, if CLooG has been requested.
1598     CLOOG_IF_FAILED([
1599       AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1600   fi
1601 fi
1602
1603 # If either the ISL or the CLooG check failed, disable builds of in-tree
1604 # variants of both
1605 if test "x$with_isl" = xno ||
1606    test "x$with_cloog" = xno ||
1607    test "x$gcc_cv_cloog" = xno ||
1608    test "x$gcc_cv_isl" = xno; then
1609   noconfigdirs="$noconfigdirs cloog isl"
1610   islinc=
1611   clooginc=
1612   clooglibs=
1613 fi
1614
1615 AC_SUBST(islinc)
1616 AC_SUBST(clooglibs)
1617 AC_SUBST(clooginc)
1618
1619
1620 # Check for LTO support.
1621 AC_ARG_ENABLE(lto,
1622 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1623 enable_lto=$enableval,
1624 enable_lto=yes; default_enable_lto=yes)
1625
1626 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1627   build_lto_plugin=yes
1628 ],[if test x"$default_enable_lto" = x"yes" ; then
1629     case $target in
1630       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1631       # On other non-ELF platforms, LTO has yet to be validated.
1632       *) enable_lto=no ;;
1633     esac
1634   else
1635   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1636   # It would also be nice to check the binutils support, but we don't
1637   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1638   # warn during gcc/ subconfigure; unless you're bootstrapping with
1639   # -flto it won't be needed until after installation anyway.
1640     case $target in
1641       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1642       *) if test x"$enable_lto" = x"yes"; then
1643         AC_MSG_ERROR([LTO support is not enabled for this target.])
1644         fi
1645       ;;
1646     esac
1647   fi
1648   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1649   # Build it unless LTO was explicitly disabled.
1650   case $target in
1651     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1652     *) ;;
1653   esac
1654 ])
1655
1656
1657 # By default, C and C++ are the only stage 1 languages.
1658 stage1_languages=,c,
1659
1660 # Target libraries that we bootstrap.
1661 bootstrap_target_libs=,target-libgcc,
1662
1663 # Figure out what language subdirectories are present.
1664 # Look if the user specified --enable-languages="..."; if not, use
1665 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1666 # go away some day.
1667 # NB:  embedded tabs in this IF block -- do not untabify
1668 if test -d ${srcdir}/gcc; then
1669   if test x"${enable_languages+set}" != xset; then
1670     if test x"${LANGUAGES+set}" = xset; then
1671       enable_languages="${LANGUAGES}"
1672         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1673     else
1674       enable_languages=all
1675     fi
1676   else
1677     if test x"${enable_languages}" = x ||
1678        test x"${enable_languages}" = xyes;
1679        then
1680       echo configure.in: --enable-languages needs at least one language argument 1>&2
1681       exit 1
1682     fi
1683   fi
1684   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1685
1686   # 'f95' is the old name for the 'fortran' language. We issue a warning
1687   # and make the substitution.
1688   case ,${enable_languages}, in
1689     *,f95,*)
1690       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1691       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1692       ;;
1693   esac
1694
1695   # If bootstrapping, C++ must be enabled.
1696   case ",$enable_languages,:$enable_bootstrap" in
1697     *,c++,*:*) ;;
1698     *:yes)
1699       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1700         enable_languages="${enable_languages},c++"
1701       else
1702         AC_MSG_ERROR([bootstrapping requires c++ sources])
1703       fi
1704       ;;
1705   esac
1706
1707   # First scan to see if an enabled language requires some other language.
1708   # We assume that a given config-lang.in will list all the language
1709   # front ends it requires, even if some are required indirectly.
1710   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1711     case ${lang_frag} in
1712       ..) ;;
1713       # The odd quoting in the next line works around
1714       # an apparent bug in bash 1.12 on linux.
1715       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1716       *)
1717         # From the config-lang.in, get $language, $lang_requires, and
1718         # $lang_requires_boot_languages.
1719         language=
1720         lang_requires=
1721         lang_requires_boot_languages=
1722         . ${lang_frag}
1723         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1724           case ,${enable_languages}, in
1725             *,$other,*) ;;
1726             *,all,*) ;;
1727             *,$language,*)
1728               echo " \`$other' language required by \`$language'; enabling" 1>&2
1729               enable_languages="${enable_languages},${other}"
1730               ;;
1731           esac
1732         done
1733         for other in ${lang_requires_boot_languages} ; do
1734           if test "$other" != "c"; then
1735             case ,${enable_stage1_languages}, in
1736               *,$other,*) ;;
1737               *,all,*) ;;
1738               *)
1739                 case ,${enable_languages}, in
1740                   *,$language,*)
1741                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1742                     enable_stage1_languages="$enable_stage1_languages,${other}"
1743                     ;;
1744                 esac
1745                 ;;
1746             esac
1747           fi
1748         done
1749         ;;
1750     esac
1751   done
1752
1753   new_enable_languages=,c,
1754
1755   # If LTO is enabled, add the LTO front end.
1756   extra_host_libiberty_configure_flags=
1757   if test "$enable_lto" = "yes" ; then
1758     case ,${enable_languages}, in
1759       *,lto,*) ;;
1760       *) enable_languages="${enable_languages},lto" ;;
1761     esac
1762     if test "${build_lto_plugin}" = "yes" ; then
1763       configdirs="$configdirs lto-plugin"
1764       extra_host_libiberty_configure_flags=--enable-shared
1765     fi
1766   fi
1767   AC_SUBST(extra_host_libiberty_configure_flags)
1768
1769   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1770   potential_languages=,c,
1771
1772   enabled_target_libs=
1773   disabled_target_libs=
1774
1775   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1776     case ${lang_frag} in
1777       ..) ;;
1778       # The odd quoting in the next line works around
1779       # an apparent bug in bash 1.12 on linux.
1780       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1781       *)
1782         # From the config-lang.in, get $language, $target_libs,
1783         # $lang_dirs, $boot_language, and $build_by_default
1784         language=
1785         target_libs=
1786         lang_dirs=
1787         subdir_requires=
1788         boot_language=no
1789         build_by_default=yes
1790         . ${lang_frag}
1791         if test x${language} = x; then
1792           echo "${lang_frag} doesn't set \$language." 1>&2
1793           exit 1
1794         fi
1795
1796         if test "$language" = "c++"; then
1797           boot_language=yes
1798         fi
1799
1800         add_this_lang=no
1801         case ,${enable_languages}, in
1802           *,${language},*)
1803             # Language was explicitly selected; include it
1804             # unless it is C, which is enabled by default.
1805             if test "$language" != "c"; then
1806               add_this_lang=yes
1807             fi
1808             ;;
1809           *,all,*)
1810             # 'all' was selected, select it if it is a default language
1811             if test "$language" != "c"; then
1812               add_this_lang=${build_by_default}
1813             fi
1814             ;;
1815         esac
1816
1817         # Disable languages that need other directories if these aren't available.
1818         for i in $subdir_requires; do
1819           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1820           case ,${enable_languages}, in
1821             *,${language},*)
1822               # Specifically requested language; tell them.
1823               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1824               ;;
1825             *)
1826               # Silently disable.
1827               add_this_lang=unsupported
1828               ;;
1829           esac
1830         done
1831
1832         # Disable Ada if no preexisting GNAT is available.
1833         case ,${enable_languages},:${language}:${have_gnat} in
1834           *,${language},*:ada:no)
1835             # Specifically requested language; tell them.
1836             AC_MSG_ERROR([GNAT is required to build $language])
1837             ;;
1838           *:ada:no)
1839             # Silently disable.
1840             add_this_lang=unsupported
1841             ;;
1842         esac
1843
1844         # Disable a language that is unsupported by the target.
1845         case " $unsupported_languages " in
1846           *" $language "*)
1847             add_this_lang=unsupported
1848             ;;
1849         esac
1850
1851         case $add_this_lang in
1852           unsupported)
1853             # Remove language-dependent dirs.
1854             disabled_target_libs="$disabled_target_libs $target_libs"
1855             noconfigdirs="$noconfigdirs $lang_dirs"
1856             ;;
1857           no)
1858             # Remove language-dependent dirs; still show language as supported.
1859             disabled_target_libs="$disabled_target_libs $target_libs"
1860             noconfigdirs="$noconfigdirs $lang_dirs"
1861             potential_languages="${potential_languages}${language},"
1862             ;;
1863           yes)
1864             new_enable_languages="${new_enable_languages}${language},"
1865             potential_languages="${potential_languages}${language},"
1866             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1867             enabled_target_libs="$enabled_target_libs $target_libs"
1868             case "${boot_language}:,$enable_stage1_languages," in
1869               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1870                 # Add to (comma-separated) list of stage 1 languages.
1871                 case ",$stage1_languages," in
1872                   *,$language,* | ,yes, | ,all,) ;;
1873                   *) stage1_languages="${stage1_languages}${language}," ;;
1874                 esac
1875                 # We need to bootstrap any supporting libraries.
1876                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1877                 ;;
1878             esac
1879             ;;
1880         esac
1881         ;;
1882     esac
1883   done
1884
1885   # Add target libraries which are only needed for disabled languages
1886   # to noconfigdirs.
1887   if test -n "$disabled_target_libs"; then
1888     for dir in $disabled_target_libs; do
1889       case " $enabled_target_libs " in
1890       *" ${dir} "*) ;;
1891       *) noconfigdirs="$noconfigdirs $dir" ;;
1892       esac
1893     done
1894   fi
1895
1896   AC_ARG_ENABLE(stage1-languages,
1897   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1898                   [choose additional languages to build during
1899                   stage1.  Mostly useful for compiler development])],
1900   [case ,${enable_stage1_languages}, in
1901     ,no,|,,)
1902       # Set it to something that will have no effect in the loop below
1903       enable_stage1_languages=c ;;
1904     ,yes,)
1905       enable_stage1_languages=`echo $new_enable_languages | \
1906         sed -e "s/^,//" -e "s/,$//" ` ;;
1907     *,all,*)
1908       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1909         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1910   esac
1911
1912   # Add "good" languages from enable_stage1_languages to stage1_languages,
1913   # while "bad" languages go in missing_languages.  Leave no duplicates.
1914   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1915     case $potential_languages in
1916       *,$i,*)
1917         case $stage1_languages in
1918           *,$i,*) ;;
1919           *) stage1_languages="$stage1_languages$i," ;;
1920         esac ;;
1921       *)
1922         case $missing_languages in
1923           *,$i,*) ;;
1924           *) missing_languages="$missing_languages$i," ;;
1925         esac ;;
1926      esac
1927   done])
1928
1929   # Remove leading/trailing commas that were added for simplicity
1930   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1931   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1932   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1933   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1934
1935   if test "x$missing_languages" != x; then
1936     AC_MSG_ERROR([
1937 The following requested languages could not be built: ${missing_languages}
1938 Supported languages are: ${potential_languages}])
1939   fi
1940   if test "x$new_enable_languages" != "x$enable_languages"; then
1941     echo The following languages will be built: ${new_enable_languages}
1942     enable_languages="$new_enable_languages"
1943   fi
1944
1945   AC_SUBST(stage1_languages)
1946   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1947 fi
1948
1949 # Handle --disable-<component> generically.
1950 for dir in $configdirs $build_configdirs $target_configdirs ; do
1951   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1952   varname=`echo $dirname | sed -e s/+/_/g`
1953   if eval test x\${enable_${varname}} "=" xno ; then
1954     noconfigdirs="$noconfigdirs $dir"
1955   fi
1956 done
1957
1958 # Check for Boehm's garbage collector
1959 AC_ARG_ENABLE(objc-gc,
1960 [AS_HELP_STRING([--enable-objc-gc],
1961                 [enable use of Boehm's garbage collector with the
1962                  GNU Objective-C runtime])],
1963 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1964   *,objc,*:*:yes:*target-boehm-gc*)
1965     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1966     ;;
1967 esac])
1968
1969 # Make sure we only build Boehm's garbage collector if required.
1970 case ,${enable_languages},:${enable_objc_gc} in
1971   *,objc,*:yes)
1972     # Keep target-boehm-gc if requested for Objective-C.
1973     ;;
1974   *)
1975     # Otherwise remove target-boehm-gc depending on target-libjava.
1976     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1977       noconfigdirs="$noconfigdirs target-boehm-gc"
1978     fi
1979     ;;
1980 esac
1981
1982 # Disable libitm if we're not building C++
1983 case ,${enable_languages}, in
1984   *,c++,*) ;;
1985   *)
1986     noconfigdirs="$noconfigdirs target-libitm"
1987     ;;
1988 esac
1989
1990 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1991 # $build_configdirs and $target_configdirs.
1992 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1993
1994 notsupp=""
1995 for dir in . $skipdirs $noconfigdirs ; do
1996   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1997   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1998     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1999     if test -r $srcdir/$dirname/configure ; then
2000       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2001         true
2002       else
2003         notsupp="$notsupp $dir"
2004       fi
2005     fi
2006   fi
2007   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2008     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2009     if test -r $srcdir/$dirname/configure ; then
2010       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2011         true
2012       else
2013         notsupp="$notsupp $dir"
2014       fi
2015     fi
2016   fi
2017   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2018     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2019     if test -r $srcdir/$dirname/configure ; then
2020       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2021         true
2022       else
2023         notsupp="$notsupp $dir"
2024       fi
2025     fi
2026   fi
2027 done
2028
2029 # Quietly strip out all directories which aren't configurable in this tree.
2030 # This relies on all configurable subdirectories being autoconfiscated, which
2031 # is now the case.
2032 build_configdirs_all="$build_configdirs"
2033 build_configdirs=
2034 for i in ${build_configdirs_all} ; do
2035   j=`echo $i | sed -e s/build-//g`
2036   if test -f ${srcdir}/$j/configure ; then
2037     build_configdirs="${build_configdirs} $i"
2038   fi
2039 done
2040
2041 configdirs_all="$configdirs"
2042 configdirs=
2043 for i in ${configdirs_all} ; do
2044   if test -f ${srcdir}/$i/configure ; then
2045     configdirs="${configdirs} $i"
2046   fi
2047 done
2048
2049 target_configdirs_all="$target_configdirs"
2050 target_configdirs=
2051 for i in ${target_configdirs_all} ; do
2052   j=`echo $i | sed -e s/target-//g`
2053   if test -f ${srcdir}/$j/configure ; then
2054     target_configdirs="${target_configdirs} $i"
2055   fi
2056 done
2057
2058 # Produce a warning message for the subdirs we can't configure.
2059 # This isn't especially interesting in the Cygnus tree, but in the individual
2060 # FSF releases, it's important to let people know when their machine isn't
2061 # supported by the one or two programs in a package.
2062
2063 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2064   # If $appdirs is non-empty, at least one of those directories must still
2065   # be configured, or we error out.  (E.g., if the gas release supports a
2066   # specified target in some subdirs but not the gas subdir, we shouldn't
2067   # pretend that all is well.)
2068   if test -n "$appdirs" ; then
2069     for dir in $appdirs ; do
2070       if test -r $dir/Makefile.in ; then
2071         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2072           appdirs=""
2073           break
2074         fi
2075         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2076           appdirs=""
2077           break
2078         fi
2079       fi
2080     done
2081     if test -n "$appdirs" ; then
2082       echo "*** This configuration is not supported by this package." 1>&2
2083       exit 1
2084     fi
2085   fi
2086   # Okay, some application will build, or we don't care to check.  Still
2087   # notify of subdirs not getting built.
2088   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2089   echo "    ${notsupp}" 1>&2
2090   echo "    (Any other directories should still work fine.)" 1>&2
2091 fi
2092
2093 case "$host" in
2094   *msdosdjgpp*)
2095     enable_gdbtk=no ;;
2096 esac
2097
2098 # To find our prefix, in gcc_cv_tool_prefix.
2099 ACX_TOOL_DIRS
2100
2101 copy_dirs=
2102
2103 AC_ARG_WITH([build-sysroot],
2104   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2105                   [use sysroot as the system root during the build])],
2106   [if test x"$withval" != x ; then
2107      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2108    fi],
2109   [SYSROOT_CFLAGS_FOR_TARGET=])
2110 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2111
2112 AC_ARG_WITH([debug-prefix-map],
2113   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2114                   [map A to B, C to D ... in debug information])],
2115   [if test x"$withval" != x; then
2116      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2117      for debug_map in $withval; do
2118        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2119      done
2120    fi],
2121   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2122 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2123
2124 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2125 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2126 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2127 # We want to ensure that TARGET libraries (which we know are built with
2128 # gcc) are built with "-O2 -g", so include those options when setting
2129 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2130 if test "x$CFLAGS_FOR_TARGET" = x; then
2131   CFLAGS_FOR_TARGET=$CFLAGS
2132   case " $CFLAGS " in
2133     *" -O2 "*) ;;
2134     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2135   esac
2136   case " $CFLAGS " in
2137     *" -g "* | *" -g3 "*) ;;
2138     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2139   esac
2140 fi
2141 AC_SUBST(CFLAGS_FOR_TARGET)
2142
2143 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2144   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2145   case " $CXXFLAGS " in
2146     *" -O2 "*) ;;
2147     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2148   esac
2149   case " $CXXFLAGS " in
2150     *" -g "* | *" -g3 "*) ;;
2151     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2152   esac
2153 fi
2154 AC_SUBST(CXXFLAGS_FOR_TARGET)
2155
2156 AC_SUBST(LDFLAGS_FOR_TARGET)
2157
2158 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2159 # the named directory are copied to $(tooldir)/sys-include.
2160 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2161   if test x${is_cross_compiler} = xno ; then
2162     echo 1>&2 '***' --with-headers is only supported when cross compiling
2163     exit 1
2164   fi
2165   if test x"${with_headers}" != xyes ; then
2166     x=${gcc_cv_tool_prefix}
2167     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2168   fi
2169 fi
2170
2171 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2172 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2173 # are permitted.
2174 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2175   if test x${is_cross_compiler} = xno ; then
2176     echo 1>&2 '***' --with-libs is only supported when cross compiling
2177     exit 1
2178   fi
2179   if test x"${with_libs}" != xyes ; then
2180     # Copy the libraries in reverse order, so that files in the first named
2181     # library override files in subsequent libraries.
2182     x=${gcc_cv_tool_prefix}
2183     for l in ${with_libs}; do
2184       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2185     done
2186   fi
2187 fi
2188
2189 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2190 #
2191 # This is done by determining whether or not the appropriate directory
2192 # is available, and by checking whether or not specific configurations
2193 # have requested that this magic not happen.
2194 #
2195 # The command line options always override the explicit settings in
2196 # configure.in, and the settings in configure.in override this magic.
2197 #
2198 # If the default for a toolchain is to use GNU as and ld, and you don't
2199 # want to do that, then you should use the --without-gnu-as and
2200 # --without-gnu-ld options for the configure script.  Similarly, if
2201 # the default is to use the included zlib and you don't want to do that,
2202 # you should use the --with-system-zlib option for the configure script.
2203
2204 if test x${use_gnu_as} = x &&
2205    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2206   with_gnu_as=yes
2207   extra_host_args="$extra_host_args --with-gnu-as"
2208 fi
2209
2210 if test x${use_gnu_ld} = x &&
2211    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2212   with_gnu_ld=yes
2213   extra_host_args="$extra_host_args --with-gnu-ld"
2214 fi
2215
2216 if test x${use_included_zlib} = x &&
2217    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2218   :
2219 else
2220   with_system_zlib=yes
2221   extra_host_args="$extra_host_args --with-system-zlib"
2222 fi
2223
2224 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2225 # can detect this case.
2226
2227 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2228   with_newlib=yes
2229   extra_host_args="$extra_host_args --with-newlib"
2230 fi
2231
2232 # Handle ${copy_dirs}
2233 set fnord ${copy_dirs}
2234 shift
2235 while test $# != 0 ; do
2236   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2237     :
2238   else
2239     echo Copying $1 to $2
2240
2241     # Use the install script to create the directory and all required
2242     # parent directories.
2243     if test -d $2 ; then
2244       :
2245     else
2246       echo >config.temp
2247       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2248     fi
2249
2250     # Copy the directory, assuming we have tar.
2251     # FIXME: Should we use B in the second tar?  Not all systems support it.
2252     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2253
2254     # It is the responsibility of the user to correctly adjust all
2255     # symlinks.  If somebody can figure out how to handle them correctly
2256     # here, feel free to add the code.
2257
2258     echo $1 > $2/COPIED
2259   fi
2260   shift; shift
2261 done
2262
2263 # Determine a target-dependent exec_prefix that the installed
2264 # gcc will search in.  Keep this list sorted by triplet, with
2265 # the *-*-osname triplets last.
2266 md_exec_prefix=
2267 case "${target}" in
2268   i[[34567]]86-pc-msdosdjgpp*)
2269     md_exec_prefix=/dev/env/DJDIR/bin
2270     ;;
2271   *-*-hpux* | \
2272   *-*-nto-qnx* | \
2273   *-*-solaris2*)
2274     md_exec_prefix=/usr/ccs/bin
2275     ;;
2276 esac
2277
2278 extra_arflags_for_target=
2279 extra_nmflags_for_target=
2280 extra_ranlibflags_for_target=
2281 target_makefile_frag=/dev/null
2282 case "${target}" in
2283   spu-*-*)
2284     target_makefile_frag="config/mt-spu"
2285     ;;
2286   mips*-sde-elf* | mips*-mti-elf*)
2287     target_makefile_frag="config/mt-sde"
2288     ;;
2289   mipsisa*-*-elfoabi*)
2290     target_makefile_frag="config/mt-mips-elfoabi"
2291     ;;
2292   mips*-*-*linux* | mips*-*-gnu*)
2293     target_makefile_frag="config/mt-mips-gnu"
2294     ;;
2295   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2296     target_makefile_frag="config/mt-gnu"
2297     ;;
2298   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2299     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2300     # commands to handle both 32-bit and 64-bit objects.  These flags are
2301     # harmless if we're using GNU nm or ar.
2302     extra_arflags_for_target=" -X32_64"
2303     extra_nmflags_for_target=" -B -X32_64"
2304     ;;
2305 esac
2306
2307 alphaieee_frag=/dev/null
2308 case $target in
2309   alpha*-*-*)
2310     # This just makes sure to use the -mieee option to build target libs.
2311     # This should probably be set individually by each library.
2312     alphaieee_frag="config/mt-alphaieee"
2313     ;;
2314 esac
2315
2316 # If --enable-target-optspace always use -Os instead of -O2 to build
2317 # the target libraries, similarly if it is not specified, use -Os
2318 # on selected platforms.
2319 ospace_frag=/dev/null
2320 case "${enable_target_optspace}:${target}" in
2321   yes:*)
2322     ospace_frag="config/mt-ospace"
2323     ;;
2324   :d30v-*)
2325     ospace_frag="config/mt-d30v"
2326     ;;
2327   :m32r-* | :d10v-* | :fr30-*)
2328     ospace_frag="config/mt-ospace"
2329     ;;
2330   no:* | :*)
2331     ;;
2332   *)
2333     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2334     ;;
2335 esac
2336
2337 # Some systems (e.g., one of the i386-aix systems the gas testers are
2338 # using) don't handle "\$" correctly, so don't use it here.
2339 tooldir='${exec_prefix}'/${target_noncanonical}
2340 build_tooldir=${tooldir}
2341
2342 # Create a .gdbinit file which runs the one in srcdir
2343 # and tells GDB to look there for source files.
2344
2345 if test -r ${srcdir}/.gdbinit ; then
2346   case ${srcdir} in
2347     .) ;;
2348     *) cat > ./.gdbinit <<EOF
2349 # ${NO_EDIT}
2350 dir ${srcdir}
2351 dir .
2352 source ${srcdir}/.gdbinit
2353 EOF
2354     ;;
2355   esac
2356 fi
2357
2358 # Make sure that the compiler is able to generate an executable.  If it
2359 # can't, we are probably in trouble.  We don't care whether we can run the
2360 # executable--we might be using a cross compiler--we only care whether it
2361 # can be created.  At this point the main configure script has set CC.
2362 we_are_ok=no
2363 echo "int main () { return 0; }" > conftest.c
2364 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2365 if test $? = 0 ; then
2366   if test -s conftest || test -s conftest.exe ; then
2367     we_are_ok=yes
2368   fi
2369 fi
2370 case $we_are_ok in
2371   no)
2372     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2373     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2374     rm -f conftest*
2375     exit 1
2376     ;;
2377 esac
2378 rm -f conftest*
2379
2380 # Decide which environment variable is used to find dynamic libraries.
2381 case "${host}" in
2382   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2383   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2384   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2385   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2386 esac
2387
2388 # On systems where the dynamic library environment variable is PATH,
2389 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2390 # built executables to PATH.
2391 if test "$RPATH_ENVVAR" = PATH; then
2392   GCC_SHLIB_SUBDIR=/shlib
2393 else
2394   GCC_SHLIB_SUBDIR=
2395 fi
2396
2397 # Record target_configdirs and the configure arguments for target and
2398 # build configuration in Makefile.
2399 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2400 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2401
2402 # If we are building libgomp, bootstrap it.
2403 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2404   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2405 fi
2406
2407 # Determine whether gdb needs tk/tcl or not.
2408 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2409 # and in that case we want gdb to be built without tk.  Ugh!
2410 # In fact I believe gdb is the *only* package directly dependent on tk,
2411 # so we should be able to put the 'maybe's in unconditionally and
2412 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2413 # 100% sure that that's safe though.
2414
2415 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2416 case "$enable_gdbtk" in
2417   no)
2418     GDB_TK="" ;;
2419   yes)
2420     GDB_TK="${gdb_tk}" ;;
2421   *)
2422     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2423     # distro.  Eventually someone will fix this and move Insight, nee
2424     # gdbtk to a separate directory.
2425     if test -d ${srcdir}/gdb/gdbtk ; then
2426       GDB_TK="${gdb_tk}"
2427     else
2428       GDB_TK=""
2429     fi
2430     ;;
2431 esac
2432 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2433 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2434
2435 # Strip out unwanted targets.
2436
2437 # While at that, we remove Makefiles if we were started for recursive
2438 # configuration, so that the top-level Makefile reconfigures them,
2439 # like we used to do when configure itself was recursive.
2440
2441 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2442 # but now we're fixing up the Makefile ourselves with the additional
2443 # commands passed to AC_CONFIG_FILES.  Use separate variables
2444 # extrasub-{build,host,target} not because there is any reason to split
2445 # the substitutions up that way, but only to remain below the limit of
2446 # 99 commands in a script, for HP-UX sed.
2447 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2448
2449 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2450   yes:yes:*\ gold\ *:*,c++,*) ;;
2451   yes:yes:*\ gold\ *:*)
2452     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2453     ;;
2454 esac
2455
2456 # Adjust the toplevel makefile according to whether bootstrap was selected.
2457 case $enable_bootstrap in
2458   yes)
2459     bootstrap_suffix=bootstrap
2460     BUILD_CONFIG=bootstrap-debug
2461     ;;
2462   no)
2463     bootstrap_suffix=no-bootstrap
2464     BUILD_CONFIG=
2465     ;;
2466 esac
2467
2468 AC_MSG_CHECKING(for default BUILD_CONFIG)
2469
2470 AC_ARG_WITH([build-config],
2471   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2472                   [use config/NAME.mk build configuration])],
2473   [case $with_build_config in
2474    yes) with_build_config= ;;
2475    no) with_build_config= BUILD_CONFIG= ;;
2476    esac])
2477
2478 if test "x${with_build_config}" != x; then
2479   BUILD_CONFIG=$with_build_config
2480 else
2481   case $BUILD_CONFIG in
2482   bootstrap-debug)
2483     if echo "int f (void) { return 0; }" > conftest.c &&
2484        ${CC} -c conftest.c &&
2485        mv conftest.o conftest.o.g0 &&
2486        ${CC} -c -g conftest.c &&
2487        mv conftest.o conftest.o.g &&
2488        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2489       :
2490     else
2491       BUILD_CONFIG=
2492     fi
2493     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2494     ;;
2495   esac
2496 fi
2497 AC_MSG_RESULT($BUILD_CONFIG)
2498 AC_SUBST(BUILD_CONFIG)
2499
2500 extrasub_build=
2501 for module in ${build_configdirs} ; do
2502   if test -z "${no_recursion}" \
2503      && test -f ${build_subdir}/${module}/Makefile; then
2504     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2505     rm -f ${build_subdir}/${module}/Makefile
2506   fi
2507   extrasub_build="$extrasub_build
2508 /^@if build-$module\$/d
2509 /^@endif build-$module\$/d
2510 /^@if build-$module-$bootstrap_suffix\$/d
2511 /^@endif build-$module-$bootstrap_suffix\$/d"
2512 done
2513 extrasub_host=
2514 for module in ${configdirs} ; do
2515   if test -z "${no_recursion}"; then
2516     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2517       if test -f ${file}; then
2518         echo 1>&2 "*** removing ${file} to force reconfigure"
2519         rm -f ${file}
2520       fi
2521     done
2522   fi
2523   extrasub_host="$extrasub_host
2524 /^@if $module\$/d
2525 /^@endif $module\$/d
2526 /^@if $module-$bootstrap_suffix\$/d
2527 /^@endif $module-$bootstrap_suffix\$/d"
2528 done
2529 extrasub_target=
2530 for module in ${target_configdirs} ; do
2531   if test -z "${no_recursion}" \
2532      && test -f ${target_subdir}/${module}/Makefile; then
2533     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2534     rm -f ${target_subdir}/${module}/Makefile
2535   fi
2536
2537   # We only bootstrap target libraries listed in bootstrap_target_libs.
2538   case $bootstrap_target_libs in
2539     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2540     *) target_bootstrap_suffix=no-bootstrap ;;
2541   esac
2542
2543   extrasub_target="$extrasub_target
2544 /^@if target-$module\$/d
2545 /^@endif target-$module\$/d
2546 /^@if target-$module-$target_bootstrap_suffix\$/d
2547 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2548 done
2549
2550 # Do the final fixup along with target modules.
2551 extrasub_target="$extrasub_target
2552 /^@if /,/^@endif /d"
2553
2554 # Create the serialization dependencies.  This uses a temporary file.
2555
2556 AC_ARG_ENABLE([serial-configure],
2557 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2558                 [force sequential configuration of
2559                  sub-packages for the host, target or build
2560                  machine, or all sub-packages])])
2561
2562 case ${enable_serial_configure} in
2563   yes)
2564     enable_serial_build_configure=yes
2565     enable_serial_host_configure=yes
2566     enable_serial_target_configure=yes
2567     ;;
2568 esac
2569
2570 # These force 'configure's to be done one at a time, to avoid problems
2571 # with contention over a shared config.cache.
2572 rm -f serdep.tmp
2573 echo '# serdep.tmp' > serdep.tmp
2574 olditem=
2575 test "x${enable_serial_build_configure}" = xyes &&
2576 for item in ${build_configdirs} ; do
2577   case ${olditem} in
2578     "") ;;
2579     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2580   esac
2581   olditem=${item}
2582 done
2583 olditem=
2584 test "x${enable_serial_host_configure}" = xyes &&
2585 for item in ${configdirs} ; do
2586   case ${olditem} in
2587     "") ;;
2588     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2589   esac
2590   olditem=${item}
2591 done
2592 olditem=
2593 test "x${enable_serial_target_configure}" = xyes &&
2594 for item in ${target_configdirs} ; do
2595   case ${olditem} in
2596     "") ;;
2597     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2598   esac
2599   olditem=${item}
2600 done
2601 serialization_dependencies=serdep.tmp
2602 AC_SUBST_FILE(serialization_dependencies)
2603
2604 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2605 # target, nonopt, and variable assignments.  These are the ones we
2606 # might not want to pass down to subconfigures.  The exception being
2607 # --cache-file=/dev/null, which is used to turn off the use of cache
2608 # files altogether, and which should be passed on to subconfigures.
2609 # Also strip program-prefix, program-suffix, and program-transform-name,
2610 # so that we can pass down a consistent program-transform-name.
2611 baseargs=
2612 tbaseargs=
2613 keep_next=no
2614 skip_next=no
2615 eval "set -- $ac_configure_args"
2616 for ac_arg
2617 do
2618   if test X"$skip_next" = X"yes"; then
2619     skip_next=no
2620     continue
2621   fi
2622   if test X"$keep_next" = X"yes"; then
2623     case $ac_arg in
2624       *\'*)
2625         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2626     esac
2627     baseargs="$baseargs '$ac_arg'"
2628     tbaseargs="$tbaseargs '$ac_arg'"
2629     keep_next=no
2630     continue
2631   fi
2632
2633   # Handle separated arguments.  Based on the logic generated by
2634   # autoconf 2.59.
2635   case $ac_arg in
2636     *=* | --config-cache | -C | -disable-* | --disable-* \
2637       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2638       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2639       | -with-* | --with-* | -without-* | --without-* | --x)
2640       separate_arg=no
2641       ;;
2642     -*)
2643       separate_arg=yes
2644       ;;
2645     *)
2646       separate_arg=no
2647       ;;
2648   esac
2649
2650   skip_targ=no
2651   case $ac_arg in
2652 changequote(,)
2653   --with-* | --without-*)
2654     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2655
2656     case $libopt in
2657     *[-_]include)
2658       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2659       ;;
2660     *[-_]lib)
2661       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2662       ;;
2663     *)
2664       lib=$libopt
2665       ;;
2666     esac
2667 changequote([,])
2668
2669     case $lib in
2670     mpc | mpfr | gmp | cloog)
2671       # If we're processing --with-$lib, --with-$lib-include or
2672       # --with-$lib-lib, for one of the libs above, and target is
2673       # different from host, don't pass the current argument to any
2674       # target library's configure.
2675       if test x$is_cross_compiler = xyes; then
2676         skip_targ=yes
2677       fi
2678       ;;
2679     esac
2680     ;;
2681   esac
2682
2683   case "$ac_arg" in
2684     --cache-file=/dev/null | \
2685     -cache-file=/dev/null )
2686       # Handled here to avoid the test to skip args below.
2687       baseargs="$baseargs '$ac_arg'"
2688       tbaseargs="$tbaseargs '$ac_arg'"
2689       # Assert: $separate_arg should always be no.
2690       keep_next=$separate_arg
2691       ;;
2692     --no*)
2693       continue
2694       ;;
2695     --c* | \
2696     --sr* | \
2697     --ho* | \
2698     --bu* | \
2699     --t* | \
2700     --program-* | \
2701     -cache_file* | \
2702     -srcdir* | \
2703     -host* | \
2704     -build* | \
2705     -target* | \
2706     -program-prefix* | \
2707     -program-suffix* | \
2708     -program-transform-name* )
2709       skip_next=$separate_arg
2710       continue
2711       ;;
2712     -*)
2713       # An option.  Add it.
2714       case $ac_arg in
2715         *\'*)
2716           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2717       esac
2718       baseargs="$baseargs '$ac_arg'"
2719       if test X"$skip_targ" = Xno; then
2720         tbaseargs="$tbaseargs '$ac_arg'"
2721       fi
2722       keep_next=$separate_arg
2723       ;;
2724     *)
2725       # Either a variable assignment, or a nonopt (triplet).  Don't
2726       # pass it down; let the Makefile handle this.
2727       continue
2728       ;;
2729   esac
2730 done
2731 # Remove the initial space we just introduced and, as these will be
2732 # expanded by make, quote '$'.
2733 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2734
2735 # Add in --program-transform-name, after --program-prefix and
2736 # --program-suffix have been applied to it.  Autoconf has already
2737 # doubled dollar signs and backslashes in program_transform_name; we want
2738 # the backslashes un-doubled, and then the entire thing wrapped in single
2739 # quotes, because this will be expanded first by make and then by the shell.
2740 # Also, because we want to override the logic in subdir configure scripts to
2741 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2742 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2743 ${program_transform_name}
2744 EOF_SED
2745 gcc_transform_name=`cat conftestsed.out`
2746 rm -f conftestsed.out
2747 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2748 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2749 if test "$silent" = yes; then
2750   baseargs="$baseargs --silent"
2751   tbaseargs="$tbaseargs --silent"
2752 fi
2753 baseargs="$baseargs --disable-option-checking"
2754 tbaseargs="$tbaseargs --disable-option-checking"
2755
2756 # Record and document user additions to sub configure arguments.
2757 AC_ARG_VAR([build_configargs],
2758            [additional configure arguments for build directories])
2759 AC_ARG_VAR([host_configargs],
2760            [additional configure arguments for host directories])
2761 AC_ARG_VAR([target_configargs],
2762            [additional configure arguments for target directories])
2763
2764 # For the build-side libraries, we just need to pretend we're native,
2765 # and not use the same cache file.  Multilibs are neither needed nor
2766 # desired.
2767 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2768
2769 # For host modules, accept cache file option, or specification as blank.
2770 case "${cache_file}" in
2771 "") # empty
2772   cache_file_option="" ;;
2773 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2774   cache_file_option="--cache-file=${cache_file}" ;;
2775 *) # relative path
2776   cache_file_option="--cache-file=../${cache_file}" ;;
2777 esac
2778
2779 # Host dirs don't like to share a cache file either, horribly enough.
2780 # This seems to be due to autoconf 2.5x stupidity.
2781 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2782
2783 target_configargs="$target_configargs ${tbaseargs}"
2784
2785 # Passing a --with-cross-host argument lets the target libraries know
2786 # whether they are being built with a cross-compiler or being built
2787 # native.  However, it would be better to use other mechanisms to make the
2788 # sorts of decisions they want to make on this basis.  Please consider
2789 # this option to be deprecated.  FIXME.
2790 if test x${is_cross_compiler} = xyes ; then
2791   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2792 fi
2793
2794 # Default to --enable-multilib.
2795 if test x${enable_multilib} = x ; then
2796   target_configargs="--enable-multilib ${target_configargs}"
2797 fi
2798
2799 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2800 # changed from the earlier setting of with_newlib.
2801 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2802   target_configargs="--with-newlib ${target_configargs}"
2803 fi
2804
2805 # Different target subdirs use different values of certain variables
2806 # (notably CXX).  Worse, multilibs use *lots* of different values.
2807 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2808 # it doesn't automatically accept command-line overrides of them.
2809 # This means it's not safe for target subdirs to share a cache file,
2810 # which is disgusting, but there you have it.  Hopefully this can be
2811 # fixed in future.  It's still worthwhile to use a cache file for each
2812 # directory.  I think.
2813
2814 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2815 # We need to pass --target, as newer autoconf's requires consistency
2816 # for target_alias and gcc doesn't manage it consistently.
2817 target_configargs="--cache-file=./config.cache ${target_configargs}"
2818
2819 FLAGS_FOR_TARGET=
2820 case " $target_configdirs " in
2821  *" newlib "*)
2822   case " $target_configargs " in
2823   *" --with-newlib "*)
2824    case "$target" in
2825     *-cygwin*)
2826       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2827       ;;
2828    esac
2829
2830    # If we're not building GCC, don't discard standard headers.
2831    if test -d ${srcdir}/gcc; then
2832      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2833
2834      if test "${build}" != "${host}"; then
2835        # On Canadian crosses, CC_FOR_TARGET will have already been set
2836        # by `configure', so we won't have an opportunity to add -Bgcc/
2837        # to it.  This is right: we don't want to search that directory
2838        # for binaries, but we want the header files in there, so add
2839        # them explicitly.
2840        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2841
2842        # Someone might think of using the pre-installed headers on
2843        # Canadian crosses, in case the installed compiler is not fully
2844        # compatible with the compiler being built.  In this case, it
2845        # would be better to flag an error than risking having
2846        # incompatible object files being constructed.  We can't
2847        # guarantee that an error will be flagged, but let's hope the
2848        # compiler will do it, when presented with incompatible header
2849        # files.
2850      fi
2851    fi
2852
2853    case "${target}-${is_cross_compiler}" in
2854    i[[3456789]]86-*-linux*-no)
2855       # Here host == target, so we don't need to build gcc,
2856       # so we don't want to discard standard headers.
2857       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2858       ;;
2859    *)
2860       # If we're building newlib, use its generic headers last, but search
2861       # for any libc-related directories first (so make it the last -B
2862       # switch).
2863       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2864
2865       # If we're building libgloss, find the startup file, simulator library
2866       # and linker script.
2867       case " $target_configdirs " in
2868         *" libgloss "*)
2869         # Look for startup file, simulator library and maybe linker script.
2870         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2871         # Look for libnosys.a in case the target needs it.
2872         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2873         # Most targets have the linker script in the source directory.
2874         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2875         ;;
2876       esac
2877       ;;
2878    esac
2879    ;;
2880   esac
2881   ;;
2882 esac
2883
2884 case "$target" in
2885   x86_64-*mingw* | *-w64-mingw*)
2886   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2887   # however, use a symlink named 'mingw' in ${prefix} .
2888     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2889     ;;
2890   *-mingw*)
2891   # MinGW can't be handled as Cygwin above since it does not use newlib.
2892     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2893     ;;
2894 esac
2895
2896 # Allow the user to override the flags for
2897 # our build compiler if desired.
2898 if test x"${build}" = x"${host}" ; then
2899   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2900   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2901   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2902 fi
2903
2904 # On Canadian crosses, we'll be searching the right directories for
2905 # the previously-installed cross compiler, so don't bother to add
2906 # flags for directories within the install tree of the compiler
2907 # being built; programs in there won't even run.
2908 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2909   # Search for pre-installed headers if nothing else fits.
2910   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2911 fi
2912
2913 if test "x${use_gnu_ld}" = x &&
2914    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2915   # Arrange for us to find uninstalled linker scripts.
2916   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2917 fi
2918
2919 # Search for other target-specific linker scripts and such.
2920 case "${target}" in
2921   mep*)
2922     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2923     ;;
2924 esac
2925
2926 # Makefile fragments.
2927 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2928 do
2929   eval fragval=\$$frag
2930   if test $fragval != /dev/null; then
2931     eval $frag=${srcdir}/$fragval
2932   fi
2933 done
2934 AC_SUBST_FILE(host_makefile_frag)
2935 AC_SUBST_FILE(target_makefile_frag)
2936 AC_SUBST_FILE(alphaieee_frag)
2937 AC_SUBST_FILE(ospace_frag)
2938
2939 # Miscellanea: directories, flags, etc.
2940 AC_SUBST(RPATH_ENVVAR)
2941 AC_SUBST(GCC_SHLIB_SUBDIR)
2942 AC_SUBST(tooldir)
2943 AC_SUBST(build_tooldir)
2944 AC_SUBST(CONFIGURE_GDB_TK)
2945 AC_SUBST(GDB_TK)
2946 AC_SUBST(INSTALL_GDB_TK)
2947
2948 # Build module lists & subconfigure args.
2949 AC_SUBST(build_configargs)
2950 AC_SUBST(build_configdirs)
2951
2952 # Host module lists & subconfigure args.
2953 AC_SUBST(host_configargs)
2954 AC_SUBST(configdirs)
2955 AC_SUBST(target_configdirs)
2956
2957 # Target module lists & subconfigure args.
2958 AC_SUBST(target_configargs)
2959
2960
2961 # Build tools.
2962 AC_SUBST(AR_FOR_BUILD)
2963 AC_SUBST(AS_FOR_BUILD)
2964 AC_SUBST(CC_FOR_BUILD)
2965 AC_SUBST(CFLAGS_FOR_BUILD)
2966 AC_SUBST(CXXFLAGS_FOR_BUILD)
2967 AC_SUBST(CXX_FOR_BUILD)
2968 AC_SUBST(DLLTOOL_FOR_BUILD)
2969 AC_SUBST(GCJ_FOR_BUILD)
2970 AC_SUBST(GFORTRAN_FOR_BUILD)
2971 AC_SUBST(GOC_FOR_BUILD)
2972 AC_SUBST(LDFLAGS_FOR_BUILD)
2973 AC_SUBST(LD_FOR_BUILD)
2974 AC_SUBST(NM_FOR_BUILD)
2975 AC_SUBST(RANLIB_FOR_BUILD)
2976 AC_SUBST(WINDMC_FOR_BUILD)
2977 AC_SUBST(WINDRES_FOR_BUILD)
2978
2979 # Generate default definitions for YACC, M4, LEX and other programs that run
2980 # on the build machine.  These are used if the Makefile can't locate these
2981 # programs in objdir.
2982 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2983
2984 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2985 case " $build_configdirs " in
2986   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2987 esac
2988
2989 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2990 case " $build_configdirs " in
2991   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2992 esac
2993
2994 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2995 case " $build_configdirs " in
2996   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2997 esac
2998
2999 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3000 case " $build_configdirs " in
3001   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3002   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3003 esac
3004
3005 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3006 case " $build_configdirs " in
3007   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3008 esac
3009
3010 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3011 case " $build_configdirs " in
3012   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3013   *)
3014 changequote(,)
3015     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3016     # higher, else we use the "missing" dummy.
3017     if ${MAKEINFO} --version \
3018        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3019       :
3020     else
3021       MAKEINFO="$MISSING makeinfo"
3022     fi
3023     ;;
3024 changequote([,])
3025 esac
3026
3027 # FIXME: expect and dejagnu may become build tools?
3028
3029 AC_CHECK_PROGS(EXPECT, expect, expect)
3030 case " $configdirs " in
3031   *" expect "*)
3032     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3033     ;;
3034 esac
3035
3036 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3037 case " $configdirs " in
3038   *" dejagnu "*)
3039     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3040     ;;
3041 esac
3042
3043
3044 # Host tools.
3045 NCN_STRICT_CHECK_TOOLS(AR, ar)
3046 NCN_STRICT_CHECK_TOOLS(AS, as)
3047 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3048 NCN_STRICT_CHECK_TOOLS(LD, ld)
3049 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3050 NCN_STRICT_CHECK_TOOLS(NM, nm)
3051 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3052 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3053 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3054 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3055 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3056 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3057 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3058 AC_SUBST(CC)
3059 AC_SUBST(CXX)
3060 AC_SUBST(CFLAGS)
3061 AC_SUBST(CXXFLAGS)
3062
3063 # Target tools.
3064 AC_ARG_WITH([build-time-tools],
3065   [AS_HELP_STRING([--with-build-time-tools=PATH],
3066                   [use given path to find target tools during the build])],
3067   [case x"$withval" in
3068      x/*) ;;
3069      *)
3070        with_build_time_tools=
3071        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3072        ;;
3073    esac],
3074   [with_build_time_tools=])
3075
3076 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3077 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3078 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3079 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3080 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3081 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3082
3083 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3084 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3085 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3086 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3087 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3088 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3089 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3095
3096 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3097
3098 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3099 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3100 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3101 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3102 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3103                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3104                 c++)
3105 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3106                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3107                 c++)
3108 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3109 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3110 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3111                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3112 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3113                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3114 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3115                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3116 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3117 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3118 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3119 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3120 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3121 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3122 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3123 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3124 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3125
3126 AC_SUBST(FLAGS_FOR_TARGET)
3127 AC_SUBST(RAW_CXX_FOR_TARGET)
3128
3129 # Certain tools may need extra flags.
3130 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3131 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3132 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3133
3134 # When building target libraries, except in a Canadian cross, we use
3135 # the same toolchain as the compiler we just built.
3136 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3137 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3138 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3139 if test $host = $build; then
3140   case " $configdirs " in
3141     *" gcc "*)
3142       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3143       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3144       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3145       ;;
3146   esac
3147 fi
3148
3149 AC_SUBST(COMPILER_AS_FOR_TARGET)
3150 AC_SUBST(COMPILER_LD_FOR_TARGET)
3151 AC_SUBST(COMPILER_NM_FOR_TARGET)
3152
3153 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3154 AC_ARG_ENABLE(maintainer-mode,
3155 [AS_HELP_STRING([--enable-maintainer-mode],
3156                 [enable make rules and dependencies not useful
3157                  (and sometimes confusing) to the casual installer])],
3158       USE_MAINTAINER_MODE=$enableval,
3159       USE_MAINTAINER_MODE=no)
3160 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3161 AC_SUBST(MAINTAINER_MODE_TRUE)
3162 AC_SUBST(MAINTAINER_MODE_FALSE)
3163 if test "$USE_MAINTAINER_MODE" = yes; then
3164   MAINTAINER_MODE_TRUE=
3165   MAINTAINER_MODE_FALSE='#'
3166 else
3167   MAINTAINER_MODE_TRUE='#'
3168   MAINTAINER_MODE_FALSE=
3169 fi
3170 MAINT=$MAINTAINER_MODE_TRUE
3171 AC_SUBST(MAINT)dnl
3172
3173 # ---------------------
3174 # GCC bootstrap support
3175 # ---------------------
3176
3177 # Stage specific cflags for build.
3178 stage1_cflags="-g"
3179 case $build in
3180   vax-*-*)
3181     case ${GCC} in
3182       yes) stage1_cflags="-g -Wa,-J" ;;
3183       *) stage1_cflags="-g -J" ;;
3184     esac ;;
3185 esac
3186
3187 AC_SUBST(stage1_cflags)
3188
3189 # Enable --enable-checking in stage1 of the compiler.
3190 AC_ARG_ENABLE(stage1-checking,
3191 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3192                 [choose additional checking for stage1 of the compiler])],
3193 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3194 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3195   stage1_checking=--enable-checking=yes,types
3196 else
3197   stage1_checking=--enable-checking=$enable_checking,types
3198 fi])
3199 AC_SUBST(stage1_checking)
3200
3201 # Enable -Werror in bootstrap stage2 and later.
3202 AC_ARG_ENABLE(werror,
3203 [AS_HELP_STRING([--enable-werror],
3204                 [enable -Werror in bootstrap stage2 and later])], [],
3205 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3206   enable_werror=yes
3207 else
3208   enable_werror=no
3209 fi])
3210 case ${enable_werror} in
3211   yes) stage2_werror_flag="--enable-werror-always" ;;
3212   *) stage2_werror_flag="" ;;
3213 esac
3214 AC_SUBST(stage2_werror_flag)
3215
3216 # Specify what files to not compare during bootstrap.
3217
3218 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3219 case "$target" in
3220   hppa*64*-*-hpux*) ;;
3221   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3222   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3223 esac
3224 AC_SUBST(compare_exclusions)
3225
3226 AC_CONFIG_FILES([Makefile],
3227   [sed "$extrasub_build" Makefile |
3228    sed "$extrasub_host" |
3229    sed "$extrasub_target" > mf$$
3230    mv -f mf$$ Makefile],
3231   [extrasub_build="$extrasub_build"
3232    extrasub_host="$extrasub_host"
3233    extrasub_target="$extrasub_target"])
3234 AC_OUTPUT