configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(lightdm, 1.9.6)
   4 AC_CONFIG_MACRO_DIR(m4)
   5 AC_CONFIG_HEADER(config.h)
   6 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz foreign])
   7 AM_SILENT_RULES(yes)
   8 LT_INIT
   9 AM_PROG_CC_C_O
  10 AC_PROG_CXX
  11 AC_PROG_LIBTOOL
  12 AM_MAINTAINER_MODE
  13
  14 dnl Enable compile warnings (only supporting GCC)
  15 if test "x$GCC" == xyes; then
  16     WARN_CFLAGS="-Wall \
  17                  -Wstrict-prototypes \
  18                  -Wnested-externs \
  19                  -Werror=missing-prototypes \
  20                  -Werror=implicit-function-declaration \
  21                  -Werror=pointer-arith \
  22                  -Werror=init-self \
  23                  -Werror=format-security \
  24                  -Werror=format=2 \
  25                  -Werror=missing-include-dirs"
  26 fi
  27 AC_SUBST(WARN_CFLAGS)
  28
  29 GOBJECT_INTROSPECTION_CHECK(0.9.5)
  30
  31 dnl ###########################################################################
  32 dnl Dependencies
  33 dnl ###########################################################################
  34
  35 AC_CHECK_HEADERS(security/pam_appl.h, [], AC_MSG_ERROR(PAM not found))
  36
  37 AC_CHECK_FUNCS(setresgid setresuid clearenv)
  38
  39 PKG_CHECK_MODULES(LIGHTDM, [
  40     glib-2.0 >= 2.30
  41     gio-2.0 >= 2.26
  42     gio-unix-2.0
  43     xdmcp
  44     xcb
  45 ])
  46
  47 PKG_CHECK_MODULES(GLIB, [
  48     glib-2.0
  49 ])
  50
  51 PKG_CHECK_MODULES(GIO, [
  52     gio-2.0
  53 ])
  54
  55 PKG_CHECK_MODULES(GIO_UNIX, [
  56     gio-unix-2.0
  57 ])
  58
  59 PKG_CHECK_MODULES(GOBJECT, [
  60     gobject-2.0
  61 ])
  62
  63 PKG_CHECK_MODULES(XCB, [
  64     xcb
  65 ])
  66
  67 AC_ARG_ENABLE(liblightdm-gobject,
  68         AS_HELP_STRING([--enable-liblightdm-gobject],[Enable LightDM client gobject libraries [[default=auto]]]),
  69         [enable_liblightdm_gobject=$enableval],
  70         [enable_liblightdm_gobject="auto"])
  71 compile_liblightdm_gobject=no
  72 if test x"$enable_liblightdm_gobject" = "xauto"; then
  73     PKG_CHECK_MODULES(LIBLIGHTDM_GOBJECT, [
  74         glib-2.0
  75         gio-2.0 >= 2.26
  76         gio-unix-2.0
  77         gobject-2.0
  78         libxklavier
  79         x11
  80     ], compile_liblightdm_gobject=yes, compile_liblightdm_gobject=no)
  81 elif test x"$enable_liblightdm_gobject" = "xyes"; then
  82     PKG_CHECK_MODULES(LIBLIGHTDM_GOBJECT, [
  83         glib-2.0
  84         gio-2.0 >= 2.26
  85         gio-unix-2.0
  86         gobject-2.0
  87         libxklavier
  88         x11
  89     ])
  90     compile_liblightdm_gobject=yes
  91 fi
  92 AM_CONDITIONAL(COMPILE_LIBLIGHTDM_GOBJECT, test x"$compile_liblightdm_gobject" != "xno")
  93
  94 AC_ARG_ENABLE(liblightdm-qt,
  95         AS_HELP_STRING([--enable-liblightdm-qt],[Enable LightDM client Qt4 libraries [[default=auto]]]),
  96         [enable_liblightdm_qt4=$enableval],
  97         [enable_liblightdm_qt4="auto"])
  98 compile_liblightdm_qt4=no
  99 if test x"$enable_liblightdm_qt4" = "xyes" -o \( x"$enable_liblightdm_qt4" = "xauto" -a x$compile_liblightdm_gobject = xyes \) ; then
 100     PKG_CHECK_MODULES(LIBLIGHTDM_QT4, [
 101         QtCore
 102         QtDBus
 103         QtGui
 104     ],
 105     [compile_liblightdm_qt4=yes
 106      AC_CHECK_TOOLS(MOC4, [moc-qt4 moc])
 107      if test x"$(readlink $(which $MOC4))" = xqtchooser; then
 108          MOC4="$MOC4 --qt=qt4"
 109      fi
 110      if test "x$compile_liblightdm_gobject" != xyes; then
 111          AC_MSG_FAILURE(
 112            [liblightdm-gobject is required to compile liblightdm-qt])
 113      fi
 114     ],
 115     [if test "x$enable_liblightdm_qt4" != xauto; then
 116         AC_MSG_FAILURE(
 117           [--enable-liblightdm-qt was given, but test for Qt4 failed])
 118       fi
 119     ])
 120 fi
 121 AM_CONDITIONAL(COMPILE_LIBLIGHTDM_QT4, test x"$compile_liblightdm_qt4" != "xno")
 122
 123 AC_ARG_ENABLE(liblightdm-qt5,
 124         AS_HELP_STRING([--enable-liblightdm-qt5],[Enable LightDM client Qt5 libraries [[default=auto]]]),
 125         [enable_liblightdm_qt5=$enableval],
 126         [enable_liblightdm_qt5="auto"])
 127 compile_liblightdm_qt5=no
 128 if test x"$enable_liblightdm_qt5" != "xno"; then
 129     PKG_CHECK_MODULES(LIBLIGHTDM_QT5, [
 130         Qt5Core
 131         Qt5DBus
 132         Qt5Gui
 133     ],
 134     [compile_liblightdm_qt5=yes
 135      AC_CHECK_TOOLS(MOC5, [moc])
 136      if test x"$(readlink $(which $MOC5))" = xqtchooser; then
 137          MOC5="$MOC5 --qt=qt5"
 138      fi
 139     ],
 140     [if test "x$enable_liblightdm_qt5" != xauto; then
 141         AC_MSG_FAILURE(
 142           [--enable-liblightdm-qt5 was given, but test for Qt5 failed])
 143       fi
 144     ])
 145 fi
 146 AM_CONDITIONAL(COMPILE_LIBLIGHTDM_QT5, test x"$compile_liblightdm_qt5" != "xno")
 147
 148 AC_MSG_CHECKING(whether to build tests)
 149 AC_ARG_ENABLE(tests,
 150         AS_HELP_STRING([--disable-tests], [Disable tests building]),
 151         [], [enable_tests="yes"])
 152 AM_CONDITIONAL(COMPILE_TESTS, test x"$enable_tests" != "xno")
 153
 154 dnl ###########################################################################
 155 dnl Configurable values
 156 dnl ###########################################################################
 157
 158 USER_SESSION=default
 159 AC_ARG_WITH(user-session,
 160             AS_HELP_STRING(--with-user-session=<name>,
 161                            Session to use for user accounts),
 162     if test x$withval != x; then
 163         USER_SESSION="$withval"
 164     fi
 165 )
 166 AC_SUBST(USER_SESSION)
 167 AC_DEFINE_UNQUOTED(USER_SESSION, "$USER_SESSION", User session)
 168
 169 GREETER_SESSION=default
 170 AC_ARG_WITH(greeter-session,
 171             AS_HELP_STRING(--with-greeter-session=<session>,
 172                            Greeter session),
 173     if test x$withval != x; then
 174         GREETER_SESSION="$withval"
 175     fi
 176 )
 177 AC_SUBST(GREETER_SESSION)
 178 AC_DEFINE_UNQUOTED(GREETER_SESSION, "$GREETER_SESSION", Greeter session)
 179
 180 GREETER_USER=lightdm
 181 AC_ARG_WITH(greeter-user,
 182             AS_HELP_STRING(--with-greeter-user=<username>,
 183                            User to run greeter as),
 184     if test x$withval != x; then
 185         GREETER_USER="$withval"
 186     fi
 187 )
 188 AC_SUBST(GREETER_USER)
 189 AC_DEFINE_UNQUOTED(GREETER_USER, "$GREETER_USER", User to run greeter as)
 190
 191 dnl ###########################################################################
 192 dnl Documentation
 193 dnl ###########################################################################
 194
 195 GTK_DOC_CHECK
 196 YELP_HELP_INIT
 197
 198 dnl ###########################################################################
 199 dnl Internationalization
 200 dnl ###########################################################################
 201
 202 IT_PROG_INTLTOOL(0.35.0)
 203 AC_SUBST(GETTEXT_PACKAGE, lightdm)
 204 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", Gettext package)
 205
 206 dnl ###########################################################################
 207 dnl Files to generate
 208 dnl ###########################################################################
 209
 210 AC_CONFIG_FILES([
 211 Makefile
 212 data/Makefile
 213 doc/Makefile
 214 help/Makefile
 215 liblightdm-gobject/liblightdm-gobject-1.pc
 216 liblightdm-gobject/Makefile
 217 liblightdm-qt/Makefile
 218 liblightdm-qt/liblightdm-qt-3.pc
 219 liblightdm-qt/liblightdm-qt5-3.pc
 220 po/Makefile.in
 221 src/Makefile
 222 tests/Makefile
 223 tests/src/Makefile
 224 ])
 225 AC_OUTPUT
 226
 227 dnl ###########################################################################
 228 dnl Summary
 229 dnl ###########################################################################
 230
 231 echo "
 232                     Light Display Manager $VERSION
 233                     ===========================
 234
 235         prefix:                   $prefix
 236         Greeter session:          $GREETER_SESSION
 237         Greeter user:             $GREETER_USER
 238         User session:             $USER_SESSION
 239         liblightdm-gobject:       $compile_liblightdm_gobject
 240         GObject introspection:    $found_introspection
 241         liblightdm-qt:            $compile_liblightdm_qt4
 242         liblightdm-qt5:           $compile_liblightdm_qt5
 243         Enable tests:             $enable_tests
 244 "