lib/transport.tcl

   1 # git-gui transport (fetch/push) support
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 proc fetch_from {remote} {
   5         set w [console::new \
   6                 [mc "fetch %s" $remote] \
   7                 [mc "Fetching new changes from %s" $remote]]
   8         set cmds [list]
   9         lappend cmds [list exec git fetch $remote]
  10         if {[is_config_true gui.pruneduringfetch]} {
  11                 lappend cmds [list exec git remote prune $remote]
  12         }
  13         console::chain $w $cmds
  14 }
  15
  16 proc prune_from {remote} {
  17         set w [console::new \
  18                 [mc "remote prune %s" $remote] \
  19                 [mc "Pruning tracking branches deleted from %s" $remote]]
  20         console::exec $w [list git remote prune $remote]
  21 }
  22
  23 proc push_to {remote} {
  24         set w [console::new \
  25                 [mc "push %s" $remote] \
  26                 [mc "Pushing changes to %s" $remote]]
  27         set cmd [list git push]
  28         lappend cmd -v
  29         lappend cmd $remote
  30         console::exec $w $cmd
  31 }
  32
  33 proc start_push_anywhere_action {w} {
  34         global push_urltype push_remote push_url push_thin push_tags
  35         global push_force
  36         global repo_config
  37
  38         set is_mirror 0
  39         set r_url {}
  40         switch -- $push_urltype {
  41         remote {
  42                 set r_url $push_remote
  43                 catch {set is_mirror $repo_config(remote.$push_remote.mirror)}
  44         }
  45         url {set r_url $push_url}
  46         }
  47         if {$r_url eq {}} return
  48
  49         set cmd [list git push]
  50         lappend cmd -v
  51         if {$push_thin} {
  52                 lappend cmd --thin
  53         }
  54         if {$push_force} {
  55                 lappend cmd --force
  56         }
  57         if {$push_tags} {
  58                 lappend cmd --tags
  59         }
  60         lappend cmd $r_url
  61         if {$is_mirror} {
  62                 set cons [console::new \
  63                         [mc "push %s" $r_url] \
  64                         [mc "Mirroring to %s" $r_url]]
  65         } else {
  66                 set cnt 0
  67                 foreach i [$w.source.l curselection] {
  68                         set b [$w.source.l get $i]
  69                         lappend cmd "refs/heads/$b:refs/heads/$b"
  70                         incr cnt
  71                 }
  72                 if {$cnt == 0} {
  73                         return
  74                 } elseif {$cnt == 1} {
  75                         set unit branch
  76                 } else {
  77                         set unit branches
  78                 }
  79
  80                 set cons [console::new \
  81                         [mc "push %s" $r_url] \
  82                         [mc "Pushing %s %s to %s" $cnt $unit $r_url]]
  83         }
  84         console::exec $cons $cmd
  85         destroy $w
  86 }
  87
  88 trace add variable push_remote write \
  89         [list radio_selector push_urltype remote]
  90
  91 proc do_push_anywhere {} {
  92         global all_remotes current_branch
  93         global push_urltype push_remote push_url push_thin push_tags
  94         global push_force use_ttk NS
  95
  96         set w .push_setup
  97         toplevel $w
  98         wm withdraw $w
  99         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
 100         pave_toplevel $w
 101
 102         ${NS}::label $w.header -text [mc "Push Branches"] \
 103                 -font font_uibold -anchor center
 104         pack $w.header -side top -fill x
 105
 106         ${NS}::frame $w.buttons
 107         ${NS}::button $w.buttons.create -text [mc Push] \
 108                 -default active \
 109                 -command [list start_push_anywhere_action $w]
 110         pack $w.buttons.create -side right
 111         ${NS}::button $w.buttons.cancel -text [mc "Cancel"] \
 112                 -default normal \
 113                 -command [list destroy $w]
 114         pack $w.buttons.cancel -side right -padx 5
 115         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
 116
 117         ${NS}::labelframe $w.source -text [mc "Source Branches"]
 118         slistbox $w.source.l \
 119                 -height 10 \
 120                 -width 70 \
 121                 -selectmode extended
 122         foreach h [load_all_heads] {
 123                 $w.source.l insert end $h
 124                 if {$h eq $current_branch} {
 125                         $w.source.l select set end
 126                         $w.source.l yview end
 127                 }
 128         }
 129         pack $w.source.l -side left -fill both -expand 1
 130         pack $w.source -fill both -expand 1 -pady 5 -padx 5
 131
 132         ${NS}::labelframe $w.dest -text [mc "Destination Repository"]
 133         if {$all_remotes ne {}} {
 134                 ${NS}::radiobutton $w.dest.remote_r \
 135                         -text [mc "Remote:"] \
 136                         -value remote \
 137                         -variable push_urltype
 138                 if {$use_ttk} {
 139                         ttk::combobox $w.dest.remote_m -state readonly \
 140                                 -exportselection false \
 141                                 -textvariable push_remote \
 142                                 -values $all_remotes
 143                 } else {
 144                         eval tk_optionMenu $w.dest.remote_m push_remote $all_remotes
 145                 }
 146                 grid $w.dest.remote_r $w.dest.remote_m -sticky w
 147                 if {[lsearch -sorted -exact $all_remotes origin] != -1} {
 148                         set push_remote origin
 149                 } else {
 150                         set push_remote [lindex $all_remotes 0]
 151                 }
 152                 set push_urltype remote
 153         } else {
 154                 set push_urltype url
 155         }
 156         ${NS}::radiobutton $w.dest.url_r \
 157                 -text [mc "Arbitrary Location:"] \
 158                 -value url \
 159                 -variable push_urltype
 160         ${NS}::entry $w.dest.url_t \
 161                 -width 50 \
 162                 -textvariable push_url \
 163                 -validate key \
 164                 -validatecommand {
 165                         if {%d == 1 && [regexp {\s} %S]} {return 0}
 166                         if {%d == 1 && [string length %S] > 0} {
 167                                 set push_urltype url
 168                         }
 169                         return 1
 170                 }
 171         grid $w.dest.url_r $w.dest.url_t -sticky we -padx {0 5}
 172         grid columnconfigure $w.dest 1 -weight 1
 173         pack $w.dest -anchor nw -fill x -pady 5 -padx 5
 174
 175         ${NS}::labelframe $w.options -text [mc "Transfer Options"]
 176         ${NS}::checkbutton $w.options.force \
 177                 -text [mc "Force overwrite existing branch (may discard changes)"] \
 178                 -variable push_force
 179         grid $w.options.force -columnspan 2 -sticky w
 180         ${NS}::checkbutton $w.options.thin \
 181                 -text [mc "Use thin pack (for slow network connections)"] \
 182                 -variable push_thin
 183         grid $w.options.thin -columnspan 2 -sticky w
 184         ${NS}::checkbutton $w.options.tags \
 185                 -text [mc "Include tags"] \
 186                 -variable push_tags
 187         grid $w.options.tags -columnspan 2 -sticky w
 188         grid columnconfigure $w.options 1 -weight 1
 189         pack $w.options -anchor nw -fill x -pady 5 -padx 5
 190
 191         set push_url {}
 192         set push_force 0
 193         set push_thin 0
 194         set push_tags 0
 195
 196         bind $w <Visibility> "grab $w; focus $w.buttons.create"
 197         bind $w <Key-Escape> "destroy $w"
 198         bind $w <Key-Return> [list start_push_anywhere_action $w]
 199         wm title $w [append "[appname] ([reponame]): " [mc "Push"]]
 200         wm deiconify $w
 201         tkwait window $w
 202 }