company-dabbrev.el

   1 ;;; company-dabbrev.el --- dabbrev-like company-mode completion back-end
   2
   3 ;; Copyright (C) 2009, 2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Nikolaj Schumacher
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22
  23 ;;; Commentary:
  24 ;;
  25
  26 ;;; Code:
  27
  28 (require 'company)
  29 (eval-when-compile (require 'cl))
  30
  31 (defgroup company-dabbrev nil
  32   "dabbrev-like completion back-end."
  33   :group 'company)
  34
  35 (defcustom company-dabbrev-other-buffers 'all
  36   "Determines whether `company-dabbrev' should search other buffers.
  37 If `all', search all other buffers.  If t, search buffers with the same
  38 major mode.
  39 See also `company-dabbrev-time-limit'."
  40   :type '(choice (const :tag "Off" nil)
  41                  (const :tag "Same major mode" t)
  42                  (const :tag "All" all)))
  43
  44 (defcustom company-dabbrev-time-limit .1
  45   "Determines how many seconds `company-dabbrev' should look for matches."
  46   :type '(choice (const :tag "Off" nil)
  47                  (number :tag "Seconds")))
  48
  49 (defcustom company-dabbrev-char-regexp "\\sw"
  50   "A regular expression matching the characters `company-dabbrev' looks for."
  51   :type 'regexp)
  52
  53 (defcustom company-dabbrev-ignore-case 'keep-prefix
  54   "The value of `ignore-case' returned by `company-dabbrev'.")
  55
  56 (defcustom company-dabbrev-downcase 'case-replace
  57   "Whether to downcase the returned candidates.
  58
  59 The value of nil means keep them as-is.
  60 `case-replace' means use the value of `case-replace'.
  61 Any other value means downcase.
  62
  63 If you set this value to nil, you may also want to set
  64 `company-dabbrev-ignore-case' to any value other than `keep-prefix'.")
  65
  66 (defcustom company-dabbrev-minimum-length (1+ company-minimum-prefix-length)
  67   "The minimum length for the string to be included.")
  68
  69 (defmacro company-dabrev--time-limit-while (test start limit &rest body)
  70   (declare (indent 3) (debug t))
  71   `(let ((company-time-limit-while-counter 0))
  72      (catch 'done
  73        (while ,test
  74          ,@body
  75          (and ,limit
  76               (eq (incf company-time-limit-while-counter) 25)
  77               (setq company-time-limit-while-counter 0)
  78               (> (float-time (time-since ,start)) ,limit)
  79               (throw 'done 'company-time-out))))))
  80
  81 (defsubst company-dabbrev--make-regexp (prefix)
  82   (concat "\\<" (if (equal prefix "")
  83               company-dabbrev-char-regexp
  84             (regexp-quote prefix))
  85           "\\(" company-dabbrev-char-regexp "\\)*\\>"))
  86
  87 (defun company-dabbrev--search-buffer (regexp pos symbols start limit
  88                                        ignore-comments)
  89   (save-excursion
  90     (let (match)
  91       (goto-char (if pos (1- pos) (point-min)))
  92       ;; search before pos
  93       (company-dabrev--time-limit-while (re-search-backward regexp nil t)
  94           start limit
  95         (setq match (match-string-no-properties 0))
  96         (if (and ignore-comments (company-in-string-or-comment))
  97             (re-search-backward "\\s<\\|\\s!\\|\\s\"\\|\\s|" nil t)
  98           (when (>= (length match) company-dabbrev-minimum-length)
  99             (push match symbols))))
 100       (goto-char (or pos (point-min)))
 101       ;; search after pos
 102       (company-dabrev--time-limit-while (re-search-forward regexp nil t)
 103           start limit
 104         (setq match (match-string-no-properties 0))
 105         (if (and ignore-comments (company-in-string-or-comment))
 106             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
 107           (when (>= (length match) company-dabbrev-minimum-length)
 108             (push match symbols))))
 109       symbols)))
 110
 111 (defun company-dabbrev--search (regexp &optional limit other-buffers
 112                                 ignore-comments)
 113   (let* ((start (current-time))
 114          (symbols (company-dabbrev--search-buffer regexp (point) nil start limit
 115                                                   ignore-comments)))
 116     (when other-buffers
 117       (dolist (buffer (delq (current-buffer) (buffer-list)))
 118         (and (or (eq other-buffers 'all)
 119                  (eq (buffer-local-value 'major-mode buffer) major-mode))
 120              (with-current-buffer buffer
 121                (setq symbols
 122                      (company-dabbrev--search-buffer regexp nil symbols start
 123                                                      limit ignore-comments))))
 124         (and limit
 125              (> (float-time (time-since start)) limit)
 126              (return))))
 127     symbols))
 128
 129 ;;;###autoload
 130 (defun company-dabbrev (command &optional arg &rest ignored)
 131   "dabbrev-like `company-mode' completion back-end."
 132   (interactive (list 'interactive))
 133   (case command
 134     (interactive (company-begin-backend 'company-dabbrev))
 135     (prefix (company-grab-word))
 136     (candidates
 137      (let ((words (company-dabbrev--search (company-dabbrev--make-regexp arg)
 138                                          company-dabbrev-time-limit
 139                                          company-dabbrev-other-buffers))
 140            (downcase-p (if (eq company-dabbrev-downcase 'case-replace)
 141                            case-replace
 142                          company-dabbrev-downcase)))
 143        (if downcase-p
 144            (mapcar 'downcase words)
 145          words)))
 146     (ignore-case company-dabbrev-ignore-case)
 147     (duplicates t)))
 148
 149 (provide 'company-dabbrev)
 150 ;;; company-dabbrev.el ends here