company-dabbrev-code.el

   1 ;;; company-dabbrev-code.el --- a dabbrev-like company-mode back-end for code
   2 ;;
   3 ;; Copyright (C) 2009 Nikolaj Schumacher
   4 ;;
   5 ;; This file is part of company 0.3.1.
   6 ;;
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License
   9 ;; as published by the Free Software Foundation; either version 2
  10 ;; of the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (require 'company)
  21 (eval-when-compile (require 'cl))
  22
  23 (defcustom company-dabbrev-code-modes
  24   '(asm-mode batch-file-mode c++-mode c-mode cperl-mode csharp-mode css-mode
  25     emacs-lisp-mode erlang-mode espresso-mode f90-mode fortran-mode
  26     haskell-mode java-mode javascript-mode jde-mode js2-mode lisp-mode
  27     lua-mode objc-mode perl-mode php-mode python-mode ruby-mode scheme-mode
  28     shell-script-mode)
  29   "*Modes that use `company-dabbrev-code'.
  30 In all these modes `company-dabbrev-code' will complete only symbols, not text
  31 in comments or strings.  In other modes `company-dabbrev-code' will pass control
  32 to other back-ends \(e.g. `company-dabbrev'\).
  33 Value t means complete in all modes."
  34   :group 'company
  35   :type '(choice (repeat (symbol :tag "Major mode"))
  36                  (const tag "All modes" t)))
  37
  38 (defcustom company-dabbrev-code-other-buffers .5
  39   "*Determines whether `company-dabbrev-code' should search other buffers.
  40 If t, search all buffers with the same major-mode.  A numeric value means
  41 search other buffers for that many seconds and then return."
  42   :group 'company
  43   :type '(choice (const :tag "Off" nil)
  44                  (const :tag "Same major mode" t)
  45                  (number :tag "Seconds")))
  46
  47 (defun company-dabbrev-code--buffer-symbols (prefix pos &optional symbols
  48                                              start limit)
  49   (save-excursion
  50     (goto-char (point-min))
  51     (let ((regexp (concat "\\_<" (if (equal prefix "")
  52                                      "\\([a-zA-Z]\\|\\s_\\)"
  53                                    (regexp-quote prefix))
  54                           "\\(\\sw\\|\\s_\\)*\\_>"))
  55           (i 0)
  56           match)
  57       (while (re-search-forward regexp nil t)
  58         (setq match (match-string-no-properties 0))
  59         (if (company-in-string-or-comment)
  60             (re-search-forward "\\s>\\|\\s!\\|\\s\"" nil t)
  61           (unless (eq (match-end 0) pos) ;; ignore match before point
  62             (push match symbols)))
  63         (and limit
  64              (eq (incf i) 25)
  65              (setq i 0)
  66              (> (float-time (time-since start)) limit)
  67              (return symbols)))
  68       symbols)))
  69
  70 (defun company-dabbrev-code--symbols (prefix &optional limit)
  71   (let ((start (current-time))
  72         (symbols (company-dabbrev-code--buffer-symbols prefix (point))))
  73     (dolist (buffer (delq (current-buffer) (buffer-list)))
  74       (and (eq (buffer-local-value 'major-mode buffer) major-mode)
  75            (with-current-buffer buffer
  76              (setq symbols
  77                    (company-dabbrev-code--buffer-symbols prefix nil symbols
  78                                                          start limit))))
  79       (and limit
  80            (> (float-time (time-since start)) limit)
  81            (return)))
  82     symbols))
  83
  84 ;;;###autoload
  85 (defun company-dabbrev-code (command &optional arg &rest ignored)
  86   "A dabbrev-like `company-mode' back-end for code.
  87 The back-end looks for all symbols in the current buffer that aren't in
  88 comments or strings."
  89   (interactive (list 'interactive))
  90   (case command
  91     ('interactive (company-begin-backend 'company-dabbrev-code))
  92     ('prefix (and (or (eq t company-dabbrev-code-modes)
  93                       (apply 'derived-mode-p company-dabbrev-code-modes))
  94                   (not (company-in-string-or-comment))
  95                   (or (company-grab-symbol) 'stop)))
  96     ('candidates (let ((case-fold-search nil))
  97                    (if company-dabbrev-code-other-buffers
  98                        (company-dabbrev-code--symbols
  99                         arg
 100                         (when (numberp company-dabbrev-code-other-buffers)
 101                           company-dabbrev-code-other-buffers))
 102                      (company-dabbrev-code--buffer-symbols arg (point)))))
 103     ('duplicates t)))
 104
 105 (provide 'company-dabbrev-code)
 106 ;;; company-dabbrev-code.el ends here