opencv/CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # it _must_ go before PROJECT(OpenCV) in order to work
  15 if (NOT CMAKE_INSTALL_PREFIX)
  16     if (WIN32)
  17         set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR} CACHE INTERNAL "" FORCE)
  18     elseif()
  19         set(CMAKE_INSTALL_PREFIX "/usr" CACHE INTERNAL "" FORCE)
  20     endif()
  21 endif()
  22
  23 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  24 set(CMAKE_C_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  25 set(CMAKE_C_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  26 set(CMAKE_CXX_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  27 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  28 set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  29 set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  30 set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  31 set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  32 set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  33 set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  34
  35 project(OpenCV)
  36
  37 cmake_minimum_required(VERSION 2.4)
  38
  39 if(MSVC)
  40     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  41 endif()
  42
  43 # --------------------------------------------------------------
  44 # Indicate CMake 2.7 and above that we don't want to mix relative
  45 #  and absolute paths in linker lib lists.
  46 # Run "cmake --help-policy CMP0003" for more information.
  47 # --------------------------------------------------------------
  48 if(COMMAND cmake_policy)
  49     cmake_policy(SET CMP0003 NEW)
  50 endif()
  51
  52 # ----------------------------------------------------------------------------
  53 #  Current version number:
  54 # ----------------------------------------------------------------------------
  55 set(OPENCV_VERSION "1.1.0")
  56
  57 string(REGEX MATCHALL "[0-9]" OPENCV_VERSION_PARTS "${OPENCV_VERSION}")
  58
  59 list(GET OPENCV_VERSION_PARTS 0 OPENCV_VERSION_MAJOR)
  60 list(GET OPENCV_VERSION_PARTS 1 OPENCV_VERSION_MINOR)
  61 list(GET OPENCV_VERSION_PARTS 2 OPENCV_VERSION_PATCH)
  62
  63 set(OPENCV_SOVERSION "${OPENCV_VERSION_MAJOR}.${OPENCV_VERSION_MINOR}")
  64
  65 if(WIN32)
  66         # Postfix of DLLs:
  67         set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
  68         set(OPENCV_DEBUG_POSTFIX d)
  69 else()
  70         # Postfix of so's:
  71         #set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
  72         set(OPENCV_DLLVERSION "")
  73         set(OPENCV_DEBUG_POSTFIX)
  74 endif()
  75
  76
  77 # ----------------------------------------------------------------------------
  78 #  Variables for cvconfig.h.cmake
  79 # ----------------------------------------------------------------------------
  80 set(PACKAGE "opencv")
  81 set(PACKAGE_BUGREPORT "opencvlibrary-devel@lists.sourceforge.net")
  82 set(PACKAGE_NAME "opencv")
  83 set(PACKAGE_STRING "${PACKAGE} ${OPENCV_VERSION}")
  84 set(PACKAGE_TARNAME "${PACKAGE}")
  85 set(PACKAGE_VERSION "${OPENCV_VERSION}")
  86
  87 # ----------------------------------------------------------------------------
  88 #  Autodetect if we are in a SVN repository
  89 # ----------------------------------------------------------------------------
  90 find_program(SVNVERSION_PATH svnversion)
  91 mark_as_advanced(force SVNVERSION_PATH)
  92 if(SVNVERSION_PATH)
  93     message(STATUS "Extracting svn version, please wait...")
  94     execute_process(COMMAND ${SVNVERSION_PATH} -n ${CMAKE_SOURCE_DIR} OUTPUT_VARIABLE SVNVERSION_RESULT)
  95
  96     if(SVNVERSION_RESULT MATCHES "exported")
  97        # This is NOT a svn repository:
  98        set(OPENCV_SVNVERSION "")
  99     else()
 100         set(OPENCV_SVNVERSION " svn:${SVNVERSION_RESULT}")
 101     endif()
 102
 103     message(STATUS "SVNVERSION: ${OPENCV_SVNVERSION}")
 104 else()
 105     # We don't have svnversion:
 106     set(OPENCV_SVNVERSION "")
 107 endif()
 108
 109 # ----------------------------------------------------------------------------
 110 # Detect GNU version:
 111 # ----------------------------------------------------------------------------
 112 if(CMAKE_COMPILER_IS_GNUCXX)
 113     execute_process(COMMAND ${CMAKE_CXX_COMPILER} --version
 114                   OUTPUT_VARIABLE CMAKE_OPENCV_GCC_VERSION_FULL
 115                   OUTPUT_STRIP_TRAILING_WHITESPACE)
 116
 117     # Typical output in CMAKE_OPENCV_GCC_VERSION_FULL: "c+//0 (whatever) 4.2.3 (...)"
 118     #  Look for the version number
 119     string(REGEX MATCH "[0-9].[0-9].[0-9]" CMAKE_GCC_REGEX_VERSION "${CMAKE_OPENCV_GCC_VERSION_FULL}")
 120
 121     # Split the three parts:
 122     string(REGEX MATCHALL "[0-9]" CMAKE_OPENCV_GCC_VERSIONS "${CMAKE_GCC_REGEX_VERSION}")
 123
 124     list(GET CMAKE_OPENCV_GCC_VERSIONS 0 CMAKE_OPENCV_GCC_VERSION_MAJOR)
 125     list(GET CMAKE_OPENCV_GCC_VERSIONS 1 CMAKE_OPENCV_GCC_VERSION_MINOR)
 126
 127     set(CMAKE_OPENCV_GCC_VERSION ${CMAKE_OPENCV_GCC_VERSION_MAJOR}${CMAKE_OPENCV_GCC_VERSION_MINOR})
 128     message(STATUS "Detected version of GNU GCC: ${CMAKE_OPENCV_GCC_VERSION}")
 129 endif()
 130
 131 # ----------------------------------------------------------------------------
 132 #               CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 133 # ----------------------------------------------------------------------------
 134
 135 # Build/install (or not) some apps:
 136 # ===================================================
 137 set(BUILD_EXAMPLES OFF CACHE BOOL "Build all examples")
 138 set(INSTALL_C_EXAMPLES OFF CACHE BOOL "Install C examples")
 139 set(INSTALL_PYTHON_EXAMPLES OFF CACHE BOOL "Install Python examples")
 140 set(INSTALL_OCTAVE_EXAMPLES OFF CACHE BOOL "Install Octave examples")
 141
 142 # Build tests:
 143 # ===================================================
 144 set(BUILD_TESTS ON CACHE BOOL "Build tests")
 145
 146 # Build 3rdparty libraries under unix
 147 # ===================================================
 148 if(WIN32)
 149         set(OPENCV_BUILD_3RDPARTY_LIBS TRUE  CACHE BOOL "Build 3rd party libraries")
 150 else()
 151         set(OPENCV_BUILD_3RDPARTY_LIBS FALSE CACHE BOOL "Build 3rd party libraries")
 152 endif()
 153
 154 if(UNIX)
 155     include(OpenCVFindPkgConfig.cmake OPTIONAL)
 156     include(CheckFunctionExists)
 157     include(CheckIncludeFile)
 158 endif()
 159
 160 set(OPENCV_ENABLE_OPENMP OFF CACHE BOOL "")
 161
 162 if(CMAKE_COMPILER_IS_GNUCXX)
 163     set(OPENCV_ENABLE_PROFILING OFF CACHE BOOL "Enable profiling in the GCC compiler (Add flags: -g -pg)")
 164     set(OPENCV_USE_OMIT_FRAME_POINTER ON CACHE BOOL "Enable -fomit-frame-pointer for GCC")
 165     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES arm*)
 166         # We can use only -O2 because the -O3 causes gcc crash
 167         set(OPENCV_USE_O2 ON CACHE BOOL "Enable -O2 for GCC")
 168         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 169     endif()
 170     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES amd64*)
 171         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 172         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 173         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 174         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 175         set(OPENCV_USE_SSE2 ON CACHE BOOL "Enable SSE2 for GCC")
 176         set(OPENCV_USE_SSE3 ON CACHE BOOL "Enable SSE3 for GCC")
 177     endif()
 178     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES x86_64*)
 179         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 180         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 181         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 182         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 183         set(OPENCV_USE_SSE2 ON CACHE BOOL "Enable SSE2 for GCC")
 184         set(OPENCV_USE_SSE3 ON CACHE BOOL "Enable SSE3 for GCC")
 185     endif()
 186     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES powerpc*)
 187         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 188         set(OPENCV_USE_POWERPC ON CACHE BOOL "Enable PowerPC for GCC")
 189     endif ()
 190     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES i686*)
 191         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 192         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 193         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 194         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 195         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE2 for GCC")
 196     endif ()
 197     if(${CMAKE_SYSTEM_PROCESSOR} MATCHES x86)
 198         set(OPENCV_USE_O3 ON CACHE BOOL "Enable -O3 for GCC")
 199         set(OPENCV_USE_FAST_MATH ON CACHE BOOL "Enable -ffast-math for GCC")
 200         set(OPENCV_USE_MMX ON CACHE BOOL "Enable MMX for GCC")
 201         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE for GCC")
 202         set(OPENCV_USE_SSE ON CACHE BOOL "Enable SSE2 for GCC")
 203     endif ()
 204 endif()
 205
 206 # ===================================================
 207 # Macros that checks if module have been installed.
 208 # After it adds module to build and define
 209 # constants passed as second arg
 210 # ===================================================
 211
 212 macro(CHECK_MODULE module_name define)
 213     set(${define} 0)
 214     if(PKG_CONFIG_FOUND)
 215         set(ALIAS               ALIASOF_${module_name})
 216         set(ALIAS_FOUND                 ${ALIAS}_FOUND)
 217         set(ALIAS_INCLUDE_DIRS   ${ALIAS}_INCLUDE_DIRS)
 218         set(ALIAS_LIBRARY_DIRS   ${ALIAS}_LIBRARY_DIRS)
 219         set(ALIAS_LIBRARIES         ${ALIAS}_LIBRARIES)
 220
 221         PKG_CHECK_MODULES(${ALIAS} ${module_name})
 222
 223         if (${ALIAS_FOUND})
 224             set(${define} 1)
 225             foreach(P "${ALIAS_INCLUDE_DIRS}")
 226                 list(APPEND HIGHGUI_INCLUDE_DIRS ${${P}})
 227             endforeach()
 228
 229             foreach(P "${ALIAS_LIBRARY_DIRS}")
 230                 if (${${P}})
 231                     list(APPEND HIGHGUI_LIBRARY_DIRS ${${P}})
 232                 endif()
 233             endforeach()
 234
 235             list(APPEND HIGHGUI_LIBRARIES ${${ALIAS_LIBRARIES}})
 236         endif()
 237     endif()
 238 endmacro()
 239
 240 if(UNIX)
 241     if(NOT APPLE)
 242         CHECK_MODULE(gtk+-2.0 HAVE_GTK)
 243         CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
 244         CHECK_MODULE(gstreamer-base-0.10 HAVE_GSTREAMER)
 245     endif()
 246
 247     CHECK_MODULE(libunicap HAVE_UNICAP_)
 248     CHECK_MODULE(libucil HAVE_UNICAP_UCIL)
 249     if(HAVE_UNICAP_ AND HAVE_UNICAP_UCIL)
 250         set(HAVE_UNICAP 1)
 251     endif()
 252
 253     CHECK_MODULE(libavcodec HAVE_FFMPEG_CODEC)
 254     CHECK_MODULE(libavformat HAVE_FFMPEG_FORMAT)
 255     CHECK_MODULE(libavutil HAVE_FFMPEG_UTIL)
 256     CHECK_MODULE(libswscale HAVE_FFMPEG_SWSCALE)
 257     CHECK_INCLUDE_FILE(libavformat/avformat.h HAVE_GENTOO_FFMPEG)
 258     if(HAVE_FFMPEG_CODEC AND HAVE_FFMPEG_FORMAT AND HAVE_FFMPEG_UTIL)
 259         set(HAVE_FFMPEG 1)
 260     endif()
 261
 262     CHECK_MODULE(libdc1394-2 HAVE_DC1394_2)
 263     if(NOT HAVE_DC1394_2)
 264         CHECK_MODULE(libdc1394 HAVE_DC1394)
 265     endif()
 266
 267     if(NOT APPLE)
 268         CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 269         CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 270         CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 271         CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 272
 273         CHECK_MODULE(libxine HAVE_XINE)
 274                 CHECK_MODULE(libv4l1 HAVE_LIBV4L)
 275         CHECK_INCLUDE_FILE(linux/videodev.h HAVE_CAMV4L)
 276         CHECK_INCLUDE_FILE(linux/videodev2.h HAVE_CAMV4L2)
 277
 278                 if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 279                         include(FindPNG)
 280                         if(PNG_FOUND)
 281                                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/png.h HAVE_PNG_H)
 282                                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/libpng/png.h HAVE_LIBPNG_PNG_H)
 283                         endif()
 284                         include(FindJPEG)
 285                         include(FindTIFF)
 286                         include(FindJasper)
 287                 endif()
 288
 289         set(OPENCV_LINKER_LIBS dl m pthread rt)
 290     else()
 291         add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 292     endif()
 293 endif()
 294
 295 set(BUILD_PYTHON_SUPPORT OFF CACHE BOOL "Build with Python support")
 296 set(BUILD_OCTAVE_SUPPORT OFF CACHE BOOL "Build with Octave support")
 297
 298 find_package(SWIG)
 299 if(SWIG_FOUND)
 300
 301     find_package(PythonInterp)
 302     find_package(PythonLibs)
 303
 304     # cmake 2.4 (at least on Ubuntu 8.04 (hardy)) don't define PYTHONLIBS_FOUND
 305     if(NOT PYTHONLIBS_FOUND AND PYTHON_INCLUDE_PATH)
 306         set(PYTHONLIBS_FOUND ON)
 307     endif(NOT PYTHONLIBS_FOUND AND PYTHON_INCLUDE_PATH)
 308
 309     # Build with python if installed:
 310     # ===================================================
 311     if(PYTHONLIBS_FOUND AND BUILD_PYTHON_SUPPORT)
 312         execute_process(COMMAND ${PYTHON_EXECUTABLE} --version
 313                   ERROR_VARIABLE PYTHON_VERSION_FULL
 314                   OUTPUT_STRIP_TRAILING_WHITESPACE)
 315
 316         string(REGEX MATCH "[0-9].[0-9]" PYTHON_VERSION_MAJOR_MINOR "${PYTHON_VERSION_FULL}")
 317         if(UNIX)
 318             set(PYTHON_PLUGIN_INSTALL_PATH lib/python${PYTHON_VERSION_MAJOR_MINOR}/site-packages/opencv)
 319         endif()
 320         if(WIN32)
 321             get_filename_component(PYTHON_PATH "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Python\\PythonCore\\${PYTHON_VERSION_MAJOR_MINOR}\\InstallPath]" ABSOLUTE CACHE)
 322             set(PYTHON_PLUGIN_INSTALL_PATH "${PYTHON_PATH}/Lib/site-packages/opencv")
 323         endif()
 324     endif()
 325
 326 endif()
 327
 328 if(WIN32)
 329
 330 set(IPP_FOUND)
 331 foreach(v "6.1" "6.0" "5.3" "5.2" "5.1")
 332     if(NOT IPP_FOUND)
 333         find_path(IPP_PATH "ippi-${v}.dll"
 334             PATHS ${CMAKE_PROGRAM_PATH} ${CMAKE_SYSTEM_PROGRAM_PATH}
 335             DOC "The path to IPP DLLs")
 336         if(IPP_PATH)
 337             file(GLOB IPP_HDRS "${IPP_PATH}/../include")
 338             if(IPP_HDRS)
 339                 set(IPP_FOUND TRUE)
 340             endif()
 341         endif()
 342     endif()
 343 endforeach()
 344
 345 message(STATUS "IPP detected: ${IPP_FOUND}")
 346 set(USE_IPP ${IPP_FOUND} CACHE BOOL "Use IPP when available")
 347
 348 if(IPP_FOUND AND USE_IPP)
 349     add_definitions(-DHAVE_IPP)
 350     include_directories("${IPP_PATH}/../include")
 351     link_directories("${IPP_PATH}/../lib")
 352     set(IPP_LIBS ippsmerged.lib ippsemerged.lib ippimerged.lib ippiemerged.lib
 353         ippvmmerged.lib ippvmemerged.lib ippccmerged.lib ippccemerged.lib
 354         ippcvmerged.lib ippcvemerged.lib ippcorel.lib)
 355 endif()
 356
 357 endif()
 358
 359 # ----------------------------------------------------------------------------
 360 #                               UPDATE CONFIG FILES & SCRIPTS:
 361 #
 362 #  CONFIGURE_FILE(InputFile OutputFile [COPYONLY] [ESCAPE_QUOTES] [@ONLY])
 363 # If @ONLY is specified, only variables of the form @VAR@ will be
 364 #  replaces and ${VAR} will be ignored.
 365 #
 366 #  A directory will be created for each platform so the "cvconfig.h" file is
 367 #   not overwritten if cmake generates code in the same path.
 368 # ----------------------------------------------------------------------------
 369 add_definitions(-DHAVE_CONFIG_H)
 370
 371 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 372
 373 message(STATUS "Parsing 'cvconfig.h.cmake'")
 374 configure_file("${CMAKE_SOURCE_DIR}/cvconfig.h.cmake" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}/cvconfig.h")
 375
 376 # ---------------------------------------------------------------------------
 377 # The C+//0 include & link directories:
 378 # ---------------------------------------------------------------------------
 379 include_directories("."
 380     "${OPENCV_CONFIG_FILE_INCLUDE_DIR}"
 381     "${CMAKE_SOURCE_DIR}/include"
 382     "${CMAKE_SOURCE_DIR}/include/opencv"
 383     )
 384
 385 # ----------------------------------------------------------------------------
 386 #                       Set the maximum level of warnings:
 387 # ----------------------------------------------------------------------------
 388 # Should be set to true for development
 389 set(OPENCV_WARNINGS_ARE_ERRORS OFF CACHE BOOL "Treat warnings as errors")
 390
 391 # Whole program optimization?
 392 set(OPENCV_WHOLE_PROGRAM_OPTIMIZATION OFF CACHE BOOL "Flags for whole program optimization.")
 393
 394 set(EXTRA_C_FLAGS "")
 395 set(EXTRA_C_FLAGS_RELEASE "")
 396 set(EXTRA_C_FLAGS_DEBUG "")
 397 set(EXTRA_EXE_LINKER_FLAGS "")
 398 set(EXTRA_EXE_LINKER_FLAGS_RELEASE "")
 399 set(EXTRA_EXE_LINKER_FLAGS_DEBUG "")
 400
 401 if(MSVC)
 402     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} /W4 /D _CRT_SECURE_NO_DEPRECATE /D _CRT_NONSTDC_NO_DEPRECATE")
 403     # 64-bit portability warnings, in MSVC8
 404     if(MSVC80)
 405         set(OPENCV_EXTRA_C_FLAGS "${OPENCV_EXTRA_C_FLAGS} /Wp64")
 406     endif()
 407
 408     set(EXTRA_EXE_LINKER_FLAGS_RELEASE "${EXTRA_EXE_LINKER_FLAGS_RELEASE} /debug")
 409
 410     # Whole program optimization
 411     if(OPENCV_WHOLE_PROGRAM_OPTIMIZATION AND MSVC_VERSION GREATER 1300)
 412         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /GL")
 413         set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG")
 414         set(CMAKE_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE} /LTCG")
 415     endif()
 416
 417     if(OPENCV_ENABLE_OPENMP)
 418         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /openmp")
 419     endif()
 420
 421     # Remove unreferenced functions: function level linking
 422     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} /Gy")
 423     set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} /Zi")
 424 endif()
 425
 426 if(CMAKE_COMPILER_IS_GNUCXX)
 427     # High level of warnings.
 428     # The -Wno-long-long is required in 64bit systems when including sytem headers.
 429     set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -Wall")
 430
 431     # We need pthread's
 432     if(UNIX)
 433         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -pthread")
 434     endif()
 435
 436     if(OPENCV_WARNINGS_ARE_ERRORS)
 437         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -Werror")
 438     endif()
 439
 440     # Whole program optimization
 441     if(OPENCV_WHOLE_PROGRAM_OPTIMIZATION)
 442         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -fwhole-program --combine")
 443     endif()
 444
 445     # Other optimizations
 446     if(OPENCV_USE_OMIT_FRAME_POINTER)
 447        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -fomit-frame-pointer")
 448     endif()
 449     if(OPENCV_USE_O2)
 450        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -O2")
 451     endif()
 452     if(OPENCV_USE_O3)
 453        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -O3")
 454     endif()
 455     if(OPENCV_USE_FAST_MATH)
 456        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -ffast-math")
 457     endif()
 458     if(OPENCV_USE_POWERPC)
 459        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -mcpu=G3 -mtune=G5")
 460     endif()
 461     if(OPENCV_USE_MMX)
 462        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -mmmx")
 463     endif()
 464     # SSE should be disabled under MingW because it generates compiler errors
 465     if(OPENCV_USE_SSE)
 466        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse")
 467     endif()
 468     # SSE2 should be disabled under MingW because it generates compiler errors
 469     if(OPENCV_USE_SSE2)
 470        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse2")
 471     endif()
 472     # SSE3 should be disabled under MingW because it generates compiler errors
 473     if(OPENCV_USE_SSE3 AND NOT MINGW)
 474        set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -msse3")
 475     endif()
 476
 477     # Profiling?
 478     if(OPENCV_ENABLE_PROFILING)
 479         set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -pg -g")
 480     else()
 481         # Remove unreferenced functions: function level linking
 482         if(NOT APPLE)
 483             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -ffunction-sections")
 484         endif()
 485     endif()
 486
 487     # Parallel mode
 488     if(OPENCV_ENABLE_OPENMP)
 489         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -D_GLIBCXX_PARALLEL -fopenmp")
 490     endif()
 491
 492     set(EXTRA_C_FLAGS_RELEASE "${EXTRA_C_FLAGS_RELEASE} -DNDEBUG")
 493     set(EXTRA_C_FLAGS_DEBUG "${EXTRA_C_FLAGS_DEBUG} -O0 -DDEBUG -D_DEBUG")
 494 endif()
 495
 496
 497 # Add user supplied extra options (optimization, etc...)
 498 # ==========================================================
 499 set(OPENCV_EXTRA_C_FLAGS ${EXTRA_C_FLAGS} CACHE STRING "Extra compiler options" FORCE)
 500 set(OPENCV_EXTRA_C_FLAGS_RELEASE ${EXTRA_C_FLAGS_RELEASE} CACHE STRING "Extra compiler options for Release build" FORCE)
 501 set(OPENCV_EXTRA_C_FLAGS_DEBUG ${EXTRA_C_FLAGS_DEBUG} CACHE STRING "Extra compiler options for Debug build" FORCE)
 502 set(OPENCV_EXTRA_EXE_LINKER_FLAGS ${EXTRA_EXE_LINKER_FLAGS} CACHE STRING "Extra linker flags" FORCE)
 503 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE ${EXTRA_EXE_LINKER_FLAGS_RELEASE} CACHE STRING "Extra linker flags for Release build" FORCE)
 504 set(OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG ${EXTRA_EXE_LINKER_FLAGS_DEBUG} CACHE STRING "Extra linker flags for Debug build" FORCE)
 505
 506 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 507 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OPENCV_EXTRA_C_FLAGS}")
 508 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${OPENCV_EXTRA_C_FLAGS_RELEASE}")
 509 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${OPENCV_EXTRA_C_FLAGS_RELEASE}")
 510 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${OPENCV_EXTRA_C_FLAGS_DEBUG}")
 511 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${OPENCV_EXTRA_C_FLAGS_DEBUG}")
 512 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OPENCV_EXTRA_EXE_LINKER_FLAGS}")
 513 set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_RELEASE}")
 514 set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${OPENCV_EXTRA_EXE_LINKER_FLAGS_DEBUG}")
 515
 516 if("${CMAKE_CONFIGURE_LDFLAGS}")
 517     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_CONFIGURE_LDFLAGS}")
 518 endif("${CMAKE_CONFIGURE_LDFLAGS}")
 519
 520 # ----------------------------------------------------------------------------
 521 #                                       PROCESS SUBDIRECTORIES:
 522 # ----------------------------------------------------------------------------
 523 # Save libs and executables in the same place
 524 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/lib CACHE PATH "Output directory for libraries" )
 525 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/bin CACHE PATH "Output directory for applications" )
 526
 527 if(WIN32)
 528 set(OPENCV_DOC_INSTALL_PATH doc)
 529 else()
 530 set(OPENCV_DOC_INSTALL_PATH share/opencv/doc)
 531 endif()
 532
 533 #-----------------------------------
 534 # Subdirectories:
 535 #-----------------------------------
 536 add_subdirectory(src)
 537 add_subdirectory(apps)
 538 add_subdirectory(doc)
 539 add_subdirectory(data)
 540
 541 if(BUILD_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_OCTAVE_EXAMPLES)
 542     add_subdirectory(samples)
 543 endif()
 544
 545 if(BUILD_TESTS)
 546     enable_testing()
 547     add_subdirectory(tests)
 548 endif()
 549
 550 add_subdirectory(interfaces)
 551 add_subdirectory(3rdparty)
 552
 553 # --------------------------------------------------------------------------------------------
 554 #   Installation for CMake Module:  OpenCVConfig.cmake
 555 #  Part 1/3: ${BIN_DIR}/OpenCVConfig.cmake              -> For use *without* "make install"
 556 #  Part 2/3: ${BIN_DIR}/unix-install/OpenCVConfig.cmake -> For use with "make install"
 557 #  Part 3/3: ${BIN_DIR}/win-install/OpenCVConfig.cmake  -> For use within binary installers/packages
 558 # -------------------------------------------------------------------------------------------
 559
 560 # -------------------------------------------------------------------------------------------
 561 #  Part 1/2: ${BIN_DIR}/OpenCVConfig.cmake              -> For use *without* "make install"
 562 # -------------------------------------------------------------------------------------------
 563
 564 # Name of libraries is: libcv.so.1.1.0, etc...
 565 #  OPENCV_DLLVERSION must be set to "110", etc..
 566 # Already done above.
 567
 568 # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 569 set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE)
 570 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 571 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_SOURCE_DIR}/include")
 572 list(APPEND CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_SOURCE_DIR}/include/opencv")
 573
 574 set(CMAKE_LIB_DIRS_CONFIGCMAKE ${LIBRARY_OUTPUT_PATH})
 575
 576 configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 577
 578 # --------------------------------------------------------------------------------------------
 579 #  Part 2/2: ${BIN_DIR}/unix-install/OpenCVConfig.cmake -> For use *with* "make install"
 580 # -------------------------------------------------------------------------------------------
 581 # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 582
 583 set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE "${CMAKE_INSTALL_PREFIX}/include/opencv")
 584 set(CMAKE_LIB_DIRS_CONFIGCMAKE "${CMAKE_INSTALL_PREFIX}/lib")
 585
 586 #exec_program(${CMAKE_COMMAND} ARGS "-E make_directory \"${CMAKE_BINARY_DIR}/unix-install/\"")
 587 exec_program(mkdir ARGS "-p \"${CMAKE_BINARY_DIR}/unix-install/\"")
 588 configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/unix-install/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 589
 590 if(UNIX)
 591     # For a command "FIND_PACKAGE(FOO)", CMake will look at the directory /usr/share|lib/FOO/FOOConfig.cmake, so:
 592     install(FILES ${CMAKE_BINARY_DIR}/unix-install/OpenCVConfig.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/opencv/)
 593 endif()
 594
 595 # --------------------------------------------------------------------------------------------
 596 #  Part 3/3: ${BIN_DIR}/win-install/OpenCVConfig.cmake  -> For use within binary installers/packages
 597 # -------------------------------------------------------------------------------------------
 598 if(WIN32)
 599         # Set CMAKE_INCLUDE_DIRS_CONFIGCMAKE to the list of include directories:
 600
 601         # This will expand to, for example, <program files>/OpenCV 1.1.0/include
 602         set(CMAKE_INCLUDE_DIRS_CONFIGCMAKE "\"\${THIS_OPENCV_CONFIG_PATH}/include\"")
 603
 604         # This will expand to, for example, <program files>/OpenCV 1.1.0/lib
 605         set(CMAKE_LIB_DIRS_CONFIGCMAKE "\"\${THIS_OPENCV_CONFIG_PATH}/lib\"")
 606
 607         #exec_program(${CMAKE_COMMAND} ARGS "-E make_directory \"${CMAKE_BINARY_DIR}/win-install/\"")
 608         exec_program(mkdir ARGS "-p \"${CMAKE_BINARY_DIR}/win-install/\"")
 609         configure_file("${CMAKE_SOURCE_DIR}/OpenCVConfig.cmake.in" "${CMAKE_BINARY_DIR}/win-install/OpenCVConfig.cmake" IMMEDIATE @ONLY)
 610 endif()
 611
 612
 613 # --------------------------------------------------------------------------------------------
 614 #  Part 2/2: ${BIN_DIR}/unix-install/opencv.pc -> For use *with* "make install"
 615 # prefix=/usr
 616 # exec_prefix=${prefix}
 617 # libdir=${exec_prefix}/lib
 618 # includedir=${prefix}/include/opencv
 619 # -------------------------------------------------------------------------------------------
 620 set(prefix              ${CMAKE_INSTALL_PREFIX})
 621 set(exec_prefix         "\${prefix}")
 622 set(libdir              "\${exec_prefix}/lib")
 623 set(includedir          "\${prefix}/include")
 624 set(VERSION             ${OPENCV_VERSION})
 625
 626 configure_file("${CMAKE_SOURCE_DIR}/opencv.pc.cmake.in" "${CMAKE_BINARY_DIR}/unix-install/opencv.pc" @ONLY IMMEDIATE)
 627
 628 if(UNIX)
 629     install(FILES ${CMAKE_BINARY_DIR}/unix-install/opencv.pc DESTINATION lib/pkgconfig)
 630 endif()
 631
 632
 633 # ----------------------------------------------------------------------------
 634 #   Uninstall target, for "make uninstall"
 635 # ----------------------------------------------------------------------------
 636 CONFIGURE_FILE(
 637   "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
 638   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 639   IMMEDIATE @ONLY)
 640
 641 ADD_CUSTOM_TARGET(uninstall
 642   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 643
 644
 645 # ----------------------------------------------------------------------------
 646 #   CPack target
 647 # ----------------------------------------------------------------------------
 648
 649 option(BUILD_PACKAGE "Build a installer with the SDK")
 650
 651 if(BUILD_PACKAGE)
 652
 653         configure_file(
 654         Package.cmake.in
 655         ${CMAKE_BINARY_DIR}/.cpack/Package.cmake
 656         @ONLY
 657         )
 658
 659         install(FILES
 660                 AUTHORS
 661                 ChangeLog
 662                 COPYING
 663                 INSTALL
 664                 NEWS
 665                 README
 666                 THANKS
 667                 TODO
 668                 DESTINATION ${OPENCV_DOC_INSTALL_PATH}
 669         COMPONENT doc
 670                 )
 671
 672         include(${CMAKE_BINARY_DIR}/.cpack/Package.cmake)
 673
 674 endif()
 675
 676 # ----------------------------------------------------------------------------
 677 #   Sumary:
 678 # ----------------------------------------------------------------------------
 679 message(STATUS "")
 680 message(STATUS "General configuration for opencv ${OPENCV_VERSION} =====================================")
 681 message(STATUS "")
 682 message(STATUS "    Compiler:                  ${CMAKE_COMPILER}")
 683 message(STATUS "    C++ flags (Release):       ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
 684 message(STATUS "    C++ flags (Debug):         ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
 685 if(WIN32)
 686 message(STATUS "    Linker flags (Release):    ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 687 message(STATUS "    Linker flags (Debug):      ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG}")
 688 else()
 689 message(STATUS "    Linker flags (Release):    ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE}")
 690 message(STATUS "    Linker flags (Debug):      ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG}")
 691 endif()
 692
 693 if(UNIX)
 694 if(NOT APPLE)
 695 message(STATUS "")
 696 message(STATUS "  GUI: ")
 697 message(STATUS "    GTK+ 2.x:                  ${HAVE_GTK}")
 698 message(STATUS "    GThread:                   ${HAVE_GTHREAD}")
 699 message(STATUS "")
 700 if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 701 message(STATUS "  Image I/O: ")
 702 message(STATUS "    JPEG:                      ${JPEG_FOUND}")
 703 message(STATUS "    PNG:                       ${PNG_FOUND}")
 704 message(STATUS "    TIFF:                      ${TIFF_FOUND}")
 705 message(STATUS "    JASPER:                    ${JASPER_FOUND}")
 706 else()
 707 message(STATUS "  Image I/O: ")
 708 message(STATUS "    JPEG:                      build")
 709 message(STATUS "    PNG:                       build")
 710 message(STATUS "    TIFF:                      build")
 711 message(STATUS "    JASPER:                    build")
 712 endif()
 713 endif()
 714 message(STATUS "")
 715 message(STATUS "  Video I/O: ")
 716 message(STATUS "    DC1394 1.x:                ${HAVE_DC1394}")
 717 message(STATUS "    DC1394 2.x:                ${HAVE_DC1394_2}")
 718 message(STATUS "    FFMPEG:                    ${HAVE_FFMPEG}")
 719 message(STATUS "    GStreamer:                 ${HAVE_GSTREAMER}")
 720 message(STATUS "    UniCap:                    ${HAVE_UNICAP}")
 721 if(HAVE_LIBV4L)
 722 message(STATUS "    V4L/V4L2:                  Using libv4l")
 723 else()
 724 message(STATUS "    V4L/V4L2:                  ${HAVE_CAMV4L}/${HAVE_CAMV4L2}")
 725 endif()
 726 message(STATUS "    Xine:                      ${HAVE_XINE}")
 727 endif()
 728 message(STATUS "")
 729 message(STATUS "  Interfaces: ")
 730 if(PYTHONLIBS_FOUND AND BUILD_PYTHON_SUPPORT)
 731 message(STATUS "    Python:                    1")
 732 else()
 733 message(STATUS "    Python:                    0")
 734 endif()
 735 if(IPP_FOUND AND USE_IPP)
 736 message(STATUS "    Use IPP:                   1")
 737 else()
 738 message(STATUS "    Use IPP:                   0")
 739 endif()
 740 message(STATUS "")
 741 message(STATUS "    Install path:              ${CMAKE_INSTALL_PREFIX}")
 742 message(STATUS "")
 743 message(STATUS "    cvconfig.h is in:          ${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 744 message(STATUS "-----------------------------------------------------------------")
 745 message(STATUS "")
 746
 747 #----------------------------------------------------------------------------
 748 #   Generate the OpenCVConfig.cmake file for unix
 749 #      installation in CMAKE_INSTALL_PREFIX
 750 #----------------------------------------------------------------------------