novaboot

   1 #!/usr/bin/env perl
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use File::Path qw(make_path);
  26 use IO::Handle;
  27 use Time::HiRes("usleep");
  28 use Socket;
  29 use FileHandle;
  30 use IPC::Open2;
  31 use POSIX qw(:errno_h sysconf);
  32 use Cwd qw(getcwd abs_path);
  33 use Expect;
  34
  35 # always flush
  36 $| = 1;
  37
  38 my $invocation_dir = $ENV{PWD} || getcwd();
  39
  40 # We prefer using PWD, to use nicer paths names with symbolic links.
  41 # However, when executed from 'make -C dir', PWD may contain the make
  42 # invocation path, not the real invocation path with dir at the end.
  43 # We fix that here.
  44 if (abs_path($ENV{PWD}) ne abs_path(getcwd())) {
  45     $invocation_dir = getcwd();
  46 }
  47
  48 ## Configuration file handling
  49
  50 # Default configuration
  51 $CFG::hypervisor = "";
  52 $CFG::hypervisor_params = "serial";
  53 $CFG::genisoimage = "genisoimage";
  54 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  55 $CFG::default_target = '';
  56 $CFG::netif = 'eth0';
  57 %CFG::targets = (
  58     'qemu' => '--qemu',
  59     "tud" => '--copy=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  60     "novabox" => '--ssh=novabox@rtime.felk.cvut.cz',
  61     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --copy=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  62     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  63     "ryuglab" => '--target ryu --ssh=ryu@pc-sojkam.felk.cvut.cz',
  64     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  65     );
  66
  67 {
  68     my %const;
  69     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  70     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  71
  72     $CFG::scons = "scons -j$nproc";
  73     $CFG::make = "make -j$nproc";
  74 }
  75
  76 my $builddir;
  77
  78 sub read_config($) {
  79     my ($cfg) = @_;
  80     {
  81         package CFG; # Put config data into a separate namespace
  82
  83         my $rc = do($cfg);
  84
  85         # Check for errors
  86         if ($@) {
  87             die("ERROR: Failure compiling '$cfg' - $@");
  88         } elsif (! defined($rc)) {
  89             die("ERROR: Failure reading '$cfg' - $!");
  90         } elsif (! $rc) {
  91             die("ERROR: Failure processing '$cfg'");
  92         }
  93     }
  94     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  95     print STDERR "novaboot: Read $cfg\n";
  96 }
  97
  98 my @cfgs;
  99 {
 100     # We don't use $0 here, because it points to the novaboot itself and
 101     # not to the novaboot script. The problem with this approach is that
 102     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
 103     # contains the first option. Hence the -f check.
 104     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
 105     while ((-d $dir || -l $dir ) && $dir ne "/") {
 106         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
 107         my @dirs = File::Spec->splitdir($dir);
 108         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
 109     }
 110     @cfgs = reverse @cfgs;
 111
 112     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 113     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 114
 115     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 116     if (opendir(my $dh, $dir)) {
 117         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 118         closedir $dh;
 119         @etccfg = sort(@etccfg);
 120         @cfgs = ( @etccfg, @cfgs );
 121     }
 122 }
 123 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 124 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 125 GetOptions ("config|c=s" => \$cfg);
 126 read_config($_) foreach $cfg or @cfgs;
 127
 128 ## Command line handling
 129
 130 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 131 GetOptions ("target|t=s" => \$explicit_target);
 132
 133 # Variables for command line options
 134 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $final_eol, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iprelay_cmd, $iso_image, $interactive, $kernel_opt, $make, $man, $netif, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, @remote_cmd, $remote_expect, $remote_expect_silent, $remote_expect_timeout, $reset, @reset_cmd, $reset_send, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init, $uboot_stop_key);
 135
 136 my ($target_reset, $target_power_on, $target_power_off);
 137
 138 # Default values of certain command line options
 139 %uboot_addr = (
 140     'kernel'  => '${kernel_addr_r}',
 141     'ramdisk' => '${ramdisk_addr_r}',
 142     'fdt'     => '${fdt_addr_r}',
 143     );
 144 $rsync_flags = '';
 145 $rom_prefix = 'rom://';
 146 $stty = 'raw -crtscts -onlcr -echo 115200';
 147 $reset = 1;                     # Reset target by default
 148 $interaction = 1;               # Perform target interaction by default
 149 $final_eol = 1;
 150 $netif = $CFG::netif;
 151 $remote_expect_timeout = -1;
 152
 153 my @expect_seen = ();
 154 sub handle_expect
 155 {
 156     my ($n, $v) = @_;
 157     push(@expect_seen, '-re') if $n eq "expect-re";
 158     push(@expect_seen, $v);
 159 }
 160
 161 sub handle_send
 162 {
 163     my ($n, $v) = @_;
 164     unless (@expect_seen) { die("No --expect before --send"); }
 165     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 166     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 167     unshift(@expect_raw, @expect_seen);
 168     @expect_seen = ();
 169 }
 170
 171 # Options which can be safely specified on the server (via --ssh),
 172 # i.e. which cannot cause unwanted local code execution etc.
 173 my %opt_spec_safe = (
 174     "grub|g:s"       => \$grub_config,
 175     "grub-preamble=s"=> \$grub_preamble,
 176     "grub2-prolog=s" => \$grub2_prolog,
 177     "grub2:s"        => \$grub2_config,
 178     "prefix|grub-prefix=s" => \$grub_prefix,
 179     "pulsar-root=s"  => \$pulsar_root,
 180     "pulsar|p:s"     => \$pulsar,
 181     "remote-expect=s"=> \$remote_expect,
 182     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 183     "remote-expect-timeout=i"=> \$remote_expect_timeout,
 184     "uboot-addr=s"   => \%uboot_addr,
 185     "uboot-cmd=s"    => \$uboot_cmd,
 186     "uboot-stop-key=s" => \$uboot_stop_key,
 187     "uboot-init=s"   => sub { push @uboot_init, { command => $_[1] }; },
 188     "uboot:s"        => \$uboot,
 189     );
 190
 191 my %opt_spec = (
 192     %opt_spec_safe,
 193     "amt=s"          => \$amt,
 194     "append|a=s"     => \@append,
 195     "bender|b"       => \$bender,
 196     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 197     "concat"         => \$concat,
 198     "chainloader=s"  => \@chainloaders,
 199     "dhcp-tftp|d"    => \$dhcp_tftp,
 200     "dump"           => \$dump_opt,
 201     "dump-config"    => \$dump_config,
 202     "exiton=s"       => \@exiton,
 203     "exiton-timeout=i"=> \$exiton_timeout,
 204     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 205     "expect=s"       => \&handle_expect,
 206     "expect-re=s"    => \&handle_expect,
 207     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 208     "final-eol!"     => \$final_eol,
 209     "gen-only"       => \$gen_only,
 210     "ider"           => \$ider,
 211     "interaction!"   => \$interaction,
 212     "iprelay=s"      => \$iprelay,
 213     "iprelay-cmd=s"  => \$iprelay_cmd,
 214     "iso:s"          => \$iso_image,
 215     "kernel|k=s"     => \$kernel_opt,
 216     "interactive|i"  => \$interactive,
 217     "name=s"         => \$config_name_opt,
 218     "make|m:s"       => \$make,
 219     "netif=s"        => \$netif,
 220     "no-file-gen"    => \$no_file_gen,
 221     "off"            => \$off_opt,
 222     "on"             => \$on_opt,
 223     "qemu|Q:s"       => \$qemu,
 224     "qemu-append=s"  => \$qemu_append,
 225     "qemu-flags|q=s" => \$qemu_flags_cmd,
 226     "remote-cmd=s"   => sub { @remote_cmd = ($_[1]); },
 227     "reset!"         => \$reset,
 228     "reset-cmd=s"    => sub { @reset_cmd = ($_[1]); },
 229     "reset-send=s"   => \$reset_send,
 230     "rsync-flags=s"  => \$rsync_flags,
 231     "scons:s"        => \$scons,
 232     "scriptmod=s"    => \@scriptmod,
 233     "send=s"         => \&handle_send,
 234     "sendcont=s"     => \&handle_send,
 235     "serial|s:s"     => \$serial,
 236     "server:s"       => \$server,
 237     "copy:s"         => \$server,
 238     "ssh:s"          => \&handle_novaboot_server,
 239     "strip-rom"      => sub { $rom_prefix = ''; },
 240     "stty=s"         => \$stty,
 241     "tftp"           => \$tftp,
 242     "tftp-port=i"    => \$tftp_port,
 243     "no-uboot"       => sub { undef $uboot; },
 244     "h"              => \$help,
 245     "help"           => \$man,
 246     );
 247
 248 sub handle_novaboot_server
 249 {
 250     my ($n, $val) = @_;
 251     my $xdg_runtime_dir = $ENV{XDG_RUNTIME_DIR} || '/var/run';
 252     my $ssh_ctl_path = "${xdg_runtime_dir}/novaboot$$";
 253
 254     @remote_cmd = ('ssh', '-tt', '-M', '-S', $ssh_ctl_path, $val, 'console');
 255     $remote_expect = "novaboot-shell: Connected";
 256     $server = "$val:";
 257     $rsync_flags = "--rsh='ssh -S \'${ssh_ctl_path}\''";
 258     ($grub_prefix = $val) =~ s|(.*)@.*|\/$1\/| if index($val, '@') != -1;
 259     @reset_cmd = ('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'reset');
 260
 261     $target_power_off = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'off'); };
 262     $target_power_on  = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'on'); };
 263
 264     my $cmd = "ssh '${val}' get-config";
 265     print STDERR "novaboot: Running: $cmd\n";
 266     my @target_config = qx($cmd  < /dev/null);
 267     if ($?) { die("Cannot get target configuration from the server"); }
 268     printf "novaboot: Received configuration from the server:%s\n", (!@target_config) ? " empty" : "";
 269     foreach (@target_config) { chomp; print "  $_\n"; }
 270
 271     my $p = Getopt::Long::Parser->new;
 272     $p->configure(qw/no_ignore_case no_pass_through/);
 273     $p->getoptionsfromarray(\@target_config, %opt_spec_safe) or die("Error processing configuration from the server");
 274
 275     if (scalar @target_config) { die "Unsuported configuration received from the server: ".join(", ", @target_config); }
 276 }
 277
 278 # First process target options
 279 {
 280     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 281     my @target_expanded;
 282     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 283     while ($t) {
 284         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 285
 286         undef $explicit_target;
 287         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 288         if (!$ret) { die "Error parsing target $t option"; }
 289         push(@target_expanded, @$remaining_args);
 290         $t = $explicit_target;
 291     }
 292
 293     my @args = (@target_expanded, @ARGV);
 294     print STDERR "novaboot: Effective options: @args\n";
 295
 296     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 297     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 298 }
 299
 300 # Then process other command line options - some of them may override
 301 # what was specified by the target
 302 GetOptions %opt_spec or die("Error in command line arguments");
 303 pod2usage(1) if $help;
 304 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 305
 306 ### Dump sanitized configuration (if requested)
 307
 308 if ($dump_config) {
 309     use Data::Dumper;
 310     $Data::Dumper::Indent=1;
 311     print "# This file is in perl syntax.\n";
 312     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 313         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 314         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 315         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 316     }
 317     print "1;\n";
 318     exit;
 319 }
 320
 321 ### Sanitize configuration
 322
 323 if ($interactive && !-t STDIN) {
 324     die("novaboot: Interactive mode not supported when not on terminal");
 325 }
 326
 327 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 328
 329 if ($ider) {
 330     $iso_image //= ''; # IDE-R needs an ISO image
 331     if (!defined $amt) { die "Error: --ider requires --amt"; }
 332 }
 333
 334 {
 335     my %input_opts = ('--iprelay'    => \$iprelay,
 336                       '--iprelay-cmd'=> \$iprelay_cmd,
 337                       '--serial'     => \$serial,
 338                       '--remote-cmd' => (@remote_cmd ? \$remote_cmd[0] : undef),
 339                       '--amt'        => \$amt);
 340     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 341
 342     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 343 }
 344
 345 # Default options
 346 if (defined $serial) {
 347     $serial ||= "/dev/ttyUSB0";
 348     $ENV{NB_SERIAL} = $serial;
 349 }
 350 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 351 if (defined $grub2_config) { $grub2_config ||= "./boot/grub/grub.cfg"; }
 352
 353 ## Parse the novaboot script(s)
 354 my @scripts;
 355 my $file;
 356 my $EOF;
 357 my $last_fn = '';
 358 my ($modules, $variables, $generated, $copy, $chainload, $continuation) = ([], {}, [], []);
 359 my $skip_reading = defined($on_opt) || defined($off_opt);
 360 while (!$skip_reading && ($_ = <>)) {
 361     if ($ARGV ne $last_fn) { # New script
 362         die "Missing EOF in $last_fn" if $file;
 363         die "Unfinished line in $last_fn" if $continuation;
 364         $last_fn = $ARGV;
 365         push @scripts, { 'filename' => $ARGV,
 366                          'modules' => $modules = [],
 367                          'variables' => $variables = {},
 368                          'generated' => $generated = [],
 369                          'copy' => $copy = [],
 370                          'chainload' => $chainload = [],
 371         };
 372
 373     }
 374     chomp();
 375     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 376
 377     $_ =~ s/^[[:space:]]*// if ($continuation);
 378
 379     if (/\\$/) {                # Line continuation
 380         $continuation .= substr($_, 0, length($_)-1);
 381         next;
 382     }
 383
 384     if ($continuation) {        # Last continuation line
 385         $_ = $continuation . $_;
 386         $continuation = '';
 387     }
 388
 389     foreach my $mod(@scriptmod) { eval $mod; }
 390
 391     if ($file && $_ eq $EOF) {  # Heredoc end
 392         undef $file;
 393         next;
 394     }
 395     if ($file) {                # Heredoc content
 396         push @{$file}, "$_\n";
 397         next;
 398     }
 399     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 400         $$variables{$1} = $2;
 401         push(@exiton, $2) if ($1 eq "EXITON");
 402         $interaction = $2 if ($1 eq "INTERACTION");
 403         next;
 404     }
 405     sub process_load_copy($) {
 406         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 407         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 408             $file = [];
 409             push @$generated, {filename => $1, content => $file};
 410             $EOF = $3;
 411             return "$1$2";
 412         }
 413         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 414             push @$generated, {filename => $1, command => $3};
 415             return "$1$2";
 416         }
 417         s/\s*$//;               # Strip trailing whitespace
 418         return $_;
 419     }
 420     if (s/^load *//) {          # Load line
 421         push @$modules, process_load_copy($_);
 422         next;
 423     }
 424     if (s/^copy *//) {          # Copy line
 425         push @$copy, process_load_copy($_);
 426         next;
 427     }
 428     if (s/^chld *//) {          # Chainload line
 429         push @$chainload, process_load_copy($_);
 430         next;
 431     }
 432     if (/^run (.*)/) {          # run line
 433         push @$generated, {command => $1};
 434         next;
 435     }
 436     if (/^uboot(?::([0-9]+)s)? +(< *)?(.*)/) {  # uboot line
 437         # TODO: If U-Boot supports some interactive menu, it might
 438         # make sense to store uboot lines per novaboot script.
 439         my ($timeout, $redir, $string, $dest) = ($1, $2, $3);
 440         if ($string =~ /(.*) *> *(.*)/) {
 441             $string = $1;
 442             $dest = $2;
 443         }
 444         push @uboot_init, { command => $redir ? "" : $string,
 445                             system =>  $redir ? $string : "",
 446                             timeout => $timeout,
 447                             dest => $dest,
 448         };
 449         next;
 450     }
 451
 452     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 453 }
 454 # use Data::Dumper;
 455 # print Dumper(\@scripts);
 456
 457 foreach my $script (@scripts) {
 458     $modules = $$script{modules};
 459     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 460     @$modules[0] .= ' ' . join(' ', @append) if @append;
 461
 462     my $kernel;
 463     if (exists $variables->{KERNEL}) {
 464         $kernel = $variables->{KERNEL};
 465     } else {
 466         if ($CFG::hypervisor) {
 467             $kernel = $CFG::hypervisor . " ";
 468             if (exists $variables->{HYPERVISOR_PARAMS}) {
 469                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 470             } else {
 471                 $kernel .= $CFG::hypervisor_params;
 472             }
 473         }
 474     }
 475     @$modules = ($kernel, @$modules) if $kernel;
 476     @$modules = (@chainloaders, @$modules);
 477     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 478 }
 479
 480 if ($dump_opt) {
 481     foreach my $script (@scripts) {
 482         print join("\n", @{$$script{modules}})."\n";
 483     }
 484     exit(0);
 485 }
 486
 487 ## Helper functions
 488
 489 sub generate_configs($$$) {
 490     my ($base, $generated, $filename) = @_;
 491     if ($base) { $base = "$base/"; };
 492     foreach my $g(@$generated) {
 493       if (exists $$g{content}) {
 494         my $config = $$g{content};
 495         my $fn = $$g{filename};
 496         open(my $f, '>', $fn) || die("$fn: $!");
 497         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 498         close($f);
 499         print STDERR "novaboot: Created $fn\n";
 500       } elsif (exists $$g{command} && ! $no_file_gen) {
 501         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 502         if (exists $$g{filename}) {
 503             system_verbose("( $$g{command} ) > $$g{filename}");
 504         } else {
 505             system_verbose($$g{command});
 506         }
 507       }
 508     }
 509 }
 510
 511 sub generate_grub_config($$$$;$)
 512 {
 513     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 514     if ($base) { $base = "$base/"; };
 515     open(my $fg, '>', $filename) or die "$filename: $!";
 516     print $fg "$preamble\n" if $preamble;
 517     print $fg "title $title\n" if $title;
 518     #print $fg "root $base\n"; # root doesn't really work for (nd)
 519     my $first = 1;
 520     foreach (@$modules_ref) {
 521         if ($first) {
 522             $first = 0;
 523             my ($kbin, $kcmd) = split(' ', $_, 2);
 524             $kcmd = '' if !defined $kcmd;
 525             print $fg "kernel ${base}$kbin $kcmd\n";
 526         } else {
 527             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 528             print $fg "module $base$_\n";
 529         }
 530     }
 531     close($fg);
 532     print("novaboot: Created $builddir/$filename\n");
 533     return $filename;
 534 }
 535
 536 sub generate_syslinux_config($$$$)
 537 {
 538     my ($filename, $title, $base, $modules_ref) = @_;
 539     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 540     open(my $fg, '>', $filename) or die "$filename: $!";
 541     print $fg "LABEL $title\n";
 542     #TODO print $fg "MENU LABEL $human_readable_title\n";
 543
 544     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 545
 546     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 547         my $initrd = @$modules_ref[1];
 548         die('Too many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 549         print $fg "LINUX $base$kbin\n";
 550         print $fg "APPEND $kcmd\n";
 551         print $fg "INITRD $base$initrd\n";
 552     } else {
 553         print $fg "KERNEL mboot.c32\n";
 554         my @append;
 555         foreach (@$modules_ref) {
 556             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 557             push @append, "$base$_";
 558             print $fg "APPEND ".join(' --- ', @append)."\n";
 559         }
 560     }
 561     #TODO print $fg "TEXT HELP\n";
 562     #TODO print $fg "some help here\n";
 563     #TODO print $fg "ENDTEXT\n";
 564     close($fg);
 565     print("novaboot: Created $builddir/$filename\n");
 566     return $filename;
 567 }
 568
 569 sub generate_grub2_config($$$$;$$)
 570 {
 571     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 572     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 573     my $dir = dirname($filename);
 574     make_path($dir, {
 575                 chmod => 0755,
 576     });
 577     open(my $fg, '>', $filename) or die "$filename: $!";
 578     print $fg "$preamble\n" if $preamble;
 579     $title ||= 'novaboot';
 580     print $fg "menuentry $title {\n";
 581     print $fg "$prolog\n" if $prolog;
 582     my $first = 1;
 583     my $boot_method = $variables->{BOOT_METHOD} // "multiboot";
 584     my $module_load_method = "module";
 585     if ($boot_method eq "linux") {
 586         $module_load_method = "initrd";
 587     }
 588     foreach (@$modules_ref) {
 589         if ($first) {
 590             $first = 0;
 591             my ($kbin, $kcmd) = split(' ', $_, 2);
 592             $kcmd = '' if !defined $kcmd;
 593             print $fg "  $boot_method ${base}$kbin $kcmd\n";
 594         } else {
 595             my @args = split;
 596             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 597             $_ = join(' ', ($args[0], @args));
 598             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 599             print $fg "  $module_load_method $base$_\n";
 600         }
 601     }
 602     print $fg "}\n";
 603     close($fg);
 604     print("novaboot: Created $builddir/$filename\n");
 605     return $filename;
 606 }
 607
 608 sub generate_pulsar_config($$$)
 609 {
 610     my ($filename, $modules_ref, $chainload_ref) = @_;
 611     open(my $fg, '>', $filename) or die "$filename: $!";
 612     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 613     if (scalar(@$chainload_ref) > 0) {
 614         print $fg "chld $$chainload_ref[0]\n";
 615     } else {
 616         my $first = 1;
 617         my ($kbin, $kcmd);
 618         foreach (@$modules_ref) {
 619             if ($first) {
 620                 $first = 0;
 621                 ($kbin, $kcmd) = split(' ', $_, 2);
 622                 $kcmd = '' if !defined $kcmd;
 623             } else {
 624                 my @args = split;
 625                 s|\brom://|$rom_prefix|g;
 626                 print $fg "load $_\n";
 627             }
 628         }
 629         # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 630         print $fg "exec $kbin $kcmd\n";
 631     }
 632     close($fg);
 633     print("novaboot: Created $builddir/$filename\n");
 634     return $filename;
 635 }
 636
 637 sub shell_cmd_string(@)
 638 {
 639     if (scalar(@_) == 1) {
 640         return $_[0];
 641     } else {
 642         return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 643     }
 644 }
 645
 646 sub exec_verbose(@)
 647 {
 648     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 649     exec(@_);
 650     exit(1); # should not be reached
 651 }
 652
 653 sub system_verbose
 654 {
 655     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 656     my $ret = system(@_);
 657     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 658     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 659     if ($ret) { die("Command failure $ret"); }
 660 }
 661
 662 sub trim($) {
 663     my ($str) = @_;
 664     $str =~ s/^\s+|\s+$//g;
 665     return $str
 666 }
 667
 668 ## WvTest headline
 669
 670 if (exists $variables->{WVDESC}) {
 671     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 672 } elsif ($last_fn =~ /\.wv$/) {
 673     print STDERR "Testing \"all\" in $last_fn:\n";
 674 }
 675
 676 ## Connect to the target and check whether it is not occupied
 677
 678 # We have to do this before file generation phase, because file
 679 # generation is intermixed with file deployment phase and we want to
 680 # check whether the target is not used by somebody else before
 681 # deploying files. Otherwise, we may rewrite other user's files on a
 682 # boot server.
 683
 684 my $exp; # Expect object to communicate with the target over serial line
 685
 686 sub kill_exp_on_signal() {
 687     # Sometimes, under unclear circumstances (e.g. when running under
 688     # both Jenkins and Robotframework), novaboot does not terminate
 689     # console command when killed. The console is then blocked by the
 690     # stale process forever. Theoretically, this should not happen,
 691     # because when novaboot is killed, console command's controlling
 692     # terminal sends SIGHUP to the console command and the command
 693     # should terminate. It seems that at least SSH sometimes ignores
 694     # HUP and does not terminate. The code below seems to work around
 695     # that problem by killing the process immediately with SIGTERM,
 696     # which is not ignored.
 697
 698     sub kill_console { kill TERM => $exp->pid if $exp->pid; die "Terminated by SIG$_[0]"; };
 699
 700     # For our Jenkins/Robotframework use case, it was sufficient to
 701     # handle the TERM signal, but to be on the safe side, we also
 702     # catch other signals.
 703     $SIG{TERM} = \&kill_console;
 704     $SIG{HUP} = \&kill_console;
 705     $SIG{INT} = \&kill_console;
 706     $SIG{QUIT} = \&kill_console;
 707 }
 708
 709
 710 my ($amt_user, $amt_password, $amt_host, $amt_port);
 711
 712 if (defined $iprelay || defined $iprelay_cmd) {
 713     if (defined $iprelay) {
 714         my $IPRELAY;
 715         $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 716         my $addr = $1;
 717         my $port = $3 || 23;
 718         my $paddr   = sockaddr_in($port, inet_aton($addr));
 719         my $proto   = getprotobyname('tcp');
 720         socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 721         print STDERR "novaboot: Connecting to IP relay... ";
 722         connect($IPRELAY, $paddr)    || die "connect: $!";
 723         print STDERR "done\n";
 724         $exp = Expect->init(\*$IPRELAY);
 725         $exp->log_stdout(1);
 726     }
 727     if (defined $iprelay_cmd) {
 728         print STDERR "novaboot: Running: $iprelay_cmd\n";
 729         $exp = new Expect;
 730         $exp->raw_pty(1);
 731         $exp->spawn($iprelay_cmd);
 732         kill_exp_on_signal();
 733     }
 734
 735     while (1) {
 736         print $exp "\xFF\xF6";  # AYT
 737         my $connected = $exp->expect(20, # Timeout in seconds
 738                                      '<iprelayd: connected>',
 739                                      '-re', '<WEB51 HW[^>]*>')
 740             || die "iprelay connection: " . ($! || "timeout");
 741         last if $connected;
 742     }
 743
 744     sub relaycmd($$) {
 745         my ($relay, $onoff) = @_;
 746         die unless ($relay == 1 || $relay == 2);
 747
 748         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 749         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 750     }
 751
 752     sub relayconf($$) {
 753         my ($relay, $onoff) = @_;
 754         die unless ($relay == 1 || $relay == 2);
 755         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 756         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 757     }
 758
 759     sub relay($$;$) {
 760         my ($relay, $onoff, $can_giveup) = @_;
 761         my $confirmation = '';
 762         $exp->log_stdout(0);
 763         print $exp relaycmd($relay, $onoff);
 764         my $confirmed = $exp->expect(20, # Timeout in seconds
 765                                      relayconf($relay, $onoff))
 766             || die "iprelay command: " . ($! || "timeout");
 767         if (!$confirmed) {
 768             if ($can_giveup) {
 769                 print("Relay confirmation timeout - ignoring\n");
 770             } else {
 771                 die "Relay confirmation timeout";
 772             }
 773         }
 774         $exp->log_stdout(1);
 775     }
 776
 777     $target_reset = sub {
 778         relay(2, 1, 1); # Reset the machine
 779         usleep(100000);
 780         relay(2, 0);
 781     };
 782
 783     $target_power_off = sub {
 784         relay(1, 1);            # Press power button
 785         usleep(6000000);        # Long press to switch off
 786         relay(1, 0);
 787     };
 788
 789     $target_power_on = sub {
 790         relay(1, 1);            # Press power button
 791         usleep(100000);         # Short press
 792         relay(1, 0);
 793     };
 794 }
 795 elsif ($serial) {
 796     my $CONN;
 797     system_verbose("stty -F $serial $stty");
 798     open($CONN, "+<", $serial) || die "open $serial: $!";
 799     $exp = Expect->init(\*$CONN);
 800 }
 801 elsif (@remote_cmd) {
 802     print STDERR "novaboot: Running: ".shell_cmd_string(@remote_cmd)."\n";
 803     $exp = Expect->spawn(@remote_cmd);
 804     kill_exp_on_signal();
 805 }
 806 elsif (defined $amt) {
 807     require LWP::UserAgent;
 808     require LWP::Authen::Digest;
 809
 810     sub genXML {
 811         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 812         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 813         my %pstates = ("on"        => 2,
 814                        "standby"   => 4,
 815                        "hibernate" => 7,
 816                        "off"       => 8,
 817                        "reset"     => 10,
 818                        "MNI"       => 11);
 819         return <<END;
 820                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 821                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 822                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 823                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 824                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 825                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 826                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 827                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 828                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 829                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 830                 </s:Header><s:Body>
 831                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 832                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 833                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 834                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 835                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 836                 </a:ReferenceParameters></p:ManagedElement>
 837                 </p:RequestPowerStateChange_INPUT>
 838                 </s:Body></s:Envelope>
 839 END
 840     }
 841
 842     sub sendPOST {
 843         my ($host, $username, $password, $content) = @_;
 844
 845         my $ua = LWP::UserAgent->new();
 846         $ua->agent("novaboot");
 847
 848         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 849         my $res = $ua->request($req);
 850         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 851
 852         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 853         $ua->credentials("$host:16992", $realm, $username => $password);
 854
 855         # Create a request
 856         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 857         $req->content_type('application/x-www-form-urlencoded');
 858         $req->content($content);
 859         $res = $ua->request($req);
 860         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 861         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 862         return $1;
 863     }
 864
 865     sub powerChange  {
 866         my ($host, $username, $password, $pstate)=@_;
 867         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 868         my $className="/RequestPowerStateChange";
 869         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 870         return sendPOST($host, $username, $password, $content);
 871     }
 872
 873     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 874     $amt_user ||= "admin";
 875     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 876     $amt_host || die "AMT host not specified";
 877     $amt_port ||= 16994;
 878
 879
 880     $target_power_off = sub {
 881         $exp->close();
 882         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 883         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 884     };
 885
 886     $target_power_on = sub {
 887         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 888         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 889     };
 890
 891     $target_reset = sub {
 892         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 893         if ($result != 0) {
 894             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 895             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 896         }
 897         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 898     };
 899
 900     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 901     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 902     $exp = Expect->spawn($cmd);
 903     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL': " . ($! || "timeout");
 904 }
 905
 906
 907 if ($remote_expect) {
 908     $exp || die("No serial line connection");
 909     my $log = $exp->log_stdout;
 910     if (defined $remote_expect_silent) {
 911         $exp->log_stdout(0);
 912     }
 913     $exp->expect($remote_expect_timeout >= 0 ? $remote_expect_timeout : undef,
 914                  $remote_expect) || die "Expect for '$remote_expect':" . ($! || "timeout");;
 915     if (defined $remote_expect_silent) {
 916         $exp->log_stdout($log);
 917         print $exp->after() if $log;
 918     }
 919 }
 920
 921 if (@reset_cmd) {
 922     $target_reset = sub {
 923         system_verbose(@reset_cmd);
 924     };
 925 }
 926
 927 if (defined $reset_send) {
 928     $target_reset = sub {
 929         $reset_send =~ s/\\n/\n/g;
 930         $exp->send($reset_send);
 931     };
 932 }
 933
 934 if (defined $on_opt && defined $target_power_on) {
 935     &$target_power_on();
 936     exit;
 937 }
 938 if (defined $off_opt && defined $target_power_off) {
 939     print STDERR "novaboot: Switching the target off...\n";
 940     &$target_power_off();
 941     exit;
 942 }
 943
 944 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 945 if (defined $builddir) {
 946     chdir($builddir) or die "Can't change directory to $builddir: $!";
 947     print STDERR "novaboot: Entering directory `$builddir'\n";
 948 } else {
 949     $builddir = $invocation_dir;
 950 }
 951
 952 ## File generation phase
 953 my (%files_iso, $menu_iso, $filename);
 954 my $config_name = '';
 955 my $prefix = '';
 956
 957 foreach my $script (@scripts) {
 958     $filename = $$script{filename};
 959     $modules = $$script{modules};
 960     $generated = $$script{generated};
 961     $variables = $$script{variables};
 962
 963     ($config_name = $filename) =~ s#.*/##;
 964     $config_name = $config_name_opt if (defined $config_name_opt);
 965
 966     if (exists $variables->{BUILDDIR}) {
 967         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 968         chdir($builddir) or die "Can't change directory to $builddir: $!";
 969         print STDERR "novaboot: Entering directory `$builddir'\n";
 970     }
 971
 972     if ($grub_prefix) {
 973         $prefix = $grub_prefix;
 974         $prefix =~ s/\$NAME/$config_name/;
 975         $prefix =~ s/\$BUILDDIR/$builddir/;
 976     }
 977     # TODO: use $grub_prefix as first parameter if some switch is given
 978     generate_configs('', $generated, $filename);
 979
 980 ### Generate bootloader configuration files
 981     my @bootloader_configs;
 982     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 983     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 984     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules, $chainload) if (defined $pulsar);
 985
 986 ### Run scons or make
 987     {
 988         my @all;
 989         push @all, @$modules;
 990         push @all, @$copy;
 991         push @all, @$chainload;
 992         my @files = map({ ($file) = m/([^ ]*)/; $file; } @all);
 993
 994         # Filter-out generated files
 995         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 996
 997         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 998         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 999     }
1000
1001 ### Copy files (using rsync)
1002     if (defined $server && !defined($gen_only)) {
1003         (my $real_server = $server) =~ s/\$NAME/$config_name/;
1004
1005         my ($hostname, $path) = split(":", $real_server, 2);
1006         if (! defined $path) {
1007             $path = $hostname;
1008             $hostname = "";
1009         }
1010         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs, @$copy)));
1011         map({ my $file = (split)[0]; die "Not a file: $file: $!" if ! -e $file || -d $file; } @$modules);
1012         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
1013         my $progress = $istty ? "--progress" : "";
1014         if ($files) {
1015             system_verbose("rsync $progress -RL --chmod=ugo=rwX $rsync_flags $files $real_server");
1016             if ($server =~ m|/\$NAME$| && $concat) {
1017                 my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
1018                 system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
1019             }
1020         }
1021     }
1022
1023 ### Prepare ISO image generation
1024     if (defined $iso_image) {
1025         generate_configs("(cd)", $generated, $filename);
1026         my $menu;
1027         generate_syslinux_config(\$menu, $config_name, "/", $modules);
1028         $menu_iso .= "$menu\n";
1029         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
1030     }
1031 }
1032
1033 ## Generate ISO image
1034 if (defined $iso_image) {
1035     system_verbose("mkdir -p isolinux");
1036
1037     my @files;
1038     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
1039         # Newer ISOLINUX version
1040         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
1041     } elsif (-f '/usr/lib/syslinux/isolinux.bin') {
1042         # Older ISOLINUX version
1043         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
1044     } else {
1045         # NixOS and maybe others
1046         my $syslinux = `which syslinux` || die "Cannot find syslinux";
1047         chomp $syslinux;
1048         $syslinux =~ s,/bin/syslinux$,,;
1049         @files = ("$syslinux/share/syslinux/isolinux.bin", "$syslinux/share/syslinux/mboot.c32", "$syslinux/share/syslinux/libcom32.c32", "$syslinux/share/syslinux/menu.c32", "$syslinux/share/syslinux/ldlinux.c32");
1050     }
1051     system_verbose("cp @files isolinux && chmod +w isolinux/*");
1052     open(my $fh, ">isolinux/isolinux.cfg");
1053     if ($#scripts) {
1054         print $fh "TIMEOUT 50\n";
1055         print $fh "DEFAULT menu\n";
1056     } else {
1057         print $fh "DEFAULT $config_name\n";
1058     }
1059     print $fh "$menu_iso";
1060     close($fh);
1061
1062     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
1063     $iso_image ||= "$config_name.iso";
1064
1065     # Note: We use -U flag below to "Allow 'untranslated' filenames,
1066     # completely violating the ISO9660 standards". Without this
1067     # option, isolinux is not able to read files names for example
1068     # bzImage-3.0.
1069     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
1070     print("ISO image created: $builddir/$iso_image\n");
1071 }
1072
1073 exit(0) if defined $gen_only;
1074
1075 ## Boot the system using various methods and send serial output to stdout
1076
1077 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
1078     die "You cannot do this with multiple scripts simultaneously";
1079 }
1080
1081 if ($variables->{WVTEST_TIMEOUT}) {
1082     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
1083 }
1084
1085 ### Start in Qemu
1086
1087 if (defined $qemu) {
1088     # Qemu
1089     $qemu ||= $variables->{QEMU} || $CFG::qemu;
1090     my @qemu_flags = split(" ", $qemu);
1091     $qemu = shift(@qemu_flags);
1092
1093     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
1094     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
1095     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
1096
1097     if (defined $iso_image) {
1098         # Boot NOVA with grub (and test the iso image)
1099         push(@qemu_flags, ('-cdrom', $iso_image));
1100     } else {
1101         # Boot NOVA without GRUB
1102
1103         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
1104         foreach (@$modules) {s/,/+/g;}
1105         generate_configs("", $generated, $filename);
1106
1107         if (scalar @$modules) {
1108             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1109             $kcmd = '' if !defined $kcmd;
1110             my $dtb;
1111             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1112             my $initrd = join ",", @$modules;
1113
1114             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
1115             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
1116             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
1117         }
1118     }
1119     if (!grep /^-serial$/, @qemu_flags) {
1120         push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
1121     }
1122     unshift(@qemu_flags, ('-name', $config_name));
1123     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
1124     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
1125 }
1126
1127 ### Local DHCPD and TFTPD
1128
1129 my ($dhcpd_pid, $tftpd_pid);
1130
1131 $tftp=1 if $tftp_port;
1132
1133 if (defined $dhcp_tftp)
1134 {
1135     generate_configs("(nd)", $generated, $filename);
1136     system_verbose('mkdir -p tftpboot');
1137     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
1138     open(my $fh, '>', 'dhcpd.conf');
1139     my $mac = `cat /sys/class/net/$netif/address`;
1140     chomp $mac;
1141     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
1142                       range 10.23.23.10 10.23.23.100;
1143                       filename \"bin/boot/grub/pxegrub.pxe\";
1144                       next-server 10.23.23.1;
1145 }
1146 host server {
1147         hardware ethernet $mac;
1148         fixed-address 10.23.23.1;
1149 }";
1150     close($fh);
1151     system_verbose("sudo ip a add 10.23.23.1/24 dev $netif;
1152             sudo ip l set dev $netif up;
1153             sudo touch dhcpd.leases");
1154
1155     # We run servers by forking ourselves, because the servers end up
1156     # in our process group and get killed by signals sent to the
1157     # process group (e.g. Ctrl-C on terminal).
1158     $dhcpd_pid = fork();
1159     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1160 }
1161
1162 if (defined $dhcp_tftp || defined $tftp) {
1163     $tftp_port ||= 69;
1164     my $tftp_root = "$builddir";
1165     $tftp_root = "$server" if(defined $server);
1166
1167     # Prepare a GRUB netboot directory
1168     system_verbose("grub-mknetdir --net-directory=$tftp_root") if (defined $grub2_config);
1169
1170     # Generate TFTP mapfile
1171     open(my $fh, '>', "$tftp_root/mapfile");
1172     print $fh "# Some PXE clients (mainly UEFI) have bug. They add zero byte to the end of the
1173 # path name. This rule removes it
1174 r     \\.efi.*   \\.efi";
1175     close($fh);
1176     # Unfortunately, tftpd requires root privileges even with
1177     # non-privileged (>1023) port due to initgroups().
1178     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile $builddir/tftpd.pid -m mapfile --address :$tftp_port $tftp_root");
1179
1180     # Kill server when we die
1181     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1182                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1183
1184     # We have to kill tftpd explicitely, because it is not in our process group
1185     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1186 }
1187
1188 ### AMT IDE-R
1189 if (defined $ider) {
1190     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1191     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1192     my $ider_pid = fork();
1193     if ($ider_pid == 0) {
1194         exec($ider_cmd);
1195         die "IDE redirection failed";
1196     }
1197     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1198     # to use both simultaneously.
1199     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1200 }
1201
1202 ### Reset target (IP relay, AMT, ...)
1203
1204 if (defined $target_reset && $reset) {
1205     print STDERR "novaboot: Resetting the test box... ";
1206     &$target_reset();
1207     print STDERR "done\n";
1208     if (defined $exp) {
1209         # We don't want to output anything printed by the target
1210         # before reset so we clear the buffers now. This is, however,
1211         # not ideal because we may loose some data that were sent
1212         # after the reset. If this is a problem, one should reset and
1213         # connect to serial line in atomic manner. For example, if
1214         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1215         # do not use separate --reset-cmd.
1216         my $log = $exp->log_stdout;
1217         $exp->log_stdout(0);
1218         $exp->expect(0); # Read data from target
1219         $exp->clear_accum();    # Clear the read data
1220         $exp->log_stdout($log);
1221     }
1222 }
1223
1224 ### U-boot conversation
1225 if (defined $uboot) {
1226     my $uboot_prompt = $uboot || '=> ';
1227     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1228     $exp || die("No serial line connection");
1229     $exp->log_stdout(1);
1230     #$exp->exp_internal(1);
1231     $exp->expect(20,
1232                  [qr/Hit any key to stop autoboot:/, sub {
1233                      $exp->send($uboot_stop_key // "\n");
1234                      exp_continue; }],
1235                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1236     foreach my $cmdspec (@uboot_init) {
1237         my ($cmd, $timeout);
1238         die "Internal error - please report a bug" unless ref($cmdspec) eq "HASH";
1239
1240         if ($cmdspec->{system}) {
1241             $cmd = `$cmdspec->{system}`;
1242         } else {
1243             $cmd = $cmdspec->{command};
1244         }
1245         $timeout = $cmdspec->{timeout} // 10;
1246
1247         if ($cmd =~ /\$NB_MYIP/) {
1248             my $ip = (grep /inet /, `ip addr show $netif`)[0] || die "Problem determining IP address of $netif";
1249             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1250             $cmd =~ s/\$NB_MYIP/$ip/g;
1251         }
1252         if ($cmd =~ /\$NB_PREFIX/) {
1253             my $p = $prefix;
1254             $p =~ s|/*$||;
1255             $cmd =~ s/\$NB_PREFIX/$p/g;
1256         }
1257         chomp($cmd);
1258         $exp->send("$cmd\n");
1259
1260         my ($matched_pattern_position, $error,
1261             $successfully_matching_string,
1262             $before_match, $after_match) =
1263                 $exp->expect($timeout, $uboot_prompt);
1264         die "No U-Boot prompt: $error" if $error;
1265
1266         if ($cmdspec->{dest}) {
1267             open(my $fh, ">", $cmdspec->{dest}) or die "Cannot open '$cmdspec->{dest}': $!";
1268             print $fh $before_match;
1269             close($fh);
1270         }
1271     }
1272
1273     # Load files if there are some load lines in the script
1274     if (scalar(@$modules) > 0  && !$variables->{NO_BOOT}) {
1275         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1276         my $dtb;
1277         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1278         my $initrd = shift @$modules;
1279
1280         if (defined $kbin && $kbin ne '/dev/null') {
1281             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1282             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1283             $exp->expect(15,
1284                          [qr/##/, sub { exp_continue; }],
1285                          $uboot_prompt) || die "Kernel load: " . ($! || "timeout");
1286         }
1287         if (defined $dtb) {
1288             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1289             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1290             $exp->expect(15,
1291                          [qr/##/, sub { exp_continue; }],
1292                          $uboot_prompt) || die "Device tree load: " . ($! || "timeout");
1293         } else  {
1294             $uboot_addr{fdt} = '';
1295         }
1296         if (defined $initrd) {
1297             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1298             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1299             $exp->expect(15,
1300                          [qr/##/, sub { exp_continue; }],
1301                          $uboot_prompt) || die "Initrd load: " . ($! || "timeout");
1302         } else {
1303             $uboot_addr{ramdisk} = '-';
1304         }
1305
1306         $kcmd //= '';
1307         $exp->send("setenv bootargs $kcmd\n");
1308         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt: " . ($! || "timeout");
1309
1310     }
1311     $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1312     if (!$variables->{NO_BOOT} && $uboot_cmd ne '') {
1313         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1314         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1315         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1316
1317         $exp->send($uboot_cmd . "\n");
1318         $exp->expect(5, "\n")  || die "U-Boot command: " . ($! || "timeout");
1319     }
1320 }
1321
1322 ### Serial line interaction
1323 if ($interaction && defined $exp) {
1324     # Serial line of the target is available
1325     my $interrupt = 'Ctrl-C';
1326     if ($interactive && !@exiton) {
1327         $interrupt = '"~~."';
1328     }
1329     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1330     $exp->log_stdout(1);
1331     if (@exiton) {
1332         $exp->expect($exiton_timeout, @exiton, @expect_raw) || die("exiton: " . ($! || "timeout"));
1333     } else {
1334         my @inputs = ($exp);
1335         my $infile = new IO::File;
1336         $infile->IO::File::fdopen(*STDIN,'r');
1337         my $in_object = Expect->exp_init($infile);
1338         $in_object->set_group($exp);
1339
1340         if ($interactive) {
1341             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1342             $in_object->manual_stty(0);   # Use raw terminal mode
1343         } else {
1344             $in_object->manual_stty(1);   # Do not modify terminal settings
1345         }
1346         push(@inputs, $in_object);
1347         #use Data::Dumper;
1348         #print Dumper(\@expect_raw);
1349         $exp->expect(undef, @expect_raw) if @expect_raw;
1350
1351         $^W = 0; # Suppress Expect warning: handle id(3) is not a tty. Not changing mode at /usr/share/perl5/Expect.pm line 393, <> line 8.
1352         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1353         $^W = 1;
1354     }
1355 }
1356
1357 # When exp-spawned command ignores SIGHUP, Expect waits 5 seconds
1358 # before killing it. We kill it by SIGTERM immediately.
1359 kill TERM => $exp->pid if defined $exp && $exp->pid;
1360
1361 ## Kill dhcpc or tftpd
1362 if (defined $dhcp_tftp || defined $tftp) {
1363     die("novaboot: This should kill servers on background\n");
1364 }
1365
1366 # Always finish novaboot output with newline
1367 print "\n" if $final_eol;
1368
1369 ## Documentation
1370
1371 =encoding utf8
1372
1373 =head1 NAME
1374
1375 novaboot - Boots a locally compiled operating system on a remote
1376 target or in qemu
1377
1378 =head1 SYNOPSIS
1379
1380 B<novaboot> --help
1381
1382 B<novaboot> [option]... [--] script...
1383
1384 B<./script> [option]...
1385
1386 =head1 DESCRIPTION
1387
1388 Novaboot makes booting of a locally compiled operating system (OS)
1389 (e.g. NOVA or Linux) on remote targets as simple as running a program
1390 locally. It automates things like copying OS images to a TFTP server,
1391 generation of bootloader configuration files, resetting of target
1392 hardware or redirection of target's serial line to stdin/out. Novaboot
1393 is highly configurable and makes it easy to boot a single image on
1394 different targets or different images on a single target.
1395
1396 Novaboot operation is controlled by configuration files, command line
1397 options and by a so-called novaboot script, which can be thought as a
1398 generalization of bootloader configuration files (see L</"NOVABOOT
1399 SCRIPT SYNTAX">). The typical way of using novaboot is to make the
1400 novaboot script executable and set its first line to I<#!/usr/bin/env
1401 novaboot>. Then, booting a particular OS configuration becomes the
1402 same as executing a local program – the novaboot script.
1403
1404 Novaboot uses configuration files to, among other things, define
1405 command line options needed for different targets. Users typically use
1406 only the B<-t>/B<--target> command line option to select the target.
1407 Internally, this option expands to the pre-configured options.
1408 Novaboot searches configuration files at multiple places, which allows
1409 having per-system, per-user or per-project configurations.
1410 Configuration file syntax is described in section L</"CONFIGURATION
1411 FILES">.
1412
1413 Novaboot newcomers may be confused by a large number of configuration
1414 options. Understanding all these options is not always needed,
1415 depending on the used setup. The L<figure from the doc directory
1416 |https://github.com/wentasah/novaboot/blob/master/doc/typical-setups.svg>
1417 shows different setups that vary in how much effort is needed
1418 to configure novaboot for them. The setups are:
1419
1420 =over 3
1421
1422 =item A: Laptop and target device only
1423
1424 This requires to configure everything on the laptop side, including a
1425 serial line connection (L</--serial>, L</--remote-cmd>, ...), power
1426 on/off/reset commands (L</--reset-cmd>, ...), TFTP server
1427 (L</--copy>, L</--prefix>...), device IP addresses, etc.
1428
1429 =item B: Laptop, target device and external TFTP server
1430
1431 Like the previous setup, but the TFTP (and maybe DHCP) configuration
1432 is handled by a server. Novaboot users need to understand where to
1433 copy their files to the TFTP server (L</--copy>) and which IP
1434 addresses their target will get, but do not need to configure the
1435 servers themselves.
1436
1437 =item C: Novaboot server running novaboot-shell
1438
1439 With this setup, the configuration is done on the server. Users only
1440 need to know the SSH account (L</--ssh>) used to communicate between
1441 novaboot and novaboot server. The server is implemented as a
1442 restricted shell (L<novaboot-shell(1)>) on the server. No need to give
1443 full shell access to novaboot users on the server.
1444
1445 =back
1446
1447 =head2 Simple examples of using C<novaboot>:
1448
1449 To boot Linux (files F<bzImage> and F<rootfs.cpio> in current
1450 directory), create F<mylinux> file with this content:
1451
1452     #!/usr/bin/env novaboot
1453     load bzImage console=ttyS0,115200
1454     load rootfs.cpio
1455
1456 =over 3
1457
1458 =item 1.
1459
1460 Booting an OS in Qemu can be accomplished by giving the B<--qemu> option.
1461 Thus running
1462
1463  novaboot --qemu mylinux
1464
1465 (or C<./mylinux --qemu> as described above) will run Qemu and make it
1466 boot the configuration specified in the F<mylinux> script. How is qemu
1467 started can be configured in various ways (see below).
1468
1469 =item 2.
1470
1471 Create a bootloader configuration file (currently supported
1472 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar, and U-Boot) and copy it
1473 with all other files needed for booting to a remote TFTP server. Then
1474 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1475 target and receive its serial output.
1476
1477  ./mylinux --grub2 --copy=192.168.1.1:/tftp --iprelay=192.168.1.2
1478
1479 Alternatively, you can put these switches to the configuration file
1480 and run:
1481
1482  ./mylinux --target mytarget
1483
1484 =item 3.
1485
1486 Specifying all the options needed by novaboot to successfully control
1487 the target, either on command line or in configuration files, can be
1488 difficult for users. Novaboot supports configuring the target
1489 centrally via L<novaboot-shell(1)> on a server. With such a
1490 configuration, users only need to use the B<--ssh> option to specify
1491 where to boot their OS:
1492
1493  ./mylinux --ssh myboard@example.com
1494
1495 Typically, the server is the computer connected to and controlling the
1496 target board and running the TFTP server.
1497
1498 =item 4.
1499
1500 Run DHCP and TFTP server on developer's machine to boot the target
1501 from it.
1502
1503  ./mylinux --dhcp-tftp
1504
1505 This usage is useful when no network infrastructure is in place, and
1506 the target is connected directly to developer's box.
1507
1508 =item 5.
1509
1510 Create bootable ISO image.
1511
1512  novaboot --iso -- script1 script2
1513
1514 The created ISO image will have ISOLINUX bootloader installed on it,
1515 and the boot menu will allow selecting between I<script1> and
1516 I<script2> configurations.
1517
1518 =back
1519
1520 =head1 OPTIONS AND PHASES
1521
1522 Novaboot performs its work in several phases. Command line options
1523 described bellow influence the execution of each phase or allow their
1524 skipping. The list of phases (in the execution order) is as follows.
1525
1526 =over
1527
1528 =item 1. L<Configuration reading|/Configuration reading phase>
1529
1530 =item 2. L<Command line processing|/Command line processing phase>
1531
1532 =item 3. L<Script preprocessing|/Script preprocessing phase>
1533
1534 =item 4. L<File generation|/File generation phase>
1535
1536 =item 5. L<Target connection|/Target connection check>
1537
1538 =item 6. L<File deployment|/File deployment phase>
1539
1540 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1541
1542 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1543
1544 =item 9. L<Target interaction|/Target interaction phase>
1545
1546 =back
1547
1548 Each phase is described in the following sections together with the
1549 command line options that control it.
1550
1551 =head2 Configuration reading phase
1552
1553 After starting, novaboot reads zero or more configuration files. We
1554 describe their content in section L</"CONFIGURATION FILES">. By default, the
1555 configuration is read from multiple locations. First from the system
1556 configuration directory (F</etc/novaboot.d/>), second from the user
1557 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1558 files along the path to the current directory. Alternatively, a single
1559 configuration file specified with the B<-c> switch or with the
1560 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1561 override settings from the former ones.
1562
1563 The system configuration directory is determined by the content of
1564 NOVABOOT_CONFIG_DIR environment variable and defaults to
1565 F</etc/novaboot.d>. Files in this directory with names consisting
1566 solely of English letters, numbers, dashes '-' and underscores '_'
1567 (note that dot '.' is not included) are read in alphabetical order.
1568
1569 Then, the user configuration file is read from
1570 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environment
1571 variable is not set F<~/.config/novaboot> is read instead.
1572
1573 Finally, novaboot searches for files named F<.novaboot> starting from the
1574 directory of the novaboot script (or working directory, see bellow)
1575 and continuing upwards up to the root directory. The found
1576 configuration files are then read in the opposite order (i.e. from the
1577 root directory downwards). This ordering allows having, for example, a project
1578 specific configuration in F<~/project/.novaboot>.
1579
1580 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1581 The former one is always read, whereas the latter only when novaboot
1582 script or working directory is under the C<$HOME> directory.
1583
1584 In certain cases, the location of the novaboot script cannot be
1585 determined in this early phase. This situation happens either when the script is
1586 read from the standard input or when novaboot is invoked explicitly as
1587 in the example L</"4."> above. In this case, the current working
1588 directory is used as a starting point for configuration file search
1589 instead of the novaboot script directory.
1590
1591 =over 8
1592
1593 =item -c, --config=I<filename>
1594
1595 Use the specified configuration file instead of the default one(s).
1596
1597 =back
1598
1599 =head2 Command line processing phase
1600
1601 =over 8
1602
1603 =item --dump-config
1604
1605 Dump the current configuration to stdout end exit. Useful as an
1606 initial template for a configuration file.
1607
1608 =item -h, --help
1609
1610 Print short (B<-h>) or long (B<--help>) help.
1611
1612 =item -t, --target=I<target>
1613
1614 This option serves as a user configurable shortcut for other novaboot
1615 options. The effect of this option is the same as specifying the
1616 options stored in the C<%targets> configuration variable under key
1617 I<target>. See also L</"CONFIGURATION FILES">.
1618
1619 When this option is not given, novaboot tries to determine the target
1620 to use from either B<NOVABOOT_TARGET> environment variable or
1621 B<$default_target> configuration file variable.
1622
1623 =item --ssh=I<user@hostname>
1624
1625 Configures novaboot to control the target via C<novaboot-shell>
1626 running remotely via SSH.
1627
1628 Using this option is the same as specifying B<--remote-cmd>,
1629 B<--remote-expect>, B<--copy> B<--rsync-flags>, B<--prefix> and
1630 B<--reset-cmd> manually in a way compatible with C<novaboot-shell>.
1631 The server can be configured to provide other, safe bootloader-related
1632 options, to the client. When this happens, novaboot prints them to
1633 stdout.
1634
1635 Currently, this in an initial experimental implementation. We plan to
1636 change/extend this feature soon!
1637
1638 =back
1639
1640 =head2 Script preprocessing phase
1641
1642 This phase allows modifying the parsed novaboot script before it is
1643 used in the later phases.
1644
1645 =over 8
1646
1647 =item -a, --append=I<parameters>
1648
1649 Append a string to the first C<load> line in the novaboot script. This option
1650 can be used to append parameters to the kernel's or root task's
1651 command line. This option can appear multiple times.
1652
1653 =item -b, --bender
1654
1655 Use L<Bender|https://github.com/TUD-OS/morbo/blob/master/standalone/bender.c>
1656 chainloader. Bender scans the PCI bus for PCI serial ports and stores
1657 the information about them in the BIOS data area for use by the
1658 kernel.
1659
1660 =item --chainloader=I<chainloader>
1661
1662 Specifies a chainloader that is loaded before the kernel and other
1663 files specified in the novaboot script. E.g. 'bin/boot/bender
1664 promisc'.
1665
1666 =item --dump
1667
1668 Print the modules to boot and their parameters, after this phase
1669 finishes. Then exit. This is useful for seeing the effect of other
1670 options in this section.
1671
1672 =item -k, --kernel=F<file>
1673
1674 Replace the first word on the first C<load> line in the novaboot
1675 script with F<file>.
1676
1677 =item --scriptmod=I<Perl expression>
1678
1679 When novaboot reads the script, I<Perl expression> is executed for every
1680 line (in $_ variable). For example, C<novaboot
1681 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1682 in the script with I<omega6>.
1683
1684 When this option is present, it overrides I<$script_modifier> variable
1685 from the configuration file, which has the same effect. If this option
1686 is given multiple times all expressions are evaluated in the command
1687 line order.
1688
1689 =back
1690
1691 =head2 File generation phase
1692
1693 In this phase, files needed for booting are generated in a so-called
1694 I<build directory> (see L</--build-dir>). In most cases configuration
1695 for a bootloader is generated automatically by novaboot. It is also
1696 possible to generate other files using I<heredoc> or I<"<"> syntax in
1697 novaboot scripts. Finally, novaboot can generate binaries in this phases by
1698 running C<scons> or C<make>.
1699
1700 =over 8
1701
1702 =item --build-dir=I<directory>
1703
1704 Overrides the default build directory location.
1705
1706 The default build directory location is determined as follows: If the
1707 configuration file defines the C<$builddir> variable, its value is
1708 used. Otherwise, it is the directory that contains the first processed
1709 novaboot script.
1710
1711 See also L</BUILDDIR> variable.
1712
1713 =item -g, --grub[=I<filename>]
1714
1715 Generates grub bootloader menu file. If the I<filename> is not
1716 specified, F<menu.lst> is used. The I<filename> is relative to the
1717 build directory (see B<--build-dir>).
1718
1719 =item --grub-preamble=I<prefix>
1720
1721 Specifies the I<preamble> that is at the beginning of the generated
1722 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1723 timeout.
1724
1725 =item --prefix=I<prefix>
1726
1727 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1728 filename in generated bootloader configuration files (or in U-Boot
1729 commands).
1730
1731 If the I<prefix> contains string $NAME, it will be replaced with the
1732 name of the novaboot script (see also B<--name>).
1733
1734 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1735 the build directory (see also B<--build-dir>).
1736
1737 =item --grub-prefix
1738
1739 Alias for B<--prefix>.
1740
1741 =item --grub2[=I<filename>]
1742
1743 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1744 specified F<./boot/grub/grub.cfg> is used. The content of the menu entry can be
1745 customized with B<--grub-preamble>, B<--grub2-prolog> or
1746 B<--grub_prefix> options.
1747
1748 GRUB2 can boot multiboot-compliant kernels and a few kernels with specific
1749 support. L</BOOT_METHOD> could be used to specify the command used by GRUB2 to
1750 load the kernel. See L<GNU GRUB Manual|https://www.gnu.org/software/grub/manual/grub/grub.html#Booting>.
1751
1752 To use the generated menu entry on your development
1753 machine that uses GRUB2, append the following snippet to
1754 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1755 i.e. run update-grub on Debian/Ubuntu.
1756
1757   if [ -f /path/to/nul/build/grub.cfg ]; then
1758     source /path/to/nul/build/grub.cfg
1759   fi
1760
1761 =item --grub2-prolog=I<prolog>
1762
1763 Specifies the text that novaboot puts at the beginning of the GRUB2 menu entry.
1764
1765 =item -m, --make[=make command]
1766
1767 Runs C<make> to build files that are not generated by novaboot itself.
1768
1769 =item --name=I<string>
1770
1771 Use the name I<string> instead of the name of the novaboot script.
1772 This name is used for things like a title of grub menu or for the
1773 server directory where the boot files are copied to.
1774
1775 =item --no-file-gen
1776
1777 Do not run external commands to generate files (i.e. "<" syntax and
1778 C<run> keyword). This switch does not influence the generation of files
1779 specified with "<<WORD" syntax.
1780
1781 =item -p, --pulsar[=mac]
1782
1783 Generates pulsar bootloader configuration file named F<config-I<mac>>
1784 The I<mac> string is typically a MAC address and defaults to
1785 I<novaboot>.
1786
1787 =item --scons[=scons command]
1788
1789 Runs C<scons> to build files that are not generated by novaboot
1790 itself.
1791
1792 =item --strip-rom
1793
1794 Strip I<rom://> prefix from command lines and generated config files.
1795 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1796
1797 =item --gen-only
1798
1799 Exit novaboot after file generation phase.
1800
1801 =back
1802
1803 =head2 Target connection check
1804
1805 In this phase novaboot connects to target's serial port (if it has
1806 one). If another novaboot user/instance occupies the target, novaboot
1807 exits here with an error message.
1808
1809 =over 8
1810
1811 =item --amt=I<"[user[:password]@]host[:port]>
1812
1813 Use Intel AMT technology to control the target machine. WS management
1814 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1815 The hostname or (IP address) is given by the I<host> parameter. If the
1816 I<password> is not specified, environment variable AMT_PASSWORD is
1817 used. The I<port> specifies a TCP port for SOL. If not specified, the
1818 default is 16992. The default I<user> is admin.
1819
1820 =item --iprelay=I<addr[:port]>
1821
1822 Use TCP/IP relay and serial port to access the target's serial port
1823 and powercycle it. The I<addr> parameter specifies the IP address of
1824 the relay. If I<port> is not specified, it defaults to 23.
1825
1826 Note: This option is supposed to work with HWG-ER02a IP relays.
1827
1828 =item --iprelay-cmd=I<command>
1829
1830 Similar to B<--iprelay> but uses I<command> to talk to the iprelay
1831 rather than direct network connection.
1832
1833 =item -s, --serial[=device]
1834
1835 Target's serial line is connected to host's serial line (device). The
1836 default value for device is F</dev/ttyUSB0>.
1837
1838 The value of this option is exported in NB_NOVABOOT environment
1839 variable to all subprocesses run by C<novaboot>.
1840
1841 =item --stty=I<settings>
1842
1843 Specifies settings passed to C<stty> invoked on the serial line
1844 specified with B<--serial> option. If this option is not given,
1845 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1846
1847 =item --remote-cmd=I<cmd>
1848
1849 Command that mediates connection to the target's serial line. For
1850 example C<ssh server 'cu -l /dev/ttyS0'>.
1851
1852 =item --remote-expect=I<string>
1853
1854 Wait for reception of I<string> after establishing the remote serial
1855 line connection. Novaboot assumes that after establishing the serial
1856 line connection, the user running novaboot has exclusive access to the
1857 target. If establishing of the serial line connection happens
1858 asynchronously (e.g. running a command remotely via SSH), we need this
1859 option to wait until the exclusive access is confirmed by the remote
1860 side.
1861
1862 Depending on target configuration, this option can solve two practical
1863 problems: 1) Overwriting of files deployed by another user currently
1864 using the target. 2) Resetting the target board before serial line
1865 connection is established and thus missing bootloader interaction.
1866
1867 Example of usage with the L<sterm
1868 tool|https://rtime.felk.cvut.cz/gitweb/sojka/sterm.git>:
1869
1870   --remote-cmd='ssh -tt example.com sterm -v /dev/ttyUSB0' --remote-expect='sterm: Connected'
1871
1872 =item --remote-expect-silent=I<string>
1873
1874 The same as B<--remote-expect> except that the remote output is not
1875 echoed to stdout while waiting for the I<string>. Everything after the
1876 matched string is printed to stdout, so you may want to include line
1877 end characters in the I<string> as well.
1878
1879 =item --remote-expect-timeout=I<seconds>
1880
1881 Timeout in seconds for B<--remote-expect> or
1882 B<--remote-expect-seconds>. When negative, waits forever. The default
1883 is -1 seconds.
1884
1885 =back
1886
1887 =head2 File deployment phase
1888
1889 In some setups, it is necessary to copy the files needed for booting
1890 to a particular location, e.g. to a TFTP boot server or to the
1891 F</boot> partition.
1892
1893 =over 8
1894
1895 =item -d, --dhcp-tftp
1896
1897 Turns your workstation into a DHCP and TFTP server so that the OS can
1898 be booted via PXE BIOS (or similar mechanism) on the test machine
1899 directly connected by a plain Ethernet cable to your workstation.
1900
1901 The DHCP and TFTP servers require root privileges and C<novaboot>
1902 uses C<sudo> command to obtain those. You can put the following to
1903 I</etc/sudoers> to allow running the necessary commands without asking
1904 for a password.
1905
1906  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1907  your_login ALL=NOPASSWD: NOVABOOT
1908
1909 =item --tftp
1910
1911 Starts a TFTP server on your workstation. This is similar to
1912 B<--dhcp-tftp> except that DHCP server is not started.
1913
1914 The TFTP server requires root privileges and C<novaboot> uses C<sudo>
1915 command to obtain those. You can put the following to I</etc/sudoers>
1916 to allow running the necessary commands without asking for a password.
1917
1918  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1919  your_login ALL=NOPASSWD: NOVABOOT
1920
1921 =item --tftp-port=I<port>
1922
1923 Port to run the TFTP server on. Implies B<--tftp>.
1924
1925 =item --netif=I<network interface>
1926
1927 Network interface used to deploy files to the target. This option
1928 influences the configuration of the DHCP server started by
1929 B<--dhcp-tftp> and the value that B<$NB_MYIP> get replaced with during
1930 U-Boot conversation. The default value is C<$netif> variable from
1931 configuration files, which defaults to I<eth0>.
1932
1933 =item --iso[=filename]
1934
1935 Generates the ISO image that boots NOVA system via GRUB. If no filename
1936 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1937 of the novaboot script (see also B<--name>).
1938
1939 =item --server[=[[user@]server:]path]
1940
1941 Alias of B<--copy> (kept for backward compatibility).
1942
1943 =item --copy[=[[user@]server:]path]
1944
1945 Copy all files needed for booting to another location. The files will
1946 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1947 contains string $NAME, it will be replaced with the name of the
1948 novaboot script (see also B<--name>).
1949
1950 =item --rsync-flags=I<flags>
1951
1952 Specifies I<flags> to append to F<rsync> command line when
1953 copying files as a result of I<--copy> option.
1954
1955 =item --concat
1956
1957 If B<--copy> is used and its value ends with $NAME, then after
1958 copying the files, a new bootloader configuration file (e.g. menu.lst)
1959 is created at I<path-wo-name>, i.e. the path specified by B<--copy>
1960 with $NAME part removed. The content of the file is created by
1961 concatenating all files of the same name from all subdirectories of
1962 I<path-wo-name> found on the "server".
1963
1964 =item --ider
1965
1966 Use Intel AMT technology for IDE redirection. This allows the target
1967 machine to boot from novaboot created ISO image. Implies B<--iso>.
1968
1969 The experimental C<amtider> utility needed by this option can be
1970 obtained from https://github.com/wentasah/amtterm.
1971
1972 =back
1973
1974 =head2 Target power-on and reset phase
1975
1976 At this point, the target is reset (or switched on/off). There are
1977 several ways how this can be accomplished. Resetting a physical target
1978 can currently be accomplished by the following options: B<--amt>,
1979 B<--iprelay>, B<--reset-cmd> and B<--reset-send>.
1980
1981 =over 8
1982
1983 =item --on, --off
1984
1985 Switch on/off the target machine and exit. The script (if any) is
1986 completely ignored. Currently, it works only with the following
1987 options: B<--iprelay>, B<--amt>, B<--ssh>.
1988
1989 =item -Q, --qemu[=I<qemu-binary>]
1990
1991 Boot the configuration in qemu. Optionally, the name of qemu binary
1992 can be specified as a parameter.
1993
1994 =item --qemu-append=I<flags>
1995
1996 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1997 C<-cpu coreduo -smp 2>).
1998
1999 =item -q, --qemu-flags=I<flags>
2000
2001 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
2002 -smp 2>) with I<flags> specified here.
2003
2004 =item --reset-cmd=I<cmd>
2005
2006 Runs command I<cmd> to reset the target.
2007
2008 =item --reset-send=I<string>
2009
2010 Reset the target by sending the given I<string> to the remote serial
2011 line. "\n" sequences are replaced with the newline character.
2012
2013 =item --no-reset, --reset
2014
2015 Disable/enable resetting of the target.
2016
2017 =back
2018
2019 =head2 Interaction with the bootloader on the target
2020
2021 =over 8
2022
2023 =item --uboot[=I<prompt>]
2024
2025 Interact with U-Boot bootloader to boot the thing described in the
2026 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
2027 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
2028
2029 =item --no-uboot
2030
2031 Disable U-Boot interaction previously enabled with B<--uboot>.
2032
2033 =item --uboot-stop-key=I<key>
2034
2035 Character, which is sent as a response to U-Boot's "Hit any key to
2036 stop autoboot" message. The default value is newline, but some devices
2037 (e.g. TP-Link TD-W8970) require a specific key to be pressed.
2038
2039 =item --uboot-init
2040
2041 Command(s) to send the U-Boot bootloader before loading the images and
2042 booting them. This option can be given multiple times. After sending
2043 commands from each option novaboot waits for U-Boot I<prompt>.
2044
2045 If the command contains string I<$NB_MYIP> then this string is
2046 replaced by IPv4 address of eth0 interface (see also B<--netif>).
2047 Similarly, I<$NB_PREFIX> is replaced with prefix given by B<--prefix>.
2048
2049 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
2050
2051 =item --uboot-addr I<name>=I<address>
2052
2053 Load address of U-Boot's C<tftpboot> command for loading I<name>,
2054 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
2055 tree).
2056
2057 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
2058 variables used by convention for this purpose.
2059
2060 =item --uboot-cmd=I<command>
2061
2062 Specifies U-Boot command used to execute the OS. If the command
2063 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
2064 these are replaced with the addresses configured with B<--uboot-addr>.
2065
2066 The default value is
2067
2068     bootm $kernel_addr $ramdisk_addr $fdt_addr
2069
2070 or the C<UBOOT_CMD> variable if defined in the novaboot script.
2071
2072 =back
2073
2074 =head2 Target interaction phase
2075
2076 In this phase, target's serial output is redirected to stdout and if
2077 stdin is a TTY, it is redirected to the target's serial input allowing
2078 interactive work with the target.
2079
2080 =over 8
2081
2082 =item --exiton=I<string>
2083
2084 When the I<string> is sent by the target, novaboot exits. This option can
2085 be specified multiple times, in which case novaboot exits whenever
2086 either of the specified strings is sent.
2087
2088 If the I<string> is C<-re>, then the next B<--exiton>'s I<string> is
2089 treated as a regular expression. For example:
2090
2091     --exiton -re --exiton 'error:.*failed'
2092
2093 =item --exiton-re=I<regex>
2094
2095 The same as --exiton -re --exiton I<regex>.
2096
2097 =item --exiton-timeout=I<seconds>
2098
2099 By default B<--exiton> waits for the string match forever. When this
2100 option is specified, "exiton" timeouts after the specified number of
2101 seconds and novaboot returns non-zero exit code.
2102
2103 =item -i, --interactive
2104
2105 Setup things for the interactive use of the target. Your terminal will
2106 be switched to raw mode. In raw mode, your local terminal does not
2107 process input in any way (no echoing of entered characters, no
2108 interpretation of special characters). This, among others, means that
2109 Ctrl-C is passed to the target and does not interrupt novaboot. To
2110 exit from novaboot interactive mode type "~~.".
2111
2112 =item --no-interaction, --interaction
2113
2114 Skip resp. force target interaction phase. When skipped, novaboot exits
2115 immediately after the boot is initiated.
2116
2117 =item --expect=I<string>
2118
2119 When the I<string> is received from the target, send the string specified
2120 with the subsequent B<--send*> option to the target.
2121
2122 =item --expect-re=I<regex>
2123
2124 When target's output matches regular expression I<regex>, send the
2125 string specified with the subsequent B<--send*> option to the target.
2126
2127 =item --expect-raw=I<perl-code>
2128
2129 Provides direct control over Perl's Expect module.
2130
2131 =item --send=I<string>
2132
2133 Send I<string> to the target after the previously specified
2134 B<--expect*> was matched in the target's output. The I<string> may
2135 contain escape sequences such as "\n".
2136
2137 Note that I<string> is actually interpreted by Perl, so it can contain
2138 much more that escape sequences. This behavior may change in the
2139 future.
2140
2141 Example: C<--expect='login: ' --send='root\n'>
2142
2143 =item --sendcont=I<string>
2144
2145 Similar to B<--send> but continue expecting more input.
2146
2147 Example: C<--expect='Continue?' --sendcont='yes\n'>
2148
2149 =item --final-eol, --no-final-eol
2150
2151 By default, B<novaboot> always prints an end-of-line character at the
2152 end of its execution in order to ensure that the output of programs
2153 started after novaboot appears at the beginning of the line. When this
2154 is not desired B<--no-final-eol> option can be used to override this
2155 behavior.
2156
2157 =back
2158
2159 =head1 NOVABOOT SCRIPT SYNTAX
2160
2161 The syntax tries to mimic POSIX shell syntax. The syntax is defined
2162 by the following rules.
2163
2164 Lines starting with "#" and empty lines are ignored.
2165
2166 Lines that end with "\" are concatenated with the following line after
2167 removal of the final "\" and leading whitespace of the following line.
2168
2169 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
2170 expression) assign values to internal variables. See L</VARIABLES>
2171 section.
2172
2173 Otherwise, the first word on the line defines the meaning of the line.
2174 The following keywords are supported:
2175
2176 =over 4
2177
2178 =item C<load>
2179
2180 These lines represent modules to boot. The
2181 word after C<load> is a file name (relative to the build directory
2182 (see B<--build-dir>) of the module to load and the remaining words are
2183 passed to it as the command line parameters.
2184
2185 When booting Linux, the first C<load> line usually refers to the
2186 kernel image and its command line parameters (unless you use some
2187 special pre-loader). Other C<load> lines may refer to an initramfs
2188 image and/or a device tree blob. Their order is not important, as the
2189 device tree is recognized as the file name ending with C<.dtb>.
2190
2191 When the C<load> line ends with "<<WORD" then the subsequent lines
2192 until the line containing solely WORD are copied literally to the file
2193 named on that line. This is similar to the heredoc feature of UNIX
2194 shells.
2195
2196 When the C<load> line ends with "< CMD" then command CMD is executed
2197 with F</bin/sh> and its standard output is stored in the file named on
2198 that line. The SRCDIR variable in CMD's environment is set to the
2199 absolute path of the directory containing the interpreted novaboot
2200 script.
2201
2202 =item C<copy>
2203
2204 These lines are similar to C<load> lines. The
2205 file mentioned there is copied to the same place as in the case of C<load>
2206 (e.g. tftp server), but the file is not used in the bootloader
2207 configuration. Such a file can be used by the target for other
2208 purposes than booting, e.g. at OS runtime or for firmware update.
2209
2210 =item C<chld>
2211
2212 Chainload another bootloader. Instead of loading multiboot modules
2213 identified with C<load> keyword, run another bootloader. This is
2214 currently supported only by pulsar and can be used to load e.g. Grub
2215 as in the example below:
2216
2217  chld boot/grub/i386-pc/core.0
2218
2219
2220 =item C<run>
2221
2222 Lines starting with C<run> keyword contain shell commands that are run
2223 during file generation phase. This is the same as the "< CMD" syntax
2224 for C<load> keyboard except that the command's output is not
2225 redirected to a file. The ordering of commands is the same as they
2226 appear in the novaboot script.
2227
2228 =item C<uboot>
2229
2230 These lines represent U-Boot commands that are sent to the target if
2231 B<--uboot> option is given. Having a U-Boot line in the novaboot
2232 script is the same as giving B<--uboot-init> option to novaboot. The
2233 following syntax variants are supported:
2234
2235
2236   uboot[:<timeout>] <string> [> <file>]
2237   uboot[:<timeout>] < <shell> [> <file>]
2238
2239 C<string> is the literal U-Boot command.
2240
2241 The C<uboot> keyword can be suffixed with timeout specification. The
2242 syntax is C<uboot:Ns>, where C<N> is the whole number of seconds. If
2243 the U-Boot command prompt does not appear before the timeout, novaboot
2244 fails. The default timeout is 10 seconds.
2245
2246 In the second variant with the C<<> character the shell code is
2247 executed and its standard output is sent to U-Boot. Example:
2248
2249   uboot < printf "mmc write \$loadaddr 1 %x" $(($(/usr/bin/stat -c%s rootfs.ext4) / 512))
2250
2251 When C<E<gt> file> part is present, the output of the U-Boot command
2252 is written into the given file.
2253
2254 =back
2255
2256 Example (Linux):
2257
2258   #!/usr/bin/env novaboot
2259   load bzImage console=ttyS0,115200
2260   run  make -C buildroot
2261   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
2262
2263 Example (NOVA User Land - NUL):
2264
2265   #!/usr/bin/env novaboot
2266   WVDESC=Example program
2267   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
2268                            verbose hostkeyb:0,0x60,1,12,2
2269   load bin/apps/hello.nul
2270   load hello.nulconfig <<EOF
2271   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
2272   rom://bin/apps/hello.nul
2273   EOF
2274
2275 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
2276 F<hello.nulconfig>. sigma0 receives some command line parameters and
2277 F<hello.nulconfig> file is generated on the fly from the lines between
2278 C<<<EOF> and C<EOF>.
2279
2280 Example (Zynq system update via U-Boot):
2281
2282   #!/usr/bin/env novaboot
2283
2284   uboot dhcp
2285
2286   # Write kernel to FAT filesystem on the 1st SD card partition
2287   run mkimage -f uboot-image.its image.ub
2288   copy image.ub
2289   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/image.ub
2290   uboot fatwrite mmc 0:1 ${loadaddr} image.ub $filesize
2291   uboot set bootargs console=ttyPS0,115200 root=/dev/mmcblk0p2
2292
2293   # Write root FS image to the 2nd SD card partition
2294   copy rootfs/images/rootfs.ext4
2295   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/rootfs/images/rootfs.ext4
2296   uboot mmc part > mmc-part.txt
2297   uboot < printf "mmc write \$loadaddr %x %x" $(awk '{ if ($1 == "2") { print $2 }}' mmc-part.txt) $(($(/usr/bin/stat -L --printf=%s rootfs/images/rootfs.ext4) / 512))
2298
2299   UBOOT_CMD=boot
2300
2301
2302 =head2 VARIABLES
2303
2304 The following variables are interpreted in the novaboot script:
2305
2306 =over 8
2307
2308 =item BOOT_METHOD
2309
2310 Specifies the way GRUB2 boots the kernel. For kernels with multiboot
2311 support use C<multiboot> method (the default). For Linux kernel use C<linux> method.
2312
2313 =item BUILDDIR
2314
2315 Novaboot chdir()s to this directory before file generation phase. The
2316 directory name specified here is relative to the build directory
2317 specified by other means (see L</--build-dir>).
2318
2319 =item EXITON
2320
2321 Assigning this variable has the same effect as specifying L</--exiton>
2322 option.
2323
2324 =item INTERACTION
2325
2326 Setting this variable to zero is the same as giving
2327 L</--no-interaction>, specifying to one corresponds to
2328 L</--interaction>.
2329
2330 =item HYPERVISOR_PARAMS
2331
2332 Parameters passed to the hypervisor. The default value is "serial", unless
2333 overridden in the configuration file.
2334
2335 =item KERNEL
2336
2337 The kernel to use instead of the hypervisor specified in the
2338 configuration file with the C<$hypervisor> variable. The value should
2339 contain the name of the kernel image as well as its command line
2340 parameters. If this variable is defined and non-empty, the variable
2341 HYPERVISOR_PARAMS is not used.
2342
2343 =item NO_BOOT
2344
2345 If this variable is 1, the system is not booted. This is currently
2346 only implemented for U-Boot bootloader where it is useful for
2347 interacting with the bootloader without booting the system - e.g. for
2348 flashing.
2349
2350 =item QEMU
2351
2352 Use a specific qemu binary (can be overridden with B<-Q>) and flags
2353 when booting this script under qemu. If QEMU_FLAGS variable is also
2354 specified flags specified in QEMU variable are replaced by those in
2355 QEMU_FLAGS.
2356
2357 =item QEMU_FLAGS
2358
2359 Use specific qemu flags (can be overridden with B<-q>).
2360
2361 =item UBOOT_CMD
2362
2363 See L</--uboot-cmd>.
2364
2365 =item WVDESC
2366
2367 Description of the WvTest-compliant program.
2368
2369 =item WVTEST_TIMEOUT
2370
2371 The timeout in seconds for WvTest harness. If no complete line appears
2372 in the test output within the time specified here, the test fails. It
2373 is necessary to specify this for long running tests that produce no
2374 intermediate output.
2375
2376 =back
2377
2378 =head1 CONFIGURATION FILES
2379
2380 Novaboot can read its configuration from one or more files. By
2381 default, novaboot looks for files in F</etc/novaboot.d>, file
2382 F<~/.config/novaboot> and files named F<.novaboot> as described in
2383 L</Configuration reading phase>. Alternatively, configuration file
2384 location can be specified with the B<-c> switch or with the
2385 NOVABOOT_CONFIG environment variable. The configuration file has Perl
2386 syntax (i.e. it is better to put C<1;> as the last line) and should set
2387 values of certain Perl variables. The current configuration can be
2388 dumped with the B<--dump-config> switch. Some configuration variables
2389 can be overridden by environment variables (see below) or by command
2390 line switches.
2391
2392 Supported configuration variables include:
2393
2394 =over 8
2395
2396 =item $builddir
2397
2398 Build directory location relative to the location of the configuration
2399 file.
2400
2401 =item $default_target
2402
2403 Default target (see below) to use when no target is explicitly
2404 specified with the B<--target> command line option or
2405 B<NOVABOOT_TARGET> environment variable.
2406
2407 =item $netif
2408
2409 Default value for the B<--netif> option. If not specified, it defaults
2410 to I<eth0>.
2411
2412 =item %targets
2413
2414 Hash of target definitions to be used with the B<--target> option. The
2415 key is the identifier of the target, the value is the string with
2416 command line options. For instance, if the configuration file contains:
2417
2418  $targets{'mybox'} = '--copy=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
2419
2420 then the following two commands are equivalent:
2421
2422  ./myos --copy=boot:/tftproot --serial=/dev/ttyUSB0 --grub
2423  ./myos -t mybox
2424
2425 =back
2426
2427 =head1 ENVIRONMENT VARIABLES
2428
2429 Some options can be specified not only via config file or command line
2430 but also through environment variables. Environment variables override
2431 the values from the configuration file and command line parameters
2432 override the environment variables.
2433
2434 =over 8
2435
2436 =item NOVABOOT_CONFIG
2437
2438 Name of the novaboot configuration file to use instead of the default
2439 one(s).
2440
2441 =item NOVABOOT_CONFIG_DIR
2442
2443 Name of the novaboot configuration directory. When not specified
2444 F</etc/novaboot.d> is used.
2445
2446 =item NOVABOOT_TARGET
2447
2448 Name of the novaboot target to use. This overrides the value of
2449 B<$default_target> from the configuration file and can be overridden
2450 with the B<--target> command line option.
2451
2452 =item NOVABOOT_BENDER
2453
2454 Defining this variable has the same effect as using B<--bender>
2455 option.
2456
2457 =back
2458
2459 =head1 AUTHORS
2460
2461 Michal Sojka <sojka@os.inf.tu-dresden.de>
2462
2463 Latest novaboot version can be found at
2464 L<https://github.com/wentasah/novaboot>.
2465
2466 =cut
2467
2468 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2469 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2470 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2471 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest