novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use IO::Handle;
  26 use Time::HiRes("usleep");
  27 use Socket;
  28 use FileHandle;
  29 use IPC::Open2;
  30 use POSIX qw(:errno_h sysconf);
  31 use Cwd qw(getcwd abs_path);
  32 use Expect;
  33
  34 # always flush
  35 $| = 1;
  36
  37 my $invocation_dir = $ENV{PWD} || getcwd();
  38
  39 ## Configuration file handling
  40
  41 # Default configuration
  42 $CFG::hypervisor = "";
  43 $CFG::hypervisor_params = "serial";
  44 $CFG::genisoimage = "genisoimage";
  45 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  46 $CFG::default_target = '';
  47 %CFG::targets = (
  48     'qemu' => '--qemu',
  49     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  50     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.86.92:2324',
  51     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  52     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  53     "ryuglab" => '--target ryu --server=pc-sojkam.felk.cvut.cz:/srv/tftp --remote-cmd="ssh -tt pc-sojkam.felk.cvut.cz \"sterm -d -s 115200 /dev/ttyUSB0\""',
  54     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  55     );
  56
  57 {
  58     my %const;
  59     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  60     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  61
  62     $CFG::scons = "scons -j$nproc";
  63     $CFG::make = "make -j$nproc";
  64 }
  65
  66 my $builddir;
  67
  68 sub read_config($) {
  69     my ($cfg) = @_;
  70     {
  71         package CFG; # Put config data into a separate namespace
  72
  73         my $rc = do($cfg);
  74
  75         # Check for errors
  76         if ($@) {
  77             die("ERROR: Failure compiling '$cfg' - $@");
  78         } elsif (! defined($rc)) {
  79             die("ERROR: Failure reading '$cfg' - $!");
  80         } elsif (! $rc) {
  81             die("ERROR: Failure processing '$cfg'");
  82         }
  83     }
  84     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  85     print STDERR "novaboot: Read $cfg\n";
  86 }
  87
  88 my @cfgs;
  89 {
  90     # We don't use $0 here, because it points to the novaboot itself and
  91     # not to the novaboot script. The problem with this approach is that
  92     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  93     # contains the first option. Hence the -f check.
  94     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  95     while ((-d $dir || -l $dir ) && $dir ne "/") {
  96         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  97         my @dirs = File::Spec->splitdir($dir);
  98         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  99     }
 100     @cfgs = reverse @cfgs;
 101
 102     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 103     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 104
 105     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 106     if (opendir(my $dh, $dir)) {
 107         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 108         closedir $dh;
 109         @etccfg = sort(@etccfg);
 110         @cfgs = ( @etccfg, @cfgs );
 111     }
 112 }
 113 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 114 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 115 GetOptions ("config|c=s" => \$cfg);
 116 read_config($_) foreach $cfg or @cfgs;
 117
 118 ## Command line handling
 119
 120 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 121 GetOptions ("target|t=s" => \$explicit_target);
 122
 123 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $final_eol, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iso_image, $interactive, $kernel_opt, $make, $man, $netif, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $remote_expect_silent, $reset, $reset_cmd, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init);
 124
 125 # Default values of certain command line options
 126 %uboot_addr = (
 127     'kernel'  => '${kernel_addr_r}',
 128     'ramdisk' => '${ramdisk_addr_r}',
 129     'fdt'     => '${fdt_addr_r}',
 130     );
 131 $rsync_flags = '';
 132 $rom_prefix = 'rom://';
 133 $stty = 'raw -crtscts -onlcr 115200';
 134 $reset = 1;                     # Reset target by default
 135 $interaction = 1;               # Perform target interaction by default
 136 $final_eol = 1;
 137 $netif = 'eth0';
 138
 139 my @expect_seen = ();
 140 sub handle_expect
 141 {
 142     my ($n, $v) = @_;
 143     push(@expect_seen, '-re') if $n eq "expect-re";
 144     push(@expect_seen, $v);
 145 }
 146
 147 sub handle_send
 148 {
 149     my ($n, $v) = @_;
 150     unless (@expect_seen) { die("No --expect before --send"); }
 151     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 152     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 153     unshift(@expect_raw, @expect_seen);
 154     @expect_seen = ();
 155 }
 156
 157 my %opt_spec;
 158 %opt_spec = (
 159     "amt=s"          => \$amt,
 160     "append|a=s"     => \@append,
 161     "bender|b"       => \$bender,
 162     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 163     "concat"         => \$concat,
 164     "chainloader=s"  => \@chainloaders,
 165     "dhcp-tftp|d"    => \$dhcp_tftp,
 166     "dump"           => \$dump_opt,
 167     "dump-config"    => \$dump_config,
 168     "exiton=s"       => \@exiton,
 169     "exiton-timeout=i"=> \$exiton_timeout,
 170     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 171     "expect=s"       => \&handle_expect,
 172     "expect-re=s"    => \&handle_expect,
 173     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 174     "final-eol!"     => \$final_eol,
 175     "gen-only"       => \$gen_only,
 176     "grub|g:s"       => \$grub_config,
 177     "grub-preamble=s"=> \$grub_preamble,
 178     "prefix|grub-prefix=s" => \$grub_prefix,
 179     "grub2:s"        => \$grub2_config,
 180     "grub2-prolog=s" => \$grub2_prolog,
 181     "ider"           => \$ider,
 182     "interaction!"   => \$interaction,
 183     "iprelay=s"      => \$iprelay,
 184     "iso:s"          => \$iso_image,
 185     "kernel|k=s"     => \$kernel_opt,
 186     "interactive|i"  => \$interactive,
 187     "name=s"         => \$config_name_opt,
 188     "make|m:s"       => \$make,
 189     "netif=s"        => \$netif,
 190     "no-file-gen"    => \$no_file_gen,
 191     "off"            => \$off_opt,
 192     "on"             => \$on_opt,
 193     "pulsar|p:s"     => \$pulsar,
 194     "pulsar-root=s"  => \$pulsar_root,
 195     "qemu|Q:s"       => \$qemu,
 196     "qemu-append=s"  => \$qemu_append,
 197     "qemu-flags|q=s" => \$qemu_flags_cmd,
 198     "remote-cmd=s"   => \$remote_cmd,
 199     "remote-expect=s"=> \$remote_expect,
 200     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 201     "reset!"         => \$reset,
 202     "reset-cmd=s"    => \$reset_cmd,
 203     "rsync-flags=s"  => \$rsync_flags,
 204     "scons:s"        => \$scons,
 205     "scriptmod=s"    => \@scriptmod,
 206     "send=s"         => \&handle_send,
 207     "sendcont=s"     => \&handle_send,
 208     "serial|s:s"     => \$serial,
 209     "server:s"       => \$server,
 210     "strip-rom"      => sub { $rom_prefix = ''; },
 211     "stty=s"         => \$stty,
 212     "tftp"           => \$tftp,
 213     "tftp-port=i"    => \$tftp_port,
 214     "uboot:s"        => \$uboot,
 215     "no-uboot"       => sub { undef $uboot; },
 216     "uboot-addr=s"   => \%uboot_addr,
 217     "uboot-cmd=s"    => \$uboot_cmd,
 218     "uboot-init=s"   => \@uboot_init,
 219     "h"              => \$help,
 220     "help"           => \$man,
 221     );
 222
 223 # First process target options
 224 {
 225     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 226     my @target_expanded;
 227     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 228     while ($t) {
 229         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 230
 231         undef $explicit_target;
 232         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 233         if (!$ret) { die "Error parsing target $t option"; }
 234         push(@target_expanded, @$remaining_args);
 235         $t = $explicit_target;
 236     }
 237     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 238     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 239 }
 240
 241 # Then process other command line options - some of them may override
 242 # what was specified by the target
 243 GetOptions %opt_spec or die("Error in command line arguments");
 244 pod2usage(1) if $help;
 245 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 246
 247 ### Dump sanitized configuration (if requested)
 248
 249 if ($dump_config) {
 250     use Data::Dumper;
 251     $Data::Dumper::Indent=1;
 252     print "# This file is in perl syntax.\n";
 253     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 254         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 255         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 256         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 257     }
 258     print "1;\n";
 259     exit;
 260 }
 261
 262 ### Sanitize configuration
 263
 264 if ($interactive && !-t STDIN) {
 265     die("novaboot: Interactive mode not supported when not on terminal");
 266 }
 267
 268 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 269
 270 if ($ider) {
 271     $iso_image //= ''; # IDE-R needs an ISO image
 272     if (!defined $amt) { die "Error: --ider requires --amt"; }
 273 }
 274
 275 {
 276     my %input_opts = ('--iprelay'    => \$iprelay,
 277                       '--serial'     => \$serial,
 278                       '--remote-cmd' => \$remote_cmd,
 279                       '--amt'        => \$amt);
 280     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 281
 282     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 283 }
 284
 285 # Default options
 286 if (defined $serial) {
 287     $serial ||= "/dev/ttyUSB0";
 288     $ENV{NB_SERIAL} = $serial;
 289 }
 290 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 291 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 292
 293 ## Parse the novaboot script(s)
 294 my @scripts;
 295 my $file;
 296 my $EOF;
 297 my $last_fn = '';
 298 my ($modules, $variables, $generated, $continuation) = ([], {}, []);
 299 my $skip_reading = defined($on_opt) || defined($off_opt);
 300 while (!$skip_reading && ($_ = <>)) {
 301     if ($ARGV ne $last_fn) { # New script
 302         die "Missing EOF in $last_fn" if $file;
 303         die "Unfinished line in $last_fn" if $continuation;
 304         $last_fn = $ARGV;
 305         push @scripts, { 'filename' => $ARGV,
 306                          'modules' => $modules = [],
 307                          'variables' => $variables = {},
 308                          'generated' => $generated = []};
 309
 310     }
 311     chomp();
 312     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 313
 314     $_ =~ s/^[[:space:]]*// if ($continuation);
 315
 316     if (/\\$/) {                # Line continuation
 317         $continuation .= substr($_, 0, length($_)-1);
 318         next;
 319     }
 320
 321     if ($continuation) {        # Last continuation line
 322         $_ = $continuation . $_;
 323         $continuation = '';
 324     }
 325
 326     foreach my $mod(@scriptmod) { eval $mod; }
 327
 328     if ($file && $_ eq $EOF) {  # Heredoc end
 329         undef $file;
 330         next;
 331     }
 332     if ($file) {                # Heredoc content
 333         push @{$file}, "$_\n";
 334         next;
 335     }
 336     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 337         $$variables{$1} = $2;
 338         push(@exiton, $2) if ($1 eq "EXITON");
 339         next;
 340     }
 341     if (s/^load *//) {          # Load line
 342         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 343         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 344             push @$modules, "$1$2";
 345             $file = [];
 346             push @$generated, {filename => $1, content => $file};
 347             $EOF = $3;
 348             next;
 349         }
 350         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 351             push @$modules, "$1$2";
 352             push @$generated, {filename => $1, command => $3};
 353             next;
 354         }
 355         push @$modules, $_;
 356         next;
 357     }
 358     if (/^run (.*)/) {          # run line
 359         push @$generated, {command => $1};
 360         next;
 361     }
 362     if (/^uboot(?::([0-9]+)s)? (.*)/) { # uboot line
 363         # TODO: If U-Boot supports some interactive menu, it might
 364         # make sense to store uboot lines per novaboot script.
 365         if ($1) {               # Command with explicit timeout
 366             push @uboot_init, { command => $2,
 367                                 timeout => $1 };
 368         } else {                # Command without explicit timeout
 369             push @uboot_init, $2;
 370         }
 371         next;
 372     }
 373
 374     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 375 }
 376 # use Data::Dumper;
 377 # print Dumper(\@scripts);
 378
 379 foreach my $script (@scripts) {
 380     $modules = $$script{modules};
 381     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 382     @$modules[0] .= ' ' . join(' ', @append) if @append;
 383
 384     my $kernel;
 385     if (exists $variables->{KERNEL}) {
 386         $kernel = $variables->{KERNEL};
 387     } else {
 388         if ($CFG::hypervisor) {
 389             $kernel = $CFG::hypervisor . " ";
 390             if (exists $variables->{HYPERVISOR_PARAMS}) {
 391                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 392             } else {
 393                 $kernel .= $CFG::hypervisor_params;
 394             }
 395         }
 396     }
 397     @$modules = ($kernel, @$modules) if $kernel;
 398     @$modules = (@chainloaders, @$modules);
 399     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 400 }
 401
 402 if ($dump_opt) {
 403     foreach my $script (@scripts) {
 404         print join("\n", @{$$script{modules}})."\n";
 405     }
 406     exit(0);
 407 }
 408
 409 ## Helper functions
 410
 411 sub generate_configs($$$) {
 412     my ($base, $generated, $filename) = @_;
 413     if ($base) { $base = "$base/"; };
 414     foreach my $g(@$generated) {
 415       if (exists $$g{content}) {
 416         my $config = $$g{content};
 417         my $fn = $$g{filename};
 418         open(my $f, '>', $fn) || die("$fn: $!");
 419         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 420         close($f);
 421         print STDERR "novaboot: Created $fn\n";
 422       } elsif (exists $$g{command} && ! $no_file_gen) {
 423         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 424         if (exists $$g{filename}) {
 425             system_verbose("( $$g{command} ) > $$g{filename}");
 426         } else {
 427             system_verbose($$g{command});
 428         }
 429       }
 430     }
 431 }
 432
 433 sub generate_grub_config($$$$;$)
 434 {
 435     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 436     if ($base) { $base = "$base/"; };
 437     open(my $fg, '>', $filename) or die "$filename: $!";
 438     print $fg "$preamble\n" if $preamble;
 439     print $fg "title $title\n" if $title;
 440     #print $fg "root $base\n"; # root doesn't really work for (nd)
 441     my $first = 1;
 442     foreach (@$modules_ref) {
 443         if ($first) {
 444             $first = 0;
 445             my ($kbin, $kcmd) = split(' ', $_, 2);
 446             $kcmd = '' if !defined $kcmd;
 447             print $fg "kernel ${base}$kbin $kcmd\n";
 448         } else {
 449             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 450             print $fg "module $base$_\n";
 451         }
 452     }
 453     close($fg);
 454     print("novaboot: Created $builddir/$filename\n");
 455     return $filename;
 456 }
 457
 458 sub generate_syslinux_config($$$$)
 459 {
 460     my ($filename, $title, $base, $modules_ref) = @_;
 461     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 462     open(my $fg, '>', $filename) or die "$filename: $!";
 463     print $fg "LABEL $title\n";
 464     #TODO print $fg "MENU LABEL $human_readable_title\n";
 465
 466     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 467
 468     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 469         my $initrd = @$modules_ref[1];
 470         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 471         print $fg "LINUX $base$kbin\n";
 472         print $fg "APPEND $kcmd\n";
 473         print $fg "INITRD $base$initrd\n";
 474     } else {
 475         print $fg "KERNEL mboot.c32\n";
 476         my @append;
 477         foreach (@$modules_ref) {
 478             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 479             push @append, "$base$_";
 480             print $fg "APPEND ".join(' --- ', @append)."\n";
 481         }
 482     }
 483     #TODO print $fg "TEXT HELP\n";
 484     #TODO print $fg "some help here\n";
 485     #TODO print $fg "ENDTEXT\n";
 486     close($fg);
 487     print("novaboot: Created $builddir/$filename\n");
 488     return $filename;
 489 }
 490
 491 sub generate_grub2_config($$$$;$$)
 492 {
 493     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 494     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 495     open(my $fg, '>', $filename) or die "$filename: $!";
 496     print $fg "$preamble\n" if $preamble;
 497     $title ||= 'novaboot';
 498     print $fg "menuentry $title {\n";
 499     print $fg "$prolog\n" if $prolog;
 500     my $first = 1;
 501     foreach (@$modules_ref) {
 502         if ($first) {
 503             $first = 0;
 504             my ($kbin, $kcmd) = split(' ', $_, 2);
 505             $kcmd = '' if !defined $kcmd;
 506             print $fg "  multiboot ${base}$kbin $kcmd\n";
 507         } else {
 508             my @args = split;
 509             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 510             $_ = join(' ', ($args[0], @args));
 511             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 512             print $fg "  module $base$_\n";
 513         }
 514     }
 515     print $fg "}\n";
 516     close($fg);
 517     print("novaboot: Created $builddir/$filename\n");
 518     return $filename;
 519 }
 520
 521 sub generate_pulsar_config($$)
 522 {
 523     my ($filename, $modules_ref) = @_;
 524     open(my $fg, '>', $filename) or die "$filename: $!";
 525     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 526     my $first = 1;
 527     my ($kbin, $kcmd);
 528     foreach (@$modules_ref) {
 529         if ($first) {
 530             $first = 0;
 531             ($kbin, $kcmd) = split(' ', $_, 2);
 532             $kcmd = '' if !defined $kcmd;
 533         } else {
 534             my @args = split;
 535             s|\brom://|$rom_prefix|g;
 536             print $fg "load $_\n";
 537         }
 538     }
 539     # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 540     print $fg "exec $kbin $kcmd\n";
 541     close($fg);
 542     print("novaboot: Created $builddir/$filename\n");
 543     return $filename;
 544 }
 545
 546 sub shell_cmd_string(@)
 547 {
 548     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 549 }
 550
 551 sub exec_verbose(@)
 552 {
 553     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 554     exec(@_);
 555     exit(1); # should not be reached
 556 }
 557
 558 sub system_verbose($)
 559 {
 560     my $cmd = shift;
 561     print STDERR "novaboot: Running: $cmd\n";
 562     my $ret = system($cmd);
 563     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 564     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 565     if ($ret) { die("Command failure $ret"); }
 566 }
 567
 568 sub trim($) {
 569     my ($str) = @_;
 570     $str =~ s/^\s+|\s+$//g;
 571     return $str
 572 }
 573
 574 ## WvTest headline
 575
 576 if (exists $variables->{WVDESC}) {
 577     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 578 } elsif ($last_fn =~ /\.wv$/) {
 579     print STDERR "Testing \"all\" in $last_fn:\n";
 580 }
 581
 582 ## Connect to the target and check whether it is not occupied
 583
 584 # We have to do this before file generation phase, because file
 585 # generation is intermixed with file deployment phase and we want to
 586 # check whether the target is not used by somebody else before
 587 # deploying files. Otherwise, we may rewrite other user's files on a
 588 # boot server.
 589
 590 my $exp; # Expect object to communicate with the target over serial line
 591
 592 my ($target_reset, $target_power_on, $target_power_off);
 593 my ($amt_user, $amt_password, $amt_host, $amt_port);
 594
 595 if (defined $iprelay) {
 596     my $IPRELAY;
 597     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 598     my $addr = $1;
 599     my $port = $3 || 23;
 600     my $paddr   = sockaddr_in($port, inet_aton($addr));
 601     my $proto   = getprotobyname('tcp');
 602     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 603     print STDERR "novaboot: Connecting to IP relay... ";
 604     connect($IPRELAY, $paddr)    || die "connect: $!";
 605     print STDERR "done\n";
 606     $exp = Expect->init(\*$IPRELAY);
 607     $exp->log_stdout(1);
 608
 609     while (1) {
 610         print $exp "\xFF\xF6";  # AYT
 611         my $connected = $exp->expect(20, # Timeout in seconds
 612                                      '<iprelayd: connected>',
 613                                      '-re', '<WEB51 HW[^>]*>');
 614         last if $connected;
 615     }
 616
 617     sub relaycmd($$) {
 618         my ($relay, $onoff) = @_;
 619         die unless ($relay == 1 || $relay == 2);
 620
 621         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 622         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 623     }
 624
 625     sub relayconf($$) {
 626         my ($relay, $onoff) = @_;
 627         die unless ($relay == 1 || $relay == 2);
 628         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 629         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 630     }
 631
 632     sub relay($$;$) {
 633         my ($relay, $onoff, $can_giveup) = @_;
 634         my $confirmation = '';
 635         $exp->log_stdout(0);
 636         print $exp relaycmd($relay, $onoff);
 637         my $confirmed = $exp->expect(20, # Timeout in seconds
 638                                      relayconf($relay, $onoff));
 639         if (!$confirmed) {
 640             if ($can_giveup) {
 641                 print("Relay confirmation timeout - ignoring\n");
 642             } else {
 643                 die "Relay confirmation timeout";
 644             }
 645         }
 646         $exp->log_stdout(1);
 647     }
 648
 649     $target_reset = sub {
 650         relay(2, 1, 1); # Reset the machine
 651         usleep(100000);
 652         relay(2, 0);
 653     };
 654
 655     $target_power_off = sub {
 656         relay(1, 1);            # Press power button
 657         usleep(6000000);        # Long press to switch off
 658         relay(1, 0);
 659     };
 660
 661     $target_power_on = sub {
 662         relay(1, 1);            # Press power button
 663         usleep(100000);         # Short press
 664         relay(1, 0);
 665     };
 666 }
 667 elsif ($serial) {
 668     my $CONN;
 669     system_verbose("stty -F $serial $stty");
 670     open($CONN, "+<", $serial) || die "open $serial: $!";
 671     $exp = Expect->init(\*$CONN);
 672 }
 673 elsif ($remote_cmd) {
 674     print STDERR "novaboot: Running: $remote_cmd\n";
 675     $exp = Expect->spawn($remote_cmd);
 676 }
 677 elsif (defined $amt) {
 678     require LWP::UserAgent;
 679     require LWP::Authen::Digest;
 680
 681     sub genXML {
 682         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 683         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 684         my %pstates = ("on"        => 2,
 685                        "standby"   => 4,
 686                        "hibernate" => 7,
 687                        "off"       => 8,
 688                        "reset"     => 10,
 689                        "MNI"       => 11);
 690         return <<END;
 691                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 692                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 693                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 694                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 695                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 696                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 697                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 698                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 699                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 700                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 701                 </s:Header><s:Body>
 702                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 703                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 704                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 705                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 706                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 707                 </a:ReferenceParameters></p:ManagedElement>
 708                 </p:RequestPowerStateChange_INPUT>
 709                 </s:Body></s:Envelope>
 710 END
 711     }
 712
 713     sub sendPOST {
 714         my ($host, $username, $password, $content) = @_;
 715
 716         my $ua = LWP::UserAgent->new();
 717         $ua->agent("novaboot");
 718
 719         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 720         my $res = $ua->request($req);
 721         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 722
 723         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 724         $ua->credentials("$host:16992", $realm, $username => $password);
 725
 726         # Create a request
 727         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 728         $req->content_type('application/x-www-form-urlencoded');
 729         $req->content($content);
 730         $res = $ua->request($req);
 731         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 732         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 733         return $1;
 734     }
 735
 736     sub powerChange  {
 737         my ($host, $username, $password, $pstate)=@_;
 738         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 739         my $className="/RequestPowerStateChange";
 740         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 741         return sendPOST($host, $username, $password, $content);
 742     }
 743
 744     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 745     $amt_user ||= "admin";
 746     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 747     $amt_host || die "AMT host not specified";
 748     $amt_port ||= 16994;
 749
 750
 751     $target_power_off = sub {
 752         $exp->close();
 753         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 754         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 755     };
 756
 757     $target_power_on = sub {
 758         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 759         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 760     };
 761
 762     $target_reset = sub {
 763         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 764         if ($result != 0) {
 765             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 766             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 767         }
 768         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 769     };
 770
 771     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 772     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 773     $exp = Expect->spawn($cmd);
 774     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL' timed out";
 775
 776 }
 777
 778
 779 if ($remote_expect) {
 780     $exp || die("No serial line connection");
 781     my $log = $exp->log_stdout;
 782     if (defined $remote_expect_silent) {
 783         $exp->log_stdout(0);
 784     }
 785     $exp->expect(180, $remote_expect) || die "Expect for '$remote_expect' timed out";
 786     if (defined $remote_expect_silent) {
 787         $exp->log_stdout($log);
 788         print $exp->after() if $log;
 789     }
 790 }
 791
 792 if (defined $reset_cmd) {
 793     $target_reset = sub {
 794         system_verbose($reset_cmd);
 795     };
 796 }
 797
 798 if (defined $on_opt && defined $target_power_on) {
 799     &$target_power_on();
 800     exit;
 801 }
 802 if (defined $off_opt && defined $target_power_off) {
 803     print STDERR "novaboot: Switching the target off...\n";
 804     &$target_power_off();
 805     exit;
 806 }
 807
 808 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 809 if (defined $builddir) {
 810     chdir($builddir) or die "Can't change directory to $builddir: $!";
 811     print STDERR "novaboot: Entering directory `$builddir'\n";
 812 } else {
 813     $builddir = $invocation_dir;
 814 }
 815
 816 ## File generation phase
 817 my (%files_iso, $menu_iso, $filename);
 818 my $config_name = '';
 819 my $prefix = '';
 820
 821 foreach my $script (@scripts) {
 822     $filename = $$script{filename};
 823     $modules = $$script{modules};
 824     $generated = $$script{generated};
 825     $variables = $$script{variables};
 826
 827     ($config_name = $filename) =~ s#.*/##;
 828     $config_name = $config_name_opt if (defined $config_name_opt);
 829
 830     if (exists $variables->{BUILDDIR}) {
 831         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 832         chdir($builddir) or die "Can't change directory to $builddir: $!";
 833         print STDERR "novaboot: Entering directory `$builddir'\n";
 834     }
 835
 836     if ($grub_prefix) {
 837         $prefix = $grub_prefix;
 838         $prefix =~ s/\$NAME/$config_name/;
 839         $prefix =~ s/\$BUILDDIR/$builddir/;
 840     }
 841     # TODO: use $grub_prefix as first parameter if some switch is given
 842     generate_configs('', $generated, $filename);
 843
 844 ### Generate bootloader configuration files
 845     my @bootloader_configs;
 846     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 847     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 848     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules) if (defined $pulsar);
 849
 850 ### Run scons or make
 851     {
 852         my @files = map({ ($file) = m/([^ ]*)/; $file; } @$modules);
 853         # Filter-out generated files
 854         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 855
 856         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 857         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 858     }
 859
 860 ### Copy files (using rsync)
 861     if (defined $server && !defined($gen_only)) {
 862         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 863
 864         my ($hostname, $path) = split(":", $real_server, 2);
 865         if (! defined $path) {
 866             $path = $hostname;
 867             $hostname = "";
 868         }
 869         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs)));
 870         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 871         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 872         my $progress = $istty ? "--progress" : "";
 873         if ($files) {
 874             system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 875             if ($server =~ m|/\$NAME$| && $concat) {
 876                 my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 877                 system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 878             }
 879         }
 880     }
 881
 882 ### Prepare ISO image generation
 883     if (defined $iso_image) {
 884         generate_configs("(cd)", $generated, $filename);
 885         my $menu;
 886         generate_syslinux_config(\$menu, $config_name, "/", $modules);
 887         $menu_iso .= "$menu\n";
 888         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 889     }
 890 }
 891
 892 ## Generate ISO image
 893 if (defined $iso_image) {
 894     system_verbose("mkdir -p isolinux");
 895
 896     my @files;
 897     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
 898         # Newer ISOLINUX version
 899         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
 900     } else {
 901         # Older ISOLINUX version
 902         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
 903     }
 904     system_verbose("cp @files isolinux");
 905     open(my $fh, ">isolinux/isolinux.cfg");
 906     if ($#scripts) {
 907         print $fh "TIMEOUT 50\n";
 908         print $fh "DEFAULT menu\n";
 909     } else {
 910         print $fh "DEFAULT $config_name\n";
 911     }
 912     print $fh "$menu_iso";
 913     close($fh);
 914
 915     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
 916     $iso_image ||= "$config_name.iso";
 917
 918     # Note: We use -U flag below to "Allow 'untranslated' filenames,
 919     # completely violating the ISO9660 standards". Without this
 920     # option, isolinux is not able to read files names for example
 921     # bzImage-3.0.
 922     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
 923     print("ISO image created: $builddir/$iso_image\n");
 924 }
 925
 926 exit(0) if defined $gen_only;
 927
 928 ## Boot the system using various methods and send serial output to stdout
 929
 930 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 931     die "You cannot do this with multiple scripts simultaneously";
 932 }
 933
 934 if ($variables->{WVTEST_TIMEOUT}) {
 935     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 936 }
 937
 938 ### Start in Qemu
 939
 940 if (defined $qemu) {
 941     # Qemu
 942     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 943     my @qemu_flags = split(" ", $qemu);
 944     $qemu = shift(@qemu_flags);
 945
 946     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 947     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 948     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 949
 950     if (defined $iso_image) {
 951         # Boot NOVA with grub (and test the iso image)
 952         push(@qemu_flags, ('-cdrom', $iso_image));
 953     } else {
 954         # Boot NOVA without GRUB
 955
 956         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 957         foreach (@$modules) {s/,/+/g;}
 958         generate_configs("", $generated, $filename);
 959
 960         if (scalar @$modules) {
 961             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 962             $kcmd = '' if !defined $kcmd;
 963             my $dtb;
 964             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 965             my $initrd = join ",", @$modules;
 966
 967             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
 968             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
 969             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
 970         }
 971     }
 972     push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
 973     unshift(@qemu_flags, ('-name', $config_name));
 974     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
 975     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
 976 }
 977
 978 ### Local DHCPD and TFTPD
 979
 980 my ($dhcpd_pid, $tftpd_pid);
 981
 982 $tftp=1 if $tftp_port;
 983
 984 if (defined $dhcp_tftp)
 985 {
 986     generate_configs("(nd)", $generated, $filename);
 987     system_verbose('mkdir -p tftpboot');
 988     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
 989     open(my $fh, '>', 'dhcpd.conf');
 990     my $mac = `cat /sys/class/net/$netif/address`;
 991     chomp $mac;
 992     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
 993                       range 10.23.23.10 10.23.23.100;
 994                       filename \"bin/boot/grub/pxegrub.pxe\";
 995                       next-server 10.23.23.1;
 996 }
 997 host server {
 998         hardware ethernet $mac;
 999         fixed-address 10.23.23.1;
1000 }";
1001     close($fh);
1002     system_verbose("sudo ip a add 10.23.23.1/24 dev $netif;
1003             sudo ip l set dev $netif up;
1004             sudo touch dhcpd.leases");
1005
1006     # We run servers by forking ourselves, because the servers end up
1007     # in our process group and get killed by signals sent to the
1008     # process group (e.g. Ctrl-C on terminal).
1009     $dhcpd_pid = fork();
1010     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1011 }
1012
1013 if (defined $dhcp_tftp || defined $tftp) {
1014     $tftp_port ||= 69;
1015     # Unfortunately, tftpd requires root privileges even with
1016     # non-privileged (>1023) port due to initgroups().
1017     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
1018
1019     # Kill server when we die
1020     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1021                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1022
1023     # We have to kill tftpd explicitely, because it is not in our process group
1024     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1025 }
1026
1027 ### AMT IDE-R
1028 if (defined $ider) {
1029     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1030     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1031     my $ider_pid = fork();
1032     if ($ider_pid == 0) {
1033         exec($ider_cmd);
1034         die "IDE redirection failed";
1035     }
1036     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1037     # to use both simultaneously.
1038     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1039 }
1040
1041 ### Reset target (IP relay, AMT, ...)
1042
1043 if (defined $target_reset && $reset) {
1044     print STDERR "novaboot: Reseting the test box... ";
1045     &$target_reset();
1046     print STDERR "done\n";
1047     if (defined $exp) {
1048         # We don't want to output anything printed by the target
1049         # before reset so we clear the buffers now. This is, however,
1050         # not ideal because we may loose some data that were sent
1051         # after the reset. If this is a problem, one should reset and
1052         # connect to serial line in atomic manner. For example, if
1053         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1054         # do not use separate --reset-cmd.
1055         my $log = $exp->log_stdout;
1056         $exp->log_stdout(0);
1057         $exp->expect(0); # Read data from target
1058         $exp->clear_accum();    # Clear the read data
1059         $exp->log_stdout($log);
1060     }
1061 }
1062
1063 ### U-boot conversation
1064 if (defined $uboot) {
1065     my $uboot_prompt = $uboot || '=> ';
1066     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1067     $exp || die("No serial line connection");
1068     $exp->log_stdout(1);
1069     #$exp->exp_internal(1);
1070     $exp->expect(20,
1071                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
1072                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1073     foreach my $cmdspec (@uboot_init) {
1074         my ($cmd, $timeout);
1075         if (ref($cmdspec) eq "HASH") {
1076             $cmd = $cmdspec->{command};
1077             $timeout = $cmdspec->{timeout};
1078         } else {
1079             $cmd = $cmdspec;
1080             $timeout = 10;
1081         }
1082         if ($cmd =~ /\$NB_MYIP/) {
1083             my $ip = (grep /inet /, `ip addr show $netif`)[0] || die "Problem determining our IP address";
1084             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1085             $cmd =~ s/\$NB_MYIP/$ip/g;
1086         }
1087         if ($cmd =~ /\$NB_PREFIX/) {
1088             my $p = $prefix;
1089             $p =~ s|/*$||;
1090             $cmd =~ s/\$NB_PREFIX/$p/g;
1091         }
1092         chomp($cmd);
1093         $exp->send("$cmd\n");
1094         $exp->expect($timeout, $uboot_prompt) || die "U-Boot prompt timeout";
1095     }
1096
1097     # Load files if there are some load lines in the script
1098     if (scalar(@$modules) > 0  && !$variables->{NO_BOOT}) {
1099         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1100         my $dtb;
1101         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1102         my $initrd = shift @$modules;
1103
1104         if (defined $kbin) {
1105             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1106             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1107             $exp->expect(10,
1108                          [qr/##/, sub { exp_continue; }],
1109                          $uboot_prompt) || die "Kernel load timeout";
1110         }
1111         if (defined $dtb) {
1112             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1113             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1114             $exp->expect(10,
1115                          [qr/##/, sub { exp_continue; }],
1116                          $uboot_prompt) || die "Device tree load timeout";
1117         }
1118         if (defined $initrd) {
1119             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1120             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1121             $exp->expect(10,
1122                          [qr/##/, sub { exp_continue; }],
1123                          $uboot_prompt) || die "Initrd load timeout";
1124         } else {
1125             $uboot_addr{ramdisk} = '-';
1126         }
1127
1128         $kcmd //= '';
1129         $exp->send("setenv bootargs $kcmd\n");
1130         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt timeout";
1131
1132     }
1133     $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1134     if (!$variables->{NO_BOOT} && $uboot_cmd ne '') {
1135         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1136         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1137         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1138
1139         $exp->send($uboot_cmd . "\n");
1140         $exp->expect(5, "\n")  || die "U-Boot command timeout";
1141     }
1142 }
1143
1144 ### Serial line interaction
1145 if ($interaction && defined $exp) {
1146     # Serial line of the target is available
1147     my $interrupt = 'Ctrl-C';
1148     if ($interactive && !@exiton) {
1149         $interrupt = '"~~."';
1150     }
1151     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1152     $exp->log_stdout(1);
1153     if (@exiton) {
1154         $exp->expect($exiton_timeout, @expect_raw, @exiton) || die("exiton timeout");
1155     } else {
1156         my @inputs = ($exp);
1157         my $infile = new IO::File;
1158         $infile->IO::File::fdopen(*STDIN,'r');
1159         my $in_object = Expect->exp_init($infile);
1160         $in_object->set_group($exp);
1161
1162         if ($interactive) {
1163             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1164             $in_object->manual_stty(0);   # Use raw terminal mode
1165         } else {
1166             $in_object->manual_stty(1);   # Do not modify terminal settings
1167         }
1168         push(@inputs, $in_object);
1169         #use Data::Dumper;
1170         #print Dumper(\@expect_raw);
1171         $exp->expect(undef, @expect_raw) if @expect_raw;
1172         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1173     }
1174 }
1175
1176 ## Kill dhcpc or tftpd
1177 if (defined $dhcp_tftp || defined $tftp) {
1178     die("novaboot: This should kill servers on background\n");
1179 }
1180
1181 # Always finish novaboot output with newline
1182 print "\n" if $final_eol;
1183
1184 ## Documentation
1185
1186 =encoding utf8
1187 =head1 NAME
1188
1189 novaboot - Boots a locally compiled operating system on a remote
1190 target or in qemu
1191
1192 =head1 SYNOPSIS
1193
1194 B<novaboot> --help
1195
1196 B<novaboot> [option]... [--] script...
1197
1198 B<./script> [option]...
1199
1200 =head1 DESCRIPTION
1201
1202 Novaboot makes booting of a locally compiled operating system (OS)
1203 (e.g. NOVA or Linux) on remote targets as simple as running a program
1204 locally. It automates things like copying OS images to a TFTP server,
1205 generation of bootloader configuration files, resetting of target
1206 hardware or redirection of target's serial line to stdin/out. Novaboot
1207 is highly configurable and makes it easy to boot a single image on
1208 different targets or different images on a single target.
1209
1210 Novaboot operation is controlled by configuration files, command line
1211 options and by a so called novaboot script, which can be thought as a
1212 generalization of bootloader configuration files (see L</"NOVABOOT
1213 SCRIPT SYNTAX">). Typical way of using novaboot is to make the
1214 novaboot script executable and set its first line to I<#!/usr/bin/env
1215 novaboot>. Then, booting a particular OS configuration becomes the
1216 same as executing a local program – the novaboot script.
1217
1218 Novaboot uses configuration files to, among other things, define
1219 command line options needed for different targets. Users typically use
1220 only the B<-t>/B<--target> command line option to select the target.
1221 Internally, this option expands to the pre-configured options.
1222 Configuration files are searched at multiple places, which allows to
1223 have per-system, per-user or per-project configurations. Configuration
1224 file syntax is described in section L</"CONFIGURATION FILES">.
1225
1226 Simple examples of using C<novaboot>:
1227
1228 =over 3
1229
1230 =item 1.
1231
1232 Run an OS in Qemu. This can be specified with the B<--qemu> option.
1233 Thus running
1234
1235  novaboot --qemu myos
1236
1237 (or C<./myos --qemu> as described above) will run Qemu and make it
1238 boot the configuration specified in the F<myos> script.
1239
1240 =item 2.
1241
1242 Create a bootloader configuration file (currently supported
1243 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar and U-Boot) and copy it
1244 with all other files needed for booting to a remote boot server. Then
1245 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1246 target and receive its serial output.
1247
1248  ./myos --grub2 --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1249
1250 Alternatively, you can put these switches to the configuration file
1251 and run:
1252
1253  ./myos --target mytarget
1254
1255 =item 3.
1256
1257 Run DHCP and TFTP server on developer's machine to boot the target
1258 from it.
1259
1260  ./myos --dhcp-tftp
1261
1262 This is useful when no network infrastructure is in place and
1263 the target is connected directly to developer's box.
1264
1265 =item 4.
1266
1267 Create bootable ISO image.
1268
1269  novaboot --iso -- script1 script2
1270
1271 The created ISO image will have ISOLINUX bootloader installed on it
1272 and the boot menu will allow selecting between I<script1> and
1273 I<script2> configurations.
1274
1275 =back
1276
1277 =head1 PHASES AND OPTIONS
1278
1279 Novaboot performs its work in several phases. Each phase can be
1280 influenced by several command line options, certain phases can be
1281 skipped. The list of phases (in the execution order) is as follows.
1282
1283 =over
1284
1285 =item 1. L<Configuration reading|/Configuration reading phase>
1286
1287 =item 2. L<Command line processing|/Command line processing phase>
1288
1289 =item 3. L<Script preprocessing|/Script preprocessing phase>
1290
1291 =item 4. L<File generation|/File generation phase>
1292
1293 =item 5. L<Target connection|/Target connection check>
1294
1295 =item 6. L<File deployment|/File deployment phase>
1296
1297 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1298
1299 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1300
1301 =item 9. L<Target interaction|/Target interaction phase>
1302
1303 =back
1304
1305 Each phase is described in the following sections together with the
1306 command line options that control it.
1307
1308 =head2 Configuration reading phase
1309
1310 After starting, novaboot reads configuration files. Their content is
1311 described in section L</"CONFIGURATION FILES">. By default,
1312 configuration is read from multiple locations. First from the system
1313 configuration directory (F</etc/novaboot.d/>), second from the user
1314 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1315 files along the path to the current directory. Alternatively, a single
1316 configuration file specified with the B<-c> switch or with the
1317 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1318 override settings from the former ones.
1319
1320 The system configuration directory is determined by the content of
1321 NOVABOOT_CONFIG_DIR environment variable and defaults to
1322 F</etc/novaboot.d>. Files in this directory with names consisting
1323 solely of English letters, numbers, dashes '-' and underscores '_'
1324 (note that dot '.' is not included) are read in alphabetical order.
1325
1326 Then, the user configuration file is read from
1327 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environemnt
1328 variable is not set F<~/.config/novaboot> is read instead.
1329
1330 Finally, novaboot searches for files named F<.novaboot> starting from the
1331 directory of the novaboot script (or working directory, see bellow)
1332 and continuing upwards up to the root directory. The found
1333 configuration files are then read in the opposite order (i.e. from the
1334 root directory downwards). This allows to have, for example, a project
1335 specific configuration in F<~/project/.novaboot>.
1336
1337 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1338 The former one is read always, whereas the latter only when novaboot
1339 script or working directory is under the C<$HOME> directory.
1340
1341 In certain cases, the location of the novaboot script cannot be
1342 determined in this early phase. This happens either when the script is
1343 read from the standard input or when novaboot is invoked explicitly as
1344 in the example L</"4."> above. In this case the current working
1345 directory is used as a starting point for configuration file search
1346 instead of the novaboot script directory.
1347
1348 =over 8
1349
1350 =item -c, --config=I<filename>
1351
1352 Use the specified configuration file instead of the default one(s).
1353
1354 =back
1355
1356 =head2 Command line processing phase
1357
1358 =over 8
1359
1360 =item --dump-config
1361
1362 Dump the current configuration to stdout end exit. Useful as an
1363 initial template for a configuration file.
1364
1365 =item -h, --help
1366
1367 Print short (B<-h>) or long (B<--help>) help.
1368
1369 =item -t, --target=I<target>
1370
1371 This option serves as a user configurable shortcut for other novaboot
1372 options. The effect of this option is the same as specifying the
1373 options stored in the C<%targets> configuration variable under key
1374 I<target>. See also L</"CONFIGURATION FILES">.
1375
1376 When this option is not given, novaboot tries to determine the target
1377 to use from either B<NOVABOOT_TARGET> environment variable or from
1378 B<$default_target> configuration file variable.
1379
1380 =back
1381
1382 =head2 Script preprocessing phase
1383
1384 This phases allows to modify the parsed novaboot script before it is
1385 used in the later phases.
1386
1387 =over 8
1388
1389 =item -a, --append=I<parameters>
1390
1391 Append a string to the first C<load> line in the novaboot script. This
1392 can be used to append parameters to the kernel's or root task's
1393 command line. This option can appear multiple times.
1394
1395 =item -b, --bender
1396
1397 Use F<bender> chainloader. Bender scans the PCI bus for PCI serial
1398 ports and stores the information about them in the BIOS data area for
1399 use by the kernel.
1400
1401 =item --chainloader=I<chainloader>
1402
1403 Specifies a chainloader that is loaded before the kernel and other
1404 files specified in the novaboot script. E.g. 'bin/boot/bender
1405 promisc'.
1406
1407 =item --dump
1408
1409 Print the modules to boot and their parameters after this phase
1410 finishes. Then exit. This is useful for seeing the effect of other
1411 options in this section.
1412
1413 =item -k, --kernel=F<file>
1414
1415 Replace the first word on the first C<load> line in the novaboot
1416 script with F<file>.
1417
1418 =item --scriptmod=I<perl expression>
1419
1420 When novaboot script is read, I<perl expression> is executed for every
1421 line (in $_ variable). For example, C<novaboot
1422 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1423 in the script with I<omega6>.
1424
1425 When this option is present, it overrides I<$script_modifier> variable
1426 from the configuration file, which has the same effect. If this option
1427 is given multiple times all expressions are evaluated in the command
1428 line order.
1429
1430 =back
1431
1432 =head2 File generation phase
1433
1434 In this phase, files needed for booting are generated in a so called
1435 I<build directory> (see L</--build-dir>). In most cases configuration
1436 for a bootloader is generated automatically by novaboot. It is also
1437 possible to generate other files using I<heredoc> or I<"<"> syntax in
1438 novaboot scripts. Finally, binaries can be generated in this phases by
1439 running C<scons> or C<make>.
1440
1441 =over 8
1442
1443 =item --build-dir=I<directory>
1444
1445 Overrides the default build directory location.
1446
1447 The default build directory location is determined as follows: If the
1448 configuration file defines the C<$builddir> variable, its value is
1449 used. Otherwise, it is the directory that contains the first processed
1450 novaboot script.
1451
1452 See also L</BUILDDIR> variable.
1453
1454 =item -g, --grub[=I<filename>]
1455
1456 Generates grub bootloader menu file. If the I<filename> is not
1457 specified, F<menu.lst> is used. The I<filename> is relative to the
1458 build directory (see B<--build-dir>).
1459
1460 =item --grub-preamble=I<prefix>
1461
1462 Specifies the I<preable> that is at the beginning of the generated
1463 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1464 timeout.
1465
1466 =item --prefix=I<prefix>
1467
1468 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1469 file name in generated bootloader configuration files (or in U-Boot
1470 commands).
1471
1472 If the I<prefix> contains string $NAME, it will be replaced with the
1473 name of the novaboot script (see also B<--name>).
1474
1475 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1476 the build directory (see also B<--build-dir>).
1477
1478 =item --grub-prefix
1479
1480 Alias for B<--prefix>.
1481
1482 =item --grub2[=I<filename>]
1483
1484 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1485 specified F<grub.cfg> is used. The content of the menu entry can be
1486 customized with B<--grub-preamble>, B<--grub2-prolog> or
1487 B<--grub_prefix> options.
1488
1489 In order to use the the generated menu entry on your development
1490 machine that uses GRUB2, append the following snippet to
1491 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1492 i.e. run update-grub on Debian/Ubuntu.
1493
1494   if [ -f /path/to/nul/build/grub.cfg ]; then
1495     source /path/to/nul/build/grub.cfg
1496   fi
1497
1498 =item --grub2-prolog=I<prolog>
1499
1500 Specifies text that is put at the beginning of the GRUB2 menu entry.
1501
1502 =item -m, --make[=make command]
1503
1504 Runs C<make> to build files that are not generated by novaboot itself.
1505
1506 =item --name=I<string>
1507
1508 Use the name I<string> instead of the name of the novaboot script.
1509 This name is used for things like a title of grub menu or for the
1510 server directory where the boot files are copied to.
1511
1512 =item --no-file-gen
1513
1514 Do not run external commands to generate files (i.e. "<" syntax and
1515 C<run> keyword). This switch does not influence generation of files
1516 specified with "<<WORD" syntax.
1517
1518 =item -p, --pulsar[=mac]
1519
1520 Generates pulsar bootloader configuration file named F<config-I<mac>>
1521 The I<mac> string is typically a MAC address and defaults to
1522 I<novaboot>.
1523
1524 =item --scons[=scons command]
1525
1526 Runs C<scons> to build files that are not generated by novaboot
1527 itself.
1528
1529 =item --strip-rom
1530
1531 Strip I<rom://> prefix from command lines and generated config files.
1532 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1533
1534 =item --gen-only
1535
1536 Exit novaboot after file generation phase.
1537
1538 =back
1539
1540 =head2 Target connection check
1541
1542 If supported by the target, the connection to it is made and it is
1543 checked whether the target is not occupied by another novaboot
1544 user/instance.
1545
1546 =over 8
1547
1548 =item --amt=I<"[user[:password]@]host[:port]>
1549
1550 Use Intel AMT technology to control the target machine. WS management
1551 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1552 The hostname or (IP address) is given by the I<host> parameter. If
1553 I<password> is not specified, environment variable AMT_PASSWORD is
1554 used. The I<port> specifies a TCP port for SOL. If not specified, the
1555 default is 16992. Default I<user> is admin.
1556
1557 =item --iprelay=I<addr[:port]>
1558
1559 Use TCP/IP relay and serial port to access the target's serial port
1560 and powercycle it. The IP address of the relay is given by I<addr>
1561 parameter. If I<port> is not specified, it default to 23.
1562
1563 Note: This option is supposed to work with HWG-ER02a IP relays.
1564
1565 =item -s, --serial[=device]
1566
1567 Target's serial line is connected to host's serial line (device). The
1568 default value for device is F</dev/ttyUSB0>.
1569
1570 The value of this option is exported in NB_NOVABOOT environment
1571 variable to all subprocesses run by C<novaboot>.
1572
1573 =item --stty=I<settings>
1574
1575 Specifies settings passed to C<stty> invoked on the serial line
1576 specified with B<--serial> option. If this option is not given,
1577 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1578
1579 =item --remote-cmd=I<cmd>
1580
1581 Command that mediates connection to the target's serial line. For
1582 example C<ssh server 'cu -l /dev/ttyS0'>.
1583
1584 =item --remote-expect=I<string>
1585
1586 Wait for reception of I<string> after establishing the remote
1587 connection.
1588
1589 =item --remote-expect-silent=I<string>
1590
1591 The same as B<--remote-expect> except that the remote output is not
1592 echoed to stdout while waiting for the I<string>. Everything after the
1593 matched string is printed to stdout, so you may want to include line
1594 end characters in the I<string> as well.
1595
1596 =back
1597
1598 =head2 File deployment phase
1599
1600 In some setups, it is necessary to copy the files needed for booting
1601 to a particular location, e.g. to a TFTP boot server or to the
1602 F</boot> partition.
1603
1604 =over 8
1605
1606 =item -d, --dhcp-tftp
1607
1608 Turns your workstation into a DHCP and TFTP server so that the OS can
1609 be booted via PXE BIOS (or similar mechanism) on the test machine
1610 directly connected by a plain Ethernet cable to your workstation.
1611
1612 The DHCP and TFTP servers requires root privileges and C<novaboot>
1613 uses C<sudo> command to obtain those. You can put the following to
1614 I</etc/sudoers> to allow running the necessary commands without asking
1615 for password.
1616
1617  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1618  your_login ALL=NOPASSWD: NOVABOOT
1619
1620 =item --tftp
1621
1622 Starts a TFTP server on your workstation. This is similar to
1623 B<--dhcp-tftp> except that DHCP server is not started.
1624
1625 The TFTP server require root privileges and C<novaboot> uses C<sudo>
1626 command to obtain those. You can put the following to I</etc/sudoers>
1627 to allow running the necessary commands without asking for password.
1628
1629  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1630  your_login ALL=NOPASSWD: NOVABOOT
1631
1632 =item --tftp-port=I<port>
1633
1634 Port to run the TFTP server on. Implies B<--tftp>.
1635
1636 =item --netif=I<network interface>
1637
1638 Network interface used to deploy files to the target. Default value is
1639 I<eth0>. This influences the configuration of the DHCP server started
1640 by B<--dhcp-tftp> and the value that B<$NB_MYIP> get replaced with in
1641 U-Boot conversation.
1642
1643 =item --iso[=filename]
1644
1645 Generates the ISO image that boots NOVA system via GRUB. If no filename
1646 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1647 of the novaboot script (see also B<--name>).
1648
1649 =item --server[=[[user@]server:]path]
1650
1651 Copy all files needed for booting to another location. The files will
1652 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1653 contains string $NAME, it will be replaced with the name of the
1654 novaboot script (see also B<--name>).
1655
1656 =item --rsync-flags=I<flags>
1657
1658 Specifies which I<flags> are appended to F<rsync> command line when
1659 copying files as a result of I<--server> option.
1660
1661 =item --concat
1662
1663 If B<--server> is used and its value ends with $NAME, then after
1664 copying the files, a new bootloader configuration file (e.g. menu.lst)
1665 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1666 with $NAME part removed. The content of the file is created by
1667 concatenating all files of the same name from all subdirectories of
1668 I<path-wo-name> found on the "server".
1669
1670 =item --ider
1671
1672 Use Intel AMT technology for IDE redirection. This allows the target
1673 machine to boot from novaboot created ISO image. Implies B<--iso>.
1674
1675 The experimental C<amtider> utility needed by this option can be
1676 obtained from https://github.com/wentasah/amtterm.
1677
1678 =back
1679
1680 =head2 Target power-on and reset phase
1681
1682 At this point, the target is reset (or switched on/off). There is
1683 several ways how this can be accomplished. Resetting a physical target
1684 can currently be accomplished by the following options: B<--amt>,
1685 B<--iprelay>, B<--reset-cmd>.
1686
1687 =over 8
1688
1689 =item --on, --off
1690
1691 Switch on/off the target machine and exit. The script (if any) is
1692 completely ignored. Currently it works only with B<--iprelay> or
1693 B<--amt>.
1694
1695 =item -Q, --qemu[=I<qemu-binary>]
1696
1697 Boot the configuration in qemu. Optionally, the name of qemu binary
1698 can be specified as a parameter.
1699
1700 =item --qemu-append=I<flags>
1701
1702 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1703 C<-cpu coreduo -smp 2>).
1704
1705 =item -q, --qemu-flags=I<flags>
1706
1707 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1708 -smp 2>) with I<flags> specified here.
1709
1710 =item --reset-cmd=I<cmd>
1711
1712 Command that resets the target.
1713
1714 =item --no-reset, --reset
1715
1716 Disable/enable resetting of the target.
1717
1718 =back
1719
1720 =head2 Interaction with the bootloader on the target
1721
1722 =over 8
1723
1724 =item --uboot[=I<prompt>]
1725
1726 Interact with U-Boot bootloader to boot the thing described in the
1727 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1728 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1729 Implementation of this option is currently tied to a particular board
1730 that we use. It may be subject to changes in the future!
1731
1732 =item --no-uboot
1733
1734 Disable U-Boot interaction previously enabled with B<--uboot>.
1735
1736 =item --uboot-init
1737
1738 Command(s) to send the U-Boot bootloader before loading the images and
1739 booting them. This option can be given multiple times. After sending
1740 commands from each option novaboot waits for U-Boot I<prompt>.
1741
1742 If the command contains string I<$NB_MYIP> then this string is
1743 replaced by IPv4 address of eth0 interface (see also B<--netif>).
1744 Similarly I<$NB_PREFIX> is replaced with prefix given by B<--prefix>.
1745
1746 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
1747
1748 =item --uboot-addr I<name>=I<address>
1749
1750 Load address of U-Boot's C<tftpboot> command for loading I<name>,
1751 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
1752 tree).
1753
1754 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
1755 variables used by convention for this purpose.
1756
1757 =item --uboot-cmd=I<command>
1758
1759 Specifies U-Boot command used to execute the OS. If the command
1760 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
1761 these are replaced with the addresses configured with B<--uboot-addr>.
1762
1763 The default value is
1764
1765     bootm $kernel_addr $ramdisk_addr $fdt_addr
1766
1767 or the C<UBOOT_CMD> variable if defined in the novaboot script.
1768
1769 =back
1770
1771 =head2 Target interaction phase
1772
1773 In this phase, target's serial output is redirected to stdout and if
1774 stdin is a TTY, it is redirected to the target's serial input allowing
1775 interactive work with the target.
1776
1777 =over 8
1778
1779 =item --exiton=I<string>
1780
1781 When I<string> is sent by the target, novaboot exits. This option can
1782 be specified multiple times, in which case novaboot exits whenever
1783 either of the specified strings is sent.
1784
1785 If I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1786 treated as regular expression. For example:
1787
1788     --exiton -re --exiton 'error:.*failed'
1789
1790 =item --exiton-re=I<regex>
1791
1792 The same as --exiton -re --exiton I<regex>.
1793
1794 =item --exiton-timeout=I<seconds>
1795
1796 By default B<--exiton> waits for the string match forever. When this
1797 option is specified, "exiton" timeouts after the specifies number of
1798 seconds and novaboot returns non-zero exit code.
1799
1800 =item -i, --interactive
1801
1802 Setup things for interactive use of target. Your terminal will be
1803 switched to raw mode. In raw mode, your system does not process input
1804 in any way (no echoing of entered characters, no interpretation
1805 special characters). This, among others, means that Ctrl-C is passed
1806 to the target and does no longer interrupt novaboot. Use "~~."
1807 sequence to exit novaboot.
1808
1809 =item --no-interaction, --interaction
1810
1811 Skip resp. force target interaction phase. When skipped, novaboot exits
1812 immediately when boot is initiated.
1813
1814 =item --expect=I<string>
1815
1816 When I<string> is received from the target, send the string specified
1817 with the subsequent B<--send*> option to the target.
1818
1819 =item --expect-re=I<regex>
1820
1821 When target's output matches regular expression I<regex>, send the
1822 string specified with the subsequent B<--send*> option to the target.
1823
1824 =item --expect-raw=I<perl-code>
1825
1826 Provides direct control over Perl's Expect module.
1827
1828 =item --send=I<string>
1829
1830 Send I<string> to the target after the previously specified
1831 B<--expect*> was matched in the target's output. The I<string> may
1832 contain escape sequences such as "\n".
1833
1834 Note that I<string> is actually interpreted by Perl, so it can contain
1835 much more that escape sequences. This behavior may change in the
1836 future.
1837
1838 Example: C<--expect='login: ' --send='root\n'>
1839
1840 =item --sendcont=I<string>
1841
1842 Similar to B<--send> but continue expecting more input.
1843
1844 Example: C<--expect='Continue?' --sendcont='yes\n'>
1845
1846 =item --final-eol, --no-final-eol
1847
1848 By default, B<novaboot> always prints an end-of-line character at the
1849 end of its execution in order to ensure that the output of programs
1850 started after novaboot appears at the beginning of the line. When this
1851 is not desired B<--no-final-eol> option can be used to override this
1852 behavior.
1853
1854 =back
1855
1856 =head1 NOVABOOT SCRIPT SYNTAX
1857
1858 The syntax tries to mimic POSIX shell syntax. The syntax is defined
1859 with the following rules.
1860
1861 Lines starting with "#" and empty lines are ignored.
1862
1863 Lines that end with "\" are concatenated with the following line after
1864 removal of the final "\" and leading whitespace of the following line.
1865
1866 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1867 expression) assign values to internal variables. See L</VARIABLES>
1868 section.
1869
1870 Lines starting with C<load> keyword represent modules to boot. The
1871 word after C<load> is a file name (relative to the build directory
1872 (see B<--build-dir>) of the module to load and the remaining words are
1873 passed to it as the command line parameters.
1874
1875 When the C<load> line ends with "<<WORD" then the subsequent lines
1876 until the line containing solely WORD are copied literally to the file
1877 named on that line. This is similar to shell's heredoc feature.
1878
1879 When the C<load> line ends with "< CMD" then command CMD is executed
1880 with F</bin/sh> and its standard output is stored in the file named on
1881 that line. The SRCDIR variable in CMD's environment is set to the
1882 absolute path of the directory containing the interpreted novaboot
1883 script.
1884
1885 Lines starting with C<run> keyword contain shell commands that are run
1886 during file generation phase. This is the same as the "< CMD" syntax
1887 for C<load> keyboard except that the command's output is not
1888 redirected to a file. The ordering of commands is the same as they
1889 appear in the novaboot script.
1890
1891 Lines starting with C<uboot> represent U-Boot commands that are sent
1892 to the target if B<--uboot> option is given. Having a U-Boot line in
1893 the novaboot script is the same as passing an equivalent
1894 B<--uboot-init> option to novaboot. The C<uboot> keyword can be
1895 suffixed with timeout specification. The syntax is C<uboot:Ns>, where
1896 C<N> is the whole number of seconds. If the U-Boot command prompt does
1897 not appear before the timeout, novaboot fails. The default timeout is
1898 10 seconds.
1899
1900 Example (Linux):
1901
1902   #!/usr/bin/env novaboot
1903   load bzImage console=ttyS0,115200
1904   run  make -C buildroot
1905   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
1906
1907 Example (NOVA User Land - NUL):
1908
1909   #!/usr/bin/env novaboot
1910   WVDESC=Example program
1911   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
1912                            verbose hostkeyb:0,0x60,1,12,2
1913   load bin/apps/hello.nul
1914   load hello.nulconfig <<EOF
1915   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
1916   rom://bin/apps/hello.nul
1917   EOF
1918
1919 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
1920 F<hello.nulconfig>. sigma0 receives some command line parameters and
1921 F<hello.nulconfig> file is generated on the fly from the lines between
1922 C<<<EOF> and C<EOF>.
1923
1924 =head2 VARIABLES
1925
1926 The following variables are interpreted in the novaboot script:
1927
1928 =over 8
1929
1930 =item BUILDDIR
1931
1932 Novaboot chdir()s to this directory before file generation phase. The
1933 directory name specified here is relative to the build directory
1934 specified by other means (see L</--build-dir>).
1935
1936 =item EXITON
1937
1938 Assigning this variable has the same effect as specifying L</--exiton>
1939 option.
1940
1941 =item HYPERVISOR_PARAMS
1942
1943 Parameters passed to hypervisor. The default value is "serial", unless
1944 overridden in configuration file.
1945
1946 =item KERNEL
1947
1948 The kernel to use instead of the hypervisor specified in the
1949 configuration file with the C<$hypervisor> variable. The value should
1950 contain the name of the kernel image as well as its command line
1951 parameters. If this variable is defined and non-empty, the variable
1952 HYPERVISOR_PARAMS is not used.
1953
1954 =item NO_BOOT
1955
1956 If this variable is 1, the system is not booted. This is currently
1957 only implemented for U-Boot bootloader where it is useful for
1958 interacting with the bootloader without booting the system - e.g. for
1959 flashing.
1960
1961 =item QEMU
1962
1963 Use a specific qemu binary (can be overridden with B<-Q>) and flags
1964 when booting this script under qemu. If QEMU_FLAGS variable is also
1965 specified flags specified in QEMU variable are replaced by those in
1966 QEMU_FLAGS.
1967
1968 =item QEMU_FLAGS
1969
1970 Use specific qemu flags (can be overridden with B<-q>).
1971
1972 =item UBOOT_CMD
1973
1974 See L</--uboot-cmd>.
1975
1976 =item WVDESC
1977
1978 Description of the WvTest-compliant program.
1979
1980 =item WVTEST_TIMEOUT
1981
1982 The timeout in seconds for WvTest harness. If no complete line appears
1983 in the test output within the time specified here, the test fails. It
1984 is necessary to specify this for long running tests that produce no
1985 intermediate output.
1986
1987 =back
1988
1989 =head1 CONFIGURATION FILES
1990
1991 Novaboot can read its configuration from one or more files. By
1992 default, novaboot looks for files in F</etc/novaboot.d>, file
1993 F<~/.config/novaboot> and files named F<.novaboot> as described in
1994 L</Configuration reading phase>. Alternatively, configuration file
1995 location can be specified with the B<-c> switch or with the
1996 NOVABOOT_CONFIG environment variable. The configuration file has Perl
1997 syntax (i.e. it is better to put C<1;> as the last line) and should set
1998 values of certain Perl variables. The current configuration can be
1999 dumped with the B<--dump-config> switch. Some configuration variables
2000 can be overridden by environment variables (see below) or by command
2001 line switches.
2002
2003 Supported configuration variables include:
2004
2005 =over 8
2006
2007 =item $builddir
2008
2009 Build directory location relative to the location of the configuration
2010 file.
2011
2012 =item $default_target
2013
2014 Default target (see below) to use when no target is explicitly
2015 specified with the B<--target> command line option or
2016 B<NOVABOOT_TARGET> environment variable.
2017
2018 =item %targets
2019
2020 Hash of target definitions to be used with the B<--target> option. The
2021 key is the identifier of the target, the value is the string with
2022 command line options. For instance, if the configuration file contains:
2023
2024  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
2025
2026 then the following two commands are equivalent:
2027
2028  ./myos --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
2029  ./myos -t mybox
2030
2031 =back
2032
2033 =head1 ENVIRONMENT VARIABLES
2034
2035 Some options can be specified not only via config file or command line
2036 but also through environment variables. Environment variables override
2037 the values from configuration file and command line parameters
2038 override the environment variables.
2039
2040 =over 8
2041
2042 =item NOVABOOT_CONFIG
2043
2044 Name of the novaboot configuration file to use instead of the default
2045 one(s).
2046
2047 =item NOVABOOT_CONFIG_DIR
2048
2049 Name of the novaboot configuration directory. When not specified
2050 F</etc/novaboot.d> is used.
2051
2052 =item NOVABOOT_TARGET
2053
2054 Name of the novaboot target to use. This overrides the value of
2055 B<$default_target> from the configuration file and can be overriden
2056 with the B<--target> command line option.
2057
2058 =item NOVABOOT_BENDER
2059
2060 Defining this variable has the same meaning as B<--bender> option.
2061
2062 =back
2063
2064 =head1 AUTHORS
2065
2066 Michal Sojka <sojka@os.inf.tu-dresden.de>
2067
2068 Latest novaboot version can be found at
2069 L<https://github.com/wentasah/novaboot>.
2070
2071 =cut
2072
2073 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2074 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2075 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2076 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest