novaboot

   1 #!/usr/bin/env perl
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use IO::Handle;
  26 use Time::HiRes("usleep");
  27 use Socket;
  28 use FileHandle;
  29 use IPC::Open2;
  30 use POSIX qw(:errno_h sysconf);
  31 use Cwd qw(getcwd abs_path);
  32 use Expect;
  33
  34 # always flush
  35 $| = 1;
  36
  37 my $invocation_dir = $ENV{PWD} || getcwd();
  38
  39 # We prefer using PWD, to use nicer paths names with symbolic links.
  40 # However, when executed from 'make -C dir', PWD may contain the make
  41 # invocation path, not the real invocation path with dir at the end.
  42 # We fix that here.
  43 if (abs_path($ENV{PWD}) ne abs_path(getcwd())) {
  44     $invocation_dir = getcwd();
  45 }
  46
  47 ## Configuration file handling
  48
  49 # Default configuration
  50 $CFG::hypervisor = "";
  51 $CFG::hypervisor_params = "serial";
  52 $CFG::genisoimage = "genisoimage";
  53 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  54 $CFG::default_target = '';
  55 $CFG::netif = 'eth0';
  56 %CFG::targets = (
  57     'qemu' => '--qemu',
  58     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  59     "novabox" => '--ssh=novabox@rtime.felk.cvut.cz',
  60     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  61     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  62     "ryuglab" => '--target ryu --ssh=ryu@pc-sojkam.felk.cvut.cz',
  63     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  64     );
  65
  66 {
  67     my %const;
  68     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  69     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  70
  71     $CFG::scons = "scons -j$nproc";
  72     $CFG::make = "make -j$nproc";
  73 }
  74
  75 my $builddir;
  76
  77 sub read_config($) {
  78     my ($cfg) = @_;
  79     {
  80         package CFG; # Put config data into a separate namespace
  81
  82         my $rc = do($cfg);
  83
  84         # Check for errors
  85         if ($@) {
  86             die("ERROR: Failure compiling '$cfg' - $@");
  87         } elsif (! defined($rc)) {
  88             die("ERROR: Failure reading '$cfg' - $!");
  89         } elsif (! $rc) {
  90             die("ERROR: Failure processing '$cfg'");
  91         }
  92     }
  93     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  94     print STDERR "novaboot: Read $cfg\n";
  95 }
  96
  97 my @cfgs;
  98 {
  99     # We don't use $0 here, because it points to the novaboot itself and
 100     # not to the novaboot script. The problem with this approach is that
 101     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
 102     # contains the first option. Hence the -f check.
 103     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
 104     while ((-d $dir || -l $dir ) && $dir ne "/") {
 105         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
 106         my @dirs = File::Spec->splitdir($dir);
 107         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
 108     }
 109     @cfgs = reverse @cfgs;
 110
 111     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 112     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 113
 114     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 115     if (opendir(my $dh, $dir)) {
 116         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 117         closedir $dh;
 118         @etccfg = sort(@etccfg);
 119         @cfgs = ( @etccfg, @cfgs );
 120     }
 121 }
 122 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 123 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 124 GetOptions ("config|c=s" => \$cfg);
 125 read_config($_) foreach $cfg or @cfgs;
 126
 127 ## Command line handling
 128
 129 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 130 GetOptions ("target|t=s" => \$explicit_target);
 131
 132 # Variables for command line options
 133 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $final_eol, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iprelay_cmd, $iso_image, $interactive, $kernel_opt, $make, $man, $netif, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, @remote_cmd, $remote_expect, $remote_expect_silent, $remote_expect_timeout, $reset, @reset_cmd, $reset_send, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init, $uboot_stop_key);
 134
 135 my ($target_reset, $target_power_on, $target_power_off);
 136
 137 # Default values of certain command line options
 138 %uboot_addr = (
 139     'kernel'  => '${kernel_addr_r}',
 140     'ramdisk' => '${ramdisk_addr_r}',
 141     'fdt'     => '${fdt_addr_r}',
 142     );
 143 $rsync_flags = '';
 144 $rom_prefix = 'rom://';
 145 $stty = 'raw -crtscts -onlcr -echo 115200';
 146 $reset = 1;                     # Reset target by default
 147 $interaction = 1;               # Perform target interaction by default
 148 $final_eol = 1;
 149 $netif = $CFG::netif;
 150 $remote_expect_timeout = -1;
 151
 152 my @expect_seen = ();
 153 sub handle_expect
 154 {
 155     my ($n, $v) = @_;
 156     push(@expect_seen, '-re') if $n eq "expect-re";
 157     push(@expect_seen, $v);
 158 }
 159
 160 sub handle_send
 161 {
 162     my ($n, $v) = @_;
 163     unless (@expect_seen) { die("No --expect before --send"); }
 164     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 165     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 166     unshift(@expect_raw, @expect_seen);
 167     @expect_seen = ();
 168 }
 169
 170 # Options which can be safely specified on the server (via --ssh),
 171 # i.e. which cannot cause unwanted local code execution etc.
 172 my %opt_spec_safe = (
 173     "grub|g:s"       => \$grub_config,
 174     "grub-preamble=s"=> \$grub_preamble,
 175     "grub2-prolog=s" => \$grub2_prolog,
 176     "grub2:s"        => \$grub2_config,
 177     "prefix|grub-prefix=s" => \$grub_prefix,
 178     "pulsar-root=s"  => \$pulsar_root,
 179     "pulsar|p:s"     => \$pulsar,
 180     "remote-expect=s"=> \$remote_expect,
 181     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 182     "remote-expect-timeout=i"=> \$remote_expect_timeout,
 183     "uboot-addr=s"   => \%uboot_addr,
 184     "uboot-cmd=s"    => \$uboot_cmd,
 185     "uboot-stop-key=s" => \$uboot_stop_key,
 186     "uboot-init=s"   => sub { push @uboot_init, { command => $_[1] }; },
 187     "uboot:s"        => \$uboot,
 188     );
 189
 190 my %opt_spec = (
 191     %opt_spec_safe,
 192     "amt=s"          => \$amt,
 193     "append|a=s"     => \@append,
 194     "bender|b"       => \$bender,
 195     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 196     "concat"         => \$concat,
 197     "chainloader=s"  => \@chainloaders,
 198     "dhcp-tftp|d"    => \$dhcp_tftp,
 199     "dump"           => \$dump_opt,
 200     "dump-config"    => \$dump_config,
 201     "exiton=s"       => \@exiton,
 202     "exiton-timeout=i"=> \$exiton_timeout,
 203     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 204     "expect=s"       => \&handle_expect,
 205     "expect-re=s"    => \&handle_expect,
 206     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 207     "final-eol!"     => \$final_eol,
 208     "gen-only"       => \$gen_only,
 209     "ider"           => \$ider,
 210     "interaction!"   => \$interaction,
 211     "iprelay=s"      => \$iprelay,
 212     "iprelay-cmd=s"  => \$iprelay_cmd,
 213     "iso:s"          => \$iso_image,
 214     "kernel|k=s"     => \$kernel_opt,
 215     "interactive|i"  => \$interactive,
 216     "name=s"         => \$config_name_opt,
 217     "make|m:s"       => \$make,
 218     "netif=s"        => \$netif,
 219     "no-file-gen"    => \$no_file_gen,
 220     "off"            => \$off_opt,
 221     "on"             => \$on_opt,
 222     "qemu|Q:s"       => \$qemu,
 223     "qemu-append=s"  => \$qemu_append,
 224     "qemu-flags|q=s" => \$qemu_flags_cmd,
 225     "remote-cmd=s"   => sub { @remote_cmd = ($_[1]); },
 226     "reset!"         => \$reset,
 227     "reset-cmd=s"    => sub { @reset_cmd = ($_[1]); },
 228     "reset-send=s"   => \$reset_send,
 229     "rsync-flags=s"  => \$rsync_flags,
 230     "scons:s"        => \$scons,
 231     "scriptmod=s"    => \@scriptmod,
 232     "send=s"         => \&handle_send,
 233     "sendcont=s"     => \&handle_send,
 234     "serial|s:s"     => \$serial,
 235     "server:s"       => \$server,
 236     "ssh:s"          => \&handle_novaboot_server,
 237     "strip-rom"      => sub { $rom_prefix = ''; },
 238     "stty=s"         => \$stty,
 239     "tftp"           => \$tftp,
 240     "tftp-port=i"    => \$tftp_port,
 241     "no-uboot"       => sub { undef $uboot; },
 242     "h"              => \$help,
 243     "help"           => \$man,
 244     );
 245
 246 sub handle_novaboot_server
 247 {
 248     my ($n, $val) = @_;
 249     my $xdg_runtime_dir = $ENV{XDG_RUNTIME_DIR} || '/var/run';
 250     my $ssh_ctl_path = "${xdg_runtime_dir}/novaboot$$";
 251
 252     @remote_cmd = ('ssh', '-tt', '-M', '-S', $ssh_ctl_path, $val, 'console');
 253     $remote_expect = "novaboot-shell: Connected";
 254     $server = "$val:";
 255     $rsync_flags = "--rsh='ssh -S \'${ssh_ctl_path}\''";
 256     ($grub_prefix = $val) =~ s|(.*)@.*|\/$1\/| if index($val, '@') != -1;
 257     @reset_cmd = ('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'reset');
 258
 259     $target_power_off = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'off'); };
 260     $target_power_on  = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'on'); };
 261
 262     my $cmd = "ssh '${val}' get-config";
 263     print STDERR "novaboot: Running: $cmd\n";
 264     my @target_config = qx($cmd  < /dev/null);
 265     if ($?) { die("Cannot get target configuration from the server"); }
 266     printf "novaboot: Received configuration from the server:%s\n", (!@target_config) ? " empty" : "";
 267     foreach (@target_config) { chomp; print "  $_\n"; }
 268
 269     my $p = Getopt::Long::Parser->new;
 270     $p->configure(qw/no_ignore_case no_pass_through/);
 271     $p->getoptionsfromarray(\@target_config, %opt_spec_safe) or die("Error processing configuration from the server");
 272
 273     if (scalar @target_config) { die "Unsuported configuration received from the server: ".join(", ", @target_config); }
 274 }
 275
 276 # First process target options
 277 {
 278     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 279     my @target_expanded;
 280     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 281     while ($t) {
 282         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 283
 284         undef $explicit_target;
 285         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 286         if (!$ret) { die "Error parsing target $t option"; }
 287         push(@target_expanded, @$remaining_args);
 288         $t = $explicit_target;
 289     }
 290
 291     my @args = (@target_expanded, @ARGV);
 292     print STDERR "novaboot: Effective options: @args\n";
 293
 294     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 295     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 296 }
 297
 298 # Then process other command line options - some of them may override
 299 # what was specified by the target
 300 GetOptions %opt_spec or die("Error in command line arguments");
 301 pod2usage(1) if $help;
 302 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 303
 304 ### Dump sanitized configuration (if requested)
 305
 306 if ($dump_config) {
 307     use Data::Dumper;
 308     $Data::Dumper::Indent=1;
 309     print "# This file is in perl syntax.\n";
 310     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 311         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 312         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 313         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 314     }
 315     print "1;\n";
 316     exit;
 317 }
 318
 319 ### Sanitize configuration
 320
 321 if ($interactive && !-t STDIN) {
 322     die("novaboot: Interactive mode not supported when not on terminal");
 323 }
 324
 325 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 326
 327 if ($ider) {
 328     $iso_image //= ''; # IDE-R needs an ISO image
 329     if (!defined $amt) { die "Error: --ider requires --amt"; }
 330 }
 331
 332 {
 333     my %input_opts = ('--iprelay'    => \$iprelay,
 334                       '--iprelay-cmd'=> \$iprelay_cmd,
 335                       '--serial'     => \$serial,
 336                       '--remote-cmd' => (@remote_cmd ? \$remote_cmd[0] : undef),
 337                       '--amt'        => \$amt);
 338     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 339
 340     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 341 }
 342
 343 # Default options
 344 if (defined $serial) {
 345     $serial ||= "/dev/ttyUSB0";
 346     $ENV{NB_SERIAL} = $serial;
 347 }
 348 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 349 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 350
 351 ## Parse the novaboot script(s)
 352 my @scripts;
 353 my $file;
 354 my $EOF;
 355 my $last_fn = '';
 356 my ($modules, $variables, $generated, $copy, $chainload, $continuation) = ([], {}, [], []);
 357 my $skip_reading = defined($on_opt) || defined($off_opt);
 358 while (!$skip_reading && ($_ = <>)) {
 359     if ($ARGV ne $last_fn) { # New script
 360         die "Missing EOF in $last_fn" if $file;
 361         die "Unfinished line in $last_fn" if $continuation;
 362         $last_fn = $ARGV;
 363         push @scripts, { 'filename' => $ARGV,
 364                          'modules' => $modules = [],
 365                          'variables' => $variables = {},
 366                          'generated' => $generated = [],
 367                          'copy' => $copy = [],
 368                          'chainload' => $chainload = [],
 369         };
 370
 371     }
 372     chomp();
 373     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 374
 375     $_ =~ s/^[[:space:]]*// if ($continuation);
 376
 377     if (/\\$/) {                # Line continuation
 378         $continuation .= substr($_, 0, length($_)-1);
 379         next;
 380     }
 381
 382     if ($continuation) {        # Last continuation line
 383         $_ = $continuation . $_;
 384         $continuation = '';
 385     }
 386
 387     foreach my $mod(@scriptmod) { eval $mod; }
 388
 389     if ($file && $_ eq $EOF) {  # Heredoc end
 390         undef $file;
 391         next;
 392     }
 393     if ($file) {                # Heredoc content
 394         push @{$file}, "$_\n";
 395         next;
 396     }
 397     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 398         $$variables{$1} = $2;
 399         push(@exiton, $2) if ($1 eq "EXITON");
 400         $interaction = $2 if ($1 eq "INTERACTION");
 401         next;
 402     }
 403     sub process_load_copy($) {
 404         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 405         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 406             $file = [];
 407             push @$generated, {filename => $1, content => $file};
 408             $EOF = $3;
 409             return "$1$2";
 410         }
 411         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 412             push @$generated, {filename => $1, command => $3};
 413             return "$1$2";
 414         }
 415         s/\s*$//;               # Strip trailing whitespace
 416         return $_;
 417     }
 418     if (s/^load *//) {          # Load line
 419         push @$modules, process_load_copy($_);
 420         next;
 421     }
 422     if (s/^copy *//) {          # Copy line
 423         push @$copy, process_load_copy($_);
 424         next;
 425     }
 426     if (s/^chld *//) {          # Chainload line
 427         push @$chainload, process_load_copy($_);
 428         next;
 429     }
 430     if (/^run (.*)/) {          # run line
 431         push @$generated, {command => $1};
 432         next;
 433     }
 434     if (/^uboot(?::([0-9]+)s)? +(< *)?(.*)/) {  # uboot line
 435         # TODO: If U-Boot supports some interactive menu, it might
 436         # make sense to store uboot lines per novaboot script.
 437         my ($timeout, $redir, $string, $dest) = ($1, $2, $3);
 438         if ($string =~ /(.*) *> *(.*)/) {
 439             $string = $1;
 440             $dest = $2;
 441         }
 442         push @uboot_init, { command => $redir ? "" : $string,
 443                             system =>  $redir ? $string : "",
 444                             timeout => $timeout,
 445                             dest => $dest,
 446         };
 447         next;
 448     }
 449
 450     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 451 }
 452 # use Data::Dumper;
 453 # print Dumper(\@scripts);
 454
 455 foreach my $script (@scripts) {
 456     $modules = $$script{modules};
 457     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 458     @$modules[0] .= ' ' . join(' ', @append) if @append;
 459
 460     my $kernel;
 461     if (exists $variables->{KERNEL}) {
 462         $kernel = $variables->{KERNEL};
 463     } else {
 464         if ($CFG::hypervisor) {
 465             $kernel = $CFG::hypervisor . " ";
 466             if (exists $variables->{HYPERVISOR_PARAMS}) {
 467                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 468             } else {
 469                 $kernel .= $CFG::hypervisor_params;
 470             }
 471         }
 472     }
 473     @$modules = ($kernel, @$modules) if $kernel;
 474     @$modules = (@chainloaders, @$modules);
 475     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 476 }
 477
 478 if ($dump_opt) {
 479     foreach my $script (@scripts) {
 480         print join("\n", @{$$script{modules}})."\n";
 481     }
 482     exit(0);
 483 }
 484
 485 ## Helper functions
 486
 487 sub generate_configs($$$) {
 488     my ($base, $generated, $filename) = @_;
 489     if ($base) { $base = "$base/"; };
 490     foreach my $g(@$generated) {
 491       if (exists $$g{content}) {
 492         my $config = $$g{content};
 493         my $fn = $$g{filename};
 494         open(my $f, '>', $fn) || die("$fn: $!");
 495         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 496         close($f);
 497         print STDERR "novaboot: Created $fn\n";
 498       } elsif (exists $$g{command} && ! $no_file_gen) {
 499         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 500         if (exists $$g{filename}) {
 501             system_verbose("( $$g{command} ) > $$g{filename}");
 502         } else {
 503             system_verbose($$g{command});
 504         }
 505       }
 506     }
 507 }
 508
 509 sub generate_grub_config($$$$;$)
 510 {
 511     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 512     if ($base) { $base = "$base/"; };
 513     open(my $fg, '>', $filename) or die "$filename: $!";
 514     print $fg "$preamble\n" if $preamble;
 515     print $fg "title $title\n" if $title;
 516     #print $fg "root $base\n"; # root doesn't really work for (nd)
 517     my $first = 1;
 518     foreach (@$modules_ref) {
 519         if ($first) {
 520             $first = 0;
 521             my ($kbin, $kcmd) = split(' ', $_, 2);
 522             $kcmd = '' if !defined $kcmd;
 523             print $fg "kernel ${base}$kbin $kcmd\n";
 524         } else {
 525             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 526             print $fg "module $base$_\n";
 527         }
 528     }
 529     close($fg);
 530     print("novaboot: Created $builddir/$filename\n");
 531     return $filename;
 532 }
 533
 534 sub generate_syslinux_config($$$$)
 535 {
 536     my ($filename, $title, $base, $modules_ref) = @_;
 537     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 538     open(my $fg, '>', $filename) or die "$filename: $!";
 539     print $fg "LABEL $title\n";
 540     #TODO print $fg "MENU LABEL $human_readable_title\n";
 541
 542     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 543
 544     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 545         my $initrd = @$modules_ref[1];
 546         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 547         print $fg "LINUX $base$kbin\n";
 548         print $fg "APPEND $kcmd\n";
 549         print $fg "INITRD $base$initrd\n";
 550     } else {
 551         print $fg "KERNEL mboot.c32\n";
 552         my @append;
 553         foreach (@$modules_ref) {
 554             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 555             push @append, "$base$_";
 556             print $fg "APPEND ".join(' --- ', @append)."\n";
 557         }
 558     }
 559     #TODO print $fg "TEXT HELP\n";
 560     #TODO print $fg "some help here\n";
 561     #TODO print $fg "ENDTEXT\n";
 562     close($fg);
 563     print("novaboot: Created $builddir/$filename\n");
 564     return $filename;
 565 }
 566
 567 sub generate_grub2_config($$$$;$$)
 568 {
 569     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 570     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 571     open(my $fg, '>', $filename) or die "$filename: $!";
 572     print $fg "$preamble\n" if $preamble;
 573     $title ||= 'novaboot';
 574     print $fg "menuentry $title {\n";
 575     print $fg "$prolog\n" if $prolog;
 576     my $first = 1;
 577     foreach (@$modules_ref) {
 578         if ($first) {
 579             $first = 0;
 580             my ($kbin, $kcmd) = split(' ', $_, 2);
 581             $kcmd = '' if !defined $kcmd;
 582             print $fg "  multiboot ${base}$kbin $kcmd\n";
 583         } else {
 584             my @args = split;
 585             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 586             $_ = join(' ', ($args[0], @args));
 587             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 588             print $fg "  module $base$_\n";
 589         }
 590     }
 591     print $fg "}\n";
 592     close($fg);
 593     print("novaboot: Created $builddir/$filename\n");
 594     return $filename;
 595 }
 596
 597 sub generate_pulsar_config($$$)
 598 {
 599     my ($filename, $modules_ref, $chainload_ref) = @_;
 600     open(my $fg, '>', $filename) or die "$filename: $!";
 601     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 602     if (scalar(@$chainload_ref) > 0) {
 603         print $fg "chld $$chainload_ref[0]\n";
 604     } else {
 605         my $first = 1;
 606         my ($kbin, $kcmd);
 607         foreach (@$modules_ref) {
 608             if ($first) {
 609                 $first = 0;
 610                 ($kbin, $kcmd) = split(' ', $_, 2);
 611                 $kcmd = '' if !defined $kcmd;
 612             } else {
 613                 my @args = split;
 614                 s|\brom://|$rom_prefix|g;
 615                 print $fg "load $_\n";
 616             }
 617         }
 618         # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 619         print $fg "exec $kbin $kcmd\n";
 620     }
 621     close($fg);
 622     print("novaboot: Created $builddir/$filename\n");
 623     return $filename;
 624 }
 625
 626 sub shell_cmd_string(@)
 627 {
 628     if (scalar(@_) == 1) {
 629         return $_[0];
 630     } else {
 631         return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 632     }
 633 }
 634
 635 sub exec_verbose(@)
 636 {
 637     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 638     exec(@_);
 639     exit(1); # should not be reached
 640 }
 641
 642 sub system_verbose
 643 {
 644     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 645     my $ret = system(@_);
 646     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 647     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 648     if ($ret) { die("Command failure $ret"); }
 649 }
 650
 651 sub trim($) {
 652     my ($str) = @_;
 653     $str =~ s/^\s+|\s+$//g;
 654     return $str
 655 }
 656
 657 ## WvTest headline
 658
 659 if (exists $variables->{WVDESC}) {
 660     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 661 } elsif ($last_fn =~ /\.wv$/) {
 662     print STDERR "Testing \"all\" in $last_fn:\n";
 663 }
 664
 665 ## Connect to the target and check whether it is not occupied
 666
 667 # We have to do this before file generation phase, because file
 668 # generation is intermixed with file deployment phase and we want to
 669 # check whether the target is not used by somebody else before
 670 # deploying files. Otherwise, we may rewrite other user's files on a
 671 # boot server.
 672
 673 my $exp; # Expect object to communicate with the target over serial line
 674
 675 sub kill_exp_on_signal() {
 676     # Sometimes, under unclear circumstances (e.g. when running under
 677     # both Jenkins and Robotframework), novaboot does not terminate
 678     # console command when killed. The console is then blocked by the
 679     # stale process forever. Theoretically, this should not happen,
 680     # because when novaboot is killed, console command's controlling
 681     # terminal sends SIGHUP to the console command and the command
 682     # should terminate. It seems that at least SSH sometimes ignores
 683     # HUP and does not terminate. The code below seems to work around
 684     # that problem by killing the process immediately with SIGTERM,
 685     # which is not ignored.
 686
 687     sub kill_console { kill TERM => $exp->pid if $exp->pid; die "Terminated by SIG$_[0]"; };
 688
 689     # For our Jenkins/Robotframework use case, it was sufficient to
 690     # handle the TERM signal, but to be on the safe side, we also
 691     # catch other signals.
 692     $SIG{TERM} = \&kill_console;
 693     $SIG{HUP} = \&kill_console;
 694     $SIG{INT} = \&kill_console;
 695     $SIG{QUIT} = \&kill_console;
 696 }
 697
 698
 699 my ($amt_user, $amt_password, $amt_host, $amt_port);
 700
 701 if (defined $iprelay || defined $iprelay_cmd) {
 702     if (defined $iprelay) {
 703         my $IPRELAY;
 704         $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 705         my $addr = $1;
 706         my $port = $3 || 23;
 707         my $paddr   = sockaddr_in($port, inet_aton($addr));
 708         my $proto   = getprotobyname('tcp');
 709         socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 710         print STDERR "novaboot: Connecting to IP relay... ";
 711         connect($IPRELAY, $paddr)    || die "connect: $!";
 712         print STDERR "done\n";
 713         $exp = Expect->init(\*$IPRELAY);
 714         $exp->log_stdout(1);
 715     }
 716     if (defined $iprelay_cmd) {
 717         print STDERR "novaboot: Running: $iprelay_cmd\n";
 718         $exp = new Expect;
 719         $exp->raw_pty(1);
 720         $exp->spawn($iprelay_cmd);
 721         kill_exp_on_signal();
 722     }
 723
 724     while (1) {
 725         print $exp "\xFF\xF6";  # AYT
 726         my $connected = $exp->expect(20, # Timeout in seconds
 727                                      '<iprelayd: connected>',
 728                                      '-re', '<WEB51 HW[^>]*>')
 729             || die "iprelay connection: " . ($! || "timeout");
 730         last if $connected;
 731     }
 732
 733     sub relaycmd($$) {
 734         my ($relay, $onoff) = @_;
 735         die unless ($relay == 1 || $relay == 2);
 736
 737         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 738         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 739     }
 740
 741     sub relayconf($$) {
 742         my ($relay, $onoff) = @_;
 743         die unless ($relay == 1 || $relay == 2);
 744         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 745         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 746     }
 747
 748     sub relay($$;$) {
 749         my ($relay, $onoff, $can_giveup) = @_;
 750         my $confirmation = '';
 751         $exp->log_stdout(0);
 752         print $exp relaycmd($relay, $onoff);
 753         my $confirmed = $exp->expect(20, # Timeout in seconds
 754                                      relayconf($relay, $onoff))
 755             || die "iprelay command: " . ($! || "timeout");
 756         if (!$confirmed) {
 757             if ($can_giveup) {
 758                 print("Relay confirmation timeout - ignoring\n");
 759             } else {
 760                 die "Relay confirmation timeout";
 761             }
 762         }
 763         $exp->log_stdout(1);
 764     }
 765
 766     $target_reset = sub {
 767         relay(2, 1, 1); # Reset the machine
 768         usleep(100000);
 769         relay(2, 0);
 770     };
 771
 772     $target_power_off = sub {
 773         relay(1, 1);            # Press power button
 774         usleep(6000000);        # Long press to switch off
 775         relay(1, 0);
 776     };
 777
 778     $target_power_on = sub {
 779         relay(1, 1);            # Press power button
 780         usleep(100000);         # Short press
 781         relay(1, 0);
 782     };
 783 }
 784 elsif ($serial) {
 785     my $CONN;
 786     system_verbose("stty -F $serial $stty");
 787     open($CONN, "+<", $serial) || die "open $serial: $!";
 788     $exp = Expect->init(\*$CONN);
 789 }
 790 elsif (@remote_cmd) {
 791     print STDERR "novaboot: Running: ".shell_cmd_string(@remote_cmd)."\n";
 792     $exp = Expect->spawn(@remote_cmd);
 793     kill_exp_on_signal();
 794 }
 795 elsif (defined $amt) {
 796     require LWP::UserAgent;
 797     require LWP::Authen::Digest;
 798
 799     sub genXML {
 800         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 801         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 802         my %pstates = ("on"        => 2,
 803                        "standby"   => 4,
 804                        "hibernate" => 7,
 805                        "off"       => 8,
 806                        "reset"     => 10,
 807                        "MNI"       => 11);
 808         return <<END;
 809                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 810                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 811                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 812                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 813                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 814                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 815                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 816                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 817                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 818                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 819                 </s:Header><s:Body>
 820                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 821                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 822                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 823                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 824                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 825                 </a:ReferenceParameters></p:ManagedElement>
 826                 </p:RequestPowerStateChange_INPUT>
 827                 </s:Body></s:Envelope>
 828 END
 829     }
 830
 831     sub sendPOST {
 832         my ($host, $username, $password, $content) = @_;
 833
 834         my $ua = LWP::UserAgent->new();
 835         $ua->agent("novaboot");
 836
 837         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 838         my $res = $ua->request($req);
 839         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 840
 841         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 842         $ua->credentials("$host:16992", $realm, $username => $password);
 843
 844         # Create a request
 845         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 846         $req->content_type('application/x-www-form-urlencoded');
 847         $req->content($content);
 848         $res = $ua->request($req);
 849         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 850         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 851         return $1;
 852     }
 853
 854     sub powerChange  {
 855         my ($host, $username, $password, $pstate)=@_;
 856         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 857         my $className="/RequestPowerStateChange";
 858         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 859         return sendPOST($host, $username, $password, $content);
 860     }
 861
 862     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 863     $amt_user ||= "admin";
 864     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 865     $amt_host || die "AMT host not specified";
 866     $amt_port ||= 16994;
 867
 868
 869     $target_power_off = sub {
 870         $exp->close();
 871         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 872         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 873     };
 874
 875     $target_power_on = sub {
 876         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 877         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 878     };
 879
 880     $target_reset = sub {
 881         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 882         if ($result != 0) {
 883             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 884             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 885         }
 886         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 887     };
 888
 889     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 890     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 891     $exp = Expect->spawn($cmd);
 892     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL': " . ($! || "timeout");
 893 }
 894
 895
 896 if ($remote_expect) {
 897     $exp || die("No serial line connection");
 898     my $log = $exp->log_stdout;
 899     if (defined $remote_expect_silent) {
 900         $exp->log_stdout(0);
 901     }
 902     $exp->expect($remote_expect_timeout >= 0 ? $remote_expect_timeout : undef,
 903                  $remote_expect) || die "Expect for '$remote_expect':" . ($! || "timeout");;
 904     if (defined $remote_expect_silent) {
 905         $exp->log_stdout($log);
 906         print $exp->after() if $log;
 907     }
 908 }
 909
 910 if (@reset_cmd) {
 911     $target_reset = sub {
 912         system_verbose(@reset_cmd);
 913     };
 914 }
 915
 916 if (defined $reset_send) {
 917     $target_reset = sub {
 918         $reset_send =~ s/\\n/\n/g;
 919         $exp->send($reset_send);
 920     };
 921 }
 922
 923 if (defined $on_opt && defined $target_power_on) {
 924     &$target_power_on();
 925     exit;
 926 }
 927 if (defined $off_opt && defined $target_power_off) {
 928     print STDERR "novaboot: Switching the target off...\n";
 929     &$target_power_off();
 930     exit;
 931 }
 932
 933 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 934 if (defined $builddir) {
 935     chdir($builddir) or die "Can't change directory to $builddir: $!";
 936     print STDERR "novaboot: Entering directory `$builddir'\n";
 937 } else {
 938     $builddir = $invocation_dir;
 939 }
 940
 941 ## File generation phase
 942 my (%files_iso, $menu_iso, $filename);
 943 my $config_name = '';
 944 my $prefix = '';
 945
 946 foreach my $script (@scripts) {
 947     $filename = $$script{filename};
 948     $modules = $$script{modules};
 949     $generated = $$script{generated};
 950     $variables = $$script{variables};
 951
 952     ($config_name = $filename) =~ s#.*/##;
 953     $config_name = $config_name_opt if (defined $config_name_opt);
 954
 955     if (exists $variables->{BUILDDIR}) {
 956         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 957         chdir($builddir) or die "Can't change directory to $builddir: $!";
 958         print STDERR "novaboot: Entering directory `$builddir'\n";
 959     }
 960
 961     if ($grub_prefix) {
 962         $prefix = $grub_prefix;
 963         $prefix =~ s/\$NAME/$config_name/;
 964         $prefix =~ s/\$BUILDDIR/$builddir/;
 965     }
 966     # TODO: use $grub_prefix as first parameter if some switch is given
 967     generate_configs('', $generated, $filename);
 968
 969 ### Generate bootloader configuration files
 970     my @bootloader_configs;
 971     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 972     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 973     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules, $chainload) if (defined $pulsar);
 974
 975 ### Run scons or make
 976     {
 977         my @all;
 978         push @all, @$modules;
 979         push @all, @$copy;
 980         push @all, @$chainload;
 981         my @files = map({ ($file) = m/([^ ]*)/; $file; } @all);
 982
 983         # Filter-out generated files
 984         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 985
 986         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 987         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 988     }
 989
 990 ### Copy files (using rsync)
 991     if (defined $server && !defined($gen_only)) {
 992         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 993
 994         my ($hostname, $path) = split(":", $real_server, 2);
 995         if (! defined $path) {
 996             $path = $hostname;
 997             $hostname = "";
 998         }
 999         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs, @$copy)));
1000         map({ my $file = (split)[0]; die "Not a file: $file: $!" if ! -e $file || -d $file; } @$modules);
1001         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
1002         my $progress = $istty ? "--progress" : "";
1003         if ($files) {
1004             system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
1005             if ($server =~ m|/\$NAME$| && $concat) {
1006                 my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
1007                 system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
1008             }
1009         }
1010     }
1011
1012 ### Prepare ISO image generation
1013     if (defined $iso_image) {
1014         generate_configs("(cd)", $generated, $filename);
1015         my $menu;
1016         generate_syslinux_config(\$menu, $config_name, "/", $modules);
1017         $menu_iso .= "$menu\n";
1018         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
1019     }
1020 }
1021
1022 ## Generate ISO image
1023 if (defined $iso_image) {
1024     system_verbose("mkdir -p isolinux");
1025
1026     my @files;
1027     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
1028         # Newer ISOLINUX version
1029         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
1030     } elsif (-f '/usr/lib/syslinux/isolinux.bin') {
1031         # Older ISOLINUX version
1032         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
1033     } else {
1034         # NixOS and maybe others
1035         my $syslinux = `which syslinux` || die "Cannot find syslinux";
1036         chomp $syslinux;
1037         $syslinux =~ s,/bin/syslinux$,,;
1038         @files = ("$syslinux/share/syslinux/isolinux.bin", "$syslinux/share/syslinux/mboot.c32", "$syslinux/share/syslinux/libcom32.c32", "$syslinux/share/syslinux/menu.c32", "$syslinux/share/syslinux/ldlinux.c32");
1039     }
1040     system_verbose("cp @files isolinux && chmod +w isolinux/*");
1041     open(my $fh, ">isolinux/isolinux.cfg");
1042     if ($#scripts) {
1043         print $fh "TIMEOUT 50\n";
1044         print $fh "DEFAULT menu\n";
1045     } else {
1046         print $fh "DEFAULT $config_name\n";
1047     }
1048     print $fh "$menu_iso";
1049     close($fh);
1050
1051     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
1052     $iso_image ||= "$config_name.iso";
1053
1054     # Note: We use -U flag below to "Allow 'untranslated' filenames,
1055     # completely violating the ISO9660 standards". Without this
1056     # option, isolinux is not able to read files names for example
1057     # bzImage-3.0.
1058     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
1059     print("ISO image created: $builddir/$iso_image\n");
1060 }
1061
1062 exit(0) if defined $gen_only;
1063
1064 ## Boot the system using various methods and send serial output to stdout
1065
1066 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
1067     die "You cannot do this with multiple scripts simultaneously";
1068 }
1069
1070 if ($variables->{WVTEST_TIMEOUT}) {
1071     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
1072 }
1073
1074 ### Start in Qemu
1075
1076 if (defined $qemu) {
1077     # Qemu
1078     $qemu ||= $variables->{QEMU} || $CFG::qemu;
1079     my @qemu_flags = split(" ", $qemu);
1080     $qemu = shift(@qemu_flags);
1081
1082     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
1083     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
1084     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
1085
1086     if (defined $iso_image) {
1087         # Boot NOVA with grub (and test the iso image)
1088         push(@qemu_flags, ('-cdrom', $iso_image));
1089     } else {
1090         # Boot NOVA without GRUB
1091
1092         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
1093         foreach (@$modules) {s/,/+/g;}
1094         generate_configs("", $generated, $filename);
1095
1096         if (scalar @$modules) {
1097             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1098             $kcmd = '' if !defined $kcmd;
1099             my $dtb;
1100             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1101             my $initrd = join ",", @$modules;
1102
1103             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
1104             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
1105             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
1106         }
1107     }
1108     if (!grep /^-serial$/, @qemu_flags) {
1109         push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
1110     }
1111     unshift(@qemu_flags, ('-name', $config_name));
1112     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
1113     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
1114 }
1115
1116 ### Local DHCPD and TFTPD
1117
1118 my ($dhcpd_pid, $tftpd_pid);
1119
1120 $tftp=1 if $tftp_port;
1121
1122 if (defined $dhcp_tftp)
1123 {
1124     generate_configs("(nd)", $generated, $filename);
1125     system_verbose('mkdir -p tftpboot');
1126     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
1127     open(my $fh, '>', 'dhcpd.conf');
1128     my $mac = `cat /sys/class/net/$netif/address`;
1129     chomp $mac;
1130     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
1131                       range 10.23.23.10 10.23.23.100;
1132                       filename \"bin/boot/grub/pxegrub.pxe\";
1133                       next-server 10.23.23.1;
1134 }
1135 host server {
1136         hardware ethernet $mac;
1137         fixed-address 10.23.23.1;
1138 }";
1139     close($fh);
1140     system_verbose("sudo ip a add 10.23.23.1/24 dev $netif;
1141             sudo ip l set dev $netif up;
1142             sudo touch dhcpd.leases");
1143
1144     # We run servers by forking ourselves, because the servers end up
1145     # in our process group and get killed by signals sent to the
1146     # process group (e.g. Ctrl-C on terminal).
1147     $dhcpd_pid = fork();
1148     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1149 }
1150
1151 if (defined $dhcp_tftp || defined $tftp) {
1152     $tftp_port ||= 69;
1153     # Unfortunately, tftpd requires root privileges even with
1154     # non-privileged (>1023) port due to initgroups().
1155     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
1156
1157     # Kill server when we die
1158     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1159                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1160
1161     # We have to kill tftpd explicitely, because it is not in our process group
1162     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1163 }
1164
1165 ### AMT IDE-R
1166 if (defined $ider) {
1167     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1168     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1169     my $ider_pid = fork();
1170     if ($ider_pid == 0) {
1171         exec($ider_cmd);
1172         die "IDE redirection failed";
1173     }
1174     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1175     # to use both simultaneously.
1176     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1177 }
1178
1179 ### Reset target (IP relay, AMT, ...)
1180
1181 if (defined $target_reset && $reset) {
1182     print STDERR "novaboot: Resetting the test box... ";
1183     &$target_reset();
1184     print STDERR "done\n";
1185     if (defined $exp) {
1186         # We don't want to output anything printed by the target
1187         # before reset so we clear the buffers now. This is, however,
1188         # not ideal because we may loose some data that were sent
1189         # after the reset. If this is a problem, one should reset and
1190         # connect to serial line in atomic manner. For example, if
1191         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1192         # do not use separate --reset-cmd.
1193         my $log = $exp->log_stdout;
1194         $exp->log_stdout(0);
1195         $exp->expect(0); # Read data from target
1196         $exp->clear_accum();    # Clear the read data
1197         $exp->log_stdout($log);
1198     }
1199 }
1200
1201 ### U-boot conversation
1202 if (defined $uboot) {
1203     my $uboot_prompt = $uboot || '=> ';
1204     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1205     $exp || die("No serial line connection");
1206     $exp->log_stdout(1);
1207     #$exp->exp_internal(1);
1208     $exp->expect(20,
1209                  [qr/Hit any key to stop autoboot:/, sub {
1210                      $exp->send($uboot_stop_key // "\n");
1211                      exp_continue; }],
1212                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1213     foreach my $cmdspec (@uboot_init) {
1214         my ($cmd, $timeout);
1215         die "Internal error - please report a bug" unless ref($cmdspec) eq "HASH";
1216
1217         if ($cmdspec->{system}) {
1218             $cmd = `$cmdspec->{system}`;
1219         } else {
1220             $cmd = $cmdspec->{command};
1221         }
1222         $timeout = $cmdspec->{timeout} // 10;
1223
1224         if ($cmd =~ /\$NB_MYIP/) {
1225             my $ip = (grep /inet /, `ip addr show $netif`)[0] || die "Problem determining IP address of $netif";
1226             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1227             $cmd =~ s/\$NB_MYIP/$ip/g;
1228         }
1229         if ($cmd =~ /\$NB_PREFIX/) {
1230             my $p = $prefix;
1231             $p =~ s|/*$||;
1232             $cmd =~ s/\$NB_PREFIX/$p/g;
1233         }
1234         chomp($cmd);
1235         $exp->send("$cmd\n");
1236
1237         my ($matched_pattern_position, $error,
1238             $successfully_matching_string,
1239             $before_match, $after_match) =
1240                 $exp->expect($timeout, $uboot_prompt);
1241         die "No U-Boot prompt: $error" if $error;
1242
1243         if ($cmdspec->{dest}) {
1244             open(my $fh, ">", $cmdspec->{dest}) or die "Cannot open '$cmdspec->{dest}': $!";
1245             print $fh $before_match;
1246             close($fh);
1247         }
1248     }
1249
1250     # Load files if there are some load lines in the script
1251     if (scalar(@$modules) > 0  && !$variables->{NO_BOOT}) {
1252         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1253         my $dtb;
1254         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1255         my $initrd = shift @$modules;
1256
1257         if (defined $kbin && $kbin ne '/dev/null') {
1258             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1259             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1260             $exp->expect(15,
1261                          [qr/##/, sub { exp_continue; }],
1262                          $uboot_prompt) || die "Kernel load: " . ($! || "timeout");
1263         }
1264         if (defined $dtb) {
1265             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1266             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1267             $exp->expect(15,
1268                          [qr/##/, sub { exp_continue; }],
1269                          $uboot_prompt) || die "Device tree load: " . ($! || "timeout");
1270         } else  {
1271             $uboot_addr{fdt} = '';
1272         }
1273         if (defined $initrd) {
1274             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1275             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1276             $exp->expect(15,
1277                          [qr/##/, sub { exp_continue; }],
1278                          $uboot_prompt) || die "Initrd load: " . ($! || "timeout");
1279         } else {
1280             $uboot_addr{ramdisk} = '-';
1281         }
1282
1283         $kcmd //= '';
1284         $exp->send("setenv bootargs $kcmd\n");
1285         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt: " . ($! || "timeout");
1286
1287     }
1288     $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1289     if (!$variables->{NO_BOOT} && $uboot_cmd ne '') {
1290         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1291         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1292         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1293
1294         $exp->send($uboot_cmd . "\n");
1295         $exp->expect(5, "\n")  || die "U-Boot command: " . ($! || "timeout");
1296     }
1297 }
1298
1299 ### Serial line interaction
1300 if ($interaction && defined $exp) {
1301     # Serial line of the target is available
1302     my $interrupt = 'Ctrl-C';
1303     if ($interactive && !@exiton) {
1304         $interrupt = '"~~."';
1305     }
1306     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1307     $exp->log_stdout(1);
1308     if (@exiton) {
1309         $exp->expect($exiton_timeout, @exiton, @expect_raw) || die("exiton: " . ($! || "timeout"));
1310     } else {
1311         my @inputs = ($exp);
1312         my $infile = new IO::File;
1313         $infile->IO::File::fdopen(*STDIN,'r');
1314         my $in_object = Expect->exp_init($infile);
1315         $in_object->set_group($exp);
1316
1317         if ($interactive) {
1318             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1319             $in_object->manual_stty(0);   # Use raw terminal mode
1320         } else {
1321             $in_object->manual_stty(1);   # Do not modify terminal settings
1322         }
1323         push(@inputs, $in_object);
1324         #use Data::Dumper;
1325         #print Dumper(\@expect_raw);
1326         $exp->expect(undef, @expect_raw) if @expect_raw;
1327
1328         $^W = 0; # Suppress Expect warning: handle id(3) is not a tty. Not changing mode at /usr/share/perl5/Expect.pm line 393, <> line 8.
1329         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1330         $^W = 1;
1331     }
1332 }
1333
1334 # When exp-spawned command ignores SIGHUP, Expect waits 5 seconds
1335 # before killing it. We kill it by SIGTERM immediately.
1336 kill TERM => $exp->pid if defined $exp && $exp->pid;
1337
1338 ## Kill dhcpc or tftpd
1339 if (defined $dhcp_tftp || defined $tftp) {
1340     die("novaboot: This should kill servers on background\n");
1341 }
1342
1343 # Always finish novaboot output with newline
1344 print "\n" if $final_eol;
1345
1346 ## Documentation
1347
1348 =encoding utf8
1349
1350 =head1 NAME
1351
1352 novaboot - Boots a locally compiled operating system on a remote
1353 target or in qemu
1354
1355 =head1 SYNOPSIS
1356
1357 B<novaboot> --help
1358
1359 B<novaboot> [option]... [--] script...
1360
1361 B<./script> [option]...
1362
1363 =head1 DESCRIPTION
1364
1365 Novaboot makes booting of a locally compiled operating system (OS)
1366 (e.g. NOVA or Linux) on remote targets as simple as running a program
1367 locally. It automates things like copying OS images to a TFTP server,
1368 generation of bootloader configuration files, resetting of target
1369 hardware or redirection of target's serial line to stdin/out. Novaboot
1370 is highly configurable and makes it easy to boot a single image on
1371 different targets or different images on a single target.
1372
1373 Novaboot operation is controlled by configuration files, command line
1374 options and by a so-called novaboot script, which can be thought as a
1375 generalization of bootloader configuration files (see L</"NOVABOOT
1376 SCRIPT SYNTAX">). The typical way of using novaboot is to make the
1377 novaboot script executable and set its first line to I<#!/usr/bin/env
1378 novaboot>. Then, booting a particular OS configuration becomes the
1379 same as executing a local program – the novaboot script.
1380
1381 Novaboot uses configuration files to, among other things, define
1382 command line options needed for different targets. Users typically use
1383 only the B<-t>/B<--target> command line option to select the target.
1384 Internally, this option expands to the pre-configured options.
1385 Novaboot searches configuration files at multiple places, which allows
1386 having per-system, per-user or per-project configurations.
1387 Configuration file syntax is described in section L</"CONFIGURATION
1388 FILES">.
1389
1390 Novaboot newcomers may be confused by a large number of configuration
1391 options. Understanding all these options is not always needed,
1392 depending on the used setup. The L<figure from the doc directory
1393 |https://github.com/wentasah/novaboot/blob/master/doc/typical-setups.svg>
1394 shows different setups that vary in how much effort is needed
1395 to configure novaboot for them. The setups are:
1396
1397 =over 3
1398
1399 =item A: Laptop and target device only
1400
1401 This requires to configure everything on the laptop side, including a
1402 serial line connection (L</--serial>, L</--remote-cmd>, ...), power
1403 on/off/reset commands (L</--reset-cmd>, ...), TFTP server
1404 (L</--server>, L</--prefix>...), device IP addresses, etc.
1405
1406 =item B: Laptop, target device and external TFTP server
1407
1408 Like the previous setup, but the TFTP (and maybe DHCP) configuration
1409 is handled by a server. Novaboot users need to understand where to
1410 copy their files to the TFTP server (L</--server>) and which IP
1411 addresses their target will get, but do not need to configure the
1412 servers themselves.
1413
1414 =item C: Novaboot server running novaboot-shell
1415
1416 With this setup, the configuration is done on the server. Users only
1417 need to know the SSH account (L</--ssh>) used to communicate between
1418 novaboot and novaboot server. The server is implemented as a
1419 restricted shell (L<novaboot-shell(1)>) on the server. No need to give
1420 full shell access to novaboot users on the server.
1421
1422 =back
1423
1424 =head2 Simple examples of using C<novaboot>:
1425
1426 To boot Linux (files F<bzImage> and F<rootfs.cpio> in current
1427 directory), create F<mylinux> file with this content:
1428
1429     #!/usr/bin/env novaboot
1430     load bzImage console=ttyS0,115200
1431     load rootfs.cpio
1432
1433 =over 3
1434
1435 =item 1.
1436
1437 Booting an OS in Qemu can be accomplished by giving the B<--qemu> option.
1438 Thus running
1439
1440  novaboot --qemu mylinux
1441
1442 (or C<./mylinux --qemu> as described above) will run Qemu and make it
1443 boot the configuration specified in the F<mylinux> script. How is qemu
1444 started can be configured in various ways (see below).
1445
1446 =item 2.
1447
1448 Create a bootloader configuration file (currently supported
1449 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar, and U-Boot) and copy it
1450 with all other files needed for booting to a remote TFTP server. Then
1451 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1452 target and receive its serial output.
1453
1454  ./mylinux --grub2 --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1455
1456 Alternatively, you can put these switches to the configuration file
1457 and run:
1458
1459  ./mylinux --target mytarget
1460
1461 =item 3.
1462
1463 Specifying all the options needed by novaboot to successfully control
1464 the target, either on command line or in configuration files, can be
1465 difficult for users. Novaboot supports configuring the target
1466 centrally via L<novaboot-shell(1)> on a server. With such a
1467 configuration, users only need to use the B<--ssh> option to specify
1468 where to boot their OS:
1469
1470  ./mylinux --ssh myboard@example.com
1471
1472 Typically, the server is the computer connected to and controlling the
1473 target board and running the TFTP server.
1474
1475 =item 4.
1476
1477 Run DHCP and TFTP server on developer's machine to boot the target
1478 from it.
1479
1480  ./mylinux --dhcp-tftp
1481
1482 This usage is useful when no network infrastructure is in place, and
1483 the target is connected directly to developer's box.
1484
1485 =item 5.
1486
1487 Create bootable ISO image.
1488
1489  novaboot --iso -- script1 script2
1490
1491 The created ISO image will have ISOLINUX bootloader installed on it,
1492 and the boot menu will allow selecting between I<script1> and
1493 I<script2> configurations.
1494
1495 =back
1496
1497 =head1 OPTIONS AND PHASES
1498
1499 Novaboot performs its work in several phases. Command line options
1500 described bellow influence the execution of each phase or allow their
1501 skipping. The list of phases (in the execution order) is as follows.
1502
1503 =over
1504
1505 =item 1. L<Configuration reading|/Configuration reading phase>
1506
1507 =item 2. L<Command line processing|/Command line processing phase>
1508
1509 =item 3. L<Script preprocessing|/Script preprocessing phase>
1510
1511 =item 4. L<File generation|/File generation phase>
1512
1513 =item 5. L<Target connection|/Target connection check>
1514
1515 =item 6. L<File deployment|/File deployment phase>
1516
1517 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1518
1519 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1520
1521 =item 9. L<Target interaction|/Target interaction phase>
1522
1523 =back
1524
1525 Each phase is described in the following sections together with the
1526 command line options that control it.
1527
1528 =head2 Configuration reading phase
1529
1530 After starting, novaboot reads zero or more configuration files. We
1531 describe their content in section L</"CONFIGURATION FILES">. By default, the
1532 configuration is read from multiple locations. First from the system
1533 configuration directory (F</etc/novaboot.d/>), second from the user
1534 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1535 files along the path to the current directory. Alternatively, a single
1536 configuration file specified with the B<-c> switch or with the
1537 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1538 override settings from the former ones.
1539
1540 The system configuration directory is determined by the content of
1541 NOVABOOT_CONFIG_DIR environment variable and defaults to
1542 F</etc/novaboot.d>. Files in this directory with names consisting
1543 solely of English letters, numbers, dashes '-' and underscores '_'
1544 (note that dot '.' is not included) are read in alphabetical order.
1545
1546 Then, the user configuration file is read from
1547 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environment
1548 variable is not set F<~/.config/novaboot> is read instead.
1549
1550 Finally, novaboot searches for files named F<.novaboot> starting from the
1551 directory of the novaboot script (or working directory, see bellow)
1552 and continuing upwards up to the root directory. The found
1553 configuration files are then read in the opposite order (i.e. from the
1554 root directory downwards). This ordering allows having, for example, a project
1555 specific configuration in F<~/project/.novaboot>.
1556
1557 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1558 The former one is always read, whereas the latter only when novaboot
1559 script or working directory is under the C<$HOME> directory.
1560
1561 In certain cases, the location of the novaboot script cannot be
1562 determined in this early phase. This situation happens either when the script is
1563 read from the standard input or when novaboot is invoked explicitly as
1564 in the example L</"4."> above. In this case, the current working
1565 directory is used as a starting point for configuration file search
1566 instead of the novaboot script directory.
1567
1568 =over 8
1569
1570 =item -c, --config=I<filename>
1571
1572 Use the specified configuration file instead of the default one(s).
1573
1574 =back
1575
1576 =head2 Command line processing phase
1577
1578 =over 8
1579
1580 =item --dump-config
1581
1582 Dump the current configuration to stdout end exit. Useful as an
1583 initial template for a configuration file.
1584
1585 =item -h, --help
1586
1587 Print short (B<-h>) or long (B<--help>) help.
1588
1589 =item -t, --target=I<target>
1590
1591 This option serves as a user configurable shortcut for other novaboot
1592 options. The effect of this option is the same as specifying the
1593 options stored in the C<%targets> configuration variable under key
1594 I<target>. See also L</"CONFIGURATION FILES">.
1595
1596 When this option is not given, novaboot tries to determine the target
1597 to use from either B<NOVABOOT_TARGET> environment variable or
1598 B<$default_target> configuration file variable.
1599
1600 =item --ssh=I<user@hostname>
1601
1602 Configures novaboot to control the target via C<novaboot-shell>
1603 running remotely via SSH.
1604
1605 Using this option is the same as specifying B<--remote-cmd>,
1606 B<--remote-expect>, B<--server> B<--rsync-flags>, B<--prefix> and
1607 B<--reset-cmd> manually in a way compatible with C<novaboot-shell>.
1608 The server can be configured to provide other, safe bootloader-related
1609 options, to the client. When this happens, novaboot prints them to
1610 stdout.
1611
1612 Currently, this in an initial experimental implementation. We plan to
1613 change/extend this feature soon!
1614
1615 =back
1616
1617 =head2 Script preprocessing phase
1618
1619 This phase allows modifying the parsed novaboot script before it is
1620 used in the later phases.
1621
1622 =over 8
1623
1624 =item -a, --append=I<parameters>
1625
1626 Append a string to the first C<load> line in the novaboot script. This option
1627 can be used to append parameters to the kernel's or root task's
1628 command line. This option can appear multiple times.
1629
1630 =item -b, --bender
1631
1632 Use L<Bender|https://github.com/TUD-OS/morbo/blob/master/standalone/bender.c>
1633 chainloader. Bender scans the PCI bus for PCI serial ports and stores
1634 the information about them in the BIOS data area for use by the
1635 kernel.
1636
1637 =item --chainloader=I<chainloader>
1638
1639 Specifies a chainloader that is loaded before the kernel and other
1640 files specified in the novaboot script. E.g. 'bin/boot/bender
1641 promisc'.
1642
1643 =item --dump
1644
1645 Print the modules to boot and their parameters, after this phase
1646 finishes. Then exit. This is useful for seeing the effect of other
1647 options in this section.
1648
1649 =item -k, --kernel=F<file>
1650
1651 Replace the first word on the first C<load> line in the novaboot
1652 script with F<file>.
1653
1654 =item --scriptmod=I<Perl expression>
1655
1656 When novaboot reads the script, I<Perl expression> is executed for every
1657 line (in $_ variable). For example, C<novaboot
1658 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1659 in the script with I<omega6>.
1660
1661 When this option is present, it overrides I<$script_modifier> variable
1662 from the configuration file, which has the same effect. If this option
1663 is given multiple times all expressions are evaluated in the command
1664 line order.
1665
1666 =back
1667
1668 =head2 File generation phase
1669
1670 In this phase, files needed for booting are generated in a so-called
1671 I<build directory> (see L</--build-dir>). In most cases configuration
1672 for a bootloader is generated automatically by novaboot. It is also
1673 possible to generate other files using I<heredoc> or I<"<"> syntax in
1674 novaboot scripts. Finally, novaboot can generate binaries in this phases by
1675 running C<scons> or C<make>.
1676
1677 =over 8
1678
1679 =item --build-dir=I<directory>
1680
1681 Overrides the default build directory location.
1682
1683 The default build directory location is determined as follows: If the
1684 configuration file defines the C<$builddir> variable, its value is
1685 used. Otherwise, it is the directory that contains the first processed
1686 novaboot script.
1687
1688 See also L</BUILDDIR> variable.
1689
1690 =item -g, --grub[=I<filename>]
1691
1692 Generates grub bootloader menu file. If the I<filename> is not
1693 specified, F<menu.lst> is used. The I<filename> is relative to the
1694 build directory (see B<--build-dir>).
1695
1696 =item --grub-preamble=I<prefix>
1697
1698 Specifies the I<preamble> that is at the beginning of the generated
1699 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1700 timeout.
1701
1702 =item --prefix=I<prefix>
1703
1704 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1705 filename in generated bootloader configuration files (or in U-Boot
1706 commands).
1707
1708 If the I<prefix> contains string $NAME, it will be replaced with the
1709 name of the novaboot script (see also B<--name>).
1710
1711 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1712 the build directory (see also B<--build-dir>).
1713
1714 =item --grub-prefix
1715
1716 Alias for B<--prefix>.
1717
1718 =item --grub2[=I<filename>]
1719
1720 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1721 specified F<grub.cfg> is used. The content of the menu entry can be
1722 customized with B<--grub-preamble>, B<--grub2-prolog> or
1723 B<--grub_prefix> options.
1724
1725 To use the generated menu entry on your development
1726 machine that uses GRUB2, append the following snippet to
1727 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1728 i.e. run update-grub on Debian/Ubuntu.
1729
1730   if [ -f /path/to/nul/build/grub.cfg ]; then
1731     source /path/to/nul/build/grub.cfg
1732   fi
1733
1734 =item --grub2-prolog=I<prolog>
1735
1736 Specifies the text that novaboot puts at the beginning of the GRUB2 menu entry.
1737
1738 =item -m, --make[=make command]
1739
1740 Runs C<make> to build files that are not generated by novaboot itself.
1741
1742 =item --name=I<string>
1743
1744 Use the name I<string> instead of the name of the novaboot script.
1745 This name is used for things like a title of grub menu or for the
1746 server directory where the boot files are copied to.
1747
1748 =item --no-file-gen
1749
1750 Do not run external commands to generate files (i.e. "<" syntax and
1751 C<run> keyword). This switch does not influence the generation of files
1752 specified with "<<WORD" syntax.
1753
1754 =item -p, --pulsar[=mac]
1755
1756 Generates pulsar bootloader configuration file named F<config-I<mac>>
1757 The I<mac> string is typically a MAC address and defaults to
1758 I<novaboot>.
1759
1760 =item --scons[=scons command]
1761
1762 Runs C<scons> to build files that are not generated by novaboot
1763 itself.
1764
1765 =item --strip-rom
1766
1767 Strip I<rom://> prefix from command lines and generated config files.
1768 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1769
1770 =item --gen-only
1771
1772 Exit novaboot after file generation phase.
1773
1774 =back
1775
1776 =head2 Target connection check
1777
1778 In this phase novaboot connects to target's serial port (if it has
1779 one). If another novaboot user/instance occupies the target, novaboot
1780 exits here with an error message.
1781
1782 =over 8
1783
1784 =item --amt=I<"[user[:password]@]host[:port]>
1785
1786 Use Intel AMT technology to control the target machine. WS management
1787 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1788 The hostname or (IP address) is given by the I<host> parameter. If the
1789 I<password> is not specified, environment variable AMT_PASSWORD is
1790 used. The I<port> specifies a TCP port for SOL. If not specified, the
1791 default is 16992. The default I<user> is admin.
1792
1793 =item --iprelay=I<addr[:port]>
1794
1795 Use TCP/IP relay and serial port to access the target's serial port
1796 and powercycle it. The I<addr> parameter specifies the IP address of
1797 the relay. If I<port> is not specified, it defaults to 23.
1798
1799 Note: This option is supposed to work with HWG-ER02a IP relays.
1800
1801 =item --iprelay-cmd=I<command>
1802
1803 Similar to B<--iprelay> but uses I<command> to talk to the iprelay
1804 rather than direct network connection.
1805
1806 =item -s, --serial[=device]
1807
1808 Target's serial line is connected to host's serial line (device). The
1809 default value for device is F</dev/ttyUSB0>.
1810
1811 The value of this option is exported in NB_NOVABOOT environment
1812 variable to all subprocesses run by C<novaboot>.
1813
1814 =item --stty=I<settings>
1815
1816 Specifies settings passed to C<stty> invoked on the serial line
1817 specified with B<--serial> option. If this option is not given,
1818 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1819
1820 =item --remote-cmd=I<cmd>
1821
1822 Command that mediates connection to the target's serial line. For
1823 example C<ssh server 'cu -l /dev/ttyS0'>.
1824
1825 =item --remote-expect=I<string>
1826
1827 Wait for reception of I<string> after establishing the remote serial
1828 line connection. Novaboot assumes that after establishing the serial
1829 line connection, the user running novaboot has exclusive access to the
1830 target. If establishing of the serial line connection happens
1831 asynchronously (e.g. running a command remotely via SSH), we need this
1832 option to wait until the exclusive access is confirmed by the remote
1833 side.
1834
1835 Depending on target configuration, this option can solve two practical
1836 problems: 1) Overwriting of files deployed by another user currently
1837 using the target. 2) Resetting the target board before serial line
1838 connection is established and thus missing bootloader interaction.
1839
1840 Example of usage with the L<sterm
1841 tool|https://rtime.felk.cvut.cz/gitweb/sojka/sterm.git>:
1842
1843   --remote-cmd='ssh -tt example.com sterm -v /dev/ttyUSB0' --remote-expect='sterm: Connected'
1844
1845 =item --remote-expect-silent=I<string>
1846
1847 The same as B<--remote-expect> except that the remote output is not
1848 echoed to stdout while waiting for the I<string>. Everything after the
1849 matched string is printed to stdout, so you may want to include line
1850 end characters in the I<string> as well.
1851
1852 =item --remote-expect-timeout=I<seconds>
1853
1854 Timeout in seconds for B<--remote-expect> or
1855 B<--remote-expect-seconds>. When negative, waits forever. The default
1856 is -1 seconds.
1857
1858 =back
1859
1860 =head2 File deployment phase
1861
1862 In some setups, it is necessary to copy the files needed for booting
1863 to a particular location, e.g. to a TFTP boot server or to the
1864 F</boot> partition.
1865
1866 =over 8
1867
1868 =item -d, --dhcp-tftp
1869
1870 Turns your workstation into a DHCP and TFTP server so that the OS can
1871 be booted via PXE BIOS (or similar mechanism) on the test machine
1872 directly connected by a plain Ethernet cable to your workstation.
1873
1874 The DHCP and TFTP servers require root privileges and C<novaboot>
1875 uses C<sudo> command to obtain those. You can put the following to
1876 I</etc/sudoers> to allow running the necessary commands without asking
1877 for a password.
1878
1879  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1880  your_login ALL=NOPASSWD: NOVABOOT
1881
1882 =item --tftp
1883
1884 Starts a TFTP server on your workstation. This is similar to
1885 B<--dhcp-tftp> except that DHCP server is not started.
1886
1887 The TFTP server requires root privileges and C<novaboot> uses C<sudo>
1888 command to obtain those. You can put the following to I</etc/sudoers>
1889 to allow running the necessary commands without asking for a password.
1890
1891  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1892  your_login ALL=NOPASSWD: NOVABOOT
1893
1894 =item --tftp-port=I<port>
1895
1896 Port to run the TFTP server on. Implies B<--tftp>.
1897
1898 =item --netif=I<network interface>
1899
1900 Network interface used to deploy files to the target. This option
1901 influences the configuration of the DHCP server started by
1902 B<--dhcp-tftp> and the value that B<$NB_MYIP> get replaced with during
1903 U-Boot conversation. The default value is C<$netif> variable from
1904 configuration files, which defaults to I<eth0>.
1905
1906 =item --iso[=filename]
1907
1908 Generates the ISO image that boots NOVA system via GRUB. If no filename
1909 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1910 of the novaboot script (see also B<--name>).
1911
1912 =item --server[=[[user@]server:]path]
1913
1914 Copy all files needed for booting to another location. The files will
1915 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1916 contains string $NAME, it will be replaced with the name of the
1917 novaboot script (see also B<--name>).
1918
1919 =item --rsync-flags=I<flags>
1920
1921 Specifies I<flags> to append to F<rsync> command line when
1922 copying files as a result of I<--server> option.
1923
1924 =item --concat
1925
1926 If B<--server> is used and its value ends with $NAME, then after
1927 copying the files, a new bootloader configuration file (e.g. menu.lst)
1928 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1929 with $NAME part removed. The content of the file is created by
1930 concatenating all files of the same name from all subdirectories of
1931 I<path-wo-name> found on the "server".
1932
1933 =item --ider
1934
1935 Use Intel AMT technology for IDE redirection. This allows the target
1936 machine to boot from novaboot created ISO image. Implies B<--iso>.
1937
1938 The experimental C<amtider> utility needed by this option can be
1939 obtained from https://github.com/wentasah/amtterm.
1940
1941 =back
1942
1943 =head2 Target power-on and reset phase
1944
1945 At this point, the target is reset (or switched on/off). There are
1946 several ways how this can be accomplished. Resetting a physical target
1947 can currently be accomplished by the following options: B<--amt>,
1948 B<--iprelay>, B<--reset-cmd> and B<--reset-send>.
1949
1950 =over 8
1951
1952 =item --on, --off
1953
1954 Switch on/off the target machine and exit. The script (if any) is
1955 completely ignored. Currently, it works only with the following
1956 options: B<--iprelay>, B<--amt>, B<--ssh>.
1957
1958 =item -Q, --qemu[=I<qemu-binary>]
1959
1960 Boot the configuration in qemu. Optionally, the name of qemu binary
1961 can be specified as a parameter.
1962
1963 =item --qemu-append=I<flags>
1964
1965 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1966 C<-cpu coreduo -smp 2>).
1967
1968 =item -q, --qemu-flags=I<flags>
1969
1970 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1971 -smp 2>) with I<flags> specified here.
1972
1973 =item --reset-cmd=I<cmd>
1974
1975 Runs command I<cmd> to reset the target.
1976
1977 =item --reset-send=I<string>
1978
1979 Reset the target by sending the given I<string> to the remote serial
1980 line. "\n" sequences are replaced with the newline character.
1981
1982 =item --no-reset, --reset
1983
1984 Disable/enable resetting of the target.
1985
1986 =back
1987
1988 =head2 Interaction with the bootloader on the target
1989
1990 =over 8
1991
1992 =item --uboot[=I<prompt>]
1993
1994 Interact with U-Boot bootloader to boot the thing described in the
1995 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1996 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1997
1998 =item --no-uboot
1999
2000 Disable U-Boot interaction previously enabled with B<--uboot>.
2001
2002 =item --uboot-stop-key=I<key>
2003
2004 Character, which is sent as a response to U-Boot's "Hit any key to
2005 stop autoboot" message. The default value is newline, but some devices
2006 (e.g. TP-Link TD-W8970) require a specific key to be pressed.
2007
2008 =item --uboot-init
2009
2010 Command(s) to send the U-Boot bootloader before loading the images and
2011 booting them. This option can be given multiple times. After sending
2012 commands from each option novaboot waits for U-Boot I<prompt>.
2013
2014 If the command contains string I<$NB_MYIP> then this string is
2015 replaced by IPv4 address of eth0 interface (see also B<--netif>).
2016 Similarly, I<$NB_PREFIX> is replaced with prefix given by B<--prefix>.
2017
2018 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
2019
2020 =item --uboot-addr I<name>=I<address>
2021
2022 Load address of U-Boot's C<tftpboot> command for loading I<name>,
2023 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
2024 tree).
2025
2026 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
2027 variables used by convention for this purpose.
2028
2029 =item --uboot-cmd=I<command>
2030
2031 Specifies U-Boot command used to execute the OS. If the command
2032 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
2033 these are replaced with the addresses configured with B<--uboot-addr>.
2034
2035 The default value is
2036
2037     bootm $kernel_addr $ramdisk_addr $fdt_addr
2038
2039 or the C<UBOOT_CMD> variable if defined in the novaboot script.
2040
2041 =back
2042
2043 =head2 Target interaction phase
2044
2045 In this phase, target's serial output is redirected to stdout and if
2046 stdin is a TTY, it is redirected to the target's serial input allowing
2047 interactive work with the target.
2048
2049 =over 8
2050
2051 =item --exiton=I<string>
2052
2053 When the I<string> is sent by the target, novaboot exits. This option can
2054 be specified multiple times, in which case novaboot exits whenever
2055 either of the specified strings is sent.
2056
2057 If the I<string> is C<-re>, then the next B<--exiton>'s I<string> is
2058 treated as a regular expression. For example:
2059
2060     --exiton -re --exiton 'error:.*failed'
2061
2062 =item --exiton-re=I<regex>
2063
2064 The same as --exiton -re --exiton I<regex>.
2065
2066 =item --exiton-timeout=I<seconds>
2067
2068 By default B<--exiton> waits for the string match forever. When this
2069 option is specified, "exiton" timeouts after the specified number of
2070 seconds and novaboot returns non-zero exit code.
2071
2072 =item -i, --interactive
2073
2074 Setup things for the interactive use of the target. Your terminal will
2075 be switched to raw mode. In raw mode, your local terminal does not
2076 process input in any way (no echoing of entered characters, no
2077 interpretation of special characters). This, among others, means that
2078 Ctrl-C is passed to the target and does not interrupt novaboot. To
2079 exit from novaboot interactive mode type "~~.".
2080
2081 =item --no-interaction, --interaction
2082
2083 Skip resp. force target interaction phase. When skipped, novaboot exits
2084 immediately after the boot is initiated.
2085
2086 =item --expect=I<string>
2087
2088 When the I<string> is received from the target, send the string specified
2089 with the subsequent B<--send*> option to the target.
2090
2091 =item --expect-re=I<regex>
2092
2093 When target's output matches regular expression I<regex>, send the
2094 string specified with the subsequent B<--send*> option to the target.
2095
2096 =item --expect-raw=I<perl-code>
2097
2098 Provides direct control over Perl's Expect module.
2099
2100 =item --send=I<string>
2101
2102 Send I<string> to the target after the previously specified
2103 B<--expect*> was matched in the target's output. The I<string> may
2104 contain escape sequences such as "\n".
2105
2106 Note that I<string> is actually interpreted by Perl, so it can contain
2107 much more that escape sequences. This behavior may change in the
2108 future.
2109
2110 Example: C<--expect='login: ' --send='root\n'>
2111
2112 =item --sendcont=I<string>
2113
2114 Similar to B<--send> but continue expecting more input.
2115
2116 Example: C<--expect='Continue?' --sendcont='yes\n'>
2117
2118 =item --final-eol, --no-final-eol
2119
2120 By default, B<novaboot> always prints an end-of-line character at the
2121 end of its execution in order to ensure that the output of programs
2122 started after novaboot appears at the beginning of the line. When this
2123 is not desired B<--no-final-eol> option can be used to override this
2124 behavior.
2125
2126 =back
2127
2128 =head1 NOVABOOT SCRIPT SYNTAX
2129
2130 The syntax tries to mimic POSIX shell syntax. The syntax is defined
2131 by the following rules.
2132
2133 Lines starting with "#" and empty lines are ignored.
2134
2135 Lines that end with "\" are concatenated with the following line after
2136 removal of the final "\" and leading whitespace of the following line.
2137
2138 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
2139 expression) assign values to internal variables. See L</VARIABLES>
2140 section.
2141
2142 Otherwise, the first word on the line defines the meaning of the line.
2143 The following keywords are supported:
2144
2145 =over 4
2146
2147 =item C<load>
2148
2149 These lines represent modules to boot. The
2150 word after C<load> is a file name (relative to the build directory
2151 (see B<--build-dir>) of the module to load and the remaining words are
2152 passed to it as the command line parameters.
2153
2154 When booting Linux, the first C<load> line usually refers to the
2155 kernel image and its command line parameters (unless you use some
2156 special pre-loader). Other C<load> lines may refer to an initramfs
2157 image and/or a device tree blob. Their order is not important, as the
2158 device tree is recognized as the file name ending with C<.dtb>.
2159
2160 When the C<load> line ends with "<<WORD" then the subsequent lines
2161 until the line containing solely WORD are copied literally to the file
2162 named on that line. This is similar to the heredoc feature of UNIX
2163 shells.
2164
2165 When the C<load> line ends with "< CMD" then command CMD is executed
2166 with F</bin/sh> and its standard output is stored in the file named on
2167 that line. The SRCDIR variable in CMD's environment is set to the
2168 absolute path of the directory containing the interpreted novaboot
2169 script.
2170
2171 =item C<copy>
2172
2173 These lines are similar to C<load> lines. The
2174 file mentioned there is copied to the same place as in the case of C<load>
2175 (e.g. tftp server), but the file is not used in the bootloader
2176 configuration. Such a file can be used by the target for other
2177 purposes than booting, e.g. at OS runtime or for firmware update.
2178
2179 =item C<chld>
2180
2181 Chainload another bootloader. Instead of loading multiboot modules
2182 identified with C<load> keyword, run another bootloader. This is
2183 currently supported only by pulsar and can be used to load e.g. Grub
2184 as in the example below:
2185
2186  chld boot/grub/i386-pc/core.0
2187
2188
2189 =item C<run>
2190
2191 Lines starting with C<run> keyword contain shell commands that are run
2192 during file generation phase. This is the same as the "< CMD" syntax
2193 for C<load> keyboard except that the command's output is not
2194 redirected to a file. The ordering of commands is the same as they
2195 appear in the novaboot script.
2196
2197 =item C<uboot>
2198
2199 These lines represent U-Boot commands that are sent to the target if
2200 B<--uboot> option is given. Having a U-Boot line in the novaboot
2201 script is the same as giving B<--uboot-init> option to novaboot. The
2202 following syntax variants are supported:
2203
2204
2205   uboot[:<timeout>] <string> [> <file>]
2206   uboot[:<timeout>] < <shell> [> <file>]
2207
2208 C<string> is the literal U-Boot command.
2209
2210 The C<uboot> keyword can be suffixed with timeout specification. The
2211 syntax is C<uboot:Ns>, where C<N> is the whole number of seconds. If
2212 the U-Boot command prompt does not appear before the timeout, novaboot
2213 fails. The default timeout is 10 seconds.
2214
2215 In the second variant with the C<<> character the shell code is
2216 executed and its standard output is sent to U-Boot. Example:
2217
2218   uboot < printf "mmc write \$loadaddr 1 %x" $(($(/usr/bin/stat -c%s rootfs.ext4) / 512))
2219
2220 When C<E<gt> file> part is present, the output of the U-Boot command
2221 is written into the given file.
2222
2223 =back
2224
2225 Example (Linux):
2226
2227   #!/usr/bin/env novaboot
2228   load bzImage console=ttyS0,115200
2229   run  make -C buildroot
2230   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
2231
2232 Example (NOVA User Land - NUL):
2233
2234   #!/usr/bin/env novaboot
2235   WVDESC=Example program
2236   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
2237                            verbose hostkeyb:0,0x60,1,12,2
2238   load bin/apps/hello.nul
2239   load hello.nulconfig <<EOF
2240   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
2241   rom://bin/apps/hello.nul
2242   EOF
2243
2244 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
2245 F<hello.nulconfig>. sigma0 receives some command line parameters and
2246 F<hello.nulconfig> file is generated on the fly from the lines between
2247 C<<<EOF> and C<EOF>.
2248
2249 Example (Zynq system update via U-Boot):
2250
2251   #!/usr/bin/env novaboot
2252
2253   uboot dhcp
2254
2255   # Write kernel to FAT filesystem on the 1st SD card partition
2256   run mkimage -f uboot-image.its image.ub
2257   copy image.ub
2258   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/image.ub
2259   uboot fatwrite mmc 0:1 ${loadaddr} image.ub $filesize
2260   uboot set bootargs console=ttyPS0,115200 root=/dev/mmcblk0p2
2261
2262   # Write root FS image to the 2nd SD card partition
2263   copy rootfs/images/rootfs.ext4
2264   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/rootfs/images/rootfs.ext4
2265   uboot mmc part > mmc-part.txt
2266   uboot < printf "mmc write \$loadaddr %x %x" $(awk '{ if ($1 == "2") { print $2 }}' mmc-part.txt) $(($(/usr/bin/stat -L --printf=%s rootfs/images/rootfs.ext4) / 512))
2267
2268   UBOOT_CMD=boot
2269
2270
2271 =head2 VARIABLES
2272
2273 The following variables are interpreted in the novaboot script:
2274
2275 =over 8
2276
2277 =item BUILDDIR
2278
2279 Novaboot chdir()s to this directory before file generation phase. The
2280 directory name specified here is relative to the build directory
2281 specified by other means (see L</--build-dir>).
2282
2283 =item EXITON
2284
2285 Assigning this variable has the same effect as specifying L</--exiton>
2286 option.
2287
2288 =item INTERACTION
2289
2290 Setting this variable to zero is the same as giving
2291 L</--no-interaction>, specifying to one corresponds to
2292 L</--interaction>.
2293
2294 =item HYPERVISOR_PARAMS
2295
2296 Parameters passed to the hypervisor. The default value is "serial", unless
2297 overridden in the configuration file.
2298
2299 =item KERNEL
2300
2301 The kernel to use instead of the hypervisor specified in the
2302 configuration file with the C<$hypervisor> variable. The value should
2303 contain the name of the kernel image as well as its command line
2304 parameters. If this variable is defined and non-empty, the variable
2305 HYPERVISOR_PARAMS is not used.
2306
2307 =item NO_BOOT
2308
2309 If this variable is 1, the system is not booted. This is currently
2310 only implemented for U-Boot bootloader where it is useful for
2311 interacting with the bootloader without booting the system - e.g. for
2312 flashing.
2313
2314 =item QEMU
2315
2316 Use a specific qemu binary (can be overridden with B<-Q>) and flags
2317 when booting this script under qemu. If QEMU_FLAGS variable is also
2318 specified flags specified in QEMU variable are replaced by those in
2319 QEMU_FLAGS.
2320
2321 =item QEMU_FLAGS
2322
2323 Use specific qemu flags (can be overridden with B<-q>).
2324
2325 =item UBOOT_CMD
2326
2327 See L</--uboot-cmd>.
2328
2329 =item WVDESC
2330
2331 Description of the WvTest-compliant program.
2332
2333 =item WVTEST_TIMEOUT
2334
2335 The timeout in seconds for WvTest harness. If no complete line appears
2336 in the test output within the time specified here, the test fails. It
2337 is necessary to specify this for long running tests that produce no
2338 intermediate output.
2339
2340 =back
2341
2342 =head1 CONFIGURATION FILES
2343
2344 Novaboot can read its configuration from one or more files. By
2345 default, novaboot looks for files in F</etc/novaboot.d>, file
2346 F<~/.config/novaboot> and files named F<.novaboot> as described in
2347 L</Configuration reading phase>. Alternatively, configuration file
2348 location can be specified with the B<-c> switch or with the
2349 NOVABOOT_CONFIG environment variable. The configuration file has Perl
2350 syntax (i.e. it is better to put C<1;> as the last line) and should set
2351 values of certain Perl variables. The current configuration can be
2352 dumped with the B<--dump-config> switch. Some configuration variables
2353 can be overridden by environment variables (see below) or by command
2354 line switches.
2355
2356 Supported configuration variables include:
2357
2358 =over 8
2359
2360 =item $builddir
2361
2362 Build directory location relative to the location of the configuration
2363 file.
2364
2365 =item $default_target
2366
2367 Default target (see below) to use when no target is explicitly
2368 specified with the B<--target> command line option or
2369 B<NOVABOOT_TARGET> environment variable.
2370
2371 =item $netif
2372
2373 Default value for the B<--netif> option. If not specified, it defaults
2374 to I<eth0>.
2375
2376 =item %targets
2377
2378 Hash of target definitions to be used with the B<--target> option. The
2379 key is the identifier of the target, the value is the string with
2380 command line options. For instance, if the configuration file contains:
2381
2382  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
2383
2384 then the following two commands are equivalent:
2385
2386  ./myos --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
2387  ./myos -t mybox
2388
2389 =back
2390
2391 =head1 ENVIRONMENT VARIABLES
2392
2393 Some options can be specified not only via config file or command line
2394 but also through environment variables. Environment variables override
2395 the values from the configuration file and command line parameters
2396 override the environment variables.
2397
2398 =over 8
2399
2400 =item NOVABOOT_CONFIG
2401
2402 Name of the novaboot configuration file to use instead of the default
2403 one(s).
2404
2405 =item NOVABOOT_CONFIG_DIR
2406
2407 Name of the novaboot configuration directory. When not specified
2408 F</etc/novaboot.d> is used.
2409
2410 =item NOVABOOT_TARGET
2411
2412 Name of the novaboot target to use. This overrides the value of
2413 B<$default_target> from the configuration file and can be overridden
2414 with the B<--target> command line option.
2415
2416 =item NOVABOOT_BENDER
2417
2418 Defining this variable has the same effect as using B<--bender>
2419 option.
2420
2421 =back
2422
2423 =head1 AUTHORS
2424
2425 Michal Sojka <sojka@os.inf.tu-dresden.de>
2426
2427 Latest novaboot version can be found at
2428 L<https://github.com/wentasah/novaboot>.
2429
2430 =cut
2431
2432 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2433 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2434 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2435 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest