novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 use strict;
  17 use warnings;
  18 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  19 use Getopt::Long qw(GetOptionsFromString);
  20 use Pod::Usage;
  21 use File::Basename;
  22 use File::Spec;
  23 use IO::Handle;
  24 use Time::HiRes("usleep");
  25 use Socket;
  26 use FileHandle;
  27 use IPC::Open2;
  28 use POSIX qw(:errno_h);
  29 use Cwd qw(getcwd abs_path);
  30 use Expect;
  31
  32 # always flush
  33 $| = 1;
  34
  35 my $invocation_dir = $ENV{PWD} || getcwd();
  36
  37 ## Configuration file handling
  38
  39 # Default configuration
  40 $CFG::hypervisor = "";
  41 $CFG::hypervisor_params = "serial";
  42 $CFG::genisoimage = "genisoimage";
  43 $CFG::qemu = 'qemu -cpu coreduo -smp 2';
  44 $CFG::default_target = 'qemu';
  45 %CFG::targets = (
  46     'qemu' => '--qemu',
  47     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  48     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.86.92:2324',
  49     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  50     "ryuglab" => '--server=pc-sojkam.felk.cvut.cz:/srv/tftp --uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --remote-cmd="ssh -t pc-sojkam.felk.cvut.cz \"cu -l /dev/ttyUSB0 -s 115200\"" --remote-expect="Connected." --reset-cmd="ssh -t pc-sojkam.felk.cvut.cz \"dtrrts /dev/ttyUSB0 1 1\""',
  51     "ryulocal" => '--dhcp-tftp --serial --uboot --uboot-init="dhcp; mw f0000b00 \${psc_cfg}; sleep 1" --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  52
  53     );
  54 chomp(my $nproc = `nproc`);
  55 $CFG::scons = "scons -j$nproc";
  56 $CFG::make = "make -j$nproc";
  57
  58 my $builddir;
  59
  60 sub read_config($) {
  61     my ($cfg) = @_;
  62     {
  63         package CFG; # Put config data into a separate namespace
  64         my $rc = do($cfg);
  65
  66         # Check for errors
  67         if ($@) {
  68             die("ERROR: Failure compiling '$cfg' - $@");
  69         } elsif (! defined($rc)) {
  70             die("ERROR: Failure reading '$cfg' - $!");
  71         } elsif (! $rc) {
  72             die("ERROR: Failure processing '$cfg'");
  73         }
  74     }
  75     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  76     print STDERR "novaboot: Read $cfg\n";
  77 }
  78
  79 my @cfgs;
  80 {
  81     # We don't use $0 here, because it points to the novaboot itself and
  82     # not to the novaboot script. The problem with this approach is that
  83     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  84     # contains the first option. Hence the -f check.
  85     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  86     while ((-d $dir || -l $dir ) && $dir ne "/") {
  87         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  88         my @dirs = File::Spec->splitdir($dir);
  89         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  90     }
  91 }
  92 my $cfg = $ENV{'NOVABOOT_CONFIG'};
  93 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
  94 GetOptions ("config|c=s" => \$cfg);
  95 read_config($_) foreach $cfg or reverse @cfgs;
  96
  97 ## Command line handling
  98
  99 my $explicit_target;
 100 GetOptions ("target|t=s" => \$explicit_target);
 101
 102 my ($append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $iprelay, $iso_image, $make, $man, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $reset_cmd, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $uboot, $uboot_init);
 103
 104 $rsync_flags = '';
 105 $rom_prefix = 'rom://';
 106 $stty = 'raw -crtscts -onlcr 115200';
 107
 108 Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 109 my %opt_spec;
 110 %opt_spec = (
 111     "append|a=s"     => \$append,
 112     "bender|b"       => \$bender,
 113     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 114     "concat"         => \$concat,
 115     "chainloader=s"  => \@chainloaders,
 116     "dhcp-tftp|d"    => \$dhcp_tftp,
 117     "dump"           => \$dump_opt,
 118     "dump-config"    => \$dump_config,
 119     "exiton=s"       => \@exiton,
 120     "gen-only"       => \$gen_only,
 121     "grub|g:s"       => \$grub_config,
 122     "grub-preamble=s"=> \$grub_preamble,
 123     "grub-prefix=s"  => \$grub_prefix,
 124     "grub2:s"        => \$grub2_config,
 125     "grub2-prolog=s" => \$grub2_prolog,
 126     "iprelay=s"      => \$iprelay,
 127     "iso:s"          => \$iso_image,
 128     "name=s"         => \$config_name_opt,
 129     "make|m:s"       => \$make,
 130     "no-file-gen"    => \$no_file_gen,
 131     "off"            => \$off_opt,
 132     "on"             => \$on_opt,
 133     "pulsar|p:s"     => \$pulsar,
 134     "pulsar-root=s"  => \$pulsar_root,
 135     "qemu|Q:s"       => \$qemu,
 136     "qemu-append=s"  => \$qemu_append,
 137     "qemu-flags|q=s" => \$qemu_flags_cmd,
 138     "remote-cmd=s"   => \$remote_cmd,
 139     "remote-expect=s"=> \$remote_expect,
 140     "reset-cmd=s"    => \$reset_cmd,
 141     "rsync-flags=s"  => \$rsync_flags,
 142     "scons:s"        => \$scons,
 143     "scriptmod=s"    => \@scriptmod,
 144     "serial|s:s"     => \$serial,
 145     "server:s"       => \$server,
 146     "strip-rom"      => sub { $rom_prefix = ''; },
 147     "stty=s"         => \$stty,
 148     "uboot"          => \$uboot,
 149     "uboot-init=s"   => \$uboot_init,
 150     "h"              => \$help,
 151     "help"           => \$man,
 152     );
 153
 154 # First process target options
 155 {
 156     my $t = $explicit_target || $CFG::default_target;
 157     exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 158     GetOptionsFromString($CFG::targets{$t}, %opt_spec);
 159 }
 160
 161 # Then process other command line options - some of them may override
 162 # what was specified by the target
 163 GetOptions %opt_spec or die("Error in command line arguments");
 164 pod2usage(1) if $help;
 165 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 166
 167 ### Dump sanitized configuration (if requested)
 168
 169 if ($dump_config) {
 170     use Data::Dumper;
 171     $Data::Dumper::Indent=1;
 172     print "# This file is in perl syntax.\n";
 173     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 174         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 175         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 176         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 177     }
 178     print "1;\n";
 179     exit;
 180 }
 181
 182 ### Sanitize configuration
 183
 184 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 185
 186 # Default options
 187 if (defined $serial) {
 188     $serial ||= "/dev/ttyUSB0";
 189     $ENV{NB_SERIAL} = $serial;
 190 }
 191 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 192 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 193
 194 ## Parse the novaboot script(s)
 195 my @scripts;
 196 my $file;
 197 my $line;
 198 my $EOF;
 199 my $last_fn = '';
 200 my ($modules, $variables, $generated, $continuation);
 201 while (<>) {
 202     if ($ARGV ne $last_fn) { # New script
 203         die "Missing EOF in $last_fn" if $file;
 204         die "Unfinished line in $last_fn" if $line;
 205         $last_fn = $ARGV;
 206         push @scripts, { 'filename' => $ARGV,
 207                          'modules' => $modules = [],
 208                          'variables' => $variables = {},
 209                          'generated' => $generated = []};
 210
 211     }
 212     chomp();
 213     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 214
 215     foreach my $mod(@scriptmod) { eval $mod; }
 216
 217     print "$_\n" if $dump_opt;
 218
 219     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 220         $$variables{$1} = $2;
 221         push(@exiton, $2) if ($1 eq "EXITON");
 222         next;
 223     }
 224     if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 225         push @$modules, "$1$2";
 226         $file = [];
 227         push @$generated, {filename => $1, content => $file};
 228         $EOF = $3;
 229         next;
 230     }
 231     if ($file && $_ eq $EOF) {  # Heredoc end
 232         undef $file;
 233         next;
 234     }
 235     if ($file) {                # Heredoc content
 236         push @{$file}, "$_\n";
 237         next;
 238     }
 239     $_ =~ s/^[[:space:]]*// if ($continuation);
 240     if (/\\$/) {                # Line continuation
 241         $line .= substr($_, 0, length($_)-1);
 242         $continuation = 1;
 243         next;
 244     }
 245     $continuation = 0;
 246     $line .= $_;
 247     $line .= " $append" if ($append && scalar(@$modules) == 0);
 248
 249     if ($line =~ /^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 250         push @$modules, "$1$2";
 251         push @$generated, {filename => $1, command => $3};
 252         $line = '';
 253         next;
 254     }
 255     push @$modules, $line;
 256     $line = '';
 257 }
 258 #use Data::Dumper;
 259 #print Dumper(\@scripts);
 260
 261 exit if $dump_opt;
 262
 263 ## Helper functions
 264
 265 sub generate_configs($$$) {
 266     my ($base, $generated, $filename) = @_;
 267     if ($base) { $base = "$base/"; };
 268     foreach my $g(@$generated) {
 269       if (exists $$g{content}) {
 270         my $config = $$g{content};
 271         my $fn = $$g{filename};
 272         open(my $f, '>', $fn) || die("$fn: $!");
 273         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 274         close($f);
 275         print "novaboot: Created $fn\n";
 276       } elsif (exists $$g{command} && ! $no_file_gen) {
 277         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 278         system_verbose("( $$g{command} ) > $$g{filename}");
 279       }
 280     }
 281 }
 282
 283 sub generate_grub_config($$$$;$)
 284 {
 285     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 286     if ($base) { $base = "$base/"; };
 287     open(my $fg, '>', $filename) or die "$filename: $!";
 288     print $fg "$preamble\n" if $preamble;
 289     print $fg "title $title\n" if $title;
 290     #print $fg "root $base\n"; # root doesn't really work for (nd)
 291     my $first = 1;
 292     foreach (@$modules_ref) {
 293         if ($first) {
 294             $first = 0;
 295             my ($kbin, $kcmd) = split(' ', $_, 2);
 296             $kcmd = '' if !defined $kcmd;
 297             print $fg "kernel ${base}$kbin $kcmd\n";
 298         } else {
 299             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 300             print $fg "module $base$_\n";
 301         }
 302     }
 303     close($fg);
 304     print("novaboot: Created $builddir/$filename\n");
 305     return $filename;
 306 }
 307
 308 sub generate_grub2_config($$$$;$$)
 309 {
 310     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 311     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 312     open(my $fg, '>', $filename) or die "$filename: $!";
 313     print $fg "$preamble\n" if $preamble;
 314     $title ||= 'novaboot';
 315     print $fg "menuentry $title {\n";
 316     print $fg "$prolog\n" if $prolog;
 317     my $first = 1;
 318     foreach (@$modules_ref) {
 319         if ($first) {
 320             $first = 0;
 321             my ($kbin, $kcmd) = split(' ', $_, 2);
 322             $kcmd = '' if !defined $kcmd;
 323             print $fg "  multiboot ${base}$kbin $kcmd\n";
 324         } else {
 325             my @args = split;
 326             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 327             $_ = join(' ', ($args[0], @args));
 328             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 329             print $fg "  module $base$_\n";
 330         }
 331     }
 332     print $fg "}\n";
 333     close($fg);
 334     print("novaboot: Created $builddir/$filename\n");
 335     return $filename;
 336 }
 337
 338 sub generate_pulsar_config($$)
 339 {
 340     my ($filename, $modules_ref) = @_;
 341     open(my $fg, '>', $filename) or die "$filename: $!";
 342     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 343     my $first = 1;
 344     my ($kbin, $kcmd);
 345     foreach (@$modules_ref) {
 346         if ($first) {
 347             $first = 0;
 348             ($kbin, $kcmd) = split(' ', $_, 2);
 349             $kcmd = '' if !defined $kcmd;
 350         } else {
 351             my @args = split;
 352             s|\brom://|$rom_prefix|g;
 353             print $fg "load $_\n";
 354         }
 355     }
 356     # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 357     print $fg "exec $kbin $kcmd\n";
 358     close($fg);
 359     print("novaboot: Created $builddir/$filename\n");
 360     return $filename;
 361 }
 362
 363 sub shell_cmd_string(@)
 364 {
 365     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 366 }
 367
 368 sub exec_verbose(@)
 369 {
 370     print "novaboot: Running: ".shell_cmd_string(@_)."\n";
 371     exec(@_);
 372 }
 373
 374 sub system_verbose($)
 375 {
 376     my $cmd = shift;
 377     print "novaboot: Running: $cmd\n";
 378     my $ret = system($cmd);
 379     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 380     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 381     if ($ret) { die("Command failure $ret"); }
 382 }
 383
 384 ## WvTest handline
 385
 386 if (exists $variables->{WVDESC}) {
 387     print "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 388 } elsif ($last_fn =~ /\.wv$/) {
 389     print "Testing \"all\" in $last_fn:\n";
 390 }
 391
 392 ## Connect to the target and check whether is not occupied
 393
 394 # We have to do this before file generation phase, because file
 395 # generation is intermixed with file deployment phase and we want to
 396 # check whether the target is not used by somebody else before
 397 # deploying files. Otherwise, we may rewrite other user's files on a
 398 # boot server.
 399
 400 my $exp; # Expect object to communicate with the target over serial line
 401
 402 my ($target_reset, $target_power_on, $target_power_off);
 403
 404 if (defined $iprelay) {
 405     my $IPRELAY;
 406     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 407     my $addr = $1;
 408     my $port = $3 || 23;
 409     my $paddr   = sockaddr_in($port, inet_aton($addr));
 410     my $proto   = getprotobyname('tcp');
 411     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 412     print "novaboot: Connecting to IP relay... ";
 413     connect($IPRELAY, $paddr)    || die "connect: $!";
 414     print "done\n";
 415     $exp = Expect->init(\*$IPRELAY);
 416     $exp->log_stdout(1);
 417
 418     while (1) {
 419         print $exp "\xFF\xF6";  # AYT
 420         my $connected = $exp->expect(20, # Timeout in seconds
 421                                      '<iprelayd: connected>',
 422                                      '-re', '<WEB51 HW[^>]*>');
 423         last if $connected;
 424     }
 425
 426     sub relaycmd($$) {
 427         my ($relay, $onoff) = @_;
 428         die unless ($relay == 1 || $relay == 2);
 429
 430         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 431         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 432     }
 433
 434     sub relayconf($$) {
 435         my ($relay, $onoff) = @_;
 436         die unless ($relay == 1 || $relay == 2);
 437         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 438         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 439     }
 440
 441     sub relay($$;$) {
 442         my ($relay, $onoff, $can_giveup) = @_;
 443         my $confirmation = '';
 444         $exp->log_stdout(0);
 445         print $exp relaycmd($relay, $onoff);
 446         my $confirmed = $exp->expect(20, # Timeout in seconds
 447                                      relayconf($relay, $onoff));
 448         if (!$confirmed) {
 449             if ($can_giveup) {
 450                 print("Relay confirmation timeout - ignoring\n");
 451             } else {
 452                 die "Relay confirmation timeout";
 453             }
 454         }
 455         $exp->log_stdout(1);
 456     }
 457
 458     $target_reset = sub {
 459         relay(2, 1, 1); # Reset the machine
 460         usleep(100000);
 461         relay(2, 0);
 462     };
 463
 464     $target_power_off = sub {
 465         relay(1, 1);            # Press power button
 466         usleep(6000000);        # Long press to switch off
 467         relay(1, 0);
 468     };
 469
 470     $target_power_on = sub {
 471         relay(1, 1);            # Press power button
 472         usleep(100000);         # Short press
 473         relay(1, 0);
 474     };
 475 }
 476 elsif ($serial) {
 477     my $CONN;
 478     system_verbose("stty -F $serial $stty");
 479     open($CONN, "+<", $serial) || die "open $serial: $!";
 480     $exp = Expect->init(\*$CONN);
 481 } elsif ($remote_cmd) {
 482     print "novaboot: Running: $remote_cmd\n";
 483     $exp = Expect->spawn($remote_cmd);
 484 }
 485
 486 if ($remote_expect) {
 487     $exp->expect(10, $remote_expect) || die "Expect for '$remote_expect' timed out";
 488 }
 489
 490 if (defined $reset_cmd) {
 491     $target_reset = sub {
 492         system_verbose($reset_cmd);
 493     };
 494 }
 495
 496 if (defined $on_opt && defined $target_power_on) {
 497     &$target_power_on();
 498     exit;
 499 }
 500 if (defined $off_opt && defined $target_power_off) {
 501     print "novaboot: Switching the target off...\n";
 502     &$target_power_off();
 503     exit;
 504 }
 505
 506 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 507 if (defined $builddir) {
 508     chdir($builddir) or die "Can't change directory to $builddir: $!";
 509     print "novaboot: Entering directory `$builddir'\n";
 510 }
 511
 512 ## File generation phase
 513 my (%files_iso, $menu_iso, $filename);
 514 my $config_name = '';
 515
 516 foreach my $script (@scripts) {
 517     $filename = $$script{filename};
 518     $modules = $$script{modules};
 519     $generated = $$script{generated};
 520     $variables = $$script{variables};
 521
 522     ($config_name = $filename) =~ s#.*/##;
 523     $config_name = $config_name_opt if (defined $config_name_opt);
 524
 525     if (exists $variables->{BUILDDIR}) {
 526         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 527         chdir($builddir) or die "Can't change directory to $builddir: $!";
 528         print "novaboot: Entering directory `$builddir'\n";
 529     }
 530
 531     my $kernel;
 532     if (exists $variables->{KERNEL}) {
 533         $kernel = $variables->{KERNEL};
 534     } else {
 535         if ($CFG::hypervisor) {
 536             $kernel = $CFG::hypervisor . " ";
 537             if (exists $variables->{HYPERVISOR_PARAMS}) {
 538                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 539             } else {
 540                 $kernel .= $CFG::hypervisor_params;
 541             }
 542         }
 543     }
 544     @$modules = ($kernel, @$modules) if $kernel;
 545     @$modules = (@chainloaders, @$modules);
 546     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 547
 548     my $prefix;
 549     ($prefix = $grub_prefix) =~ s/\$NAME/$config_name/ if defined $grub_prefix;
 550     $prefix ||= $builddir;
 551     # TODO: use $grub_prefix as first parameter if some switch is given
 552     generate_configs('', $generated, $filename);
 553
 554 ### Generate bootloader configuration files
 555     my @bootloader_configs;
 556     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 557     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 558     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules) if (defined $pulsar);
 559
 560 ### Run scons or make
 561     {
 562         my @files = map({ ($file) = m/([^ ]*)/; $file; } @$modules);
 563         # Filter-out generated files
 564         my @to_build = grep({ my $file = $_; !scalar(grep($file eq $$_{filename}, @$generated)) } @files);
 565
 566         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 567         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 568     }
 569
 570 ### Copy files (using rsync)
 571     if (defined $server && !defined($gen_only)) {
 572         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 573
 574         my ($hostname, $path) = split(":", $real_server, 2);
 575         if (! defined $path) {
 576             $path = $hostname;
 577             $hostname = "";
 578         }
 579         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs)));
 580         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 581         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 582         my $progress = $istty ? "--progress" : "";
 583         system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 584         if ($server =~ m|/\$NAME$| && $concat) {
 585             my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 586             system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 587         }
 588     }
 589
 590 ### Prepare ISO image generation
 591     if (defined $iso_image) {
 592         generate_configs("(cd)", $generated, $filename);
 593         my $menu;
 594         generate_grub_config(\$menu, $config_name, "(cd)", $modules);
 595         $menu_iso .= "$menu\n";
 596         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 597     }
 598 }
 599
 600 ## Generate ISO image
 601 if (defined $iso_image) {
 602     open(my $fh, ">menu-iso.lst");
 603     print $fh "timeout 5\n\n$menu_iso";
 604     close($fh);
 605     my $files = "boot/grub/menu.lst=menu-iso.lst " . join(" ", map("$_=$_", keys(%files_iso)));
 606     $iso_image ||= "$config_name.iso";
 607     system_verbose("$CFG::genisoimage -R -b stage2_eltorito -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -J -joliet-long -o $iso_image -graft-points bin/boot/grub/ $files");
 608     print("ISO image created: $builddir/$iso_image\n");
 609 }
 610
 611 exit(0) if defined $gen_only;
 612
 613 ## Boot the system using various methods and send serial output to stdout
 614
 615 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 616     die "You cannot do this with multiple scripts simultaneously";
 617 }
 618
 619 if ($variables->{WVTEST_TIMEOUT}) {
 620     print "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 621 }
 622
 623 sub trim($) {
 624     my ($str) = @_;
 625     $str =~ s/^\s+|\s+$//g;
 626     return $str
 627 }
 628
 629 ### Qemu
 630
 631 if (defined $qemu) {
 632     # Qemu
 633     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 634     my @qemu_flags = split(" ", $qemu);
 635     $qemu = shift(@qemu_flags);
 636
 637     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 638     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 639     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 640
 641     if (defined $iso_image) {
 642         # Boot NOVA with grub (and test the iso image)
 643         push(@qemu_flags, ('-cdrom', "$config_name.iso"));
 644     } else {
 645         # Boot NOVA without GRUB
 646
 647         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 648         foreach (@$modules) {s/,/+/g;}
 649         generate_configs("", $generated, $filename);
 650
 651         if (scalar @$modules) {
 652             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 653             $kcmd = '' if !defined $kcmd;
 654             my $dtb;
 655             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 656             my $initrd = join ",", @$modules;
 657
 658             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
 659             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
 660             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
 661         }
 662     }
 663     push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
 664     unshift(@qemu_flags, ('-name', $config_name));
 665     print "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
 666     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
 667 }
 668
 669 ### Local DHCPD and TFTPD
 670
 671 my ($dhcpd_pid, $tftpd_pid);
 672
 673 if (defined $dhcp_tftp)
 674 {
 675     generate_configs("(nd)", $generated, $filename);
 676     system_verbose('mkdir -p tftpboot');
 677     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
 678     open(my $fh, '>', 'dhcpd.conf');
 679     my $mac = `cat /sys/class/net/eth0/address`;
 680     chomp $mac;
 681     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
 682                       range 10.23.23.10 10.23.23.100;
 683                       filename \"bin/boot/grub/pxegrub.pxe\";
 684                       next-server 10.23.23.1;
 685 }
 686 host server {
 687         hardware ethernet $mac;
 688         fixed-address 10.23.23.1;
 689 }";
 690     close($fh);
 691     system_verbose("sudo ip a add 10.23.23.1/24 dev eth0;
 692             sudo ip l set dev eth0 up;
 693             sudo touch dhcpd.leases");
 694
 695     # We run servers by forking ourselves, because the servers end up
 696     # in our process group and get killed by signals sent to the
 697     # process group (e.g. Ctrl-C on terminal).
 698     $dhcpd_pid = fork();
 699     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
 700     $tftpd_pid = fork();
 701     exec_verbose("sudo in.tftpd --foreground --secure -v -v -v --pidfile tftpd.pid $builddir") if ($tftpd_pid == 0);
 702
 703     # Kill server when we die
 704     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid');
 705                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
 706 }
 707
 708 ### Serial line or IP relay
 709
 710 if (defined $target_reset) {
 711     print "novaboot: Reseting the test box... ";
 712     &$target_reset();
 713     print "done\n";
 714 }
 715
 716 if (defined $uboot) {
 717     print "novaboot: Waiting for uBoot prompt...\n";
 718     $exp->log_stdout(1);
 719     $exp->expect(20,
 720                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
 721                  '=> ') || die "No uBoot prompt deteceted";
 722     $exp->send("$uboot_init\n") if $uboot_init;
 723     $exp->expect(10, '=> ') || die "uBoot prompt timeout";
 724
 725     my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 726     my $dtb;
 727     @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 728     my $initrd = shift @$modules;
 729
 730     my $kern_addr = '800000';
 731     my $initrd_addr = '-';
 732     my $dtb_addr = '';
 733
 734     $exp->send("tftp $kern_addr $kbin\n");
 735     $exp->expect(10,
 736                  [qr/#/, sub { exp_continue; }],
 737                  '=> ') || die "Kernel load failed";
 738     if (defined $dtb) {
 739         $dtb_addr = '7f0000';
 740         $exp->send("tftp $dtb_addr $dtb\n");
 741         $exp->expect(10,
 742                      [qr/#/, sub { exp_continue; }],
 743                      '=> ') || die "Device tree load failed";
 744     }
 745     if (defined $initrd) {
 746         $initrd_addr = 'b00000';
 747         $exp->send("tftp $initrd_addr $initrd\n");
 748         $exp->expect(10,
 749                      [qr/#/, sub { exp_continue; }],
 750                      '=> ') || die "Initrd load failed";
 751     }
 752     $exp->send("set bootargs $kcmd\n");
 753     $exp->expect(1, '=> ')  || die "uBoot prompt timeout";
 754     $exp->send("bootm $kern_addr $initrd_addr $dtb_addr\n");
 755     $exp->expect(1, "\n")  || die "uBoot command timeout";
 756 }
 757
 758 if (defined $exp) {
 759     # Serial line of the target is available
 760     print "novaboot: Serial line interaction (press Ctrl-C to interrupt)...\n";
 761     $exp->log_stdout(1);
 762     if (@exiton) {
 763         $exp->expect(undef, @exiton);
 764     } else {
 765         my @inputs = ($exp);
 766         if (-t STDIN) { # Set up bi-directional communication if we run on terminal
 767             my $infile = new IO::File;
 768             $infile->IO::File::fdopen(*STDIN,'r');
 769             my $in_object = Expect->exp_init($infile);
 770             $in_object->set_group($exp);
 771             #$in_object->set_seq("\cC",undef);
 772
 773             # I'm not sure when to use raw mode and when not. With
 774             # --dhcp-tftp, I want the output of daemons to be normally
 775             # formated (no raw mode). On the other hand, I don't want
 776             # input for qemu to be echoed. Need to think more about this.
 777             $in_object->manual_stty(1);
 778             push(@inputs, $in_object);
 779         }
 780         Expect::interconnect(@inputs);
 781     }
 782 }
 783
 784 ## Kill dhcpc or tftpd
 785 if (defined $dhcp_tftp) {
 786     die("novaboot: This should kill servers on background\n");
 787 }
 788
 789 ## Documentation
 790
 791 =head1 NAME
 792
 793 novaboot - A tool for booting various operating systems on various hardware or in qemu
 794
 795 =head1 SYNOPSIS
 796
 797 B<novaboot> [ options ] [--] script...
 798
 799 B<./script> [ options ]
 800
 801 =head1 DESCRIPTION
 802
 803 This program makes it easier to boot NOVA or other operating system
 804 (OS) on different targets (machines or emulators). It reads a so
 805 called novaboot script, that specifies the boot configuration, and
 806 setups the target to boot that configuration. Setting up the target
 807 means to generate the bootloader configuration files, deploy the
 808 binaries and other needed files to proper locations, perhaps on a
 809 remote boot server and reset the target. Then, target's serial output
 810 is redirected to standard output if that is possible.
 811
 812 A typical way of using novaboot is to make the novaboot script
 813 executable and set its first line to I<#!/usr/bin/env novaboot>. Then,
 814 booting a particular OS configuration becomes the same as executing a
 815 local program - the novaboot script.
 816
 817 For example, with C<novaboot> you can:
 818
 819 =over 3
 820
 821 =item 1.
 822
 823 Run an OS in Qemu. This is the default action when no other action is
 824 specified by command line switches. Thus running C<novaboot ./script>
 825 (or C<./script> as described above) will run Qemu and make it boot the
 826 configuration specified in the I<script>.
 827
 828 =item 2.
 829
 830 Create a bootloader configuration file (currently supported
 831 bootloaders are GRUB, GRUB2, Pulsar and uBoot) and copy it with all
 832 other files needed for booting to another, perhaps remote, location.
 833
 834  ./script --server=192.168.1.1:/tftp --iprelay=192.168.1.2
 835
 836 This command copies files to the TFTP server and uses
 837 TCP/IP-controlled relay to reset the test box and receive its serial
 838 output.
 839
 840 =item 3.
 841
 842 Run DHCP and TFTP server on developer's machine to PXE-boot the OS
 843 from it. E.g.
 844
 845  ./script --dhcp-tftp
 846
 847 When a PXE-bootable machine is connected via Ethernet to developer's
 848 machine, it will boot the configuration described in I<script>.
 849
 850 =item 4.
 851
 852 Create bootable ISO images. E.g.
 853
 854  novaboot --iso -- script1 script2
 855
 856 The created ISO image will have GRUB bootloader installed on it and
 857 the boot menu will allow selecting between I<script1> and I<script2>
 858 configurations.
 859
 860 =back
 861
 862 Note that the options needed for a specific target can be stored in a
 863 L</"CONFIGURATION FILE"> and then it is sufficient to use only the
 864 B<-t> option to specify the name of the target.
 865
 866 =head1 PHASES AND OPTIONS
 867
 868 Novaboot performs its work in several phases. Each phase can be
 869 influenced by several options, certain phases can be skipped. The list
 870 of phases (in the execution order) and the corresponding options
 871 follow.
 872
 873 =head2 Configuration reading phase
 874
 875 After starting, novaboot reads configuration files. By default, it
 876 searches for files named F<.novaboot> starting from the directory of
 877 the novaboot script (or working directory, see bellow) and continuing
 878 upwards up to the root directory. The configuration files are read in
 879 order from the root directory downwards with latter files overriding
 880 settings from the former ones.
 881
 882 In certain cases, the location of the novaboot script cannot be
 883 determined in this early phase. This happens either when the script is
 884 read from the standard input or when novaboot is invoked explicitly
 885 and options precede the script name, as in the example L</"4."> above.
 886 In this case the current working directory is used as a starting point
 887 for configuration file search.
 888
 889 =over 8
 890
 891 =item -c, --config=I<filename>
 892
 893 Use the specified configuration file instead of the default one(s).
 894
 895 =back
 896
 897 =head2 Command line processing phase
 898
 899 =over 8
 900
 901 =item --dump-config
 902
 903 Dump the current configuration to stdout end exits. Useful as an
 904 initial template for a configuration file.
 905
 906 =item -h, --help
 907
 908 Print short (B<-h>) or long (B<--help>) help.
 909
 910 =item -t, --target=I<target>
 911
 912 This option serves as a user configurable shortcut for other novaboot
 913 options. The effect of this option is the same as the options stored
 914 in the C<%targets> configuration variable under key I<target>. See
 915 also L</"CONFIGURATION FILE">.
 916
 917 =back
 918
 919 =head2 Script preprocessing phase
 920
 921 This phases allows to modify the parsed novaboot script before it is
 922 used in the later phases.
 923
 924 =over 8
 925
 926 =item -a, --append=I<parameters>
 927
 928 Appends a string to the first "filename" line in the novaboot script.
 929 This can be used to append parameters to the kernel's or root task's
 930 command line.
 931
 932 =item -b, --bender
 933
 934 Use F<bender> chainloader. Bender scans the PCI bus for PCI serial
 935 ports and stores the information about them in the BIOS data area for
 936 use by the kernel.
 937
 938 =item --chainloader=I<chainloader>
 939
 940 Chainloader that is loaded before the kernel and other files specified
 941 in the novaboot script. E.g. 'bin/boot/bender promisc'.
 942
 943 =item --dump
 944
 945 Prints the content of the novaboot script after removing comments and
 946 evaluating all I<--scriptmod> expressions. Exit after reading (and
 947 dumping) the script.
 948
 949 =item --scriptmod=I<perl expression>
 950
 951 When novaboot script is read, I<perl expression> is executed for every
 952 line (in $_ variable). For example, C<novaboot
 953 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
 954 in the script with I<omega6>.
 955
 956 When this option is present, it overrides I<$script_modifier> variable
 957 from the configuration file, which has the same effect. If this option
 958 is given multiple times all expressions are evaluated in the command
 959 line order.
 960
 961 =item --strip-rom
 962
 963 Strip I<rom://> prefix from command lines and generated config files.
 964 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
 965
 966 =back
 967
 968 =head2 File generation phase
 969
 970 In this phase, files needed for booting are generated in a so called
 971 I<build directory> (see TODO). In most cases configuration for a
 972 bootloader is generated automatically by novaboot. It is also possible
 973 to generate other files using I<heredoc> or I<"<"> syntax in novaboot
 974 scripts. Finally, binaries can be generated in this phases by running
 975 C<scons> or C<make>.
 976
 977 =over 8
 978
 979 =item --build-dir=I<directory>
 980
 981 Overrides the default build directory location.
 982
 983 The default build directory location is determined as follows: If the
 984 configuration file defines the C<$builddir> variable, its value is
 985 used. Otherwise, it is the directory that contains the first processed
 986 novaboot script.
 987
 988 =item -g, --grub[=I<filename>]
 989
 990 Generates grub bootloader menu file. If the I<filename> is not
 991 specified, F<menu.lst> is used. The I<filename> is relative to the
 992 build directory (see B<--build-dir>).
 993
 994 =item --grub-preamble=I<prefix>
 995
 996 Specifies the I<preable> that is at the beginning of the generated
 997 GRUB or GRUB2 config files. This is useful for specifying GRUB's
 998 timeout.
 999
1000 =item --grub-prefix=I<prefix>
1001
1002 Specifies I<prefix> that is put in front of every file name in GRUB's
1003 F<menu.lst>. The default value is the absolute path to the build directory.
1004
1005 If the I<prefix> contains string $NAME, it will be replaced with the
1006 name of the novaboot script (see also B<--name>).
1007
1008 =item --grub2[=I<filename>]
1009
1010 Generate GRUB2 menuentry in I<filename>. If I<filename> is not
1011 specified F<grub.cfg> is used. The content of the menuentry can be
1012 customized with B<--grub-preable>, B<--grub2-prolog> or
1013 B<--grub_prefix> options.
1014
1015 In order to use the the generated menuentry on your development
1016 machine that uses GRUB2, append the following snippet to
1017 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1018 i.e. run update-grub on Debian/Ubuntu.
1019
1020   if [ -f /path/to/nul/build/grub.cfg ]; then
1021     source /path/to/nul/build/grub.cfg
1022   fi
1023
1024 =item --grub2-prolog=I<prolog>
1025
1026 Specifies text I<preable> that is put at the beginning of the entry
1027 GRUB2 entry.
1028
1029 =item -m, --make[=make command]
1030
1031 Runs C<make> to build files that are not generated by novaboot itself.
1032
1033 =item --name=I<string>
1034
1035 Use the name I<string> instead of the name of the novaboot script.
1036 This name is used for things like a title of grub menu or for the
1037 server directory where the boot files are copied to.
1038
1039 =item --no-file-gen
1040
1041 Do not generate files on the fly (i.e. "<" syntax) except for the
1042 files generated via "<<WORD" syntax.
1043
1044 =item -p, --pulsar[=mac]
1045
1046 Generates pulsar bootloader configuration file named F<config-I<mac>>
1047 The I<mac> string is typically a MAC address and defaults to
1048 I<novaboot>.
1049
1050 =item --scons[=scons command]
1051
1052 Runs C<scons> to build files that are not generated by novaboot
1053 itself.
1054
1055 =item --gen-only
1056
1057 Exit novaboot after file generation phase.
1058
1059 =back
1060
1061 =head2 Target connection check
1062
1063 If supported by the target, the connection to it is made and it is
1064 checked whether the target is not occupied by another novaboot
1065 user/instance.
1066
1067 =over 8
1068
1069 =item --iprelay=I<addr[:port]>
1070
1071 Use TCP/IP relay and serial port to access the target's serial port
1072 and powercycle it. The IP address of the relay is given by I<addr>
1073 parameter. If I<port> is not specified, it default to 23.
1074
1075 Note: This option is supposed to work with HWG-ER02a IP relays.
1076
1077 =item -s, --serial[=device]
1078
1079 Target's serial line is connected to host's serial line (device). The
1080 default value for device is F</dev/ttyUSB0>.
1081
1082 The value of this option is exported in NB_NOVABOOT environment
1083 variable to all subprocesses run by C<novaboot>.
1084
1085 =item --stty=I<settings>
1086
1087 Specifies settings passed to C<stty> invoked on the serial line
1088 specified with B<--serial> option. If this option is not given,
1089 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1090
1091 =item --remote-cmd=I<cmd>
1092
1093 Command that mediates connection to the target's serial line. For
1094 example C<ssh server 'cu -l /dev/ttyS0'>.
1095
1096 =item --remote-expect=I<string>
1097
1098 Wait for reception of I<string> on the remote connection before
1099 continuing.
1100
1101 =back
1102
1103 =head2 File deployment phase
1104
1105 In some setups, it is necessary to copy the files needed for booting
1106 to a particular location, e.g. to a TFTP boot server or to the
1107 F</boot> partition.
1108
1109 =over 8
1110
1111 =item -d, --dhcp-tftp
1112
1113 Turns your workstation into a DHCP and TFTP server so that the OS can
1114 be booted via PXE BIOS (or similar mechanism) on the test machine
1115 directly connected by a plain Ethernet cable to your workstation.
1116
1117 The DHCP and TFTP servers require root privileges and C<novaboot>
1118 uses C<sudo> command to obtain those. You can put the following to
1119 I</etc/sudoers> to allow running the necessary commands without
1120 asking for password.
1121
1122  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --foreground --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1123  your_login ALL=NOPASSWD: NOVABOOT
1124
1125 =item --iso[=filename]
1126
1127 Generates the ISO image that boots NOVA system via GRUB. If no filename
1128 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1129 of the novaboot script (see also B<--name>).
1130
1131 =item --server[=[[user@]server:]path]
1132
1133 Copy all files needed for booting to another location (implies B<-g>
1134 unless B<--grub2> is given). The files will be copied (by B<rsync>
1135 tool) to the directory I<path>. If the I<path> contains string $NAME,
1136 it will be replaced with the name of the novaboot script (see also
1137 B<--name>).
1138
1139 =item --concat
1140
1141 If B<--server> is used and its value ends with $NAME, then after
1142 copying the files, a new bootloader configuration file (e.g. menu.lst)
1143 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1144 with $NAME part removed. The content of the file is created by
1145 concatenating all files of the same name from all subdirectories of
1146 I<path-wo-name> found on the "server".
1147
1148 =item --rsync-flags=I<flags>
1149
1150 Specifies which I<flags> are appended to F<rsync> command line when
1151 copying files as a result of I<--server> option.
1152
1153 =back
1154
1155 =head2 Target power-on and reset phase
1156
1157 =over 8
1158
1159 =item --on, --off
1160
1161 Switch on/off the target machine. Currently works only with
1162 B<--iprelay>.
1163
1164 =item -Q, --qemu[=I<qemu-binary>]
1165
1166 Boot the configuration in qemu. Optionally, the name of qemu binary
1167 can be specified as a parameter.
1168
1169 =item --qemu-append=I<flags>
1170
1171 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1172 C<-cpu coreduo -smp 2>).
1173
1174 =item -q, --qemu-flags=I<flags>
1175
1176 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1177 -smp 2>) with I<flags> specified here.
1178
1179 =item --reset-cmd=I<cmd>
1180
1181 Command that resets the target.
1182
1183 =back
1184
1185 =head2 Interaction with the bootloader on the target
1186
1187 =over 8
1188
1189 =item --uboot
1190
1191 Interact with uBoot bootloader to boot the thing described in the
1192 novaboot script. Implementation of this option is currently tied to a
1193 particular board that we use. It may be subject to changes in the
1194 future!
1195
1196 =item --uboot-init
1197
1198 Command(s) to send the uBoot bootloader before loading the images and
1199 botting them.
1200
1201 =back
1202
1203 =head2 Target interaction phase
1204
1205 In this phase, target's serial output is passed to C<novaboot> stdout.
1206 If C<novaboot>'s stdin is on TTY, the stdin is passed to the target
1207 allowing interactive work with the target.
1208
1209 This phase end when the target hangs up or when Ctrl-C is pressed.
1210
1211 =over 8
1212
1213 =item --exiton=I<string>
1214
1215 When I<string> is sent by the target, novaboot exits. This option can
1216 be specified multiple times.
1217
1218 If I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1219 treated as regular expression. For example:
1220
1221     --exiton -re --exiton 'error:.*failed'
1222
1223 =back
1224
1225 =head1 NOVABOOT SCRIPT SYNTAX
1226
1227 The syntax tries to mimic POSIX shell syntax. The syntax is defined with the following rules.
1228
1229 Lines starting with "#" are ignored.
1230
1231 Lines that end with "\" are concatenated with the following line after
1232 removal of the final "\" and leading whitespace of the following line.
1233
1234 Lines in the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1235 expression) assign values to internal variables. See VARIABLES
1236 section.
1237
1238 Otherwise, the first word on the line represents the filename
1239 (relative to the build directory (see B<--build-dir>) of the module to
1240 load and the remaining words are passed as the command line
1241 parameters.
1242
1243 When the line ends with "<<WORD" then the subsequent lines until the
1244 line containing only WORD are copied literally to the file named on
1245 that line.
1246
1247 When the line ends with "< CMD" the command CMD is executed with
1248 C</bin/sh> and its standard output is stored in the file named on that
1249 line. The SRCDIR variable in CMD's environment is set to the absolute
1250 path of the directory containing the interpreted novaboot script.
1251
1252 Example:
1253   #!/usr/bin/env novaboot
1254   WVDESC=Example program
1255   bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
1256     verbose hostkeyb:0,0x60,1,12,2
1257   bin/apps/hello.nul
1258   hello.nulconfig <<EOF
1259   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
1260   rom://bin/apps/hello.nul
1261   EOF
1262
1263 This example will load three modules: sigma0.nul, hello.nul and
1264 hello.nulconfig. sigma0 gets some command line parameters and
1265 hello.nulconfig file is generated on the fly from the lines between
1266 <<EOF and EOF.
1267
1268 =head2 VARIABLES
1269
1270 The following variables are interpreted in the novaboot script:
1271
1272 =over 8
1273
1274 =item BUILDDIR
1275
1276 Novaboot chdir()s to this directory before file generation phase. The
1277 directory name specified here is relative to the build directory
1278 specified by other means (see L</--build-dir>).
1279
1280 =item EXITON
1281
1282 Assigning this variable has the same effect as specifying L</--exiton>
1283 option.
1284
1285 =item HYPERVISOR_PARAMS
1286
1287 Parameters passed to hypervisor. The default value is "serial", unless
1288 overriden in configuration file.
1289
1290 =item KERNEL
1291
1292 The kernel to use instead of NOVA hypervisor specified in the
1293 configuration file. The value should contain the name of the kernel
1294 image as well as its command line parameters. If this variable is
1295 defined and non-empty, the variable HYPERVISOR_PARAMS is not used.
1296
1297 =item QEMU
1298
1299 Use a specific qemu binary (can be overriden with B<-Q>) and flags
1300 when booting this script under qemu. If QEMU_FLAGS variable is also
1301 specified flags specified in QEMU variable are replaced by those in
1302 QEMU_FLAGS.
1303
1304 =item QEMU_FLAGS
1305
1306 Use specific qemu flags (can be overriden with B<-q>).
1307
1308 =item WVDESC
1309
1310 Description of the wvtest-compliant program.
1311
1312 =item WVTEST_TIMEOUT
1313
1314 The timeout in seconds for WvTest harness. If no complete line appears
1315 in the test output within the time specified here, the test fails. It
1316 is necessary to specify this for long running tests that produce no
1317 intermediate output.
1318
1319 =back
1320
1321 =head1 CONFIGURATION FILE
1322
1323 Novaboot can read its configuration from one or more files. By
1324 default, novaboot looks for files named F<.novaboot> as described in
1325 L</Configuration reading phase>. Alternatively, its location can be
1326 specified with the B<-c> switch or with the NOVABOOT_CONFIG
1327 environment variable. The configuration file has perl syntax and
1328 should set values of certain Perl variables. The current configuration
1329 can be dumped with the B<--dump-config> switch. Some configuration
1330 variables can be overriden by environment variables (see below) or by
1331 command line switches.
1332
1333 Supported configuration variables include:
1334
1335 =over 8
1336
1337 =item $builddir
1338
1339 Build directory location relative to the location of the configuration
1340 file.
1341
1342 =item $default_target
1343
1344 Default target (see below) to use when no target is explicitly
1345 specified on command line with the B<--target> option.
1346
1347 =item %targets
1348
1349 Hash of shortcuts to be used with the B<--target> option. If the hash
1350 contains, for instance, the following pair of values
1351
1352  'mybox' => '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
1353
1354 then the following two commands are equivalent:
1355
1356  ./script --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
1357  ./script -t mybox
1358
1359 =back
1360
1361 =head1 ENVIRONMENT VARIABLES
1362
1363 Some options can be specified not only via config file or command line
1364 but also through environment variables. Environment variables override
1365 the values from configuration file and command line parameters
1366 override the environment variables.
1367
1368 =over 8
1369
1370 =item NOVABOOT_CONFIG
1371
1372 Name of the novaboot configuration file to use instead of the default
1373 one(s).
1374
1375 =item NOVABOOT_BENDER
1376
1377 Defining this variable has the same meaning as B<--bender> option.
1378
1379 =back
1380
1381 =head1 AUTHORS
1382
1383 Michal Sojka <sojka@os.inf.tu-dresden.de>