novaboot

   1 #!/usr/bin/perl -w
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 use strict;
  17 use warnings;
  18 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  19 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  20 use Pod::Usage;
  21 use File::Basename;
  22 use File::Spec;
  23 use IO::Handle;
  24 use Time::HiRes("usleep");
  25 use Socket;
  26 use FileHandle;
  27 use IPC::Open2;
  28 use POSIX qw(:errno_h);
  29 use Cwd qw(getcwd abs_path);
  30 use Expect;
  31
  32 # always flush
  33 $| = 1;
  34
  35 my $invocation_dir = $ENV{PWD} || getcwd();
  36
  37 ## Configuration file handling
  38
  39 # Default configuration
  40 $CFG::hypervisor = "";
  41 $CFG::hypervisor_params = "serial";
  42 $CFG::genisoimage = "genisoimage";
  43 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  44 $CFG::default_target = 'qemu';
  45 %CFG::targets = (
  46     'qemu' => '--qemu',
  47     "tud" => '--server=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  48     "novabox" => '--server=rtime.felk.cvut.cz:/srv/tftp/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --pulsar --iprelay=147.32.86.92:2324',
  49     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --server=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  50     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  51     "ryuglab" => '--target ryu --server=pc-sojkam.felk.cvut.cz:/srv/tftp --remote-cmd="ssh -tt pc-sojkam.felk.cvut.cz \"sterm -d -s 115200 /dev/ttyUSB0\""',
  52     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  53     );
  54 chomp(my $nproc = `nproc`);
  55 $CFG::scons = "scons -j$nproc";
  56 $CFG::make = "make -j$nproc";
  57
  58 my $builddir;
  59
  60 sub read_config($) {
  61     my ($cfg) = @_;
  62     {
  63         package CFG; # Put config data into a separate namespace
  64         my $rc = do($cfg);
  65
  66         # Check for errors
  67         if ($@) {
  68             die("ERROR: Failure compiling '$cfg' - $@");
  69         } elsif (! defined($rc)) {
  70             die("ERROR: Failure reading '$cfg' - $!");
  71         } elsif (! $rc) {
  72             die("ERROR: Failure processing '$cfg'");
  73         }
  74     }
  75     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  76     print STDERR "novaboot: Read $cfg\n";
  77 }
  78
  79 my @cfgs;
  80 {
  81     # We don't use $0 here, because it points to the novaboot itself and
  82     # not to the novaboot script. The problem with this approach is that
  83     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
  84     # contains the first option. Hence the -f check.
  85     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
  86     while ((-d $dir || -l $dir ) && $dir ne "/") {
  87         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
  88         my @dirs = File::Spec->splitdir($dir);
  89         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
  90     }
  91     @cfgs = reverse @cfgs;
  92     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
  93     if (opendir(my $dh, $dir)) {
  94         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
  95         closedir $dh;
  96         @etccfg = sort(@etccfg);
  97         @cfgs = ( @etccfg, @cfgs );
  98     }
  99 }
 100 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 101 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 102 GetOptions ("config|c=s" => \$cfg);
 103 read_config($_) foreach $cfg or @cfgs;
 104
 105 ## Command line handling
 106
 107 my $explicit_target;
 108 GetOptions ("target|t=s" => \$explicit_target);
 109
 110 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, @expect_raw, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $iprelay, $iso_image, $interactive, $kernel_opt, $make, $man, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, $remote_cmd, $remote_expect, $reset_cmd, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, @uboot_init);
 111
 112 $rsync_flags = '';
 113 $rom_prefix = 'rom://';
 114 $stty = 'raw -crtscts -onlcr 115200';
 115
 116 my @expect_seen = ();
 117 sub handle_expect
 118 {
 119     my ($n, $v) = @_;
 120     push(@expect_seen, '-re') if $n eq "expect-re";
 121     push(@expect_seen, $v);
 122 }
 123
 124 sub handle_send
 125 {
 126     my ($n, $v) = @_;
 127     unless (@expect_seen) { die("No --expect before --send"); }
 128     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 129     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 130     unshift(@expect_raw, @expect_seen);
 131     @expect_seen = ();
 132 }
 133
 134 my %opt_spec;
 135 %opt_spec = (
 136     "amt=s"          => \$amt,
 137     "append|a=s"     => \@append,
 138     "bender|b"       => \$bender,
 139     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 140     "concat"         => \$concat,
 141     "chainloader=s"  => \@chainloaders,
 142     "dhcp-tftp|d"    => \$dhcp_tftp,
 143     "dump"           => \$dump_opt,
 144     "dump-config"    => \$dump_config,
 145     "exiton=s"       => \@exiton,
 146     "expect=s"       => \&handle_expect,
 147     "expect-re=s"    => \&handle_expect,
 148     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 149     "gen-only"       => \$gen_only,
 150     "grub|g:s"       => \$grub_config,
 151     "grub-preamble=s"=> \$grub_preamble,
 152     "prefix|grub-prefix=s" => \$grub_prefix,
 153     "grub2:s"        => \$grub2_config,
 154     "grub2-prolog=s" => \$grub2_prolog,
 155     "ider"           => \$ider,
 156     "iprelay=s"      => \$iprelay,
 157     "iso:s"          => \$iso_image,
 158     "kernel|k=s"     => \$kernel_opt,
 159     "interactive|i"  => \$interactive,
 160     "name=s"         => \$config_name_opt,
 161     "make|m:s"       => \$make,
 162     "no-file-gen"    => \$no_file_gen,
 163     "off"            => \$off_opt,
 164     "on"             => \$on_opt,
 165     "pulsar|p:s"     => \$pulsar,
 166     "pulsar-root=s"  => \$pulsar_root,
 167     "qemu|Q:s"       => \$qemu,
 168     "qemu-append=s"  => \$qemu_append,
 169     "qemu-flags|q=s" => \$qemu_flags_cmd,
 170     "remote-cmd=s"   => \$remote_cmd,
 171     "remote-expect=s"=> \$remote_expect,
 172     "reset-cmd=s"    => \$reset_cmd,
 173     "rsync-flags=s"  => \$rsync_flags,
 174     "scons:s"        => \$scons,
 175     "scriptmod=s"    => \@scriptmod,
 176     "send=s"         => \&handle_send,
 177     "sendcont=s"     => \&handle_send,
 178     "serial|s:s"     => \$serial,
 179     "server:s"       => \$server,
 180     "strip-rom"      => sub { $rom_prefix = ''; },
 181     "stty=s"         => \$stty,
 182     "tftp"           => \$tftp,
 183     "tftp-port=i"    => \$tftp_port,
 184     "uboot:s"        => \$uboot,
 185     "uboot-addr=s"   => \%uboot_addr,
 186     "uboot-init=s"   => \@uboot_init,
 187     "h"              => \$help,
 188     "help"           => \$man,
 189     );
 190
 191 # First process target options
 192 {
 193     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 194     my @target_expanded;
 195     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 196     while ($t) {
 197         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 198
 199         undef $explicit_target;
 200         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 201         if (!$ret) { die "Error parsing target $t option"; }
 202         push(@target_expanded, @$remaining_args);
 203         $t = $explicit_target;
 204     }
 205     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 206     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 207 }
 208
 209 # Then process other command line options - some of them may override
 210 # what was specified by the target
 211 GetOptions %opt_spec or die("Error in command line arguments");
 212 pod2usage(1) if $help;
 213 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 214
 215 ### Dump sanitized configuration (if requested)
 216
 217 if ($dump_config) {
 218     use Data::Dumper;
 219     $Data::Dumper::Indent=1;
 220     print "# This file is in perl syntax.\n";
 221     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 222         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 223         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 224         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 225     }
 226     print "1;\n";
 227     exit;
 228 }
 229
 230 ### Sanitize configuration
 231
 232 if ($interactive && !-t STDIN) {
 233     die("novaboot: Interactive mode not supported when not on terminal");
 234 }
 235
 236 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 237
 238 if ($ider) {
 239     $iso_image //= ''; # IDE-R needs an ISO image
 240     if (!defined $amt) { die "Error: --ider requires --amt"; }
 241 }
 242
 243 # Default options
 244 if (defined $serial) {
 245     $serial ||= "/dev/ttyUSB0";
 246     $ENV{NB_SERIAL} = $serial;
 247 }
 248 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 249 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 250
 251 ## Parse the novaboot script(s)
 252 my @scripts;
 253 my $file;
 254 my $EOF;
 255 my $last_fn = '';
 256 my ($modules, $variables, $generated, $continuation) = ([], {}, []);
 257 my $skip_reading = defined($on_opt) || defined($off_opt);
 258 while (!$skip_reading && ($_ = <>)) {
 259     if ($ARGV ne $last_fn) { # New script
 260         die "Missing EOF in $last_fn" if $file;
 261         die "Unfinished line in $last_fn" if $continuation;
 262         $last_fn = $ARGV;
 263         push @scripts, { 'filename' => $ARGV,
 264                          'modules' => $modules = [],
 265                          'variables' => $variables = {},
 266                          'generated' => $generated = []};
 267
 268     }
 269     chomp();
 270     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 271
 272     $_ =~ s/^[[:space:]]*// if ($continuation);
 273
 274     if (/\\$/) {                # Line continuation
 275         $continuation .= substr($_, 0, length($_)-1);
 276         next;
 277     }
 278
 279     if ($continuation) {        # Last continuation line
 280         $_ = $continuation . $_;
 281         $continuation = '';
 282     }
 283
 284     foreach my $mod(@scriptmod) { eval $mod; }
 285
 286     if ($file && $_ eq $EOF) {  # Heredoc end
 287         undef $file;
 288         next;
 289     }
 290     if ($file) {                # Heredoc content
 291         push @{$file}, "$_\n";
 292         next;
 293     }
 294     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 295         $$variables{$1} = $2;
 296         push(@exiton, $2) if ($1 eq "EXITON");
 297         next;
 298     }
 299     if (s/^load *//) {          # Load line
 300         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 301         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 302             push @$modules, "$1$2";
 303             $file = [];
 304             push @$generated, {filename => $1, content => $file};
 305             $EOF = $3;
 306             next;
 307         }
 308         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 309             push @$modules, "$1$2";
 310             push @$generated, {filename => $1, command => $3};
 311             next;
 312         }
 313         push @$modules, $_;
 314         next;
 315     }
 316     if (/^run (.*)/) {          # run line
 317         push @$generated, {command => $1};
 318         next;
 319     }
 320
 321     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 322 }
 323 # use Data::Dumper;
 324 # print Dumper(\@scripts);
 325
 326 foreach my $script (@scripts) {
 327     $modules = $$script{modules};
 328     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 329     @$modules[0] .= ' ' . join(' ', @append) if @append;
 330
 331     my $kernel;
 332     if (exists $variables->{KERNEL}) {
 333         $kernel = $variables->{KERNEL};
 334     } else {
 335         if ($CFG::hypervisor) {
 336             $kernel = $CFG::hypervisor . " ";
 337             if (exists $variables->{HYPERVISOR_PARAMS}) {
 338                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 339             } else {
 340                 $kernel .= $CFG::hypervisor_params;
 341             }
 342         }
 343     }
 344     @$modules = ($kernel, @$modules) if $kernel;
 345     @$modules = (@chainloaders, @$modules);
 346     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 347 }
 348
 349 if ($dump_opt) {
 350     foreach my $script (@scripts) {
 351         print join("\n", @{$$script{modules}})."\n";
 352     }
 353     exit(0);
 354 }
 355
 356 ## Helper functions
 357
 358 sub generate_configs($$$) {
 359     my ($base, $generated, $filename) = @_;
 360     if ($base) { $base = "$base/"; };
 361     foreach my $g(@$generated) {
 362       if (exists $$g{content}) {
 363         my $config = $$g{content};
 364         my $fn = $$g{filename};
 365         open(my $f, '>', $fn) || die("$fn: $!");
 366         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 367         close($f);
 368         print "novaboot: Created $fn\n";
 369       } elsif (exists $$g{command} && ! $no_file_gen) {
 370         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 371         if (exists $$g{filename}) {
 372             system_verbose("( $$g{command} ) > $$g{filename}");
 373         } else {
 374             system_verbose($$g{command});
 375         }
 376       }
 377     }
 378 }
 379
 380 sub generate_grub_config($$$$;$)
 381 {
 382     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 383     if ($base) { $base = "$base/"; };
 384     open(my $fg, '>', $filename) or die "$filename: $!";
 385     print $fg "$preamble\n" if $preamble;
 386     print $fg "title $title\n" if $title;
 387     #print $fg "root $base\n"; # root doesn't really work for (nd)
 388     my $first = 1;
 389     foreach (@$modules_ref) {
 390         if ($first) {
 391             $first = 0;
 392             my ($kbin, $kcmd) = split(' ', $_, 2);
 393             $kcmd = '' if !defined $kcmd;
 394             print $fg "kernel ${base}$kbin $kcmd\n";
 395         } else {
 396             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 397             print $fg "module $base$_\n";
 398         }
 399     }
 400     close($fg);
 401     print("novaboot: Created $builddir/$filename\n");
 402     return $filename;
 403 }
 404
 405 sub generate_syslinux_config($$$$)
 406 {
 407     my ($filename, $title, $base, $modules_ref) = @_;
 408     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 409     open(my $fg, '>', $filename) or die "$filename: $!";
 410     print $fg "LABEL $title\n";
 411     #TODO print $fg "MENU LABEL $human_readable_title\n";
 412
 413     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 414
 415     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 416         my $initrd = @$modules_ref[1];
 417         die('To many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 418         print $fg "LINUX $base$kbin\n";
 419         print $fg "APPEND $kcmd\n";
 420         print $fg "INITRD $base$initrd\n";
 421     } else {
 422         print $fg "KERNEL mboot.c32\n";
 423         my @append;
 424         foreach (@$modules_ref) {
 425             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 426             push @append, "$base$_";
 427             print $fg "APPEND ".join(' --- ', @append)."\n";
 428         }
 429     }
 430     #TODO print $fg "TEXT HELP\n";
 431     #TODO print $fg "some help here\n";
 432     #TODO print $fg "ENDTEXT\n";
 433     close($fg);
 434     print("novaboot: Created $builddir/$filename\n");
 435     return $filename;
 436 }
 437
 438 sub generate_grub2_config($$$$;$$)
 439 {
 440     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 441     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 442     open(my $fg, '>', $filename) or die "$filename: $!";
 443     print $fg "$preamble\n" if $preamble;
 444     $title ||= 'novaboot';
 445     print $fg "menuentry $title {\n";
 446     print $fg "$prolog\n" if $prolog;
 447     my $first = 1;
 448     foreach (@$modules_ref) {
 449         if ($first) {
 450             $first = 0;
 451             my ($kbin, $kcmd) = split(' ', $_, 2);
 452             $kcmd = '' if !defined $kcmd;
 453             print $fg "  multiboot ${base}$kbin $kcmd\n";
 454         } else {
 455             my @args = split;
 456             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 457             $_ = join(' ', ($args[0], @args));
 458             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 459             print $fg "  module $base$_\n";
 460         }
 461     }
 462     print $fg "}\n";
 463     close($fg);
 464     print("novaboot: Created $builddir/$filename\n");
 465     return $filename;
 466 }
 467
 468 sub generate_pulsar_config($$)
 469 {
 470     my ($filename, $modules_ref) = @_;
 471     open(my $fg, '>', $filename) or die "$filename: $!";
 472     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 473     my $first = 1;
 474     my ($kbin, $kcmd);
 475     foreach (@$modules_ref) {
 476         if ($first) {
 477             $first = 0;
 478             ($kbin, $kcmd) = split(' ', $_, 2);
 479             $kcmd = '' if !defined $kcmd;
 480         } else {
 481             my @args = split;
 482             s|\brom://|$rom_prefix|g;
 483             print $fg "load $_\n";
 484         }
 485     }
 486     # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 487     print $fg "exec $kbin $kcmd\n";
 488     close($fg);
 489     print("novaboot: Created $builddir/$filename\n");
 490     return $filename;
 491 }
 492
 493 sub shell_cmd_string(@)
 494 {
 495     return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 496 }
 497
 498 sub exec_verbose(@)
 499 {
 500     print "novaboot: Running: ".shell_cmd_string(@_)."\n";
 501     exec(@_);
 502     exit(1); # should not be reached
 503 }
 504
 505 sub system_verbose($)
 506 {
 507     my $cmd = shift;
 508     print "novaboot: Running: $cmd\n";
 509     my $ret = system($cmd);
 510     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 511     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 512     if ($ret) { die("Command failure $ret"); }
 513 }
 514
 515 ## WvTest handline
 516
 517 if (exists $variables->{WVDESC}) {
 518     print "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 519 } elsif ($last_fn =~ /\.wv$/) {
 520     print "Testing \"all\" in $last_fn:\n";
 521 }
 522
 523 ## Connect to the target and check whether it is not occupied
 524
 525 # We have to do this before file generation phase, because file
 526 # generation is intermixed with file deployment phase and we want to
 527 # check whether the target is not used by somebody else before
 528 # deploying files. Otherwise, we may rewrite other user's files on a
 529 # boot server.
 530
 531 my $exp; # Expect object to communicate with the target over serial line
 532
 533 my ($target_reset, $target_power_on, $target_power_off);
 534 my ($amt_user, $amt_password, $amt_host, $amt_port);
 535
 536 if (defined $iprelay) {
 537     my $IPRELAY;
 538     $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 539     my $addr = $1;
 540     my $port = $3 || 23;
 541     my $paddr   = sockaddr_in($port, inet_aton($addr));
 542     my $proto   = getprotobyname('tcp');
 543     socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 544     print "novaboot: Connecting to IP relay... ";
 545     connect($IPRELAY, $paddr)    || die "connect: $!";
 546     print "done\n";
 547     $exp = Expect->init(\*$IPRELAY);
 548     $exp->log_stdout(1);
 549
 550     while (1) {
 551         print $exp "\xFF\xF6";  # AYT
 552         my $connected = $exp->expect(20, # Timeout in seconds
 553                                      '<iprelayd: connected>',
 554                                      '-re', '<WEB51 HW[^>]*>');
 555         last if $connected;
 556     }
 557
 558     sub relaycmd($$) {
 559         my ($relay, $onoff) = @_;
 560         die unless ($relay == 1 || $relay == 2);
 561
 562         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 563         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 564     }
 565
 566     sub relayconf($$) {
 567         my ($relay, $onoff) = @_;
 568         die unless ($relay == 1 || $relay == 2);
 569         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 570         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 571     }
 572
 573     sub relay($$;$) {
 574         my ($relay, $onoff, $can_giveup) = @_;
 575         my $confirmation = '';
 576         $exp->log_stdout(0);
 577         print $exp relaycmd($relay, $onoff);
 578         my $confirmed = $exp->expect(20, # Timeout in seconds
 579                                      relayconf($relay, $onoff));
 580         if (!$confirmed) {
 581             if ($can_giveup) {
 582                 print("Relay confirmation timeout - ignoring\n");
 583             } else {
 584                 die "Relay confirmation timeout";
 585             }
 586         }
 587         $exp->log_stdout(1);
 588     }
 589
 590     $target_reset = sub {
 591         relay(2, 1, 1); # Reset the machine
 592         usleep(100000);
 593         relay(2, 0);
 594     };
 595
 596     $target_power_off = sub {
 597         relay(1, 1);            # Press power button
 598         usleep(6000000);        # Long press to switch off
 599         relay(1, 0);
 600     };
 601
 602     $target_power_on = sub {
 603         relay(1, 1);            # Press power button
 604         usleep(100000);         # Short press
 605         relay(1, 0);
 606     };
 607 }
 608 elsif ($serial) {
 609     my $CONN;
 610     system_verbose("stty -F $serial $stty");
 611     open($CONN, "+<", $serial) || die "open $serial: $!";
 612     $exp = Expect->init(\*$CONN);
 613 }
 614 elsif ($remote_cmd) {
 615     print "novaboot: Running: $remote_cmd\n";
 616     $exp = Expect->spawn($remote_cmd);
 617 }
 618 elsif (defined $amt) {
 619     require LWP::UserAgent;
 620     require LWP::Authen::Digest;
 621
 622     sub genXML {
 623         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 624         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 625         my %pstates = ("on"        => 2,
 626                        "standby"   => 4,
 627                        "hibernate" => 7,
 628                        "off"       => 8,
 629                        "reset"     => 10,
 630                        "MNI"       => 11);
 631         return <<END;
 632                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 633                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 634                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 635                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 636                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 637                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 638                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 639                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 640                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 641                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 642                 </s:Header><s:Body>
 643                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 644                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 645                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 646                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 647                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 648                 </a:ReferenceParameters></p:ManagedElement>
 649                 </p:RequestPowerStateChange_INPUT>
 650                 </s:Body></s:Envelope>
 651 END
 652     }
 653
 654     sub sendPOST {
 655         my ($host, $username, $password, $content) = @_;
 656
 657         my $ua = LWP::UserAgent->new();
 658         $ua->agent("novaboot");
 659
 660         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 661         my $res = $ua->request($req);
 662         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 663
 664         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 665         $ua->credentials("$host:16992", $realm, $username => $password);
 666
 667         # Create a request
 668         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 669         $req->content_type('application/x-www-form-urlencoded');
 670         $req->content($content);
 671         $res = $ua->request($req);
 672         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 673         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 674         return $1;
 675     }
 676
 677     sub powerChange  {
 678         my ($host, $username, $password, $pstate)=@_;
 679         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 680         my $className="/RequestPowerStateChange";
 681         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 682         return sendPOST($host, $username, $password, $content);
 683     }
 684
 685     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 686     $amt_user ||= "admin";
 687     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 688     $amt_host || die "AMT host not specified";
 689     $amt_port ||= 16994;
 690
 691
 692     $target_power_off = sub {
 693         $exp->close();
 694         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 695         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 696     };
 697
 698     $target_power_on = sub {
 699         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 700         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 701     };
 702
 703     $target_reset = sub {
 704         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 705         if ($result != 0) {
 706             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 707             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 708         }
 709         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 710     };
 711
 712     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 713     print "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 714     $exp = Expect->spawn($cmd);
 715     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL' timed out";
 716
 717 }
 718
 719
 720 if ($remote_expect) {
 721     $exp->expect(10, $remote_expect) || die "Expect for '$remote_expect' timed out";
 722 }
 723
 724 if (defined $reset_cmd) {
 725     $target_reset = sub {
 726         system_verbose($reset_cmd);
 727     };
 728 }
 729
 730 if (defined $on_opt && defined $target_power_on) {
 731     &$target_power_on();
 732     exit;
 733 }
 734 if (defined $off_opt && defined $target_power_off) {
 735     print "novaboot: Switching the target off...\n";
 736     &$target_power_off();
 737     exit;
 738 }
 739
 740 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 741 if (defined $builddir) {
 742     chdir($builddir) or die "Can't change directory to $builddir: $!";
 743     print "novaboot: Entering directory `$builddir'\n";
 744 } else {
 745     $builddir = $invocation_dir;
 746 }
 747
 748 ## File generation phase
 749 my (%files_iso, $menu_iso, $filename);
 750 my $config_name = '';
 751 my $prefix = '';
 752
 753 foreach my $script (@scripts) {
 754     $filename = $$script{filename};
 755     $modules = $$script{modules};
 756     $generated = $$script{generated};
 757     $variables = $$script{variables};
 758
 759     ($config_name = $filename) =~ s#.*/##;
 760     $config_name = $config_name_opt if (defined $config_name_opt);
 761
 762     if (exists $variables->{BUILDDIR}) {
 763         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 764         chdir($builddir) or die "Can't change directory to $builddir: $!";
 765         print "novaboot: Entering directory `$builddir'\n";
 766     }
 767
 768     if ($grub_prefix) {
 769         $prefix = $grub_prefix;
 770         $prefix =~ s/\$NAME/$config_name/;
 771         $prefix =~ s/\$BUILDDIR/$builddir/;
 772     }
 773     # TODO: use $grub_prefix as first parameter if some switch is given
 774     generate_configs('', $generated, $filename);
 775
 776 ### Generate bootloader configuration files
 777     my @bootloader_configs;
 778     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 779     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 780     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules) if (defined $pulsar);
 781
 782 ### Run scons or make
 783     {
 784         my @files = map({ ($file) = m/([^ ]*)/; $file; } @$modules);
 785         # Filter-out generated files
 786         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 787
 788         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 789         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 790     }
 791
 792 ### Copy files (using rsync)
 793     if (defined $server && !defined($gen_only)) {
 794         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 795
 796         my ($hostname, $path) = split(":", $real_server, 2);
 797         if (! defined $path) {
 798             $path = $hostname;
 799             $hostname = "";
 800         }
 801         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs)));
 802         map({ my $file = (split)[0]; die "$file: $!" if ! -f $file; } @$modules);
 803         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
 804         my $progress = $istty ? "--progress" : "";
 805         system_verbose("rsync $progress -RLp $rsync_flags $files $real_server");
 806         if ($server =~ m|/\$NAME$| && $concat) {
 807             my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
 808             system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
 809         }
 810     }
 811
 812 ### Prepare ISO image generation
 813     if (defined $iso_image) {
 814         generate_configs("(cd)", $generated, $filename);
 815         my $menu;
 816         generate_syslinux_config(\$menu, $config_name, "/", $modules);
 817         $menu_iso .= "$menu\n";
 818         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
 819     }
 820 }
 821
 822 ## Generate ISO image
 823 if (defined $iso_image) {
 824     system_verbose("mkdir -p isolinux");
 825
 826     my @files;
 827     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
 828         # Newer ISOLINUX version
 829         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
 830     } else {
 831         # Older ISOLINUX version
 832         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
 833     }
 834     system_verbose("cp @files isolinux");
 835     open(my $fh, ">isolinux/isolinux.cfg");
 836     if ($#scripts) {
 837         print $fh "TIMEOUT 50\n";
 838         print $fh "DEFAULT menu\n";
 839     } else {
 840         print $fh "DEFAULT $config_name\n";
 841     }
 842     print $fh "$menu_iso";
 843     close($fh);
 844
 845     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
 846     $iso_image ||= "$config_name.iso";
 847
 848     # Note: We use -U flag below to "Allow 'untranslated' filenames,
 849     # completely violating the ISO9660 standards". Without this
 850     # option, isolinux is not able to read files names for example
 851     # bzImage-3.0.
 852     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
 853     print("ISO image created: $builddir/$iso_image\n");
 854 }
 855
 856 exit(0) if defined $gen_only;
 857
 858 ## Boot the system using various methods and send serial output to stdout
 859
 860 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
 861     die "You cannot do this with multiple scripts simultaneously";
 862 }
 863
 864 if ($variables->{WVTEST_TIMEOUT}) {
 865     print "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
 866 }
 867
 868 sub trim($) {
 869     my ($str) = @_;
 870     $str =~ s/^\s+|\s+$//g;
 871     return $str
 872 }
 873
 874 ### Start in Qemu
 875
 876 if (defined $qemu) {
 877     # Qemu
 878     $qemu ||= $variables->{QEMU} || $CFG::qemu;
 879     my @qemu_flags = split(" ", $qemu);
 880     $qemu = shift(@qemu_flags);
 881
 882     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
 883     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
 884     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
 885
 886     if (defined $iso_image) {
 887         # Boot NOVA with grub (and test the iso image)
 888         push(@qemu_flags, ('-cdrom', $iso_image));
 889     } else {
 890         # Boot NOVA without GRUB
 891
 892         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
 893         foreach (@$modules) {s/,/+/g;}
 894         generate_configs("", $generated, $filename);
 895
 896         if (scalar @$modules) {
 897             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
 898             $kcmd = '' if !defined $kcmd;
 899             my $dtb;
 900             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
 901             my $initrd = join ",", @$modules;
 902
 903             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
 904             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
 905             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
 906         }
 907     }
 908     push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
 909     unshift(@qemu_flags, ('-name', $config_name));
 910     print "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
 911     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
 912 }
 913
 914 ### Local DHCPD and TFTPD
 915
 916 my ($dhcpd_pid, $tftpd_pid);
 917
 918 $tftp=1 if $tftp_port;
 919
 920 if (defined $dhcp_tftp)
 921 {
 922     generate_configs("(nd)", $generated, $filename);
 923     system_verbose('mkdir -p tftpboot');
 924     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
 925     open(my $fh, '>', 'dhcpd.conf');
 926     my $mac = `cat /sys/class/net/eth0/address`;
 927     chomp $mac;
 928     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
 929                       range 10.23.23.10 10.23.23.100;
 930                       filename \"bin/boot/grub/pxegrub.pxe\";
 931                       next-server 10.23.23.1;
 932 }
 933 host server {
 934         hardware ethernet $mac;
 935         fixed-address 10.23.23.1;
 936 }";
 937     close($fh);
 938     system_verbose("sudo ip a add 10.23.23.1/24 dev eth0;
 939             sudo ip l set dev eth0 up;
 940             sudo touch dhcpd.leases");
 941
 942     # We run servers by forking ourselves, because the servers end up
 943     # in our process group and get killed by signals sent to the
 944     # process group (e.g. Ctrl-C on terminal).
 945     $dhcpd_pid = fork();
 946     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
 947 }
 948
 949 if (defined $dhcp_tftp || defined $tftp) {
 950     $tftp_port ||= 69;
 951     # Unfortunately, tftpd requires root privileges even with
 952     # non-privileged (>1023) port due to initgroups().
 953     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
 954
 955     # Kill server when we die
 956     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
 957                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
 958
 959     # We have to kill tftpd explicitely, because it is not in our process group
 960     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
 961 }
 962
 963 ### AMT IDE-R
 964 if (defined $ider) {
 965     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
 966     print "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
 967     my $ider_pid = fork();
 968     if ($ider_pid == 0) {
 969         exec($ider_cmd);
 970         die "IDE redirection failed";
 971     }
 972     # FIXME: This collides with --tftp option. Hopefully, nobody needs
 973     # to use both simultaneously.
 974     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
 975 }
 976
 977 ### Reset target (IP relay, AMT, ...)
 978
 979 if (defined $target_reset) {
 980     print "novaboot: Reseting the test box... ";
 981     &$target_reset();
 982     print "done\n";
 983 }
 984
 985 ### U-boot conversation
 986 if (defined $uboot) {
 987     my $uboot_prompt = $uboot || '=> ';
 988     print "novaboot: Waiting for uBoot prompt...\n";
 989     $exp->log_stdout(1);
 990     #$exp->exp_internal(1);
 991     $exp->expect(20,
 992                  [qr/Hit any key to stop autoboot:/, sub { $exp->send("\n"); exp_continue; }],
 993                  $uboot_prompt) || die "No uBoot prompt deteceted";
 994     foreach my $cmd (@uboot_init) {
 995         if ($cmd =~ /\$NB_MYIP/) {
 996             my $ip = (grep /inet /, `ip addr show eth0`)[0] || die "Problem determining our IP address";
 997             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
 998             $cmd =~ s/\$NB_MYIP/$ip/g;
 999         }
1000         chomp($cmd);
1001         $exp->send("$cmd\n");
1002         $exp->expect(10, $uboot_prompt) || die "uBoot prompt timeout";
1003     }
1004
1005     # Boot the system if there are some load lines in the script
1006     if (scalar(@$modules) > 0) {
1007         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1008         my $dtb;
1009         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1010         my $initrd = shift @$modules;
1011
1012         my ($ramdisk_addr, $fdt_addr) = ('-', '');
1013
1014         die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1015         $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1016         $exp->expect(10,
1017                      [qr/##/, sub { exp_continue; }],
1018                      $uboot_prompt) || die "No U-Boot prompt deteceted";
1019         if (defined $dtb) {
1020             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1021             $fdt_addr = $uboot_addr{fdt};
1022             $exp->send("tftpboot $fdt_addr $prefix$dtb\n");
1023             $exp->expect(10,
1024                          [qr/##/, sub { exp_continue; }],
1025                          $uboot_prompt) || die "Device tree load failed";
1026         }
1027         if (defined $initrd) {
1028             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1029             $ramdisk_addr = $uboot_addr{ramdisk};
1030             $exp->send("tftpboot $ramdisk_addr $prefix$initrd\n");
1031             $exp->expect(10,
1032                          [qr/#/, sub { exp_continue; }],
1033                          $uboot_prompt) || die "Initrd load failed";
1034         }
1035         $exp->send("setenv bootargs $kcmd\n");
1036         $exp->expect(5, $uboot_prompt)  || die "uBoot prompt timeout";
1037         $exp->send("bootm $uboot_addr{kernel} $ramdisk_addr $fdt_addr\n");
1038         $exp->expect(5, "\n")  || die "uBoot command timeout";
1039     }
1040 }
1041
1042 ### Serial line interaction
1043 if (defined $exp) {
1044     # Serial line of the target is available
1045     my $interrupt = 'Ctrl-C';
1046     if ($interactive && !@exiton) {
1047         $interrupt = '"~~."';
1048     }
1049     my $note = (-t STDIN) ? '' : '- only target->host ';
1050     print "novaboot: Serial line interaction $note(press $interrupt to interrupt)...\n";
1051     $exp->log_stdout(1);
1052     if (@exiton) {
1053         $exp->expect(undef, @expect_raw, @exiton);
1054     } else {
1055         my @inputs = ($exp);
1056         if (-t STDIN) { # Set up bi-directional communication if we run on terminal
1057             my $infile = new IO::File;
1058             $infile->IO::File::fdopen(*STDIN,'r');
1059             my $in_object = Expect->exp_init($infile);
1060             $in_object->set_group($exp);
1061
1062             if ($interactive) {
1063                 $in_object->set_seq('~~\.', sub { print "novaboot: Escape sequence detected\r\n"; undef; });
1064                 $in_object->manual_stty(0);       # Use raw terminal mode
1065             } else {
1066                 $in_object->manual_stty(1);       # Do not modify terminal settings
1067             }
1068             push(@inputs, $in_object);
1069         }
1070         #use Data::Dumper;
1071         #print Dumper(\@expect_raw);
1072         $exp->expect(undef, @expect_raw) if @expect_raw;
1073         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1074     }
1075 }
1076
1077 ## Kill dhcpc or tftpd
1078 if (defined $dhcp_tftp || defined $tftp) {
1079     die("novaboot: This should kill servers on background\n");
1080 }
1081
1082 ## Documentation
1083
1084 =head1 NAME
1085
1086 novaboot - A tool for booting various operating systems on various hardware or in qemu
1087
1088 =head1 SYNOPSIS
1089
1090 B<novaboot> --help
1091
1092 B<novaboot> [option]... [--] script...
1093
1094 B<./script> [option]...
1095
1096 =head1 DESCRIPTION
1097
1098 This program makes booting of an operating system (e.g. NOVA or Linux)
1099 as simple as running a local program. It facilitates booting on local
1100 or remote hosts or in emulators such as qemu. Novaboot operation is
1101 controlled by command line options and by a so called novaboot script,
1102 which can be thought as a generalization of bootloader configuration
1103 files (see L</"NOVABOOT SCRIPT SYNTAX">). Based on this input,
1104 novaboot setups everything for the target host to boot the desired
1105 configuration, i.e. it generates the bootloader configuration file in
1106 the proper format, deploy the binaries and other needed files to
1107 required locations, perhaps on a remote boot server and reset the
1108 target host. Finally, target host's serial output is redirected to
1109 standard output if that is possible.
1110
1111 Typical way of using novaboot is to make the novaboot script
1112 executable and set its first line to I<#!/usr/bin/env novaboot>. Then,
1113 booting a particular OS configuration becomes the same as executing a
1114 local program - the novaboot script.
1115
1116 For example, with C<novaboot> you can:
1117
1118 =over 3
1119
1120 =item 1.
1121
1122 Run an OS in Qemu. This is the default action when no other action is
1123 specified by command line switches. Thus running C<novaboot ./script>
1124 (or C<./script> as described above) will run Qemu and make it boot the
1125 configuration specified in the F<script>.
1126
1127 =item 2.
1128
1129 Create a bootloader configuration file (currently supported
1130 bootloaders are GRUB, GRUB2, Pulsar and U-Boot) and copy it with all
1131 other files needed for booting to a remote boot server.
1132
1133  ./script --server=192.168.1.1:/tftp --iprelay=192.168.1.2
1134
1135 This command copies files to the TFTP server and uses
1136 TCP/IP-controlled relay to reset the target host and receive its
1137 serial output.
1138
1139 =item 3.
1140
1141 Run DHCP and TFTP server on developer's machine to PXE-boot the target
1142 host from it. E.g.
1143
1144  ./script --dhcp-tftp
1145
1146 When a PXE-bootable machine is connected via Ethernet to developer's
1147 machine, it will boot the configuration described in I<script>.
1148
1149 =item 4.
1150
1151 Create bootable ISO images. E.g.
1152
1153  novaboot --iso -- script1 script2
1154
1155 The created ISO image will have GRUB bootloader installed on it and
1156 the boot menu will allow selecting between I<script1> and I<script2>
1157 configurations.
1158
1159 =back
1160
1161 Note that the options needed for a specific target can be stored in a
1162 L</"CONFIGURATION FILE">. Then it is sufficient to use only the B<-t>
1163 option to specify the name of the target.
1164
1165 =head1 PHASES AND OPTIONS
1166
1167 Novaboot performs its work in several phases. Each phase can be
1168 influenced by several options, certain phases can be skipped. The list
1169 of phases (in the execution order) and the corresponding options
1170 follow.
1171
1172 =head2 Configuration reading phase
1173
1174 After starting, novaboot reads configuration files. Their content is
1175 described in L</"CONFIGURATION FILE">. By default, configuration is
1176 read from two locations. First from the configuration directory and
1177 second from F<.novaboot> files along the path to the current
1178 directory. The later read files override settings from the former
1179 ones.
1180
1181 Configuration directory is determined by the content of
1182 NOVABOOT_CONFIG_DIR environment variable defaulting to
1183 F</etc/novaboot.d>. Files in this directory with names consisting
1184 solely from English letters, numbers, dashes '-' and underscores '_'
1185 (note that dot '.' is not included) are read in alphabetical order.
1186
1187 Then novaboot searches for files named F<.novaboot> starting
1188 from the directory of the novaboot script (or working directory, see
1189 bellow) and continuing upwards up to the root directory. The found
1190 configuration files are then read in order from the root directory
1191 downwards.
1192
1193 In certain cases, the location of the novaboot script cannot be
1194 determined in this early phase. This happens either when the script is
1195 read from the standard input or when novaboot is invoked explicitly
1196 and options precede the script name, as in the example L</"4."> above.
1197 In this case the current working directory is used as a starting point
1198 for configuration file search instead of the novaboot script
1199 directory.
1200
1201 =over 8
1202
1203 =item -c, --config=I<filename>
1204
1205 Use the specified configuration file instead of the default one(s).
1206
1207 =back
1208
1209 =head2 Command line processing phase
1210
1211 =over 8
1212
1213 =item --dump-config
1214
1215 Dump the current configuration to stdout end exits. Useful as an
1216 initial template for a configuration file.
1217
1218 =item -h, --help
1219
1220 Print short (B<-h>) or long (B<--help>) help.
1221
1222 =item -t, --target=I<target>
1223
1224 This option serves as a user configurable shortcut for other novaboot
1225 options. The effect of this option is the same as the options stored
1226 in the C<%targets> configuration variable under key I<target>. See
1227 also L</"CONFIGURATION FILE">.
1228
1229 =back
1230
1231 =head2 Script preprocessing phase
1232
1233 This phases allows to modify the parsed novaboot script before it is
1234 used in the later phases.
1235
1236 =over 8
1237
1238 =item -a, --append=I<parameters>
1239
1240 Append a string to the first C<load> line in the novaboot script. This
1241 can be used to append parameters to the kernel's or root task's
1242 command line. Can appear multiple times.
1243
1244 =item -b, --bender
1245
1246 Use F<bender> chainloader. Bender scans the PCI bus for PCI serial
1247 ports and stores the information about them in the BIOS data area for
1248 use by the kernel.
1249
1250 =item --chainloader=I<chainloader>
1251
1252 Chainloader that is loaded before the kernel and other files specified
1253 in the novaboot script. E.g. 'bin/boot/bender promisc'.
1254
1255 =item --dump
1256
1257 Print the modules to boot and their parameters after this phase
1258 finishes. Then exit. This is useful for seeing the effect of other
1259 options in this section.
1260
1261 =item -k, --kernel=F<file>
1262
1263 Replace the first word on the first C<load> line in the novaboot
1264 script with F<file>.
1265
1266 =item --scriptmod=I<perl expression>
1267
1268 When novaboot script is read, I<perl expression> is executed for every
1269 line (in $_ variable). For example, C<novaboot
1270 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1271 in the script with I<omega6>.
1272
1273 When this option is present, it overrides I<$script_modifier> variable
1274 from the configuration file, which has the same effect. If this option
1275 is given multiple times all expressions are evaluated in the command
1276 line order.
1277
1278 =back
1279
1280 =head2 File generation phase
1281
1282 In this phase, files needed for booting are generated in a so called
1283 I<build directory> (see L</--build-dir>). In most cases configuration
1284 for a bootloader is generated automatically by novaboot. It is also
1285 possible to generate other files using I<heredoc> or I<"<"> syntax in
1286 novaboot scripts. Finally, binaries can be generated in this phases by
1287 running C<scons> or C<make>.
1288
1289 =over 8
1290
1291 =item --build-dir=I<directory>
1292
1293 Overrides the default build directory location.
1294
1295 The default build directory location is determined as follows: If the
1296 configuration file defines the C<$builddir> variable, its value is
1297 used. Otherwise, it is the directory that contains the first processed
1298 novaboot script.
1299
1300 See also L</BUILDDIR> variable.
1301
1302 =item -g, --grub[=I<filename>]
1303
1304 Generates grub bootloader menu file. If the I<filename> is not
1305 specified, F<menu.lst> is used. The I<filename> is relative to the
1306 build directory (see B<--build-dir>).
1307
1308 =item --grub-preamble=I<prefix>
1309
1310 Specifies the I<preable> that is at the beginning of the generated
1311 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1312 timeout.
1313
1314 =item --prefix=I<prefix>
1315
1316 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1317 file name in generated bootloader configuration files (or in U-Boot
1318 commands).
1319
1320 If the I<prefix> contains string $NAME, it will be replaced with the
1321 name of the novaboot script (see also B<--name>).
1322
1323 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1324 the build directory (see also B<--build-dir>).
1325
1326 =item --grub-prefix
1327
1328 Alias for B<--prefix>.
1329
1330 =item --grub2[=I<filename>]
1331
1332 Generate GRUB2 menuentry in I<filename>. If I<filename> is not
1333 specified F<grub.cfg> is used. The content of the menuentry can be
1334 customized with B<--grub-preable>, B<--grub2-prolog> or
1335 B<--grub_prefix> options.
1336
1337 In order to use the the generated menuentry on your development
1338 machine that uses GRUB2, append the following snippet to
1339 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1340 i.e. run update-grub on Debian/Ubuntu.
1341
1342   if [ -f /path/to/nul/build/grub.cfg ]; then
1343     source /path/to/nul/build/grub.cfg
1344   fi
1345
1346 =item --grub2-prolog=I<prolog>
1347
1348 Specifies text I<preable> that is put at the beginning of the entry
1349 GRUB2 entry.
1350
1351 =item -m, --make[=make command]
1352
1353 Runs C<make> to build files that are not generated by novaboot itself.
1354
1355 =item --name=I<string>
1356
1357 Use the name I<string> instead of the name of the novaboot script.
1358 This name is used for things like a title of grub menu or for the
1359 server directory where the boot files are copied to.
1360
1361 =item --no-file-gen
1362
1363 Do not run external commands to generate files (i.e. "<" syntax and
1364 C<run> keyword). This switch does not influence generation of files
1365 specified with "<<WORD" syntax.
1366
1367 =item -p, --pulsar[=mac]
1368
1369 Generates pulsar bootloader configuration file named F<config-I<mac>>
1370 The I<mac> string is typically a MAC address and defaults to
1371 I<novaboot>.
1372
1373 =item --scons[=scons command]
1374
1375 Runs C<scons> to build files that are not generated by novaboot
1376 itself.
1377
1378 =item --strip-rom
1379
1380 Strip I<rom://> prefix from command lines and generated config files.
1381 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1382
1383 =item --gen-only
1384
1385 Exit novaboot after file generation phase.
1386
1387 =back
1388
1389 =head2 Target connection check
1390
1391 If supported by the target, the connection to it is made and it is
1392 checked whether the target is not occupied by another novaboot
1393 user/instance.
1394
1395 =over 8
1396
1397 =item --amt=I<"[user[:password]@]host[:port]>
1398
1399 Use Intel AMT technology to control the target machine. WS management
1400 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1401 The hostname or (IP address) is given by the I<host> parameter. If
1402 I<password> is not specified, environment variable AMT_PASSWORD is
1403 used. The I<port> specifies a TCP port for SOL. If not specified, the
1404 default is 16992. Default I<user> is admin.
1405
1406 =item --ider
1407
1408 Use Intel AMT technology for IDE redirection. This allows the target
1409 machine to boot from nonvaboot created ISO image.
1410
1411 The experimental I<amtider> utility needed by this option can be
1412 obtained from https://github.com/wentasah/amtterm.
1413
1414 =item --iprelay=I<addr[:port]>
1415
1416 Use TCP/IP relay and serial port to access the target's serial port
1417 and powercycle it. The IP address of the relay is given by I<addr>
1418 parameter. If I<port> is not specified, it default to 23.
1419
1420 Note: This option is supposed to work with HWG-ER02a IP relays.
1421
1422 =item -s, --serial[=device]
1423
1424 Target's serial line is connected to host's serial line (device). The
1425 default value for device is F</dev/ttyUSB0>.
1426
1427 The value of this option is exported in NB_NOVABOOT environment
1428 variable to all subprocesses run by C<novaboot>.
1429
1430 =item --stty=I<settings>
1431
1432 Specifies settings passed to C<stty> invoked on the serial line
1433 specified with B<--serial> option. If this option is not given,
1434 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1435
1436 =item --remote-cmd=I<cmd>
1437
1438 Command that mediates connection to the target's serial line. For
1439 example C<ssh server 'cu -l /dev/ttyS0'>.
1440
1441 =item --remote-expect=I<string>
1442
1443 Wait for reception of I<string> after establishing the the remote
1444 connection before continuing.
1445
1446
1447 =back
1448
1449 =head2 File deployment phase
1450
1451 In some setups, it is necessary to copy the files needed for booting
1452 to a particular location, e.g. to a TFTP boot server or to the
1453 F</boot> partition.
1454
1455 =over 8
1456
1457 =item -d, --dhcp-tftp
1458
1459 Turns your workstation into a DHCP and TFTP server so that the OS can
1460 be booted via PXE BIOS (or similar mechanism) on the test machine
1461 directly connected by a plain Ethernet cable to your workstation.
1462
1463 The DHCP and TFTP servers requires root privileges and C<novaboot>
1464 uses C<sudo> command to obtain those. You can put the following to
1465 I</etc/sudoers> to allow running the necessary commands without asking
1466 for password.
1467
1468  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1469  your_login ALL=NOPASSWD: NOVABOOT
1470
1471 =item --tftp
1472
1473 Starts a TFTP server on your workstation. This is similar to
1474 B<--dhcp-tftp> except that DHCP server is not started.
1475
1476 The TFTP server require root privileges and C<novaboot> uses C<sudo>
1477 command to obtain those. You can put the following to I</etc/sudoers>
1478 to allow running the necessary commands without asking for password.
1479
1480  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1481  your_login ALL=NOPASSWD: NOVABOOT
1482
1483 =item --tftp-port=I<port>
1484
1485 Port to run the TFTP server on. Implies B<--tftp>.
1486
1487 =item --iso[=filename]
1488
1489 Generates the ISO image that boots NOVA system via GRUB. If no filename
1490 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1491 of the novaboot script (see also B<--name>).
1492
1493 =item --server[=[[user@]server:]path]
1494
1495 Copy all files needed for booting to another location (implies B<-g>
1496 unless B<--grub2> is given). The files will be copied (by B<rsync>
1497 tool) to the directory I<path>. If the I<path> contains string $NAME,
1498 it will be replaced with the name of the novaboot script (see also
1499 B<--name>).
1500
1501 =item --concat
1502
1503 If B<--server> is used and its value ends with $NAME, then after
1504 copying the files, a new bootloader configuration file (e.g. menu.lst)
1505 is created at I<path-wo-name>, i.e. the path specified by B<--server>
1506 with $NAME part removed. The content of the file is created by
1507 concatenating all files of the same name from all subdirectories of
1508 I<path-wo-name> found on the "server".
1509
1510 =item --rsync-flags=I<flags>
1511
1512 Specifies which I<flags> are appended to F<rsync> command line when
1513 copying files as a result of I<--server> option.
1514
1515 =back
1516
1517 =head2 Target power-on and reset phase
1518
1519 =over 8
1520
1521 =item --on, --off
1522
1523 Switch on/off the target machine and exit. The script (if any) is
1524 completely ignored. Currently it works only with B<--iprelay> or
1525 B<--amt>.
1526
1527 =item -Q, --qemu[=I<qemu-binary>]
1528
1529 Boot the configuration in qemu. Optionally, the name of qemu binary
1530 can be specified as a parameter.
1531
1532 =item --qemu-append=I<flags>
1533
1534 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1535 C<-cpu coreduo -smp 2>).
1536
1537 =item -q, --qemu-flags=I<flags>
1538
1539 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1540 -smp 2>) with I<flags> specified here.
1541
1542 =item --reset-cmd=I<cmd>
1543
1544 Command that resets the target.
1545
1546 =back
1547
1548 =head2 Interaction with the bootloader on the target
1549
1550 =over 8
1551
1552 =item --uboot[=I<prompt>]
1553
1554 Interact with uBoot bootloader to boot the thing described in the
1555 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
1556 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
1557 Implementation of this option is currently tied to a particular board
1558 that we use. It may be subject to changes in the future!
1559
1560 =item --uboot-init
1561
1562 Command(s) to send the U-Boot bootloader before loading the images and
1563 booting them. This option can be given multiple times. After sending
1564 commands from each option novaboot waits for U-Boot I<prompt>.
1565
1566 If the command contains string I<$NB_MYIP> then this string is
1567 replaced by IPv4 address of eth0 interface.
1568
1569 =item --uboot-addr I<name>=I<address>
1570
1571 Load address of U-Boot's C<tftpboot> command for loading I<name>,
1572 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
1573 tree).
1574
1575 =back
1576
1577 =head2 Target interaction phase
1578
1579 In this phase, target's serial output is redirected to stdout and if
1580 stdin is a TTY, it is redirected to the target's serial input allowing
1581 interactive work with the target.
1582
1583 =over 8
1584
1585 =item --exiton=I<string>
1586
1587 When I<string> is sent by the target, novaboot exits. This option can
1588 be specified multiple times.
1589
1590 If I<string> is C<-re>, then the next B<--exiton>'s I<string> is
1591 treated as regular expression. For example:
1592
1593     --exiton -re --exiton 'error:.*failed'
1594
1595 =item -i, --interactive
1596
1597 Setup things for interactive use of target. Your terminal will be
1598 switched to raw mode. In raw mode, your system does not process input
1599 in any way (no echoing of entered characters, no interpretation
1600 special characters). This, among others, means that Ctrl-C is passed
1601 to the target and does no longer interrupt novaboot. Use "~~."
1602 sequence to exit novaboot.
1603
1604 =item --expect=I<string>
1605
1606 When I<string> is received from the target, send the string specified
1607 with the subsequent B<--send*> option to the target.
1608
1609 =item --expect-re=I<regex>
1610
1611 When target's output matches regular expression I<regex>, send the
1612 string specified with the subsequent B<--send*> option to the target.
1613
1614 =item --expect-raw=I<perl-code>
1615
1616 Provides direct control over Perl's Expect module.
1617
1618 =item --send=I<string>
1619
1620 Send I<string> to the target after the previously specified
1621 B<--expect*> was matched in the target's output. The I<string> may
1622 contain escape sequences such as "\n".
1623
1624 Note that I<string> is actually interpreted by Perl, so it can contain
1625 much more that escape sequences. This behavior may change in the
1626 future.
1627
1628 Example: C<--expect='login: ' --send='root\n'>
1629
1630 =item --sendcont=I<string>
1631
1632 Similar to B<--send> but continue expecting more input.
1633
1634 Example: C<--expect='Continue?' --sendcont='yes\n'>
1635
1636 =back
1637
1638 =head1 NOVABOOT SCRIPT SYNTAX
1639
1640 The syntax tries to mimic POSIX shell syntax. The syntax is defined
1641 with the following rules.
1642
1643 Lines starting with "#" and empty lines are ignored.
1644
1645 Lines that end with "\" are concatenated with the following line after
1646 removal of the final "\" and leading whitespace of the following line.
1647
1648 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
1649 expression) assign values to internal variables. See L</VARIABLES>
1650 section.
1651
1652 Lines starting with C<load> keyword represent modules to boot. The
1653 word after C<load> is a file name (relative to the build directory
1654 (see B<--build-dir>) of the module to load and the remaining words are
1655 passed to it as the command line parameters.
1656
1657 When the C<load> line ends with "<<WORD" then the subsequent lines
1658 until the line containing solely WORD are copied literally to the file
1659 named on that line. This is similar to shell's heredoc feature.
1660
1661 When the C<load> line ends with "< CMD" then command CMD is executed
1662 with F</bin/sh> and its standard output is stored in the file named on
1663 that line. The SRCDIR variable in CMD's environment is set to the
1664 absolute path of the directory containing the interpreted novaboot
1665 script.
1666
1667 Lines starting with C<run> keyword contain shell commands that are run
1668 during file generation phase. This is the same as the "< CMD" syntax
1669 for C<load> keyboard except that the command's output is not
1670 redirected to a file. The ordering of commands is the same as they
1671 appear in the novaboot script.
1672
1673 Example (Linux):
1674
1675   #!/usr/bin/env novaboot
1676   load bzImage console=ttyS0,115200
1677   run  make -C buildroot
1678   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
1679
1680 Example (NOVA User Land - NUL):
1681
1682   #!/usr/bin/env novaboot
1683   WVDESC=Example program
1684   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
1685                            verbose hostkeyb:0,0x60,1,12,2
1686   load bin/apps/hello.nul
1687   load hello.nulconfig <<EOF
1688   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
1689   rom://bin/apps/hello.nul
1690   EOF
1691
1692 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
1693 F<hello.nulconfig>. sigma0 receives some command line parameters and
1694 F<hello.nulconfig> file is generated on the fly from the lines between
1695 C<<<EOF> and C<EOF>.
1696
1697 =head2 VARIABLES
1698
1699 The following variables are interpreted in the novaboot script:
1700
1701 =over 8
1702
1703 =item BUILDDIR
1704
1705 Novaboot chdir()s to this directory before file generation phase. The
1706 directory name specified here is relative to the build directory
1707 specified by other means (see L</--build-dir>).
1708
1709 =item EXITON
1710
1711 Assigning this variable has the same effect as specifying L</--exiton>
1712 option.
1713
1714 =item HYPERVISOR_PARAMS
1715
1716 Parameters passed to hypervisor. The default value is "serial", unless
1717 overridden in configuration file.
1718
1719 =item KERNEL
1720
1721 The kernel to use instead of the hypervisor specified in the
1722 configuration file with the C<$hypervisor> variable. The value should
1723 contain the name of the kernel image as well as its command line
1724 parameters. If this variable is defined and non-empty, the variable
1725 HYPERVISOR_PARAMS is not used.
1726
1727 =item QEMU
1728
1729 Use a specific qemu binary (can be overridden with B<-Q>) and flags
1730 when booting this script under qemu. If QEMU_FLAGS variable is also
1731 specified flags specified in QEMU variable are replaced by those in
1732 QEMU_FLAGS.
1733
1734 =item QEMU_FLAGS
1735
1736 Use specific qemu flags (can be overridden with B<-q>).
1737
1738 =item WVDESC
1739
1740 Description of the wvtest-compliant program.
1741
1742 =item WVTEST_TIMEOUT
1743
1744 The timeout in seconds for WvTest harness. If no complete line appears
1745 in the test output within the time specified here, the test fails. It
1746 is necessary to specify this for long running tests that produce no
1747 intermediate output.
1748
1749 =back
1750
1751 =head1 CONFIGURATION FILE
1752
1753 Novaboot can read its configuration from one or more files. By
1754 default, novaboot looks for files named F<.novaboot> as described in
1755 L</Configuration reading phase>. Alternatively, configuration file
1756 location can be specified with the B<-c> switch or with the
1757 NOVABOOT_CONFIG environment variable. The configuration file has perl
1758 syntax and should set values of certain Perl variables. The current
1759 configuration can be dumped with the B<--dump-config> switch. Some
1760 configuration variables can be overridden by environment variables
1761 (see below) or by command line switches.
1762
1763 Supported configuration variables include:
1764
1765 =over 8
1766
1767 =item $builddir
1768
1769 Build directory location relative to the location of the configuration
1770 file.
1771
1772 =item $default_target
1773
1774 Default target (see below) to use when no target is explicitly
1775 specified on command line with the B<--target> option.
1776
1777 =item %targets
1778
1779 Hash of target definitions to be used with the B<--target> option. The
1780 key is the identifier of the target, the value is the string with
1781 command line options. For instance, if the configuration file contains:
1782
1783  $targets{'mybox'} = '--server=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
1784
1785 then the following two commands are equivalent:
1786
1787  ./script --server=boot:/tftproot --serial=/dev/ttyUSB0 --grub
1788  ./script -t mybox
1789
1790 =back
1791
1792 =head1 ENVIRONMENT VARIABLES
1793
1794 Some options can be specified not only via config file or command line
1795 but also through environment variables. Environment variables override
1796 the values from configuration file and command line parameters
1797 override the environment variables.
1798
1799 =over 8
1800
1801 =item NOVABOOT_CONFIG
1802
1803 Name of the novaboot configuration file to use instead of the default
1804 one(s).
1805
1806 =item NOVABOOT_CONFIG_DIR
1807
1808 Name of the novaboot configuration directory. When not specified
1809 F</etc/novaboot.d> is used.
1810
1811 =item NOVABOOT_BENDER
1812
1813 Defining this variable has the same meaning as B<--bender> option.
1814
1815 =back
1816
1817 =head1 AUTHORS
1818
1819 Michal Sojka <sojka@os.inf.tu-dresden.de>