novaboot

   1 #!/usr/bin/env perl
   2
   3 # This program is free software: you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation, either version 2 of the License, or
   6 # (at your option) any later version.
   7
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 ## Initialization
  17
  18 use strict;
  19 use warnings;
  20 use warnings (exists $ENV{NOVABOOT_TEST} ? (FATAL => 'all') : ());
  21 use Getopt::Long qw(GetOptionsFromString GetOptionsFromArray);
  22 use Pod::Usage;
  23 use File::Basename;
  24 use File::Spec;
  25 use IO::Handle;
  26 use Time::HiRes("usleep");
  27 use Socket;
  28 use FileHandle;
  29 use IPC::Open2;
  30 use POSIX qw(:errno_h sysconf);
  31 use Cwd qw(getcwd abs_path);
  32 use Expect;
  33
  34 # always flush
  35 $| = 1;
  36
  37 my $invocation_dir = $ENV{PWD} || getcwd();
  38
  39 # We prefer using PWD, to use nicer paths names with symbolic links.
  40 # However, when executed from 'make -C dir', PWD may contain the make
  41 # invocation path, not the real invocation path with dir at the end.
  42 # We fix that here.
  43 if (abs_path($ENV{PWD}) ne abs_path(getcwd())) {
  44     $invocation_dir = getcwd();
  45 }
  46
  47 ## Configuration file handling
  48
  49 # Default configuration
  50 $CFG::hypervisor = "";
  51 $CFG::hypervisor_params = "serial";
  52 $CFG::genisoimage = "genisoimage";
  53 $CFG::qemu = 'qemu-system-i386 -cpu coreduo -smp 2';
  54 $CFG::default_target = '';
  55 $CFG::netif = 'eth0';
  56 %CFG::targets = (
  57     'qemu' => '--qemu',
  58     "tud" => '--copy=erwin.inf.tu-dresden.de:~sojka/boot/novaboot --rsync-flags="--chmod=Dg+s,ug+w,o-w,+rX --rsync-path=\"umask 002 && rsync\"" --grub --grub-prefix=(nd)/tftpboot/sojka/novaboot --grub-preamble="timeout 0" --concat --iprelay=141.76.48.80:2324 --scriptmod=s/\\\\bhostserial\\\\b/hostserialpci/g',
  59     "novabox" => '--ssh=novabox@rtime.felk.cvut.cz',
  60     "localhost" => '--scriptmod=s/console=tty[A-Z0-9,]+// --copy=/boot/novaboot/$NAME --grub2 --grub-prefix=/boot/novaboot/$NAME --grub2-prolog="  set root=\'(hd0,msdos1)\'"',
  61     "ryu" =>  '--uboot --uboot-init="mw f0000b00 \${psc_cfg}; sleep 1" --uboot-addr kernel=800000 --uboot-addr ramdisk=b00000 --uboot-addr fdt=7f0000',
  62     "ryuglab" => '--target ryu --ssh=ryu@pc-sojkam.felk.cvut.cz',
  63     "ryulocal" => '--target ryu --dhcp-tftp --serial --reset-cmd="if which dtrrts; then dtrrts $NB_SERIAL 0 1; sleep 0.1; dtrrts $NB_SERIAL 1 1; fi"',
  64     );
  65
  66 {
  67     my %const;
  68     $const{linux}->{_SC_NPROCESSORS_CONF} = 83;
  69     my $nproc = sysconf($const{$^O}->{_SC_NPROCESSORS_CONF});
  70
  71     $CFG::scons = "scons -j$nproc";
  72     $CFG::make = "make -j$nproc";
  73 }
  74
  75 my $builddir;
  76
  77 sub read_config($) {
  78     my ($cfg) = @_;
  79     {
  80         package CFG; # Put config data into a separate namespace
  81
  82         my $rc = do($cfg);
  83
  84         # Check for errors
  85         if ($@) {
  86             die("ERROR: Failure compiling '$cfg' - $@");
  87         } elsif (! defined($rc)) {
  88             die("ERROR: Failure reading '$cfg' - $!");
  89         } elsif (! $rc) {
  90             die("ERROR: Failure processing '$cfg'");
  91         }
  92     }
  93     $builddir = File::Spec->rel2abs($CFG::builddir, dirname($cfg)) if defined $CFG::builddir;
  94     print STDERR "novaboot: Read $cfg\n";
  95 }
  96
  97 my @cfgs;
  98 {
  99     # We don't use $0 here, because it points to the novaboot itself and
 100     # not to the novaboot script. The problem with this approach is that
 101     # when a script is run as "novaboot <options> <script>" then $ARGV[0]
 102     # contains the first option. Hence the -f check.
 103     my $dir = File::Spec->rel2abs($ARGV[0] && -f $ARGV[0] ? dirname($ARGV[0]) : '', $invocation_dir);
 104     while ((-d $dir || -l $dir ) && $dir ne "/") {
 105         push @cfgs, "$dir/.novaboot" if -r "$dir/.novaboot";
 106         my @dirs = File::Spec->splitdir($dir);
 107         $dir = File::Spec->catdir(@dirs[0..$#dirs-1]);
 108     }
 109     @cfgs = reverse @cfgs;
 110
 111     my $xdg_config_home = $ENV{'XDG_CONFIG_HOME'} || $ENV{'HOME'}.'/.config';
 112     unshift(@cfgs, "$xdg_config_home/novaboot") if -r "$xdg_config_home/novaboot";
 113
 114     $dir = $ENV{'NOVABOOT_CONFIG_DIR'} || '/etc/novaboot.d';
 115     if (opendir(my $dh, $dir)) {
 116         my @etccfg = map { "$dir/$_" } grep { /^[-_a-zA-Z0-9]+$/ && -f "$dir/$_" } readdir($dh);
 117         closedir $dh;
 118         @etccfg = sort(@etccfg);
 119         @cfgs = ( @etccfg, @cfgs );
 120     }
 121 }
 122 my $cfg = $ENV{'NOVABOOT_CONFIG'};
 123 Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 124 GetOptions ("config|c=s" => \$cfg);
 125 read_config($_) foreach $cfg or @cfgs;
 126
 127 ## Command line handling
 128
 129 my $explicit_target = $ENV{'NOVABOOT_TARGET'};
 130 GetOptions ("target|t=s" => \$explicit_target);
 131
 132 # Variables for command line options
 133 my ($amt, @append, $bender, @chainloaders, $concat, $config_name_opt, $dhcp_tftp, $dump_opt, $dump_config, @exiton, $exiton_timeout, @expect_raw, $final_eol, $gen_only, $grub_config, $grub_prefix, $grub_preamble, $grub2_prolog, $grub2_config, $help, $ider, $interaction, $iprelay, $iprelay_cmd, $iso_image, $interactive, $kernel_opt, $make, $man, $netif, $no_file_gen, $off_opt, $on_opt, $pulsar, $pulsar_root, $qemu, $qemu_append, $qemu_flags_cmd, @remote_cmd, $remote_expect, $remote_expect_silent, $remote_expect_timeout, $reset, @reset_cmd, $reset_send, $rom_prefix, $rsync_flags, @scriptmod, $scons, $serial, $server, $stty, $tftp, $tftp_port, $uboot, %uboot_addr, $uboot_cmd, @uboot_init, $uboot_stop_key);
 134
 135 my ($target_reset, $target_power_on, $target_power_off);
 136
 137 # Default values of certain command line options
 138 %uboot_addr = (
 139     'kernel'  => '${kernel_addr_r}',
 140     'ramdisk' => '${ramdisk_addr_r}',
 141     'fdt'     => '${fdt_addr_r}',
 142     );
 143 $rsync_flags = '';
 144 $rom_prefix = 'rom://';
 145 $stty = 'raw -crtscts -onlcr -echo 115200';
 146 $reset = 1;                     # Reset target by default
 147 $interaction = 1;               # Perform target interaction by default
 148 $final_eol = 1;
 149 $netif = $CFG::netif;
 150 $remote_expect_timeout = -1;
 151
 152 my @expect_seen = ();
 153 sub handle_expect
 154 {
 155     my ($n, $v) = @_;
 156     push(@expect_seen, '-re') if $n eq "expect-re";
 157     push(@expect_seen, $v);
 158 }
 159
 160 sub handle_send
 161 {
 162     my ($n, $v) = @_;
 163     unless (@expect_seen) { die("No --expect before --send"); }
 164     my $ret = ($n eq "sendcont") ? exp_continue : 0;
 165     unshift(@expect_raw, sub { shift->send(eval("\"$v\"")); $ret; });
 166     unshift(@expect_raw, @expect_seen);
 167     @expect_seen = ();
 168 }
 169
 170 # Options which can be safely specified on the server (via --ssh),
 171 # i.e. which cannot cause unwanted local code execution etc.
 172 my %opt_spec_safe = (
 173     "grub|g:s"       => \$grub_config,
 174     "grub-preamble=s"=> \$grub_preamble,
 175     "grub2-prolog=s" => \$grub2_prolog,
 176     "grub2:s"        => \$grub2_config,
 177     "prefix|grub-prefix=s" => \$grub_prefix,
 178     "pulsar-root=s"  => \$pulsar_root,
 179     "pulsar|p:s"     => \$pulsar,
 180     "remote-expect=s"=> \$remote_expect,
 181     "remote-expect-silent=s"=> sub { $remote_expect=$_[1]; $remote_expect_silent=1; },
 182     "remote-expect-timeout=i"=> \$remote_expect_timeout,
 183     "uboot-addr=s"   => \%uboot_addr,
 184     "uboot-cmd=s"    => \$uboot_cmd,
 185     "uboot-stop-key=s" => \$uboot_stop_key,
 186     "uboot-init=s"   => sub { push @uboot_init, { command => $_[1] }; },
 187     "uboot:s"        => \$uboot,
 188     );
 189
 190 my %opt_spec = (
 191     %opt_spec_safe,
 192     "amt=s"          => \$amt,
 193     "append|a=s"     => \@append,
 194     "bender|b"       => \$bender,
 195     "build-dir=s"    => sub { my ($n, $v) = @_; $builddir = File::Spec->rel2abs($v); },
 196     "concat"         => \$concat,
 197     "chainloader=s"  => \@chainloaders,
 198     "dhcp-tftp|d"    => \$dhcp_tftp,
 199     "dump"           => \$dump_opt,
 200     "dump-config"    => \$dump_config,
 201     "exiton=s"       => \@exiton,
 202     "exiton-timeout=i"=> \$exiton_timeout,
 203     "exiton-re=s"    => sub { my ($n, $v) = @_; push(@exiton, '-re', $v); },
 204     "expect=s"       => \&handle_expect,
 205     "expect-re=s"    => \&handle_expect,
 206     "expect-raw=s"   => sub { my ($n, $v) = @_; unshift(@expect_raw, eval($v)); },
 207     "final-eol!"     => \$final_eol,
 208     "gen-only"       => \$gen_only,
 209     "ider"           => \$ider,
 210     "interaction!"   => \$interaction,
 211     "iprelay=s"      => \$iprelay,
 212     "iprelay-cmd=s"  => \$iprelay_cmd,
 213     "iso:s"          => \$iso_image,
 214     "kernel|k=s"     => \$kernel_opt,
 215     "interactive|i"  => \$interactive,
 216     "name=s"         => \$config_name_opt,
 217     "make|m:s"       => \$make,
 218     "netif=s"        => \$netif,
 219     "no-file-gen"    => \$no_file_gen,
 220     "off"            => \$off_opt,
 221     "on"             => \$on_opt,
 222     "qemu|Q:s"       => \$qemu,
 223     "qemu-append=s"  => \$qemu_append,
 224     "qemu-flags|q=s" => \$qemu_flags_cmd,
 225     "remote-cmd=s"   => sub { @remote_cmd = ($_[1]); },
 226     "reset!"         => \$reset,
 227     "reset-cmd=s"    => sub { @reset_cmd = ($_[1]); },
 228     "reset-send=s"   => \$reset_send,
 229     "rsync-flags=s"  => \$rsync_flags,
 230     "scons:s"        => \$scons,
 231     "scriptmod=s"    => \@scriptmod,
 232     "send=s"         => \&handle_send,
 233     "sendcont=s"     => \&handle_send,
 234     "serial|s:s"     => \$serial,
 235     "server:s"       => \$server,
 236     "copy:s"         => \$server,
 237     "ssh:s"          => \&handle_novaboot_server,
 238     "strip-rom"      => sub { $rom_prefix = ''; },
 239     "stty=s"         => \$stty,
 240     "tftp"           => \$tftp,
 241     "tftp-port=i"    => \$tftp_port,
 242     "no-uboot"       => sub { undef $uboot; },
 243     "h"              => \$help,
 244     "help"           => \$man,
 245     );
 246
 247 sub handle_novaboot_server
 248 {
 249     my ($n, $val) = @_;
 250     my $xdg_runtime_dir = $ENV{XDG_RUNTIME_DIR} || '/var/run';
 251     my $ssh_ctl_path = "${xdg_runtime_dir}/novaboot$$";
 252
 253     @remote_cmd = ('ssh', '-tt', '-M', '-S', $ssh_ctl_path, $val, 'console');
 254     $remote_expect = "novaboot-shell: Connected";
 255     $server = "$val:";
 256     $rsync_flags = "--rsh='ssh -S \'${ssh_ctl_path}\''";
 257     ($grub_prefix = $val) =~ s|(.*)@.*|\/$1\/| if index($val, '@') != -1;
 258     @reset_cmd = ('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'reset');
 259
 260     $target_power_off = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'off'); };
 261     $target_power_on  = sub { system_verbose('ssh', '-tt', '-S', $ssh_ctl_path, $val, 'on'); };
 262
 263     my $cmd = "ssh '${val}' get-config";
 264     print STDERR "novaboot: Running: $cmd\n";
 265     my @target_config = qx($cmd  < /dev/null);
 266     if ($?) { die("Cannot get target configuration from the server"); }
 267     printf "novaboot: Received configuration from the server:%s\n", (!@target_config) ? " empty" : "";
 268     foreach (@target_config) { chomp; print "  $_\n"; }
 269
 270     my $p = Getopt::Long::Parser->new;
 271     $p->configure(qw/no_ignore_case no_pass_through/);
 272     $p->getoptionsfromarray(\@target_config, %opt_spec_safe) or die("Error processing configuration from the server");
 273
 274     if (scalar @target_config) { die "Unsuported configuration received from the server: ".join(", ", @target_config); }
 275 }
 276
 277 # First process target options
 278 {
 279     my $t = defined($explicit_target) ? $explicit_target : $CFG::default_target;
 280     my @target_expanded;
 281     Getopt::Long::Configure(qw/no_ignore_case pass_through/);
 282     while ($t) {
 283         exists $CFG::targets{$t} or die("Unknown target '$t' (valid targets are: ".join(", ", sort keys(%CFG::targets)).")");
 284
 285         undef $explicit_target;
 286         my ($ret, $remaining_args) = GetOptionsFromString ($CFG::targets{$t}, ("target|t=s" => \$explicit_target));
 287         if (!$ret) { die "Error parsing target $t option"; }
 288         push(@target_expanded, @$remaining_args);
 289         $t = $explicit_target;
 290     }
 291
 292     my @args = (@target_expanded, @ARGV);
 293     print STDERR "novaboot: Effective options: @args\n";
 294
 295     Getopt::Long::Configure(qw/no_ignore_case no_pass_through/);
 296     GetOptionsFromArray(\@target_expanded, %opt_spec) or die ("Error in target definition");
 297 }
 298
 299 # Then process other command line options - some of them may override
 300 # what was specified by the target
 301 GetOptions %opt_spec or die("Error in command line arguments");
 302 pod2usage(1) if $help;
 303 pod2usage(-exitstatus => 0, -verbose => 2) if $man;
 304
 305 ### Dump sanitized configuration (if requested)
 306
 307 if ($dump_config) {
 308     use Data::Dumper;
 309     $Data::Dumper::Indent=1;
 310     print "# This file is in perl syntax.\n";
 311     foreach my $key(sort(keys(%CFG::))) { # See "Symbol Tables" in perlmod(1)
 312         if (defined ${$CFG::{$key}}) { print Data::Dumper->Dump([${$CFG::{$key}}], ["*$key"]); }
 313         if (        @{$CFG::{$key}}) { print Data::Dumper->Dump([\@{$CFG::{$key}}], ["*$key"]); }
 314         if (        %{$CFG::{$key}}) { print Data::Dumper->Dump([\%{$CFG::{$key}}], ["*$key"]); }
 315     }
 316     print "1;\n";
 317     exit;
 318 }
 319
 320 ### Sanitize configuration
 321
 322 if ($interactive && !-t STDIN) {
 323     die("novaboot: Interactive mode not supported when not on terminal");
 324 }
 325
 326 if (defined $config_name_opt && scalar(@ARGV) > 1) { die "You cannot use --name with multiple scripts"; }
 327
 328 if ($ider) {
 329     $iso_image //= ''; # IDE-R needs an ISO image
 330     if (!defined $amt) { die "Error: --ider requires --amt"; }
 331 }
 332
 333 {
 334     my %input_opts = ('--iprelay'    => \$iprelay,
 335                       '--iprelay-cmd'=> \$iprelay_cmd,
 336                       '--serial'     => \$serial,
 337                       '--remote-cmd' => (@remote_cmd ? \$remote_cmd[0] : undef),
 338                       '--amt'        => \$amt);
 339     my @opts = grep(defined(${$input_opts{$_}}) , keys %input_opts);
 340
 341     die("novaboot: More than one target connection option: ".join(', ', @opts)) if scalar @opts > 1;
 342 }
 343
 344 # Default options
 345 if (defined $serial) {
 346     $serial ||= "/dev/ttyUSB0";
 347     $ENV{NB_SERIAL} = $serial;
 348 }
 349 if (defined $grub_config) { $grub_config ||= "menu.lst"; }
 350 if (defined $grub2_config) { $grub2_config ||= "grub.cfg"; }
 351
 352 ## Parse the novaboot script(s)
 353 my @scripts;
 354 my $file;
 355 my $EOF;
 356 my $last_fn = '';
 357 my ($modules, $variables, $generated, $copy, $chainload, $continuation) = ([], {}, [], []);
 358 my $skip_reading = defined($on_opt) || defined($off_opt);
 359 while (!$skip_reading && ($_ = <>)) {
 360     if ($ARGV ne $last_fn) { # New script
 361         die "Missing EOF in $last_fn" if $file;
 362         die "Unfinished line in $last_fn" if $continuation;
 363         $last_fn = $ARGV;
 364         push @scripts, { 'filename' => $ARGV,
 365                          'modules' => $modules = [],
 366                          'variables' => $variables = {},
 367                          'generated' => $generated = [],
 368                          'copy' => $copy = [],
 369                          'chainload' => $chainload = [],
 370         };
 371
 372     }
 373     chomp();
 374     next if /^#/ || /^\s*$/;    # Skip comments and empty lines
 375
 376     $_ =~ s/^[[:space:]]*// if ($continuation);
 377
 378     if (/\\$/) {                # Line continuation
 379         $continuation .= substr($_, 0, length($_)-1);
 380         next;
 381     }
 382
 383     if ($continuation) {        # Last continuation line
 384         $_ = $continuation . $_;
 385         $continuation = '';
 386     }
 387
 388     foreach my $mod(@scriptmod) { eval $mod; }
 389
 390     if ($file && $_ eq $EOF) {  # Heredoc end
 391         undef $file;
 392         next;
 393     }
 394     if ($file) {                # Heredoc content
 395         push @{$file}, "$_\n";
 396         next;
 397     }
 398     if (/^([A-Z_]+)=(.*)$/) {   # Internal variable
 399         $$variables{$1} = $2;
 400         push(@exiton, $2) if ($1 eq "EXITON");
 401         $interaction = $2 if ($1 eq "INTERACTION");
 402         next;
 403     }
 404     sub process_load_copy($) {
 405         die("novaboot: '$last_fn' line $.: Missing file name\n") unless /^[^ <]+/;
 406         if (/^([^ ]*)(.*?)[[:space:]]*<<([^ ]*)$/) { # Heredoc start
 407             $file = [];
 408             push @$generated, {filename => $1, content => $file};
 409             $EOF = $3;
 410             return "$1$2";
 411         }
 412         if (/^([^ ]*)(.*?)[[:space:]]*< ?(.*)$/) { # Command substitution
 413             push @$generated, {filename => $1, command => $3};
 414             return "$1$2";
 415         }
 416         s/\s*$//;               # Strip trailing whitespace
 417         return $_;
 418     }
 419     if (s/^load *//) {          # Load line
 420         push @$modules, process_load_copy($_);
 421         next;
 422     }
 423     if (s/^copy *//) {          # Copy line
 424         push @$copy, process_load_copy($_);
 425         next;
 426     }
 427     if (s/^chld *//) {          # Chainload line
 428         push @$chainload, process_load_copy($_);
 429         next;
 430     }
 431     if (/^run (.*)/) {          # run line
 432         push @$generated, {command => $1};
 433         next;
 434     }
 435     if (/^uboot(?::([0-9]+)s)? +(< *)?(.*)/) {  # uboot line
 436         # TODO: If U-Boot supports some interactive menu, it might
 437         # make sense to store uboot lines per novaboot script.
 438         my ($timeout, $redir, $string, $dest) = ($1, $2, $3);
 439         if ($string =~ /(.*) *> *(.*)/) {
 440             $string = $1;
 441             $dest = $2;
 442         }
 443         push @uboot_init, { command => $redir ? "" : $string,
 444                             system =>  $redir ? $string : "",
 445                             timeout => $timeout,
 446                             dest => $dest,
 447         };
 448         next;
 449     }
 450
 451     die("novaboot: Cannot parse script '$last_fn' line $.. Didn't you forget 'load' keyword?\n");
 452 }
 453 # use Data::Dumper;
 454 # print Dumper(\@scripts);
 455
 456 foreach my $script (@scripts) {
 457     $modules = $$script{modules};
 458     @$modules[0] =~ s/^[^ ]*/$kernel_opt/ if $kernel_opt;
 459     @$modules[0] .= ' ' . join(' ', @append) if @append;
 460
 461     my $kernel;
 462     if (exists $variables->{KERNEL}) {
 463         $kernel = $variables->{KERNEL};
 464     } else {
 465         if ($CFG::hypervisor) {
 466             $kernel = $CFG::hypervisor . " ";
 467             if (exists $variables->{HYPERVISOR_PARAMS}) {
 468                 $kernel .= $variables->{HYPERVISOR_PARAMS};
 469             } else {
 470                 $kernel .= $CFG::hypervisor_params;
 471             }
 472         }
 473     }
 474     @$modules = ($kernel, @$modules) if $kernel;
 475     @$modules = (@chainloaders, @$modules);
 476     @$modules = ("bin/boot/bender", @$modules) if ($bender || defined $ENV{'NOVABOOT_BENDER'});
 477 }
 478
 479 if ($dump_opt) {
 480     foreach my $script (@scripts) {
 481         print join("\n", @{$$script{modules}})."\n";
 482     }
 483     exit(0);
 484 }
 485
 486 ## Helper functions
 487
 488 sub generate_configs($$$) {
 489     my ($base, $generated, $filename) = @_;
 490     if ($base) { $base = "$base/"; };
 491     foreach my $g(@$generated) {
 492       if (exists $$g{content}) {
 493         my $config = $$g{content};
 494         my $fn = $$g{filename};
 495         open(my $f, '>', $fn) || die("$fn: $!");
 496         map { s|\brom://([^ ]*)|$rom_prefix$base$1|g; print $f "$_"; } @{$config};
 497         close($f);
 498         print STDERR "novaboot: Created $fn\n";
 499       } elsif (exists $$g{command} && ! $no_file_gen) {
 500         $ENV{SRCDIR} = dirname(File::Spec->rel2abs( $filename, $invocation_dir ));
 501         if (exists $$g{filename}) {
 502             system_verbose("( $$g{command} ) > $$g{filename}");
 503         } else {
 504             system_verbose($$g{command});
 505         }
 506       }
 507     }
 508 }
 509
 510 sub generate_grub_config($$$$;$)
 511 {
 512     my ($filename, $title, $base, $modules_ref, $preamble) = @_;
 513     if ($base) { $base = "$base/"; };
 514     open(my $fg, '>', $filename) or die "$filename: $!";
 515     print $fg "$preamble\n" if $preamble;
 516     print $fg "title $title\n" if $title;
 517     #print $fg "root $base\n"; # root doesn't really work for (nd)
 518     my $first = 1;
 519     foreach (@$modules_ref) {
 520         if ($first) {
 521             $first = 0;
 522             my ($kbin, $kcmd) = split(' ', $_, 2);
 523             $kcmd = '' if !defined $kcmd;
 524             print $fg "kernel ${base}$kbin $kcmd\n";
 525         } else {
 526             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 527             print $fg "module $base$_\n";
 528         }
 529     }
 530     close($fg);
 531     print("novaboot: Created $builddir/$filename\n");
 532     return $filename;
 533 }
 534
 535 sub generate_syslinux_config($$$$)
 536 {
 537     my ($filename, $title, $base, $modules_ref) = @_;
 538     if ($base && $base !~ /\/$/) { $base = "$base/"; };
 539     open(my $fg, '>', $filename) or die "$filename: $!";
 540     print $fg "LABEL $title\n";
 541     #TODO print $fg "MENU LABEL $human_readable_title\n";
 542
 543     my ($kbin, $kcmd) = split(' ', @$modules_ref[0], 2);
 544
 545     if (system("file $kbin|grep 'Linux kernel'") == 0) {
 546         my $initrd = @$modules_ref[1];
 547         die('Too many "load" lines for Linux kernel') if (scalar @$modules_ref > 2);
 548         print $fg "LINUX $base$kbin\n";
 549         print $fg "APPEND $kcmd\n";
 550         print $fg "INITRD $base$initrd\n";
 551     } else {
 552         print $fg "KERNEL mboot.c32\n";
 553         my @append;
 554         foreach (@$modules_ref) {
 555             s|\brom://([^ ]*)|$rom_prefix$base$1|g; # Translate rom:// files - needed for vdisk parameter of sigma0
 556             push @append, "$base$_";
 557             print $fg "APPEND ".join(' --- ', @append)."\n";
 558         }
 559     }
 560     #TODO print $fg "TEXT HELP\n";
 561     #TODO print $fg "some help here\n";
 562     #TODO print $fg "ENDTEXT\n";
 563     close($fg);
 564     print("novaboot: Created $builddir/$filename\n");
 565     return $filename;
 566 }
 567
 568 sub generate_grub2_config($$$$;$$)
 569 {
 570     my ($filename, $title, $base, $modules_ref, $preamble, $prolog) = @_;
 571     if ($base && substr($base,-1,1) ne '/') { $base = "$base/"; };
 572     open(my $fg, '>', $filename) or die "$filename: $!";
 573     print $fg "$preamble\n" if $preamble;
 574     $title ||= 'novaboot';
 575     print $fg "menuentry $title {\n";
 576     print $fg "$prolog\n" if $prolog;
 577     my $first = 1;
 578     foreach (@$modules_ref) {
 579         if ($first) {
 580             $first = 0;
 581             my ($kbin, $kcmd) = split(' ', $_, 2);
 582             $kcmd = '' if !defined $kcmd;
 583             print $fg "  multiboot ${base}$kbin $kcmd\n";
 584         } else {
 585             my @args = split;
 586             # GRUB2 doesn't pass filename in multiboot info so we have to duplicate it here
 587             $_ = join(' ', ($args[0], @args));
 588             s|\brom://|$rom_prefix|g; # We do not need to translate path for GRUB2
 589             print $fg "  module $base$_\n";
 590         }
 591     }
 592     print $fg "}\n";
 593     close($fg);
 594     print("novaboot: Created $builddir/$filename\n");
 595     return $filename;
 596 }
 597
 598 sub generate_pulsar_config($$$)
 599 {
 600     my ($filename, $modules_ref, $chainload_ref) = @_;
 601     open(my $fg, '>', $filename) or die "$filename: $!";
 602     print $fg "root $pulsar_root\n" if defined $pulsar_root;
 603     if (scalar(@$chainload_ref) > 0) {
 604         print $fg "chld $$chainload_ref[0]\n";
 605     } else {
 606         my $first = 1;
 607         my ($kbin, $kcmd);
 608         foreach (@$modules_ref) {
 609             if ($first) {
 610                 $first = 0;
 611                 ($kbin, $kcmd) = split(' ', $_, 2);
 612                 $kcmd = '' if !defined $kcmd;
 613             } else {
 614                 my @args = split;
 615                 s|\brom://|$rom_prefix|g;
 616                 print $fg "load $_\n";
 617             }
 618         }
 619         # Put kernel as last - this is needed for booting Linux and has no influence on non-Linux OSes
 620         print $fg "exec $kbin $kcmd\n";
 621     }
 622     close($fg);
 623     print("novaboot: Created $builddir/$filename\n");
 624     return $filename;
 625 }
 626
 627 sub shell_cmd_string(@)
 628 {
 629     if (scalar(@_) == 1) {
 630         return $_[0];
 631     } else {
 632         return join(' ', map((/^[-_=a-zA-Z0-9\/\.\+]+$/ ? "$_" : "'$_'"), @_));
 633     }
 634 }
 635
 636 sub exec_verbose(@)
 637 {
 638     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 639     exec(@_);
 640     exit(1); # should not be reached
 641 }
 642
 643 sub system_verbose
 644 {
 645     print STDERR "novaboot: Running: ".shell_cmd_string(@_)."\n";
 646     my $ret = system(@_);
 647     if ($ret & 0x007f) { die("Command terminated by a signal"); }
 648     if ($ret & 0xff00) {die("Command exit with non-zero exit code"); }
 649     if ($ret) { die("Command failure $ret"); }
 650 }
 651
 652 sub trim($) {
 653     my ($str) = @_;
 654     $str =~ s/^\s+|\s+$//g;
 655     return $str
 656 }
 657
 658 ## WvTest headline
 659
 660 if (exists $variables->{WVDESC}) {
 661     print STDERR "Testing \"$variables->{WVDESC}\" in $last_fn:\n";
 662 } elsif ($last_fn =~ /\.wv$/) {
 663     print STDERR "Testing \"all\" in $last_fn:\n";
 664 }
 665
 666 ## Connect to the target and check whether it is not occupied
 667
 668 # We have to do this before file generation phase, because file
 669 # generation is intermixed with file deployment phase and we want to
 670 # check whether the target is not used by somebody else before
 671 # deploying files. Otherwise, we may rewrite other user's files on a
 672 # boot server.
 673
 674 my $exp; # Expect object to communicate with the target over serial line
 675
 676 sub kill_exp_on_signal() {
 677     # Sometimes, under unclear circumstances (e.g. when running under
 678     # both Jenkins and Robotframework), novaboot does not terminate
 679     # console command when killed. The console is then blocked by the
 680     # stale process forever. Theoretically, this should not happen,
 681     # because when novaboot is killed, console command's controlling
 682     # terminal sends SIGHUP to the console command and the command
 683     # should terminate. It seems that at least SSH sometimes ignores
 684     # HUP and does not terminate. The code below seems to work around
 685     # that problem by killing the process immediately with SIGTERM,
 686     # which is not ignored.
 687
 688     sub kill_console { kill TERM => $exp->pid if $exp->pid; die "Terminated by SIG$_[0]"; };
 689
 690     # For our Jenkins/Robotframework use case, it was sufficient to
 691     # handle the TERM signal, but to be on the safe side, we also
 692     # catch other signals.
 693     $SIG{TERM} = \&kill_console;
 694     $SIG{HUP} = \&kill_console;
 695     $SIG{INT} = \&kill_console;
 696     $SIG{QUIT} = \&kill_console;
 697 }
 698
 699
 700 my ($amt_user, $amt_password, $amt_host, $amt_port);
 701
 702 if (defined $iprelay || defined $iprelay_cmd) {
 703     if (defined $iprelay) {
 704         my $IPRELAY;
 705         $iprelay =~ /([.0-9]+)(:([0-9]+))?/;
 706         my $addr = $1;
 707         my $port = $3 || 23;
 708         my $paddr   = sockaddr_in($port, inet_aton($addr));
 709         my $proto   = getprotobyname('tcp');
 710         socket($IPRELAY, PF_INET, SOCK_STREAM, $proto)  || die "socket: $!";
 711         print STDERR "novaboot: Connecting to IP relay... ";
 712         connect($IPRELAY, $paddr)    || die "connect: $!";
 713         print STDERR "done\n";
 714         $exp = Expect->init(\*$IPRELAY);
 715         $exp->log_stdout(1);
 716     }
 717     if (defined $iprelay_cmd) {
 718         print STDERR "novaboot: Running: $iprelay_cmd\n";
 719         $exp = new Expect;
 720         $exp->raw_pty(1);
 721         $exp->spawn($iprelay_cmd);
 722         kill_exp_on_signal();
 723     }
 724
 725     while (1) {
 726         print $exp "\xFF\xF6";  # AYT
 727         my $connected = $exp->expect(20, # Timeout in seconds
 728                                      '<iprelayd: connected>',
 729                                      '-re', '<WEB51 HW[^>]*>')
 730             || die "iprelay connection: " . ($! || "timeout");
 731         last if $connected;
 732     }
 733
 734     sub relaycmd($$) {
 735         my ($relay, $onoff) = @_;
 736         die unless ($relay == 1 || $relay == 2);
 737
 738         my $cmd = ($relay == 1 ? 0x5 : 0x6) | ($onoff ? 0x20 : 0x10);
 739         return "\xFF\xFA\x2C\x32".chr($cmd)."\xFF\xF0";
 740     }
 741
 742     sub relayconf($$) {
 743         my ($relay, $onoff) = @_;
 744         die unless ($relay == 1 || $relay == 2);
 745         my $cmd = ($relay == 1 ? 0xdf : 0xbf) | ($onoff ? 0x00 : 0xff);
 746         return "\xFF\xFA\x2C\x97".chr($cmd)."\xFF\xF0";
 747     }
 748
 749     sub relay($$;$) {
 750         my ($relay, $onoff, $can_giveup) = @_;
 751         my $confirmation = '';
 752         $exp->log_stdout(0);
 753         print $exp relaycmd($relay, $onoff);
 754         my $confirmed = $exp->expect(20, # Timeout in seconds
 755                                      relayconf($relay, $onoff))
 756             || die "iprelay command: " . ($! || "timeout");
 757         if (!$confirmed) {
 758             if ($can_giveup) {
 759                 print("Relay confirmation timeout - ignoring\n");
 760             } else {
 761                 die "Relay confirmation timeout";
 762             }
 763         }
 764         $exp->log_stdout(1);
 765     }
 766
 767     $target_reset = sub {
 768         relay(2, 1, 1); # Reset the machine
 769         usleep(100000);
 770         relay(2, 0);
 771     };
 772
 773     $target_power_off = sub {
 774         relay(1, 1);            # Press power button
 775         usleep(6000000);        # Long press to switch off
 776         relay(1, 0);
 777     };
 778
 779     $target_power_on = sub {
 780         relay(1, 1);            # Press power button
 781         usleep(100000);         # Short press
 782         relay(1, 0);
 783     };
 784 }
 785 elsif ($serial) {
 786     my $CONN;
 787     system_verbose("stty -F $serial $stty");
 788     open($CONN, "+<", $serial) || die "open $serial: $!";
 789     $exp = Expect->init(\*$CONN);
 790 }
 791 elsif (@remote_cmd) {
 792     print STDERR "novaboot: Running: ".shell_cmd_string(@remote_cmd)."\n";
 793     $exp = Expect->spawn(@remote_cmd);
 794     kill_exp_on_signal();
 795 }
 796 elsif (defined $amt) {
 797     require LWP::UserAgent;
 798     require LWP::Authen::Digest;
 799
 800     sub genXML {
 801         my ($host, $username, $password, $schema, $className, $pstate) = @_;
 802         #AMT numbers for PowerStateChange (MNI => bluescreen on windows;-)
 803         my %pstates = ("on"        => 2,
 804                        "standby"   => 4,
 805                        "hibernate" => 7,
 806                        "off"       => 8,
 807                        "reset"     => 10,
 808                        "MNI"       => 11);
 809         return <<END;
 810                 <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope" xmlns:a="http://schemas.xmlsoap.org/ws/2004/08/addressing" xmlns:w="http://schemas.dmtf.org/wbem/wsman/1/wsman.xsd">
 811                 <s:Header><a:To>http://$host:16992/wsman</a:To>
 812                 <w:ResourceURI s:mustUnderstand="true">$schema</w:ResourceURI>
 813                 <a:ReplyTo><a:Address s:mustUnderstand="true">http://schemas.xmlsoap.org/ws/2004/08/addressing/role/anonymous</a:Address></a:ReplyTo>
 814                 <a:Action s:mustUnderstand="true">$schema$className</a:Action>
 815                 <w:MaxEnvelopeSize s:mustUnderstand="true">153600</w:MaxEnvelopeSize>
 816                 <a:MessageID>uuid:709072C9-609C-4B43-B301-075004043C7C</a:MessageID>
 817                 <w:Locale xml:lang="en-US" s:mustUnderstand="false" />
 818                 <w:OperationTimeout>PT60.000S</w:OperationTimeout>
 819                 <w:SelectorSet><w:Selector Name="Name">Intel(r) AMT Power Management Service</w:Selector></w:SelectorSet>
 820                 </s:Header><s:Body>
 821                 <p:RequestPowerStateChange_INPUT xmlns:p="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService">
 822                 <p:PowerState>$pstates{$pstate}</p:PowerState>
 823                 <p:ManagedElement><a:Address>http://$host:16992/wsman</a:Address>
 824                 <a:ReferenceParameters><w:ResourceURI>http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_ComputerSystem</w:ResourceURI>
 825                 <w:SelectorSet><w:Selector Name="Name">ManagedSystem</w:Selector></w:SelectorSet>
 826                 </a:ReferenceParameters></p:ManagedElement>
 827                 </p:RequestPowerStateChange_INPUT>
 828                 </s:Body></s:Envelope>
 829 END
 830     }
 831
 832     sub sendPOST {
 833         my ($host, $username, $password, $content) = @_;
 834
 835         my $ua = LWP::UserAgent->new();
 836         $ua->agent("novaboot");
 837
 838         my $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 839         my $res = $ua->request($req);
 840         die ("Unexpected AMT response: " . $res->status_line) unless $res->code == 401;
 841
 842         my ($realm) = $res->header("WWW-Authenticate") =~ /Digest realm="(.*?)"/;
 843         $ua->credentials("$host:16992", $realm, $username => $password);
 844
 845         # Create a request
 846         $req = HTTP::Request->new(POST => "http://$host:16992/wsman");
 847         $req->content_type('application/x-www-form-urlencoded');
 848         $req->content($content);
 849         $res = $ua->request($req);
 850         die ("AMT power change request failed: " . $res->status_line) unless $res->is_success;
 851         $res->content() =~ /<g:ReturnValue>(\d+)<\/g:ReturnValue>/;
 852         return $1;
 853     }
 854
 855     sub powerChange  {
 856         my ($host, $username, $password, $pstate)=@_;
 857         my $schema="http://schemas.dmtf.org/wbem/wscim/1/cim-schema/2/CIM_PowerManagementService";
 858         my $className="/RequestPowerStateChange";
 859         my $content = genXML($host, $username, $password ,$schema, $className, $pstate);
 860         return sendPOST($host, $username, $password, $content);
 861     }
 862
 863     ($amt_user,$amt_password,$amt_host,$amt_port) = ($amt =~ /(?:(.*?)(?::(.*))?@)?([^:]*)(?::([0-9]*))?/);;
 864     $amt_user ||= "admin";
 865     $amt_password ||= $ENV{'AMT_PASSWORD'} || die "AMT password not specified";
 866     $amt_host || die "AMT host not specified";
 867     $amt_port ||= 16994;
 868
 869
 870     $target_power_off = sub {
 871         $exp->close();
 872         my $result = powerChange($amt_host,$amt_user,$amt_password, "off");
 873         die "AMT power off failed (ReturnValue $result)" if $result != 0;
 874     };
 875
 876     $target_power_on = sub {
 877         my $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 878         die "AMT power on failed (ReturnValue $result)" if $result != 0;
 879     };
 880
 881     $target_reset = sub {
 882         my $result = powerChange($amt_host,$amt_user,$amt_password, "reset");
 883         if ($result != 0) {
 884             print STDERR "Warning: Cannot reset $amt_host, trying power on. ";
 885             $result = powerChange($amt_host,$amt_user,$amt_password, "on");
 886         }
 887         die "AMT reset failed (ReturnValue $result)" if $result != 0;
 888     };
 889
 890     my $cmd = "amtterm -u $amt_user -p $amt_password $amt_host $amt_port";
 891     print STDERR "novaboot: Running: $cmd\n" =~ s/\Q$amt_password\E/???/r;
 892     $exp = Expect->spawn($cmd);
 893     $exp->expect(10, "RUN_SOL") || die "Expect for 'RUN_SOL': " . ($! || "timeout");
 894 }
 895
 896
 897 if ($remote_expect) {
 898     $exp || die("No serial line connection");
 899     my $log = $exp->log_stdout;
 900     if (defined $remote_expect_silent) {
 901         $exp->log_stdout(0);
 902     }
 903     $exp->expect($remote_expect_timeout >= 0 ? $remote_expect_timeout : undef,
 904                  $remote_expect) || die "Expect for '$remote_expect':" . ($! || "timeout");;
 905     if (defined $remote_expect_silent) {
 906         $exp->log_stdout($log);
 907         print $exp->after() if $log;
 908     }
 909 }
 910
 911 if (@reset_cmd) {
 912     $target_reset = sub {
 913         system_verbose(@reset_cmd);
 914     };
 915 }
 916
 917 if (defined $reset_send) {
 918     $target_reset = sub {
 919         $reset_send =~ s/\\n/\n/g;
 920         $exp->send($reset_send);
 921     };
 922 }
 923
 924 if (defined $on_opt && defined $target_power_on) {
 925     &$target_power_on();
 926     exit;
 927 }
 928 if (defined $off_opt && defined $target_power_off) {
 929     print STDERR "novaboot: Switching the target off...\n";
 930     &$target_power_off();
 931     exit;
 932 }
 933
 934 $builddir ||= dirname(File::Spec->rel2abs( ${$scripts[0]}{filename})) if scalar @scripts;
 935 if (defined $builddir) {
 936     chdir($builddir) or die "Can't change directory to $builddir: $!";
 937     print STDERR "novaboot: Entering directory `$builddir'\n";
 938 } else {
 939     $builddir = $invocation_dir;
 940 }
 941
 942 ## File generation phase
 943 my (%files_iso, $menu_iso, $filename);
 944 my $config_name = '';
 945 my $prefix = '';
 946
 947 foreach my $script (@scripts) {
 948     $filename = $$script{filename};
 949     $modules = $$script{modules};
 950     $generated = $$script{generated};
 951     $variables = $$script{variables};
 952
 953     ($config_name = $filename) =~ s#.*/##;
 954     $config_name = $config_name_opt if (defined $config_name_opt);
 955
 956     if (exists $variables->{BUILDDIR}) {
 957         $builddir = File::Spec->rel2abs($variables->{BUILDDIR});
 958         chdir($builddir) or die "Can't change directory to $builddir: $!";
 959         print STDERR "novaboot: Entering directory `$builddir'\n";
 960     }
 961
 962     if ($grub_prefix) {
 963         $prefix = $grub_prefix;
 964         $prefix =~ s/\$NAME/$config_name/;
 965         $prefix =~ s/\$BUILDDIR/$builddir/;
 966     }
 967     # TODO: use $grub_prefix as first parameter if some switch is given
 968     generate_configs('', $generated, $filename);
 969
 970 ### Generate bootloader configuration files
 971     my @bootloader_configs;
 972     push @bootloader_configs, generate_grub_config($grub_config, $config_name, $prefix, $modules, $grub_preamble) if (defined $grub_config);
 973     push @bootloader_configs, generate_grub2_config($grub2_config, $config_name, $prefix, $modules, $grub_preamble, $grub2_prolog) if (defined $grub2_config);
 974     push @bootloader_configs, generate_pulsar_config('config-'.($pulsar||'novaboot'), $modules, $chainload) if (defined $pulsar);
 975
 976 ### Run scons or make
 977     {
 978         my @all;
 979         push @all, @$modules;
 980         push @all, @$copy;
 981         push @all, @$chainload;
 982         my @files = map({ ($file) = m/([^ ]*)/; $file; } @all);
 983
 984         # Filter-out generated files
 985         my @to_build = grep({ my $file = $_; !scalar(grep($file eq ($$_{filename} || ''), @$generated)) } @files);
 986
 987         system_verbose($scons || $CFG::scons." ".join(" ", @to_build)) if (defined $scons);
 988         system_verbose($make  || $CFG::make ." ".join(" ", @to_build)) if (defined $make);
 989     }
 990
 991 ### Copy files (using rsync)
 992     if (defined $server && !defined($gen_only)) {
 993         (my $real_server = $server) =~ s/\$NAME/$config_name/;
 994
 995         my ($hostname, $path) = split(":", $real_server, 2);
 996         if (! defined $path) {
 997             $path = $hostname;
 998             $hostname = "";
 999         }
1000         my $files = join(" ", map({ ($file) = m/([^ ]*)/; $file; } ( @$modules, @bootloader_configs, @$copy)));
1001         map({ my $file = (split)[0]; die "Not a file: $file: $!" if ! -e $file || -d $file; } @$modules);
1002         my $istty = -t STDOUT && ($ENV{'TERM'} || 'dumb') ne 'dumb';
1003         my $progress = $istty ? "--progress" : "";
1004         if ($files) {
1005             system_verbose("rsync $progress -RL --chmod=ugo=rwX $rsync_flags $files $real_server");
1006             if ($server =~ m|/\$NAME$| && $concat) {
1007                 my $cmd = join("; ", map { "( cd $path/.. && cat */$_ > $_ )" } @bootloader_configs);
1008                 system_verbose($hostname ? "ssh $hostname '$cmd'" : $cmd);
1009             }
1010         }
1011     }
1012
1013 ### Prepare ISO image generation
1014     if (defined $iso_image) {
1015         generate_configs("(cd)", $generated, $filename);
1016         my $menu;
1017         generate_syslinux_config(\$menu, $config_name, "/", $modules);
1018         $menu_iso .= "$menu\n";
1019         map { ($file,undef) = split; $files_iso{$file} = 1; } @$modules;
1020     }
1021 }
1022
1023 ## Generate ISO image
1024 if (defined $iso_image) {
1025     system_verbose("mkdir -p isolinux");
1026
1027     my @files;
1028     if (-f '/usr/lib/ISOLINUX/isolinux.bin') {
1029         # Newer ISOLINUX version
1030         @files = qw(/usr/lib/ISOLINUX/isolinux.bin /usr/lib/syslinux/modules/bios/mboot.c32 /usr/lib/syslinux/modules/bios/libcom32.c32 /usr/lib/syslinux/modules/bios/menu.c32 /usr/lib/syslinux/modules/bios/ldlinux.c32);
1031     } elsif (-f '/usr/lib/syslinux/isolinux.bin') {
1032         # Older ISOLINUX version
1033         @files = qw(/usr/lib/syslinux/isolinux.bin /usr/lib/syslinux/mboot.c32 /usr/lib/syslinux/menu.c32);
1034     } else {
1035         # NixOS and maybe others
1036         my $syslinux = `which syslinux` || die "Cannot find syslinux";
1037         chomp $syslinux;
1038         $syslinux =~ s,/bin/syslinux$,,;
1039         @files = ("$syslinux/share/syslinux/isolinux.bin", "$syslinux/share/syslinux/mboot.c32", "$syslinux/share/syslinux/libcom32.c32", "$syslinux/share/syslinux/menu.c32", "$syslinux/share/syslinux/ldlinux.c32");
1040     }
1041     system_verbose("cp @files isolinux && chmod +w isolinux/*");
1042     open(my $fh, ">isolinux/isolinux.cfg");
1043     if ($#scripts) {
1044         print $fh "TIMEOUT 50\n";
1045         print $fh "DEFAULT menu\n";
1046     } else {
1047         print $fh "DEFAULT $config_name\n";
1048     }
1049     print $fh "$menu_iso";
1050     close($fh);
1051
1052     my $files = join(" ", map("$_=$_", (keys(%files_iso), 'isolinux/isolinux.cfg', map(s|.*/|isolinux/|r, @files))));
1053     $iso_image ||= "$config_name.iso";
1054
1055     # Note: We use -U flag below to "Allow 'untranslated' filenames,
1056     # completely violating the ISO9660 standards". Without this
1057     # option, isolinux is not able to read files names for example
1058     # bzImage-3.0.
1059     system_verbose("$CFG::genisoimage -R -b isolinux/isolinux.bin -c isolinux/boot.cat -no-emul-boot -boot-load-size 4 -boot-info-table -hide-rr-moved -U -o $iso_image -graft-points $files");
1060     print("ISO image created: $builddir/$iso_image\n");
1061 }
1062
1063 exit(0) if defined $gen_only;
1064
1065 ## Boot the system using various methods and send serial output to stdout
1066
1067 if (scalar(@scripts) > 1 && ( defined $dhcp_tftp || defined $serial || defined $iprelay)) {
1068     die "You cannot do this with multiple scripts simultaneously";
1069 }
1070
1071 if ($variables->{WVTEST_TIMEOUT}) {
1072     print STDERR "wvtest: timeout ", $variables->{WVTEST_TIMEOUT}, "\n";
1073 }
1074
1075 ### Start in Qemu
1076
1077 if (defined $qemu) {
1078     # Qemu
1079     $qemu ||= $variables->{QEMU} || $CFG::qemu;
1080     my @qemu_flags = split(" ", $qemu);
1081     $qemu = shift(@qemu_flags);
1082
1083     @qemu_flags = split(/ +/, trim($variables->{QEMU_FLAGS})) if exists $variables->{QEMU_FLAGS};
1084     @qemu_flags = split(/ +/, trim($qemu_flags_cmd)) if $qemu_flags_cmd;
1085     push(@qemu_flags, split(/ +/, trim($qemu_append || '')));
1086
1087     if (defined $iso_image) {
1088         # Boot NOVA with grub (and test the iso image)
1089         push(@qemu_flags, ('-cdrom', $iso_image));
1090     } else {
1091         # Boot NOVA without GRUB
1092
1093         # Non-patched qemu doesn't like commas, but NUL can live with pluses instead of commans
1094         foreach (@$modules) {s/,/+/g;}
1095         generate_configs("", $generated, $filename);
1096
1097         if (scalar @$modules) {
1098             my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1099             $kcmd = '' if !defined $kcmd;
1100             my $dtb;
1101             @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1102             my $initrd = join ",", @$modules;
1103
1104             push(@qemu_flags, ('-kernel', $kbin, '-append', $kcmd));
1105             push(@qemu_flags, ('-initrd', $initrd)) if $initrd;
1106             push(@qemu_flags, ('-dtb', $dtb)) if $dtb;
1107         }
1108     }
1109     if (!grep /^-serial$/, @qemu_flags) {
1110         push(@qemu_flags,  qw(-serial stdio)); # Redirect serial output (for collecting test restuls)
1111     }
1112     unshift(@qemu_flags, ('-name', $config_name));
1113     print STDERR "novaboot: Running: ".shell_cmd_string($qemu, @qemu_flags)."\n";
1114     $exp = Expect->spawn(($qemu, @qemu_flags)) || die("exec() failed: $!");
1115 }
1116
1117 ### Local DHCPD and TFTPD
1118
1119 my ($dhcpd_pid, $tftpd_pid);
1120
1121 $tftp=1 if $tftp_port;
1122
1123 if (defined $dhcp_tftp)
1124 {
1125     generate_configs("(nd)", $generated, $filename);
1126     system_verbose('mkdir -p tftpboot');
1127     generate_grub_config("tftpboot/os-menu.lst", $config_name, "(nd)", \@$modules, "timeout 0");
1128     open(my $fh, '>', 'dhcpd.conf');
1129     my $mac = `cat /sys/class/net/$netif/address`;
1130     chomp $mac;
1131     print $fh "subnet 10.23.23.0 netmask 255.255.255.0 {
1132                       range 10.23.23.10 10.23.23.100;
1133                       filename \"bin/boot/grub/pxegrub.pxe\";
1134                       next-server 10.23.23.1;
1135 }
1136 host server {
1137         hardware ethernet $mac;
1138         fixed-address 10.23.23.1;
1139 }";
1140     close($fh);
1141     system_verbose("sudo ip a add 10.23.23.1/24 dev $netif;
1142             sudo ip l set dev $netif up;
1143             sudo touch dhcpd.leases");
1144
1145     # We run servers by forking ourselves, because the servers end up
1146     # in our process group and get killed by signals sent to the
1147     # process group (e.g. Ctrl-C on terminal).
1148     $dhcpd_pid = fork();
1149     exec_verbose("sudo dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid") if ($dhcpd_pid == 0);
1150 }
1151
1152 if (defined $dhcp_tftp || defined $tftp) {
1153     $tftp_port ||= 69;
1154     # Unfortunately, tftpd requires root privileges even with
1155     # non-privileged (>1023) port due to initgroups().
1156     system_verbose("sudo in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid  --address :$tftp_port $builddir");
1157
1158     # Kill server when we die
1159     $SIG{__DIE__} = sub { system_verbose('sudo pkill --pidfile=dhcpd.pid') if (defined $dhcp_tftp);
1160                           system_verbose('sudo pkill --pidfile=tftpd.pid'); };
1161
1162     # We have to kill tftpd explicitely, because it is not in our process group
1163     $SIG{INT} = sub { system_verbose('sudo pkill --pidfile=tftpd.pid'); exit(0); };
1164 }
1165
1166 ### AMT IDE-R
1167 if (defined $ider) {
1168     my $ider_cmd= "amtider -c $iso_image -u $amt_user -p $amt_password $amt_host $amt_port"  ;
1169     print STDERR "novaboot: Running: $ider_cmd\n" =~ s/\Q$amt_password\E/???/r;
1170     my $ider_pid = fork();
1171     if ($ider_pid == 0) {
1172         exec($ider_cmd);
1173         die "IDE redirection failed";
1174     }
1175     # FIXME: This collides with --tftp option. Hopefully, nobody needs
1176     # to use both simultaneously.
1177     $SIG{__DIE__} = sub { system_verbose('kill $ider_pid'); };
1178 }
1179
1180 ### Reset target (IP relay, AMT, ...)
1181
1182 if (defined $target_reset && $reset) {
1183     print STDERR "novaboot: Resetting the test box... ";
1184     &$target_reset();
1185     print STDERR "done\n";
1186     if (defined $exp) {
1187         # We don't want to output anything printed by the target
1188         # before reset so we clear the buffers now. This is, however,
1189         # not ideal because we may loose some data that were sent
1190         # after the reset. If this is a problem, one should reset and
1191         # connect to serial line in atomic manner. For example, if
1192         # supported by hardware, use --remote-cmd 'sterm -d ...' and
1193         # do not use separate --reset-cmd.
1194         my $log = $exp->log_stdout;
1195         $exp->log_stdout(0);
1196         $exp->expect(0); # Read data from target
1197         $exp->clear_accum();    # Clear the read data
1198         $exp->log_stdout($log);
1199     }
1200 }
1201
1202 ### U-boot conversation
1203 if (defined $uboot) {
1204     my $uboot_prompt = $uboot || '=> ';
1205     print STDERR "novaboot: Waiting for U-Boot prompt...\n";
1206     $exp || die("No serial line connection");
1207     $exp->log_stdout(1);
1208     #$exp->exp_internal(1);
1209     $exp->expect(20,
1210                  [qr/Hit any key to stop autoboot:/, sub {
1211                      $exp->send($uboot_stop_key // "\n");
1212                      exp_continue; }],
1213                  $uboot_prompt) || die "No U-Boot prompt deteceted";
1214     foreach my $cmdspec (@uboot_init) {
1215         my ($cmd, $timeout);
1216         die "Internal error - please report a bug" unless ref($cmdspec) eq "HASH";
1217
1218         if ($cmdspec->{system}) {
1219             $cmd = `$cmdspec->{system}`;
1220         } else {
1221             $cmd = $cmdspec->{command};
1222         }
1223         $timeout = $cmdspec->{timeout} // 10;
1224
1225         if ($cmd =~ /\$NB_MYIP/) {
1226             my $ip = (grep /inet /, `ip addr show $netif`)[0] || die "Problem determining IP address of $netif";
1227             $ip =~ s/\s*inet ([0-9.]*).*/$1/;
1228             $cmd =~ s/\$NB_MYIP/$ip/g;
1229         }
1230         if ($cmd =~ /\$NB_PREFIX/) {
1231             my $p = $prefix;
1232             $p =~ s|/*$||;
1233             $cmd =~ s/\$NB_PREFIX/$p/g;
1234         }
1235         chomp($cmd);
1236         $exp->send("$cmd\n");
1237
1238         my ($matched_pattern_position, $error,
1239             $successfully_matching_string,
1240             $before_match, $after_match) =
1241                 $exp->expect($timeout, $uboot_prompt);
1242         die "No U-Boot prompt: $error" if $error;
1243
1244         if ($cmdspec->{dest}) {
1245             open(my $fh, ">", $cmdspec->{dest}) or die "Cannot open '$cmdspec->{dest}': $!";
1246             print $fh $before_match;
1247             close($fh);
1248         }
1249     }
1250
1251     # Load files if there are some load lines in the script
1252     if (scalar(@$modules) > 0  && !$variables->{NO_BOOT}) {
1253         my ($kbin, $kcmd) = split(' ', shift(@$modules), 2);
1254         my $dtb;
1255         @$modules = map { if (/\.dtb$/) { $dtb=$_; (); } else { $_ } } @$modules;
1256         my $initrd = shift @$modules;
1257
1258         if (defined $kbin && $kbin ne '/dev/null') {
1259             die "No '--uboot-addr kernel' given" unless $uboot_addr{kernel};
1260             $exp->send("tftpboot $uboot_addr{kernel} $prefix$kbin\n");
1261             $exp->expect(15,
1262                          [qr/##/, sub { exp_continue; }],
1263                          $uboot_prompt) || die "Kernel load: " . ($! || "timeout");
1264         }
1265         if (defined $dtb) {
1266             die "No '--uboot-addr fdt' given" unless $uboot_addr{fdt};
1267             $exp->send("tftpboot $uboot_addr{fdt} $prefix$dtb\n");
1268             $exp->expect(15,
1269                          [qr/##/, sub { exp_continue; }],
1270                          $uboot_prompt) || die "Device tree load: " . ($! || "timeout");
1271         } else  {
1272             $uboot_addr{fdt} = '';
1273         }
1274         if (defined $initrd) {
1275             die "No '--uboot-addr ramdisk' given" unless $uboot_addr{ramdisk};
1276             $exp->send("tftpboot $uboot_addr{ramdisk} $prefix$initrd\n");
1277             $exp->expect(15,
1278                          [qr/##/, sub { exp_continue; }],
1279                          $uboot_prompt) || die "Initrd load: " . ($! || "timeout");
1280         } else {
1281             $uboot_addr{ramdisk} = '-';
1282         }
1283
1284         $kcmd //= '';
1285         $exp->send("setenv bootargs $kcmd\n");
1286         $exp->expect(5, $uboot_prompt)  || die "U-Boot prompt: " . ($! || "timeout");
1287
1288     }
1289     $uboot_cmd //= $variables->{UBOOT_CMD} // 'bootm $kernel_addr $ramdisk_addr $fdt_addr';
1290     if (!$variables->{NO_BOOT} && $uboot_cmd ne '') {
1291         $uboot_cmd =~ s/\$kernel_addr/$uboot_addr{kernel}/g;
1292         $uboot_cmd =~ s/\$ramdisk_addr/$uboot_addr{ramdisk}/g;
1293         $uboot_cmd =~ s/\$fdt_addr/$uboot_addr{fdt}/g;
1294
1295         $exp->send($uboot_cmd . "\n");
1296         $exp->expect(5, "\n")  || die "U-Boot command: " . ($! || "timeout");
1297     }
1298 }
1299
1300 ### Serial line interaction
1301 if ($interaction && defined $exp) {
1302     # Serial line of the target is available
1303     my $interrupt = 'Ctrl-C';
1304     if ($interactive && !@exiton) {
1305         $interrupt = '"~~."';
1306     }
1307     print STDERR "novaboot: Serial line interaction (press $interrupt to interrupt)...\n";
1308     $exp->log_stdout(1);
1309     if (@exiton) {
1310         $exp->expect($exiton_timeout, @exiton, @expect_raw) || die("exiton: " . ($! || "timeout"));
1311     } else {
1312         my @inputs = ($exp);
1313         my $infile = new IO::File;
1314         $infile->IO::File::fdopen(*STDIN,'r');
1315         my $in_object = Expect->exp_init($infile);
1316         $in_object->set_group($exp);
1317
1318         if ($interactive) {
1319             $in_object->set_seq('~~\.', sub { print STDERR "novaboot: Escape sequence detected\r\n"; undef; });
1320             $in_object->manual_stty(0);   # Use raw terminal mode
1321         } else {
1322             $in_object->manual_stty(1);   # Do not modify terminal settings
1323         }
1324         push(@inputs, $in_object);
1325         #use Data::Dumper;
1326         #print Dumper(\@expect_raw);
1327         $exp->expect(undef, @expect_raw) if @expect_raw;
1328
1329         $^W = 0; # Suppress Expect warning: handle id(3) is not a tty. Not changing mode at /usr/share/perl5/Expect.pm line 393, <> line 8.
1330         Expect::interconnect(@inputs) unless defined($exp->exitstatus);
1331         $^W = 1;
1332     }
1333 }
1334
1335 # When exp-spawned command ignores SIGHUP, Expect waits 5 seconds
1336 # before killing it. We kill it by SIGTERM immediately.
1337 kill TERM => $exp->pid if defined $exp && $exp->pid;
1338
1339 ## Kill dhcpc or tftpd
1340 if (defined $dhcp_tftp || defined $tftp) {
1341     die("novaboot: This should kill servers on background\n");
1342 }
1343
1344 # Always finish novaboot output with newline
1345 print "\n" if $final_eol;
1346
1347 ## Documentation
1348
1349 =encoding utf8
1350
1351 =head1 NAME
1352
1353 novaboot - Boots a locally compiled operating system on a remote
1354 target or in qemu
1355
1356 =head1 SYNOPSIS
1357
1358 B<novaboot> --help
1359
1360 B<novaboot> [option]... [--] script...
1361
1362 B<./script> [option]...
1363
1364 =head1 DESCRIPTION
1365
1366 Novaboot makes booting of a locally compiled operating system (OS)
1367 (e.g. NOVA or Linux) on remote targets as simple as running a program
1368 locally. It automates things like copying OS images to a TFTP server,
1369 generation of bootloader configuration files, resetting of target
1370 hardware or redirection of target's serial line to stdin/out. Novaboot
1371 is highly configurable and makes it easy to boot a single image on
1372 different targets or different images on a single target.
1373
1374 Novaboot operation is controlled by configuration files, command line
1375 options and by a so-called novaboot script, which can be thought as a
1376 generalization of bootloader configuration files (see L</"NOVABOOT
1377 SCRIPT SYNTAX">). The typical way of using novaboot is to make the
1378 novaboot script executable and set its first line to I<#!/usr/bin/env
1379 novaboot>. Then, booting a particular OS configuration becomes the
1380 same as executing a local program – the novaboot script.
1381
1382 Novaboot uses configuration files to, among other things, define
1383 command line options needed for different targets. Users typically use
1384 only the B<-t>/B<--target> command line option to select the target.
1385 Internally, this option expands to the pre-configured options.
1386 Novaboot searches configuration files at multiple places, which allows
1387 having per-system, per-user or per-project configurations.
1388 Configuration file syntax is described in section L</"CONFIGURATION
1389 FILES">.
1390
1391 Novaboot newcomers may be confused by a large number of configuration
1392 options. Understanding all these options is not always needed,
1393 depending on the used setup. The L<figure from the doc directory
1394 |https://github.com/wentasah/novaboot/blob/master/doc/typical-setups.svg>
1395 shows different setups that vary in how much effort is needed
1396 to configure novaboot for them. The setups are:
1397
1398 =over 3
1399
1400 =item A: Laptop and target device only
1401
1402 This requires to configure everything on the laptop side, including a
1403 serial line connection (L</--serial>, L</--remote-cmd>, ...), power
1404 on/off/reset commands (L</--reset-cmd>, ...), TFTP server
1405 (L</--copy>, L</--prefix>...), device IP addresses, etc.
1406
1407 =item B: Laptop, target device and external TFTP server
1408
1409 Like the previous setup, but the TFTP (and maybe DHCP) configuration
1410 is handled by a server. Novaboot users need to understand where to
1411 copy their files to the TFTP server (L</--copy>) and which IP
1412 addresses their target will get, but do not need to configure the
1413 servers themselves.
1414
1415 =item C: Novaboot server running novaboot-shell
1416
1417 With this setup, the configuration is done on the server. Users only
1418 need to know the SSH account (L</--ssh>) used to communicate between
1419 novaboot and novaboot server. The server is implemented as a
1420 restricted shell (L<novaboot-shell(1)>) on the server. No need to give
1421 full shell access to novaboot users on the server.
1422
1423 =back
1424
1425 =head2 Simple examples of using C<novaboot>:
1426
1427 To boot Linux (files F<bzImage> and F<rootfs.cpio> in current
1428 directory), create F<mylinux> file with this content:
1429
1430     #!/usr/bin/env novaboot
1431     load bzImage console=ttyS0,115200
1432     load rootfs.cpio
1433
1434 =over 3
1435
1436 =item 1.
1437
1438 Booting an OS in Qemu can be accomplished by giving the B<--qemu> option.
1439 Thus running
1440
1441  novaboot --qemu mylinux
1442
1443 (or C<./mylinux --qemu> as described above) will run Qemu and make it
1444 boot the configuration specified in the F<mylinux> script. How is qemu
1445 started can be configured in various ways (see below).
1446
1447 =item 2.
1448
1449 Create a bootloader configuration file (currently supported
1450 bootloaders are GRUB, GRUB2, ISOLINUX, Pulsar, and U-Boot) and copy it
1451 with all other files needed for booting to a remote TFTP server. Then
1452 use a TCP/IP-controlled relay/serial-to-TCP converter to reset the
1453 target and receive its serial output.
1454
1455  ./mylinux --grub2 --copy=192.168.1.1:/tftp --iprelay=192.168.1.2
1456
1457 Alternatively, you can put these switches to the configuration file
1458 and run:
1459
1460  ./mylinux --target mytarget
1461
1462 =item 3.
1463
1464 Specifying all the options needed by novaboot to successfully control
1465 the target, either on command line or in configuration files, can be
1466 difficult for users. Novaboot supports configuring the target
1467 centrally via L<novaboot-shell(1)> on a server. With such a
1468 configuration, users only need to use the B<--ssh> option to specify
1469 where to boot their OS:
1470
1471  ./mylinux --ssh myboard@example.com
1472
1473 Typically, the server is the computer connected to and controlling the
1474 target board and running the TFTP server.
1475
1476 =item 4.
1477
1478 Run DHCP and TFTP server on developer's machine to boot the target
1479 from it.
1480
1481  ./mylinux --dhcp-tftp
1482
1483 This usage is useful when no network infrastructure is in place, and
1484 the target is connected directly to developer's box.
1485
1486 =item 5.
1487
1488 Create bootable ISO image.
1489
1490  novaboot --iso -- script1 script2
1491
1492 The created ISO image will have ISOLINUX bootloader installed on it,
1493 and the boot menu will allow selecting between I<script1> and
1494 I<script2> configurations.
1495
1496 =back
1497
1498 =head1 OPTIONS AND PHASES
1499
1500 Novaboot performs its work in several phases. Command line options
1501 described bellow influence the execution of each phase or allow their
1502 skipping. The list of phases (in the execution order) is as follows.
1503
1504 =over
1505
1506 =item 1. L<Configuration reading|/Configuration reading phase>
1507
1508 =item 2. L<Command line processing|/Command line processing phase>
1509
1510 =item 3. L<Script preprocessing|/Script preprocessing phase>
1511
1512 =item 4. L<File generation|/File generation phase>
1513
1514 =item 5. L<Target connection|/Target connection check>
1515
1516 =item 6. L<File deployment|/File deployment phase>
1517
1518 =item 7. L<Target power-on and reset|/Target power-on and reset phase>
1519
1520 =item 8. L<Interaction with the bootloader|/Interaction with the bootloader on the target>
1521
1522 =item 9. L<Target interaction|/Target interaction phase>
1523
1524 =back
1525
1526 Each phase is described in the following sections together with the
1527 command line options that control it.
1528
1529 =head2 Configuration reading phase
1530
1531 After starting, novaboot reads zero or more configuration files. We
1532 describe their content in section L</"CONFIGURATION FILES">. By default, the
1533 configuration is read from multiple locations. First from the system
1534 configuration directory (F</etc/novaboot.d/>), second from the user
1535 configuration file (F<~/.config/novaboot>) and third from F<.novaboot>
1536 files along the path to the current directory. Alternatively, a single
1537 configuration file specified with the B<-c> switch or with the
1538 C<NOVABOOT_CONFIG> environment variable is read. The latter read files
1539 override settings from the former ones.
1540
1541 The system configuration directory is determined by the content of
1542 NOVABOOT_CONFIG_DIR environment variable and defaults to
1543 F</etc/novaboot.d>. Files in this directory with names consisting
1544 solely of English letters, numbers, dashes '-' and underscores '_'
1545 (note that dot '.' is not included) are read in alphabetical order.
1546
1547 Then, the user configuration file is read from
1548 F<$XDG_CONFIG_HOME/novaboot>. If C<$XDG_CONFIG_HOME> environment
1549 variable is not set F<~/.config/novaboot> is read instead.
1550
1551 Finally, novaboot searches for files named F<.novaboot> starting from the
1552 directory of the novaboot script (or working directory, see bellow)
1553 and continuing upwards up to the root directory. The found
1554 configuration files are then read in the opposite order (i.e. from the
1555 root directory downwards). This ordering allows having, for example, a project
1556 specific configuration in F<~/project/.novaboot>.
1557
1558 Note the difference between F<~/.config/novaboot> and F<~/.novaboot>.
1559 The former one is always read, whereas the latter only when novaboot
1560 script or working directory is under the C<$HOME> directory.
1561
1562 In certain cases, the location of the novaboot script cannot be
1563 determined in this early phase. This situation happens either when the script is
1564 read from the standard input or when novaboot is invoked explicitly as
1565 in the example L</"4."> above. In this case, the current working
1566 directory is used as a starting point for configuration file search
1567 instead of the novaboot script directory.
1568
1569 =over 8
1570
1571 =item -c, --config=I<filename>
1572
1573 Use the specified configuration file instead of the default one(s).
1574
1575 =back
1576
1577 =head2 Command line processing phase
1578
1579 =over 8
1580
1581 =item --dump-config
1582
1583 Dump the current configuration to stdout end exit. Useful as an
1584 initial template for a configuration file.
1585
1586 =item -h, --help
1587
1588 Print short (B<-h>) or long (B<--help>) help.
1589
1590 =item -t, --target=I<target>
1591
1592 This option serves as a user configurable shortcut for other novaboot
1593 options. The effect of this option is the same as specifying the
1594 options stored in the C<%targets> configuration variable under key
1595 I<target>. See also L</"CONFIGURATION FILES">.
1596
1597 When this option is not given, novaboot tries to determine the target
1598 to use from either B<NOVABOOT_TARGET> environment variable or
1599 B<$default_target> configuration file variable.
1600
1601 =item --ssh=I<user@hostname>
1602
1603 Configures novaboot to control the target via C<novaboot-shell>
1604 running remotely via SSH.
1605
1606 Using this option is the same as specifying B<--remote-cmd>,
1607 B<--remote-expect>, B<--copy> B<--rsync-flags>, B<--prefix> and
1608 B<--reset-cmd> manually in a way compatible with C<novaboot-shell>.
1609 The server can be configured to provide other, safe bootloader-related
1610 options, to the client. When this happens, novaboot prints them to
1611 stdout.
1612
1613 Currently, this in an initial experimental implementation. We plan to
1614 change/extend this feature soon!
1615
1616 =back
1617
1618 =head2 Script preprocessing phase
1619
1620 This phase allows modifying the parsed novaboot script before it is
1621 used in the later phases.
1622
1623 =over 8
1624
1625 =item -a, --append=I<parameters>
1626
1627 Append a string to the first C<load> line in the novaboot script. This option
1628 can be used to append parameters to the kernel's or root task's
1629 command line. This option can appear multiple times.
1630
1631 =item -b, --bender
1632
1633 Use L<Bender|https://github.com/TUD-OS/morbo/blob/master/standalone/bender.c>
1634 chainloader. Bender scans the PCI bus for PCI serial ports and stores
1635 the information about them in the BIOS data area for use by the
1636 kernel.
1637
1638 =item --chainloader=I<chainloader>
1639
1640 Specifies a chainloader that is loaded before the kernel and other
1641 files specified in the novaboot script. E.g. 'bin/boot/bender
1642 promisc'.
1643
1644 =item --dump
1645
1646 Print the modules to boot and their parameters, after this phase
1647 finishes. Then exit. This is useful for seeing the effect of other
1648 options in this section.
1649
1650 =item -k, --kernel=F<file>
1651
1652 Replace the first word on the first C<load> line in the novaboot
1653 script with F<file>.
1654
1655 =item --scriptmod=I<Perl expression>
1656
1657 When novaboot reads the script, I<Perl expression> is executed for every
1658 line (in $_ variable). For example, C<novaboot
1659 --scriptmod=s/sigma0/omega6/g> replaces every occurrence of I<sigma0>
1660 in the script with I<omega6>.
1661
1662 When this option is present, it overrides I<$script_modifier> variable
1663 from the configuration file, which has the same effect. If this option
1664 is given multiple times all expressions are evaluated in the command
1665 line order.
1666
1667 =back
1668
1669 =head2 File generation phase
1670
1671 In this phase, files needed for booting are generated in a so-called
1672 I<build directory> (see L</--build-dir>). In most cases configuration
1673 for a bootloader is generated automatically by novaboot. It is also
1674 possible to generate other files using I<heredoc> or I<"<"> syntax in
1675 novaboot scripts. Finally, novaboot can generate binaries in this phases by
1676 running C<scons> or C<make>.
1677
1678 =over 8
1679
1680 =item --build-dir=I<directory>
1681
1682 Overrides the default build directory location.
1683
1684 The default build directory location is determined as follows: If the
1685 configuration file defines the C<$builddir> variable, its value is
1686 used. Otherwise, it is the directory that contains the first processed
1687 novaboot script.
1688
1689 See also L</BUILDDIR> variable.
1690
1691 =item -g, --grub[=I<filename>]
1692
1693 Generates grub bootloader menu file. If the I<filename> is not
1694 specified, F<menu.lst> is used. The I<filename> is relative to the
1695 build directory (see B<--build-dir>).
1696
1697 =item --grub-preamble=I<prefix>
1698
1699 Specifies the I<preamble> that is at the beginning of the generated
1700 GRUB or GRUB2 config files. This is useful for specifying GRUB's
1701 timeout.
1702
1703 =item --prefix=I<prefix>
1704
1705 Specifies I<prefix> (e.g. F</srv/tftp>) that is put in front of every
1706 filename in generated bootloader configuration files (or in U-Boot
1707 commands).
1708
1709 If the I<prefix> contains string $NAME, it will be replaced with the
1710 name of the novaboot script (see also B<--name>).
1711
1712 If the I<prefix> contains string $BUILDDIR, it will be replaced with
1713 the build directory (see also B<--build-dir>).
1714
1715 =item --grub-prefix
1716
1717 Alias for B<--prefix>.
1718
1719 =item --grub2[=I<filename>]
1720
1721 Generate GRUB2 menu entry in I<filename>. If I<filename> is not
1722 specified F<grub.cfg> is used. The content of the menu entry can be
1723 customized with B<--grub-preamble>, B<--grub2-prolog> or
1724 B<--grub_prefix> options.
1725
1726 To use the generated menu entry on your development
1727 machine that uses GRUB2, append the following snippet to
1728 F</etc/grub.d/40_custom> file and regenerate your grub configuration,
1729 i.e. run update-grub on Debian/Ubuntu.
1730
1731   if [ -f /path/to/nul/build/grub.cfg ]; then
1732     source /path/to/nul/build/grub.cfg
1733   fi
1734
1735 =item --grub2-prolog=I<prolog>
1736
1737 Specifies the text that novaboot puts at the beginning of the GRUB2 menu entry.
1738
1739 =item -m, --make[=make command]
1740
1741 Runs C<make> to build files that are not generated by novaboot itself.
1742
1743 =item --name=I<string>
1744
1745 Use the name I<string> instead of the name of the novaboot script.
1746 This name is used for things like a title of grub menu or for the
1747 server directory where the boot files are copied to.
1748
1749 =item --no-file-gen
1750
1751 Do not run external commands to generate files (i.e. "<" syntax and
1752 C<run> keyword). This switch does not influence the generation of files
1753 specified with "<<WORD" syntax.
1754
1755 =item -p, --pulsar[=mac]
1756
1757 Generates pulsar bootloader configuration file named F<config-I<mac>>
1758 The I<mac> string is typically a MAC address and defaults to
1759 I<novaboot>.
1760
1761 =item --scons[=scons command]
1762
1763 Runs C<scons> to build files that are not generated by novaboot
1764 itself.
1765
1766 =item --strip-rom
1767
1768 Strip I<rom://> prefix from command lines and generated config files.
1769 The I<rom://> prefix is used by NUL. For NRE, it has to be stripped.
1770
1771 =item --gen-only
1772
1773 Exit novaboot after file generation phase.
1774
1775 =back
1776
1777 =head2 Target connection check
1778
1779 In this phase novaboot connects to target's serial port (if it has
1780 one). If another novaboot user/instance occupies the target, novaboot
1781 exits here with an error message.
1782
1783 =over 8
1784
1785 =item --amt=I<"[user[:password]@]host[:port]>
1786
1787 Use Intel AMT technology to control the target machine. WS management
1788 is used to powercycle it and Serial-Over-Lan (SOL) for input/output.
1789 The hostname or (IP address) is given by the I<host> parameter. If the
1790 I<password> is not specified, environment variable AMT_PASSWORD is
1791 used. The I<port> specifies a TCP port for SOL. If not specified, the
1792 default is 16992. The default I<user> is admin.
1793
1794 =item --iprelay=I<addr[:port]>
1795
1796 Use TCP/IP relay and serial port to access the target's serial port
1797 and powercycle it. The I<addr> parameter specifies the IP address of
1798 the relay. If I<port> is not specified, it defaults to 23.
1799
1800 Note: This option is supposed to work with HWG-ER02a IP relays.
1801
1802 =item --iprelay-cmd=I<command>
1803
1804 Similar to B<--iprelay> but uses I<command> to talk to the iprelay
1805 rather than direct network connection.
1806
1807 =item -s, --serial[=device]
1808
1809 Target's serial line is connected to host's serial line (device). The
1810 default value for device is F</dev/ttyUSB0>.
1811
1812 The value of this option is exported in NB_NOVABOOT environment
1813 variable to all subprocesses run by C<novaboot>.
1814
1815 =item --stty=I<settings>
1816
1817 Specifies settings passed to C<stty> invoked on the serial line
1818 specified with B<--serial> option. If this option is not given,
1819 C<stty> is called with C<raw -crtscts -onlcr 115200> settings.
1820
1821 =item --remote-cmd=I<cmd>
1822
1823 Command that mediates connection to the target's serial line. For
1824 example C<ssh server 'cu -l /dev/ttyS0'>.
1825
1826 =item --remote-expect=I<string>
1827
1828 Wait for reception of I<string> after establishing the remote serial
1829 line connection. Novaboot assumes that after establishing the serial
1830 line connection, the user running novaboot has exclusive access to the
1831 target. If establishing of the serial line connection happens
1832 asynchronously (e.g. running a command remotely via SSH), we need this
1833 option to wait until the exclusive access is confirmed by the remote
1834 side.
1835
1836 Depending on target configuration, this option can solve two practical
1837 problems: 1) Overwriting of files deployed by another user currently
1838 using the target. 2) Resetting the target board before serial line
1839 connection is established and thus missing bootloader interaction.
1840
1841 Example of usage with the L<sterm
1842 tool|https://rtime.felk.cvut.cz/gitweb/sojka/sterm.git>:
1843
1844   --remote-cmd='ssh -tt example.com sterm -v /dev/ttyUSB0' --remote-expect='sterm: Connected'
1845
1846 =item --remote-expect-silent=I<string>
1847
1848 The same as B<--remote-expect> except that the remote output is not
1849 echoed to stdout while waiting for the I<string>. Everything after the
1850 matched string is printed to stdout, so you may want to include line
1851 end characters in the I<string> as well.
1852
1853 =item --remote-expect-timeout=I<seconds>
1854
1855 Timeout in seconds for B<--remote-expect> or
1856 B<--remote-expect-seconds>. When negative, waits forever. The default
1857 is -1 seconds.
1858
1859 =back
1860
1861 =head2 File deployment phase
1862
1863 In some setups, it is necessary to copy the files needed for booting
1864 to a particular location, e.g. to a TFTP boot server or to the
1865 F</boot> partition.
1866
1867 =over 8
1868
1869 =item -d, --dhcp-tftp
1870
1871 Turns your workstation into a DHCP and TFTP server so that the OS can
1872 be booted via PXE BIOS (or similar mechanism) on the test machine
1873 directly connected by a plain Ethernet cable to your workstation.
1874
1875 The DHCP and TFTP servers require root privileges and C<novaboot>
1876 uses C<sudo> command to obtain those. You can put the following to
1877 I</etc/sudoers> to allow running the necessary commands without asking
1878 for a password.
1879
1880  Cmnd_Alias NOVABOOT = /bin/ip a add 10.23.23.1/24 dev eth0, /bin/ip l set dev eth0 up, /usr/sbin/dhcpd -d -cf dhcpd.conf -lf dhcpd.leases -pf dhcpd.pid, /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/touch dhcpd.leases, /usr/bin/pkill --pidfile=dhcpd.pid, /usr/bin/pkill --pidfile=tftpd.pid
1881  your_login ALL=NOPASSWD: NOVABOOT
1882
1883 =item --tftp
1884
1885 Starts a TFTP server on your workstation. This is similar to
1886 B<--dhcp-tftp> except that DHCP server is not started.
1887
1888 The TFTP server requires root privileges and C<novaboot> uses C<sudo>
1889 command to obtain those. You can put the following to I</etc/sudoers>
1890 to allow running the necessary commands without asking for a password.
1891
1892  Cmnd_Alias NOVABOOT =  /usr/sbin/in.tftpd --listen --secure -v -v -v --pidfile tftpd.pid *, /usr/bin/pkill --pidfile=tftpd.pid
1893  your_login ALL=NOPASSWD: NOVABOOT
1894
1895 =item --tftp-port=I<port>
1896
1897 Port to run the TFTP server on. Implies B<--tftp>.
1898
1899 =item --netif=I<network interface>
1900
1901 Network interface used to deploy files to the target. This option
1902 influences the configuration of the DHCP server started by
1903 B<--dhcp-tftp> and the value that B<$NB_MYIP> get replaced with during
1904 U-Boot conversation. The default value is C<$netif> variable from
1905 configuration files, which defaults to I<eth0>.
1906
1907 =item --iso[=filename]
1908
1909 Generates the ISO image that boots NOVA system via GRUB. If no filename
1910 is given, the image is stored under I<NAME>.iso, where I<NAME> is the name
1911 of the novaboot script (see also B<--name>).
1912
1913 =item --server[=[[user@]server:]path]
1914
1915 Alias of B<--copy> (kept for backward compatibility).
1916
1917 =item --copy[=[[user@]server:]path]
1918
1919 Copy all files needed for booting to another location. The files will
1920 be copied (by B<rsync> tool) to the directory I<path>. If the I<path>
1921 contains string $NAME, it will be replaced with the name of the
1922 novaboot script (see also B<--name>).
1923
1924 =item --rsync-flags=I<flags>
1925
1926 Specifies I<flags> to append to F<rsync> command line when
1927 copying files as a result of I<--copy> option.
1928
1929 =item --concat
1930
1931 If B<--copy> is used and its value ends with $NAME, then after
1932 copying the files, a new bootloader configuration file (e.g. menu.lst)
1933 is created at I<path-wo-name>, i.e. the path specified by B<--copy>
1934 with $NAME part removed. The content of the file is created by
1935 concatenating all files of the same name from all subdirectories of
1936 I<path-wo-name> found on the "server".
1937
1938 =item --ider
1939
1940 Use Intel AMT technology for IDE redirection. This allows the target
1941 machine to boot from novaboot created ISO image. Implies B<--iso>.
1942
1943 The experimental C<amtider> utility needed by this option can be
1944 obtained from https://github.com/wentasah/amtterm.
1945
1946 =back
1947
1948 =head2 Target power-on and reset phase
1949
1950 At this point, the target is reset (or switched on/off). There are
1951 several ways how this can be accomplished. Resetting a physical target
1952 can currently be accomplished by the following options: B<--amt>,
1953 B<--iprelay>, B<--reset-cmd> and B<--reset-send>.
1954
1955 =over 8
1956
1957 =item --on, --off
1958
1959 Switch on/off the target machine and exit. The script (if any) is
1960 completely ignored. Currently, it works only with the following
1961 options: B<--iprelay>, B<--amt>, B<--ssh>.
1962
1963 =item -Q, --qemu[=I<qemu-binary>]
1964
1965 Boot the configuration in qemu. Optionally, the name of qemu binary
1966 can be specified as a parameter.
1967
1968 =item --qemu-append=I<flags>
1969
1970 Append I<flags> to the default qemu flags (QEMU_FLAGS variable or
1971 C<-cpu coreduo -smp 2>).
1972
1973 =item -q, --qemu-flags=I<flags>
1974
1975 Replace the default qemu flags (QEMU_FLAGS variable or C<-cpu coreduo
1976 -smp 2>) with I<flags> specified here.
1977
1978 =item --reset-cmd=I<cmd>
1979
1980 Runs command I<cmd> to reset the target.
1981
1982 =item --reset-send=I<string>
1983
1984 Reset the target by sending the given I<string> to the remote serial
1985 line. "\n" sequences are replaced with the newline character.
1986
1987 =item --no-reset, --reset
1988
1989 Disable/enable resetting of the target.
1990
1991 =back
1992
1993 =head2 Interaction with the bootloader on the target
1994
1995 =over 8
1996
1997 =item --uboot[=I<prompt>]
1998
1999 Interact with U-Boot bootloader to boot the thing described in the
2000 novaboot script. I<prompt> specifies the U-Boot's prompt (default is
2001 "=> ", other common prompts are "U-Boot> " or "U-Boot# ").
2002
2003 =item --no-uboot
2004
2005 Disable U-Boot interaction previously enabled with B<--uboot>.
2006
2007 =item --uboot-stop-key=I<key>
2008
2009 Character, which is sent as a response to U-Boot's "Hit any key to
2010 stop autoboot" message. The default value is newline, but some devices
2011 (e.g. TP-Link TD-W8970) require a specific key to be pressed.
2012
2013 =item --uboot-init
2014
2015 Command(s) to send the U-Boot bootloader before loading the images and
2016 booting them. This option can be given multiple times. After sending
2017 commands from each option novaboot waits for U-Boot I<prompt>.
2018
2019 If the command contains string I<$NB_MYIP> then this string is
2020 replaced by IPv4 address of eth0 interface (see also B<--netif>).
2021 Similarly, I<$NB_PREFIX> is replaced with prefix given by B<--prefix>.
2022
2023 See also C<uboot> keyword in L</"NOVABOOT SCRIPT SYNTAX">).
2024
2025 =item --uboot-addr I<name>=I<address>
2026
2027 Load address of U-Boot's C<tftpboot> command for loading I<name>,
2028 where name is one of I<kernel>, I<ramdisk> or I<fdt> (flattened device
2029 tree).
2030
2031 The default addresses are ${I<name>_addr_r}, i.e. U-Boot environment
2032 variables used by convention for this purpose.
2033
2034 =item --uboot-cmd=I<command>
2035
2036 Specifies U-Boot command used to execute the OS. If the command
2037 contains strings C<$kernel_addr>, C<$ramdisk_addr>, C<$fdt_addr>,
2038 these are replaced with the addresses configured with B<--uboot-addr>.
2039
2040 The default value is
2041
2042     bootm $kernel_addr $ramdisk_addr $fdt_addr
2043
2044 or the C<UBOOT_CMD> variable if defined in the novaboot script.
2045
2046 =back
2047
2048 =head2 Target interaction phase
2049
2050 In this phase, target's serial output is redirected to stdout and if
2051 stdin is a TTY, it is redirected to the target's serial input allowing
2052 interactive work with the target.
2053
2054 =over 8
2055
2056 =item --exiton=I<string>
2057
2058 When the I<string> is sent by the target, novaboot exits. This option can
2059 be specified multiple times, in which case novaboot exits whenever
2060 either of the specified strings is sent.
2061
2062 If the I<string> is C<-re>, then the next B<--exiton>'s I<string> is
2063 treated as a regular expression. For example:
2064
2065     --exiton -re --exiton 'error:.*failed'
2066
2067 =item --exiton-re=I<regex>
2068
2069 The same as --exiton -re --exiton I<regex>.
2070
2071 =item --exiton-timeout=I<seconds>
2072
2073 By default B<--exiton> waits for the string match forever. When this
2074 option is specified, "exiton" timeouts after the specified number of
2075 seconds and novaboot returns non-zero exit code.
2076
2077 =item -i, --interactive
2078
2079 Setup things for the interactive use of the target. Your terminal will
2080 be switched to raw mode. In raw mode, your local terminal does not
2081 process input in any way (no echoing of entered characters, no
2082 interpretation of special characters). This, among others, means that
2083 Ctrl-C is passed to the target and does not interrupt novaboot. To
2084 exit from novaboot interactive mode type "~~.".
2085
2086 =item --no-interaction, --interaction
2087
2088 Skip resp. force target interaction phase. When skipped, novaboot exits
2089 immediately after the boot is initiated.
2090
2091 =item --expect=I<string>
2092
2093 When the I<string> is received from the target, send the string specified
2094 with the subsequent B<--send*> option to the target.
2095
2096 =item --expect-re=I<regex>
2097
2098 When target's output matches regular expression I<regex>, send the
2099 string specified with the subsequent B<--send*> option to the target.
2100
2101 =item --expect-raw=I<perl-code>
2102
2103 Provides direct control over Perl's Expect module.
2104
2105 =item --send=I<string>
2106
2107 Send I<string> to the target after the previously specified
2108 B<--expect*> was matched in the target's output. The I<string> may
2109 contain escape sequences such as "\n".
2110
2111 Note that I<string> is actually interpreted by Perl, so it can contain
2112 much more that escape sequences. This behavior may change in the
2113 future.
2114
2115 Example: C<--expect='login: ' --send='root\n'>
2116
2117 =item --sendcont=I<string>
2118
2119 Similar to B<--send> but continue expecting more input.
2120
2121 Example: C<--expect='Continue?' --sendcont='yes\n'>
2122
2123 =item --final-eol, --no-final-eol
2124
2125 By default, B<novaboot> always prints an end-of-line character at the
2126 end of its execution in order to ensure that the output of programs
2127 started after novaboot appears at the beginning of the line. When this
2128 is not desired B<--no-final-eol> option can be used to override this
2129 behavior.
2130
2131 =back
2132
2133 =head1 NOVABOOT SCRIPT SYNTAX
2134
2135 The syntax tries to mimic POSIX shell syntax. The syntax is defined
2136 by the following rules.
2137
2138 Lines starting with "#" and empty lines are ignored.
2139
2140 Lines that end with "\" are concatenated with the following line after
2141 removal of the final "\" and leading whitespace of the following line.
2142
2143 Lines of the form I<VARIABLE=...> (i.e. matching '^[A-Z_]+=' regular
2144 expression) assign values to internal variables. See L</VARIABLES>
2145 section.
2146
2147 Otherwise, the first word on the line defines the meaning of the line.
2148 The following keywords are supported:
2149
2150 =over 4
2151
2152 =item C<load>
2153
2154 These lines represent modules to boot. The
2155 word after C<load> is a file name (relative to the build directory
2156 (see B<--build-dir>) of the module to load and the remaining words are
2157 passed to it as the command line parameters.
2158
2159 When booting Linux, the first C<load> line usually refers to the
2160 kernel image and its command line parameters (unless you use some
2161 special pre-loader). Other C<load> lines may refer to an initramfs
2162 image and/or a device tree blob. Their order is not important, as the
2163 device tree is recognized as the file name ending with C<.dtb>.
2164
2165 When the C<load> line ends with "<<WORD" then the subsequent lines
2166 until the line containing solely WORD are copied literally to the file
2167 named on that line. This is similar to the heredoc feature of UNIX
2168 shells.
2169
2170 When the C<load> line ends with "< CMD" then command CMD is executed
2171 with F</bin/sh> and its standard output is stored in the file named on
2172 that line. The SRCDIR variable in CMD's environment is set to the
2173 absolute path of the directory containing the interpreted novaboot
2174 script.
2175
2176 =item C<copy>
2177
2178 These lines are similar to C<load> lines. The
2179 file mentioned there is copied to the same place as in the case of C<load>
2180 (e.g. tftp server), but the file is not used in the bootloader
2181 configuration. Such a file can be used by the target for other
2182 purposes than booting, e.g. at OS runtime or for firmware update.
2183
2184 =item C<chld>
2185
2186 Chainload another bootloader. Instead of loading multiboot modules
2187 identified with C<load> keyword, run another bootloader. This is
2188 currently supported only by pulsar and can be used to load e.g. Grub
2189 as in the example below:
2190
2191  chld boot/grub/i386-pc/core.0
2192
2193
2194 =item C<run>
2195
2196 Lines starting with C<run> keyword contain shell commands that are run
2197 during file generation phase. This is the same as the "< CMD" syntax
2198 for C<load> keyboard except that the command's output is not
2199 redirected to a file. The ordering of commands is the same as they
2200 appear in the novaboot script.
2201
2202 =item C<uboot>
2203
2204 These lines represent U-Boot commands that are sent to the target if
2205 B<--uboot> option is given. Having a U-Boot line in the novaboot
2206 script is the same as giving B<--uboot-init> option to novaboot. The
2207 following syntax variants are supported:
2208
2209
2210   uboot[:<timeout>] <string> [> <file>]
2211   uboot[:<timeout>] < <shell> [> <file>]
2212
2213 C<string> is the literal U-Boot command.
2214
2215 The C<uboot> keyword can be suffixed with timeout specification. The
2216 syntax is C<uboot:Ns>, where C<N> is the whole number of seconds. If
2217 the U-Boot command prompt does not appear before the timeout, novaboot
2218 fails. The default timeout is 10 seconds.
2219
2220 In the second variant with the C<<> character the shell code is
2221 executed and its standard output is sent to U-Boot. Example:
2222
2223   uboot < printf "mmc write \$loadaddr 1 %x" $(($(/usr/bin/stat -c%s rootfs.ext4) / 512))
2224
2225 When C<E<gt> file> part is present, the output of the U-Boot command
2226 is written into the given file.
2227
2228 =back
2229
2230 Example (Linux):
2231
2232   #!/usr/bin/env novaboot
2233   load bzImage console=ttyS0,115200
2234   run  make -C buildroot
2235   load rootfs.cpio < gen_cpio buildroot/images/rootfs.cpio "myapp->/etc/init.d/S99myapp"
2236
2237 Example (NOVA User Land - NUL):
2238
2239   #!/usr/bin/env novaboot
2240   WVDESC=Example program
2241   load bin/apps/sigma0.nul S0_DEFAULT script_start:1,1 \
2242                            verbose hostkeyb:0,0x60,1,12,2
2243   load bin/apps/hello.nul
2244   load hello.nulconfig <<EOF
2245   sigma0::mem:16 name::/s0/log name::/s0/timer name::/s0/fs/rom ||
2246   rom://bin/apps/hello.nul
2247   EOF
2248
2249 This example will load three modules: F<sigma0.nul>, F<hello.nul> and
2250 F<hello.nulconfig>. sigma0 receives some command line parameters and
2251 F<hello.nulconfig> file is generated on the fly from the lines between
2252 C<<<EOF> and C<EOF>.
2253
2254 Example (Zynq system update via U-Boot):
2255
2256   #!/usr/bin/env novaboot
2257
2258   uboot dhcp
2259
2260   # Write kernel to FAT filesystem on the 1st SD card partition
2261   run mkimage -f uboot-image.its image.ub
2262   copy image.ub
2263   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/image.ub
2264   uboot fatwrite mmc 0:1 ${loadaddr} image.ub $filesize
2265   uboot set bootargs console=ttyPS0,115200 root=/dev/mmcblk0p2
2266
2267   # Write root FS image to the 2nd SD card partition
2268   copy rootfs/images/rootfs.ext4
2269   uboot:60s tftpboot ${loadaddr} $NB_PREFIX/rootfs/images/rootfs.ext4
2270   uboot mmc part > mmc-part.txt
2271   uboot < printf "mmc write \$loadaddr %x %x" $(awk '{ if ($1 == "2") { print $2 }}' mmc-part.txt) $(($(/usr/bin/stat -L --printf=%s rootfs/images/rootfs.ext4) / 512))
2272
2273   UBOOT_CMD=boot
2274
2275
2276 =head2 VARIABLES
2277
2278 The following variables are interpreted in the novaboot script:
2279
2280 =over 8
2281
2282 =item BUILDDIR
2283
2284 Novaboot chdir()s to this directory before file generation phase. The
2285 directory name specified here is relative to the build directory
2286 specified by other means (see L</--build-dir>).
2287
2288 =item EXITON
2289
2290 Assigning this variable has the same effect as specifying L</--exiton>
2291 option.
2292
2293 =item INTERACTION
2294
2295 Setting this variable to zero is the same as giving
2296 L</--no-interaction>, specifying to one corresponds to
2297 L</--interaction>.
2298
2299 =item HYPERVISOR_PARAMS
2300
2301 Parameters passed to the hypervisor. The default value is "serial", unless
2302 overridden in the configuration file.
2303
2304 =item KERNEL
2305
2306 The kernel to use instead of the hypervisor specified in the
2307 configuration file with the C<$hypervisor> variable. The value should
2308 contain the name of the kernel image as well as its command line
2309 parameters. If this variable is defined and non-empty, the variable
2310 HYPERVISOR_PARAMS is not used.
2311
2312 =item NO_BOOT
2313
2314 If this variable is 1, the system is not booted. This is currently
2315 only implemented for U-Boot bootloader where it is useful for
2316 interacting with the bootloader without booting the system - e.g. for
2317 flashing.
2318
2319 =item QEMU
2320
2321 Use a specific qemu binary (can be overridden with B<-Q>) and flags
2322 when booting this script under qemu. If QEMU_FLAGS variable is also
2323 specified flags specified in QEMU variable are replaced by those in
2324 QEMU_FLAGS.
2325
2326 =item QEMU_FLAGS
2327
2328 Use specific qemu flags (can be overridden with B<-q>).
2329
2330 =item UBOOT_CMD
2331
2332 See L</--uboot-cmd>.
2333
2334 =item WVDESC
2335
2336 Description of the WvTest-compliant program.
2337
2338 =item WVTEST_TIMEOUT
2339
2340 The timeout in seconds for WvTest harness. If no complete line appears
2341 in the test output within the time specified here, the test fails. It
2342 is necessary to specify this for long running tests that produce no
2343 intermediate output.
2344
2345 =back
2346
2347 =head1 CONFIGURATION FILES
2348
2349 Novaboot can read its configuration from one or more files. By
2350 default, novaboot looks for files in F</etc/novaboot.d>, file
2351 F<~/.config/novaboot> and files named F<.novaboot> as described in
2352 L</Configuration reading phase>. Alternatively, configuration file
2353 location can be specified with the B<-c> switch or with the
2354 NOVABOOT_CONFIG environment variable. The configuration file has Perl
2355 syntax (i.e. it is better to put C<1;> as the last line) and should set
2356 values of certain Perl variables. The current configuration can be
2357 dumped with the B<--dump-config> switch. Some configuration variables
2358 can be overridden by environment variables (see below) or by command
2359 line switches.
2360
2361 Supported configuration variables include:
2362
2363 =over 8
2364
2365 =item $builddir
2366
2367 Build directory location relative to the location of the configuration
2368 file.
2369
2370 =item $default_target
2371
2372 Default target (see below) to use when no target is explicitly
2373 specified with the B<--target> command line option or
2374 B<NOVABOOT_TARGET> environment variable.
2375
2376 =item $netif
2377
2378 Default value for the B<--netif> option. If not specified, it defaults
2379 to I<eth0>.
2380
2381 =item %targets
2382
2383 Hash of target definitions to be used with the B<--target> option. The
2384 key is the identifier of the target, the value is the string with
2385 command line options. For instance, if the configuration file contains:
2386
2387  $targets{'mybox'} = '--copy=boot:/tftproot --serial=/dev/ttyUSB0 --grub',
2388
2389 then the following two commands are equivalent:
2390
2391  ./myos --copy=boot:/tftproot --serial=/dev/ttyUSB0 --grub
2392  ./myos -t mybox
2393
2394 =back
2395
2396 =head1 ENVIRONMENT VARIABLES
2397
2398 Some options can be specified not only via config file or command line
2399 but also through environment variables. Environment variables override
2400 the values from the configuration file and command line parameters
2401 override the environment variables.
2402
2403 =over 8
2404
2405 =item NOVABOOT_CONFIG
2406
2407 Name of the novaboot configuration file to use instead of the default
2408 one(s).
2409
2410 =item NOVABOOT_CONFIG_DIR
2411
2412 Name of the novaboot configuration directory. When not specified
2413 F</etc/novaboot.d> is used.
2414
2415 =item NOVABOOT_TARGET
2416
2417 Name of the novaboot target to use. This overrides the value of
2418 B<$default_target> from the configuration file and can be overridden
2419 with the B<--target> command line option.
2420
2421 =item NOVABOOT_BENDER
2422
2423 Defining this variable has the same effect as using B<--bender>
2424 option.
2425
2426 =back
2427
2428 =head1 AUTHORS
2429
2430 Michal Sojka <sojka@os.inf.tu-dresden.de>
2431
2432 Latest novaboot version can be found at
2433 L<https://github.com/wentasah/novaboot>.
2434
2435 =cut
2436
2437 # LocalWords:  novaboot Novaboot NOVABOOT TFTP PXE DHCP filename stty
2438 # LocalWords:  chainloader stdout Qemu qemu preprocessing ISOLINUX bootable
2439 # LocalWords:  config subprocesses sudo sudoers tftp dhcp IDE stdin
2440 # LocalWords:  subdirectories TTY whitespace heredoc POSIX WvTest