emacs/notmuch-lib.el

   1 ;; notmuch-lib.el --- common variables, functions and function declarations
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;; This is an part of an emacs-based interface to the notmuch mail system.
  23
  24 (require 'mm-view)
  25 (require 'mm-decode)
  26 (require 'cl)
  27
  28 (unless (require 'notmuch-version nil t)
  29   (defconst notmuch-emacs-version "unknown"
  30     "Placeholder variable when notmuch-version.el[c] is not available."))
  31
  32 (autoload 'notmuch-jump-search "notmuch-jump"
  33   "Jump to a saved search by shortcut key." t)
  34
  35 (defgroup notmuch nil
  36   "Notmuch mail reader for Emacs."
  37   :group 'mail)
  38
  39 (defgroup notmuch-hello nil
  40   "Overview of saved searches, tags, etc."
  41   :group 'notmuch)
  42
  43 (defgroup notmuch-search nil
  44   "Searching and sorting mail."
  45   :group 'notmuch)
  46
  47 (defgroup notmuch-show nil
  48   "Showing messages and threads."
  49   :group 'notmuch)
  50
  51 (defgroup notmuch-send nil
  52   "Sending messages from Notmuch."
  53   :group 'notmuch)
  54
  55 (custom-add-to-group 'notmuch-send 'message 'custom-group)
  56
  57 (defgroup notmuch-crypto nil
  58   "Processing and display of cryptographic MIME parts."
  59   :group 'notmuch)
  60
  61 (defgroup notmuch-hooks nil
  62   "Running custom code on well-defined occasions."
  63   :group 'notmuch)
  64
  65 (defgroup notmuch-external nil
  66   "Running external commands from within Notmuch."
  67   :group 'notmuch)
  68
  69 (defgroup notmuch-faces nil
  70   "Graphical attributes for displaying text"
  71   :group 'notmuch)
  72
  73 (defcustom notmuch-command "notmuch"
  74   "Name of the notmuch binary.
  75
  76 This can be a relative or absolute path to the notmuch binary.
  77 If this is a relative path, it will be searched for in all of the
  78 directories given in `exec-path' (which is, by default, based on
  79 $PATH)."
  80   :type 'string
  81   :group 'notmuch-external)
  82
  83 (defcustom notmuch-search-oldest-first t
  84   "Show the oldest mail first when searching.
  85
  86 This variable defines the default sort order for displaying
  87 search results. Note that any filtered searches created by
  88 `notmuch-search-filter' retain the search order of the parent
  89 search."
  90   :type 'boolean
  91   :group 'notmuch-search)
  92
  93 (defcustom notmuch-poll-script nil
  94   "[Deprecated] Command to run to incorporate new mail into the notmuch database.
  95
  96 This option has been deprecated in favor of \"notmuch new\"
  97 hooks (see man notmuch-hooks).  To change the path to the notmuch
  98 binary, customize `notmuch-command'.
  99
 100 This variable controls the action invoked by
 101 `notmuch-poll-and-refresh-this-buffer' (bound by default to 'G')
 102 to incorporate new mail into the notmuch database.
 103
 104 If set to nil (the default), new mail is processed by invoking
 105 \"notmuch new\". Otherwise, this should be set to a string that
 106 gives the name of an external script that processes new mail. If
 107 set to the empty string, no command will be run.
 108
 109 The external script could do any of the following depending on
 110 the user's needs:
 111
 112 1. Invoke a program to transfer mail to the local mail store
 113 2. Invoke \"notmuch new\" to incorporate the new mail
 114 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 115   :type '(choice (const :tag "notmuch new" nil)
 116                  (const :tag "Disabled" "")
 117                  (string :tag "Custom script"))
 118   :group 'notmuch-external)
 119
 120 ;;
 121
 122 (defvar notmuch-search-history nil
 123   "Variable to store notmuch searches history.")
 124
 125 (defcustom notmuch-archive-tags '("-inbox")
 126   "List of tag changes to apply to a message or a thread when it is archived.
 127
 128 Tags starting with \"+\" (or not starting with either \"+\" or
 129 \"-\") in the list will be added, and tags starting with \"-\"
 130 will be removed from the message or thread being archived.
 131
 132 For example, if you wanted to remove an \"inbox\" tag and add an
 133 \"archived\" tag, you would set:
 134     (\"-inbox\" \"+archived\")"
 135   :type '(repeat string)
 136   :group 'notmuch-search
 137   :group 'notmuch-show)
 138
 139 (defvar notmuch-common-keymap
 140   (let ((map (make-sparse-keymap)))
 141     (define-key map "?" 'notmuch-help)
 142     (define-key map "q" 'notmuch-bury-or-kill-this-buffer)
 143     (define-key map "s" 'notmuch-search)
 144     (define-key map "z" 'notmuch-tree)
 145     (define-key map "m" 'notmuch-mua-new-mail)
 146     (define-key map "=" 'notmuch-refresh-this-buffer)
 147     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
 148     (define-key map "j" 'notmuch-jump-search)
 149     map)
 150   "Keymap shared by all notmuch modes.")
 151
 152 ;; By default clicking on a button does not select the window
 153 ;; containing the button (as opposed to clicking on a widget which
 154 ;; does). This means that the button action is then executed in the
 155 ;; current selected window which can cause problems if the button
 156 ;; changes the buffer (e.g., id: links) or moves point.
 157 ;;
 158 ;; This provides a button type which overrides mouse-action so that
 159 ;; the button's window is selected before the action is run. Other
 160 ;; notmuch buttons can get the same behaviour by inheriting from this
 161 ;; button type.
 162 (define-button-type 'notmuch-button-type
 163   'mouse-action (lambda (button)
 164                   (select-window (posn-window (event-start last-input-event)))
 165                   (button-activate button)))
 166
 167 (defun notmuch-command-to-string (&rest args)
 168   "Synchronously invoke \"notmuch\" with the given list of arguments.
 169
 170 If notmuch exits with a non-zero status, output from the process
 171 will appear in a buffer named \"*Notmuch errors*\" and an error
 172 will be signaled.
 173
 174 Otherwise the output will be returned"
 175   (with-temp-buffer
 176     (let* ((status (apply #'call-process notmuch-command nil t nil args))
 177            (output (buffer-string)))
 178       (notmuch-check-exit-status status (cons notmuch-command args) output)
 179       output)))
 180
 181 (defvar notmuch--cli-sane-p nil
 182   "Cache whether the CLI seems to be configured sanely.")
 183
 184 (defun notmuch-cli-sane-p ()
 185   "Return t if the cli seems to be configured sanely."
 186   (unless notmuch--cli-sane-p
 187     (let ((status (call-process notmuch-command nil nil nil
 188                                 "config" "get" "user.primary_email")))
 189       (setq notmuch--cli-sane-p (= status 0))))
 190   notmuch--cli-sane-p)
 191
 192 (defun notmuch-assert-cli-sane ()
 193   (unless (notmuch-cli-sane-p)
 194     (notmuch-logged-error
 195      "notmuch cli seems misconfigured or unconfigured."
 196 "Perhaps you haven't run \"notmuch setup\" yet? Try running this
 197 on the command line, and then retry your notmuch command")))
 198
 199 (defun notmuch-cli-version ()
 200   "Return a string with the notmuch cli command version number."
 201   (let ((long-string
 202          ;; Trim off the trailing newline.
 203          (substring (notmuch-command-to-string "--version") 0 -1)))
 204     (if (string-match "^notmuch\\( version\\)? \\(.*\\)$"
 205                       long-string)
 206         (match-string 2 long-string)
 207       "unknown")))
 208
 209 (defun notmuch-config-get (item)
 210   "Return a value from the notmuch configuration."
 211   (let* ((val (notmuch-command-to-string "config" "get" item))
 212          (len (length val)))
 213     ;; Trim off the trailing newline (if the value is empty or not
 214     ;; configured, there will be no newline)
 215     (if (and (> len 0) (= (aref val (- len 1)) ?\n))
 216         (substring val 0 -1)
 217       val)))
 218
 219 (defun notmuch-database-path ()
 220   "Return the database.path value from the notmuch configuration."
 221   (notmuch-config-get "database.path"))
 222
 223 (defun notmuch-user-name ()
 224   "Return the user.name value from the notmuch configuration."
 225   (notmuch-config-get "user.name"))
 226
 227 (defun notmuch-user-primary-email ()
 228   "Return the user.primary_email value from the notmuch configuration."
 229   (notmuch-config-get "user.primary_email"))
 230
 231 (defun notmuch-user-other-email ()
 232   "Return the user.other_email value (as a list) from the notmuch configuration."
 233   (split-string (notmuch-config-get "user.other_email") "\n" t))
 234
 235 (defun notmuch-poll ()
 236   "Run \"notmuch new\" or an external script to import mail.
 237
 238 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 239 depending on the value of `notmuch-poll-script'."
 240   (interactive)
 241   (if (stringp notmuch-poll-script)
 242       (unless (string= notmuch-poll-script "")
 243         (unless (equal (call-process notmuch-poll-script nil nil) 0)
 244           (error "Notmuch: poll script `%s' failed!" notmuch-poll-script)))
 245     (notmuch-call-notmuch-process "new")))
 246
 247 (defun notmuch-bury-or-kill-this-buffer ()
 248   "Undisplay the current buffer.
 249
 250 Bury the current buffer, unless there is only one window showing
 251 it, in which case it is killed."
 252   (interactive)
 253   (if (> (length (get-buffer-window-list nil nil t)) 1)
 254       (bury-buffer)
 255     (kill-buffer)))
 256
 257 (defun notmuch-documentation-first-line (symbol)
 258   "Return the first line of the documentation string for SYMBOL."
 259   (let ((doc (documentation symbol)))
 260     (if doc
 261         (with-temp-buffer
 262           (insert (documentation symbol t))
 263           (goto-char (point-min))
 264           (let ((beg (point)))
 265             (end-of-line)
 266             (buffer-substring beg (point))))
 267       "")))
 268
 269 (defun notmuch-prefix-key-description (key)
 270   "Given a prefix key code, return a human-readable string representation.
 271
 272 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 273   (let* ((key-vector (if (vectorp key) key (vector key)))
 274          (desc (format-kbd-macro key-vector)))
 275     (if (string= desc "ESC")
 276         "M-"
 277       (concat desc " "))))
 278
 279
 280 (defun notmuch-describe-key (actual-key binding prefix ua-keys tail)
 281   "Prepend cons cells describing prefix-arg ACTUAL-KEY and ACTUAL-KEY to TAIL
 282
 283 It does not prepend if ACTUAL-KEY is already listed in TAIL."
 284   (let ((key-string (concat prefix (format-kbd-macro actual-key))))
 285     ;; We don't include documentation if the key-binding is
 286     ;; over-ridden. Note, over-riding a binding automatically hides the
 287     ;; prefixed version too.
 288     (unless (assoc key-string tail)
 289       (when (and ua-keys (symbolp binding)
 290                  (get binding 'notmuch-prefix-doc))
 291         ;; Documentation for prefixed command
 292         (let ((ua-desc (key-description ua-keys)))
 293           (push (cons (concat ua-desc " " prefix (format-kbd-macro actual-key))
 294                       (get binding 'notmuch-prefix-doc))
 295                 tail)))
 296       ;; Documentation for command
 297       (push (cons key-string
 298                   (or (and (symbolp binding) (get binding 'notmuch-doc))
 299                       (notmuch-documentation-first-line binding)))
 300             tail)))
 301     tail)
 302
 303 (defun notmuch-describe-remaps (remap-keymap ua-keys base-keymap prefix tail)
 304   ;; Remappings are represented as a binding whose first "event" is
 305   ;; 'remap.  Hence, if the keymap has any remappings, it will have a
 306   ;; binding whose "key" is 'remap, and whose "binding" is itself a
 307   ;; keymap that maps not from keys to commands, but from old (remapped)
 308   ;; functions to the commands to use in their stead.
 309   (map-keymap
 310    (lambda (command binding)
 311      (mapc
 312       (lambda (actual-key)
 313         (setq tail (notmuch-describe-key actual-key binding prefix ua-keys tail)))
 314       (where-is-internal command base-keymap)))
 315    remap-keymap)
 316   tail)
 317
 318 (defun notmuch-describe-keymap (keymap ua-keys base-keymap &optional prefix tail)
 319   "Return a list of cons cells, each describing one binding in KEYMAP.
 320
 321 Each cons cell consists of a string giving a human-readable
 322 description of the key, and a one-line description of the bound
 323 function.  See `notmuch-help' for an overview of how this
 324 documentation is extracted.
 325
 326 UA-KEYS should be a key sequence bound to `universal-argument'.
 327 It will be used to describe bindings of commands that support a
 328 prefix argument.  PREFIX and TAIL are used internally."
 329   (map-keymap
 330    (lambda (key binding)
 331      (cond ((mouse-event-p key) nil)
 332            ((keymapp binding)
 333             (setq tail
 334                   (if (eq key 'remap)
 335                       (notmuch-describe-remaps
 336                        binding ua-keys base-keymap prefix tail)
 337                     (notmuch-describe-keymap
 338                      binding ua-keys base-keymap (notmuch-prefix-key-description key) tail))))
 339            (binding
 340             (setq tail (notmuch-describe-key (vector key) binding prefix ua-keys tail)))))
 341    keymap)
 342   tail)
 343
 344 (defun notmuch-substitute-command-keys (doc)
 345   "Like `substitute-command-keys' but with documentation, not function names."
 346   (let ((beg 0))
 347     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 348       (let ((desc
 349              (save-match-data
 350                (let* ((keymap-name (substring doc (match-beginning 1) (match-end 1)))
 351                       (keymap (symbol-value (intern keymap-name)))
 352                       (ua-keys (where-is-internal 'universal-argument keymap t))
 353                       (desc-alist (notmuch-describe-keymap keymap ua-keys keymap))
 354                       (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist)))
 355                  (mapconcat #'identity desc-list "\n")))))
 356         (setq doc (replace-match desc 1 1 doc)))
 357       (setq beg (match-end 0)))
 358     doc))
 359
 360 (defun notmuch-help ()
 361   "Display help for the current notmuch mode.
 362
 363 This is similar to `describe-function' for the current major
 364 mode, but bindings tables are shown with documentation strings
 365 rather than command names.  By default, this uses the first line
 366 of each command's documentation string.  A command can override
 367 this by setting the 'notmuch-doc property of its command symbol.
 368 A command that supports a prefix argument can explicitly document
 369 its prefixed behavior by setting the 'notmuch-prefix-doc property
 370 of its command symbol."
 371   (interactive)
 372   (let* ((mode major-mode)
 373          (doc (substitute-command-keys (notmuch-substitute-command-keys (documentation mode t)))))
 374     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 375       (insert doc)
 376       (goto-char (point-min))
 377       (set-buffer-modified-p nil)
 378       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 379
 380 (defun notmuch-subkeymap-help ()
 381   "Show help for a subkeymap."
 382   (interactive)
 383   (let* ((key (this-command-keys-vector))
 384         (prefix (make-vector (1- (length key)) nil))
 385         (i 0))
 386     (while (< i (length prefix))
 387       (aset prefix i (aref key i))
 388       (setq i (1+ i)))
 389
 390     (let* ((subkeymap (key-binding prefix))
 391            (ua-keys (where-is-internal 'universal-argument nil t))
 392            (prefix-string (notmuch-prefix-key-description prefix))
 393            (desc-alist (notmuch-describe-keymap subkeymap ua-keys subkeymap prefix-string))
 394            (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg))) desc-alist))
 395            (desc (mapconcat #'identity desc-list "\n")))
 396       (with-help-window (help-buffer)
 397         (with-current-buffer standard-output
 398           (insert "\nPress 'q' to quit this window.\n\n")
 399           (insert desc)))
 400       (pop-to-buffer (help-buffer)))))
 401
 402 (defvar notmuch-buffer-refresh-function nil
 403   "Function to call to refresh the current buffer.")
 404 (make-variable-buffer-local 'notmuch-buffer-refresh-function)
 405
 406 (defun notmuch-refresh-this-buffer ()
 407   "Refresh the current buffer."
 408   (interactive)
 409   (when notmuch-buffer-refresh-function
 410     (if (commandp notmuch-buffer-refresh-function)
 411         ;; Pass prefix argument, etc.
 412         (call-interactively notmuch-buffer-refresh-function)
 413       (funcall notmuch-buffer-refresh-function))))
 414
 415 (defun notmuch-poll-and-refresh-this-buffer ()
 416   "Invoke `notmuch-poll' to import mail, then refresh the current buffer."
 417   (interactive)
 418   (notmuch-poll)
 419   (notmuch-refresh-this-buffer))
 420
 421 (defun notmuch-prettify-subject (subject)
 422   ;; This function is used by `notmuch-search-process-filter' which
 423   ;; requires that we not disrupt its' matching state.
 424   (save-match-data
 425     (if (and subject
 426              (string-match "^[ \t]*$" subject))
 427         "[No Subject]"
 428       subject)))
 429
 430 (defun notmuch-sanitize (str)
 431   "Sanitize control character in STR.
 432
 433 This includes newlines, tabs, and other funny characters."
 434   (replace-regexp-in-string "[[:cntrl:]\x7f\u2028\u2029]+" " " str))
 435
 436 (defun notmuch-escape-boolean-term (term)
 437   "Escape a boolean term for use in a query.
 438
 439 The caller is responsible for prepending the term prefix and a
 440 colon.  This performs minimal escaping in order to produce
 441 user-friendly queries."
 442
 443   (save-match-data
 444     (if (or (equal term "")
 445             ;; To be pessimistic, only pass through terms composed
 446             ;; entirely of ASCII printing characters other than ", (,
 447             ;; and ).
 448             (string-match "[^!#-'*-~]" term))
 449         ;; Requires escaping
 450         (concat "\"" (replace-regexp-in-string "\"" "\"\"" term t t) "\"")
 451       term)))
 452
 453 (defun notmuch-id-to-query (id)
 454   "Return a query that matches the message with id ID."
 455   (concat "id:" (notmuch-escape-boolean-term id)))
 456
 457 (defun notmuch-hex-encode (str)
 458   "Hex-encode STR (e.g., as used by batch tagging).
 459
 460 This replaces spaces, percents, and double quotes in STR with
 461 %NN where NN is the hexadecimal value of the character."
 462   (replace-regexp-in-string
 463    "[ %\"]" (lambda (match) (format "%%%02x" (aref match 0))) str))
 464
 465 ;;
 466
 467 (defun notmuch-common-do-stash (text)
 468   "Common function to stash text in kill ring, and display in minibuffer."
 469   (if text
 470       (progn
 471         (kill-new text)
 472         (message "Stashed: %s" text))
 473     ;; There is nothing to stash so stash an empty string so the user
 474     ;; doesn't accidentally paste something else somewhere.
 475     (kill-new "")
 476     (message "Nothing to stash!")))
 477
 478 ;;
 479
 480 (defun notmuch-remove-if-not (predicate list)
 481   "Return a copy of LIST with all items not satisfying PREDICATE removed."
 482   (let (out)
 483     (while list
 484       (when (funcall predicate (car list))
 485         (push (car list) out))
 486       (setq list (cdr list)))
 487     (nreverse out)))
 488
 489 (defun notmuch-plist-delete (plist property)
 490   (let* ((xplist (cons nil plist))
 491          (pred xplist))
 492     (while (cdr pred)
 493       (when (eq (cadr pred) property)
 494         (setcdr pred (cdddr pred)))
 495       (setq pred (cddr pred)))
 496     (cdr xplist)))
 497
 498 (defun notmuch-split-content-type (content-type)
 499   "Split content/type into 'content' and 'type'"
 500   (split-string content-type "/"))
 501
 502 (defun notmuch-match-content-type (t1 t2)
 503   "Return t if t1 and t2 are matching content types, taking wildcards into account"
 504   (let ((st1 (notmuch-split-content-type t1))
 505         (st2 (notmuch-split-content-type t2)))
 506     (if (or (string= (cadr st1) "*")
 507             (string= (cadr st2) "*"))
 508         ;; Comparison of content types should be case insensitive.
 509         (string= (downcase (car st1)) (downcase (car st2)))
 510       (string= (downcase t1) (downcase t2)))))
 511
 512 (defvar notmuch-multipart/alternative-discouraged
 513   '(
 514     ;; Avoid HTML parts.
 515     "text/html"
 516     ;; multipart/related usually contain a text/html part and some associated graphics.
 517     "multipart/related"
 518     ))
 519
 520 (defun notmuch-multipart/alternative-choose (types)
 521   "Return a list of preferred types from the given list of types"
 522   ;; Based on `mm-preferred-alternative-precedence'.
 523   (let ((seq types))
 524     (dolist (pref (reverse notmuch-multipart/alternative-discouraged))
 525       (dolist (elem (copy-sequence seq))
 526         (when (string-match pref elem)
 527           (setq seq (nconc (delete elem seq) (list elem))))))
 528     seq))
 529
 530 (defun notmuch-parts-filter-by-type (parts type)
 531   "Given a list of message parts, return a list containing the ones matching
 532 the given type."
 533   (remove-if-not
 534    (lambda (part) (notmuch-match-content-type (plist-get part :content-type) type))
 535    parts))
 536
 537 (defun notmuch-get-bodypart-binary (msg part process-crypto &optional cache)
 538   "Return the unprocessed content of PART in MSG as a unibyte string.
 539
 540 This returns the \"raw\" content of the given part after content
 541 transfer decoding, but with no further processing (see the
 542 discussion of --format=raw in man notmuch-show).  In particular,
 543 this does no charset conversion.
 544
 545 If CACHE is non-nil, the content of this part will be saved in
 546 MSG (if it isn't already)."
 547   (let ((data (plist-get part :binary-content)))
 548     (when (not data)
 549       (let ((args `("show" "--format=raw"
 550                     ,(format "--part=%d" (plist-get part :id))
 551                     ,@(when process-crypto '("--decrypt"))
 552                     ,(notmuch-id-to-query (plist-get msg :id)))))
 553         (with-temp-buffer
 554           ;; Emacs internally uses a UTF-8-like multibyte string
 555           ;; representation by default (regardless of the coding
 556           ;; system, which only affects how it goes from outside data
 557           ;; to this internal representation).  This *almost* never
 558           ;; matters.  Annoyingly, it does matter if we use this data
 559           ;; in an image descriptor, since Emacs will use its internal
 560           ;; data buffer directly and this multibyte representation
 561           ;; corrupts binary image formats.  Since the caller is
 562           ;; asking for binary data, a unibyte string is a more
 563           ;; appropriate representation anyway.
 564           (set-buffer-multibyte nil)
 565           (let ((coding-system-for-read 'no-conversion))
 566             (apply #'call-process notmuch-command nil '(t nil) nil args)
 567             (setq data (buffer-string)))))
 568       (when cache
 569         ;; Cheat.  part is non-nil, and `plist-put' always modifies
 570         ;; the list in place if it's non-nil.
 571         (plist-put part :binary-content data)))
 572     data))
 573
 574 (defun notmuch-get-bodypart-text (msg part process-crypto &optional cache)
 575   "Return the text content of PART in MSG.
 576
 577 This returns the content of the given part as a multibyte Lisp
 578 string after performing content transfer decoding and any
 579 necessary charset decoding.  It is an error to use this for
 580 non-text/* parts.
 581
 582 If CACHE is non-nil, the content of this part will be saved in
 583 MSG (if it isn't already)."
 584   (let ((content (plist-get part :content)))
 585     (when (not content)
 586       ;; Use show --format=sexp to fetch decoded content
 587       (let* ((args `("show" "--format=sexp" "--include-html"
 588                      ,(format "--part=%s" (plist-get part :id))
 589                      ,@(when process-crypto '("--decrypt"))
 590                      ,(notmuch-id-to-query (plist-get msg :id))))
 591              (npart (apply #'notmuch-call-notmuch-sexp args)))
 592         (setq content (plist-get npart :content))
 593         (when (not content)
 594           (error "Internal error: No :content from %S" args)))
 595       (when cache
 596         (plist-put part :content content)))
 597     content))
 598
 599 ;; Workaround: The call to `mm-display-part' below triggers a bug in
 600 ;; Emacs 24 if it attempts to use the shr renderer to display an HTML
 601 ;; part with images in it (demonstrated in 24.1 and 24.2 on Debian and
 602 ;; Fedora 17, though unreproducable in other configurations).
 603 ;; `mm-shr' references the variable `gnus-inhibit-images' without
 604 ;; first loading gnus-art, which defines it, resulting in a
 605 ;; void-variable error.  Hence, we advise `mm-shr' to ensure gnus-art
 606 ;; is loaded.
 607 (if (>= emacs-major-version 24)
 608     (defadvice mm-shr (before load-gnus-arts activate)
 609       (require 'gnus-art nil t)
 610       (ad-disable-advice 'mm-shr 'before 'load-gnus-arts)
 611       (ad-activate 'mm-shr)))
 612
 613 (defun notmuch-mm-display-part-inline (msg part content-type process-crypto)
 614   "Use the mm-decode/mm-view functions to display a part in the
 615 current buffer, if possible."
 616   (let ((display-buffer (current-buffer)))
 617     (with-temp-buffer
 618       ;; In case we already have :content, use it and tell mm-* that
 619       ;; it's already been charset-decoded by using the fake
 620       ;; `gnus-decoded' charset.  Otherwise, we'll fetch the binary
 621       ;; part content and let mm-* decode it.
 622       (let* ((have-content (plist-member part :content))
 623              (charset (if have-content 'gnus-decoded
 624                         (plist-get part :content-charset)))
 625              (handle (mm-make-handle (current-buffer) `(,content-type (charset . ,charset)))))
 626         ;; If the user wants the part inlined, insert the content and
 627         ;; test whether we are able to inline it (which includes both
 628         ;; capability and suitability tests).
 629         (when (mm-inlined-p handle)
 630           (if have-content
 631               (insert (notmuch-get-bodypart-text msg part process-crypto))
 632             (insert (notmuch-get-bodypart-binary msg part process-crypto)))
 633           (when (mm-inlinable-p handle)
 634             (set-buffer display-buffer)
 635             (mm-display-part handle)
 636             t))))))
 637
 638 ;; Converts a plist of headers to an alist of headers. The input plist should
 639 ;; have symbols of the form :Header as keys, and the resulting alist will have
 640 ;; symbols of the form 'Header as keys.
 641 (defun notmuch-headers-plist-to-alist (plist)
 642   (loop for (key value . rest) on plist by #'cddr
 643         collect (cons (intern (substring (symbol-name key) 1)) value)))
 644
 645 (defun notmuch-face-ensure-list-form (face)
 646   "Return FACE in face list form.
 647
 648 If FACE is already a face list, it will be returned as-is.  If
 649 FACE is a face name or face plist, it will be returned as a
 650 single element face list."
 651   (if (and (listp face) (not (keywordp (car face))))
 652       face
 653     (list face)))
 654
 655 (defun notmuch-apply-face (object face &optional below start end)
 656   "Combine FACE into the 'face text property of OBJECT between START and END.
 657
 658 This function combines FACE with any existing faces between START
 659 and END in OBJECT.  Attributes specified by FACE take precedence
 660 over existing attributes unless BELOW is non-nil.
 661
 662 OBJECT may be a string, a buffer, or nil (which means the current
 663 buffer).  If object is a string, START and END are 0-based;
 664 otherwise they are buffer positions (integers or markers).  FACE
 665 must be a face name (a symbol or string), a property list of face
 666 attributes, or a list of these.  If START and/or END are omitted,
 667 they default to the beginning/end of OBJECT.  For convenience
 668 when applied to strings, this returns OBJECT."
 669
 670   ;; A face property can have three forms: a face name (a string or
 671   ;; symbol), a property list, or a list of these two forms.  In the
 672   ;; list case, the faces will be combined, with the earlier faces
 673   ;; taking precedent.  Here we canonicalize everything to list form
 674   ;; to make it easy to combine.
 675   (let ((pos (cond (start start)
 676                    ((stringp object) 0)
 677                    (t 1)))
 678         (end (cond (end end)
 679                    ((stringp object) (length object))
 680                    (t (1+ (buffer-size object)))))
 681         (face-list (notmuch-face-ensure-list-form face)))
 682     (while (< pos end)
 683       (let* ((cur (get-text-property pos 'face object))
 684              (cur-list (notmuch-face-ensure-list-form cur))
 685              (new (cond ((null cur-list) face)
 686                         (below (append cur-list face-list))
 687                         (t (append face-list cur-list))))
 688              (next (next-single-property-change pos 'face object end)))
 689         (put-text-property pos next 'face new object)
 690         (setq pos next))))
 691   object)
 692
 693 (defun notmuch-map-text-property (start end prop func &optional object)
 694   "Transform text property PROP using FUNC.
 695
 696 Applies FUNC to each distinct value of the text property PROP
 697 between START and END of OBJECT, setting PROP to the value
 698 returned by FUNC."
 699   (while (< start end)
 700     (let ((value (get-text-property start prop object))
 701           (next (next-single-property-change start prop object end)))
 702       (put-text-property start next prop (funcall func value) object)
 703       (setq start next))))
 704
 705 (defun notmuch-logged-error (msg &optional extra)
 706   "Log MSG and EXTRA to *Notmuch errors* and signal MSG.
 707
 708 This logs MSG and EXTRA to the *Notmuch errors* buffer and
 709 signals MSG as an error.  If EXTRA is non-nil, text referring the
 710 user to the *Notmuch errors* buffer will be appended to the
 711 signaled error.  This function does not return."
 712
 713   (with-current-buffer (get-buffer-create "*Notmuch errors*")
 714     (goto-char (point-max))
 715     (unless (bobp)
 716       (newline))
 717     (save-excursion
 718       (insert "[" (current-time-string) "]\n" msg)
 719       (unless (bolp)
 720         (newline))
 721       (when extra
 722         (insert extra)
 723         (unless (bolp)
 724           (newline)))))
 725   (error "%s" (concat msg (when extra
 726                             " (see *Notmuch errors* for more details)"))))
 727
 728 (defun notmuch-check-async-exit-status (proc msg &optional command err-file)
 729   "If PROC exited abnormally, pop up an error buffer and signal an error.
 730
 731 This is a wrapper around `notmuch-check-exit-status' for
 732 asynchronous process sentinels.  PROC and MSG must be the
 733 arguments passed to the sentinel.  COMMAND and ERR-FILE, if
 734 provided, are passed to `notmuch-check-exit-status'.  If COMMAND
 735 is not provided, it is taken from `process-command'."
 736   (let ((exit-status
 737          (case (process-status proc)
 738            ((exit) (process-exit-status proc))
 739            ((signal) msg))))
 740     (when exit-status
 741       (notmuch-check-exit-status exit-status (or command (process-command proc))
 742                                  nil err-file))))
 743
 744 (defun notmuch-check-exit-status (exit-status command &optional output err-file)
 745   "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
 746
 747 If EXIT-STATUS is non-zero, pop up a notmuch error buffer
 748 describing the error and signal an Elisp error.  EXIT-STATUS must
 749 be a number indicating the exit status code of a process or a
 750 string describing the signal that terminated the process (such as
 751 returned by `call-process').  COMMAND must be a list giving the
 752 command and its arguments.  OUTPUT, if provided, is a string
 753 giving the output of command.  ERR-FILE, if provided, is the name
 754 of a file containing the error output of command.  OUTPUT and the
 755 contents of ERR-FILE will be included in the error message."
 756
 757   (cond
 758    ((eq exit-status 0) t)
 759    ((eq exit-status 20)
 760     (notmuch-logged-error "notmuch CLI version mismatch
 761 Emacs requested an older output format than supported by the notmuch CLI.
 762 You may need to restart Emacs or upgrade your notmuch Emacs package."))
 763    ((eq exit-status 21)
 764     (notmuch-logged-error "notmuch CLI version mismatch
 765 Emacs requested a newer output format than supported by the notmuch CLI.
 766 You may need to restart Emacs or upgrade your notmuch package."))
 767    (t
 768     (let* ((err (when err-file
 769                   (with-temp-buffer
 770                     (insert-file-contents err-file)
 771                     (unless (eobp)
 772                       (buffer-string)))))
 773            (extra
 774             (concat
 775              "command: " (mapconcat #'shell-quote-argument command " ") "\n"
 776              (if (integerp exit-status)
 777                  (format "exit status: %s\n" exit-status)
 778                (format "exit signal: %s\n" exit-status))
 779              (when err
 780                (concat "stderr:\n" err))
 781              (when output
 782                (concat "stdout:\n" output)))))
 783         (if err
 784             ;; We have an error message straight from the CLI.
 785             (notmuch-logged-error
 786              (replace-regexp-in-string "[ \n\r\t\f]*\\'" "" err) extra)
 787           ;; We only have combined output from the CLI; don't inundate
 788           ;; the user with it.  Mimic `process-lines'.
 789           (notmuch-logged-error (format "%s exited with status %s"
 790                                         (car command) exit-status)
 791                                 extra))
 792         ;; `notmuch-logged-error' does not return.
 793         ))))
 794
 795 (defun notmuch-call-notmuch--helper (destination args)
 796   "Helper for synchronous notmuch invocation commands.
 797
 798 This wraps `call-process'.  DESTINATION has the same meaning as
 799 for `call-process'.  ARGS is as described for
 800 `notmuch-call-notmuch-process'."
 801
 802   (let (stdin-string)
 803     (while (keywordp (car args))
 804       (case (car args)
 805         (:stdin-string (setq stdin-string (cadr args)
 806                              args (cddr args)))
 807         (otherwise
 808          (error "Unknown keyword argument: %s" (car args)))))
 809     (if (null stdin-string)
 810         (apply #'call-process notmuch-command nil destination nil args)
 811       (insert stdin-string)
 812       (apply #'call-process-region (point-min) (point-max)
 813              notmuch-command t destination nil args))))
 814
 815 (defun notmuch-call-notmuch-process (&rest args)
 816   "Synchronously invoke `notmuch-command' with ARGS.
 817
 818 The caller may provide keyword arguments before ARGS.  Currently
 819 supported keyword arguments are:
 820
 821   :stdin-string STRING - Write STRING to stdin
 822
 823 If notmuch exits with a non-zero status, output from the process
 824 will appear in a buffer named \"*Notmuch errors*\" and an error
 825 will be signaled."
 826   (with-temp-buffer
 827     (let ((status (notmuch-call-notmuch--helper t args)))
 828       (notmuch-check-exit-status status (cons notmuch-command args)
 829                                  (buffer-string)))))
 830
 831 (defun notmuch-call-notmuch-sexp (&rest args)
 832   "Invoke `notmuch-command' with ARGS and return the parsed S-exp output.
 833
 834 This is equivalent to `notmuch-call-notmuch-process', but parses
 835 notmuch's output as an S-expression and returns the parsed value.
 836 Like `notmuch-call-notmuch-process', if notmuch exits with a
 837 non-zero status, this will report its output and signal an
 838 error."
 839
 840   (with-temp-buffer
 841     (let ((err-file (make-temp-file "nmerr")))
 842       (unwind-protect
 843           (let ((status (notmuch-call-notmuch--helper (list t err-file) args)))
 844             (notmuch-check-exit-status status (cons notmuch-command args)
 845                                        (buffer-string) err-file)
 846             (goto-char (point-min))
 847             (read (current-buffer)))
 848         (delete-file err-file)))))
 849
 850 (defun notmuch-start-notmuch (name buffer sentinel &rest args)
 851   "Start and return an asynchronous notmuch command.
 852
 853 This starts and returns an asynchronous process running
 854 `notmuch-command' with ARGS.  The exit status is checked via
 855 `notmuch-check-async-exit-status'.  Output written to stderr is
 856 redirected and displayed when the process exits (even if the
 857 process exits successfully).  NAME and BUFFER are the same as in
 858 `start-process'.  SENTINEL is a process sentinel function to call
 859 when the process exits, or nil for none.  The caller must *not*
 860 invoke `set-process-sentinel' directly on the returned process,
 861 as that will interfere with the handling of stderr and the exit
 862 status."
 863
 864   ;; There is no way (as of Emacs 24.3) to capture stdout and stderr
 865   ;; separately for asynchronous processes, or even to redirect stderr
 866   ;; to a file, so we use a trivial shell wrapper to send stderr to a
 867   ;; temporary file and clean things up in the sentinel.
 868   (let* ((err-file (make-temp-file "nmerr"))
 869          ;; Use a pipe
 870          (process-connection-type nil)
 871          ;; Find notmuch using Emacs' `exec-path'
 872          (command (or (executable-find notmuch-command)
 873                       (error "command not found: %s" notmuch-command)))
 874          (proc (apply #'start-process name buffer
 875                       "/bin/sh" "-c"
 876                       "exec 2>\"$1\"; shift; exec \"$0\" \"$@\""
 877                       command err-file args)))
 878     (process-put proc 'err-file err-file)
 879     (process-put proc 'sub-sentinel sentinel)
 880     (process-put proc 'real-command (cons notmuch-command args))
 881     (set-process-sentinel proc #'notmuch-start-notmuch-sentinel)
 882     proc))
 883
 884 (defun notmuch-start-notmuch-sentinel (proc event)
 885   (let ((err-file (process-get proc 'err-file))
 886         (sub-sentinel (process-get proc 'sub-sentinel))
 887         (real-command (process-get proc 'real-command)))
 888     (condition-case err
 889         (progn
 890           ;; Invoke the sub-sentinel, if any
 891           (when sub-sentinel
 892             (funcall sub-sentinel proc event))
 893           ;; Check the exit status.  This will signal an error if the
 894           ;; exit status is non-zero.  Don't do this if the process
 895           ;; buffer is dead since that means Emacs killed the process
 896           ;; and there's no point in telling the user that (but we
 897           ;; still check for and report stderr output below).
 898           (when (buffer-live-p (process-buffer proc))
 899             (notmuch-check-async-exit-status proc event real-command err-file))
 900           ;; If that didn't signal an error, then any error output was
 901           ;; really warning output.  Show warnings, if any.
 902           (let ((warnings
 903                  (with-temp-buffer
 904                    (unless (= (second (insert-file-contents err-file)) 0)
 905                      (end-of-line)
 906                      ;; Show first line; stuff remaining lines in the
 907                      ;; errors buffer.
 908                      (let ((l1 (buffer-substring (point-min) (point))))
 909                        (skip-chars-forward "\n")
 910                        (cons l1 (unless (eobp)
 911                                   (buffer-substring (point) (point-max)))))))))
 912             (when warnings
 913               (notmuch-logged-error (car warnings) (cdr warnings)))))
 914       (error
 915        ;; Emacs behaves strangely if an error escapes from a sentinel,
 916        ;; so turn errors into messages.
 917        (message "%s" (error-message-string err))))
 918     (ignore-errors (delete-file err-file))))
 919
 920 ;; This variable is used only buffer local, but it needs to be
 921 ;; declared globally first to avoid compiler warnings.
 922 (defvar notmuch-show-process-crypto nil)
 923 (make-variable-buffer-local 'notmuch-show-process-crypto)
 924
 925 (provide 'notmuch-lib)
 926
 927 ;; Local Variables:
 928 ;; byte-compile-warnings: (not cl-functions)
 929 ;; End: