hw/mem.vhd

   1 ---------------------------------------------------------------------------------
   2 --
   3 --  Entity:       mem
   4 --  Filename:     mem.vhd
   5 --  Description:  the Memory (MEM) control unit for
   6 --                the TUD MB-Lite implementation
   7 --
   8 --  Author:       Huib Lincklaen Arriens
   9 --                Delft University of Technology
  10 --                Faculty EEMCS, Department ME&CE, Circuits and Systems
  11 --  Date:         October, 2010
  12 --
  13 --  Modified:     December, 2010: handle S_FSL Data Input (Huib)
  14 --  Remarks:
  15 --------------------------------------------------------------------------------
  16
  17 LIBRARY IEEE;
  18 USE IEEE.std_logic_1164.all;
  19 USE work.mbl_Pkg.all;
  20
  21 --------------------------------------------------------------------------------
  22 ENTITY mem IS
  23 --------------------------------------------------------------------------------
  24         PORT
  25         (
  26                 EX2MEM_i    :  IN EX2MEM_Type;
  27                 --
  28                 DMEMB_i     :  IN DMEMB2CORE_Type;
  29                 DMEMB_o     : OUT CORE2DMEMB_Type;
  30                 --
  31                 MEM_REG_i   :  IN MEM_REG_Type;
  32                 MEM_REG_o   : OUT MEM_REG_Type;
  33                 --
  34                 MEM_WRB_o   : OUT WRB_Type;
  35                 MEM2CTRL_o  : OUT MEM2CTRL_Type
  36         );
  37 END ENTITY mem;
  38
  39 --------------------------------------------------------------------------------
  40 ARCHITECTURE rtl OF mem IS
  41 --------------------------------------------------------------------------------
  42
  43 BEGIN
  44
  45         -- writeback in case of reads from the data memory bus:
  46         -- delay wrb-ctrl signals (see core_ctrl) to stay in sync
  47         -- with synchronous dmem data output
  48         -- Following are only the unconditional pass-through signals. More are in the p_mem process.
  49         MEM_REG_o.wrb_Action  <= EX2MEM_i.wrb_Action;
  50         MEM_REG_o.exeq_result <= EX2MEM_i.exeq_result;
  51         MEM_REG_o.byte_Enable <= EX2MEM_i.byte_Enable;
  52         MEM_REG_o.wrix_rD     <= EX2MEM_i.wrix_rD;
  53         --
  54         MEM_WRB_o.wrb_Action <= MEM_REG_i.wrb_Action;
  55         MEM_WRB_o.wrix_rD    <= MEM_REG_i.wrix_rD;
  56         -- also signal 'slow memory decices' and interrupts from devices
  57         MEM2CTRL_o.clken <= DMEMB_i.clken;
  58         MEM2CTRL_o.int   <= DMEMB_i.int;
  59         -- pass byte_select signal (NOTE: BIG ENDIAN)
  60         DMEMB_o.bSel     <= EX2MEM_i.byte_Enable;
  61
  62 p_mem:
  63         PROCESS (EX2MEM_i, DMEMB_i, MEM_REG_i)
  64                 VARIABLE exeq_data_v : STD_LOGIC_VECTOR (31 DOWNTO 0);
  65                 VARIABLE dmem_data_v : STD_LOGIC_VECTOR (31 DOWNTO 0);
  66
  67         BEGIN
  68
  69                 -- always align Big Endian input data from memory(-bus)
  70                 CASE MEM_REG_i.byte_Enable IS
  71                         WHEN "1000" => dmem_data_v := C_24_ZEROS & DMEMB_i.data(31 DOWNTO 24);
  72                         WHEN "0100" => dmem_data_v := C_24_ZEROS & DMEMB_i.data(23 DOWNTO 16);
  73                         WHEN "0010" => dmem_data_v := C_24_ZEROS & DMEMB_i.data(15 DOWNTO  8);
  74                         WHEN "0001" => dmem_data_v := C_24_ZEROS & DMEMB_i.data( 7 DOWNTO  0);
  75                         WHEN "1100" => dmem_data_v := C_16_ZEROS & DMEMB_i.data(31 DOWNTO 16);
  76                         WHEN "0011" => dmem_data_v := C_16_ZEROS & DMEMB_i.data(15 DOWNTO  0);
  77                         WHEN OTHERS => dmem_data_v :=              DMEMB_i.data;
  78                 END CASE;
  79
  80                 -- output to dmem-bus
  81                 CASE EX2MEM_i.mem_Action IS
  82
  83                         WHEN WR_MEM =>
  84                                 -- write (or forward) to data memory bus
  85                                 DMEMB_o.addr <= EX2MEM_i.exeq_result;
  86                                 DMEMB_o.ena  <= '1';
  87                                 DMEMB_o.wre  <= '1';
  88                                 -- Note: use MEM_REG_i here, since MEM_WRB_o (output) cannot be read
  89                                 IF ((MEM_REG_i.wrb_Action /= NO_WRB) AND
  90                                         (EX2MEM_i.wrix_rD = MEM_REG_i.wrix_rD)) THEN
  91                                         CASE MEM_REG_i.wrb_Action IS
  92                                                 WHEN WRB_EX  =>
  93                                                         -- forward exeq output, to handle e.g. add rD,rA,xx; sw rD,mem[y]; ...
  94                                                         exeq_data_v := MEM_REG_i.exeq_result;
  95                                                 WHEN OTHERS  =>
  96                                                         -- forward mem_data just read, to handle e.g. lhu rD,mem[x]; sh rD,mem[y]; ...
  97                                                         exeq_data_v := dmem_data_v;
  98                                         END CASE;
  99                                 ELSE
 100                                         exeq_data_v := EX2MEM_i.data_rD;
 101                                 END IF;
 102                                 -- output data will be in Big Endian format
 103                                 CASE EX2MEM_i.byte_Enable IS
 104                                         WHEN "1000" => DMEMB_o.data <=              exeq_data_v( 7 DOWNTO 0) & C_24_ZEROS;
 105                                         WHEN "0100" => DMEMB_o.data <=  C_8_ZEROS & exeq_data_v( 7 DOWNTO 0) & C_16_ZEROS;
 106                                         WHEN "0010" => DMEMB_o.data <= C_16_ZEROS & exeq_data_v( 7 DOWNTO 0) &  C_8_ZEROS;
 107                                         WHEN "0001" => DMEMB_o.data <= C_24_ZEROS & exeq_data_v( 7 DOWNTO 0);
 108                                         WHEN "1100" => DMEMB_o.data <=              exeq_data_v(15 DOWNTO 0) & C_16_ZEROS;
 109                                         WHEN "0011" => DMEMB_o.data <= C_16_ZEROS & exeq_data_v(15 DOWNTO 0);
 110                                         WHEN OTHERS => DMEMB_o.data <=              exeq_data_v;
 111                                 END CASE;
 112
 113                         WHEN RD_MEM =>
 114                                 -- read from data memory bus
 115                                 DMEMB_o.addr <= EX2MEM_i.exeq_result;
 116                                 DMEMB_o.ena  <= '1';
 117                                 DMEMB_o.wre  <= '0';
 118                                 DMEMB_o.data <= EX2MEM_i.data_rD;   -- (OTHERS => 'Z');
 119
 120                         WHEN OTHERS =>      -- NO_MEM
 121                                 DMEMB_o.addr <= C_32_ZEROS;
 122                                 DMEMB_o.ena  <= '0';
 123                                 DMEMB_o.wre  <= '0';
 124                                 DMEMB_o.data <= EX2MEM_i.data_rD;   -- (OTHERS => 'Z');
 125                 END CASE;
 126
 127                 -- additional wrb signals
 128                 CASE MEM_REG_i.wrb_Action IS
 129                         WHEN WRB_MEM => MEM_WRB_o.data_rD <= dmem_data_v;
 130                         WHEN OTHERS  => MEM_WRB_o.data_rD <= MEM_REG_i.exeq_result;
 131                 END CASE;
 132
 133         END PROCESS;
 134
 135 END ARCHITECTURE rtl;