configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447 AC_ARG_ENABLE(static-libjava,
 448 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 449                 [build static libjava @<:@default=no@:>@])],
 450 ENABLE_STATIC_LIBJAVA=$enableval,
 451 ENABLE_STATIC_LIBJAVA=no)
 452 enable_static_libjava=
 453 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 454   enable_static_libjava=yes
 455 fi
 456
 457 if test x$enable_static_libjava != xyes ; then
 458   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 459 fi
 460 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 461
 462 # Disable libmudflap on some systems.
 463 if test x$enable_libmudflap = x ; then
 464     case "${target}" in
 465     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 466         # Enable libmudflap by default in GNU and friends.
 467         ;;
 468     *-*-freebsd*)
 469         # Enable libmudflap by default in FreeBSD.
 470         ;;
 471     *)
 472         # Disable it by default everywhere else.
 473         noconfigdirs="$noconfigdirs target-libmudflap"
 474         ;;
 475     esac
 476 fi
 477
 478 # Disable libgomp on non POSIX hosted systems.
 479 if test x$enable_libgomp = x ; then
 480     # Enable libgomp by default on hosted POSIX systems.
 481     case "${target}" in
 482     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 483         ;;
 484     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 485         ;;
 486     *-*-solaris2* | *-*-hpux11*)
 487         ;;
 488     *-*-darwin* | *-*-aix*)
 489         ;;
 490     *)
 491         noconfigdirs="$noconfigdirs target-libgomp"
 492         ;;
 493     esac
 494 fi
 495
 496 # Disable libitm on unsupported systems.
 497 if test -d ${srcdir}/libitm; then
 498     if test x$enable_libitm = x; then
 499         AC_MSG_CHECKING([for libitm support])
 500         if (srcdir=${srcdir}/libitm; \
 501                 . ${srcdir}/configure.tgt; \
 502                 test -n "$UNSUPPORTED")
 503         then
 504             AC_MSG_RESULT([no])
 505             noconfigdirs="$noconfigdirs target-libitm"
 506         else
 507             AC_MSG_RESULT([yes])
 508         fi
 509     fi
 510 fi
 511
 512 # Disable libssp for some systems.
 513 case "${target}" in
 514   avr-*-*)
 515     # No hosted I/O support.
 516     noconfigdirs="$noconfigdirs target-libssp"
 517     ;;
 518   powerpc-*-aix* | rs6000-*-aix*)
 519     noconfigdirs="$noconfigdirs target-libssp"
 520     ;;
 521   rl78-*-*)
 522     # libssp uses a misaligned load to trigger a fault, but the RL78
 523     # doesn't fault for those - instead, it gives a build-time error
 524     # for explicit misaligned loads.
 525     noconfigdirs="$noconfigdirs target-libssp"
 526     ;;
 527 esac
 528
 529 # Disable libstdc++-v3 for some systems.
 530 case "${target}" in
 531   *-*-vxworks*)
 532     # VxWorks uses the Dinkumware C++ library.
 533     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 534     ;;
 535   arm*-wince-pe*)
 536     # the C++ libraries don't build on top of CE's C libraries
 537     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 538     ;;
 539   avr-*-*)
 540     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 541     ;;
 542 esac
 543
 544 # Disable Fortran for some systems.
 545 case "${target}" in
 546   mmix-*-*)
 547     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 548     unsupported_languages="$unsupported_languages fortran"
 549     ;;
 550 esac
 551
 552 # Disable Java if libffi is not supported.
 553 case "${target}" in
 554   alpha*-*-*)
 555     ;;
 556   arm*-*-*)
 557     ;;
 558   cris-*-*)
 559     ;;
 560   frv-*-*)
 561     ;;
 562   hppa*-*-linux*)
 563     ;;
 564   hppa*-*-hpux*)
 565     ;;
 566   i?86-*-*)
 567     ;;
 568   ia64*-*-*)
 569     ;;
 570   m32r*-*-*)
 571     ;;
 572   m68k-*-*)
 573     ;;
 574   mips*-*-rtems*)
 575     ;;
 576   mips*-*-linux*)
 577     ;;
 578   powerpc*-*-linux*)
 579     ;;
 580   powerpc-*-darwin*)
 581     ;;
 582   powerpc-*-aix* | rs6000-*-aix*)
 583     ;;
 584   powerpc-*-freebsd*)
 585     ;;
 586   powerpc64-*-freebsd*)
 587     ;;
 588   powerpc*-*-rtems*)
 589     ;;
 590   s390-*-* | s390x-*-*)
 591     ;;
 592   sh-*-* | sh[[34]]*-*-*)
 593     ;;
 594   sh64-*-* | sh5*-*-*)
 595     ;;
 596   sparc*-*-*)
 597     ;;
 598   x86_64-*-*)
 599     ;;
 600   *-*-*)
 601     unsupported_languages="$unsupported_languages java"
 602     ;;
 603 esac
 604
 605 # Disable Java, libgcj or related libraries for some systems.
 606 case "${target}" in
 607   powerpc-*-darwin*)
 608     ;;
 609   i[[3456789]]86-*-darwin*)
 610     ;;
 611   x86_64-*-darwin[[912]]*)
 612     ;;
 613   *-*-darwin*)
 614     noconfigdirs="$noconfigdirs ${libgcj}"
 615     ;;
 616   *-*-netware*)
 617     noconfigdirs="$noconfigdirs ${libgcj}"
 618     ;;
 619   *-*-rtems*)
 620     noconfigdirs="$noconfigdirs ${libgcj}"
 621     ;;
 622   *-*-tpf*)
 623     noconfigdirs="$noconfigdirs ${libgcj}"
 624     ;;
 625   *-*-uclinux*)
 626     noconfigdirs="$noconfigdirs ${libgcj}"
 627     ;;
 628   *-*-vxworks*)
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   alpha*-*-*vms*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   arm-wince-pe)
 635     noconfigdirs="$noconfigdirs ${libgcj}"
 636     ;;
 637   arm*-*-symbianelf*)
 638     noconfigdirs="$noconfigdirs ${libgcj}"
 639     ;;
 640   bfin-*-*)
 641     noconfigdirs="$noconfigdirs target-boehm-gc"
 642     ;;
 643   cris-*-* | crisv32-*-*)
 644     unsupported_languages="$unsupported_languages java"
 645     case "${target}" in
 646       *-*-linux*)
 647         ;;
 648       *) # See PR46792 regarding target-libffi.
 649         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 650     esac
 651     ;;
 652   hppa*64*-*-linux*)
 653     # In this case, it's because the hppa64-linux target is for
 654     # the kernel only at this point and has no libc, and thus no
 655     # headers, crt*.o, etc., all of which are needed by these.
 656     unsupported_languages="$unsupported_languages java"
 657     ;;
 658   hppa*64*-*-hpux*)
 659     noconfigdirs="$noconfigdirs ${libgcj}"
 660     ;;
 661   hppa*-hp-hpux11*)
 662     ;;
 663   hppa*-*-hpux*)
 664     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 665     # build on HP-UX 10.20.
 666     noconfigdirs="$noconfigdirs ${libgcj}"
 667     ;;
 668   ia64*-*-*vms*)
 669     noconfigdirs="$noconfigdirs ${libgcj}"
 670     ;;
 671   i[[3456789]]86-w64-mingw*)
 672     noconfigdirs="$noconfigdirs ${libgcj}"
 673     ;;
 674   i[[3456789]]86-*-mingw*)
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677   x86_64-*-mingw*)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     ;;
 680   mmix-*-*)
 681     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 682     ;;
 683   powerpc-*-aix*)
 684     # copied from rs6000-*-* entry
 685     noconfigdirs="$noconfigdirs ${libgcj}"
 686     ;;
 687   rs6000-*-aix*)
 688     noconfigdirs="$noconfigdirs ${libgcj}"
 689     ;;
 690   *-*-lynxos*)
 691     noconfigdirs="$noconfigdirs ${libgcj}"
 692     ;;
 693 esac
 694
 695 # Default libgloss CPU subdirectory.
 696 libgloss_dir="$target_cpu"
 697
 698 case "${target}" in
 699   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 700     libgloss_dir=wince
 701     ;;
 702   arm*-*-*)
 703     libgloss_dir=arm
 704     ;;
 705   cris-*-* | crisv32-*-*)
 706     libgloss_dir=cris
 707     ;;
 708   hppa*-*-*)
 709     libgloss_dir=pa
 710     ;;
 711   i[[3456789]]86-*-*)
 712     libgloss_dir=i386
 713     ;;
 714   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 715     libgloss_dir=m68hc11
 716     ;;
 717   m68*-*-* | fido-*-*)
 718     libgloss_dir=m68k
 719     ;;
 720   mips*-*-*)
 721     libgloss_dir=mips
 722     ;;
 723   powerpc*-*-*)
 724     libgloss_dir=rs6000
 725     ;;
 726   sparc*-*-*)
 727     libgloss_dir=sparc
 728     ;;
 729 esac
 730
 731 # Disable newlib and libgloss for various target OSes.
 732 case "${target}" in
 733   alpha*-dec-osf*)
 734     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 735     ;;
 736   i[[3456789]]86-*-linux*)
 737     # This section makes it possible to build newlib natively on linux.
 738     # If we are using a cross compiler then don't configure newlib.
 739     if test x${is_cross_compiler} != xno ; then
 740       noconfigdirs="$noconfigdirs target-newlib"
 741     fi
 742     noconfigdirs="$noconfigdirs target-libgloss"
 743     # If we are not using a cross compiler, do configure newlib.
 744     # Note however, that newlib will only be configured in this situation
 745     # if the --with-newlib option has been given, because otherwise
 746     # 'target-newlib' will appear in skipdirs.
 747     ;;
 748   i[[3456789]]86-*-rdos*)
 749     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 750     ;;
 751   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 752     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 753     ;;
 754   sparc-*-sunos4*)
 755     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 756     ;;
 757   *-*-aix*)
 758     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 759     ;;
 760   *-*-beos*)
 761     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 762     ;;
 763   *-*-chorusos)
 764     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 765     ;;
 766   *-*-dragonfly*)
 767     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 768     ;;
 769   *-*-freebsd*)
 770     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 771     ;;
 772   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 773     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 774     ;;
 775   *-*-lynxos*)
 776     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 777     ;;
 778   *-*-mingw*)
 779     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 780     ;;
 781   *-*-netbsd*)
 782     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 783     ;;
 784   *-*-netware*)
 785     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 786     ;;
 787   *-*-tpf*)
 788     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 789     ;;
 790   *-*-uclinux*)
 791     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 792     ;;
 793   *-*-vxworks*)
 794     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 795     ;;
 796 esac
 797
 798 case "${target}" in
 799   *-*-chorusos)
 800     ;;
 801   powerpc-*-darwin*)
 802     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 803     noconfigdirs="$noconfigdirs sim target-rda"
 804     ;;
 805   i[[3456789]]86-*-darwin*)
 806     noconfigdirs="$noconfigdirs ld gprof"
 807     noconfigdirs="$noconfigdirs sim target-rda"
 808     ;;
 809   x86_64-*-darwin[[912]]*)
 810     noconfigdirs="$noconfigdirs ld gas gprof"
 811     noconfigdirs="$noconfigdirs sim target-rda"
 812     ;;
 813   *-*-darwin*)
 814     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 815     noconfigdirs="$noconfigdirs sim target-rda"
 816     ;;
 817   *-*-dragonfly*)
 818     ;;
 819   *-*-freebsd*)
 820     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 821         && test -f /usr/local/include/gmp.h; then
 822       with_gmp=/usr/local
 823     fi
 824     ;;
 825   *-*-kaos*)
 826     # Remove unsupported stuff on all kaOS configurations.
 827     noconfigdirs="$noconfigdirs target-libgloss"
 828     ;;
 829   *-*-netbsd*)
 830     ;;
 831   *-*-netware*)
 832     ;;
 833   *-*-rtems*)
 834     noconfigdirs="$noconfigdirs target-libgloss"
 835     ;;
 836     # The tpf target doesn't support gdb yet.
 837   *-*-tpf*)
 838     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 839     ;;
 840   *-*-uclinux*)
 841     noconfigdirs="$noconfigdirs target-rda"
 842     ;;
 843   *-*-vxworks*)
 844     ;;
 845   alpha*-dec-osf*)
 846     # ld works, but does not support shared libraries.
 847     # gas doesn't generate exception information.
 848     noconfigdirs="$noconfigdirs gas ld"
 849     ;;
 850   alpha*-*-*vms*)
 851     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 852     ;;
 853   alpha*-*-*)
 854     # newlib is not 64 bit ready
 855     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 856     ;;
 857   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 858     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 859     ;;
 860   arc-*-*)
 861     noconfigdirs="$noconfigdirs target-libgloss"
 862     ;;
 863   arm-*-pe*)
 864     noconfigdirs="$noconfigdirs target-libgloss"
 865     ;;
 866   arm-*-riscix*)
 867     noconfigdirs="$noconfigdirs ld target-libgloss"
 868     ;;
 869   c4x-*-* | tic4x-*-*)
 870     noconfigdirs="$noconfigdirs target-libgloss"
 871     ;;
 872   tic54x-*-*)
 873     noconfigdirs="$noconfigdirs target-libgloss gdb"
 874     ;;
 875   cr16-*-*)
 876     noconfigdirs="$noconfigdirs gdb"
 877     ;;
 878   d10v-*-*)
 879     noconfigdirs="$noconfigdirs target-libgloss"
 880     ;;
 881   d30v-*-*)
 882     noconfigdirs="$noconfigdirs gdb"
 883     ;;
 884   fr30-*-elf*)
 885     noconfigdirs="$noconfigdirs gdb"
 886     ;;
 887   moxie-*-*)
 888     noconfigdirs="$noconfigdirs gprof"
 889     ;;
 890   h8300*-*-*)
 891     noconfigdirs="$noconfigdirs target-libgloss"
 892     ;;
 893   h8500-*-*)
 894     noconfigdirs="$noconfigdirs target-libgloss"
 895     ;;
 896   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 897     ;;
 898   hppa*64*-*-linux*)
 899     ;;
 900   hppa*-*-linux*)
 901     ;;
 902   hppa*-*-*elf* | \
 903   hppa*-*-lites* | \
 904   hppa*-*-openbsd* | \
 905   hppa*64*-*-*)
 906     ;;
 907   hppa*-hp-hpux11*)
 908     noconfigdirs="$noconfigdirs ld"
 909     ;;
 910   hppa*-*-pro*)
 911     ;;
 912   hppa*-*-*)
 913     noconfigdirs="$noconfigdirs ld"
 914     ;;
 915   i960-*-*)
 916     noconfigdirs="$noconfigdirs gdb"
 917     ;;
 918   ia64*-*-elf*)
 919     # No gdb support yet.
 920     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 921     ;;
 922   ia64*-**-hpux*)
 923     # No ld support yet.
 924     noconfigdirs="$noconfigdirs libgui itcl ld"
 925     ;;
 926   ia64*-*-*vms*)
 927     noconfigdirs="$noconfigdirs libgui itcl"
 928     ;;
 929   i[[3456789]]86-w64-mingw*)
 930     ;;
 931   i[[3456789]]86-*-mingw*)
 932     target_configdirs="$target_configdirs target-winsup"
 933     ;;
 934   *-*-cygwin*)
 935     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 936     noconfigdirs="$noconfigdirs target-libgloss"
 937     # always build newlib if winsup directory is present.
 938     if test -d "$srcdir/winsup/cygwin"; then
 939       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 940     elif test -d "$srcdir/newlib"; then
 941       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 942     fi
 943     ;;
 944   i[[3456789]]86-*-pe)
 945     noconfigdirs="$noconfigdirs target-libgloss"
 946     ;;
 947   i[[3456789]]86-*-sco3.2v5*)
 948     # The linker does not yet know about weak symbols in COFF,
 949     # and is not configured to handle mixed ELF and COFF.
 950     noconfigdirs="$noconfigdirs ld target-libgloss"
 951     ;;
 952   i[[3456789]]86-*-sco*)
 953     noconfigdirs="$noconfigdirs gprof target-libgloss"
 954     ;;
 955   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 956     noconfigdirs="$noconfigdirs target-libgloss"
 957     ;;
 958   i[[3456789]]86-*-sysv4*)
 959     noconfigdirs="$noconfigdirs target-libgloss"
 960     ;;
 961   i[[3456789]]86-*-beos*)
 962     noconfigdirs="$noconfigdirs gdb"
 963     ;;
 964   i[[3456789]]86-*-rdos*)
 965     noconfigdirs="$noconfigdirs gdb"
 966     ;;
 967   mmix-*-*)
 968     noconfigdirs="$noconfigdirs gdb"
 969     ;;
 970   mt-*-*)
 971     noconfigdirs="$noconfigdirs sim"
 972     ;;
 973   powerpc-*-aix*)
 974     # copied from rs6000-*-* entry
 975     noconfigdirs="$noconfigdirs gprof"
 976     ;;
 977   powerpc*-*-winnt* | powerpc*-*-pe*)
 978     target_configdirs="$target_configdirs target-winsup"
 979     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 980     # always build newlib.
 981     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 982     ;;
 983     # This is temporary until we can link against shared libraries
 984   powerpcle-*-solaris*)
 985     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 986     ;;
 987   powerpc-*-beos*)
 988     noconfigdirs="$noconfigdirs gdb"
 989     ;;
 990   rs6000-*-lynxos*)
 991     noconfigdirs="$noconfigdirs gprof"
 992     ;;
 993   rs6000-*-aix*)
 994     noconfigdirs="$noconfigdirs gprof"
 995     ;;
 996   rs6000-*-*)
 997     noconfigdirs="$noconfigdirs gprof"
 998     ;;
 999   m68k-apollo-*)
1000     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1001     ;;
1002   mbtumbl*)
1003     noconfigdirs="$noconfigdirs gprof"
1004     ;;
1005   microblaze*)
1006     noconfigdirs="$noconfigdirs gprof"
1007     ;;
1008   mips*-sde-elf*)
1009     if test x$with_newlib = xyes; then
1010       noconfigdirs="$noconfigdirs gprof"
1011     fi
1012     ;;
1013   mips*-*-irix5*)
1014     noconfigdirs="$noconfigdirs gprof target-libgloss"
1015     ;;
1016   mips*-*-irix6*)
1017     noconfigdirs="$noconfigdirs gprof target-libgloss"
1018     ;;
1019   mips*-*-bsd*)
1020     noconfigdirs="$noconfigdirs gprof target-libgloss"
1021     ;;
1022   mips*-*-linux*)
1023     ;;
1024   mips*-*-*)
1025     noconfigdirs="$noconfigdirs gprof"
1026     ;;
1027   sh-*-* | sh64-*-*)
1028     case "${target}" in
1029       sh*-*-elf)
1030          ;;
1031       *)
1032          noconfigdirs="$noconfigdirs target-libgloss" ;;
1033     esac
1034     ;;
1035   sparc-*-sunos4*)
1036     if test x${is_cross_compiler} = xno ; then
1037            use_gnu_ld=no
1038     fi
1039     ;;
1040   tic6x-*-*)
1041     noconfigdirs="$noconfigdirs sim"
1042     ;;
1043   tilepro-*-* | tilegx-*-*)
1044     noconfigdirs="$noconfigdirs sim"
1045     ;;
1046   v810-*-*)
1047     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1048     ;;
1049   vax-*-*)
1050     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1051     ;;
1052 esac
1053
1054 # If we aren't building newlib, then don't build libgloss, since libgloss
1055 # depends upon some newlib header files.
1056 case "${noconfigdirs}" in
1057   *target-libgloss*) ;;
1058   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1059 esac
1060
1061 # Work in distributions that contain no compiler tools, like Autoconf.
1062 host_makefile_frag=/dev/null
1063 if test -d ${srcdir}/config ; then
1064 case "${host}" in
1065   i[[3456789]]86-*-msdosdjgpp*)
1066     host_makefile_frag="config/mh-djgpp"
1067     ;;
1068   *-cygwin*)
1069     ACX_CHECK_CYGWIN_CAT_WORKS
1070     host_makefile_frag="config/mh-cygwin"
1071     ;;
1072   *-mingw*)
1073     host_makefile_frag="config/mh-mingw"
1074     ;;
1075   *-interix*)
1076     host_makefile_frag="config/mh-interix"
1077     ;;
1078   hppa*-hp-hpux10*)
1079     host_makefile_frag="config/mh-pa-hpux10"
1080     ;;
1081   hppa*-hp-hpux*)
1082     host_makefile_frag="config/mh-pa"
1083     ;;
1084   hppa*-*)
1085     host_makefile_frag="config/mh-pa"
1086     ;;
1087   *-*-darwin*)
1088     host_makefile_frag="config/mh-darwin"
1089     ;;
1090   powerpc-*-aix*)
1091     host_makefile_frag="config/mh-ppc-aix"
1092     ;;
1093   rs6000-*-aix*)
1094     host_makefile_frag="config/mh-ppc-aix"
1095     ;;
1096 esac
1097 fi
1098
1099 if test "${build}" != "${host}" ; then
1100   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1101   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1102   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1103   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1104   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1105   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1106   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1107   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1108   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1109   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1110   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1111   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1112   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1113 else
1114   AR_FOR_BUILD="\$(AR)"
1115   AS_FOR_BUILD="\$(AS)"
1116   CC_FOR_BUILD="\$(CC)"
1117   CXX_FOR_BUILD="\$(CXX)"
1118   GCJ_FOR_BUILD="\$(GCJ)"
1119   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1120   GOC_FOR_BUILD="\$(GOC)"
1121   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1122   LD_FOR_BUILD="\$(LD)"
1123   NM_FOR_BUILD="\$(NM)"
1124   RANLIB_FOR_BUILD="\$(RANLIB)"
1125   WINDRES_FOR_BUILD="\$(WINDRES)"
1126   WINDMC_FOR_BUILD="\$(WINDMC)"
1127 fi
1128
1129 AC_PROG_CC
1130 AC_PROG_CXX
1131
1132 # We must set the default linker to the linker used by gcc for the correct
1133 # operation of libtool.  If LD is not defined and we are using gcc, try to
1134 # set the LD default to the ld used by gcc.
1135 if test -z "$LD"; then
1136   if test "$GCC" = yes; then
1137     case $build in
1138     *-*-mingw*)
1139       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1140     *)
1141       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1142     esac
1143     case $gcc_prog_ld in
1144     # Accept absolute paths.
1145     [[\\/]* | [A-Za-z]:[\\/]*)]
1146       LD="$gcc_prog_ld" ;;
1147     esac
1148   fi
1149 fi
1150
1151 ACX_PROG_GNAT
1152 ACX_PROG_CMP_IGNORE_INITIAL
1153
1154 AC_ARG_ENABLE([bootstrap],
1155 [AS_HELP_STRING([--enable-bootstrap],
1156                 [enable bootstrapping @<:@yes if native build@:>@])],,
1157 enable_bootstrap=default)
1158
1159 # Issue errors and warnings for invalid/strange bootstrap combinations.
1160 if test -r $srcdir/gcc/configure; then
1161   have_compiler=yes
1162 else
1163   have_compiler=no
1164 fi
1165
1166 case "$have_compiler:$host:$target:$enable_bootstrap" in
1167   *:*:*:no) ;;
1168
1169   # Default behavior.  Enable bootstrap if we have a compiler
1170   # and we are in a native configuration.
1171   yes:$build:$build:default)
1172     enable_bootstrap=yes ;;
1173
1174   *:*:*:default)
1175     enable_bootstrap=no ;;
1176
1177   # We have a compiler and we are in a native configuration, bootstrap is ok
1178   yes:$build:$build:yes)
1179     ;;
1180
1181   # Other configurations, but we have a compiler.  Assume the user knows
1182   # what he's doing.
1183   yes:*:*:yes)
1184     AC_MSG_WARN([trying to bootstrap a cross compiler])
1185     ;;
1186
1187   # No compiler: if they passed --enable-bootstrap explicitly, fail
1188   no:*:*:yes)
1189     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1190
1191   # Fail if wrong command line
1192   *)
1193     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1194     ;;
1195 esac
1196
1197 # See if we are building gcc with C++.
1198 AC_ARG_ENABLE(build-with-cxx,
1199 [AS_HELP_STRING([--enable-build-with-cxx],
1200                 [build with C++ compiler instead of C compiler])],
1201 ENABLE_BUILD_WITH_CXX=$enableval,
1202 ENABLE_BUILD_WITH_CXX=no)
1203
1204 # Build stage1 with C and build stages 2 and 3 with C++.
1205 AC_ARG_ENABLE(build-poststage1-with-cxx,
1206 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1207                 [build stages 2 and 3 with C++, not C])],
1208 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1209 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1210
1211 # Used for setting $lt_cv_objdir
1212 _LT_CHECK_OBJDIR
1213
1214 # Check for GMP, MPFR and MPC
1215 gmplibs="-lmpc -lmpfr -lgmp"
1216 gmpinc=
1217 have_gmp=no
1218
1219 # Specify a location for mpc
1220 # check for this first so it ends up on the link line before mpfr.
1221 AC_ARG_WITH(mpc,
1222 [AS_HELP_STRING([--with-mpc=PATH],
1223                 [specify prefix directory for installed MPC package.
1224                  Equivalent to --with-mpc-include=PATH/include
1225                  plus --with-mpc-lib=PATH/lib])])
1226 AC_ARG_WITH(mpc-include,
1227 [AS_HELP_STRING([--with-mpc-include=PATH],
1228                 [specify directory for installed MPC include files])])
1229 AC_ARG_WITH(mpc-lib,
1230 [AS_HELP_STRING([--with-mpc-lib=PATH],
1231                 [specify directory for the installed MPC library])])
1232
1233 if test "x$with_mpc" != x; then
1234   gmplibs="-L$with_mpc/lib $gmplibs"
1235   gmpinc="-I$with_mpc/include $gmpinc"
1236 fi
1237 if test "x$with_mpc_include" != x; then
1238   gmpinc="-I$with_mpc_include $gmpinc"
1239 fi
1240 if test "x$with_mpc_lib" != x; then
1241   gmplibs="-L$with_mpc_lib $gmplibs"
1242 fi
1243 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1244   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1245   gmpinc='-I$$s/mpc/src '"$gmpinc"
1246   # Do not test the mpc version.  Assume that it is sufficient, since
1247   # it is in the source tree, and the library has not been built yet
1248   # but it would be included on the link line in the version check below
1249   # hence making the test fail.
1250   have_gmp=yes
1251 fi
1252
1253 # Specify a location for mpfr
1254 # check for this first so it ends up on the link line before gmp.
1255 AC_ARG_WITH(mpfr-dir,
1256 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1257 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1258 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1259
1260 AC_ARG_WITH(mpfr,
1261 [AS_HELP_STRING([--with-mpfr=PATH],
1262                 [specify prefix directory for installed MPFR package.
1263                  Equivalent to --with-mpfr-include=PATH/include
1264                  plus --with-mpfr-lib=PATH/lib])])
1265 AC_ARG_WITH(mpfr-include,
1266 [AS_HELP_STRING([--with-mpfr-include=PATH],
1267                 [specify directory for installed MPFR include files])])
1268 AC_ARG_WITH(mpfr-lib,
1269 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1270                 [specify directory for the installed MPFR library])])
1271
1272 if test "x$with_mpfr" != x; then
1273   gmplibs="-L$with_mpfr/lib $gmplibs"
1274   gmpinc="-I$with_mpfr/include $gmpinc"
1275 fi
1276 if test "x$with_mpfr_include" != x; then
1277   gmpinc="-I$with_mpfr_include $gmpinc"
1278 fi
1279 if test "x$with_mpfr_lib" != x; then
1280   gmplibs="-L$with_mpfr_lib $gmplibs"
1281 fi
1282 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1283   # MPFR v3.1.0 moved the sources into a src sub-directory.
1284   if test -d ${srcdir}/mpfr/src; then
1285     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1286     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1287     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1288   else
1289     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1290     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1291     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1292   fi
1293   # Do not test the mpfr version.  Assume that it is sufficient, since
1294   # it is in the source tree, and the library has not been built yet
1295   # but it would be included on the link line in the version check below
1296   # hence making the test fail.
1297   have_gmp=yes
1298 fi
1299
1300 # Specify a location for gmp
1301 AC_ARG_WITH(gmp-dir,
1302 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1303 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1304 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1305
1306 AC_ARG_WITH(gmp,
1307 [AS_HELP_STRING([--with-gmp=PATH],
1308                 [specify prefix directory for the installed GMP package.
1309                  Equivalent to --with-gmp-include=PATH/include
1310                  plus --with-gmp-lib=PATH/lib])])
1311 AC_ARG_WITH(gmp-include,
1312 [AS_HELP_STRING([--with-gmp-include=PATH],
1313                 [specify directory for installed GMP include files])])
1314 AC_ARG_WITH(gmp-lib,
1315 [AS_HELP_STRING([--with-gmp-lib=PATH],
1316                 [specify directory for the installed GMP library])])
1317
1318
1319 if test "x$with_gmp" != x; then
1320   gmplibs="-L$with_gmp/lib $gmplibs"
1321   gmpinc="-I$with_gmp/include $gmpinc"
1322 fi
1323 if test "x$with_gmp_include" != x; then
1324   gmpinc="-I$with_gmp_include $gmpinc"
1325 fi
1326 if test "x$with_gmp_lib" != x; then
1327   gmplibs="-L$with_gmp_lib $gmplibs"
1328 fi
1329 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1330   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1331   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1332   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1333   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1334   # Do not test the gmp version.  Assume that it is sufficient, since
1335   # it is in the source tree, and the library has not been built yet
1336   # but it would be included on the link line in the version check below
1337   # hence making the test fail.
1338   have_gmp=yes
1339 fi
1340
1341 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1342   have_gmp=yes
1343   saved_CFLAGS="$CFLAGS"
1344   CFLAGS="$CFLAGS $gmpinc"
1345   # Check for the recommended and required versions of GMP.
1346   AC_MSG_CHECKING([for the correct version of gmp.h])
1347   AC_TRY_COMPILE([#include "gmp.h"],[
1348   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1349   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1350   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1351   choke me
1352   #endif
1353   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1354   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1355   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1356   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1357   choke me
1358   #endif
1359   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1360    [AC_MSG_RESULT([no]); have_gmp=no])
1361
1362   # If we have GMP, check the MPFR version.
1363   if test x"$have_gmp" = xyes; then
1364     # Check for the recommended and required versions of MPFR.
1365     AC_MSG_CHECKING([for the correct version of mpfr.h])
1366     AC_TRY_COMPILE([#include <gmp.h>
1367     #include <mpfr.h>],[
1368     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1369     choke me
1370     #endif
1371     ], [AC_TRY_COMPILE([#include <gmp.h>
1372     #include <mpfr.h>],[
1373     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1374     choke me
1375     #endif
1376     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1377      [AC_MSG_RESULT([no]); have_gmp=no])
1378   fi
1379
1380   # Check for the MPC header version.
1381   if test x"$have_gmp" = xyes ; then
1382     # Check for the recommended and required versions of MPC.
1383     AC_MSG_CHECKING([for the correct version of mpc.h])
1384     AC_TRY_COMPILE([#include <mpc.h>],[
1385     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1386     choke me
1387     #endif
1388     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1389     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1390     choke me
1391     #endif
1392     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1393      [AC_MSG_RESULT([no]); have_gmp=no])
1394   fi
1395
1396   # Now check the MPFR library.
1397   if test x"$have_gmp" = xyes; then
1398     saved_LIBS="$LIBS"
1399     LIBS="$LIBS $gmplibs"
1400     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1401     AC_TRY_LINK([#include <mpc.h>],[
1402     mpfr_t n;
1403     mpfr_t x;
1404     mpc_t c;
1405     int t;
1406     mpfr_init (n);
1407     mpfr_init (x);
1408     mpfr_atan2 (n, n, x, GMP_RNDN);
1409     mpfr_erfc (n, x, GMP_RNDN);
1410     mpfr_subnormalize (x, t, GMP_RNDN);
1411     mpfr_clear(n);
1412     mpfr_clear(x);
1413     mpc_init2 (c, 53);
1414     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1415     mpc_cosh (c, c, MPC_RNDNN);
1416     mpc_pow (c, c, c, MPC_RNDNN);
1417     mpc_acosh (c, c, MPC_RNDNN);
1418     mpc_clear (c);
1419     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1420     LIBS="$saved_LIBS"
1421   fi
1422
1423   CFLAGS="$saved_CFLAGS"
1424
1425 # The library versions listed in the error message below should match
1426 # the HARD-minimums enforced above.
1427   if test x$have_gmp != xyes; then
1428     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1429 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1430 their locations.  Source code for these libraries can be found at
1431 their respective hosting sites as well as at
1432 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1433 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1434 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1435 make sure that you have installed both the libraries and the header
1436 files.  They may be located in separate packages.])
1437   fi
1438 fi
1439
1440 # Flags needed for both GMP, MPFR and/or MPC.
1441 AC_SUBST(gmplibs)
1442 AC_SUBST(gmpinc)
1443 AC_SUBST(extra_mpfr_configure_flags)
1444 AC_SUBST(extra_mpc_gmp_configure_flags)
1445 AC_SUBST(extra_mpc_mpfr_configure_flags)
1446
1447 # Allow host libstdc++ to be specified for static linking with PPL.
1448 AC_ARG_WITH(host-libstdcxx,
1449 [AS_HELP_STRING([--with-host-libstdcxx=L],
1450                 [use linker arguments L to link with libstdc++
1451                  when linking with PPL])])
1452
1453 case $with_host_libstdcxx in
1454   no|yes)
1455     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1456     ;;
1457 esac
1458
1459 # Linker flags to use for stage1 or when not boostrapping.
1460 AC_ARG_WITH(stage1-ldflags,
1461 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1462 [if test "$withval" = "no" -o "$withval" = "yes"; then
1463    stage1_ldflags=
1464  else
1465    stage1_ldflags=$withval
1466  fi],
1467 [stage1_ldflags=])
1468 AC_SUBST(stage1_ldflags)
1469
1470 # Libraries to use for stage1 or when not bootstrapping.
1471 AC_ARG_WITH(stage1-libs,
1472 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1473 [if test "$withval" = "no" -o "$withval" = "yes"; then
1474    stage1_libs=
1475  else
1476    stage1_libs=$withval
1477  fi],
1478 [stage1_libs=$with_host_libstdcxx])
1479 AC_SUBST(stage1_libs)
1480
1481 # Libraries to use for stage2 and later builds.  This defaults to the
1482 # argument passed to --with-host-libstdcxx.
1483 AC_ARG_WITH(boot-libs,
1484 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1485 [if test "$withval" = "no" -o "$withval" = "yes"; then
1486    poststage1_libs=
1487  else
1488    poststage1_libs=$withval
1489  fi],
1490 [poststage1_libs=$with_host_libstdcxx])
1491 AC_SUBST(poststage1_libs)
1492
1493 # Linker flags to use for stage2 and later builds.
1494 AC_ARG_WITH(boot-ldflags,
1495 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1496                 [linker flags for stage2 and later])],
1497 [if test "$withval" = "no" -o "$withval" = "yes"; then
1498    poststage1_ldflags=
1499  else
1500    poststage1_ldflags=$withval
1501  fi],
1502 [poststage1_ldflags=
1503  # In stages 2 and 3, default to linking libstdc++ and libgcc
1504  # statically.  But if the user explicitly specified the libraries to
1505  # use, trust that they are doing what they want.
1506  if test "$poststage1_libs" = ""; then
1507    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1508  fi])
1509 AC_SUBST(poststage1_ldflags)
1510
1511 # Check for PPL
1512 ppllibs=
1513 pplinc=
1514 pwllib=
1515
1516 AC_ARG_WITH(ppl,
1517 [AS_HELP_STRING([--with-ppl=PATH],
1518                 [specify prefix directory for the installed PPL package.
1519                  Equivalent to --with-ppl-include=PATH/include
1520                  plus --with-ppl-lib=PATH/lib])])
1521 AC_ARG_WITH(ppl-include,
1522 [AS_HELP_STRING([--with-ppl-include=PATH],
1523                 [specify directory for installed PPL include files])])
1524 AC_ARG_WITH(ppl-lib,
1525 [AS_HELP_STRING([--with-ppl-lib=PATH],
1526                 [specify directory for the installed PPL library])])
1527
1528 AC_ARG_ENABLE(ppl-version-check,
1529 [AS_HELP_STRING([--disable-ppl-version-check],
1530                 [disable check for PPL version])])
1531
1532 case $with_ppl in
1533   yes | no | "")
1534     ;;
1535   *)
1536     ppllibs="-L$with_ppl/lib"
1537     pplinc="-I$with_ppl/include $pplinc"
1538     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1539       with_ppl=yes
1540     else
1541       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1542     fi
1543     ;;
1544 esac
1545
1546 if test x"$with_ppl_include" != x; then
1547   pplinc="-I$with_ppl_include $pplinc"
1548   with_ppl=yes
1549 fi
1550
1551 if test "x$with_ppl_lib" != x; then
1552   ppllibs="-L$with_ppl_lib"
1553   with_ppl=yes
1554 fi
1555
1556 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1557   if test x"$enable_watchdog" = xyes; then
1558     pwllib="-lpwl"
1559   fi
1560   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1561   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1562   enable_ppl_version_check=no
1563   with_ppl=yes
1564 fi
1565
1566 if test "x$with_ppl" != xno; then
1567   if test "x$pwllib" = x; then
1568     saved_LIBS="$LIBS"
1569     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1570     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1571     LIBS="$saved_LIBS"
1572   fi
1573
1574   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1575
1576   if test "$enable_ppl_version_check" != no; then
1577     saved_CFLAGS="$CFLAGS"
1578     CFLAGS="$CFLAGS $pplinc $gmpinc"
1579     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1580     AC_TRY_COMPILE([#include "ppl_c.h"],[
1581     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1582     choke me
1583     #endif
1584     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1585     CFLAGS="$saved_CFLAGS"
1586   fi
1587 fi
1588
1589 # Flags needed for PPL
1590 AC_SUBST(ppllibs)
1591 AC_SUBST(pplinc)
1592
1593
1594 # Check for CLOOG
1595
1596 dnl Provide configure switches and initialize clooginc & clooglibs
1597 dnl with user input.
1598 CLOOG_INIT_FLAGS
1599 if test "x$with_ppl" = "xno"; then
1600   dnl Only execute fail-action, if CLooG has been requested.
1601   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1602   if test "${graphite_requested}" = yes; then
1603     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1604   fi
1605   with_cloog=no
1606 fi
1607 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1608   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1609   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1610   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1611 fi
1612 if test "x$with_cloog" != "xno"; then
1613   dnl The minimal version of CLooG required for Graphite.
1614   dnl
1615   dnl If we use CLooG-Legacy, the provided version information is
1616   dnl ignored.
1617   CLOOG_CHECK_VERSION(0,16,1)
1618
1619   dnl Only execute fail-action, if CLooG has been requested.
1620   CLOOG_IF_FAILED([
1621     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1622 fi
1623
1624 # Check for LTO support.
1625 AC_ARG_ENABLE(lto,
1626 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1627 enable_lto=$enableval,
1628 enable_lto=yes; default_enable_lto=yes)
1629
1630 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1631   build_lto_plugin=yes
1632 ],[if test x"$default_enable_lto" = x"yes" ; then
1633     case $target in
1634       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1635       # On other non-ELF platforms, LTO has yet to be validated.
1636       *) enable_lto=no ;;
1637     esac
1638   else
1639   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1640   # It would also be nice to check the binutils support, but we don't
1641   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1642   # warn during gcc/ subconfigure; unless you're bootstrapping with
1643   # -flto it won't be needed until after installation anyway.
1644     case $target in
1645       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1646       *) if test x"$enable_lto" = x"yes"; then
1647         AC_MSG_ERROR([LTO support is not enabled for this target.])
1648         fi
1649       ;;
1650     esac
1651   fi
1652   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1653   # Build it unless LTO was explicitly disabled.
1654   case $target in
1655     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1656     *) ;;
1657   esac
1658 ])
1659
1660
1661 # By default, C is the only stage 1 language.
1662 stage1_languages=,c,
1663
1664 # Target libraries that we bootstrap.
1665 bootstrap_target_libs=,target-libgcc,
1666
1667 # Figure out what language subdirectories are present.
1668 # Look if the user specified --enable-languages="..."; if not, use
1669 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1670 # go away some day.
1671 # NB:  embedded tabs in this IF block -- do not untabify
1672 if test -d ${srcdir}/gcc; then
1673   if test x"${enable_languages+set}" != xset; then
1674     if test x"${LANGUAGES+set}" = xset; then
1675       enable_languages="${LANGUAGES}"
1676         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1677     else
1678       enable_languages=all
1679     fi
1680   else
1681     if test x"${enable_languages}" = x ||
1682        test x"${enable_languages}" = xyes;
1683        then
1684       echo configure.in: --enable-languages needs at least one language argument 1>&2
1685       exit 1
1686     fi
1687   fi
1688   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1689
1690   # 'f95' is the old name for the 'fortran' language. We issue a warning
1691   # and make the substitution.
1692   case ,${enable_languages}, in
1693     *,f95,*)
1694       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1695       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1696       ;;
1697   esac
1698
1699   # If bootstrapping, then using --enable-build-with-cxx or
1700   # --enable-build-poststage1-with-cxx requires enabling C++.
1701   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1702     *,c++,*:*:*) ;;
1703     *:*,yes,*:yes)
1704       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1705         enable_languages="${enable_languages},c++"
1706       else
1707         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1708       fi
1709       ;;
1710   esac
1711
1712   # First scan to see if an enabled language requires some other language.
1713   # We assume that a given config-lang.in will list all the language
1714   # front ends it requires, even if some are required indirectly.
1715   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1716     case ${lang_frag} in
1717       ..) ;;
1718       # The odd quoting in the next line works around
1719       # an apparent bug in bash 1.12 on linux.
1720       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1721       *)
1722         # From the config-lang.in, get $language, $lang_requires, and
1723         # $lang_requires_boot_languages.
1724         language=
1725         lang_requires=
1726         lang_requires_boot_languages=
1727         . ${lang_frag}
1728         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1729           case ,${enable_languages}, in
1730             *,$other,*) ;;
1731             *,all,*) ;;
1732             *,$language,*)
1733               echo " \`$other' language required by \`$language'; enabling" 1>&2
1734               enable_languages="${enable_languages},${other}"
1735               ;;
1736           esac
1737         done
1738         for other in ${lang_requires_boot_languages} ; do
1739           if test "$other" != "c"; then
1740             case ,${enable_stage1_languages}, in
1741               *,$other,*) ;;
1742               *,all,*) ;;
1743               *)
1744                 case ,${enable_languages}, in
1745                   *,$language,*)
1746                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1747                     enable_stage1_languages="$enable_stage1_languages,${other}"
1748                     ;;
1749                 esac
1750                 ;;
1751             esac
1752           fi
1753         done
1754         ;;
1755     esac
1756   done
1757
1758   new_enable_languages=,c,
1759
1760   # If LTO is enabled, add the LTO front end.
1761   extra_host_libiberty_configure_flags=
1762   if test "$enable_lto" = "yes" ; then
1763     case ,${enable_languages}, in
1764       *,lto,*) ;;
1765       *) enable_languages="${enable_languages},lto" ;;
1766     esac
1767     if test "${build_lto_plugin}" = "yes" ; then
1768       configdirs="$configdirs lto-plugin"
1769       extra_host_libiberty_configure_flags=--enable-shared
1770     fi
1771   fi
1772   AC_SUBST(extra_host_libiberty_configure_flags)
1773
1774   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1775   potential_languages=,c,
1776
1777   enabled_target_libs=
1778   disabled_target_libs=
1779
1780   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1781     case ${lang_frag} in
1782       ..) ;;
1783       # The odd quoting in the next line works around
1784       # an apparent bug in bash 1.12 on linux.
1785       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1786       *)
1787         # From the config-lang.in, get $language, $target_libs,
1788         # $lang_dirs, $boot_language, and $build_by_default
1789         language=
1790         target_libs=
1791         lang_dirs=
1792         subdir_requires=
1793         boot_language=no
1794         build_by_default=yes
1795         . ${lang_frag}
1796         if test x${language} = x; then
1797           echo "${lang_frag} doesn't set \$language." 1>&2
1798           exit 1
1799         fi
1800
1801         if test "$language" = "c++"; then
1802           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1803              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1804             boot_language=yes
1805           fi
1806         fi
1807
1808         case ,${enable_languages}, in
1809           *,${language},*)
1810             # Language was explicitly selected; include it.
1811             add_this_lang=yes
1812             ;;
1813           *,all,*)
1814             # 'all' was selected, select it if it is a default language
1815             add_this_lang=${build_by_default}
1816             ;;
1817           *)
1818             add_this_lang=no
1819             ;;
1820         esac
1821
1822         # Disable languages that need other directories if these aren't available.
1823         for i in $subdir_requires; do
1824           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1825           case ,${enable_languages}, in
1826             *,${language},*)
1827               # Specifically requested language; tell them.
1828               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1829               ;;
1830             *)
1831               # Silently disable.
1832               add_this_lang=unsupported
1833               ;;
1834           esac
1835         done
1836
1837         # Disable Ada if no preexisting GNAT is available.
1838         case ,${enable_languages},:${language}:${have_gnat} in
1839           *,${language},*:ada:no)
1840             # Specifically requested language; tell them.
1841             AC_MSG_ERROR([GNAT is required to build $language])
1842             ;;
1843           *:ada:no)
1844             # Silently disable.
1845             add_this_lang=unsupported
1846             ;;
1847         esac
1848
1849         # Disable a language that is unsupported by the target.
1850         case " $unsupported_languages " in
1851           *" $language "*)
1852             add_this_lang=unsupported
1853             ;;
1854         esac
1855
1856         case $add_this_lang in
1857           unsupported)
1858             # Remove language-dependent dirs.
1859             disabled_target_libs="$disabled_target_libs $target_libs"
1860             noconfigdirs="$noconfigdirs $lang_dirs"
1861             ;;
1862           no)
1863             # Remove language-dependent dirs; still show language as supported.
1864             disabled_target_libs="$disabled_target_libs $target_libs"
1865             noconfigdirs="$noconfigdirs $lang_dirs"
1866             potential_languages="${potential_languages}${language},"
1867             ;;
1868           yes)
1869             new_enable_languages="${new_enable_languages}${language},"
1870             potential_languages="${potential_languages}${language},"
1871             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1872             enabled_target_libs="$enabled_target_libs $target_libs"
1873             case "${boot_language}:,$enable_stage1_languages," in
1874               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1875                 # Add to (comma-separated) list of stage 1 languages.
1876                 case ",$stage1_languages," in
1877                   *,$language,* | ,yes, | ,all,) ;;
1878                   *) stage1_languages="${stage1_languages}${language}," ;;
1879                 esac
1880                 # We need to bootstrap any supporting libraries.
1881                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1882                 ;;
1883             esac
1884             ;;
1885         esac
1886         ;;
1887     esac
1888   done
1889
1890   # Add target libraries which are only needed for disabled languages
1891   # to noconfigdirs.
1892   if test -n "$disabled_target_libs"; then
1893     for dir in $disabled_target_libs; do
1894       case " $enabled_target_libs " in
1895       *" ${dir} "*) ;;
1896       *) noconfigdirs="$noconfigdirs $dir" ;;
1897       esac
1898     done
1899   fi
1900
1901   AC_ARG_ENABLE(stage1-languages,
1902   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1903                   [choose additional languages to build during
1904                   stage1.  Mostly useful for compiler development])],
1905   [case ,${enable_stage1_languages}, in
1906     ,no,|,,)
1907       # Set it to something that will have no effect in the loop below
1908       enable_stage1_languages=c ;;
1909     ,yes,)
1910       enable_stage1_languages=`echo $new_enable_languages | \
1911         sed -e "s/^,//" -e "s/,$//" ` ;;
1912     *,all,*)
1913       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1914         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1915   esac
1916
1917   # Add "good" languages from enable_stage1_languages to stage1_languages,
1918   # while "bad" languages go in missing_languages.  Leave no duplicates.
1919   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1920     case $potential_languages in
1921       *,$i,*)
1922         case $stage1_languages in
1923           *,$i,*) ;;
1924           *) stage1_languages="$stage1_languages$i," ;;
1925         esac ;;
1926       *)
1927         case $missing_languages in
1928           *,$i,*) ;;
1929           *) missing_languages="$missing_languages$i," ;;
1930         esac ;;
1931      esac
1932   done])
1933
1934   # Remove leading/trailing commas that were added for simplicity
1935   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1936   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1937   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1938   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1939
1940   if test "x$missing_languages" != x; then
1941     AC_MSG_ERROR([
1942 The following requested languages could not be built: ${missing_languages}
1943 Supported languages are: ${potential_languages}])
1944   fi
1945   if test "x$new_enable_languages" != "x$enable_languages"; then
1946     echo The following languages will be built: ${new_enable_languages}
1947     enable_languages="$new_enable_languages"
1948   fi
1949
1950   AC_SUBST(stage1_languages)
1951   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1952 fi
1953
1954 # Handle --disable-<component> generically.
1955 for dir in $configdirs $build_configdirs $target_configdirs ; do
1956   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1957   varname=`echo $dirname | sed -e s/+/_/g`
1958   if eval test x\${enable_${varname}} "=" xno ; then
1959     noconfigdirs="$noconfigdirs $dir"
1960   fi
1961 done
1962
1963 # Check for Boehm's garbage collector
1964 AC_ARG_ENABLE(objc-gc,
1965 [AS_HELP_STRING([--enable-objc-gc],
1966                 [enable use of Boehm's garbage collector with the
1967                  GNU Objective-C runtime])],
1968 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1969   *,objc,*:*:yes:*target-boehm-gc*)
1970     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1971     ;;
1972 esac])
1973
1974 # Make sure we only build Boehm's garbage collector if required.
1975 case ,${enable_languages},:${enable_objc_gc} in
1976   *,objc,*:yes)
1977     # Keep target-boehm-gc if requested for Objective-C.
1978     ;;
1979   *)
1980     # Otherwise remove target-boehm-gc depending on target-libjava.
1981     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1982       noconfigdirs="$noconfigdirs target-boehm-gc"
1983     fi
1984     ;;
1985 esac
1986
1987 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1988 # $build_configdirs and $target_configdirs.
1989 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1990
1991 notsupp=""
1992 for dir in . $skipdirs $noconfigdirs ; do
1993   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1994   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1995     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1996     if test -r $srcdir/$dirname/configure ; then
1997       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1998         true
1999       else
2000         notsupp="$notsupp $dir"
2001       fi
2002     fi
2003   fi
2004   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2005     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2006     if test -r $srcdir/$dirname/configure ; then
2007       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2008         true
2009       else
2010         notsupp="$notsupp $dir"
2011       fi
2012     fi
2013   fi
2014   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2015     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2016     if test -r $srcdir/$dirname/configure ; then
2017       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2018         true
2019       else
2020         notsupp="$notsupp $dir"
2021       fi
2022     fi
2023   fi
2024 done
2025
2026 # Quietly strip out all directories which aren't configurable in this tree.
2027 # This relies on all configurable subdirectories being autoconfiscated, which
2028 # is now the case.
2029 build_configdirs_all="$build_configdirs"
2030 build_configdirs=
2031 for i in ${build_configdirs_all} ; do
2032   j=`echo $i | sed -e s/build-//g`
2033   if test -f ${srcdir}/$j/configure ; then
2034     build_configdirs="${build_configdirs} $i"
2035   fi
2036 done
2037
2038 configdirs_all="$configdirs"
2039 configdirs=
2040 for i in ${configdirs_all} ; do
2041   if test -f ${srcdir}/$i/configure ; then
2042     configdirs="${configdirs} $i"
2043   fi
2044 done
2045
2046 target_configdirs_all="$target_configdirs"
2047 target_configdirs=
2048 for i in ${target_configdirs_all} ; do
2049   j=`echo $i | sed -e s/target-//g`
2050   if test -f ${srcdir}/$j/configure ; then
2051     target_configdirs="${target_configdirs} $i"
2052   fi
2053 done
2054
2055 # Produce a warning message for the subdirs we can't configure.
2056 # This isn't especially interesting in the Cygnus tree, but in the individual
2057 # FSF releases, it's important to let people know when their machine isn't
2058 # supported by the one or two programs in a package.
2059
2060 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2061   # If $appdirs is non-empty, at least one of those directories must still
2062   # be configured, or we error out.  (E.g., if the gas release supports a
2063   # specified target in some subdirs but not the gas subdir, we shouldn't
2064   # pretend that all is well.)
2065   if test -n "$appdirs" ; then
2066     for dir in $appdirs ; do
2067       if test -r $dir/Makefile.in ; then
2068         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2069           appdirs=""
2070           break
2071         fi
2072         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2073           appdirs=""
2074           break
2075         fi
2076       fi
2077     done
2078     if test -n "$appdirs" ; then
2079       echo "*** This configuration is not supported by this package." 1>&2
2080       exit 1
2081     fi
2082   fi
2083   # Okay, some application will build, or we don't care to check.  Still
2084   # notify of subdirs not getting built.
2085   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2086   echo "    ${notsupp}" 1>&2
2087   echo "    (Any other directories should still work fine.)" 1>&2
2088 fi
2089
2090 case "$host" in
2091   *msdosdjgpp*)
2092     enable_gdbtk=no ;;
2093 esac
2094
2095 # To find our prefix, in gcc_cv_tool_prefix.
2096 ACX_TOOL_DIRS
2097
2098 copy_dirs=
2099
2100 AC_ARG_WITH([build-sysroot],
2101   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2102                   [use sysroot as the system root during the build])],
2103   [if test x"$withval" != x ; then
2104      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2105    fi],
2106   [SYSROOT_CFLAGS_FOR_TARGET=])
2107 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2108
2109 AC_ARG_WITH([debug-prefix-map],
2110   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2111                   [map A to B, C to D ... in debug information])],
2112   [if test x"$withval" != x; then
2113      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2114      for debug_map in $withval; do
2115        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2116      done
2117    fi],
2118   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2119 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2120
2121 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2122 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2123 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2124 # We want to ensure that TARGET libraries (which we know are built with
2125 # gcc) are built with "-O2 -g", so include those options when setting
2126 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2127 if test "x$CFLAGS_FOR_TARGET" = x; then
2128   CFLAGS_FOR_TARGET=$CFLAGS
2129   case " $CFLAGS " in
2130     *" -O2 "*) ;;
2131     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2132   esac
2133   case " $CFLAGS " in
2134     *" -g "* | *" -g3 "*) ;;
2135     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2136   esac
2137 fi
2138 AC_SUBST(CFLAGS_FOR_TARGET)
2139
2140 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2141   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2142   case " $CXXFLAGS " in
2143     *" -O2 "*) ;;
2144     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2145   esac
2146   case " $CXXFLAGS " in
2147     *" -g "* | *" -g3 "*) ;;
2148     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2149   esac
2150 fi
2151 AC_SUBST(CXXFLAGS_FOR_TARGET)
2152
2153 AC_SUBST(LDFLAGS_FOR_TARGET)
2154
2155 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2156 # the named directory are copied to $(tooldir)/sys-include.
2157 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2158   if test x${is_cross_compiler} = xno ; then
2159     echo 1>&2 '***' --with-headers is only supported when cross compiling
2160     exit 1
2161   fi
2162   if test x"${with_headers}" != xyes ; then
2163     x=${gcc_cv_tool_prefix}
2164     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2165   fi
2166 fi
2167
2168 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2169 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2170 # are permitted.
2171 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2172   if test x${is_cross_compiler} = xno ; then
2173     echo 1>&2 '***' --with-libs is only supported when cross compiling
2174     exit 1
2175   fi
2176   if test x"${with_libs}" != xyes ; then
2177     # Copy the libraries in reverse order, so that files in the first named
2178     # library override files in subsequent libraries.
2179     x=${gcc_cv_tool_prefix}
2180     for l in ${with_libs}; do
2181       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2182     done
2183   fi
2184 fi
2185
2186 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2187 #
2188 # This is done by determining whether or not the appropriate directory
2189 # is available, and by checking whether or not specific configurations
2190 # have requested that this magic not happen.
2191 #
2192 # The command line options always override the explicit settings in
2193 # configure.in, and the settings in configure.in override this magic.
2194 #
2195 # If the default for a toolchain is to use GNU as and ld, and you don't
2196 # want to do that, then you should use the --without-gnu-as and
2197 # --without-gnu-ld options for the configure script.  Similarly, if
2198 # the default is to use the included zlib and you don't want to do that,
2199 # you should use the --with-system-zlib option for the configure script.
2200
2201 if test x${use_gnu_as} = x &&
2202    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2203   with_gnu_as=yes
2204   extra_host_args="$extra_host_args --with-gnu-as"
2205 fi
2206
2207 if test x${use_gnu_ld} = x &&
2208    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2209   with_gnu_ld=yes
2210   extra_host_args="$extra_host_args --with-gnu-ld"
2211 fi
2212
2213 if test x${use_included_zlib} = x &&
2214    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2215   :
2216 else
2217   with_system_zlib=yes
2218   extra_host_args="$extra_host_args --with-system-zlib"
2219 fi
2220
2221 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2222 # can detect this case.
2223
2224 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2225   with_newlib=yes
2226   extra_host_args="$extra_host_args --with-newlib"
2227 fi
2228
2229 # Handle ${copy_dirs}
2230 set fnord ${copy_dirs}
2231 shift
2232 while test $# != 0 ; do
2233   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2234     :
2235   else
2236     echo Copying $1 to $2
2237
2238     # Use the install script to create the directory and all required
2239     # parent directories.
2240     if test -d $2 ; then
2241       :
2242     else
2243       echo >config.temp
2244       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2245     fi
2246
2247     # Copy the directory, assuming we have tar.
2248     # FIXME: Should we use B in the second tar?  Not all systems support it.
2249     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2250
2251     # It is the responsibility of the user to correctly adjust all
2252     # symlinks.  If somebody can figure out how to handle them correctly
2253     # here, feel free to add the code.
2254
2255     echo $1 > $2/COPIED
2256   fi
2257   shift; shift
2258 done
2259
2260 # Determine a target-dependent exec_prefix that the installed
2261 # gcc will search in.  Keep this list sorted by triplet, with
2262 # the *-*-osname triplets last.
2263 md_exec_prefix=
2264 case "${target}" in
2265   i[[34567]]86-pc-msdosdjgpp*)
2266     md_exec_prefix=/dev/env/DJDIR/bin
2267     ;;
2268   *-*-hpux* | \
2269   *-*-nto-qnx* | \
2270   *-*-solaris2*)
2271     md_exec_prefix=/usr/ccs/bin
2272     ;;
2273 esac
2274
2275 extra_arflags_for_target=
2276 extra_nmflags_for_target=
2277 extra_ranlibflags_for_target=
2278 target_makefile_frag=/dev/null
2279 case "${target}" in
2280   spu-*-*)
2281     target_makefile_frag="config/mt-spu"
2282     ;;
2283   mips*-sde-elf*)
2284     target_makefile_frag="config/mt-sde"
2285     ;;
2286   mipsisa*-*-elfoabi*)
2287     target_makefile_frag="config/mt-mips-elfoabi"
2288     ;;
2289   mips*-*-*linux* | mips*-*-gnu*)
2290     target_makefile_frag="config/mt-mips-gnu"
2291     ;;
2292   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2293     target_makefile_frag="config/mt-gnu"
2294     ;;
2295   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2296     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2297     # commands to handle both 32-bit and 64-bit objects.  These flags are
2298     # harmless if we're using GNU nm or ar.
2299     extra_arflags_for_target=" -X32_64"
2300     extra_nmflags_for_target=" -B -X32_64"
2301     ;;
2302   *-*-darwin[[3-9]]*)
2303     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2304     extra_ranlibflags_for_target=" -c"
2305     ;;
2306 esac
2307
2308 alphaieee_frag=/dev/null
2309 case $target in
2310   alpha*-*-*)
2311     # This just makes sure to use the -mieee option to build target libs.
2312     # This should probably be set individually by each library.
2313     alphaieee_frag="config/mt-alphaieee"
2314     ;;
2315 esac
2316
2317 # If --enable-target-optspace always use -Os instead of -O2 to build
2318 # the target libraries, similarly if it is not specified, use -Os
2319 # on selected platforms.
2320 ospace_frag=/dev/null
2321 case "${enable_target_optspace}:${target}" in
2322   yes:*)
2323     ospace_frag="config/mt-ospace"
2324     ;;
2325   :d30v-*)
2326     ospace_frag="config/mt-d30v"
2327     ;;
2328   :m32r-* | :d10v-* | :fr30-*)
2329     ospace_frag="config/mt-ospace"
2330     ;;
2331   no:* | :*)
2332     ;;
2333   *)
2334     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2335     ;;
2336 esac
2337
2338 # Some systems (e.g., one of the i386-aix systems the gas testers are
2339 # using) don't handle "\$" correctly, so don't use it here.
2340 tooldir='${exec_prefix}'/${target_noncanonical}
2341 build_tooldir=${tooldir}
2342
2343 # Create a .gdbinit file which runs the one in srcdir
2344 # and tells GDB to look there for source files.
2345
2346 if test -r ${srcdir}/.gdbinit ; then
2347   case ${srcdir} in
2348     .) ;;
2349     *) cat > ./.gdbinit <<EOF
2350 # ${NO_EDIT}
2351 dir ${srcdir}
2352 dir .
2353 source ${srcdir}/.gdbinit
2354 EOF
2355     ;;
2356   esac
2357 fi
2358
2359 # Make sure that the compiler is able to generate an executable.  If it
2360 # can't, we are probably in trouble.  We don't care whether we can run the
2361 # executable--we might be using a cross compiler--we only care whether it
2362 # can be created.  At this point the main configure script has set CC.
2363 we_are_ok=no
2364 echo "int main () { return 0; }" > conftest.c
2365 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2366 if test $? = 0 ; then
2367   if test -s conftest || test -s conftest.exe ; then
2368     we_are_ok=yes
2369   fi
2370 fi
2371 case $we_are_ok in
2372   no)
2373     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2374     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2375     rm -f conftest*
2376     exit 1
2377     ;;
2378 esac
2379 rm -f conftest*
2380
2381 # Decide which environment variable is used to find dynamic libraries.
2382 case "${host}" in
2383   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2384   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2385   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2386   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2387 esac
2388
2389 # On systems where the dynamic library environment variable is PATH,
2390 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2391 # built executables to PATH.
2392 if test "$RPATH_ENVVAR" = PATH; then
2393   GCC_SHLIB_SUBDIR=/shlib
2394 else
2395   GCC_SHLIB_SUBDIR=
2396 fi
2397
2398 # Record target_configdirs and the configure arguments for target and
2399 # build configuration in Makefile.
2400 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2401 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2402
2403 # If we are building libgomp, bootstrap it.
2404 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2405   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2406 fi
2407
2408 # Determine whether gdb needs tk/tcl or not.
2409 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2410 # and in that case we want gdb to be built without tk.  Ugh!
2411 # In fact I believe gdb is the *only* package directly dependent on tk,
2412 # so we should be able to put the 'maybe's in unconditionally and
2413 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2414 # 100% sure that that's safe though.
2415
2416 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2417 case "$enable_gdbtk" in
2418   no)
2419     GDB_TK="" ;;
2420   yes)
2421     GDB_TK="${gdb_tk}" ;;
2422   *)
2423     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2424     # distro.  Eventually someone will fix this and move Insight, nee
2425     # gdbtk to a separate directory.
2426     if test -d ${srcdir}/gdb/gdbtk ; then
2427       GDB_TK="${gdb_tk}"
2428     else
2429       GDB_TK=""
2430     fi
2431     ;;
2432 esac
2433 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2434 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2435
2436 # Strip out unwanted targets.
2437
2438 # While at that, we remove Makefiles if we were started for recursive
2439 # configuration, so that the top-level Makefile reconfigures them,
2440 # like we used to do when configure itself was recursive.
2441
2442 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2443 # but now we're fixing up the Makefile ourselves with the additional
2444 # commands passed to AC_CONFIG_FILES.  Use separate variables
2445 # extrasub-{build,host,target} not because there is any reason to split
2446 # the substitutions up that way, but only to remain below the limit of
2447 # 99 commands in a script, for HP-UX sed.
2448 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2449
2450 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2451   yes:yes:*\ gold\ *:*,c++,*) ;;
2452   yes:yes:*\ gold\ *:*)
2453     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2454     ;;
2455 esac
2456
2457 # Adjust the toplevel makefile according to whether bootstrap was selected.
2458 case $enable_bootstrap in
2459   yes)
2460     bootstrap_suffix=bootstrap
2461     BUILD_CONFIG=bootstrap-debug
2462     ;;
2463   no)
2464     bootstrap_suffix=no-bootstrap
2465     BUILD_CONFIG=
2466     ;;
2467 esac
2468
2469 AC_MSG_CHECKING(for default BUILD_CONFIG)
2470
2471 AC_ARG_WITH([build-config],
2472   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2473                   [use config/NAME.mk build configuration])],
2474   [case $with_build_config in
2475    yes) with_build_config= ;;
2476    no) with_build_config= BUILD_CONFIG= ;;
2477    esac])
2478
2479 if test "x${with_build_config}" != x; then
2480   BUILD_CONFIG=$with_build_config
2481 else
2482   case $BUILD_CONFIG in
2483   bootstrap-debug)
2484     if echo "int f (void) { return 0; }" > conftest.c &&
2485        ${CC} -c conftest.c &&
2486        mv conftest.o conftest.o.g0 &&
2487        ${CC} -c -g conftest.c &&
2488        mv conftest.o conftest.o.g &&
2489        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2490       :
2491     else
2492       BUILD_CONFIG=
2493     fi
2494     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2495     ;;
2496   esac
2497 fi
2498 AC_MSG_RESULT($BUILD_CONFIG)
2499 AC_SUBST(BUILD_CONFIG)
2500
2501 extrasub_build=
2502 for module in ${build_configdirs} ; do
2503   if test -z "${no_recursion}" \
2504      && test -f ${build_subdir}/${module}/Makefile; then
2505     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2506     rm -f ${build_subdir}/${module}/Makefile
2507   fi
2508   extrasub_build="$extrasub_build
2509 /^@if build-$module\$/d
2510 /^@endif build-$module\$/d
2511 /^@if build-$module-$bootstrap_suffix\$/d
2512 /^@endif build-$module-$bootstrap_suffix\$/d"
2513 done
2514 extrasub_host=
2515 for module in ${configdirs} ; do
2516   if test -z "${no_recursion}"; then
2517     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2518       if test -f ${file}; then
2519         echo 1>&2 "*** removing ${file} to force reconfigure"
2520         rm -f ${file}
2521       fi
2522     done
2523   fi
2524   extrasub_host="$extrasub_host
2525 /^@if $module\$/d
2526 /^@endif $module\$/d
2527 /^@if $module-$bootstrap_suffix\$/d
2528 /^@endif $module-$bootstrap_suffix\$/d"
2529 done
2530 extrasub_target=
2531 for module in ${target_configdirs} ; do
2532   if test -z "${no_recursion}" \
2533      && test -f ${target_subdir}/${module}/Makefile; then
2534     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2535     rm -f ${target_subdir}/${module}/Makefile
2536   fi
2537
2538   # We only bootstrap target libraries listed in bootstrap_target_libs.
2539   case $bootstrap_target_libs in
2540     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2541     *) target_bootstrap_suffix=no-bootstrap ;;
2542   esac
2543
2544   extrasub_target="$extrasub_target
2545 /^@if target-$module\$/d
2546 /^@endif target-$module\$/d
2547 /^@if target-$module-$target_bootstrap_suffix\$/d
2548 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2549 done
2550
2551 # Do the final fixup along with target modules.
2552 extrasub_target="$extrasub_target
2553 /^@if /,/^@endif /d"
2554
2555 # Create the serialization dependencies.  This uses a temporary file.
2556
2557 AC_ARG_ENABLE([serial-configure],
2558 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2559                 [force sequential configuration of
2560                  sub-packages for the host, target or build
2561                  machine, or all sub-packages])])
2562
2563 case ${enable_serial_configure} in
2564   yes)
2565     enable_serial_build_configure=yes
2566     enable_serial_host_configure=yes
2567     enable_serial_target_configure=yes
2568     ;;
2569 esac
2570
2571 # These force 'configure's to be done one at a time, to avoid problems
2572 # with contention over a shared config.cache.
2573 rm -f serdep.tmp
2574 echo '# serdep.tmp' > serdep.tmp
2575 olditem=
2576 test "x${enable_serial_build_configure}" = xyes &&
2577 for item in ${build_configdirs} ; do
2578   case ${olditem} in
2579     "") ;;
2580     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2581   esac
2582   olditem=${item}
2583 done
2584 olditem=
2585 test "x${enable_serial_host_configure}" = xyes &&
2586 for item in ${configdirs} ; do
2587   case ${olditem} in
2588     "") ;;
2589     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2590   esac
2591   olditem=${item}
2592 done
2593 olditem=
2594 test "x${enable_serial_target_configure}" = xyes &&
2595 for item in ${target_configdirs} ; do
2596   case ${olditem} in
2597     "") ;;
2598     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2599   esac
2600   olditem=${item}
2601 done
2602 serialization_dependencies=serdep.tmp
2603 AC_SUBST_FILE(serialization_dependencies)
2604
2605 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2606 # target, nonopt, and variable assignments.  These are the ones we
2607 # might not want to pass down to subconfigures.  The exception being
2608 # --cache-file=/dev/null, which is used to turn off the use of cache
2609 # files altogether, and which should be passed on to subconfigures.
2610 # Also strip program-prefix, program-suffix, and program-transform-name,
2611 # so that we can pass down a consistent program-transform-name.
2612 baseargs=
2613 tbaseargs=
2614 keep_next=no
2615 skip_next=no
2616 eval "set -- $ac_configure_args"
2617 for ac_arg
2618 do
2619   if test X"$skip_next" = X"yes"; then
2620     skip_next=no
2621     continue
2622   fi
2623   if test X"$keep_next" = X"yes"; then
2624     case $ac_arg in
2625       *\'*)
2626         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2627     esac
2628     baseargs="$baseargs '$ac_arg'"
2629     tbaseargs="$tbaseargs '$ac_arg'"
2630     keep_next=no
2631     continue
2632   fi
2633
2634   # Handle separated arguments.  Based on the logic generated by
2635   # autoconf 2.59.
2636   case $ac_arg in
2637     *=* | --config-cache | -C | -disable-* | --disable-* \
2638       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2639       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2640       | -with-* | --with-* | -without-* | --without-* | --x)
2641       separate_arg=no
2642       ;;
2643     -*)
2644       separate_arg=yes
2645       ;;
2646     *)
2647       separate_arg=no
2648       ;;
2649   esac
2650
2651   skip_targ=no
2652   case $ac_arg in
2653 changequote(,)
2654   --with-* | --without-*)
2655     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2656
2657     case $libopt in
2658     *[-_]include)
2659       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2660       ;;
2661     *[-_]lib)
2662       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2663       ;;
2664     *)
2665       lib=$libopt
2666       ;;
2667     esac
2668 changequote([,])
2669
2670     case $lib in
2671     mpc | mpfr | gmp | ppl | cloog)
2672       # If we're processing --with-$lib, --with-$lib-include or
2673       # --with-$lib-lib, for one of the libs above, and target is
2674       # different from host, don't pass the current argument to any
2675       # target library's configure.
2676       if test x$is_cross_compiler = xyes; then
2677         skip_targ=yes
2678       fi
2679       ;;
2680     esac
2681     ;;
2682   esac
2683
2684   case "$ac_arg" in
2685     --cache-file=/dev/null | \
2686     -cache-file=/dev/null )
2687       # Handled here to avoid the test to skip args below.
2688       baseargs="$baseargs '$ac_arg'"
2689       tbaseargs="$tbaseargs '$ac_arg'"
2690       # Assert: $separate_arg should always be no.
2691       keep_next=$separate_arg
2692       ;;
2693     --no*)
2694       continue
2695       ;;
2696     --c* | \
2697     --sr* | \
2698     --ho* | \
2699     --bu* | \
2700     --t* | \
2701     --program-* | \
2702     -cache_file* | \
2703     -srcdir* | \
2704     -host* | \
2705     -build* | \
2706     -target* | \
2707     -program-prefix* | \
2708     -program-suffix* | \
2709     -program-transform-name* )
2710       skip_next=$separate_arg
2711       continue
2712       ;;
2713     -*)
2714       # An option.  Add it.
2715       case $ac_arg in
2716         *\'*)
2717           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2718       esac
2719       baseargs="$baseargs '$ac_arg'"
2720       if test X"$skip_targ" = Xno; then
2721         tbaseargs="$tbaseargs '$ac_arg'"
2722       fi
2723       keep_next=$separate_arg
2724       ;;
2725     *)
2726       # Either a variable assignment, or a nonopt (triplet).  Don't
2727       # pass it down; let the Makefile handle this.
2728       continue
2729       ;;
2730   esac
2731 done
2732 # Remove the initial space we just introduced and, as these will be
2733 # expanded by make, quote '$'.
2734 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2735
2736 # Add in --program-transform-name, after --program-prefix and
2737 # --program-suffix have been applied to it.  Autoconf has already
2738 # doubled dollar signs and backslashes in program_transform_name; we want
2739 # the backslashes un-doubled, and then the entire thing wrapped in single
2740 # quotes, because this will be expanded first by make and then by the shell.
2741 # Also, because we want to override the logic in subdir configure scripts to
2742 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2743 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2744 ${program_transform_name}
2745 EOF_SED
2746 gcc_transform_name=`cat conftestsed.out`
2747 rm -f conftestsed.out
2748 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2749 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2750 if test "$silent" = yes; then
2751   baseargs="$baseargs --silent"
2752   tbaseargs="$tbaseargs --silent"
2753 fi
2754 baseargs="$baseargs --disable-option-checking"
2755 tbaseargs="$tbaseargs --disable-option-checking"
2756
2757 # Record and document user additions to sub configure arguments.
2758 AC_ARG_VAR([build_configargs],
2759            [additional configure arguments for build directories])
2760 AC_ARG_VAR([host_configargs],
2761            [additional configure arguments for host directories])
2762 AC_ARG_VAR([target_configargs],
2763            [additional configure arguments for target directories])
2764
2765 # For the build-side libraries, we just need to pretend we're native,
2766 # and not use the same cache file.  Multilibs are neither needed nor
2767 # desired.
2768 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2769
2770 # For host modules, accept cache file option, or specification as blank.
2771 case "${cache_file}" in
2772 "") # empty
2773   cache_file_option="" ;;
2774 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2775   cache_file_option="--cache-file=${cache_file}" ;;
2776 *) # relative path
2777   cache_file_option="--cache-file=../${cache_file}" ;;
2778 esac
2779
2780 # Host dirs don't like to share a cache file either, horribly enough.
2781 # This seems to be due to autoconf 2.5x stupidity.
2782 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2783
2784 target_configargs="$target_configargs ${tbaseargs}"
2785
2786 # Passing a --with-cross-host argument lets the target libraries know
2787 # whether they are being built with a cross-compiler or being built
2788 # native.  However, it would be better to use other mechanisms to make the
2789 # sorts of decisions they want to make on this basis.  Please consider
2790 # this option to be deprecated.  FIXME.
2791 if test x${is_cross_compiler} = xyes ; then
2792   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2793 fi
2794
2795 # Default to --enable-multilib.
2796 if test x${enable_multilib} = x ; then
2797   target_configargs="--enable-multilib ${target_configargs}"
2798 fi
2799
2800 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2801 # changed from the earlier setting of with_newlib.
2802 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2803   target_configargs="--with-newlib ${target_configargs}"
2804 fi
2805
2806 # Different target subdirs use different values of certain variables
2807 # (notably CXX).  Worse, multilibs use *lots* of different values.
2808 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2809 # it doesn't automatically accept command-line overrides of them.
2810 # This means it's not safe for target subdirs to share a cache file,
2811 # which is disgusting, but there you have it.  Hopefully this can be
2812 # fixed in future.  It's still worthwhile to use a cache file for each
2813 # directory.  I think.
2814
2815 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2816 # We need to pass --target, as newer autoconf's requires consistency
2817 # for target_alias and gcc doesn't manage it consistently.
2818 target_configargs="--cache-file=./config.cache ${target_configargs}"
2819
2820 FLAGS_FOR_TARGET=
2821 case " $target_configdirs " in
2822  *" newlib "*)
2823   case " $target_configargs " in
2824   *" --with-newlib "*)
2825    case "$target" in
2826     *-cygwin*)
2827       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2828       ;;
2829    esac
2830
2831    # If we're not building GCC, don't discard standard headers.
2832    if test -d ${srcdir}/gcc; then
2833      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2834
2835      if test "${build}" != "${host}"; then
2836        # On Canadian crosses, CC_FOR_TARGET will have already been set
2837        # by `configure', so we won't have an opportunity to add -Bgcc/
2838        # to it.  This is right: we don't want to search that directory
2839        # for binaries, but we want the header files in there, so add
2840        # them explicitly.
2841        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2842
2843        # Someone might think of using the pre-installed headers on
2844        # Canadian crosses, in case the installed compiler is not fully
2845        # compatible with the compiler being built.  In this case, it
2846        # would be better to flag an error than risking having
2847        # incompatible object files being constructed.  We can't
2848        # guarantee that an error will be flagged, but let's hope the
2849        # compiler will do it, when presented with incompatible header
2850        # files.
2851      fi
2852    fi
2853
2854    case "${target}-${is_cross_compiler}" in
2855    i[[3456789]]86-*-linux*-no)
2856       # Here host == target, so we don't need to build gcc,
2857       # so we don't want to discard standard headers.
2858       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2859       ;;
2860    *)
2861       # If we're building newlib, use its generic headers last, but search
2862       # for any libc-related directories first (so make it the last -B
2863       # switch).
2864       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2865
2866       # If we're building libgloss, find the startup file, simulator library
2867       # and linker script.
2868       case " $target_configdirs " in
2869         *" libgloss "*)
2870         # Look for startup file, simulator library and maybe linker script.
2871         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2872         # Look for libnosys.a in case the target needs it.
2873         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2874         # Most targets have the linker script in the source directory.
2875         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2876         ;;
2877       esac
2878       ;;
2879    esac
2880    ;;
2881   esac
2882   ;;
2883 esac
2884
2885 case "$target" in
2886   x86_64-*mingw* | *-w64-mingw*)
2887   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2888   # however, use a symlink named 'mingw' in ${prefix} .
2889     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2890     ;;
2891   *-mingw*)
2892   # MinGW can't be handled as Cygwin above since it does not use newlib.
2893     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2894     ;;
2895 esac
2896
2897 # Allow the user to override the flags for
2898 # our build compiler if desired.
2899 if test x"${build}" = x"${host}" ; then
2900   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2901   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2902   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2903 fi
2904
2905 # On Canadian crosses, we'll be searching the right directories for
2906 # the previously-installed cross compiler, so don't bother to add
2907 # flags for directories within the install tree of the compiler
2908 # being built; programs in there won't even run.
2909 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2910   # Search for pre-installed headers if nothing else fits.
2911   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2912 fi
2913
2914 if test "x${use_gnu_ld}" = x &&
2915    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2916   # Arrange for us to find uninstalled linker scripts.
2917   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2918 fi
2919
2920 # Search for other target-specific linker scripts and such.
2921 case "${target}" in
2922   mep*)
2923     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2924     ;;
2925 esac
2926
2927 # Makefile fragments.
2928 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2929 do
2930   eval fragval=\$$frag
2931   if test $fragval != /dev/null; then
2932     eval $frag=${srcdir}/$fragval
2933   fi
2934 done
2935 AC_SUBST_FILE(host_makefile_frag)
2936 AC_SUBST_FILE(target_makefile_frag)
2937 AC_SUBST_FILE(alphaieee_frag)
2938 AC_SUBST_FILE(ospace_frag)
2939
2940 # Miscellanea: directories, flags, etc.
2941 AC_SUBST(RPATH_ENVVAR)
2942 AC_SUBST(GCC_SHLIB_SUBDIR)
2943 AC_SUBST(tooldir)
2944 AC_SUBST(build_tooldir)
2945 AC_SUBST(CONFIGURE_GDB_TK)
2946 AC_SUBST(GDB_TK)
2947 AC_SUBST(INSTALL_GDB_TK)
2948
2949 # Build module lists & subconfigure args.
2950 AC_SUBST(build_configargs)
2951 AC_SUBST(build_configdirs)
2952
2953 # Host module lists & subconfigure args.
2954 AC_SUBST(host_configargs)
2955 AC_SUBST(configdirs)
2956 AC_SUBST(target_configdirs)
2957
2958 # Target module lists & subconfigure args.
2959 AC_SUBST(target_configargs)
2960
2961
2962 # Build tools.
2963 AC_SUBST(AR_FOR_BUILD)
2964 AC_SUBST(AS_FOR_BUILD)
2965 AC_SUBST(CC_FOR_BUILD)
2966 AC_SUBST(CFLAGS_FOR_BUILD)
2967 AC_SUBST(CXXFLAGS_FOR_BUILD)
2968 AC_SUBST(CXX_FOR_BUILD)
2969 AC_SUBST(DLLTOOL_FOR_BUILD)
2970 AC_SUBST(GCJ_FOR_BUILD)
2971 AC_SUBST(GFORTRAN_FOR_BUILD)
2972 AC_SUBST(GOC_FOR_BUILD)
2973 AC_SUBST(LDFLAGS_FOR_BUILD)
2974 AC_SUBST(LD_FOR_BUILD)
2975 AC_SUBST(NM_FOR_BUILD)
2976 AC_SUBST(RANLIB_FOR_BUILD)
2977 AC_SUBST(WINDMC_FOR_BUILD)
2978 AC_SUBST(WINDRES_FOR_BUILD)
2979
2980 # Generate default definitions for YACC, M4, LEX and other programs that run
2981 # on the build machine.  These are used if the Makefile can't locate these
2982 # programs in objdir.
2983 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2984
2985 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2986 case " $build_configdirs " in
2987   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2988 esac
2989
2990 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2991 case " $build_configdirs " in
2992   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2993 esac
2994
2995 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2996 case " $build_configdirs " in
2997   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2998 esac
2999
3000 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3001 case " $build_configdirs " in
3002   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3003   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3004 esac
3005
3006 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3007 case " $build_configdirs " in
3008   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3009 esac
3010
3011 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3012 case " $build_configdirs " in
3013   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3014   *)
3015 changequote(,)
3016     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3017     # higher, else we use the "missing" dummy.
3018     if ${MAKEINFO} --version \
3019        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3020       :
3021     else
3022       MAKEINFO="$MISSING makeinfo"
3023     fi
3024     ;;
3025 changequote([,])
3026 esac
3027
3028 # FIXME: expect and dejagnu may become build tools?
3029
3030 AC_CHECK_PROGS(EXPECT, expect, expect)
3031 case " $configdirs " in
3032   *" expect "*)
3033     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3034     ;;
3035 esac
3036
3037 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3038 case " $configdirs " in
3039   *" dejagnu "*)
3040     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3041     ;;
3042 esac
3043
3044
3045 # Host tools.
3046 NCN_STRICT_CHECK_TOOLS(AR, ar)
3047 NCN_STRICT_CHECK_TOOLS(AS, as)
3048 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3049 NCN_STRICT_CHECK_TOOLS(LD, ld)
3050 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3051 NCN_STRICT_CHECK_TOOLS(NM, nm)
3052 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3053 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3054 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3055 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3056 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3057 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3058 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3059 AC_SUBST(CC)
3060 AC_SUBST(CXX)
3061 AC_SUBST(CFLAGS)
3062 AC_SUBST(CXXFLAGS)
3063
3064 # Target tools.
3065 AC_ARG_WITH([build-time-tools],
3066   [AS_HELP_STRING([--with-build-time-tools=PATH],
3067                   [use given path to find target tools during the build])],
3068   [case x"$withval" in
3069      x/*) ;;
3070      *)
3071        with_build_time_tools=
3072        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3073        ;;
3074    esac],
3075   [with_build_time_tools=])
3076
3077 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3078 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3079 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3080 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3081 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3082 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3083
3084 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3085 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3086 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3087 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3088 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3089 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3095 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3096
3097 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3098
3099 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3100 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3101 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3102 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3103 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3104                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3105                 c++)
3106 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3107                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3108                 c++)
3109 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3110 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3111 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3112                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3113 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3114                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3115 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3116                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3117 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3118 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3119 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3120 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3121 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3122 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3123 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3124 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3125 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3126
3127 AC_SUBST(FLAGS_FOR_TARGET)
3128 AC_SUBST(RAW_CXX_FOR_TARGET)
3129
3130 # Certain tools may need extra flags.
3131 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3132 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3133 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3134
3135 # When building target libraries, except in a Canadian cross, we use
3136 # the same toolchain as the compiler we just built.
3137 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3138 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3139 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3140 if test $host = $build; then
3141   case " $configdirs " in
3142     *" gcc "*)
3143       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3144       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3145       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3146       ;;
3147   esac
3148 fi
3149
3150 AC_SUBST(COMPILER_AS_FOR_TARGET)
3151 AC_SUBST(COMPILER_LD_FOR_TARGET)
3152 AC_SUBST(COMPILER_NM_FOR_TARGET)
3153
3154 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3155 AC_ARG_ENABLE(maintainer-mode,
3156 [AS_HELP_STRING([--enable-maintainer-mode],
3157                 [enable make rules and dependencies not useful
3158                  (and sometimes confusing) to the casual installer])],
3159       USE_MAINTAINER_MODE=$enableval,
3160       USE_MAINTAINER_MODE=no)
3161 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3162 AC_SUBST(MAINTAINER_MODE_TRUE)
3163 AC_SUBST(MAINTAINER_MODE_FALSE)
3164 if test "$USE_MAINTAINER_MODE" = yes; then
3165   MAINTAINER_MODE_TRUE=
3166   MAINTAINER_MODE_FALSE='#'
3167 else
3168   MAINTAINER_MODE_TRUE='#'
3169   MAINTAINER_MODE_FALSE=
3170 fi
3171 MAINT=$MAINTAINER_MODE_TRUE
3172 AC_SUBST(MAINT)dnl
3173
3174 # ---------------------
3175 # GCC bootstrap support
3176 # ---------------------
3177
3178 # Stage specific cflags for build.
3179 stage1_cflags="-g"
3180 case $build in
3181   vax-*-*)
3182     case ${GCC} in
3183       yes) stage1_cflags="-g -Wa,-J" ;;
3184       *) stage1_cflags="-g -J" ;;
3185     esac ;;
3186 esac
3187
3188 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3189 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3190   saved_CFLAGS="$CFLAGS"
3191
3192   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3193   CFLAGS="$CFLAGS -fkeep-inline-functions"
3194   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3195   AC_TRY_COMPILE([
3196 #if (__GNUC__ < 3) \
3197     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3198                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3199 #error http://gcc.gnu.org/PR29382
3200 #endif
3201     ],,
3202     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3203     [AC_MSG_RESULT([no])])
3204
3205   CFLAGS="$saved_CFLAGS"
3206 fi
3207
3208 AC_SUBST(stage1_cflags)
3209
3210 # Enable --enable-checking in stage1 of the compiler.
3211 AC_ARG_ENABLE(stage1-checking,
3212 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3213                 [choose additional checking for stage1 of the compiler])],
3214 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3215 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3216   stage1_checking=--enable-checking=yes,types
3217 else
3218   stage1_checking=--enable-checking=$enable_checking,types
3219 fi])
3220 AC_SUBST(stage1_checking)
3221
3222 # Enable -Werror in bootstrap stage2 and later.
3223 AC_ARG_ENABLE(werror,
3224 [AS_HELP_STRING([--enable-werror],
3225                 [enable -Werror in bootstrap stage2 and later])], [],
3226 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3227   enable_werror=yes
3228 else
3229   enable_werror=no
3230 fi])
3231 case ${enable_werror} in
3232   yes) stage2_werror_flag="--enable-werror-always" ;;
3233   *) stage2_werror_flag="" ;;
3234 esac
3235 AC_SUBST(stage2_werror_flag)
3236
3237 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3238 # --enable-build-with-cxx after stage1.
3239 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3240   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3241 else
3242   POSTSTAGE1_CONFIGURE_FLAGS=
3243 fi
3244 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3245
3246 # Specify what files to not compare during bootstrap.
3247
3248 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3249 case "$target" in
3250   hppa*64*-*-hpux*) ;;
3251   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3252 esac
3253 case " $configdirs " in
3254 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3255 esac
3256 AC_SUBST(compare_exclusions)
3257
3258 AC_CONFIG_FILES([Makefile],
3259   [sed "$extrasub_build" Makefile |
3260    sed "$extrasub_host" |
3261    sed "$extrasub_target" > mf$$
3262    mv -f mf$$ Makefile],
3263   [extrasub_build="$extrasub_build"
3264    extrasub_host="$extrasub_host"
3265    extrasub_target="$extrasub_target"])
3266 AC_OUTPUT