configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447 AC_ARG_ENABLE(static-libjava,
 448 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 449                 [build static libjava @<:@default=no@:>@])],
 450 ENABLE_STATIC_LIBJAVA=$enableval,
 451 ENABLE_STATIC_LIBJAVA=no)
 452 enable_static_libjava=
 453 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 454   enable_static_libjava=yes
 455 fi
 456
 457 if test x$enable_static_libjava != xyes ; then
 458   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 459 fi
 460 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 461
 462 # Disable libmudflap on some systems.
 463 if test x$enable_libmudflap = x ; then
 464     case "${target}" in
 465     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 466         # Enable libmudflap by default in GNU and friends.
 467         ;;
 468     *-*-freebsd*)
 469         # Enable libmudflap by default in FreeBSD.
 470         ;;
 471     *)
 472         # Disable it by default everywhere else.
 473         noconfigdirs="$noconfigdirs target-libmudflap"
 474         ;;
 475     esac
 476 fi
 477
 478 # Disable libgomp on non POSIX hosted systems.
 479 if test x$enable_libgomp = x ; then
 480     # Enable libgomp by default on hosted POSIX systems.
 481     case "${target}" in
 482     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 483         ;;
 484     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 485         ;;
 486     *-*-solaris2* | *-*-hpux11*)
 487         ;;
 488     *-*-darwin* | *-*-aix*)
 489         ;;
 490     *)
 491         noconfigdirs="$noconfigdirs target-libgomp"
 492         ;;
 493     esac
 494 fi
 495
 496 # Disable libitm on unsupported systems.
 497 if test -d ${srcdir}/libitm; then
 498     if test x$enable_libitm = x; then
 499         AC_MSG_CHECKING([for libitm support])
 500         if (srcdir=${srcdir}/libitm; \
 501                 . ${srcdir}/configure.tgt; \
 502                 test -n "$UNSUPPORTED")
 503         then
 504             AC_MSG_RESULT([no])
 505             noconfigdirs="$noconfigdirs target-libitm"
 506         else
 507             AC_MSG_RESULT([yes])
 508         fi
 509     fi
 510 fi
 511
 512 # Disable libssp for some systems.
 513 case "${target}" in
 514   avr-*-*)
 515     # No hosted I/O support.
 516     noconfigdirs="$noconfigdirs target-libssp"
 517     ;;
 518   powerpc-*-aix* | rs6000-*-aix*)
 519     noconfigdirs="$noconfigdirs target-libssp"
 520     ;;
 521   rl78-*-*)
 522     # Dereferencing -1 is a compile-time error
 523     noconfigdirs="$noconfigdirs target-libssp"
 524     ;;
 525 esac
 526
 527 # Disable libstdc++-v3 for some systems.
 528 case "${target}" in
 529   *-*-vxworks*)
 530     # VxWorks uses the Dinkumware C++ library.
 531     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 532     ;;
 533   arm*-wince-pe*)
 534     # the C++ libraries don't build on top of CE's C libraries
 535     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 536     ;;
 537   avr-*-*)
 538     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 539     ;;
 540 esac
 541
 542 # Disable Fortran for some systems.
 543 case "${target}" in
 544   mmix-*-*)
 545     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 546     unsupported_languages="$unsupported_languages fortran"
 547     ;;
 548 esac
 549
 550 # Disable Java if libffi is not supported.
 551 case "${target}" in
 552   alpha*-*-*)
 553     ;;
 554   arm*-*-*)
 555     ;;
 556   cris-*-*)
 557     ;;
 558   frv-*-*)
 559     ;;
 560   hppa*-*-linux*)
 561     ;;
 562   hppa*-*-hpux*)
 563     ;;
 564   i?86-*-*)
 565     ;;
 566   ia64*-*-*)
 567     ;;
 568   m32r*-*-*)
 569     ;;
 570   m68k-*-*)
 571     ;;
 572   mips*-*-rtems*)
 573     ;;
 574   mips*-*-linux*)
 575     ;;
 576   powerpc*-*-linux*)
 577     ;;
 578   powerpc-*-darwin*)
 579     ;;
 580   powerpc-*-aix* | rs6000-*-aix*)
 581     ;;
 582   powerpc-*-freebsd*)
 583     ;;
 584   powerpc64-*-freebsd*)
 585     ;;
 586   powerpc*-*-rtems*)
 587     ;;
 588   s390-*-* | s390x-*-*)
 589     ;;
 590   sh-*-* | sh[[34]]*-*-*)
 591     ;;
 592   sh64-*-* | sh5*-*-*)
 593     ;;
 594   sparc*-*-*)
 595     ;;
 596   x86_64-*-*)
 597     ;;
 598   *-*-*)
 599     unsupported_languages="$unsupported_languages java"
 600     ;;
 601 esac
 602
 603 # Disable Java, libgcj or related libraries for some systems.
 604 case "${target}" in
 605   powerpc-*-darwin*)
 606     ;;
 607   i[[3456789]]86-*-darwin*)
 608     ;;
 609   x86_64-*-darwin[[912]]*)
 610     ;;
 611   *-*-darwin*)
 612     noconfigdirs="$noconfigdirs ${libgcj}"
 613     ;;
 614   *-*-netware*)
 615     noconfigdirs="$noconfigdirs ${libgcj}"
 616     ;;
 617   *-*-rtems*)
 618     noconfigdirs="$noconfigdirs ${libgcj}"
 619     ;;
 620   *-*-tpf*)
 621     noconfigdirs="$noconfigdirs ${libgcj}"
 622     ;;
 623   *-*-uclinux*)
 624     noconfigdirs="$noconfigdirs ${libgcj}"
 625     ;;
 626   *-*-vxworks*)
 627     noconfigdirs="$noconfigdirs ${libgcj}"
 628     ;;
 629   alpha*-*-*vms*)
 630     noconfigdirs="$noconfigdirs ${libgcj}"
 631     ;;
 632   arm-wince-pe)
 633     noconfigdirs="$noconfigdirs ${libgcj}"
 634     ;;
 635   arm*-*-symbianelf*)
 636     noconfigdirs="$noconfigdirs ${libgcj}"
 637     ;;
 638   bfin-*-*)
 639     noconfigdirs="$noconfigdirs target-boehm-gc"
 640     ;;
 641   cris-*-* | crisv32-*-*)
 642     unsupported_languages="$unsupported_languages java"
 643     case "${target}" in
 644       *-*-linux*)
 645         ;;
 646       *) # See PR46792 regarding target-libffi.
 647         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 648     esac
 649     ;;
 650   hppa*64*-*-linux*)
 651     # In this case, it's because the hppa64-linux target is for
 652     # the kernel only at this point and has no libc, and thus no
 653     # headers, crt*.o, etc., all of which are needed by these.
 654     unsupported_languages="$unsupported_languages java"
 655     ;;
 656   hppa*64*-*-hpux*)
 657     noconfigdirs="$noconfigdirs ${libgcj}"
 658     ;;
 659   hppa*-hp-hpux11*)
 660     ;;
 661   hppa*-*-hpux*)
 662     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 663     # build on HP-UX 10.20.
 664     noconfigdirs="$noconfigdirs ${libgcj}"
 665     ;;
 666   ia64*-*-*vms*)
 667     noconfigdirs="$noconfigdirs ${libgcj}"
 668     ;;
 669   i[[3456789]]86-w64-mingw*)
 670     noconfigdirs="$noconfigdirs ${libgcj}"
 671     ;;
 672   i[[3456789]]86-*-mingw*)
 673     noconfigdirs="$noconfigdirs ${libgcj}"
 674     ;;
 675   x86_64-*-mingw*)
 676     noconfigdirs="$noconfigdirs ${libgcj}"
 677     ;;
 678   mmix-*-*)
 679     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 680     ;;
 681   powerpc-*-aix*)
 682     # copied from rs6000-*-* entry
 683     noconfigdirs="$noconfigdirs ${libgcj}"
 684     ;;
 685   rs6000-*-aix*)
 686     noconfigdirs="$noconfigdirs ${libgcj}"
 687     ;;
 688   *-*-lynxos*)
 689     noconfigdirs="$noconfigdirs ${libgcj}"
 690     ;;
 691 esac
 692
 693 # Default libgloss CPU subdirectory.
 694 libgloss_dir="$target_cpu"
 695
 696 case "${target}" in
 697   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 698     libgloss_dir=wince
 699     ;;
 700   arm*-*-*)
 701     libgloss_dir=arm
 702     ;;
 703   cris-*-* | crisv32-*-*)
 704     libgloss_dir=cris
 705     ;;
 706   hppa*-*-*)
 707     libgloss_dir=pa
 708     ;;
 709   i[[3456789]]86-*-*)
 710     libgloss_dir=i386
 711     ;;
 712   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 713     libgloss_dir=m68hc11
 714     ;;
 715   m68*-*-* | fido-*-*)
 716     libgloss_dir=m68k
 717     ;;
 718   mips*-*-*)
 719     libgloss_dir=mips
 720     ;;
 721   powerpc*-*-*)
 722     libgloss_dir=rs6000
 723     ;;
 724   sparc*-*-*)
 725     libgloss_dir=sparc
 726     ;;
 727 esac
 728
 729 # Disable newlib and libgloss for various target OSes.
 730 case "${target}" in
 731   alpha*-dec-osf*)
 732     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 733     ;;
 734   i[[3456789]]86-*-linux*)
 735     # This section makes it possible to build newlib natively on linux.
 736     # If we are using a cross compiler then don't configure newlib.
 737     if test x${is_cross_compiler} != xno ; then
 738       noconfigdirs="$noconfigdirs target-newlib"
 739     fi
 740     noconfigdirs="$noconfigdirs target-libgloss"
 741     # If we are not using a cross compiler, do configure newlib.
 742     # Note however, that newlib will only be configured in this situation
 743     # if the --with-newlib option has been given, because otherwise
 744     # 'target-newlib' will appear in skipdirs.
 745     ;;
 746   i[[3456789]]86-*-rdos*)
 747     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 748     ;;
 749   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 750     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 751     ;;
 752   sparc-*-sunos4*)
 753     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 754     ;;
 755   *-*-aix*)
 756     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 757     ;;
 758   *-*-beos*)
 759     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 760     ;;
 761   *-*-chorusos)
 762     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 763     ;;
 764   *-*-dragonfly*)
 765     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 766     ;;
 767   *-*-freebsd*)
 768     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 769     ;;
 770   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 771     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 772     ;;
 773   *-*-lynxos*)
 774     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 775     ;;
 776   *-*-mingw*)
 777     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 778     ;;
 779   *-*-netbsd*)
 780     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 781     ;;
 782   *-*-netware*)
 783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 784     ;;
 785   *-*-tpf*)
 786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 787     ;;
 788   *-*-uclinux*)
 789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 790     ;;
 791   *-*-vxworks*)
 792     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 793     ;;
 794 esac
 795
 796 case "${target}" in
 797   *-*-chorusos)
 798     ;;
 799   powerpc-*-darwin*)
 800     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 801     noconfigdirs="$noconfigdirs sim target-rda"
 802     ;;
 803   i[[3456789]]86-*-darwin*)
 804     noconfigdirs="$noconfigdirs ld gprof"
 805     noconfigdirs="$noconfigdirs sim target-rda"
 806     ;;
 807   x86_64-*-darwin[[912]]*)
 808     noconfigdirs="$noconfigdirs ld gas gprof"
 809     noconfigdirs="$noconfigdirs sim target-rda"
 810     ;;
 811   *-*-darwin*)
 812     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 813     noconfigdirs="$noconfigdirs sim target-rda"
 814     ;;
 815   *-*-dragonfly*)
 816     ;;
 817   *-*-freebsd*)
 818     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 819         && test -f /usr/local/include/gmp.h; then
 820       with_gmp=/usr/local
 821     fi
 822     ;;
 823   *-*-kaos*)
 824     # Remove unsupported stuff on all kaOS configurations.
 825     noconfigdirs="$noconfigdirs target-libgloss"
 826     ;;
 827   *-*-netbsd*)
 828     ;;
 829   *-*-netware*)
 830     ;;
 831   *-*-rtems*)
 832     noconfigdirs="$noconfigdirs target-libgloss"
 833     ;;
 834     # The tpf target doesn't support gdb yet.
 835   *-*-tpf*)
 836     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 837     ;;
 838   *-*-uclinux*)
 839     noconfigdirs="$noconfigdirs target-rda"
 840     ;;
 841   *-*-vxworks*)
 842     ;;
 843   alpha*-dec-osf*)
 844     # ld works, but does not support shared libraries.
 845     # gas doesn't generate exception information.
 846     noconfigdirs="$noconfigdirs gas ld"
 847     ;;
 848   alpha*-*-*vms*)
 849     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 850     ;;
 851   alpha*-*-*)
 852     # newlib is not 64 bit ready
 853     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 854     ;;
 855   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 856     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 857     ;;
 858   arc-*-*)
 859     noconfigdirs="$noconfigdirs target-libgloss"
 860     ;;
 861   arm-*-pe*)
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     ;;
 864   arm-*-riscix*)
 865     noconfigdirs="$noconfigdirs ld target-libgloss"
 866     ;;
 867   c4x-*-* | tic4x-*-*)
 868     noconfigdirs="$noconfigdirs target-libgloss"
 869     ;;
 870   tic54x-*-*)
 871     noconfigdirs="$noconfigdirs target-libgloss gdb"
 872     ;;
 873   cr16-*-*)
 874     noconfigdirs="$noconfigdirs gdb"
 875     ;;
 876   d10v-*-*)
 877     noconfigdirs="$noconfigdirs target-libgloss"
 878     ;;
 879   d30v-*-*)
 880     noconfigdirs="$noconfigdirs gdb"
 881     ;;
 882   fr30-*-elf*)
 883     noconfigdirs="$noconfigdirs gdb"
 884     ;;
 885   moxie-*-*)
 886     noconfigdirs="$noconfigdirs gprof"
 887     ;;
 888   h8300*-*-*)
 889     noconfigdirs="$noconfigdirs target-libgloss"
 890     ;;
 891   h8500-*-*)
 892     noconfigdirs="$noconfigdirs target-libgloss"
 893     ;;
 894   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 895     ;;
 896   hppa*64*-*-linux*)
 897     ;;
 898   hppa*-*-linux*)
 899     ;;
 900   hppa*-*-*elf* | \
 901   hppa*-*-lites* | \
 902   hppa*-*-openbsd* | \
 903   hppa*64*-*-*)
 904     ;;
 905   hppa*-hp-hpux11*)
 906     noconfigdirs="$noconfigdirs ld"
 907     ;;
 908   hppa*-*-pro*)
 909     ;;
 910   hppa*-*-*)
 911     noconfigdirs="$noconfigdirs ld"
 912     ;;
 913   i960-*-*)
 914     noconfigdirs="$noconfigdirs gdb"
 915     ;;
 916   ia64*-*-elf*)
 917     # No gdb support yet.
 918     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 919     ;;
 920   ia64*-**-hpux*)
 921     # No ld support yet.
 922     noconfigdirs="$noconfigdirs libgui itcl ld"
 923     ;;
 924   ia64*-*-*vms*)
 925     # No ld support yet.
 926     noconfigdirs="$noconfigdirs libgui itcl ld"
 927     ;;
 928   i[[3456789]]86-w64-mingw*)
 929     ;;
 930   i[[3456789]]86-*-mingw*)
 931     target_configdirs="$target_configdirs target-winsup"
 932     ;;
 933   *-*-cygwin*)
 934     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 935     noconfigdirs="$noconfigdirs target-libgloss"
 936     # always build newlib if winsup directory is present.
 937     if test -d "$srcdir/winsup/cygwin"; then
 938       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 939     elif test -d "$srcdir/newlib"; then
 940       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 941     fi
 942     ;;
 943   i[[3456789]]86-*-pe)
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     ;;
 946   i[[3456789]]86-*-sco3.2v5*)
 947     # The linker does not yet know about weak symbols in COFF,
 948     # and is not configured to handle mixed ELF and COFF.
 949     noconfigdirs="$noconfigdirs ld target-libgloss"
 950     ;;
 951   i[[3456789]]86-*-sco*)
 952     noconfigdirs="$noconfigdirs gprof target-libgloss"
 953     ;;
 954   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 955     noconfigdirs="$noconfigdirs target-libgloss"
 956     ;;
 957   i[[3456789]]86-*-sysv4*)
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   i[[3456789]]86-*-beos*)
 961     noconfigdirs="$noconfigdirs gdb"
 962     ;;
 963   i[[3456789]]86-*-rdos*)
 964     noconfigdirs="$noconfigdirs gdb"
 965     ;;
 966   mmix-*-*)
 967     noconfigdirs="$noconfigdirs gdb"
 968     ;;
 969   mt-*-*)
 970     noconfigdirs="$noconfigdirs sim"
 971     ;;
 972   powerpc-*-aix*)
 973     # copied from rs6000-*-* entry
 974     noconfigdirs="$noconfigdirs gprof"
 975     ;;
 976   powerpc*-*-winnt* | powerpc*-*-pe*)
 977     target_configdirs="$target_configdirs target-winsup"
 978     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 979     # always build newlib.
 980     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 981     ;;
 982     # This is temporary until we can link against shared libraries
 983   powerpcle-*-solaris*)
 984     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 985     ;;
 986   powerpc-*-beos*)
 987     noconfigdirs="$noconfigdirs gdb"
 988     ;;
 989   rs6000-*-lynxos*)
 990     noconfigdirs="$noconfigdirs gprof"
 991     ;;
 992   rs6000-*-aix*)
 993     noconfigdirs="$noconfigdirs gprof"
 994     ;;
 995   rs6000-*-*)
 996     noconfigdirs="$noconfigdirs gprof"
 997     ;;
 998   m68k-apollo-*)
 999     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1000     ;;
1001   microblaze*)
1002     noconfigdirs="$noconfigdirs gprof"
1003     ;;
1004   mips*-sde-elf*)
1005     if test x$with_newlib = xyes; then
1006       noconfigdirs="$noconfigdirs gprof"
1007     fi
1008     ;;
1009   mips*-*-irix5*)
1010     noconfigdirs="$noconfigdirs gprof target-libgloss"
1011     ;;
1012   mips*-*-irix6*)
1013     noconfigdirs="$noconfigdirs gprof target-libgloss"
1014     ;;
1015   mips*-*-bsd*)
1016     noconfigdirs="$noconfigdirs gprof target-libgloss"
1017     ;;
1018   mips*-*-linux*)
1019     ;;
1020   mips*-*-*)
1021     noconfigdirs="$noconfigdirs gprof"
1022     ;;
1023   sh-*-* | sh64-*-*)
1024     case "${target}" in
1025       sh*-*-elf)
1026          ;;
1027       *)
1028          noconfigdirs="$noconfigdirs target-libgloss" ;;
1029     esac
1030     ;;
1031   sparc-*-sunos4*)
1032     if test x${is_cross_compiler} = xno ; then
1033            use_gnu_ld=no
1034     fi
1035     ;;
1036   tic6x-*-*)
1037     noconfigdirs="$noconfigdirs sim"
1038     ;;
1039   tilepro-*-* | tilegx-*-*)
1040     noconfigdirs="$noconfigdirs sim"
1041     ;;
1042   v810-*-*)
1043     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1044     ;;
1045   vax-*-*)
1046     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1047     ;;
1048 esac
1049
1050 # If we aren't building newlib, then don't build libgloss, since libgloss
1051 # depends upon some newlib header files.
1052 case "${noconfigdirs}" in
1053   *target-libgloss*) ;;
1054   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1055 esac
1056
1057 # Work in distributions that contain no compiler tools, like Autoconf.
1058 host_makefile_frag=/dev/null
1059 if test -d ${srcdir}/config ; then
1060 case "${host}" in
1061   i[[3456789]]86-*-msdosdjgpp*)
1062     host_makefile_frag="config/mh-djgpp"
1063     ;;
1064   *-cygwin*)
1065     ACX_CHECK_CYGWIN_CAT_WORKS
1066     host_makefile_frag="config/mh-cygwin"
1067     ;;
1068   *-mingw*)
1069     host_makefile_frag="config/mh-mingw"
1070     ;;
1071   *-interix*)
1072     host_makefile_frag="config/mh-interix"
1073     ;;
1074   hppa*-hp-hpux10*)
1075     host_makefile_frag="config/mh-pa-hpux10"
1076     ;;
1077   hppa*-hp-hpux*)
1078     host_makefile_frag="config/mh-pa"
1079     ;;
1080   hppa*-*)
1081     host_makefile_frag="config/mh-pa"
1082     ;;
1083   *-*-darwin*)
1084     host_makefile_frag="config/mh-darwin"
1085     ;;
1086   powerpc-*-aix*)
1087     host_makefile_frag="config/mh-ppc-aix"
1088     ;;
1089   rs6000-*-aix*)
1090     host_makefile_frag="config/mh-ppc-aix"
1091     ;;
1092 esac
1093 fi
1094
1095 if test "${build}" != "${host}" ; then
1096   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1097   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1098   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1099   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1100   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1101   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1102   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1103   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1104   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1105   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1106   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1107   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1108   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1109 else
1110   AR_FOR_BUILD="\$(AR)"
1111   AS_FOR_BUILD="\$(AS)"
1112   CC_FOR_BUILD="\$(CC)"
1113   CXX_FOR_BUILD="\$(CXX)"
1114   GCJ_FOR_BUILD="\$(GCJ)"
1115   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1116   GOC_FOR_BUILD="\$(GOC)"
1117   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1118   LD_FOR_BUILD="\$(LD)"
1119   NM_FOR_BUILD="\$(NM)"
1120   RANLIB_FOR_BUILD="\$(RANLIB)"
1121   WINDRES_FOR_BUILD="\$(WINDRES)"
1122   WINDMC_FOR_BUILD="\$(WINDMC)"
1123 fi
1124
1125 AC_PROG_CC
1126 AC_PROG_CXX
1127
1128 # We must set the default linker to the linker used by gcc for the correct
1129 # operation of libtool.  If LD is not defined and we are using gcc, try to
1130 # set the LD default to the ld used by gcc.
1131 if test -z "$LD"; then
1132   if test "$GCC" = yes; then
1133     case $build in
1134     *-*-mingw*)
1135       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1136     *)
1137       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1138     esac
1139     case $gcc_prog_ld in
1140     # Accept absolute paths.
1141     [[\\/]* | [A-Za-z]:[\\/]*)]
1142       LD="$gcc_prog_ld" ;;
1143     esac
1144   fi
1145 fi
1146
1147 ACX_PROG_GNAT
1148 ACX_PROG_CMP_IGNORE_INITIAL
1149
1150 AC_ARG_ENABLE([bootstrap],
1151 [AS_HELP_STRING([--enable-bootstrap],
1152                 [enable bootstrapping @<:@yes if native build@:>@])],,
1153 enable_bootstrap=default)
1154
1155 # Issue errors and warnings for invalid/strange bootstrap combinations.
1156 if test -r $srcdir/gcc/configure; then
1157   have_compiler=yes
1158 else
1159   have_compiler=no
1160 fi
1161
1162 case "$have_compiler:$host:$target:$enable_bootstrap" in
1163   *:*:*:no) ;;
1164
1165   # Default behavior.  Enable bootstrap if we have a compiler
1166   # and we are in a native configuration.
1167   yes:$build:$build:default)
1168     enable_bootstrap=yes ;;
1169
1170   *:*:*:default)
1171     enable_bootstrap=no ;;
1172
1173   # We have a compiler and we are in a native configuration, bootstrap is ok
1174   yes:$build:$build:yes)
1175     ;;
1176
1177   # Other configurations, but we have a compiler.  Assume the user knows
1178   # what he's doing.
1179   yes:*:*:yes)
1180     AC_MSG_WARN([trying to bootstrap a cross compiler])
1181     ;;
1182
1183   # No compiler: if they passed --enable-bootstrap explicitly, fail
1184   no:*:*:yes)
1185     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1186
1187   # Fail if wrong command line
1188   *)
1189     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1190     ;;
1191 esac
1192
1193 # See if we are building gcc with C++.
1194 AC_ARG_ENABLE(build-with-cxx,
1195 [AS_HELP_STRING([--enable-build-with-cxx],
1196                 [build with C++ compiler instead of C compiler])],
1197 ENABLE_BUILD_WITH_CXX=$enableval,
1198 ENABLE_BUILD_WITH_CXX=no)
1199
1200 # Build stage1 with C and build stages 2 and 3 with C++.
1201 AC_ARG_ENABLE(build-poststage1-with-cxx,
1202 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1203                 [build stages 2 and 3 with C++, not C])],
1204 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1205 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1206
1207 # Used for setting $lt_cv_objdir
1208 _LT_CHECK_OBJDIR
1209
1210 # Check for GMP, MPFR and MPC
1211 gmplibs="-lmpc -lmpfr -lgmp"
1212 gmpinc=
1213 have_gmp=no
1214
1215 # Specify a location for mpc
1216 # check for this first so it ends up on the link line before mpfr.
1217 AC_ARG_WITH(mpc,
1218 [AS_HELP_STRING([--with-mpc=PATH],
1219                 [specify prefix directory for installed MPC package.
1220                  Equivalent to --with-mpc-include=PATH/include
1221                  plus --with-mpc-lib=PATH/lib])])
1222 AC_ARG_WITH(mpc-include,
1223 [AS_HELP_STRING([--with-mpc-include=PATH],
1224                 [specify directory for installed MPC include files])])
1225 AC_ARG_WITH(mpc-lib,
1226 [AS_HELP_STRING([--with-mpc-lib=PATH],
1227                 [specify directory for the installed MPC library])])
1228
1229 if test "x$with_mpc" != x; then
1230   gmplibs="-L$with_mpc/lib $gmplibs"
1231   gmpinc="-I$with_mpc/include $gmpinc"
1232 fi
1233 if test "x$with_mpc_include" != x; then
1234   gmpinc="-I$with_mpc_include $gmpinc"
1235 fi
1236 if test "x$with_mpc_lib" != x; then
1237   gmplibs="-L$with_mpc_lib $gmplibs"
1238 fi
1239 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1240   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1241   gmpinc='-I$$s/mpc/src '"$gmpinc"
1242   # Do not test the mpc version.  Assume that it is sufficient, since
1243   # it is in the source tree, and the library has not been built yet
1244   # but it would be included on the link line in the version check below
1245   # hence making the test fail.
1246   have_gmp=yes
1247 fi
1248
1249 # Specify a location for mpfr
1250 # check for this first so it ends up on the link line before gmp.
1251 AC_ARG_WITH(mpfr-dir,
1252 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1253 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1254 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1255
1256 AC_ARG_WITH(mpfr,
1257 [AS_HELP_STRING([--with-mpfr=PATH],
1258                 [specify prefix directory for installed MPFR package.
1259                  Equivalent to --with-mpfr-include=PATH/include
1260                  plus --with-mpfr-lib=PATH/lib])])
1261 AC_ARG_WITH(mpfr-include,
1262 [AS_HELP_STRING([--with-mpfr-include=PATH],
1263                 [specify directory for installed MPFR include files])])
1264 AC_ARG_WITH(mpfr-lib,
1265 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1266                 [specify directory for the installed MPFR library])])
1267
1268 if test "x$with_mpfr" != x; then
1269   gmplibs="-L$with_mpfr/lib $gmplibs"
1270   gmpinc="-I$with_mpfr/include $gmpinc"
1271 fi
1272 if test "x$with_mpfr_include" != x; then
1273   gmpinc="-I$with_mpfr_include $gmpinc"
1274 fi
1275 if test "x$with_mpfr_lib" != x; then
1276   gmplibs="-L$with_mpfr_lib $gmplibs"
1277 fi
1278 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1279   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1280   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1281   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1282   # Do not test the mpfr version.  Assume that it is sufficient, since
1283   # it is in the source tree, and the library has not been built yet
1284   # but it would be included on the link line in the version check below
1285   # hence making the test fail.
1286   have_gmp=yes
1287 fi
1288
1289 # Specify a location for gmp
1290 AC_ARG_WITH(gmp-dir,
1291 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1292 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1293 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1294
1295 AC_ARG_WITH(gmp,
1296 [AS_HELP_STRING([--with-gmp=PATH],
1297                 [specify prefix directory for the installed GMP package.
1298                  Equivalent to --with-gmp-include=PATH/include
1299                  plus --with-gmp-lib=PATH/lib])])
1300 AC_ARG_WITH(gmp-include,
1301 [AS_HELP_STRING([--with-gmp-include=PATH],
1302                 [specify directory for installed GMP include files])])
1303 AC_ARG_WITH(gmp-lib,
1304 [AS_HELP_STRING([--with-gmp-lib=PATH],
1305                 [specify directory for the installed GMP library])])
1306
1307
1308 if test "x$with_gmp" != x; then
1309   gmplibs="-L$with_gmp/lib $gmplibs"
1310   gmpinc="-I$with_gmp/include $gmpinc"
1311 fi
1312 if test "x$with_gmp_include" != x; then
1313   gmpinc="-I$with_gmp_include $gmpinc"
1314 fi
1315 if test "x$with_gmp_lib" != x; then
1316   gmplibs="-L$with_gmp_lib $gmplibs"
1317 fi
1318 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1319   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1320   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1321   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1322   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1323   # Do not test the gmp version.  Assume that it is sufficient, since
1324   # it is in the source tree, and the library has not been built yet
1325   # but it would be included on the link line in the version check below
1326   # hence making the test fail.
1327   have_gmp=yes
1328 fi
1329
1330 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1331   have_gmp=yes
1332   saved_CFLAGS="$CFLAGS"
1333   CFLAGS="$CFLAGS $gmpinc"
1334   # Check for the recommended and required versions of GMP.
1335   AC_MSG_CHECKING([for the correct version of gmp.h])
1336   AC_TRY_COMPILE([#include "gmp.h"],[
1337   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1338   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1339   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1340   choke me
1341   #endif
1342   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1343   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1344   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1345   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1346   choke me
1347   #endif
1348   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1349    [AC_MSG_RESULT([no]); have_gmp=no])
1350
1351   # If we have GMP, check the MPFR version.
1352   if test x"$have_gmp" = xyes; then
1353     # Check for the recommended and required versions of MPFR.
1354     AC_MSG_CHECKING([for the correct version of mpfr.h])
1355     AC_TRY_COMPILE([#include <gmp.h>
1356     #include <mpfr.h>],[
1357     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1358     choke me
1359     #endif
1360     ], [AC_TRY_COMPILE([#include <gmp.h>
1361     #include <mpfr.h>],[
1362     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1363     choke me
1364     #endif
1365     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1366      [AC_MSG_RESULT([no]); have_gmp=no])
1367   fi
1368
1369   # Check for the MPC header version.
1370   if test x"$have_gmp" = xyes ; then
1371     # Check for the recommended and required versions of MPC.
1372     AC_MSG_CHECKING([for the correct version of mpc.h])
1373     AC_TRY_COMPILE([#include <mpc.h>],[
1374     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1375     choke me
1376     #endif
1377     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1378     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1379     choke me
1380     #endif
1381     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1382      [AC_MSG_RESULT([no]); have_gmp=no])
1383   fi
1384
1385   # Now check the MPFR library.
1386   if test x"$have_gmp" = xyes; then
1387     saved_LIBS="$LIBS"
1388     LIBS="$LIBS $gmplibs"
1389     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1390     AC_TRY_LINK([#include <mpc.h>],[
1391     mpfr_t n;
1392     mpfr_t x;
1393     mpc_t c;
1394     int t;
1395     mpfr_init (n);
1396     mpfr_init (x);
1397     mpfr_atan2 (n, n, x, GMP_RNDN);
1398     mpfr_erfc (n, x, GMP_RNDN);
1399     mpfr_subnormalize (x, t, GMP_RNDN);
1400     mpfr_clear(n);
1401     mpfr_clear(x);
1402     mpc_init2 (c, 53);
1403     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1404     mpc_cosh (c, c, MPC_RNDNN);
1405     mpc_pow (c, c, c, MPC_RNDNN);
1406     mpc_acosh (c, c, MPC_RNDNN);
1407     mpc_clear (c);
1408     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1409     LIBS="$saved_LIBS"
1410   fi
1411
1412   CFLAGS="$saved_CFLAGS"
1413
1414 # The library versions listed in the error message below should match
1415 # the HARD-minimums enforced above.
1416   if test x$have_gmp != xyes; then
1417     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1418 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1419 their locations.  Source code for these libraries can be found at
1420 their respective hosting sites as well as at
1421 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1422 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1423 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1424 make sure that you have installed both the libraries and the header
1425 files.  They may be located in separate packages.])
1426   fi
1427 fi
1428
1429 # Flags needed for both GMP, MPFR and/or MPC.
1430 AC_SUBST(gmplibs)
1431 AC_SUBST(gmpinc)
1432 AC_SUBST(extra_mpfr_configure_flags)
1433 AC_SUBST(extra_mpc_gmp_configure_flags)
1434 AC_SUBST(extra_mpc_mpfr_configure_flags)
1435
1436 # Allow host libstdc++ to be specified for static linking with PPL.
1437 AC_ARG_WITH(host-libstdcxx,
1438 [AS_HELP_STRING([--with-host-libstdcxx=L],
1439                 [use linker arguments L to link with libstdc++
1440                  when linking with PPL])])
1441
1442 case $with_host_libstdcxx in
1443   no|yes)
1444     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1445     ;;
1446 esac
1447
1448 # Linker flags to use for stage1 or when not boostrapping.
1449 AC_ARG_WITH(stage1-ldflags,
1450 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1451 [if test "$withval" = "no" -o "$withval" = "yes"; then
1452    stage1_ldflags=
1453  else
1454    stage1_ldflags=$withval
1455  fi],
1456 [stage1_ldflags=])
1457 AC_SUBST(stage1_ldflags)
1458
1459 # Libraries to use for stage1 or when not bootstrapping.
1460 AC_ARG_WITH(stage1-libs,
1461 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1462 [if test "$withval" = "no" -o "$withval" = "yes"; then
1463    stage1_libs=
1464  else
1465    stage1_libs=$withval
1466  fi],
1467 [stage1_libs=$with_host_libstdcxx])
1468 AC_SUBST(stage1_libs)
1469
1470 # Libraries to use for stage2 and later builds.  This defaults to the
1471 # argument passed to --with-host-libstdcxx.
1472 AC_ARG_WITH(boot-libs,
1473 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1474 [if test "$withval" = "no" -o "$withval" = "yes"; then
1475    poststage1_libs=
1476  else
1477    poststage1_libs=$withval
1478  fi],
1479 [poststage1_libs=$with_host_libstdcxx])
1480 AC_SUBST(poststage1_libs)
1481
1482 # Linker flags to use for stage2 and later builds.
1483 AC_ARG_WITH(boot-ldflags,
1484 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1485                 [linker flags for stage2 and later])],
1486 [if test "$withval" = "no" -o "$withval" = "yes"; then
1487    poststage1_ldflags=
1488  else
1489    poststage1_ldflags=$withval
1490  fi],
1491 [poststage1_ldflags=
1492  # In stages 2 and 3, default to linking libstdc++ and libgcc
1493  # statically.  But if the user explicitly specified the libraries to
1494  # use, trust that they are doing what they want.
1495  if test "$poststage1_libs" = ""; then
1496    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1497  fi])
1498 AC_SUBST(poststage1_ldflags)
1499
1500 # Check for PPL
1501 ppllibs=
1502 pplinc=
1503 pwllib=
1504
1505 AC_ARG_WITH(ppl,
1506 [AS_HELP_STRING([--with-ppl=PATH],
1507                 [specify prefix directory for the installed PPL package.
1508                  Equivalent to --with-ppl-include=PATH/include
1509                  plus --with-ppl-lib=PATH/lib])])
1510 AC_ARG_WITH(ppl-include,
1511 [AS_HELP_STRING([--with-ppl-include=PATH],
1512                 [specify directory for installed PPL include files])])
1513 AC_ARG_WITH(ppl-lib,
1514 [AS_HELP_STRING([--with-ppl-lib=PATH],
1515                 [specify directory for the installed PPL library])])
1516
1517 AC_ARG_ENABLE(ppl-version-check,
1518 [AS_HELP_STRING([--disable-ppl-version-check],
1519                 [disable check for PPL version])])
1520
1521 case $with_ppl in
1522   yes | no | "")
1523     ;;
1524   *)
1525     ppllibs="-L$with_ppl/lib"
1526     pplinc="-I$with_ppl/include $pplinc"
1527     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1528       with_ppl=yes
1529     else
1530       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1531     fi
1532     ;;
1533 esac
1534
1535 if test x"$with_ppl_include" != x; then
1536   pplinc="-I$with_ppl_include $pplinc"
1537   with_ppl=yes
1538 fi
1539
1540 if test "x$with_ppl_lib" != x; then
1541   ppllibs="-L$with_ppl_lib"
1542   with_ppl=yes
1543 fi
1544
1545 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1546   if test x"$enable_watchdog" = xyes; then
1547     pwllib="-lpwl"
1548   fi
1549   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1550   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1551   enable_ppl_version_check=no
1552   with_ppl=yes
1553 fi
1554
1555 if test "x$with_ppl" != xno; then
1556   if test "x$pwllib" = x; then
1557     saved_LIBS="$LIBS"
1558     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1559     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1560     LIBS="$saved_LIBS"
1561   fi
1562
1563   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1564
1565   if test "$enable_ppl_version_check" != no; then
1566     saved_CFLAGS="$CFLAGS"
1567     CFLAGS="$CFLAGS $pplinc $gmpinc"
1568     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1569     AC_TRY_COMPILE([#include "ppl_c.h"],[
1570     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1571     choke me
1572     #endif
1573     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1574     CFLAGS="$saved_CFLAGS"
1575   fi
1576 fi
1577
1578 # Flags needed for PPL
1579 AC_SUBST(ppllibs)
1580 AC_SUBST(pplinc)
1581
1582
1583 # Check for CLOOG
1584
1585 dnl Provide configure switches and initialize clooginc & clooglibs
1586 dnl with user input.
1587 CLOOG_INIT_FLAGS
1588 if test "x$with_ppl" = "xno"; then
1589   dnl Only execute fail-action, if CLooG has been requested.
1590   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1591   if test "${graphite_requested}" = yes; then
1592     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1593   fi
1594   with_cloog=no
1595 fi
1596 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1597   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1598   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1599   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1600 fi
1601 if test "x$with_cloog" != "xno"; then
1602   dnl The minimal version of CLooG required for Graphite.
1603   dnl
1604   dnl If we use CLooG-Legacy, the provided version information is
1605   dnl ignored.
1606   CLOOG_CHECK_VERSION(0,16,1)
1607
1608   dnl Only execute fail-action, if CLooG has been requested.
1609   CLOOG_IF_FAILED([
1610     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1611 fi
1612
1613 # Check for LTO support.
1614 AC_ARG_ENABLE(lto,
1615 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1616 enable_lto=$enableval,
1617 enable_lto=yes; default_enable_lto=yes)
1618
1619 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1620   build_lto_plugin=yes
1621 ],[if test x"$default_enable_lto" = x"yes" ; then
1622     case $target in
1623       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1624       # On other non-ELF platforms, LTO has yet to be validated.
1625       *) enable_lto=no ;;
1626     esac
1627   else
1628   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1629   # It would also be nice to check the binutils support, but we don't
1630   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1631   # warn during gcc/ subconfigure; unless you're bootstrapping with
1632   # -flto it won't be needed until after installation anyway.
1633     case $target in
1634       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1635       *) if test x"$enable_lto" = x"yes"; then
1636         AC_MSG_ERROR([LTO support is not enabled for this target.])
1637         fi
1638       ;;
1639     esac
1640   fi
1641   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1642   # Build it unless LTO was explicitly disabled.
1643   case $target in
1644     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1645     *) ;;
1646   esac
1647 ])
1648
1649
1650 # By default, C is the only stage 1 language.
1651 stage1_languages=,c,
1652
1653 # Target libraries that we bootstrap.
1654 bootstrap_target_libs=,target-libgcc,
1655
1656 # Figure out what language subdirectories are present.
1657 # Look if the user specified --enable-languages="..."; if not, use
1658 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1659 # go away some day.
1660 # NB:  embedded tabs in this IF block -- do not untabify
1661 if test -d ${srcdir}/gcc; then
1662   if test x"${enable_languages+set}" != xset; then
1663     if test x"${LANGUAGES+set}" = xset; then
1664       enable_languages="${LANGUAGES}"
1665         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1666     else
1667       enable_languages=all
1668     fi
1669   else
1670     if test x"${enable_languages}" = x ||
1671        test x"${enable_languages}" = xyes;
1672        then
1673       echo configure.in: --enable-languages needs at least one language argument 1>&2
1674       exit 1
1675     fi
1676   fi
1677   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1678
1679   # 'f95' is the old name for the 'fortran' language. We issue a warning
1680   # and make the substitution.
1681   case ,${enable_languages}, in
1682     *,f95,*)
1683       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1684       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1685       ;;
1686   esac
1687
1688   # If bootstrapping, then using --enable-build-with-cxx or
1689   # --enable-build-poststage1-with-cxx requires enabling C++.
1690   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1691     *,c++,*:*:*) ;;
1692     *:*,yes,*:yes)
1693       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1694         enable_languages="${enable_languages},c++"
1695       else
1696         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1697       fi
1698       ;;
1699   esac
1700
1701   # First scan to see if an enabled language requires some other language.
1702   # We assume that a given config-lang.in will list all the language
1703   # front ends it requires, even if some are required indirectly.
1704   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1705     case ${lang_frag} in
1706       ..) ;;
1707       # The odd quoting in the next line works around
1708       # an apparent bug in bash 1.12 on linux.
1709       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1710       *)
1711         # From the config-lang.in, get $language, $lang_requires, and
1712         # $lang_requires_boot_languages.
1713         language=
1714         lang_requires=
1715         lang_requires_boot_languages=
1716         . ${lang_frag}
1717         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1718           case ,${enable_languages}, in
1719             *,$other,*) ;;
1720             *,all,*) ;;
1721             *,$language,*)
1722               echo " \`$other' language required by \`$language'; enabling" 1>&2
1723               enable_languages="${enable_languages},${other}"
1724               ;;
1725           esac
1726         done
1727         for other in ${lang_requires_boot_languages} ; do
1728           if test "$other" != "c"; then
1729             case ,${enable_stage1_languages}, in
1730               *,$other,*) ;;
1731               *,all,*) ;;
1732               *)
1733                 case ,${enable_languages}, in
1734                   *,$language,*)
1735                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1736                     enable_stage1_languages="$enable_stage1_languages,${other}"
1737                     ;;
1738                 esac
1739                 ;;
1740             esac
1741           fi
1742         done
1743         ;;
1744     esac
1745   done
1746
1747   new_enable_languages=,c,
1748
1749   # If LTO is enabled, add the LTO front end.
1750   extra_host_libiberty_configure_flags=
1751   if test "$enable_lto" = "yes" ; then
1752     case ,${enable_languages}, in
1753       *,lto,*) ;;
1754       *) enable_languages="${enable_languages},lto" ;;
1755     esac
1756     if test "${build_lto_plugin}" = "yes" ; then
1757       configdirs="$configdirs lto-plugin"
1758       extra_host_libiberty_configure_flags=--enable-shared
1759     fi
1760   fi
1761   AC_SUBST(extra_host_libiberty_configure_flags)
1762
1763   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1764   potential_languages=,c,
1765
1766   enabled_target_libs=
1767   disabled_target_libs=
1768
1769   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1770     case ${lang_frag} in
1771       ..) ;;
1772       # The odd quoting in the next line works around
1773       # an apparent bug in bash 1.12 on linux.
1774       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1775       *)
1776         # From the config-lang.in, get $language, $target_libs,
1777         # $lang_dirs, $boot_language, and $build_by_default
1778         language=
1779         target_libs=
1780         lang_dirs=
1781         subdir_requires=
1782         boot_language=no
1783         build_by_default=yes
1784         . ${lang_frag}
1785         if test x${language} = x; then
1786           echo "${lang_frag} doesn't set \$language." 1>&2
1787           exit 1
1788         fi
1789
1790         if test "$language" = "c++"; then
1791           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1792              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1793             boot_language=yes
1794           fi
1795         fi
1796
1797         case ,${enable_languages}, in
1798           *,${language},*)
1799             # Language was explicitly selected; include it.
1800             add_this_lang=yes
1801             ;;
1802           *,all,*)
1803             # 'all' was selected, select it if it is a default language
1804             add_this_lang=${build_by_default}
1805             ;;
1806           *)
1807             add_this_lang=no
1808             ;;
1809         esac
1810
1811         # Disable languages that need other directories if these aren't available.
1812         for i in $subdir_requires; do
1813           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1814           case ,${enable_languages}, in
1815             *,${language},*)
1816               # Specifically requested language; tell them.
1817               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1818               ;;
1819             *)
1820               # Silently disable.
1821               add_this_lang=unsupported
1822               ;;
1823           esac
1824         done
1825
1826         # Disable Ada if no preexisting GNAT is available.
1827         case ,${enable_languages},:${language}:${have_gnat} in
1828           *,${language},*:ada:no)
1829             # Specifically requested language; tell them.
1830             AC_MSG_ERROR([GNAT is required to build $language])
1831             ;;
1832           *:ada:no)
1833             # Silently disable.
1834             add_this_lang=unsupported
1835             ;;
1836         esac
1837
1838         # Disable a language that is unsupported by the target.
1839         case " $unsupported_languages " in
1840           *" $language "*)
1841             add_this_lang=unsupported
1842             ;;
1843         esac
1844
1845         case $add_this_lang in
1846           unsupported)
1847             # Remove language-dependent dirs.
1848             disabled_target_libs="$disabled_target_libs $target_libs"
1849             noconfigdirs="$noconfigdirs $lang_dirs"
1850             ;;
1851           no)
1852             # Remove language-dependent dirs; still show language as supported.
1853             disabled_target_libs="$disabled_target_libs $target_libs"
1854             noconfigdirs="$noconfigdirs $lang_dirs"
1855             potential_languages="${potential_languages}${language},"
1856             ;;
1857           yes)
1858             new_enable_languages="${new_enable_languages}${language},"
1859             potential_languages="${potential_languages}${language},"
1860             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1861             enabled_target_libs="$enabled_target_libs $target_libs"
1862             case "${boot_language}:,$enable_stage1_languages," in
1863               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1864                 # Add to (comma-separated) list of stage 1 languages.
1865                 case ",$stage1_languages," in
1866                   *,$language,* | ,yes, | ,all,) ;;
1867                   *) stage1_languages="${stage1_languages}${language}," ;;
1868                 esac
1869                 # We need to bootstrap any supporting libraries.
1870                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1871                 ;;
1872             esac
1873             ;;
1874         esac
1875         ;;
1876     esac
1877   done
1878
1879   # Add target libraries which are only needed for disabled languages
1880   # to noconfigdirs.
1881   if test -n "$disabled_target_libs"; then
1882     for dir in $disabled_target_libs; do
1883       case " $enabled_target_libs " in
1884       *" ${dir} "*) ;;
1885       *) noconfigdirs="$noconfigdirs $dir" ;;
1886       esac
1887     done
1888   fi
1889
1890   AC_ARG_ENABLE(stage1-languages,
1891   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1892                   [choose additional languages to build during
1893                   stage1.  Mostly useful for compiler development])],
1894   [case ,${enable_stage1_languages}, in
1895     ,no,|,,)
1896       # Set it to something that will have no effect in the loop below
1897       enable_stage1_languages=c ;;
1898     ,yes,)
1899       enable_stage1_languages=`echo $new_enable_languages | \
1900         sed -e "s/^,//" -e "s/,$//" ` ;;
1901     *,all,*)
1902       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1903         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1904   esac
1905
1906   # Add "good" languages from enable_stage1_languages to stage1_languages,
1907   # while "bad" languages go in missing_languages.  Leave no duplicates.
1908   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1909     case $potential_languages in
1910       *,$i,*)
1911         case $stage1_languages in
1912           *,$i,*) ;;
1913           *) stage1_languages="$stage1_languages$i," ;;
1914         esac ;;
1915       *)
1916         case $missing_languages in
1917           *,$i,*) ;;
1918           *) missing_languages="$missing_languages$i," ;;
1919         esac ;;
1920      esac
1921   done])
1922
1923   # Remove leading/trailing commas that were added for simplicity
1924   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1925   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1926   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1927   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1928
1929   if test "x$missing_languages" != x; then
1930     AC_MSG_ERROR([
1931 The following requested languages could not be built: ${missing_languages}
1932 Supported languages are: ${potential_languages}])
1933   fi
1934   if test "x$new_enable_languages" != "x$enable_languages"; then
1935     echo The following languages will be built: ${new_enable_languages}
1936     enable_languages="$new_enable_languages"
1937   fi
1938
1939   AC_SUBST(stage1_languages)
1940   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1941 fi
1942
1943 # Handle --disable-<component> generically.
1944 for dir in $configdirs $build_configdirs $target_configdirs ; do
1945   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1946   varname=`echo $dirname | sed -e s/+/_/g`
1947   if eval test x\${enable_${varname}} "=" xno ; then
1948     noconfigdirs="$noconfigdirs $dir"
1949   fi
1950 done
1951
1952 # Check for Boehm's garbage collector
1953 AC_ARG_ENABLE(objc-gc,
1954 [AS_HELP_STRING([--enable-objc-gc],
1955                 [enable use of Boehm's garbage collector with the
1956                  GNU Objective-C runtime])],
1957 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1958   *,objc,*:*:yes:*target-boehm-gc*)
1959     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1960     ;;
1961 esac])
1962
1963 # Make sure we only build Boehm's garbage collector if required.
1964 case ,${enable_languages},:${enable_objc_gc} in
1965   *,objc,*:yes)
1966     # Keep target-boehm-gc if requested for Objective-C.
1967     ;;
1968   *)
1969     # Otherwise remove target-boehm-gc depending on target-libjava.
1970     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1971       noconfigdirs="$noconfigdirs target-boehm-gc"
1972     fi
1973     ;;
1974 esac
1975
1976 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1977 # $build_configdirs and $target_configdirs.
1978 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1979
1980 notsupp=""
1981 for dir in . $skipdirs $noconfigdirs ; do
1982   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1983   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1984     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1985     if test -r $srcdir/$dirname/configure ; then
1986       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1987         true
1988       else
1989         notsupp="$notsupp $dir"
1990       fi
1991     fi
1992   fi
1993   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1994     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1995     if test -r $srcdir/$dirname/configure ; then
1996       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1997         true
1998       else
1999         notsupp="$notsupp $dir"
2000       fi
2001     fi
2002   fi
2003   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2004     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2005     if test -r $srcdir/$dirname/configure ; then
2006       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2007         true
2008       else
2009         notsupp="$notsupp $dir"
2010       fi
2011     fi
2012   fi
2013 done
2014
2015 # Quietly strip out all directories which aren't configurable in this tree.
2016 # This relies on all configurable subdirectories being autoconfiscated, which
2017 # is now the case.
2018 build_configdirs_all="$build_configdirs"
2019 build_configdirs=
2020 for i in ${build_configdirs_all} ; do
2021   j=`echo $i | sed -e s/build-//g`
2022   if test -f ${srcdir}/$j/configure ; then
2023     build_configdirs="${build_configdirs} $i"
2024   fi
2025 done
2026
2027 configdirs_all="$configdirs"
2028 configdirs=
2029 for i in ${configdirs_all} ; do
2030   if test -f ${srcdir}/$i/configure ; then
2031     configdirs="${configdirs} $i"
2032   fi
2033 done
2034
2035 target_configdirs_all="$target_configdirs"
2036 target_configdirs=
2037 for i in ${target_configdirs_all} ; do
2038   j=`echo $i | sed -e s/target-//g`
2039   if test -f ${srcdir}/$j/configure ; then
2040     target_configdirs="${target_configdirs} $i"
2041   fi
2042 done
2043
2044 # Produce a warning message for the subdirs we can't configure.
2045 # This isn't especially interesting in the Cygnus tree, but in the individual
2046 # FSF releases, it's important to let people know when their machine isn't
2047 # supported by the one or two programs in a package.
2048
2049 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2050   # If $appdirs is non-empty, at least one of those directories must still
2051   # be configured, or we error out.  (E.g., if the gas release supports a
2052   # specified target in some subdirs but not the gas subdir, we shouldn't
2053   # pretend that all is well.)
2054   if test -n "$appdirs" ; then
2055     for dir in $appdirs ; do
2056       if test -r $dir/Makefile.in ; then
2057         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2058           appdirs=""
2059           break
2060         fi
2061         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2062           appdirs=""
2063           break
2064         fi
2065       fi
2066     done
2067     if test -n "$appdirs" ; then
2068       echo "*** This configuration is not supported by this package." 1>&2
2069       exit 1
2070     fi
2071   fi
2072   # Okay, some application will build, or we don't care to check.  Still
2073   # notify of subdirs not getting built.
2074   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2075   echo "    ${notsupp}" 1>&2
2076   echo "    (Any other directories should still work fine.)" 1>&2
2077 fi
2078
2079 case "$host" in
2080   *msdosdjgpp*)
2081     enable_gdbtk=no ;;
2082 esac
2083
2084 # To find our prefix, in gcc_cv_tool_prefix.
2085 ACX_TOOL_DIRS
2086
2087 copy_dirs=
2088
2089 AC_ARG_WITH([build-sysroot],
2090   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2091                   [use sysroot as the system root during the build])],
2092   [if test x"$withval" != x ; then
2093      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2094    fi],
2095   [SYSROOT_CFLAGS_FOR_TARGET=])
2096 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2097
2098 AC_ARG_WITH([debug-prefix-map],
2099   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2100                   [map A to B, C to D ... in debug information])],
2101   [if test x"$withval" != x; then
2102      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2103      for debug_map in $withval; do
2104        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2105      done
2106    fi],
2107   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2108 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2109
2110 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2111 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2112 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2113 # We want to ensure that TARGET libraries (which we know are built with
2114 # gcc) are built with "-O2 -g", so include those options when setting
2115 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2116 if test "x$CFLAGS_FOR_TARGET" = x; then
2117   CFLAGS_FOR_TARGET=$CFLAGS
2118   case " $CFLAGS " in
2119     *" -O2 "*) ;;
2120     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2121   esac
2122   case " $CFLAGS " in
2123     *" -g "* | *" -g3 "*) ;;
2124     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2125   esac
2126 fi
2127 AC_SUBST(CFLAGS_FOR_TARGET)
2128
2129 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2130   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2131   case " $CXXFLAGS " in
2132     *" -O2 "*) ;;
2133     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2134   esac
2135   case " $CXXFLAGS " in
2136     *" -g "* | *" -g3 "*) ;;
2137     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2138   esac
2139 fi
2140 AC_SUBST(CXXFLAGS_FOR_TARGET)
2141
2142 AC_SUBST(LDFLAGS_FOR_TARGET)
2143
2144 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2145 # the named directory are copied to $(tooldir)/sys-include.
2146 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2147   if test x${is_cross_compiler} = xno ; then
2148     echo 1>&2 '***' --with-headers is only supported when cross compiling
2149     exit 1
2150   fi
2151   if test x"${with_headers}" != xyes ; then
2152     x=${gcc_cv_tool_prefix}
2153     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2154   fi
2155 fi
2156
2157 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2158 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2159 # are permitted.
2160 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2161   if test x${is_cross_compiler} = xno ; then
2162     echo 1>&2 '***' --with-libs is only supported when cross compiling
2163     exit 1
2164   fi
2165   if test x"${with_libs}" != xyes ; then
2166     # Copy the libraries in reverse order, so that files in the first named
2167     # library override files in subsequent libraries.
2168     x=${gcc_cv_tool_prefix}
2169     for l in ${with_libs}; do
2170       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2171     done
2172   fi
2173 fi
2174
2175 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2176 #
2177 # This is done by determining whether or not the appropriate directory
2178 # is available, and by checking whether or not specific configurations
2179 # have requested that this magic not happen.
2180 #
2181 # The command line options always override the explicit settings in
2182 # configure.in, and the settings in configure.in override this magic.
2183 #
2184 # If the default for a toolchain is to use GNU as and ld, and you don't
2185 # want to do that, then you should use the --without-gnu-as and
2186 # --without-gnu-ld options for the configure script.  Similarly, if
2187 # the default is to use the included zlib and you don't want to do that,
2188 # you should use the --with-system-zlib option for the configure script.
2189
2190 if test x${use_gnu_as} = x &&
2191    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2192   with_gnu_as=yes
2193   extra_host_args="$extra_host_args --with-gnu-as"
2194 fi
2195
2196 if test x${use_gnu_ld} = x &&
2197    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2198   with_gnu_ld=yes
2199   extra_host_args="$extra_host_args --with-gnu-ld"
2200 fi
2201
2202 if test x${use_included_zlib} = x &&
2203    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2204   :
2205 else
2206   with_system_zlib=yes
2207   extra_host_args="$extra_host_args --with-system-zlib"
2208 fi
2209
2210 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2211 # can detect this case.
2212
2213 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2214   with_newlib=yes
2215   extra_host_args="$extra_host_args --with-newlib"
2216 fi
2217
2218 # Handle ${copy_dirs}
2219 set fnord ${copy_dirs}
2220 shift
2221 while test $# != 0 ; do
2222   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2223     :
2224   else
2225     echo Copying $1 to $2
2226
2227     # Use the install script to create the directory and all required
2228     # parent directories.
2229     if test -d $2 ; then
2230       :
2231     else
2232       echo >config.temp
2233       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2234     fi
2235
2236     # Copy the directory, assuming we have tar.
2237     # FIXME: Should we use B in the second tar?  Not all systems support it.
2238     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2239
2240     # It is the responsibility of the user to correctly adjust all
2241     # symlinks.  If somebody can figure out how to handle them correctly
2242     # here, feel free to add the code.
2243
2244     echo $1 > $2/COPIED
2245   fi
2246   shift; shift
2247 done
2248
2249 # Determine a target-dependent exec_prefix that the installed
2250 # gcc will search in.  Keep this list sorted by triplet, with
2251 # the *-*-osname triplets last.
2252 md_exec_prefix=
2253 case "${target}" in
2254   i[[34567]]86-pc-msdosdjgpp*)
2255     md_exec_prefix=/dev/env/DJDIR/bin
2256     ;;
2257   *-*-hpux* | \
2258   *-*-nto-qnx* | \
2259   *-*-solaris2*)
2260     md_exec_prefix=/usr/ccs/bin
2261     ;;
2262 esac
2263
2264 extra_arflags_for_target=
2265 extra_nmflags_for_target=
2266 extra_ranlibflags_for_target=
2267 target_makefile_frag=/dev/null
2268 case "${target}" in
2269   spu-*-*)
2270     target_makefile_frag="config/mt-spu"
2271     ;;
2272   mips*-sde-elf*)
2273     target_makefile_frag="config/mt-sde"
2274     ;;
2275   mipsisa*-*-elfoabi*)
2276     target_makefile_frag="config/mt-mips-elfoabi"
2277     ;;
2278   mips*-*-*linux* | mips*-*-gnu*)
2279     target_makefile_frag="config/mt-mips-gnu"
2280     ;;
2281   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2282     target_makefile_frag="config/mt-gnu"
2283     ;;
2284   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2285     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2286     # commands to handle both 32-bit and 64-bit objects.  These flags are
2287     # harmless if we're using GNU nm or ar.
2288     extra_arflags_for_target=" -X32_64"
2289     extra_nmflags_for_target=" -B -X32_64"
2290     ;;
2291   *-*-darwin[[3-9]]*)
2292     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2293     extra_ranlibflags_for_target=" -c"
2294     ;;
2295 esac
2296
2297 alphaieee_frag=/dev/null
2298 case $target in
2299   alpha*-*-*)
2300     # This just makes sure to use the -mieee option to build target libs.
2301     # This should probably be set individually by each library.
2302     alphaieee_frag="config/mt-alphaieee"
2303     ;;
2304 esac
2305
2306 # If --enable-target-optspace always use -Os instead of -O2 to build
2307 # the target libraries, similarly if it is not specified, use -Os
2308 # on selected platforms.
2309 ospace_frag=/dev/null
2310 case "${enable_target_optspace}:${target}" in
2311   yes:*)
2312     ospace_frag="config/mt-ospace"
2313     ;;
2314   :d30v-*)
2315     ospace_frag="config/mt-d30v"
2316     ;;
2317   :m32r-* | :d10v-* | :fr30-*)
2318     ospace_frag="config/mt-ospace"
2319     ;;
2320   no:* | :*)
2321     ;;
2322   *)
2323     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2324     ;;
2325 esac
2326
2327 # Some systems (e.g., one of the i386-aix systems the gas testers are
2328 # using) don't handle "\$" correctly, so don't use it here.
2329 tooldir='${exec_prefix}'/${target_noncanonical}
2330 build_tooldir=${tooldir}
2331
2332 # Create a .gdbinit file which runs the one in srcdir
2333 # and tells GDB to look there for source files.
2334
2335 if test -r ${srcdir}/.gdbinit ; then
2336   case ${srcdir} in
2337     .) ;;
2338     *) cat > ./.gdbinit <<EOF
2339 # ${NO_EDIT}
2340 dir ${srcdir}
2341 dir .
2342 source ${srcdir}/.gdbinit
2343 EOF
2344     ;;
2345   esac
2346 fi
2347
2348 # Make sure that the compiler is able to generate an executable.  If it
2349 # can't, we are probably in trouble.  We don't care whether we can run the
2350 # executable--we might be using a cross compiler--we only care whether it
2351 # can be created.  At this point the main configure script has set CC.
2352 we_are_ok=no
2353 echo "int main () { return 0; }" > conftest.c
2354 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2355 if test $? = 0 ; then
2356   if test -s conftest || test -s conftest.exe ; then
2357     we_are_ok=yes
2358   fi
2359 fi
2360 case $we_are_ok in
2361   no)
2362     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2363     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2364     rm -f conftest*
2365     exit 1
2366     ;;
2367 esac
2368 rm -f conftest*
2369
2370 # Decide which environment variable is used to find dynamic libraries.
2371 case "${host}" in
2372   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2373   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2374   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2375   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2376 esac
2377
2378 # On systems where the dynamic library environment variable is PATH,
2379 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2380 # built executables to PATH.
2381 if test "$RPATH_ENVVAR" = PATH; then
2382   GCC_SHLIB_SUBDIR=/shlib
2383 else
2384   GCC_SHLIB_SUBDIR=
2385 fi
2386
2387 # Record target_configdirs and the configure arguments for target and
2388 # build configuration in Makefile.
2389 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2390 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2391
2392 # If we are building libgomp, bootstrap it.
2393 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2394   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2395 fi
2396
2397 # Determine whether gdb needs tk/tcl or not.
2398 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2399 # and in that case we want gdb to be built without tk.  Ugh!
2400 # In fact I believe gdb is the *only* package directly dependent on tk,
2401 # so we should be able to put the 'maybe's in unconditionally and
2402 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2403 # 100% sure that that's safe though.
2404
2405 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2406 case "$enable_gdbtk" in
2407   no)
2408     GDB_TK="" ;;
2409   yes)
2410     GDB_TK="${gdb_tk}" ;;
2411   *)
2412     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2413     # distro.  Eventually someone will fix this and move Insight, nee
2414     # gdbtk to a separate directory.
2415     if test -d ${srcdir}/gdb/gdbtk ; then
2416       GDB_TK="${gdb_tk}"
2417     else
2418       GDB_TK=""
2419     fi
2420     ;;
2421 esac
2422 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2423 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2424
2425 # Strip out unwanted targets.
2426
2427 # While at that, we remove Makefiles if we were started for recursive
2428 # configuration, so that the top-level Makefile reconfigures them,
2429 # like we used to do when configure itself was recursive.
2430
2431 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2432 # but now we're fixing up the Makefile ourselves with the additional
2433 # commands passed to AC_CONFIG_FILES.  Use separate variables
2434 # extrasub-{build,host,target} not because there is any reason to split
2435 # the substitutions up that way, but only to remain below the limit of
2436 # 99 commands in a script, for HP-UX sed.
2437 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2438
2439 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2440   yes:yes:*\ gold\ *:*,c++,*) ;;
2441   yes:yes:*\ gold\ *:*)
2442     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2443     ;;
2444 esac
2445
2446 # Adjust the toplevel makefile according to whether bootstrap was selected.
2447 case $enable_bootstrap in
2448   yes)
2449     bootstrap_suffix=bootstrap
2450     BUILD_CONFIG=bootstrap-debug
2451     ;;
2452   no)
2453     bootstrap_suffix=no-bootstrap
2454     BUILD_CONFIG=
2455     ;;
2456 esac
2457
2458 AC_MSG_CHECKING(for default BUILD_CONFIG)
2459
2460 AC_ARG_WITH([build-config],
2461   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2462                   [use config/NAME.mk build configuration])],
2463   [case $with_build_config in
2464    yes) with_build_config= ;;
2465    no) with_build_config= BUILD_CONFIG= ;;
2466    esac])
2467
2468 if test "x${with_build_config}" != x; then
2469   BUILD_CONFIG=$with_build_config
2470 else
2471   case $BUILD_CONFIG in
2472   bootstrap-debug)
2473     if echo "int f (void) { return 0; }" > conftest.c &&
2474        ${CC} -c conftest.c &&
2475        mv conftest.o conftest.o.g0 &&
2476        ${CC} -c -g conftest.c &&
2477        mv conftest.o conftest.o.g &&
2478        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2479       :
2480     else
2481       BUILD_CONFIG=
2482     fi
2483     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2484     ;;
2485   esac
2486 fi
2487 AC_MSG_RESULT($BUILD_CONFIG)
2488 AC_SUBST(BUILD_CONFIG)
2489
2490 extrasub_build=
2491 for module in ${build_configdirs} ; do
2492   if test -z "${no_recursion}" \
2493      && test -f ${build_subdir}/${module}/Makefile; then
2494     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2495     rm -f ${build_subdir}/${module}/Makefile
2496   fi
2497   extrasub_build="$extrasub_build
2498 /^@if build-$module\$/d
2499 /^@endif build-$module\$/d
2500 /^@if build-$module-$bootstrap_suffix\$/d
2501 /^@endif build-$module-$bootstrap_suffix\$/d"
2502 done
2503 extrasub_host=
2504 for module in ${configdirs} ; do
2505   if test -z "${no_recursion}"; then
2506     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2507       if test -f ${file}; then
2508         echo 1>&2 "*** removing ${file} to force reconfigure"
2509         rm -f ${file}
2510       fi
2511     done
2512   fi
2513   extrasub_host="$extrasub_host
2514 /^@if $module\$/d
2515 /^@endif $module\$/d
2516 /^@if $module-$bootstrap_suffix\$/d
2517 /^@endif $module-$bootstrap_suffix\$/d"
2518 done
2519 extrasub_target=
2520 for module in ${target_configdirs} ; do
2521   if test -z "${no_recursion}" \
2522      && test -f ${target_subdir}/${module}/Makefile; then
2523     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2524     rm -f ${target_subdir}/${module}/Makefile
2525   fi
2526
2527   # We only bootstrap target libraries listed in bootstrap_target_libs.
2528   case $bootstrap_target_libs in
2529     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2530     *) target_bootstrap_suffix=no-bootstrap ;;
2531   esac
2532
2533   extrasub_target="$extrasub_target
2534 /^@if target-$module\$/d
2535 /^@endif target-$module\$/d
2536 /^@if target-$module-$target_bootstrap_suffix\$/d
2537 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2538 done
2539
2540 # Do the final fixup along with target modules.
2541 extrasub_target="$extrasub_target
2542 /^@if /,/^@endif /d"
2543
2544 # Create the serialization dependencies.  This uses a temporary file.
2545
2546 AC_ARG_ENABLE([serial-configure],
2547 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2548                 [force sequential configuration of
2549                  sub-packages for the host, target or build
2550                  machine, or all sub-packages])])
2551
2552 case ${enable_serial_configure} in
2553   yes)
2554     enable_serial_build_configure=yes
2555     enable_serial_host_configure=yes
2556     enable_serial_target_configure=yes
2557     ;;
2558 esac
2559
2560 # These force 'configure's to be done one at a time, to avoid problems
2561 # with contention over a shared config.cache.
2562 rm -f serdep.tmp
2563 echo '# serdep.tmp' > serdep.tmp
2564 olditem=
2565 test "x${enable_serial_build_configure}" = xyes &&
2566 for item in ${build_configdirs} ; do
2567   case ${olditem} in
2568     "") ;;
2569     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2570   esac
2571   olditem=${item}
2572 done
2573 olditem=
2574 test "x${enable_serial_host_configure}" = xyes &&
2575 for item in ${configdirs} ; do
2576   case ${olditem} in
2577     "") ;;
2578     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2579   esac
2580   olditem=${item}
2581 done
2582 olditem=
2583 test "x${enable_serial_target_configure}" = xyes &&
2584 for item in ${target_configdirs} ; do
2585   case ${olditem} in
2586     "") ;;
2587     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2588   esac
2589   olditem=${item}
2590 done
2591 serialization_dependencies=serdep.tmp
2592 AC_SUBST_FILE(serialization_dependencies)
2593
2594 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2595 # target, nonopt, and variable assignments.  These are the ones we
2596 # might not want to pass down to subconfigures.  The exception being
2597 # --cache-file=/dev/null, which is used to turn off the use of cache
2598 # files altogether, and which should be passed on to subconfigures.
2599 # Also strip program-prefix, program-suffix, and program-transform-name,
2600 # so that we can pass down a consistent program-transform-name.
2601 baseargs=
2602 tbaseargs=
2603 keep_next=no
2604 skip_next=no
2605 eval "set -- $ac_configure_args"
2606 for ac_arg
2607 do
2608   if test X"$skip_next" = X"yes"; then
2609     skip_next=no
2610     continue
2611   fi
2612   if test X"$keep_next" = X"yes"; then
2613     case $ac_arg in
2614       *\'*)
2615         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2616     esac
2617     baseargs="$baseargs '$ac_arg'"
2618     tbaseargs="$tbaseargs '$ac_arg'"
2619     keep_next=no
2620     continue
2621   fi
2622
2623   # Handle separated arguments.  Based on the logic generated by
2624   # autoconf 2.59.
2625   case $ac_arg in
2626     *=* | --config-cache | -C | -disable-* | --disable-* \
2627       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2628       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2629       | -with-* | --with-* | -without-* | --without-* | --x)
2630       separate_arg=no
2631       ;;
2632     -*)
2633       separate_arg=yes
2634       ;;
2635     *)
2636       separate_arg=no
2637       ;;
2638   esac
2639
2640   skip_targ=no
2641   case $ac_arg in
2642 changequote(,)
2643   --with-* | --without-*)
2644     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2645
2646     case $libopt in
2647     *[-_]include)
2648       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2649       ;;
2650     *[-_]lib)
2651       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2652       ;;
2653     *)
2654       lib=$libopt
2655       ;;
2656     esac
2657 changequote([,])
2658
2659     case $lib in
2660     mpc | mpfr | gmp | ppl | cloog)
2661       # If we're processing --with-$lib, --with-$lib-include or
2662       # --with-$lib-lib, for one of the libs above, and target is
2663       # different from host, don't pass the current argument to any
2664       # target library's configure.
2665       if test x$is_cross_compiler = xyes; then
2666         skip_targ=yes
2667       fi
2668       ;;
2669     esac
2670     ;;
2671   esac
2672
2673   case "$ac_arg" in
2674     --cache-file=/dev/null | \
2675     -cache-file=/dev/null )
2676       # Handled here to avoid the test to skip args below.
2677       baseargs="$baseargs '$ac_arg'"
2678       tbaseargs="$tbaseargs '$ac_arg'"
2679       # Assert: $separate_arg should always be no.
2680       keep_next=$separate_arg
2681       ;;
2682     --no*)
2683       continue
2684       ;;
2685     --c* | \
2686     --sr* | \
2687     --ho* | \
2688     --bu* | \
2689     --t* | \
2690     --program-* | \
2691     -cache_file* | \
2692     -srcdir* | \
2693     -host* | \
2694     -build* | \
2695     -target* | \
2696     -program-prefix* | \
2697     -program-suffix* | \
2698     -program-transform-name* )
2699       skip_next=$separate_arg
2700       continue
2701       ;;
2702     -*)
2703       # An option.  Add it.
2704       case $ac_arg in
2705         *\'*)
2706           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2707       esac
2708       baseargs="$baseargs '$ac_arg'"
2709       if test X"$skip_targ" = Xno; then
2710         tbaseargs="$tbaseargs '$ac_arg'"
2711       fi
2712       keep_next=$separate_arg
2713       ;;
2714     *)
2715       # Either a variable assignment, or a nonopt (triplet).  Don't
2716       # pass it down; let the Makefile handle this.
2717       continue
2718       ;;
2719   esac
2720 done
2721 # Remove the initial space we just introduced and, as these will be
2722 # expanded by make, quote '$'.
2723 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2724
2725 # Add in --program-transform-name, after --program-prefix and
2726 # --program-suffix have been applied to it.  Autoconf has already
2727 # doubled dollar signs and backslashes in program_transform_name; we want
2728 # the backslashes un-doubled, and then the entire thing wrapped in single
2729 # quotes, because this will be expanded first by make and then by the shell.
2730 # Also, because we want to override the logic in subdir configure scripts to
2731 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2732 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2733 ${program_transform_name}
2734 EOF_SED
2735 gcc_transform_name=`cat conftestsed.out`
2736 rm -f conftestsed.out
2737 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2738 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2739 if test "$silent" = yes; then
2740   baseargs="$baseargs --silent"
2741   tbaseargs="$tbaseargs --silent"
2742 fi
2743 baseargs="$baseargs --disable-option-checking"
2744 tbaseargs="$tbaseargs --disable-option-checking"
2745
2746 # Record and document user additions to sub configure arguments.
2747 AC_ARG_VAR([build_configargs],
2748            [additional configure arguments for build directories])
2749 AC_ARG_VAR([host_configargs],
2750            [additional configure arguments for host directories])
2751 AC_ARG_VAR([target_configargs],
2752            [additional configure arguments for target directories])
2753
2754 # For the build-side libraries, we just need to pretend we're native,
2755 # and not use the same cache file.  Multilibs are neither needed nor
2756 # desired.
2757 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2758
2759 # For host modules, accept cache file option, or specification as blank.
2760 case "${cache_file}" in
2761 "") # empty
2762   cache_file_option="" ;;
2763 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2764   cache_file_option="--cache-file=${cache_file}" ;;
2765 *) # relative path
2766   cache_file_option="--cache-file=../${cache_file}" ;;
2767 esac
2768
2769 # Host dirs don't like to share a cache file either, horribly enough.
2770 # This seems to be due to autoconf 2.5x stupidity.
2771 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2772
2773 target_configargs="$target_configargs ${tbaseargs}"
2774
2775 # Passing a --with-cross-host argument lets the target libraries know
2776 # whether they are being built with a cross-compiler or being built
2777 # native.  However, it would be better to use other mechanisms to make the
2778 # sorts of decisions they want to make on this basis.  Please consider
2779 # this option to be deprecated.  FIXME.
2780 if test x${is_cross_compiler} = xyes ; then
2781   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2782 fi
2783
2784 # Default to --enable-multilib.
2785 if test x${enable_multilib} = x ; then
2786   target_configargs="--enable-multilib ${target_configargs}"
2787 fi
2788
2789 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2790 # changed from the earlier setting of with_newlib.
2791 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2792   target_configargs="--with-newlib ${target_configargs}"
2793 fi
2794
2795 # Different target subdirs use different values of certain variables
2796 # (notably CXX).  Worse, multilibs use *lots* of different values.
2797 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2798 # it doesn't automatically accept command-line overrides of them.
2799 # This means it's not safe for target subdirs to share a cache file,
2800 # which is disgusting, but there you have it.  Hopefully this can be
2801 # fixed in future.  It's still worthwhile to use a cache file for each
2802 # directory.  I think.
2803
2804 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2805 # We need to pass --target, as newer autoconf's requires consistency
2806 # for target_alias and gcc doesn't manage it consistently.
2807 target_configargs="--cache-file=./config.cache ${target_configargs}"
2808
2809 FLAGS_FOR_TARGET=
2810 case " $target_configdirs " in
2811  *" newlib "*)
2812   case " $target_configargs " in
2813   *" --with-newlib "*)
2814    case "$target" in
2815     *-cygwin*)
2816       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2817       ;;
2818    esac
2819
2820    # If we're not building GCC, don't discard standard headers.
2821    if test -d ${srcdir}/gcc; then
2822      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2823
2824      if test "${build}" != "${host}"; then
2825        # On Canadian crosses, CC_FOR_TARGET will have already been set
2826        # by `configure', so we won't have an opportunity to add -Bgcc/
2827        # to it.  This is right: we don't want to search that directory
2828        # for binaries, but we want the header files in there, so add
2829        # them explicitly.
2830        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2831
2832        # Someone might think of using the pre-installed headers on
2833        # Canadian crosses, in case the installed compiler is not fully
2834        # compatible with the compiler being built.  In this case, it
2835        # would be better to flag an error than risking having
2836        # incompatible object files being constructed.  We can't
2837        # guarantee that an error will be flagged, but let's hope the
2838        # compiler will do it, when presented with incompatible header
2839        # files.
2840      fi
2841    fi
2842
2843    case "${target}-${is_cross_compiler}" in
2844    i[[3456789]]86-*-linux*-no)
2845       # Here host == target, so we don't need to build gcc,
2846       # so we don't want to discard standard headers.
2847       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2848       ;;
2849    *)
2850       # If we're building newlib, use its generic headers last, but search
2851       # for any libc-related directories first (so make it the last -B
2852       # switch).
2853       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2854
2855       # If we're building libgloss, find the startup file, simulator library
2856       # and linker script.
2857       case " $target_configdirs " in
2858         *" libgloss "*)
2859         # Look for startup file, simulator library and maybe linker script.
2860         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2861         # Look for libnosys.a in case the target needs it.
2862         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2863         # Most targets have the linker script in the source directory.
2864         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2865         ;;
2866       esac
2867       ;;
2868    esac
2869    ;;
2870   esac
2871   ;;
2872 esac
2873
2874 case "$target" in
2875   x86_64-*mingw* | *-w64-mingw*)
2876   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2877   # however, use a symlink named 'mingw' in ${prefix} .
2878     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2879     ;;
2880   *-mingw*)
2881   # MinGW can't be handled as Cygwin above since it does not use newlib.
2882     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2883     ;;
2884 esac
2885
2886 # Allow the user to override the flags for
2887 # our build compiler if desired.
2888 if test x"${build}" = x"${host}" ; then
2889   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2890   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2891   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2892 fi
2893
2894 # On Canadian crosses, we'll be searching the right directories for
2895 # the previously-installed cross compiler, so don't bother to add
2896 # flags for directories within the install tree of the compiler
2897 # being built; programs in there won't even run.
2898 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2899   # Search for pre-installed headers if nothing else fits.
2900   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2901 fi
2902
2903 if test "x${use_gnu_ld}" = x &&
2904    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2905   # Arrange for us to find uninstalled linker scripts.
2906   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2907 fi
2908
2909 # Search for other target-specific linker scripts and such.
2910 case "${target}" in
2911   mep*)
2912     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2913     ;;
2914 esac
2915
2916 # Makefile fragments.
2917 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2918 do
2919   eval fragval=\$$frag
2920   if test $fragval != /dev/null; then
2921     eval $frag=${srcdir}/$fragval
2922   fi
2923 done
2924 AC_SUBST_FILE(host_makefile_frag)
2925 AC_SUBST_FILE(target_makefile_frag)
2926 AC_SUBST_FILE(alphaieee_frag)
2927 AC_SUBST_FILE(ospace_frag)
2928
2929 # Miscellanea: directories, flags, etc.
2930 AC_SUBST(RPATH_ENVVAR)
2931 AC_SUBST(GCC_SHLIB_SUBDIR)
2932 AC_SUBST(tooldir)
2933 AC_SUBST(build_tooldir)
2934 AC_SUBST(CONFIGURE_GDB_TK)
2935 AC_SUBST(GDB_TK)
2936 AC_SUBST(INSTALL_GDB_TK)
2937
2938 # Build module lists & subconfigure args.
2939 AC_SUBST(build_configargs)
2940 AC_SUBST(build_configdirs)
2941
2942 # Host module lists & subconfigure args.
2943 AC_SUBST(host_configargs)
2944 AC_SUBST(configdirs)
2945 AC_SUBST(target_configdirs)
2946
2947 # Target module lists & subconfigure args.
2948 AC_SUBST(target_configargs)
2949
2950
2951 # Build tools.
2952 AC_SUBST(AR_FOR_BUILD)
2953 AC_SUBST(AS_FOR_BUILD)
2954 AC_SUBST(CC_FOR_BUILD)
2955 AC_SUBST(CFLAGS_FOR_BUILD)
2956 AC_SUBST(CXXFLAGS_FOR_BUILD)
2957 AC_SUBST(CXX_FOR_BUILD)
2958 AC_SUBST(DLLTOOL_FOR_BUILD)
2959 AC_SUBST(GCJ_FOR_BUILD)
2960 AC_SUBST(GFORTRAN_FOR_BUILD)
2961 AC_SUBST(GOC_FOR_BUILD)
2962 AC_SUBST(LDFLAGS_FOR_BUILD)
2963 AC_SUBST(LD_FOR_BUILD)
2964 AC_SUBST(NM_FOR_BUILD)
2965 AC_SUBST(RANLIB_FOR_BUILD)
2966 AC_SUBST(WINDMC_FOR_BUILD)
2967 AC_SUBST(WINDRES_FOR_BUILD)
2968
2969 # Generate default definitions for YACC, M4, LEX and other programs that run
2970 # on the build machine.  These are used if the Makefile can't locate these
2971 # programs in objdir.
2972 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2973
2974 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2975 case " $build_configdirs " in
2976   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2977 esac
2978
2979 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2980 case " $build_configdirs " in
2981   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2982 esac
2983
2984 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2985 case " $build_configdirs " in
2986   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2987 esac
2988
2989 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2990 case " $build_configdirs " in
2991   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2992   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2993 esac
2994
2995 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2996 case " $build_configdirs " in
2997   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2998 esac
2999
3000 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3001 case " $build_configdirs " in
3002   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3003   *)
3004 changequote(,)
3005     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3006     # higher, else we use the "missing" dummy.
3007     if ${MAKEINFO} --version \
3008        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3009       :
3010     else
3011       MAKEINFO="$MISSING makeinfo"
3012     fi
3013     ;;
3014 changequote([,])
3015 esac
3016
3017 # FIXME: expect and dejagnu may become build tools?
3018
3019 AC_CHECK_PROGS(EXPECT, expect, expect)
3020 case " $configdirs " in
3021   *" expect "*)
3022     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3023     ;;
3024 esac
3025
3026 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3027 case " $configdirs " in
3028   *" dejagnu "*)
3029     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3030     ;;
3031 esac
3032
3033
3034 # Host tools.
3035 NCN_STRICT_CHECK_TOOLS(AR, ar)
3036 NCN_STRICT_CHECK_TOOLS(AS, as)
3037 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3038 NCN_STRICT_CHECK_TOOLS(LD, ld)
3039 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3040 NCN_STRICT_CHECK_TOOLS(NM, nm)
3041 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3042 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3043 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3044 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3045 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3046 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3047 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3048 AC_SUBST(CC)
3049 AC_SUBST(CXX)
3050 AC_SUBST(CFLAGS)
3051 AC_SUBST(CXXFLAGS)
3052
3053 # Target tools.
3054 AC_ARG_WITH([build-time-tools],
3055   [AS_HELP_STRING([--with-build-time-tools=PATH],
3056                   [use given path to find target tools during the build])],
3057   [case x"$withval" in
3058      x/*) ;;
3059      *)
3060        with_build_time_tools=
3061        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3062        ;;
3063    esac],
3064   [with_build_time_tools=])
3065
3066 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3067 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3068 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3069 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3070 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3071 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3072
3073 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3074 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3075 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3076 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3077 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3078 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3079 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3080 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3081 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3082 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3083 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3084 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3085
3086 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3087
3088 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3089 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3090 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3091 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3092 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3093                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3094                 c++)
3095 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3096                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3097                 c++)
3098 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3099 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3100 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3101                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3102 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3103                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3104 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3105                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3106 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3107 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3108 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3109 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3110 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3111 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3112 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3113 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3114 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3115
3116 AC_SUBST(FLAGS_FOR_TARGET)
3117 AC_SUBST(RAW_CXX_FOR_TARGET)
3118
3119 # Certain tools may need extra flags.
3120 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3121 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3122 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3123
3124 # When building target libraries, except in a Canadian cross, we use
3125 # the same toolchain as the compiler we just built.
3126 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3127 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3128 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3129 if test $host = $build; then
3130   case " $configdirs " in
3131     *" gcc "*)
3132       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3133       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3134       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3135       ;;
3136   esac
3137 fi
3138
3139 AC_SUBST(COMPILER_AS_FOR_TARGET)
3140 AC_SUBST(COMPILER_LD_FOR_TARGET)
3141 AC_SUBST(COMPILER_NM_FOR_TARGET)
3142
3143 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3144 AC_ARG_ENABLE(maintainer-mode,
3145 [AS_HELP_STRING([--enable-maintainer-mode],
3146                 [enable make rules and dependencies not useful
3147                  (and sometimes confusing) to the casual installer])],
3148       USE_MAINTAINER_MODE=$enableval,
3149       USE_MAINTAINER_MODE=no)
3150 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3151 AC_SUBST(MAINTAINER_MODE_TRUE)
3152 AC_SUBST(MAINTAINER_MODE_FALSE)
3153 if test "$USE_MAINTAINER_MODE" = yes; then
3154   MAINTAINER_MODE_TRUE=
3155   MAINTAINER_MODE_FALSE='#'
3156 else
3157   MAINTAINER_MODE_TRUE='#'
3158   MAINTAINER_MODE_FALSE=
3159 fi
3160 MAINT=$MAINTAINER_MODE_TRUE
3161 AC_SUBST(MAINT)dnl
3162
3163 # ---------------------
3164 # GCC bootstrap support
3165 # ---------------------
3166
3167 # Stage specific cflags for build.
3168 stage1_cflags="-g"
3169 case $build in
3170   vax-*-*)
3171     case ${GCC} in
3172       yes) stage1_cflags="-g -Wa,-J" ;;
3173       *) stage1_cflags="-g -J" ;;
3174     esac ;;
3175 esac
3176
3177 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3178 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3179   saved_CFLAGS="$CFLAGS"
3180
3181   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3182   CFLAGS="$CFLAGS -fkeep-inline-functions"
3183   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3184   AC_TRY_COMPILE([
3185 #if (__GNUC__ < 3) \
3186     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3187                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3188 #error http://gcc.gnu.org/PR29382
3189 #endif
3190     ],,
3191     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3192     [AC_MSG_RESULT([no])])
3193
3194   CFLAGS="$saved_CFLAGS"
3195 fi
3196
3197 AC_SUBST(stage1_cflags)
3198
3199 # Enable --enable-checking in stage1 of the compiler.
3200 AC_ARG_ENABLE(stage1-checking,
3201 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3202                 [choose additional checking for stage1 of the compiler])],
3203 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3204 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3205   stage1_checking=--enable-checking=yes,types
3206 else
3207   stage1_checking=--enable-checking=$enable_checking,types
3208 fi])
3209 AC_SUBST(stage1_checking)
3210
3211 # Enable -Werror in bootstrap stage2 and later.
3212 AC_ARG_ENABLE(werror,
3213 [AS_HELP_STRING([--enable-werror],
3214                 [enable -Werror in bootstrap stage2 and later])], [],
3215 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3216   enable_werror=yes
3217 else
3218   enable_werror=no
3219 fi])
3220 case ${enable_werror} in
3221   yes) stage2_werror_flag="--enable-werror-always" ;;
3222   *) stage2_werror_flag="" ;;
3223 esac
3224 AC_SUBST(stage2_werror_flag)
3225
3226 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3227 # --enable-build-with-cxx after stage1.
3228 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3229   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3230 else
3231   POSTSTAGE1_CONFIGURE_FLAGS=
3232 fi
3233 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3234
3235 # Specify what files to not compare during bootstrap.
3236
3237 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3238 case "$target" in
3239   hppa*64*-*-hpux*) ;;
3240   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3241 esac
3242 case " $configdirs " in
3243 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3244 esac
3245 AC_SUBST(compare_exclusions)
3246
3247 AC_CONFIG_FILES([Makefile],
3248   [sed "$extrasub_build" Makefile |
3249    sed "$extrasub_host" |
3250    sed "$extrasub_target" > mf$$
3251    mv -f mf$$ Makefile],
3252   [extrasub_build="$extrasub_build"
3253    extrasub_host="$extrasub_host"
3254    extrasub_target="$extrasub_target"])
3255 AC_OUTPUT