hw/mbl_Pkg.vhd

   1 ---------------------------------------------------------------------------------
   2 --
   3 --  Package:      mbl_Pkg
   4 --  Filename:     mbl_Pkg.vhd
   5 --  Description:  Package for the TUD MB-Lite implementation
   6 --
   7 --  Author:       Huib Lincklaen Arriens
   8 --                Delft University of Technology
   9 --                Faculty EEMCS, Department ME&CE, Circuits and Systems
  10 --  Date:         September, 2010
  11 --
  12 --  Modified:     September, 2013: Removed FSL, core customization
  13 --                     June, 2011: ALU_ACTION_Type extended to incorporate
  14 --                                 MUL and BS instructions (Huib)
  15 --                                 Adapted to work with separate fsl_M-
  16 --                                 and fsl_S selectors and automatic
  17 --                                 tumbl<_jtag><_fsl>.vhd generation (Huib)
  18 --                     July, 2011: function ef_nbits added (Huib)
  19 --  Remarks:
  20 --
  21 --------------------------------------------------------------------------------
  22
  23 LIBRARY IEEE;
  24 USE IEEE.std_logic_1164.all;
  25 USE IEEE.std_logic_unsigned.all;
  26 USE IEEE.numeric_std.all;
  27
  28 --------------------------------------------------------------------------------
  29 PACKAGE mbl_Pkg IS
  30 --------------------------------------------------------------------------------
  31
  32         CONSTANT  C_8_ZEROS : STD_LOGIC_VECTOR ( 7 DOWNTO 0) :=       X"00";
  33         CONSTANT C_16_ZEROS : STD_LOGIC_VECTOR (15 DOWNTO 0) :=     X"0000";
  34         CONSTANT C_24_ZEROS : STD_LOGIC_VECTOR (23 DOWNTO 0) :=   X"000000";
  35         CONSTANT C_32_ZEROS : STD_LOGIC_VECTOR (31 DOWNTO 0) := X"00000000";
  36
  37         CONSTANT C_16_ONES  : STD_LOGIC_VECTOR (15 DOWNTO 0) :=     X"FFFF";
  38         CONSTANT C_24_ONES  : STD_LOGIC_VECTOR (23 DOWNTO 0) :=   X"FFFFFF";
  39
  40
  41 ----------------------------------------------------------------------------------------------
  42 -- TYPE DEFINITIONS
  43 ----------------------------------------------------------------------------------------------
  44
  45         TYPE ALU_ACTION_Type    IS (A_NOP, A_ADD, A_CMP, A_CMPU, A_OR, A_AND, A_XOR,
  46                                                                                                                         A_SHIFT, A_SEXT8, A_SEXT16, A_MFS, A_MTS, A_MUL,
  47                                                                                                                         A_BSLL, A_BSRL, A_BSRA);
  48         TYPE ALU_IN1_Type       IS (ALU_IN_REGA, ALU_IN_NOT_REGA, ALU_IN_PC, ALU_IN_ZERO);
  49         TYPE ALU_IN2_Type       IS (ALU_IN_REGB, ALU_IN_NOT_REGB, ALU_IN_IMM, ALU_IN_NOT_IMM);
  50         TYPE ALU_CIN_Type       IS (CIN_ZERO, CIN_ONE, FROM_MSR, FROM_IN1);
  51         TYPE MSR_ACTION_Type    IS (UPDATE_CARRY, KEEP_CARRY);
  52         TYPE BRANCH_ACTION_Type IS (NO_BR, BR, BRL);
  53         TYPE IT_ACTION_Type     IS (NO_IT, IT, ITT, ITE);
  54         TYPE WRB_ACTION_Type    IS (NO_WRB, WRB_EX, WRB_MEM);
  55         TYPE MEM_ACTION_Type    IS (NO_MEM, WR_MEM, RD_MEM);
  56         TYPE TRANSFER_SIZE_Type IS (WORD, HALFWORD, BYTE);
  57         TYPE SAVE_REG_Type      IS (NO_SAVE, SAVE_RA, SAVE_RB);
  58         TYPE COND_Type          IS (COND_ALL, COND_EQ, COND_NE, COND_LT, COND_LE, COND_GT, COND_GE);
  59         --
  60         TYPE IF2ID_Type IS RECORD
  61                 program_counter : STD_LOGIC_VECTOR (31 DOWNTO 0);
  62         END RECORD;
  63
  64         TYPE ID2EX_Type IS RECORD
  65                 program_counter  : STD_LOGIC_VECTOR (31 DOWNTO 0);
  66                 rdix_rA          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  67                 rdix_rB          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  68                 curr_rD          : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  69                 alu_Action       : ALU_ACTION_Type;
  70                 alu_Op1          : ALU_IN1_Type;
  71                 alu_Op2          : ALU_IN2_Type;
  72                 alu_Cin          : ALU_CIN_Type;
  73                 IMM16            : STD_LOGIC_VECTOR (15 DOWNTO 0);
  74                 IMM_Lock         : STD_LOGIC;
  75                 msr_Action       : MSR_ACTION_Type;
  76                 branch_Action    : BRANCH_ACTION_Type;
  77                 it_Action        : IT_ACTION_Type;
  78                 mem_Action       : MEM_ACTION_Type;         -- rd_mem implies writeback
  79                 transfer_Size    : TRANSFER_SIZE_Type;
  80                 wrb_Action       : WRB_ACTION_Type;
  81                 condition        : COND_Type;
  82                 halt             : STD_LOGIC;
  83         END RECORD;
  84
  85         TYPE ID2GPRF_Type IS RECORD
  86                 rdix_rA : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  87                 rdix_rB : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  88                 rdix_rD : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
  89         END RECORD;
  90
  91         TYPE INT_CTRL_Type IS RECORD
  92                 setup_int  : STD_LOGIC;
  93                 rti_target : STD_LOGIC_VECTOR (31 DOWNTO 0);
  94                 int_busy   : STD_LOGIC;
  95         END RECORD;
  96
  97         TYPE ID2CTRL_Type IS RECORD
  98                 delayBit : STD_LOGIC;
  99                 int_busy : STD_LOGIC;
 100         END RECORD;
 101
 102         TYPE GPRF2EX_Type IS RECORD
 103                 data_rA : STD_LOGIC_VECTOR (31 DOWNTO 0);
 104                 data_rB : STD_LOGIC_VECTOR (31 DOWNTO 0);
 105                 data_rD : STD_LOGIC_VECTOR (31 DOWNTO 0);
 106         END RECORD;
 107
 108         TYPE IMM_LOCK_Type IS RECORD
 109                 locked   : STD_LOGIC;
 110                 IMM_hi16 : STD_LOGIC_VECTOR (15 DOWNTO 0);
 111         END RECORD;
 112
 113         TYPE MSR_Type IS RECORD
 114                 IE  : STD_LOGIC;        -- MSR[VHDL b1] = [MicroBlaze b30]
 115                 C   : STD_LOGIC;        -- MSR[VHDL b2 and b31] = [MicroBlaze b29 and b0]
 116         END RECORD;
 117
 118         TYPE EX2IF_Type IS RECORD
 119                 take_branch   : STD_LOGIC;
 120                 branch_target : STD_LOGIC_VECTOR (31 DOWNTO 0);
 121         END RECORD;
 122
 123         TYPE EX2CTRL_Type IS RECORD
 124                 flush_first       : STD_LOGIC;
 125                 flush_second      : STD_LOGIC;
 126                 ignore_state      : STD_LOGIC;
 127         END RECORD;
 128
 129         TYPE HALT_Type IS RECORD
 130                 halt          : STD_LOGIC;
 131                 halt_code     : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 132         END RECORD;
 133
 134         TYPE EX2MEM_Type IS RECORD
 135                 mem_Action      : MEM_ACTION_Type;                  -- RD_MEM implies writeback
 136                 wrb_Action      : WRB_ACTION_Type;
 137                 exeq_result     : STD_LOGIC_VECTOR (31 DOWNTO 0);
 138                 data_rD         : STD_LOGIC_VECTOR (31 DOWNTO 0);
 139                 byte_Enable     : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 140                 wrix_rD         : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 141         END RECORD;
 142
 143         TYPE WRB_Type IS RECORD
 144                 wrb_Action : WRB_ACTION_Type;
 145                 wrix_rD    : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 146                 data_rD    : STD_LOGIC_VECTOR (31 DOWNTO 0);
 147         END RECORD;
 148
 149         TYPE HAZARD_WRB_Type IS RECORD
 150                 hazard  : STD_LOGIC;
 151                 save_rX : SAVE_REG_Type;
 152                 data_rX : STD_LOGIC_VECTOR (31 DOWNTO 0);
 153                 data_rD : STD_LOGIC_VECTOR (31 DOWNTO 0);
 154         END RECORD;
 155
 156         TYPE MEM_REG_Type IS RECORD
 157                 wrb_Action  : WRB_ACTION_Type;
 158                 exeq_result : STD_LOGIC_VECTOR (31 DOWNTO 0);
 159                 byte_Enable : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 160                 wrix_rD     : STD_LOGIC_VECTOR ( 4 DOWNTO 0);
 161         END RECORD;
 162
 163         TYPE MEM2CTRL_Type IS RECORD
 164                 clken : STD_LOGIC;
 165                 int   : STD_LOGIC;
 166         END RECORD;
 167
 168         TYPE CORE2DMEMB_Type IS RECORD
 169                 ena   : STD_LOGIC;
 170                 addr  : STD_LOGIC_VECTOR (31 DOWNTO 0);
 171                 bSel  : STD_LOGIC_VECTOR ( 3 DOWNTO 0);
 172                 wre   : STD_LOGIC;
 173                 data  : STD_LOGIC_VECTOR (31 DOWNTO 0);
 174         END RECORD;
 175
 176         TYPE DMEMB2CORE_Type IS RECORD
 177                 clken : STD_LOGIC;
 178                 data  : STD_LOGIC_VECTOR (31 DOWNTO 0);
 179                 int   : STD_LOGIC;
 180         END RECORD;
 181
 182         TYPE MEMORY_MAP_Type IS ARRAY(NATURAL RANGE <>) OF STD_LOGIC_VECTOR (31 DOWNTO 0);
 183         -- NOTE: Use the named association format  xxxx := ( 0 => X"A0010000" );
 184         --       in case the array has to contain only one element !!
 185
 186 ----------------------------------------------------------------------------------------------
 187 -- COMPONENTS
 188 ----------------------------------------------------------------------------------------------
 189
 190         COMPONENT fetch IS
 191         PORT
 192         (
 193                 prog_cntr_i :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 194                 inc_pc_i    :  IN STD_LOGIC;
 195                 EX2IF_i     :  IN EX2IF_Type;
 196                 IF2ID_o     : OUT IF2ID_Type
 197         );
 198         END COMPONENT;
 199
 200         COMPONENT decode IS
 201         GENERIC
 202         (
 203                 USE_HW_MUL_g : BOOLEAN := TRUE;
 204                 USE_BARREL_g : BOOLEAN := TRUE;
 205                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 206         );
 207         PORT
 208         (
 209                 IF2ID_i     :  IN IF2ID_Type;
 210                 imem_data_i :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 211                 --
 212                 ID2GPRF_o   : OUT ID2GPRF_Type;
 213                 ID2EX_o     : OUT ID2EX_Type;
 214                 --
 215                 INT_CTRL_i  :  IN INT_CTRL_Type;
 216                 ID2CTRL_o   : OUT ID2CTRL_Type;
 217                 --
 218                 noLiteOpc_o : OUT STD_LOGIC
 219         );
 220         END COMPONENT;
 221
 222         COMPONENT exeq IS
 223         GENERIC
 224         (
 225                 USE_HW_MUL_g : BOOLEAN := FALSE;
 226                 USE_BARREL_g : BOOLEAN := FALSE;
 227                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 228         );
 229         PORT
 230         (
 231                 ID2EX_i      :  IN ID2EX_Type;
 232                 GPRF2EX_i    :  IN GPRF2EX_Type;
 233                 EX2IF_o      : OUT EX2IF_Type;
 234                 EX2CTRL_o    : OUT EX2CTRL_Type;
 235                 HALT_o       : OUT HALT_Type;
 236                 --
 237                 EX_WRB_i     :  IN WRB_Type;
 238                 EX_WRB_o     : OUT WRB_Type;
 239                 MEM_WRB_i    :  IN WRB_Type;
 240                 --
 241                 HAZARD_WRB_i :  IN HAZARD_WRB_Type;
 242                 HAZARD_WRB_o : OUT HAZARD_WRB_Type;
 243                 --
 244                 IMM_LOCK_i   :  IN IMM_LOCK_Type;
 245                 IMM_LOCK_o   : OUT IMM_LOCK_Type;
 246                 --
 247                 MSR_i        :  IN MSR_Type;
 248                 MSR_o        : OUT MSR_Type;
 249                 --
 250                 EX2MEM_o     : OUT EX2MEM_Type
 251         );
 252         END COMPONENT;
 253
 254         COMPONENT mem IS
 255         PORT
 256         (
 257                 EX2MEM_i    :  IN EX2MEM_Type;
 258                 --
 259                 DMEMB_i     :  IN DMEMB2CORE_Type;
 260                 DMEMB_o     : OUT CORE2DMEMB_Type;
 261                 --
 262                 MEM_REG_i   :  IN MEM_REG_Type;
 263                 MEM_REG_o   : OUT MEM_REG_Type;
 264                 --
 265                 MEM_WRB_o   : OUT WRB_Type;
 266                 MEM2CTRL_o  : OUT MEM2CTRL_Type
 267         );
 268         END COMPONENT;
 269
 270         COMPONENT core_ctrl IS
 271         GENERIC
 272         (
 273                 COMPATIBILITY_MODE_g : BOOLEAN := FALSE
 274         );
 275         PORT
 276         (
 277                 clk_i           :  IN STD_LOGIC;
 278                 rst_i           :  IN STD_LOGIC;
 279                 halt_i          :  IN STD_LOGIC;
 280                 bad_op_i        :  IN STD_LOGIC;
 281                 int_i           :  IN STD_LOGIC;
 282                 trace_i         :  IN STD_LOGIC;
 283                 trace_kick_i    :  IN STD_LOGIC;
 284                 core_clken_o    : OUT STD_LOGIC;
 285                 -- specific fetch i/o
 286                 imem_addr_o     : OUT STD_LOGIC_VECTOR (31 DOWNTO 0);
 287                 imem_clken_o    : OUT STD_LOGIC;
 288                 pc_ctrl_o       : OUT STD_LOGIC;
 289                 -- fetch to decode pipeline registers
 290                 IF2ID_REG_i     :  IN IF2ID_Type;
 291                 IF2ID_REG_o     : OUT IF2ID_Type;
 292                 -- decode to exeq pipeline registers
 293                 ID2EX_REG_i     :  IN ID2EX_Type;
 294                 ID2EX_REG_o     : OUT ID2EX_Type;
 295                 -- GPRF control
 296                 gprf_clken_o    : OUT STD_LOGIC;
 297                 -- exeq to fetch feedback registers
 298                 EX2IF_REG_i     :  IN EX2IF_Type;
 299                 EX2IF_REG_o     : OUT EX2IF_Type;
 300                 EX2CTRL_REG_i   :  IN EX2CTRL_Type;
 301                 -- exeq to core (halting)
 302                 exeq_halt_i     :  IN STD_LOGIC;
 303                 -- exeq to mem pipeline registers
 304                 EX2MEM_REG_i    :  IN EX2MEM_Type;
 305                 EX2MEM_REG_o    : OUT EX2MEM_Type;
 306                 -- mem pipeline register
 307                 MEM_REG_i       :  IN MEM_REG_Type;
 308                 MEM_REG_o       : OUT MEM_REG_Type;
 309                 -- decode control i/o
 310                 ID2CTRL_i       :  IN ID2CTRL_Type;
 311                 INT_CTRL_o      : OUT INT_CTRL_Type;
 312                 -- exeq control i/o
 313                 EX_WRB_i        :  IN WRB_Type;
 314                 EX_WRB_o        : OUT WRB_Type;
 315                 -- data hazard i/o
 316                 HAZARD_WRB_i    :  IN HAZARD_WRB_Type;
 317                 HAZARD_WRB_o    : OUT HAZARD_WRB_Type;
 318                 -- for handling the 'IMM' instruction
 319                 IMM_LOCK_i      :  IN IMM_LOCK_Type;
 320                 IMM_LOCK_o      : OUT IMM_LOCK_Type;
 321                 -- for handling the Machine Status Register
 322                 MSR_i           :  IN MSR_Type;
 323                 MSR_o           : OUT MSR_Type;
 324                 -- miscellaneous
 325                 MEM2CTRL_i      :  IN MEM2CTRL_Type
 326         );
 327         END COMPONENT;
 328
 329 ----------------------------------------------------------------------------------------------
 330 -- FUNCTION, PROCEDURE DECLARATIONS
 331 ----------------------------------------------------------------------------------------------
 332
 333         PROCEDURE ep_add32 (    a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 334                                                                                                 ci   :  IN STD_LOGIC;
 335                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0);
 336                                                                                         VARIABLE co : OUT STD_LOGIC );
 337
 338         PROCEDURE ep_add32nc (  a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 339                                                                                                         ci   :  IN STD_LOGIC;
 340                                                                                                 VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0));
 341
 342         FUNCTION ef_nbits ( value : NATURAL ) RETURN POSITIVE;
 343
 344 END PACKAGE mbl_Pkg;
 345
 346 ----------------------------------------------------------
 347 PACKAGE BODY mbl_Pkg IS
 348 ----------------------------------------------------------
 349
 350         PROCEDURE ep_add32 (    a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 351                                                                                                 ci   :  IN STD_LOGIC;
 352                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0);
 353                                                                                         VARIABLE co : OUT STD_LOGIC ) IS
 354
 355                 CONSTANT NBITS_LO_c : POSITIVE := 17;
 356                 CONSTANT NBITS_HI_c : POSITIVE := 32 -NBITS_LO_c;
 357                 VARIABLE tmp_lo_v   : STD_LOGIC_VECTOR (NBITS_LO_c +1 DOWNTO 0);
 358                 VARIABLE tmp_hi0_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 359                 VARIABLE tmp_hi1_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 360         BEGIN
 361                 tmp_lo_v  := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(NBITS_LO_c -1 DOWNTO  0) & '1' ) +
 362                                                                                                                                                 UNSIGNED( '0' & b(NBITS_LO_c -1 DOWNTO  0) & ci  ));
 363                 tmp_hi0_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 364                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '0'));
 365                 tmp_hi1_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 366                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '1'));
 367                 IF (tmp_lo_v(NBITS_LO_c +1) = '0') THEN
 368                         s  := tmp_hi0_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 369                         co := tmp_hi0_v(NBITS_HI_c +1);
 370                 ELSE
 371                         s  := tmp_hi1_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 372                         co := tmp_hi1_v(NBITS_HI_c +1);
 373                 END IF;
 374         END PROCEDURE;
 375
 376     PROCEDURE ep_add32nc (      a, b :  IN STD_LOGIC_VECTOR (31 DOWNTO 0);
 377                                                                                                                 ci   :  IN STD_LOGIC;
 378                                                                                                         VARIABLE s  : OUT STD_LOGIC_VECTOR (31 DOWNTO 0) ) IS
 379
 380                 CONSTANT NBITS_LO_c : POSITIVE := 17;
 381                 CONSTANT NBITS_HI_c : POSITIVE := 32 -NBITS_LO_c;
 382                 VARIABLE tmp_lo_v   : STD_LOGIC_VECTOR (NBITS_LO_c +1 DOWNTO 0);
 383                 VARIABLE tmp_hi0_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 384                 VARIABLE tmp_hi1_v  : STD_LOGIC_VECTOR (NBITS_HI_c +1 DOWNTO 0);
 385         BEGIN
 386                 tmp_lo_v  := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(NBITS_LO_c -1 DOWNTO  0) & '1' ) +
 387                                                                                                                                                 UNSIGNED( '0' & b(NBITS_LO_c -1 DOWNTO  0) & ci  ));
 388                 tmp_hi0_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 389                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '0'));
 390                 tmp_hi1_v := STD_LOGIC_VECTOR(  UNSIGNED( '0' & a(31 DOWNTO (32 - NBITS_HI_c)) & '1') +
 391                                                                                                                                                 UNSIGNED( '0' & b(31 DOWNTO (32 - NBITS_HI_c)) & '1'));
 392                 IF (tmp_lo_v(NBITS_LO_c +1) = '0') THEN
 393                         s  := tmp_hi0_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 394                 ELSE
 395                         s  := tmp_hi1_v(NBITS_HI_c DOWNTO 1) & tmp_lo_v(NBITS_LO_c DOWNTO 1);
 396                 END IF;
 397         END PROCEDURE;
 398
 399
 400         FUNCTION ef_nbits( value : NATURAL ) RETURN POSITIVE IS
 401                 VARIABLE temp_v : POSITIVE;
 402         BEGIN
 403                 temp_v := 1;
 404                 FOR i IN 1 TO INTEGER'HIGH LOOP
 405                         temp_v := 2*temp_v;
 406                         IF (temp_v > value) THEN
 407                                 RETURN i;
 408                         END IF;
 409                 END LOOP;
 410                 RETURN 32;
 411         END FUNCTION;
 412
 413 END PACKAGE BODY mbl_Pkg;