hw/lx_rocon_top.vhd

   1 library ieee;
   2 use ieee.std_logic_1164.all;
   3 use ieee.std_logic_arith.all;
   4 use ieee.std_logic_unsigned.all;
   5 use ieee.numeric_std.all;
   6
   7 library unisim;
   8 use unisim.vcomponents.all;
   9
  10 use work.mbl_pkg.all;
  11 use work.lx_rocon_pkg.all;
  12
  13 -- lx_rocon_top - wires the modules with the outside world
  14
  15 -- ======================================================
  16 --  MASTER CPU EXTERNAL MEMORY BUS
  17 -- ======================================================
  18 --
  19 -- Master cpu memory bus has the following wires:
  20 --
  21 -- - address[15..0]          The address, used to mark chip enable
  22 -- - data_in[31..0]          The data coming to bus
  23 -- - data_out[31..0]         The data coming from bus, multiplexed
  24 -- - bls[3..0]               Write enable for respective bytes
  25
  26 entity lx_rocon_top is
  27         port
  28         (
  29                 -- External
  30                 --clk_cpu     : in std_logic;
  31                 clk_50m     : in std_logic;
  32                 --
  33                 cs0_xc      : in std_logic;
  34                 --
  35                 rd          : in std_logic;
  36                 bls         : in std_logic_vector(3 downto 0);
  37                 address     : in std_logic_vector(15 downto 0);
  38                 data        : inout std_logic_vector(31 downto 0);
  39                 --
  40                 irc0_a      : in std_logic;
  41                 irc0_b      : in std_logic;
  42                 irc0_index  : in std_logic;
  43                 irc0_mark   : in std_logic;
  44                 --
  45                 irc1_a      : in std_logic;
  46                 irc1_b      : in std_logic;
  47                 irc1_index  : in std_logic;
  48                 irc1_mark   : in std_logic;
  49                 --
  50                 irc2_a      : in std_logic;
  51                 irc2_b      : in std_logic;
  52                 irc2_index  : in std_logic;
  53                 irc2_mark   : in std_logic;
  54                 --
  55                 irc3_a      : in std_logic;
  56                 irc3_b      : in std_logic;
  57                 irc3_index  : in std_logic;
  58                 irc3_mark   : in std_logic;
  59                 --
  60                 irc4_a      : in std_logic;
  61                 irc4_b      : in std_logic;
  62                 irc4_index  : in std_logic;
  63                 irc4_mark   : in std_logic;
  64                 --
  65                 irc5_a      : in std_logic;
  66                 irc5_b      : in std_logic;
  67                 irc5_index  : in std_logic;
  68                 irc5_mark   : in std_logic;
  69                 --
  70                 irc6_a      : in std_logic;
  71                 irc6_b      : in std_logic;
  72                 irc6_index  : in std_logic;
  73                 irc6_mark   : in std_logic;
  74                 --
  75                 irc7_a      : in std_logic;
  76                 irc7_b      : in std_logic;
  77                 irc7_index  : in std_logic;
  78                 irc7_mark   : in std_logic;
  79                 --
  80                 init        : in std_logic;
  81                 --
  82                 s1_clk_in   : in std_logic;
  83                 s1_miso     : in std_logic;
  84                 s1_sync_in  : in std_logic;
  85                 --
  86                 s1_clk_out  : out std_logic;
  87                 s1_mosi     : out std_logic;
  88                 s1_sync_out : out std_logic
  89         );
  90 end lx_rocon_top;
  91
  92 architecture Behavioral of lx_rocon_top is
  93
  94         -- Reset signal
  95         signal reset_s                  : std_logic;
  96         signal init_s                   : std_logic;
  97         -- Peripherals on the memory buses
  98         -- Master to Tumbl DMEM / IMEM (Master)
  99         signal tumbl_out_s              : std_logic_vector(31 downto 0);
 100         signal tumbl_ce_s               : std_logic;
 101         -- Measurement (Master)
 102         signal meas_out_s               : std_logic_vector(31 downto 0);
 103         signal meas_ce_s                : std_logic;
 104         -- Master to Tumbl XMEM
 105         signal master_tumbl_xmem_out_s  : std_logic_vector(31 downto 0);
 106         signal master_tumbl_xmem_ce_s   : std_logic;
 107         signal master_tumbl_xmem_lock_s : std_logic;
 108         -- IRC (Tumbl)
 109         signal irc_proc_out_s            : std_logic_vector(31 downto 0);
 110         signal irc_proc_ce_s             : std_logic;
 111         signal irc_proc_next_ce_s        : std_logic;
 112         -- LX Master (Tumbl)
 113         signal lxmaster_out_s           : std_logic_vector(15 downto 0);
 114         signal lxmaster_ce_s            : std_logic;
 115         signal lxmaster_next_ce_s       : std_logic;
 116         -- Signals for external bus transmission
 117         signal data_i_s                 : std_logic_vector(31 downto 0);
 118         signal data_o_s                 : std_logic_vector(31 downto 0);
 119         -- Signals for internal transaction
 120         signal last_address_s           : std_logic_vector(15 downto 0);
 121         signal next_last_address_s      : std_logic_vector(15 downto 0);
 122         signal next_address_hold_s      : std_logic;
 123         signal address_hold_s           : std_logic;
 124         signal last_rd_s                : std_logic;
 125         signal next_last_rd_s           : std_logic;
 126         signal last_bls_s               : std_logic_vector(3 downto 0); -- prev bls_f_s (active 1)
 127         signal next_last_bls_s          : std_logic_vector(3 downto 0);
 128
 129         -- Reading logic for Master CPU:
 130         -- Broadcast rd only till ta (transaction acknowledge)
 131         -- is received, then latch the data till the state of
 132         -- rd or address changes
 133         --
 134         -- Data latching is synchronous - it's purpose is to
 135         -- provide stable data for CPU on the bus
 136         signal cs0_xc_f_s          : std_logic;
 137         signal rd_f_s              : std_logic; -- Filtered RD
 138         signal i_rd_s              : std_logic; -- Internal bus RD (active 1)
 139         -- signal next_i_rd_s         : std_logic;
 140         signal last_i_rd_s         : std_logic; -- Delayed RD bus, used for latching
 141         signal next_last_i_rd_s    : std_logic;
 142         signal i_rd_cycle2_s       : std_logic; -- Some internal subsystems provide
 143         signal next_i_rd_cycle2_s  : std_logic; -- data only after 2 cycles
 144         --
 145         signal address_f_s         : std_logic_vector(15 downto 0); -- Filtered address
 146         --
 147         signal data_f_s            : std_logic_vector(31 downto 0); -- Filterred input data
 148         --
 149         signal data_read_s         : std_logic_vector(31 downto 0); -- Latched read data
 150         signal next_data_read_s    : std_logic_vector(31 downto 0);
 151
 152         -- Writing logic:
 153         signal bls_f_s             : std_logic_vector(3 downto 0); -- Filtered BLS (active 1)
 154         signal i_bls_s             : std_logic_vector(3 downto 0); -- Internal BLS (active 1)
 155         signal next_i_bls_s        : std_logic_vector(3 downto 0);
 156         --
 157         signal data_write_s        : std_logic_vector(31 downto 0); -- Data broadcasted to write
 158         signal next_data_write_s   : std_logic_vector(31 downto 0);
 159
 160         -- Tumbl:
 161         signal tumbl_bls_s         : std_logic_vector(3 downto 0);
 162         signal tumbl_address_s     : std_logic_vector(14 downto 0);
 163         signal tumbl_data_i_s      : std_logic_vector(31 downto 0);
 164         --
 165         signal tumbl_xmemb_o_s     : CORE2DMEMB_Type;
 166         signal tumbl_xmemb_i_s     : DMEMB2CORE_Type;
 167         signal tumbl_xmemb_sel_s   : std_logic;
 168
 169         -- XST attributes
 170         attribute REGISTER_DUPLICATION : string;
 171         attribute REGISTER_DUPLICATION of rd : signal is "NO";
 172         attribute REGISTER_DUPLICATION of rd_f_s : signal is "NO";
 173         attribute REGISTER_DUPLICATION of bls : signal is "NO";
 174         attribute REGISTER_DUPLICATION of bls_f_s : signal is "NO";
 175         attribute REGISTER_DUPLICATION of address : signal is "NO";
 176         attribute REGISTER_DUPLICATION of address_f_s : signal is "NO";
 177         attribute REGISTER_DUPLICATION of cs0_xc : signal is "NO";
 178
 179 begin
 180
 181 -- Tumbl coprocessor
 182 memory_bus_tumbl: bus_tumbl
 183         port map
 184         (
 185                 clk_i          => clk_50m,
 186                 reset_i        => reset_s,
 187                 ce_i           => tumbl_ce_s,
 188                 bls_i          => i_bls_s,
 189                 address_i      => address_f_s(11 downto 0),
 190                 data_i         => data_i_s,
 191                 data_o         => tumbl_out_s,
 192                 --
 193                 xmemb_o        => tumbl_xmemb_o_s,
 194                 xmemb_i        => tumbl_xmemb_i_s,
 195                 xmemb_sel_o    => tumbl_xmemb_sel_s
 196         );
 197
 198 -- Measurement
 199 memory_bus_measurement: bus_measurement
 200         port map
 201         (
 202                 clk_i     => clk_50m,
 203                 reset_i   => reset_s,
 204                 ce_i      => meas_ce_s,
 205                 address_i => address_f_s(1 downto 0),
 206                 bls_i     => i_bls_s,
 207                 data_i    => data_i_s,
 208                 data_o    => meas_out_s
 209         );
 210
 211 -- IRC interconnect
 212 memory_bus_irc: bus_irc
 213         port map
 214         (
 215                 reset_i        => reset_s,
 216                 --
 217                 clk_i          => clk_50m,
 218                 address_i      => tumbl_address_s(4 downto 0),
 219                 next_ce_i      => irc_proc_next_ce_s,
 220                 data_i         => tumbl_data_i_s,
 221                 data_o         => irc_proc_out_s,
 222                 bls_i          => tumbl_bls_s,
 223                 --
 224                 irc_i(0).a     => irc0_a,
 225                 irc_i(0).b     => irc0_b,
 226                 irc_i(0).index => irc0_index,
 227                 irc_i(0).mark  => irc0_mark,
 228                 --
 229                 irc_i(1).a     => irc1_a,
 230                 irc_i(1).b     => irc1_b,
 231                 irc_i(1).index => irc1_index,
 232                 irc_i(1).mark  => irc1_mark,
 233                 --
 234                 irc_i(2).a     => irc2_a,
 235                 irc_i(2).b     => irc2_b,
 236                 irc_i(2).index => irc2_index,
 237                 irc_i(2).mark  => irc2_mark,
 238                 --
 239                 irc_i(3).a     => irc3_a,
 240                 irc_i(3).b     => irc3_b,
 241                 irc_i(3).index => irc3_index,
 242                 irc_i(3).mark  => irc3_mark,
 243                 --
 244                 irc_i(4).a     => irc4_a,
 245                 irc_i(4).b     => irc4_b,
 246                 irc_i(4).index => irc4_index,
 247                 irc_i(4).mark  => irc4_mark,
 248                 --
 249                 irc_i(5).a     => irc5_a,
 250                 irc_i(5).b     => irc5_b,
 251                 irc_i(5).index => irc5_index,
 252                 irc_i(5).mark  => irc5_mark,
 253                 --
 254                 irc_i(6).a     => irc6_a,
 255                 irc_i(6).b     => irc6_b,
 256                 irc_i(6).index => irc6_index,
 257                 irc_i(6).mark  => irc6_mark,
 258                 --
 259                 irc_i(7).a     => irc7_a,
 260                 irc_i(7).b     => irc7_b,
 261                 irc_i(7).index => irc7_index,
 262                 irc_i(7).mark  => irc7_mark
 263         );
 264
 265 -- LX Master
 266 memory_bus_lxmaster: bus_lxmaster
 267         port map
 268         (
 269                 reset_i        => reset_s,
 270                 --
 271                 clk_i          => clk_50m,
 272                 address_i      => tumbl_address_s(10 downto 0),
 273                 next_ce_i      => lxmaster_next_ce_s,
 274                 data_i         => tumbl_data_i_s(15 downto 0),
 275                 data_o         => lxmaster_out_s,
 276                 bls_i          => tumbl_bls_s(1 downto 0),
 277                 --
 278                 clock_i        => s1_clk_in,
 279                 miso_i         => s1_miso,
 280                 sync_i         => s1_sync_in,
 281                 --
 282                 clock_o        => s1_clk_out,
 283                 mosi_o         => s1_mosi,
 284                 sync_o         => s1_sync_out
 285         );
 286
 287 -- Reset
 288 dff_reset: dff2
 289         port map
 290         (
 291                 clk_i   => clk_50m,
 292                 d_i     => init_s,
 293                 q_o     => reset_s
 294         );
 295
 296         -- Reset
 297         init_s          <= not init;
 298
 299         -- Signalling
 300         data_i_s        <= data_write_s;
 301
 302         -- Tumbl
 303         tumbl_bls_s     <= i_bls_s when (master_tumbl_xmem_lock_s = '1')
 304                            else tumbl_xmemb_o_s.bls when (tumbl_xmemb_sel_s = '1')
 305                            else "0000";
 306         tumbl_address_s <= address_f_s(14 downto 0) when (master_tumbl_xmem_lock_s = '1')
 307                            else tumbl_xmemb_o_s.addr when (tumbl_xmemb_sel_s = '1')
 308                            else (others => '0');
 309         tumbl_data_i_s  <= data_i_s when (master_tumbl_xmem_lock_s = '1')
 310                            else tumbl_xmemb_o_s.data when (tumbl_xmemb_sel_s = '1')
 311                            else (others => '0');
 312         --
 313         tumbl_xmemb_i_s.int <= '0'; -- No interrupt
 314         -- Enable clken only when available for Tumbl
 315         tumbl_xmemb_i_s.clken <= not master_tumbl_xmem_lock_s;
 316
 317
 318 -- Bus update
 319 memory_bus_logic:
 320         process(cs0_xc_f_s, rd_f_s, last_rd_s, i_rd_cycle2_s, last_i_rd_s,
 321                 bls_f_s, last_bls_s, data_f_s, data_write_s,
 322                 data_o_s, data_read_s, last_address_s, address_f_s)
 323         begin
 324                 -- Defaults
 325                 next_i_rd_cycle2_s <= '0';
 326                 next_address_hold_s <= '0';
 327
 328                 -- Check if we have chip select
 329                 if cs0_xc_f_s = '1' then
 330
 331                         -- Reading
 332                         if rd_f_s = '1' then
 333                                 -- Internal read
 334                                 if last_rd_s = '0' or (last_address_s /= address_f_s) then
 335                                         i_rd_s <= '1';
 336                                         next_i_rd_cycle2_s <= '1';
 337                                         next_last_i_rd_s  <= '1';
 338                                 elsif i_rd_cycle2_s = '1' then    -- FIXME it seems that some internal
 339                                         i_rd_s <= '1';            -- peripherals demands 2 cycles to read
 340                                         next_last_i_rd_s  <= '1';
 341                                 else
 342                                         i_rd_s            <= '0';
 343                                         next_last_i_rd_s  <= '0';
 344                                 end if;
 345
 346                                 if last_i_rd_s = '1' then
 347                                         -- Latch data we just read - they are valid in this cycle
 348                                         next_data_read_s <= data_o_s;
 349                                 else
 350                                         next_data_read_s <= data_read_s;
 351                                 end if;
 352                         else
 353                         --      -- Not reading, anything goes
 354                         --      data_read_s       <= (others => 'X');
 355                                 next_data_read_s  <= data_read_s;
 356                                 i_rd_s            <= '0';
 357                                 next_last_i_rd_s  <= '0';
 358                         end if;
 359
 360                         next_last_rd_s            <= rd_f_s;
 361
 362                         -- Data for write are captured only when BLS signals are stable
 363                         if bls_f_s /= "0000" then
 364                                 next_data_write_s <= data_f_s;
 365                                 next_address_hold_s <= '1';
 366                         else
 367                                 next_data_write_s <= data_write_s;
 368                         end if;
 369
 370                         if (bls_f_s /= "0000") or (rd_f_s = '1') then
 371                                 next_last_address_s <= address_f_s;
 372                         else
 373                                 next_last_address_s <= last_address_s;
 374                         end if;
 375                 else
 376                         next_last_rd_s <= '0';
 377                         i_rd_s <= '0';
 378                         next_last_i_rd_s <= '0';
 379
 380                         next_i_bls_s <= "0000";
 381                         next_data_write_s <= data_write_s;
 382                         next_data_read_s  <= data_read_s;
 383                         next_last_address_s <= last_address_s;
 384                 end if;
 385
 386                 -- Data for write are captured at/before BLS signals are negated
 387                 -- and actual write cycle takes place exacly after BLS negation
 388                 if ((last_bls_s and not bls_f_s) /= "0000") or
 389                     ((last_bls_s /= "0000") and (cs0_xc_f_s = '0')) then
 390                         next_i_bls_s <= last_bls_s;
 391                         next_last_bls_s   <= "0000";
 392                         next_address_hold_s <= '1';
 393                 else
 394                         next_i_bls_s <= "0000";
 395                         if cs0_xc_f_s = '1' then
 396                                 next_last_bls_s <= bls_f_s;
 397                         else
 398                                 next_last_bls_s <= "0000" ;
 399                         end if;
 400                 end if;
 401
 402         end process;
 403
 404 -- Bus update
 405 memory_bus_update:
 406         process
 407         begin
 408
 409                 wait until clk_50m = '1' and clk_50m'event;
 410
 411                 address_hold_s <= next_address_hold_s;
 412
 413                 -- Synchronized external signals with main clock domain
 414                 cs0_xc_f_s     <= not cs0_xc;
 415                 bls_f_s        <= not bls;
 416                 rd_f_s         <= not rd;
 417                 data_f_s       <= data;
 418                 if address_hold_s = '0' then
 419                         address_f_s <= address;
 420                 else
 421                         address_f_s <= next_last_address_s;
 422                 end if;
 423
 424                 -- Synchronoust state andvance to next period
 425                 last_bls_s     <= next_last_bls_s;
 426                 last_rd_s      <= next_last_rd_s;
 427                 i_bls_s        <= next_i_bls_s;
 428                 -- i_rd_s         <= next_i_rd_s;
 429                 i_rd_cycle2_s  <= next_i_rd_cycle2_s;
 430                 last_i_rd_s    <= next_last_i_rd_s;
 431                 data_write_s   <= next_data_write_s;
 432                 last_address_s <= next_last_address_s;
 433                 data_read_s    <= next_data_read_s;
 434                 --
 435                 -- ======================================================
 436                 --  TUMBL BUS
 437                 -- ======================================================
 438
 439                 -- Just copy these to their desired next state
 440                 irc_proc_ce_s <= irc_proc_next_ce_s;
 441                 lxmaster_ce_s <= lxmaster_next_ce_s;
 442
 443         end process;
 444
 445 -- Do the actual wiring here
 446 memory_bus_wiring:
 447         process(cs0_xc_f_s, i_bls_s, address_f_s, tumbl_out_s, meas_out_s, master_tumbl_xmem_out_s)
 448         begin
 449
 450                 -- Inactive by default
 451                 tumbl_ce_s             <= '0';
 452                 meas_ce_s              <= '0';
 453                 master_tumbl_xmem_ce_s <= '0';
 454                 data_o_s               <= (others => '0');
 455
 456                 if cs0_xc_f_s = '1' or i_bls_s /= "0000" then
 457
 458                         -- Memory Map (16-bit address @ 32-bit each)
 459
 460                         -- Each address is seen as 32-bit entry now
 461                         -- 0x0000 - 0x0FFF: Tumbl IMEM / DMEM
 462                         -- 0x1FFC - 0x1FFF: Measurement
 463                         -- 0x8000 - 0x8FFF: Tumbl BUS
 464
 465                         if address_f_s < "0001000000000000" then                  -- Tumbl
 466                                 tumbl_ce_s             <= '1';
 467                                 data_o_s               <= tumbl_out_s;
 468                         elsif address_f_s(15 downto 2) = "00011111111111" then    -- Measurement
 469                                 meas_ce_s              <= '1';
 470                                 data_o_s               <= meas_out_s;
 471                         elsif address_f_s(15) = '1' then                          -- Tumbl External BUS
 472                                 master_tumbl_xmem_ce_s <= '1';
 473                                 data_o_s               <= master_tumbl_xmem_out_s;
 474                         end if;
 475
 476                 end if;
 477
 478         end process;
 479
 480 -- If RD and BLS is not high, we must keep DATA at high impedance
 481 -- or the FPGA collides with SDRAM (damaging each other)
 482 memory_bus_out:
 483         process(cs0_xc, rd, data_read_s)
 484         begin
 485
 486                 -- CS0 / RD / BLS are active LOW
 487                 if cs0_xc = '0' and rd = '0' then
 488                         -- Don't risk flipping (between data_o_s and latched data_read_s, it's better to wait)
 489                         -- Maybe check this later.
 490                         -- if last_i_rd_s = '1' then
 491                         --   data <= data_o_s;
 492                         -- else
 493                         data <= data_read_s;
 494                         -- end if;
 495                 else
 496                         -- IMPORTANT!!!
 497                         data <= (others => 'Z');
 498                 end if;
 499
 500         end process;
 501
 502 -- Outputs from Tumbl (enabling and address muxing) and Master CPU
 503 tumbl_bus_o:
 504         process(tumbl_xmemb_sel_s, tumbl_xmemb_o_s, master_tumbl_xmem_ce_s, address_f_s, i_rd_s, i_bls_s)
 505                 variable addr_v : std_logic_vector(14 downto 0); -- This space is visible by both (32-bit)
 506                 variable sel_v  : std_logic;
 507         begin
 508
 509                 -- Defaults
 510                 irc_proc_next_ce_s        <= '0';
 511                 lxmaster_next_ce_s        <= '0';
 512                 master_tumbl_xmem_lock_s  <= '0';
 513                 --
 514                 addr_v                    := (others => '0');
 515                 sel_v                     := '0';
 516
 517                 -- Check who is accessing
 518                 if master_tumbl_xmem_ce_s = '1' and (i_rd_s = '1' or i_bls_s /= "0000") then
 519                         -- Master blocks Tumbl
 520                         master_tumbl_xmem_lock_s <= '1';
 521                         addr_v                   := address_f_s(14 downto 0);
 522                         sel_v                    := '1';
 523                 else
 524                         addr_v                   := tumbl_xmemb_o_s.addr;
 525                         sel_v                    := '1';
 526                 end if;
 527
 528                 if sel_v = '1' then
 529                         -- IRC:       0x0800 - 0x081F (32-bit address)
 530                         -- LX MASTER: 0x1000 - 0x17FF (32-bit address)
 531                         if addr_v(14 downto 5) = "0001000000" then
 532                                 irc_proc_next_ce_s     <= '1';
 533                         elsif addr_v(14 downto 11) = "0010" then
 534                                 lxmaster_next_ce_s     <= '1';
 535                         end if;
 536                 end if;
 537
 538         end process;
 539
 540 -- Inputs to Tumbl (enabling and address muxing)
 541 tumbl_bus_i:
 542         process(irc_proc_ce_s, irc_proc_out_s, lxmaster_ce_s, lxmaster_out_s, tumbl_xmemb_i_s)
 543         begin
 544
 545                 tumbl_xmemb_i_s.data  <= (others => 'X');
 546
 547                 -- NOTE: This is input to Tumbl EXEQ - with MUL instruction for input > 18-bit,
 548                 -- (i.e. more DSPs in a sequence), this already has tough timing constraints
 549                 -- and SmartXplorer has to be used with XiSE or use Synplify.
 550                 if irc_proc_ce_s = '1' then
 551                         tumbl_xmemb_i_s.data <= irc_proc_out_s;
 552                 elsif lxmaster_ce_s = '1' then
 553                         tumbl_xmemb_i_s.data(15 downto 0)  <= lxmaster_out_s;
 554                         tumbl_xmemb_i_s.data(31 downto 16) <= (others => '0');
 555                 end if;
 556
 557                 master_tumbl_xmem_out_s <= tumbl_xmemb_i_s.data;
 558
 559         end process;
 560
 561 end Behavioral;
 562