/* linker script for applications running from FLASH */

INCLUDE "hi_cpu2.ld-cfg"

/* PROVIDE ( sym = val ); */

PROVIDE( ___stack_top = ( __iram0_end & ~ 3 ) - 4 );
PROVIDE( ___heap_end = __ram_end );

STARTUP(crt0.o)
INPUT(bsp0common.o)

SECTIONS
{
	.text :
	{
	  . = ALIGN( 4 ) ;
	  text_start = . ;
	  LONG( ABSOLUTE( _start ) + 0x5a000000 ) /* JMP _start */
/* 	  KEEP (crt0.o(.text)) */
	  . = ALIGN( 4 ) ;
	  ___boot_fn_load = ALIGN( 0x4 ) ;
	  ___boot_fn_start = ALIGN( 0x4 ) ;
          KEEP (*boot_fn.o(.text))
	  KEEP (*boot_fn.o(.rodata))
	  . = ALIGN( 4 ) ;
	  ___boot_fn_end = ALIGN( 0x4 ) ;
	  *(.text .stub .text.* .gnu.linkonce.t.*)
	  *(.rodata .rodata.* .gnu.linkonce.r.*)
	  . = ALIGN( 4 ) ;
	  ___nls_str_start = ALIGN( 0x4 ) ;
	  *(.nls_str) 				
	  ___nls_str_end = ALIGN( 0x4 ) ;
	  *(.strings)
	  _etext = ALIGN( 0x10 ) ;
	} > flashusr

	.shadreg (NOLOAD) :
	{
	  *(.shadreg)
	  . = ALIGN( 0x4 ) ;
	} > iram0

	.tors : 
	{
	  ___ctors = . ;
	  *(.ctors)
	  ___ctors_end = . ;
	  ___dtors = . ;
	  *(.dtors)
	  ___dtors_end = . ;
	  . = ALIGN( 0x10 ) ;
	  ___data_lma = ALIGN( 0x10 ) ;
	}  > flashusr

	.data :
	    AT ( ADDR( .tors ) + SIZEOF( .tors ) )
	{
	  _data_start = . ;
	  *(.data)
	  . = ALIGN( 0x4 ) ;
	  _edata = ALIGN( 0x4 ) ;
	} > ram /*at> flashusr*/

	/* ___data_lma = LOADADDR(.data) ; */

	.bss :
	{
	  _bss_start = ALIGN( 0x10 ) ;
	  *(.bss)
	  *(COMMON)
	  . = ALIGN( 0x4 ) ;
	  _end = ALIGN( 0x4 ) ;
	} > ram

	.tiny : 
	{
	  *(.tiny)
	}  > iram0
	
	.eight : 
	{
	  *(.eight)
	}  > eight

	/* Stabs debugging sections.  */
	.stab          0 (NOLOAD): { *(.stab) }
	.stabstr       0 (NOLOAD): { *(.stabstr) }
	.stab.excl     0 (NOLOAD): { *(.stab.excl) }
	.stab.exclstr  0 (NOLOAD): { *(.stab.exclstr) }
	.stab.index    0 (NOLOAD): { *(.stab.index) }
	.stab.indexstr 0 (NOLOAD): { *(.stab.indexstr) }
	.comment       0 (NOLOAD): { *(.comment) }
	/* DWARF debug sections.
	   Symbols in the DWARF debugging sections are relative to the beginning
	   of the section so we begin them at 0.  */
	/* DWARF 1 */
	.debug          0 (NOLOAD): { *(.debug) }
	.line           0 (NOLOAD): { *(.line) }
	/* GNU DWARF 1 extensions */
	.debug_srcinfo  0 (NOLOAD): { *(.debug_srcinfo) }
	.debug_sfnames  0 (NOLOAD): { *(.debug_sfnames) }
	/* DWARF 1.1 and DWARF 2 */
	.debug_aranges  0 (NOLOAD): { *(.debug_aranges) }
	.debug_pubnames 0 (NOLOAD): { *(.debug_pubnames) }
	/* DWARF 2 */
	.debug_info     0 (NOLOAD): { *(.debug_info .gnu.linkonce.wi.*) }
	.debug_abbrev   0 (NOLOAD): { *(.debug_abbrev) }
	.debug_line     0 (NOLOAD): { *(.debug_line) }
	.debug_frame    0 (NOLOAD): { *(.debug_frame) }
	.debug_str      0 (NOLOAD): { *(.debug_str) }
	.debug_loc      0 (NOLOAD): { *(.debug_loc) }
	.debug_macinfo  0 (NOLOAD): { *(.debug_macinfo) }
	/* SGI/MIPS DWARF 2 extensions */
	.debug_weaknames 0 (NOLOAD): { *(.debug_weaknames) }
	.debug_funcnames 0 (NOLOAD): { *(.debug_funcnames) }
	.debug_typenames 0 (NOLOAD): { *(.debug_typenames) }
	.debug_varnames  0 (NOLOAD): { *(.debug_varnames) }
	/* DWARF 3 */
	.debug_pubtypes 0 (NOLOAD): { *(.debug_pubtypes) }
	.debug_ranges   0 (NOLOAD): { *(.debug_ranges) }
	.gnu.attributes 0 (NOLOAD): { KEEP (*(.gnu.attributes)) }
}